CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 OPTION(ALSOFT_CPUEXT_SSE  "Check for SSE/SSE2 support" ON)
  29 OPTION(ALSOFT_CPUEXT_NEON "Check for ARM Neon support" ON)
  30
  31 OPTION(ALSOFT_REQUIRE_SSE  "Require SSE/SSE2 support" OFF)
  32 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
  33
  34 IF(WIN32)
  35     # This option is mainly for static linking OpenAL Soft into another project
  36     # that already defines the IDs. It is up to that project to ensure all
  37     # required IDs are defined.
  38     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  39 ENDIF()
  40
  41
  42 OPTION(ALSOFT_BACKEND_ALSA    "Check for ALSA backend"                ON)
  43 OPTION(ALSOFT_BACKEND_OSS     "Check for OSS backend"                 ON)
  44 OPTION(ALSOFT_BACKEND_SOLARIS "Check for Solaris backend"             ON)
  45 OPTION(ALSOFT_BACKEND_SNDIO   "Check for SndIO backend"               ON)
  46 OPTION(ALSOFT_BACKEND_QSA     "Check for QSA backend"                 ON)
  47 OPTION(ALSOFT_BACKEND_MMDEVAPI "Check for MMDevApi backend"           ON)
  48 OPTION(ALSOFT_BACKEND_DSOUND   "Check for DirectSound backend"        ON)
  49 OPTION(ALSOFT_BACKEND_WINMM    "Check for Windows Multimedia backend" ON)
  50 OPTION(ALSOFT_BACKEND_PORTAUDIO  "Check for PortAudio backend"        ON)
  51 OPTION(ALSOFT_BACKEND_PULSEAUDIO "Check for PulseAudio backend"       ON)
  52 OPTION(ALSOFT_BACKEND_COREAUDIO  "Check for CoreAudio backend"        ON)
  53 OPTION(ALSOFT_BACKEND_OPENSL     "Check for OpenSL backend"           ON)
  54 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend"               ON)
  55
  56 OPTION(ALSOFT_MIDI_FLUIDSYNTH "Check for FluidSynth MIDI"             ON)
  57
  58 OPTION(ALSOFT_REQUIRE_ALSA       "Require ALSA backend"               OFF)
  59 OPTION(ALSOFT_REQUIRE_OSS        "Require OSS backend"                OFF)
  60 OPTION(ALSOFT_REQUIRE_SOLARIS    "Require Solaris backend"            OFF)
  61 OPTION(ALSOFT_REQUIRE_SNDIO      "Require SndIO backend"              OFF)
  62 OPTION(ALSOFT_REQUIRE_QSA        "Require QSA backend"                OFF)
  63 OPTION(ALSOFT_REQUIRE_MMDEVAPI   "Require MMDevApi"                   OFF)
  64 OPTION(ALSOFT_REQUIRE_DSOUND     "Require DirectSound backend"        OFF)
  65 OPTION(ALSOFT_REQUIRE_WINMM      "Require Windows Multimedia backend" OFF)
  66 OPTION(ALSOFT_REQUIRE_PORTAUDIO  "Require PortAudio backend"          OFF)
  67 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend"         OFF)
  68 OPTION(ALSOFT_REQUIRE_COREAUDIO  "Require CoreAudio backend"          OFF)
  69 OPTION(ALSOFT_REQUIRE_OPENSL     "Require OpenSL backend"             OFF)
  70
  71 OPTION(ALSOFT_REQUIRE_FLUIDSYNTH "Require FluidSynth MIDI"            OFF)
  72
  73 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  74
  75 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  76
  77 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  78 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  79
  80 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  81
  82 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  83 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  84
  85
  86 IF(WIN32)
  87     SET(LIBNAME OpenAL32)
  88     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0501")
  89 ELSE()
  90     SET(LIBNAME openal)
  91 ENDIF()
  92
  93 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  94 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  95     ADD_DEFINITIONS("-I/usr/include")
  96     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  97 ENDIF()
  98
  99 IF(NOT LIBTYPE)
 100     SET(LIBTYPE SHARED)
 101 ENDIF()
 102
 103 SET(LIB_MAJOR_VERSION "1")
 104 SET(LIB_MINOR_VERSION "15")
 105 SET(LIB_REVISION "1")
 106 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 107
 108 SET(EXPORT_DECL "")
 109 SET(ALIGN_DECL "")
 110
 111
 112 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 113 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 114
 115
 116 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 117 IF(HAVE_STD_C99)
 118     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 119 ENDIF()
 120
 121 # MSVC may need workarounds for C99 restrict and inline
 122 IF(MSVC)
 123     # TODO: Once we truly require C99, these restrict and inline checks should go
 124     # away.
 125     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 126                              int main() {return 0;}" HAVE_RESTRICT)
 127     IF(NOT HAVE_RESTRICT)
 128         # Slightly convoluted way to do this, because MSVC may barf if restrict is
 129         # defined to __restrict.
 130         CHECK_C_SOURCE_COMPILES("#define restrict __restrict
 131                                  #include <stdlib.h>
 132                                  int *restrict foo;
 133                                  int main() {return 0;}" HAVE___RESTRICT)
 134         IF(HAVE___RESTRICT)
 135             ADD_DEFINITIONS(-Drestrict=__restrict)
 136             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=__restrict")
 137         ELSE()
 138             ADD_DEFINITIONS("-Drestrict=")
 139             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 140         ENDIF()
 141     ENDIF()
 142
 143     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 144                              int main() {return 0;}" HAVE_INLINE)
 145     IF(NOT HAVE_INLINE)
 146         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 147                                  int main() {return 0;}" HAVE___INLINE)
 148         IF(NOT HAVE___INLINE)
 149             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 150         ENDIF()
 151
 152         ADD_DEFINITIONS(-Dinline=__inline)
 153         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 154     ENDIF()
 155 ENDIF()
 156
 157 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 158 IF(CMAKE_COMPILER_IS_GNUCC)
 159     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 160     # Force no inlining for the next test.
 161     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 162
 163     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 164                              int main() {return foo();}" INLINE_IS_C99)
 165     IF(NOT INLINE_IS_C99)
 166         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 167                              Please update your compiler for better C99 compliance.")
 168     ENDIF()
 169
 170     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 171 ENDIF()
 172
 173 # Add definitions, compiler switches, etc.
 174 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 175 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 176     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 177     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 178         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 179     ENDIF()
 180 ENDIF()
 181
 182 IF(NOT CMAKE_BUILD_TYPE)
 183     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 184         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 185         FORCE)
 186 ENDIF()
 187 IF(NOT CMAKE_DEBUG_POSTFIX)
 188     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 189         "Library postfix for debug builds. Normally left blank."
 190         FORCE)
 191 ENDIF()
 192
 193 IF(MSVC)
 194     # ???
 195     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 196     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 197     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 198     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 199     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 200     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 201     ADD_DEFINITIONS("/wd4098")
 202
 203     IF(NOT DXSDK_DIR)
 204         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 205     ELSE()
 206         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 207     ENDIF()
 208     IF(DXSDK_DIR)
 209         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 210         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 211         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 212         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 213     ENDIF()
 214
 215     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 216     IF(FORCE_STATIC_VCRT)
 217         FOREACH(flag_var
 218                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 219                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 220             IF(${flag_var} MATCHES "/MD")
 221                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 222             ENDIF()
 223         ENDFOREACH(flag_var)
 224     ENDIF()
 225 ELSE()
 226     ADD_DEFINITIONS(-Winline -Wall)
 227     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 228     IF(HAVE_W_EXTRA)
 229         ADD_DEFINITIONS(-Wextra)
 230     ENDIF()
 231
 232     IF(ALSOFT_WERROR)
 233         ADD_DEFINITIONS(-Werror)
 234     ENDIF()
 235
 236     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 237         "Flags used by the compiler during Release with Debug Info builds."
 238         FORCE)
 239     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 240         "Flags used by the compiler during release minsize builds."
 241         FORCE)
 242     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 243         "Flags used by the compiler during release builds"
 244         FORCE)
 245     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 246         "Flags used by the compiler during debug builds."
 247         FORCE)
 248
 249     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 250                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 251 ENDIF()
 252
 253 # Set visibility/export options if available
 254 IF(WIN32)
 255     SET(EXPORT_DECL "__declspec(dllexport)")
 256     IF(NOT MINGW)
 257         SET(ALIGN_DECL "__declspec(align(x))")
 258     ELSE()
 259         SET(ALIGN_DECL "__declspec(aligned(x))")
 260     ENDIF()
 261 ELSE()
 262     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 263     # Yes GCC, really don't accept visibility modes you don't support
 264     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 265
 266     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 267                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 268     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 269         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 270     ELSE()
 271         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 272                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 273         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 274             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 275         ENDIF()
 276     ENDIF()
 277
 278     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 279         CHECK_C_COMPILER_FLAG(-fvisibility=internal HAVE_VISIBILITY_INTERNAL_SWITCH)
 280         IF(HAVE_VISIBILITY_INTERNAL_SWITCH)
 281             ADD_DEFINITIONS(-fvisibility=internal)
 282         ELSE()
 283             CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 284             IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 285                 ADD_DEFINITIONS(-fvisibility=hidden)
 286             ENDIF()
 287         ENDIF()
 288     ENDIF()
 289
 290     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 291                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 292     IF(HAVE_ATTRIBUTE_ALIGNED)
 293         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 294     ENDIF()
 295
 296     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 297 ENDIF()
 298
 299 SET(SSE_SWITCH "")
 300 IF(MSVC)
 301     CHECK_C_COMPILER_FLAG(/arch:SSE HAVE_ARCHSSE_SWITCH)
 302     IF(HAVE_ARCHSSE_SWITCH)
 303         SET(SSE_SWITCH "/arch:SSE")
 304     ENDIF()
 305 ENDIF()
 306 IF(NOT SSE_SWITCH)
 307     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 308     IF(HAVE_MSSE_SWITCH)
 309         SET(SSE_SWITCH "-msse")
 310     ENDIF()
 311 ENDIF()
 312
 313 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 314                          int main() {return 0;}" HAVE_GCC_FORMAT)
 315
 316 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 317 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 318 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 319 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 320 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 321 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 322 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 323 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 324 IF(NOT HAVE_GUIDDEF_H)
 325     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 326 ENDIF()
 327
 328 # Some systems need libm for some of the following math functions to work
 329 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 330 IF(HAVE_LIBM)
 331     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 332     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 333 ENDIF()
 334
 335
 336 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 337 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 338 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 339 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 340
 341 IF(HAVE_FLOAT_H)
 342     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 343     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 344 ENDIF()
 345
 346 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 347 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 348 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 349 IF(NOT HAVE_STRCASECMP)
 350     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 351     IF(NOT HAVE__STRICMP)
 352         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 353     ENDIF()
 354
 355     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 356 ENDIF()
 357
 358 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 359 IF(NOT HAVE_STRNCASECMP)
 360     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 361     IF(NOT HAVE__STRNICMP)
 362         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 363     ENDIF()
 364
 365     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 366 ENDIF()
 367
 368 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 369 IF(NOT HAVE_SNPRINTF)
 370     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 371     IF(NOT HAVE__SNPRINTF)
 372         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 373     ENDIF()
 374
 375     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 376 ENDIF()
 377
 378 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 379 IF(NOT HAVE_ISFINITE)
 380     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 381     IF(NOT HAVE_FINITE)
 382         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 383         IF(NOT HAVE__FINITE)
 384             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 385         ENDIF()
 386         ADD_DEFINITIONS(-Disfinite=_finite)
 387     ELSE()
 388         ADD_DEFINITIONS(-Disfinite=finite)
 389     ENDIF()
 390 ENDIF()
 391
 392 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 393 IF(NOT HAVE_ISNAN)
 394     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 395     IF(NOT HAVE__ISNAN)
 396         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 397     ENDIF()
 398
 399     ADD_DEFINITIONS(-Disnan=_isnan)
 400 ENDIF()
 401
 402
 403 # Check for the dlopen API (for dynamicly loading backend libs)
 404 IF(ALSOFT_DLOPEN)
 405     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 406     IF(HAVE_DLFCN_H)
 407         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 408         IF(HAVE_LIBDL)
 409             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 410         ENDIF()
 411     ENDIF()
 412 ENDIF()
 413
 414 # Check if we have Windows headers
 415 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0501)
 416 IF(NOT HAVE_WINDOWS_H)
 417     # These are needed on some systems for extra features
 418     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
 419     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
 420
 421     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 422     IF(NOT HAVE_GETTIMEOFDAY)
 423         MESSAGE(FATAL_ERROR "No timing function found!")
 424     ENDIF()
 425
 426     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 427     IF(NOT HAVE_NANOSLEEP)
 428         MESSAGE(FATAL_ERROR "No sleep function found!")
 429     ENDIF()
 430
 431     # We need pthreads outside of Windows
 432     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 433     IF(NOT HAVE_PTHREAD_H)
 434         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 435     ENDIF()
 436     # Some systems need pthread_np.h to get recursive mutexes
 437     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 438
 439     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 440     IF(HAVE_PTHREAD)
 441         ADD_DEFINITIONS(-pthread)
 442         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 443         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 444     ENDIF()
 445
 446     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 447     IF(HAVE_LIBPTHREAD)
 448         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 449     ENDIF()
 450
 451     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 452
 453     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 454     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 455         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 456     ENDIF()
 457
 458     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 459     IF(HAVE_LIBRT)
 460         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 461     ENDIF()
 462 ENDIF()
 463
 464 # Check for a 64-bit type
 465 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 466 IF(NOT HAVE_STDINT_H)
 467     IF(HAVE_WINDOWS_H)
 468         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0501
 469                                  #include <windows.h>
 470                                  __int64 foo;
 471                                  int main() {return 0;}" HAVE___INT64)
 472     ENDIF()
 473     IF(NOT HAVE___INT64)
 474         IF(NOT SIZEOF_LONG MATCHES "8")
 475             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 476                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 477             ENDIF()
 478         ENDIF()
 479     ENDIF()
 480 ENDIF()
 481
 482 # Windows needs winmm for timeGetTime, even if the backend is disabled
 483 CHECK_SHARED_FUNCTION_EXISTS(timeGetTime "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 484 IF(HAVE_LIBWINMM)
 485     SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 486     SET(PKG_CONFIG_LIBS ${PKG_CONFIG_LIBS} -lwinmm)
 487 ENDIF()
 488
 489
 490 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 491                  OpenAL32/alBuffer.c
 492                  OpenAL32/alEffect.c
 493                  OpenAL32/alError.c
 494                  OpenAL32/alExtension.c
 495                  OpenAL32/alFilter.c
 496                  OpenAL32/alFontsound.c
 497                  OpenAL32/alListener.c
 498                  OpenAL32/alMidi.c
 499                  OpenAL32/alPreset.c
 500                  OpenAL32/alSoundfont.c
 501                  OpenAL32/alSource.c
 502                  OpenAL32/alState.c
 503                  OpenAL32/alThunk.c
 504 )
 505 SET(ALC_OBJS  Alc/ALc.c
 506               Alc/ALu.c
 507               Alc/alcConfig.c
 508               Alc/alcRing.c
 509               Alc/bs2b.c
 510               Alc/effects/autowah.c
 511               Alc/effects/chorus.c
 512               Alc/effects/compressor.c
 513               Alc/effects/dedicated.c
 514               Alc/effects/distortion.c
 515               Alc/effects/echo.c
 516               Alc/effects/equalizer.c
 517               Alc/effects/flanger.c
 518               Alc/effects/modulator.c
 519               Alc/effects/null.c
 520               Alc/effects/reverb.c
 521               Alc/helpers.c
 522               Alc/hrtf.c
 523               Alc/panning.c
 524               Alc/threads.c
 525               Alc/mixer.c
 526               Alc/mixer_c.c
 527 )
 528
 529
 530 SET(CPU_EXTS "Default")
 531 SET(HAVE_SSE  0)
 532 SET(HAVE_NEON 0)
 533
 534 # Check for SSE support
 535 IF(ALSOFT_CPUEXT_SSE AND ALIGN_DECL)
 536     CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 537     IF(HAVE_XMMINTRIN_H)
 538         SET(HAVE_SSE 1)
 539         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 540         IF(SSE_SWITCH)
 541             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 542                                         COMPILE_FLAGS "${SSE_SWITCH}")
 543         ENDIF()
 544         SET(CPU_EXTS "${CPU_EXTS}, SSE")
 545     ENDIF()
 546 ENDIF()
 547 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 548     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 549 ENDIF()
 550
 551 # Check for ARM Neon support
 552 IF(ALSOFT_CPUEXT_NEON)
 553     CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 554     IF(HAVE_ARM_NEON_H)
 555         SET(HAVE_NEON 1)
 556         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 557         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 558     ENDIF()
 559 ENDIF()
 560 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 561     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 562 ENDIF()
 563
 564
 565 SET(ALC_OBJS  ${ALC_OBJS}
 566               Alc/midi/base.c
 567               Alc/midi/sf2load.c
 568               Alc/midi/dummy.c
 569               Alc/midi/fluidsynth.c
 570 )
 571
 572 SET(HAVE_FLUIDSYNTH  0)
 573
 574 # Check for FluidSynth support
 575 IF(ALSOFT_MIDI_FLUIDSYNTH)
 576     FIND_PACKAGE(FluidSynth)
 577     IF(FLUIDSYNTH_FOUND)
 578         SET(HAVE_FLUIDSYNTH 1)
 579         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 580             INCLUDE_DIRECTORIES(${FLUIDSYNTH_INCLUDE_DIR})
 581         ENDIF()
 582         SET(EXTRA_LIBS ${FLUIDSYNTH_LIBRARIES} ${EXTRA_LIBS})
 583     ENDIF()
 584 ENDIF()
 585 IF(ALSOFT_REQUIRE_FLUIDSYNTH AND NOT HAVE_FLUIDSYNTH)
 586     MESSAGE(FATAL_ERROR "Failed to enabled required FluidSynth support")
 587 ENDIF()
 588
 589
 590 SET(ALC_OBJS  ${ALC_OBJS}
 591               Alc/backends/base.c
 592               # Default backends, always available
 593               Alc/backends/loopback.c
 594               Alc/backends/null.c
 595 )
 596
 597 SET(BACKENDS "")
 598 SET(HAVE_ALSA       0)
 599 SET(HAVE_OSS        0)
 600 SET(HAVE_SOLARIS    0)
 601 SET(HAVE_SNDIO      0)
 602 SET(HAVE_QSA        0)
 603 SET(HAVE_DSOUND     0)
 604 SET(HAVE_MMDEVAPI   0)
 605 SET(HAVE_WINMM      0)
 606 SET(HAVE_PORTAUDIO  0)
 607 SET(HAVE_PULSEAUDIO 0)
 608 SET(HAVE_COREAUDIO  0)
 609 SET(HAVE_OPENSL     0)
 610 SET(HAVE_WAVE       0)
 611
 612 # Check ALSA backend
 613 IF(ALSOFT_BACKEND_ALSA)
 614     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 615     IF(HAVE_ALSA_ASOUNDLIB_H)
 616         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "alsa/asoundlib.h" asound "" HAVE_LIBASOUND)
 617         IF(HAVE_LIBASOUND OR HAVE_DLFCN_H OR WIN32)
 618             SET(HAVE_ALSA 1)
 619             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 620             IF(HAVE_DLFCN_H OR WIN32)
 621                 SET(BACKENDS  "${BACKENDS} ALSA,")
 622             ELSE()
 623                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 624                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 625             ENDIF()
 626         ENDIF()
 627     ENDIF()
 628 ENDIF()
 629 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 630     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 631 ENDIF()
 632
 633 # Check OSS backend
 634 IF(ALSOFT_BACKEND_OSS)
 635     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 636     IF(HAVE_SYS_SOUNDCARD_H)
 637         SET(HAVE_OSS 1)
 638         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 639         SET(BACKENDS  "${BACKENDS} OSS,")
 640     ENDIF()
 641 ENDIF()
 642 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 643     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 644 ENDIF()
 645
 646 # Check Solaris backend
 647 IF(ALSOFT_BACKEND_SOLARIS)
 648     CHECK_INCLUDE_FILE(sys/audioio.h HAVE_SYS_AUDIOIO_H)
 649     IF(HAVE_SYS_AUDIOIO_H)
 650         SET(HAVE_SOLARIS 1)
 651         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 652         SET(BACKENDS  "${BACKENDS} Solaris,")
 653     ENDIF()
 654 ENDIF()
 655 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 656     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 657 ENDIF()
 658
 659 # Check SndIO backend
 660 IF(ALSOFT_BACKEND_SNDIO)
 661     CHECK_INCLUDE_FILE(sndio.h HAVE_SNDIO_H)
 662     IF(HAVE_SNDIO_H)
 663         CHECK_SHARED_FUNCTION_EXISTS(sio_open "sndio.h" sndio "" HAVE_LIBSNDIO)
 664         IF(HAVE_LIBSNDIO)
 665             SET(HAVE_SNDIO 1)
 666             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 667             SET(BACKENDS  "${BACKENDS} SndIO \(linked\),")
 668             SET(EXTRA_LIBS sndio ${EXTRA_LIBS})
 669         ENDIF()
 670     ENDIF()
 671 ENDIF()
 672 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 673     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 674 ENDIF()
 675
 676 # Check QSA backend
 677 IF (ALSOFT_BACKEND_QSA AND "${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 678     CHECK_INCLUDE_FILE(sys/asoundlib.h HAVE_SYS_ASOUNDLIB_H)
 679     IF(HAVE_SYS_ASOUNDLIB_H)
 680         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "sys/asoundlib.h" asound "" HAVE_LIBASOUND)
 681         IF(HAVE_LIBASOUND)
 682             SET(HAVE_QSA 1)
 683             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 684             SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 685             SET(BACKENDS  "${BACKENDS} QSA \(linked\),")
 686         ENDIF()
 687     ENDIF()
 688 ENDIF()
 689 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 690     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 691 ENDIF()
 692
 693 # Check for MMDevApi backend
 694 IF(HAVE_WINDOWS_H)
 695     IF(ALSOFT_BACKEND_MMDEVAPI)
 696         CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 697         IF(HAVE_MMDEVICEAPI_H)
 698             SET(HAVE_MMDEVAPI 1)
 699             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 700
 701             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 702         ENDIF()
 703     ENDIF()
 704 ENDIF()
 705 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 706     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 707 ENDIF()
 708
 709 # Check DSound/MMSystem backend
 710 IF(ALSOFT_BACKEND_DSOUND)
 711     CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 712     IF(HAVE_DSOUND_H)
 713         CHECK_SHARED_FUNCTION_EXISTS(DirectSoundCreate "dsound.h" dsound "" HAVE_LIBDSOUND)
 714         IF(HAVE_LIBDSOUND OR HAVE_DLFCN_H OR WIN32)
 715             SET(HAVE_DSOUND 1)
 716             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 717
 718             IF(HAVE_DLFCN_H OR WIN32)
 719                 SET(BACKENDS  "${BACKENDS} DirectSound,")
 720             ELSE()
 721                 SET(BACKENDS  "${BACKENDS} DirectSound \(linked\),")
 722                 SET(EXTRA_LIBS dsound ${EXTRA_LIBS})
 723             ENDIF()
 724         ENDIF()
 725     ENDIF()
 726 ENDIF()
 727 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 728     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 729 ENDIF()
 730
 731 IF(HAVE_WINDOWS_H)
 732     IF(ALSOFT_BACKEND_WINMM)
 733         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0501)
 734         IF(HAVE_MMSYSTEM_H AND HAVE_LIBWINMM)
 735             SET(HAVE_WINMM 1)
 736             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 737             SET(BACKENDS  "${BACKENDS} WinMM,")
 738         ENDIF()
 739     ENDIF()
 740 ENDIF()
 741 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 742     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 743 ENDIF()
 744
 745 # Check PortAudio backend
 746 IF(ALSOFT_BACKEND_PORTAUDIO)
 747     CHECK_INCLUDE_FILE(portaudio.h HAVE_PORTAUDIO_H)
 748     IF(HAVE_PORTAUDIO_H)
 749         CHECK_SHARED_FUNCTION_EXISTS(Pa_Initialize "portaudio.h" portaudio "" HAVE_LIBPORTAUDIO)
 750         IF(HAVE_LIBPORTAUDIO OR HAVE_DLFCN_H OR WIN32)
 751             SET(HAVE_PORTAUDIO 1)
 752             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 753             IF(HAVE_DLFCN_H OR WIN32)
 754                 SET(BACKENDS  "${BACKENDS} PortAudio,")
 755             ELSE()
 756                 SET(BACKENDS  "${BACKENDS} PortAudio \(linked\),")
 757                 SET(EXTRA_LIBS portaudio ${EXTRA_LIBS})
 758             ENDIF()
 759         ENDIF()
 760     ENDIF()
 761 ENDIF()
 762 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 763     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 764 ENDIF()
 765
 766 # Check PulseAudio backend
 767 IF(ALSOFT_BACKEND_PULSEAUDIO)
 768     CHECK_INCLUDE_FILE(pulse/pulseaudio.h HAVE_PULSE_PULSEAUDIO_H)
 769     IF(HAVE_PULSE_PULSEAUDIO_H)
 770         CHECK_SHARED_FUNCTION_EXISTS(pa_context_new "pulse/pulseaudio.h" pulse "" HAVE_LIBPULSE)
 771         IF(HAVE_LIBPULSE OR HAVE_DLFCN_H OR WIN32)
 772             SET(HAVE_PULSEAUDIO 1)
 773             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 774             IF(HAVE_DLFCN_H OR WIN32)
 775                 SET(BACKENDS  "${BACKENDS} PulseAudio,")
 776             ELSE()
 777                 SET(BACKENDS  "${BACKENDS} PulseAudio \(linked\),")
 778                 SET(EXTRA_LIBS pulse ${EXTRA_LIBS})
 779             ENDIF()
 780         ENDIF()
 781     ENDIF()
 782 ENDIF()
 783 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 784     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 785 ENDIF()
 786
 787 # Check CoreAudio backend
 788 IF(ALSOFT_BACKEND_COREAUDIO)
 789     CHECK_INCLUDE_FILE(/System/Library/Frameworks/CoreAudio.framework/Headers/CoreAudio.h HAVE_COREAUDIO_FRAMEWORK)
 790     IF(HAVE_COREAUDIO_FRAMEWORK)
 791         SET(HAVE_COREAUDIO 1)
 792         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 793         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 794         SET(EXTRA_LIBS /System/Library/Frameworks/CoreAudio.framework ${EXTRA_LIBS})
 795         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 796         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 797
 798         # Some versions of OSX may need the AudioToolbox framework. Add it if
 799         # it's found.
 800         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 801                      NAMES AudioToolbox
 802                      PATHS ~/Library/Frameworks
 803                            /Library/Frameworks
 804                            /System/Library/Frameworks
 805                     )
 806         IF(AUDIOTOOLBOX_LIBRARY)
 807             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 808         ENDIF()
 809     ENDIF()
 810 ENDIF()
 811 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 812     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 813 ENDIF()
 814
 815 # Check for OpenSL (Android) backend
 816 IF(ALSOFT_BACKEND_OPENSL)
 817     CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 818     IF(HAVE_SLES_OPENSLES_ANDROID_H)
 819         CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 820         IF(HAVE_LIBOPENSLES)
 821             SET(HAVE_OPENSL 1)
 822             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 823             SET(BACKENDS  "${BACKENDS} OpenSL,")
 824             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 825         ENDIF()
 826     ENDIF()
 827 ENDIF()
 828 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 829     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 830 ENDIF()
 831
 832 # Optionally enable the Wave Writer backend
 833 IF(ALSOFT_BACKEND_WAVE)
 834     SET(HAVE_WAVE 1)
 835     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 836     SET(BACKENDS  "${BACKENDS} WaveFile,")
 837 ENDIF()
 838
 839 # This is always available
 840 SET(BACKENDS  "${BACKENDS} Null")
 841
 842 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 843     add_subdirectory(utils/alsoft-config)
 844 ENDIF()
 845 IF(ALSOFT_EXAMPLES)
 846     FIND_PACKAGE(SDL)
 847     IF(SDL_FOUND)
 848         FIND_PACKAGE(SDL_sound)
 849         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 850             INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 851         ENDIF()
 852     ENDIF()
 853 ENDIF()
 854
 855 IF(LIBTYPE STREQUAL "STATIC")
 856     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 857     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 858 ENDIF()
 859
 860 # Needed for openal.pc.in
 861 SET(prefix ${CMAKE_INSTALL_PREFIX})
 862 SET(exec_prefix "\${prefix}")
 863 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 864 SET(bindir "\${exec_prefix}/bin")
 865 SET(includedir "\${prefix}/include")
 866 SET(PACKAGE_VERSION "${LIB_VERSION}")
 867
 868 # End configuration
 869 CONFIGURE_FILE(
 870     "${OpenAL_SOURCE_DIR}/config.h.in"
 871     "${OpenAL_BINARY_DIR}/config.h")
 872 CONFIGURE_FILE(
 873     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 874     "${OpenAL_BINARY_DIR}/openal.pc"
 875     @ONLY)
 876
 877 # Build a library
 878 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 879 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
 880 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 881     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
 882 ENDIF()
 883 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 884 IF(FLUIDSYNTH_FOUND)
 885     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${FLUIDSYNTH_INCLUDE_DIR})
 886 ENDIF()
 887 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 888                                             SOVERSION ${LIB_MAJOR_VERSION})
 889 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
 890     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 891 ENDIF()
 892
 893 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 894
 895 # Add an install target here
 896 INSTALL(TARGETS ${LIBNAME}
 897         RUNTIME DESTINATION bin
 898         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 899         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 900 )
 901 INSTALL(FILES include/AL/al.h
 902               include/AL/alc.h
 903               include/AL/alext.h
 904               include/AL/efx.h
 905               include/AL/efx-creative.h
 906               include/AL/efx-presets.h
 907         DESTINATION include/AL
 908 )
 909 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 910         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
 911
 912
 913 MESSAGE(STATUS "")
 914 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 915 MESSAGE(STATUS "    ${BACKENDS}")
 916 MESSAGE(STATUS "")
 917 MESSAGE(STATUS "Building with support for CPU extensions:")
 918 MESSAGE(STATUS "    ${CPU_EXTS}")
 919 MESSAGE(STATUS "")
 920 IF(HAVE_FLUIDSYNTH)
 921     MESSAGE(STATUS "FluidSynth support for ALC_SOFT_midi_interface enabled")
 922     MESSAGE(STATUS "")
 923 ENDIF()
 924
 925 IF(WIN32)
 926     IF(NOT HAVE_DSOUND)
 927         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
 928         MESSAGE(STATUS "         This is probably NOT what you want!")
 929         MESSAGE(STATUS "")
 930     ENDIF()
 931 ENDIF()
 932
 933 # Install alsoft.conf configuration file
 934 IF(ALSOFT_CONFIG)
 935     INSTALL(FILES alsoftrc.sample
 936             DESTINATION share/openal
 937     )
 938     MESSAGE(STATUS "Installing sample configuration")
 939     MESSAGE(STATUS "")
 940 ENDIF()
 941
 942 # Install HRTF definitions
 943 IF(ALSOFT_HRTF_DEFS)
 944     INSTALL(FILES hrtf/default-44100.mhr
 945             DESTINATION share/openal/hrtf
 946     )
 947     MESSAGE(STATUS "Installing HRTF definitions")
 948     MESSAGE(STATUS "")
 949 ENDIF()
 950
 951 IF(ALSOFT_UTILS)
 952     ADD_EXECUTABLE(openal-info utils/openal-info.c)
 953     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
 954
 955     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
 956     IF(HAVE_LIBM)
 957         TARGET_LINK_LIBRARIES(makehrtf m)
 958     ENDIF()
 959
 960     INSTALL(TARGETS openal-info makehrtf
 961             RUNTIME DESTINATION bin
 962             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 963             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 964     )
 965
 966     MESSAGE(STATUS "Building utility programs")
 967     IF(TARGET alsoft-config)
 968         MESSAGE(STATUS "Building configuration program")
 969     ENDIF()
 970     MESSAGE(STATUS "")
 971 ENDIF()
 972
 973 IF(ALSOFT_EXAMPLES)
 974     IF(SDL_FOUND AND SDL_SOUND_FOUND)
 975         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
 976                                      examples/common/sdl_sound.c)
 977         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 978
 979         ADD_EXECUTABLE(alstream examples/alstream.c)
 980         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 981         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 982
 983         ADD_EXECUTABLE(alreverb examples/alreverb.c)
 984         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 985         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 986
 987         ADD_EXECUTABLE(allatency examples/allatency.c)
 988         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 989         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 990
 991         ADD_EXECUTABLE(alloopback examples/alloopback.c)
 992         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL_LIBRARY} ${LIBNAME})
 993         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_INCLUDE_DIR}
 994                                                                            ${SDL_SOUND_INCLUDE_DIR})
 995
 996         INSTALL(TARGETS alstream alreverb allatency alloopback
 997                 RUNTIME DESTINATION bin
 998                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 999                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1000         )
1001
1002         MESSAGE(STATUS "Building example programs")
1003         MESSAGE(STATUS "")
1004     ENDIF()
1005 ENDIF()