CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 cmake_minimum_required(VERSION 3.13)
   4 enable_testing()
   5
   6 if(APPLE)
   7     # The workaround for try_compile failing with code signing
   8     # since cmake-3.18.2, not required
   9     set(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES
  10         ${CMAKE_TRY_COMPILE_PLATFORM_VARIABLES}
  11         "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED"
  12         "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED")
  13     set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED NO)
  14     set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED NO)
  15 endif()
  16
  17 if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
  18     # Fix compile failure with armv7 deployment target >= 11.0, xcode clang
  19     # will report:
  20     # error: invalid iOS deployment version '--target=armv7-apple-ios13.6',
  21     # iOS 10 is the maximum deployment target for 32-bit targets
  22     # If CMAKE_OSX_DEPLOYMENT_TARGET is not defined, cmake will choose latest
  23     # deployment target
  24     if("${CMAKE_OSX_ARCHITECTURES}" MATCHES ".*armv7.*")
  25         if(NOT DEFINED CMAKE_OSX_DEPLOYMENT_TARGET
  26             OR NOT CMAKE_OSX_DEPLOYMENT_TARGET VERSION_LESS "11.0")
  27             message(STATUS "Forcing iOS deployment target to 10.0 for armv7")
  28             set(CMAKE_OSX_DEPLOYMENT_TARGET "10.0" CACHE STRING "Minimum OS X deployment version"
  29                 FORCE)
  30         endif()
  31     endif()
  32 elseif(CMAKE_SYSTEM_NAME STREQUAL "WindowsStore")
  33     set(ALSOFT_UWP TRUE)
  34 endif()
  35
  36 if(COMMAND CMAKE_POLICY)
  37     cmake_policy(SET CMP0003 NEW)
  38     cmake_policy(SET CMP0005 NEW)
  39     if(POLICY CMP0020)
  40         cmake_policy(SET CMP0020 NEW)
  41     endif(POLICY CMP0020)
  42     if(POLICY CMP0042)
  43         cmake_policy(SET CMP0042 NEW)
  44     endif(POLICY CMP0042)
  45     if(POLICY CMP0054)
  46         cmake_policy(SET CMP0054 NEW)
  47     endif(POLICY CMP0054)
  48     if(POLICY CMP0058)
  49         cmake_policy(SET CMP0058 NEW)
  50     endif(POLICY CMP0058)
  51     if(POLICY CMP0063)
  52         cmake_policy(SET CMP0063 NEW)
  53     endif(POLICY CMP0063)
  54     if(POLICY CMP0075)
  55         cmake_policy(SET CMP0075 NEW)
  56     endif(POLICY CMP0075)
  57     if(POLICY CMP0092)
  58         cmake_policy(SET CMP0092 NEW)
  59     endif(POLICY CMP0092)
  60     if(POLICY CMP0117)
  61         cmake_policy(SET CMP0117 NEW)
  62     endif(POLICY CMP0117)
  63 endif(COMMAND CMAKE_POLICY)
  64
  65 project(OpenAL)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  69         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  70         FORCE)
  71 endif()
  72 if(NOT CMAKE_DEBUG_POSTFIX)
  73     set(CMAKE_DEBUG_POSTFIX "" CACHE STRING
  74         "Library postfix for debug builds. Normally left blank."
  75         FORCE)
  76 endif()
  77
  78 set(DEFAULT_TARGET_PROPS
  79     # Require C++17.
  80     CXX_STANDARD 17
  81     CXX_STANDARD_REQUIRED TRUE
  82     # Prefer C11, but support C99 and earlier when possible.
  83     C_STANDARD 11)
  84
  85 set(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  86
  87 include(CheckFunctionExists)
  88 include(CheckLibraryExists)
  89 include(CheckIncludeFile)
  90 include(CheckIncludeFiles)
  91 include(CheckSymbolExists)
  92 include(CheckCCompilerFlag)
  93 include(CheckCXXCompilerFlag)
  94 include(CheckCSourceCompiles)
  95 include(CheckCXXSourceCompiles)
  96 include(CheckStructHasMember)
  97 include(CMakePackageConfigHelpers)
  98 include(GNUInstallDirs)
  99
 100 find_package(PkgConfig)
 101 find_package(SDL2 QUIET)
 102
 103
 104 option(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
 105
 106 option(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
 107
 108 option(ALSOFT_UTILS "Build utility programs"  ON)
 109 option(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
 110
 111 option(ALSOFT_EXAMPLES  "Build example programs"  ON)
 112 option(ALSOFT_TESTS "Build test programs"  OFF)
 113
 114 option(ALSOFT_INSTALL "Install main library" ON)
 115 option(ALSOFT_INSTALL_CONFIG "Install alsoft.conf sample configuration file" ON)
 116 option(ALSOFT_INSTALL_HRTF_DATA "Install HRTF data files" ON)
 117 option(ALSOFT_INSTALL_AMBDEC_PRESETS "Install AmbDec preset files" ON)
 118 option(ALSOFT_INSTALL_EXAMPLES "Install example programs (alplay, alstream, ...)" ON)
 119 option(ALSOFT_INSTALL_UTILS "Install utility programs (openal-info, alsoft-config, ...)" ON)
 120 option(ALSOFT_UPDATE_BUILD_VERSION "Update git build version info" ON)
 121
 122 option(ALSOFT_EAX "Enable legacy EAX extensions" ${WIN32})
 123
 124 option(ALSOFT_SEARCH_INSTALL_DATADIR "Search the installation data directory" OFF)
 125 if(ALSOFT_SEARCH_INSTALL_DATADIR)
 126     set(ALSOFT_INSTALL_DATADIR ${CMAKE_INSTALL_FULL_DATADIR})
 127 endif()
 128
 129 if(DEFINED SHARE_INSTALL_DIR)
 130     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
 131     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
 132 endif()
 133
 134 if(DEFINED LIB_SUFFIX)
 135     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
 136 endif()
 137 if(DEFINED ALSOFT_CONFIG)
 138     message(WARNING "ALSOFT_CONFIG is deprecated. Use ALSOFT_INSTALL_CONFIG instead")
 139 endif()
 140 if(DEFINED ALSOFT_HRTF_DEFS)
 141     message(WARNING "ALSOFT_HRTF_DEFS is deprecated. Use ALSOFT_INSTALL_HRTF_DATA instead")
 142 endif()
 143 if(DEFINED ALSOFT_AMBDEC_PRESETS)
 144     message(WARNING "ALSOFT_AMBDEC_PRESETS is deprecated. Use ALSOFT_INSTALL_AMBDEC_PRESETS instead")
 145 endif()
 146
 147
 148 set(CPP_DEFS ) # C pre-processor, not C++
 149 set(INC_PATHS )
 150 set(C_FLAGS )
 151 set(LINKER_FLAGS )
 152 set(LINKER_FLAGS_DEBUG )
 153 set(LINKER_FLAGS_RELEASE )
 154 set(EXTRA_LIBS )
 155
 156 if(WIN32)
 157     set(CPP_DEFS ${CPP_DEFS} _WIN32 NOMINMAX)
 158     if(MINGW)
 159         set(CPP_DEFS ${CPP_DEFS} __USE_MINGW_ANSI_STDIO)
 160     endif()
 161
 162     option(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
 163     if(MINGW)
 164         option(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
 165     endif()
 166 elseif(APPLE)
 167     option(ALSOFT_OSX_FRAMEWORK "Build as macOS framework" OFF)
 168 endif()
 169
 170
 171 # QNX's gcc do not uses /usr/include and /usr/lib paths by default
 172 if("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 173     set(INC_PATHS ${INC_PATHS} /usr/include)
 174     set(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
 175 endif()
 176
 177 # When the library is built for static linking, apps should define
 178 # AL_LIBTYPE_STATIC when including the AL headers.
 179 if(NOT LIBTYPE)
 180     set(LIBTYPE SHARED)
 181 endif()
 182
 183 set(LIB_MAJOR_VERSION "1")
 184 set(LIB_MINOR_VERSION "23")
 185 set(LIB_REVISION "1")
 186 set(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 187 set(LIB_VERSION_NUM ${LIB_MAJOR_VERSION},${LIB_MINOR_VERSION},${LIB_REVISION},0)
 188
 189 set(EXPORT_DECL "")
 190
 191
 192 # Some systems erroneously require the __STDC_FORMAT_MACROS macro to be defined
 193 # to get the fixed-width integer type formatter macros.
 194 check_cxx_source_compiles("#include <cinttypes>
 195 #include <cstdio>
 196 int main()
 197 {
 198     int64_t i64{};
 199     std::printf(\"%\" PRId64, i64);
 200 }"
 201 HAVE_STDC_FORMAT_MACROS)
 202 if(NOT HAVE_STDC_FORMAT_MACROS)
 203     set(CPP_DEFS ${CPP_DEFS} __STDC_FORMAT_MACROS)
 204 endif()
 205
 206 if(NOT WIN32)
 207     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 208     check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 209     if(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 210         set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 211         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 212         check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 213         if(NOT HAVE_POSIX_MEMALIGN_POSIX)
 214             set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 215         else()
 216             set(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 217         endif()
 218     endif()
 219     unset(OLD_REQUIRED_FLAGS)
 220 endif()
 221
 222 # C99 has restrict, but C++ does not, so we can only utilize __restrict.
 223 check_cxx_source_compiles("int *__restrict foo;
 224 int main() { return 0; }" HAVE___RESTRICT)
 225 if(HAVE___RESTRICT)
 226     set(CPP_DEFS ${CPP_DEFS} RESTRICT=__restrict)
 227 else()
 228     set(CPP_DEFS ${CPP_DEFS} "RESTRICT=")
 229 endif()
 230
 231 # Some systems may need libatomic for atomic functions to work
 232 set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 233 set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 234 check_cxx_source_compiles("#include <atomic>
 235 std::atomic<int> foo{0};
 236 int main() { return foo.fetch_add(2); }"
 237 HAVE_LIBATOMIC)
 238 if(NOT HAVE_LIBATOMIC)
 239     set(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 240 else()
 241     set(EXTRA_LIBS atomic ${EXTRA_LIBS})
 242 endif()
 243 unset(OLD_REQUIRED_LIBRARIES)
 244
 245 if(ANDROID)
 246     # Include liblog for Android logging
 247     check_library_exists(log __android_log_print "" HAVE_LIBLOG)
 248     if(HAVE_LIBLOG)
 249         set(EXTRA_LIBS log ${EXTRA_LIBS})
 250         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 251     endif()
 252 endif()
 253
 254 if(MSVC)
 255     set(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS)
 256     check_cxx_compiler_flag(/permissive- HAVE_PERMISSIVE_SWITCH)
 257     if(HAVE_PERMISSIVE_SWITCH)
 258         set(C_FLAGS ${C_FLAGS} $<$<COMPILE_LANGUAGE:CXX>:/permissive->)
 259     endif()
 260     set(C_FLAGS ${C_FLAGS} /W4 /w14640 /wd4065 /wd4127 /wd4268 /wd4324 /wd5030 /wd5051)
 261
 262     if(NOT DXSDK_DIR)
 263         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 264     else()
 265         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 266     endif()
 267     if(DXSDK_DIR)
 268         message(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 269     endif()
 270
 271     option(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 272     if(FORCE_STATIC_VCRT)
 273         foreach(flag_var
 274                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 275                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 276                 CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
 277                 CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 278             if(${flag_var} MATCHES "/MD")
 279                 string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 280             endif()
 281         endforeach(flag_var)
 282     endif()
 283 else()
 284     set(C_FLAGS ${C_FLAGS} -Winline -Wunused -Wall -Wextra -Wshadow -Wconversion -Wcast-align
 285         -Wpedantic
 286         $<$<COMPILE_LANGUAGE:CXX>:-Wold-style-cast -Wnon-virtual-dtor -Woverloaded-virtual>)
 287
 288     check_cxx_compiler_flag(-Wno-c++20-attribute-extensions HAVE_WNO_CXX20_ATTR_EXT)
 289     if(HAVE_WNO_CXX20_ATTR_EXT)
 290         set(C_FLAGS ${C_FLAGS} $<$<COMPILE_LANGUAGE:CXX>:-Wno-c++20-attribute-extensions>)
 291     else()
 292         check_cxx_compiler_flag(-Wno-c++20-extensions HAVE_WNO_CXX20_EXT)
 293         if(HAVE_WNO_CXX20_EXT)
 294             set(C_FLAGS ${C_FLAGS} $<$<COMPILE_LANGUAGE:CXX>:-Wno-c++20-extensions>)
 295         endif()
 296     endif()
 297
 298     if(ALSOFT_WERROR)
 299         set(C_FLAGS ${C_FLAGS} -Werror)
 300     endif()
 301
 302     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 303     # instead of NDEBUG)
 304     foreach(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 305         if(${flag_var} MATCHES "-DNDEBUG")
 306             string(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 307         endif()
 308     endforeach()
 309
 310     check_c_compiler_flag(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 311     if(HAVE_FNO_MATH_ERRNO)
 312         set(C_FLAGS ${C_FLAGS} -fno-math-errno)
 313     endif()
 314
 315     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 316     if(ALSOFT_STATIC_LIBGCC)
 317         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 318         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 319         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBGCC_SWITCH)
 320         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 321         unset(OLD_REQUIRED_LIBRARIES)
 322
 323         if(NOT HAVE_STATIC_LIBGCC_SWITCH)
 324             message(FATAL_ERROR "Cannot static link libgcc")
 325         endif()
 326         set(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 327     endif()
 328
 329     option(ALSOFT_STATIC_STDCXX "Static link libstdc++" OFF)
 330     if(ALSOFT_STATIC_STDCXX)
 331         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 332         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-static-libstdc++")
 333         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBSTDCXX_SWITCH)
 334         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 335         unset(OLD_REQUIRED_LIBRARIES)
 336
 337         if(NOT HAVE_STATIC_LIBSTDCXX_SWITCH)
 338             message(FATAL_ERROR "Cannot static link libstdc++")
 339         endif()
 340         set(LINKER_FLAGS ${LINKER_FLAGS} "-static-libstdc++")
 341     endif()
 342
 343     if(WIN32)
 344         option(ALSOFT_STATIC_WINPTHREAD "Static link libwinpthread" OFF)
 345         if(ALSOFT_STATIC_WINPTHREAD)
 346             set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 347             set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lstdc++,-lwinpthread,--pop-state")
 348             check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 349             set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 350             unset(OLD_REQUIRED_LIBRARIES)
 351
 352             if(NOT HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 353                 message(FATAL_ERROR "Cannot static link libwinpthread")
 354             endif()
 355             set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lstdc++,-lwinpthread,--pop-state")
 356         endif()
 357     endif()
 358 endif()
 359
 360 # Set visibility/export options if available
 361 if(NOT LIBTYPE STREQUAL "STATIC")
 362     if(WIN32)
 363         set(EXPORT_DECL "__declspec(dllexport)")
 364     else()
 365         set(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 366         # Yes GCC, really don't accept visibility modes you don't support
 367         set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 368
 369         check_c_source_compiles("int foo() __attribute__((visibility(\"protected\")));
 370                                 int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 371         if(HAVE_GCC_PROTECTED_VISIBILITY)
 372             set(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 373         else()
 374             check_c_source_compiles("int foo() __attribute__((visibility(\"default\")));
 375                                     int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 376             if(HAVE_GCC_DEFAULT_VISIBILITY)
 377                 set(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 378             endif()
 379         endif()
 380         if(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 381             set(CMAKE_C_VISIBILITY_PRESET hidden)
 382             set(CMAKE_CXX_VISIBILITY_PRESET hidden)
 383         endif()
 384
 385         set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 386     endif()
 387 endif()
 388
 389
 390 set(SSE2_SWITCH "")
 391
 392 if(NOT MSVC)
 393     set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 394     # Yes GCC, really don't accept command line options you don't support
 395     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Werror")
 396     check_c_compiler_flag(-msse2 HAVE_MSSE2_SWITCH)
 397     if(HAVE_MSSE2_SWITCH)
 398         set(SSE2_SWITCH "-msse2")
 399     endif()
 400     set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 401     unset(OLD_REQUIRED_FLAGS)
 402 endif()
 403
 404 check_include_file(xmmintrin.h HAVE_XMMINTRIN_H)
 405 check_include_file(emmintrin.h HAVE_EMMINTRIN_H)
 406 check_include_file(pmmintrin.h HAVE_PMMINTRIN_H)
 407 check_include_file(smmintrin.h HAVE_SMMINTRIN_H)
 408 check_include_file(arm_neon.h HAVE_ARM_NEON_H)
 409
 410 set(HAVE_SSE        0)
 411 set(HAVE_SSE2       0)
 412 set(HAVE_SSE3       0)
 413 set(HAVE_SSE4_1     0)
 414 set(HAVE_NEON       0)
 415
 416 # Check for SSE support
 417 option(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 418 option(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 419 if(ALSOFT_CPUEXT_SSE AND HAVE_XMMINTRIN_H)
 420     set(HAVE_SSE 1)
 421 endif()
 422 if(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 423     message(FATAL_ERROR "Failed to enable required SSE CPU extensions")
 424 endif()
 425
 426 option(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 427 option(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 428 if(ALSOFT_CPUEXT_SSE2 AND HAVE_SSE AND HAVE_EMMINTRIN_H)
 429     set(HAVE_SSE2 1)
 430 endif()
 431 if(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 432     message(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 433 endif()
 434
 435 option(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 436 option(ALSOFT_REQUIRE_SSE3 "Require SSE3 support" OFF)
 437 if(ALSOFT_CPUEXT_SSE3 AND HAVE_SSE2 AND HAVE_PMMINTRIN_H)
 438     set(HAVE_SSE3 1)
 439 endif()
 440 if(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 441     message(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 442 endif()
 443
 444 option(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 445 option(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 446 if(ALSOFT_CPUEXT_SSE4_1 AND HAVE_SSE3 AND HAVE_SMMINTRIN_H)
 447     set(HAVE_SSE4_1 1)
 448 endif()
 449 if(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 450     message(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 451 endif()
 452
 453 # Check for ARM Neon support
 454 option(ALSOFT_CPUEXT_NEON "Enable ARM NEON support" ON)
 455 option(ALSOFT_REQUIRE_NEON "Require ARM NEON support" OFF)
 456 if(ALSOFT_CPUEXT_NEON AND HAVE_ARM_NEON_H)
 457     check_c_source_compiles("#include <arm_neon.h>
 458         int main()
 459         {
 460             int32x4_t ret4 = vdupq_n_s32(0);
 461             return vgetq_lane_s32(ret4, 0);
 462         }" HAVE_NEON_INTRINSICS)
 463     if(HAVE_NEON_INTRINSICS)
 464         set(HAVE_NEON 1)
 465     endif()
 466 endif()
 467 if(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 468     message(FATAL_ERROR "Failed to enable required ARM NEON CPU extensions")
 469 endif()
 470
 471
 472 set(ALSOFT_FORCE_ALIGN )
 473 set(SSE_FLAGS )
 474 set(FPMATH_SET "0")
 475 if(CMAKE_SIZEOF_VOID_P MATCHES "4" AND HAVE_SSE2)
 476     option(ALSOFT_ENABLE_SSE2_CODEGEN "Enable SSE2 code generation instead of x87 for 32-bit targets." TRUE)
 477     if(ALSOFT_ENABLE_SSE2_CODEGEN)
 478         if(MSVC)
 479             check_c_compiler_flag("/arch:SSE2" HAVE_ARCH_SSE2)
 480             if(HAVE_ARCH_SSE2)
 481                 set(SSE_FLAGS ${SSE_FLAGS} "/arch:SSE2")
 482                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 483                 set(FPMATH_SET 2)
 484             endif()
 485         elseif(SSE2_SWITCH)
 486             check_c_compiler_flag("${SSE2_SWITCH} -mfpmath=sse" HAVE_MFPMATH_SSE_2)
 487             if(HAVE_MFPMATH_SSE_2)
 488                 set(SSE_FLAGS ${SSE_FLAGS} ${SSE2_SWITCH} -mfpmath=sse)
 489                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 490                 set(FPMATH_SET 2)
 491             endif()
 492             # SSE depends on a 16-byte aligned stack, and by default, GCC
 493             # assumes the stack is suitably aligned. Older Linux code or other
 494             # OSs don't guarantee this on 32-bit, so externally-callable
 495             # functions need to ensure an aligned stack.
 496             set(EXPORT_DECL "${EXPORT_DECL}__attribute__((force_align_arg_pointer))")
 497             set(ALSOFT_FORCE_ALIGN "__attribute__((force_align_arg_pointer))")
 498         endif()
 499     endif()
 500 endif()
 501
 502 if(HAVE_SSE2)
 503     set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 504     foreach(flag_var ${SSE_FLAGS})
 505         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${flag_var}")
 506     endforeach()
 507
 508     check_c_source_compiles("#include <emmintrin.h>
 509         int main() {_mm_pause(); return 0;}" HAVE_SSE_INTRINSICS)
 510
 511     set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 512 endif()
 513
 514
 515 check_include_file(malloc.h HAVE_MALLOC_H)
 516 check_include_file(cpuid.h HAVE_CPUID_H)
 517 check_include_file(intrin.h HAVE_INTRIN_H)
 518 check_include_file(guiddef.h HAVE_GUIDDEF_H)
 519 if(NOT HAVE_GUIDDEF_H)
 520     check_include_file(initguid.h HAVE_INITGUID_H)
 521 endif()
 522
 523 # Some systems need libm for some math functions to work
 524 set(MATH_LIB )
 525 check_library_exists(m pow "" HAVE_LIBM)
 526 if(HAVE_LIBM)
 527     set(MATH_LIB ${MATH_LIB} m)
 528     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 529 endif()
 530
 531 # Some systems need to link with -lrt for clock_gettime as used by the common
 532 # eaxmple functions.
 533 set(RT_LIB )
 534 check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 535 if(HAVE_LIBRT)
 536     set(RT_LIB rt)
 537 endif()
 538
 539 # Check for the dlopen API (for dynamically loading backend libs)
 540 if(ALSOFT_DLOPEN)
 541     check_include_file(dlfcn.h HAVE_DLFCN_H)
 542     check_library_exists(dl dlopen "" HAVE_LIBDL)
 543     if(HAVE_LIBDL)
 544         set(EXTRA_LIBS dl ${EXTRA_LIBS})
 545         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 546     endif()
 547 endif()
 548
 549 # Check for a cpuid intrinsic
 550 if(HAVE_CPUID_H)
 551     check_c_source_compiles("#include <cpuid.h>
 552         int main()
 553         {
 554             unsigned int eax, ebx, ecx, edx;
 555             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 556         }" HAVE_GCC_GET_CPUID)
 557 endif()
 558 if(HAVE_INTRIN_H)
 559     check_c_source_compiles("#include <intrin.h>
 560         int main()
 561         {
 562             int regs[4];
 563             __cpuid(regs, 0);
 564             return regs[0];
 565         }" HAVE_CPUID_INTRINSIC)
 566 endif()
 567
 568 check_symbol_exists(proc_pidpath     libproc.h HAVE_PROC_PIDPATH)
 569
 570 if(NOT WIN32)
 571     # We need pthreads outside of Windows, for semaphores. It's also used to
 572     # set the priority and name of threads, when possible.
 573     check_include_file(pthread.h HAVE_PTHREAD_H)
 574     if(NOT HAVE_PTHREAD_H)
 575         message(FATAL_ERROR "PThreads is required for non-Windows builds!")
 576     endif()
 577
 578     check_c_compiler_flag(-pthread HAVE_PTHREAD)
 579     if(HAVE_PTHREAD)
 580         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 581         set(C_FLAGS ${C_FLAGS} -pthread)
 582         set(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 583     endif()
 584
 585     check_symbol_exists(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 586
 587     # Some systems need pthread_np.h to get pthread_setname_np
 588     check_include_files("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 589     if(HAVE_PTHREAD_NP_H)
 590         check_symbol_exists(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 591         if(NOT HAVE_PTHREAD_SETNAME_NP)
 592             check_symbol_exists(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 593         endif()
 594     else()
 595         check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 596         if(NOT HAVE_PTHREAD_SETNAME_NP)
 597             check_symbol_exists(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 598         endif()
 599     endif()
 600 endif()
 601
 602 check_symbol_exists(getopt unistd.h HAVE_GETOPT)
 603
 604
 605 # Common sources used by both the OpenAL implementation library, the OpenAL
 606 # router, and certain tools and examples.
 607 set(COMMON_OBJS
 608     common/albit.h
 609     common/alcomplex.cpp
 610     common/alcomplex.h
 611     common/almalloc.h
 612     common/alnumbers.h
 613     common/alnumeric.h
 614     common/alsem.cpp
 615     common/alsem.h
 616     common/alspan.h
 617     common/alstring.cpp
 618     common/alstring.h
 619     common/althrd_setname.cpp
 620     common/althrd_setname.h
 621     common/althreads.h
 622     common/altraits.h
 623     common/atomic.h
 624     common/comptr.h
 625     common/dynload.cpp
 626     common/dynload.h
 627     common/flexarray.h
 628     common/intrusive_ptr.h
 629     common/opthelpers.h
 630     common/pffft.cpp
 631     common/pffft.h
 632     common/phase_shifter.h
 633     common/polyphase_resampler.cpp
 634     common/polyphase_resampler.h
 635     common/pragmadefs.h
 636     common/ringbuffer.cpp
 637     common/ringbuffer.h
 638     common/strutils.cpp
 639     common/strutils.h
 640     common/vecmat.h
 641     common/vector.h)
 642
 643 # Core library routines
 644 set(CORE_OBJS
 645     core/ambdec.cpp
 646     core/ambdec.h
 647     core/ambidefs.cpp
 648     core/ambidefs.h
 649     core/async_event.h
 650     core/bformatdec.cpp
 651     core/bformatdec.h
 652     core/bs2b.cpp
 653     core/bs2b.h
 654     core/bsinc_defs.h
 655     core/bsinc_tables.cpp
 656     core/bsinc_tables.h
 657     core/bufferline.h
 658     core/buffer_storage.cpp
 659     core/buffer_storage.h
 660     core/context.cpp
 661     core/context.h
 662     core/converter.cpp
 663     core/converter.h
 664     core/cpu_caps.cpp
 665     core/cpu_caps.h
 666     core/cubic_defs.h
 667     core/cubic_tables.cpp
 668     core/cubic_tables.h
 669     core/devformat.cpp
 670     core/devformat.h
 671     core/device.cpp
 672     core/device.h
 673     core/effects/base.h
 674     core/effectslot.cpp
 675     core/effectslot.h
 676     core/except.cpp
 677     core/except.h
 678     core/filters/biquad.h
 679     core/filters/biquad.cpp
 680     core/filters/nfc.cpp
 681     core/filters/nfc.h
 682     core/filters/splitter.cpp
 683     core/filters/splitter.h
 684     core/fmt_traits.cpp
 685     core/fmt_traits.h
 686     core/fpu_ctrl.cpp
 687     core/fpu_ctrl.h
 688     core/front_stablizer.h
 689     core/helpers.cpp
 690     core/helpers.h
 691     core/hrtf.cpp
 692     core/hrtf.h
 693     core/logging.cpp
 694     core/logging.h
 695     core/mastering.cpp
 696     core/mastering.h
 697     core/mixer.cpp
 698     core/mixer.h
 699     core/resampler_limits.h
 700     core/uhjfilter.cpp
 701     core/uhjfilter.h
 702     core/uiddefs.cpp
 703     core/voice.cpp
 704     core/voice.h
 705     core/voice_change.h)
 706
 707 set(HAVE_RTKIT 0)
 708 if(NOT WIN32)
 709     option(ALSOFT_RTKIT "Enable RTKit support" ON)
 710     option(ALSOFT_REQUIRE_RTKIT "Require RTKit/D-Bus support" FALSE)
 711     if(ALSOFT_RTKIT)
 712         find_package(DBus1 QUIET)
 713         if(NOT DBus1_FOUND AND PkgConfig_FOUND)
 714             pkg_check_modules(DBUS dbus-1)
 715         endif()
 716         if(DBus1_FOUND OR DBUS_FOUND)
 717             set(HAVE_RTKIT 1)
 718             set(CORE_OBJS ${CORE_OBJS} core/dbus_wrap.cpp core/dbus_wrap.h
 719                 core/rtkit.cpp core/rtkit.h)
 720             if(NOT DBus1_FOUND)
 721                 set(INC_PATHS ${INC_PATHS} ${DBUS_INCLUDE_DIRS})
 722                 set(CPP_DEFS ${CPP_DEFS} ${DBUS_CFLAGS_OTHER})
 723                 if(NOT HAVE_DLFCN_H)
 724                     set(EXTRA_LIBS ${EXTRA_LIBS} ${DBUS_LINK_LIBRARIES})
 725                 endif()
 726             elseif(HAVE_DLFCN_H)
 727                 set(INC_PATHS ${INC_PATHS} ${DBus1_INCLUDE_DIRS})
 728                 set(CPP_DEFS ${CPP_DEFS} ${DBus1_DEFINITIONS})
 729             else()
 730                 set(EXTRA_LIBS ${EXTRA_LIBS} ${DBus1_LIBRARIES})
 731             endif()
 732         endif()
 733     else()
 734         set(MISSING_VARS "")
 735         if(NOT DBus1_INCLUDE_DIRS)
 736             set(MISSING_VARS "${MISSING_VARS} DBus1_INCLUDE_DIRS")
 737         endif()
 738         if(NOT DBus1_LIBRARIES)
 739             set(MISSING_VARS "${MISSING_VARS} DBus1_LIBRARIES")
 740         endif()
 741         message(STATUS "Could NOT find DBus1 (missing:${MISSING_VARS})")
 742         unset(MISSING_VARS)
 743     endif()
 744 endif()
 745 if(ALSOFT_REQUIRE_RTKIT AND NOT HAVE_RTKIT)
 746     message(FATAL_ERROR "Failed to enable required RTKit support")
 747 endif()
 748
 749 # Default mixers, always available
 750 set(CORE_OBJS ${CORE_OBJS}
 751     core/mixer/defs.h
 752     core/mixer/hrtfbase.h
 753     core/mixer/hrtfdefs.h
 754     core/mixer/mixer_c.cpp)
 755
 756 # AL and related routines
 757 set(OPENAL_OBJS
 758     al/auxeffectslot.cpp
 759     al/auxeffectslot.h
 760     al/buffer.cpp
 761     al/buffer.h
 762     al/debug.cpp
 763     al/debug.h
 764     al/direct_defs.h
 765     al/effect.cpp
 766     al/effect.h
 767     al/effects/autowah.cpp
 768     al/effects/chorus.cpp
 769     al/effects/compressor.cpp
 770     al/effects/convolution.cpp
 771     al/effects/dedicated.cpp
 772     al/effects/distortion.cpp
 773     al/effects/echo.cpp
 774     al/effects/effects.cpp
 775     al/effects/effects.h
 776     al/effects/equalizer.cpp
 777     al/effects/fshifter.cpp
 778     al/effects/modulator.cpp
 779     al/effects/null.cpp
 780     al/effects/pshifter.cpp
 781     al/effects/reverb.cpp
 782     al/effects/vmorpher.cpp
 783     al/error.cpp
 784     al/event.cpp
 785     al/event.h
 786     al/extension.cpp
 787     al/filter.cpp
 788     al/filter.h
 789     al/listener.cpp
 790     al/listener.h
 791     al/source.cpp
 792     al/source.h
 793     al/state.cpp)
 794
 795 # ALC and related routines
 796 set(ALC_OBJS
 797     alc/alc.cpp
 798     alc/alu.cpp
 799     alc/alu.h
 800     alc/alconfig.cpp
 801     alc/alconfig.h
 802     alc/context.cpp
 803     alc/context.h
 804     alc/device.cpp
 805     alc/device.h
 806     alc/effects/base.h
 807     alc/effects/autowah.cpp
 808     alc/effects/chorus.cpp
 809     alc/effects/compressor.cpp
 810     alc/effects/convolution.cpp
 811     alc/effects/dedicated.cpp
 812     alc/effects/distortion.cpp
 813     alc/effects/echo.cpp
 814     alc/effects/equalizer.cpp
 815     alc/effects/fshifter.cpp
 816     alc/effects/modulator.cpp
 817     alc/effects/null.cpp
 818     alc/effects/pshifter.cpp
 819     alc/effects/reverb.cpp
 820     alc/effects/vmorpher.cpp
 821     alc/events.cpp
 822     alc/events.h
 823     alc/export_list.h
 824     alc/inprogext.h
 825     alc/panning.cpp)
 826
 827 if(ALSOFT_EAX)
 828     set(OPENAL_OBJS
 829         ${OPENAL_OBJS}
 830         al/eax/api.cpp
 831         al/eax/api.h
 832         al/eax/call.cpp
 833         al/eax/call.h
 834         al/eax/effect.h
 835         al/eax/exception.cpp
 836         al/eax/exception.h
 837         al/eax/fx_slot_index.cpp
 838         al/eax/fx_slot_index.h
 839         al/eax/fx_slots.cpp
 840         al/eax/fx_slots.h
 841         al/eax/globals.h
 842         al/eax/utils.cpp
 843         al/eax/utils.h
 844         al/eax/x_ram.h
 845     )
 846 endif()
 847
 848 # Include SIMD mixers
 849 set(CPU_EXTS "Default")
 850 if(HAVE_SSE)
 851     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse.cpp)
 852     set(CPU_EXTS "${CPU_EXTS}, SSE")
 853 endif()
 854 if(HAVE_SSE2)
 855     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse2.cpp)
 856     set(CPU_EXTS "${CPU_EXTS}, SSE2")
 857 endif()
 858 if(HAVE_SSE3)
 859     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse3.cpp)
 860     set(CPU_EXTS "${CPU_EXTS}, SSE3")
 861 endif()
 862 if(HAVE_SSE4_1)
 863     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse41.cpp)
 864     set(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 865 endif()
 866 if(HAVE_NEON)
 867     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_neon.cpp)
 868     set(CPU_EXTS "${CPU_EXTS}, Neon")
 869 endif()
 870
 871
 872 set(HAVE_ALSA       0)
 873 set(HAVE_OSS        0)
 874 set(HAVE_PIPEWIRE   0)
 875 set(HAVE_SOLARIS    0)
 876 set(HAVE_SNDIO      0)
 877 set(HAVE_DSOUND     0)
 878 set(HAVE_WASAPI     0)
 879 set(HAVE_WINMM      0)
 880 set(HAVE_PORTAUDIO  0)
 881 set(HAVE_PULSEAUDIO 0)
 882 set(HAVE_COREAUDIO  0)
 883 set(HAVE_OPENSL     0)
 884 set(HAVE_OBOE       0)
 885 set(HAVE_WAVE       0)
 886 set(HAVE_SDL2       0)
 887
 888 if(WIN32 OR HAVE_DLFCN_H)
 889     set(IS_LINKED "")
 890     macro(ADD_BACKEND_LIBS _LIBS)
 891     endmacro()
 892 else()
 893     set(IS_LINKED " (linked)")
 894     macro(ADD_BACKEND_LIBS _LIBS)
 895         set(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 896     endmacro()
 897 endif()
 898
 899 set(BACKENDS "")
 900 set(ALC_OBJS  ${ALC_OBJS}
 901     alc/backends/base.cpp
 902     alc/backends/base.h
 903     # Default backends, always available
 904     alc/backends/loopback.cpp
 905     alc/backends/loopback.h
 906     alc/backends/null.cpp
 907     alc/backends/null.h
 908 )
 909
 910 # Check PipeWire backend
 911 option(ALSOFT_BACKEND_PIPEWIRE "Enable PipeWire backend" ON)
 912 option(ALSOFT_REQUIRE_PIPEWIRE "Require PipeWire backend" OFF)
 913 if(ALSOFT_BACKEND_PIPEWIRE AND PkgConfig_FOUND)
 914     pkg_check_modules(PIPEWIRE libpipewire-0.3>=0.3.23)
 915     if(PIPEWIRE_FOUND)
 916         set(HAVE_PIPEWIRE 1)
 917         set(BACKENDS  "${BACKENDS} PipeWire${IS_LINKED},")
 918         set(ALC_OBJS  ${ALC_OBJS} alc/backends/pipewire.cpp alc/backends/pipewire.h)
 919         add_backend_libs(${PIPEWIRE_LIBRARIES})
 920         set(INC_PATHS ${INC_PATHS} ${PIPEWIRE_INCLUDE_DIRS})
 921     endif()
 922 endif()
 923 if(ALSOFT_REQUIRE_PIPEWIRE AND NOT HAVE_PIPEWIRE)
 924     message(FATAL_ERROR "Failed to enable required PipeWire backend")
 925 endif()
 926
 927 # Check PulseAudio backend
 928 option(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
 929 option(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
 930 if(ALSOFT_BACKEND_PULSEAUDIO)
 931     find_package(PulseAudio)
 932     if(PULSEAUDIO_FOUND)
 933         set(HAVE_PULSEAUDIO 1)
 934         set(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
 935         set(ALC_OBJS  ${ALC_OBJS} alc/backends/pulseaudio.cpp alc/backends/pulseaudio.h)
 936         add_backend_libs(${PULSEAUDIO_LIBRARY})
 937         set(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIR})
 938     endif()
 939 endif()
 940 if(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 941     message(FATAL_ERROR "Failed to enable required PulseAudio backend")
 942 endif()
 943
 944 if(NOT WIN32)
 945     # Check ALSA backend
 946     option(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 947     option(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 948     if(ALSOFT_BACKEND_ALSA)
 949         find_package(ALSA)
 950         if(ALSA_FOUND)
 951             set(HAVE_ALSA 1)
 952             set(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 953             set(ALC_OBJS  ${ALC_OBJS} alc/backends/alsa.cpp alc/backends/alsa.h)
 954             add_backend_libs(${ALSA_LIBRARIES})
 955             set(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 956         endif()
 957     endif()
 958
 959     # Check OSS backend
 960     option(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 961     option(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 962     if(ALSOFT_BACKEND_OSS)
 963         find_package(OSS)
 964         if(OSS_FOUND)
 965             set(HAVE_OSS 1)
 966             set(BACKENDS  "${BACKENDS} OSS,")
 967             set(ALC_OBJS  ${ALC_OBJS} alc/backends/oss.cpp alc/backends/oss.h)
 968             if(OSS_LIBRARIES)
 969                 set(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 970             endif()
 971             set(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 972         endif()
 973     endif()
 974
 975     # Check Solaris backend
 976     option(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 977     option(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 978     if(ALSOFT_BACKEND_SOLARIS)
 979         find_package(AudioIO)
 980         if(AUDIOIO_FOUND)
 981             set(HAVE_SOLARIS 1)
 982             set(BACKENDS  "${BACKENDS} Solaris,")
 983             set(ALC_OBJS  ${ALC_OBJS} alc/backends/solaris.cpp alc/backends/solaris.h)
 984             set(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 985         endif()
 986     endif()
 987
 988     # Check SndIO backend
 989     option(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 990     option(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 991     if(ALSOFT_BACKEND_SNDIO)
 992         find_package(SoundIO)
 993         if(SOUNDIO_FOUND)
 994             set(HAVE_SNDIO 1)
 995             set(BACKENDS  "${BACKENDS} SndIO (linked),")
 996             set(ALC_OBJS  ${ALC_OBJS} alc/backends/sndio.cpp alc/backends/sndio.h)
 997             set(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 998             set(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 999         endif()
1000     endif()
1001 endif()
1002 if(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
1003     message(FATAL_ERROR "Failed to enable required ALSA backend")
1004 endif()
1005 if(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
1006     message(FATAL_ERROR "Failed to enable required OSS backend")
1007 endif()
1008 if(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
1009     message(FATAL_ERROR "Failed to enable required Solaris backend")
1010 endif()
1011 if(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
1012     message(FATAL_ERROR "Failed to enable required SndIO backend")
1013 endif()
1014
1015 # Check Windows-only backends
1016 if(WIN32)
1017     if (NOT ALSOFT_UWP)
1018         # Check MMSystem backend
1019         option(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
1020         option(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
1021         if(ALSOFT_BACKEND_WINMM)
1022             set(HAVE_WINMM 1)
1023             set(BACKENDS "${BACKENDS} WinMM,")
1024             set(ALC_OBJS ${ALC_OBJS} alc/backends/winmm.cpp alc/backends/winmm.h)
1025             # There doesn't seem to be good way to search for winmm.lib for MSVC.
1026             # find_library doesn't find it without being told to look in a specific
1027             # place in the WindowsSDK, but it links anyway. If there ends up being
1028             # Windows targets without this, another means to detect it is needed.
1029             set(EXTRA_LIBS winmm ${EXTRA_LIBS})
1030         endif()
1031
1032         # Check DSound backend
1033         option(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
1034         option(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
1035         if(ALSOFT_BACKEND_DSOUND)
1036             check_include_file(dsound.h HAVE_DSOUND_H)
1037             if(DXSDK_DIR)
1038                 find_path(DSOUND_INCLUDE_DIR NAMES "dsound.h"
1039                     PATHS "${DXSDK_DIR}" PATH_SUFFIXES include
1040                     DOC "The DirectSound include directory")
1041             endif()
1042             if(HAVE_DSOUND_H OR DSOUND_INCLUDE_DIR)
1043                 set(HAVE_DSOUND 1)
1044                 set(BACKENDS "${BACKENDS} DirectSound,")
1045                 set(ALC_OBJS ${ALC_OBJS} alc/backends/dsound.cpp alc/backends/dsound.h)
1046
1047                 if(NOT HAVE_DSOUND_H)
1048                     set(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIR})
1049                 endif()
1050             endif()
1051         endif()
1052     endif()
1053
1054     # Check for WASAPI backend
1055     option(ALSOFT_BACKEND_WASAPI "Enable WASAPI backend" ON)
1056     option(ALSOFT_REQUIRE_WASAPI "Require WASAPI backend" OFF)
1057     if(ALSOFT_BACKEND_WASAPI)
1058         check_include_file(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
1059         if(HAVE_MMDEVICEAPI_H)
1060             set(HAVE_WASAPI 1)
1061             set(BACKENDS  "${BACKENDS} WASAPI,")
1062             set(ALC_OBJS  ${ALC_OBJS} alc/backends/wasapi.cpp alc/backends/wasapi.h)
1063         endif()
1064     endif()
1065 endif()
1066 if(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1067     message(FATAL_ERROR "Failed to enable required WinMM backend")
1068 endif()
1069 if(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1070     message(FATAL_ERROR "Failed to enable required DSound backend")
1071 endif()
1072 if(ALSOFT_REQUIRE_WASAPI AND NOT HAVE_WASAPI)
1073     message(FATAL_ERROR "Failed to enable required WASAPI backend")
1074 endif()
1075
1076 # Check JACK backend
1077 option(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1078 option(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1079 if(ALSOFT_BACKEND_JACK)
1080     find_package(JACK)
1081     if(JACK_FOUND)
1082         set(HAVE_JACK 1)
1083         set(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1084         set(ALC_OBJS  ${ALC_OBJS} alc/backends/jack.cpp alc/backends/jack.h)
1085         add_backend_libs(${JACK_LIBRARIES})
1086         set(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1087     endif()
1088 endif()
1089 if(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1090     message(FATAL_ERROR "Failed to enable required JACK backend")
1091 endif()
1092
1093 # Check CoreAudio backend
1094 option(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1095 option(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1096 if(ALSOFT_BACKEND_COREAUDIO)
1097     find_library(COREAUDIO_FRAMEWORK NAMES CoreAudio)
1098     find_path(AUDIOUNIT_INCLUDE_DIR NAMES AudioUnit/AudioUnit.h)
1099     if(COREAUDIO_FRAMEWORK AND AUDIOUNIT_INCLUDE_DIR)
1100         set(HAVE_COREAUDIO 1)
1101         set(ALC_OBJS  ${ALC_OBJS} alc/backends/coreaudio.cpp alc/backends/coreaudio.h)
1102         set(BACKENDS  "${BACKENDS} CoreAudio,")
1103
1104         set(EXTRA_LIBS -Wl,-framework,CoreAudio ${EXTRA_LIBS})
1105         if(CMAKE_SYSTEM_NAME MATCHES "^(iOS|tvOS)$")
1106             find_library(COREFOUNDATION_FRAMEWORK NAMES CoreFoundation)
1107             if(COREFOUNDATION_FRAMEWORK)
1108                 set(EXTRA_LIBS -Wl,-framework,CoreFoundation ${EXTRA_LIBS})
1109             endif()
1110         else()
1111             set(EXTRA_LIBS -Wl,-framework,AudioUnit,-framework,ApplicationServices ${EXTRA_LIBS})
1112         endif()
1113
1114         # Some versions of OSX may need the AudioToolbox framework. Add it if
1115         # it's found.
1116         find_library(AUDIOTOOLBOX_LIBRARY NAMES AudioToolbox)
1117         if(AUDIOTOOLBOX_LIBRARY)
1118             set(EXTRA_LIBS -Wl,-framework,AudioToolbox ${EXTRA_LIBS})
1119         endif()
1120
1121         set(INC_PATHS ${INC_PATHS} ${AUDIOUNIT_INCLUDE_DIR})
1122     endif()
1123 endif()
1124 if(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1125     message(FATAL_ERROR "Failed to enable required CoreAudio backend")
1126 endif()
1127
1128 # Check for Oboe (Android) backend
1129 option(ALSOFT_BACKEND_OBOE "Enable Oboe backend" ON)
1130 option(ALSOFT_REQUIRE_OBOE "Require Oboe backend" OFF)
1131 if(ALSOFT_BACKEND_OBOE)
1132     set(OBOE_TARGET )
1133     if(ANDROID)
1134         set(OBOE_SOURCE "" CACHE STRING "Source directory for Oboe.")
1135         if(OBOE_SOURCE)
1136             add_subdirectory(${OBOE_SOURCE} ./oboe)
1137             set(OBOE_TARGET oboe)
1138         else()
1139             find_package(oboe CONFIG)
1140             if(NOT TARGET oboe::oboe)
1141                 find_package(Oboe)
1142             endif()
1143             if(TARGET oboe::oboe)
1144                 set(OBOE_TARGET "oboe::oboe")
1145             endif()
1146         endif()
1147     endif()
1148
1149     if(OBOE_TARGET)
1150         set(HAVE_OBOE 1)
1151         set(ALC_OBJS  ${ALC_OBJS} alc/backends/oboe.cpp alc/backends/oboe.h)
1152         set(BACKENDS  "${BACKENDS} Oboe,")
1153         set(EXTRA_LIBS ${OBOE_TARGET} ${EXTRA_LIBS})
1154     endif()
1155 endif()
1156 if(ALSOFT_REQUIRE_OBOE AND NOT HAVE_OBOE)
1157     message(FATAL_ERROR "Failed to enable required Oboe backend")
1158 endif()
1159
1160 # Check for OpenSL (Android) backend
1161 option(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1162 option(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1163 if(ALSOFT_BACKEND_OPENSL)
1164     find_package(OpenSL)
1165     if(OPENSL_FOUND)
1166         set(HAVE_OPENSL 1)
1167         set(ALC_OBJS  ${ALC_OBJS} alc/backends/opensl.cpp alc/backends/opensl.h)
1168         set(BACKENDS  "${BACKENDS} OpenSL,")
1169         set(EXTRA_LIBS ${OPENSL_LIBRARIES} ${EXTRA_LIBS})
1170         set(INC_PATHS ${INC_PATHS} ${OPENSL_INCLUDE_DIRS})
1171     endif()
1172 endif()
1173 if(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1174     message(FATAL_ERROR "Failed to enable required OpenSL backend")
1175 endif()
1176
1177 # Check PortAudio backend
1178 option(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1179 option(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1180 if(ALSOFT_BACKEND_PORTAUDIO)
1181     find_package(PortAudio)
1182     if(PORTAUDIO_FOUND)
1183         set(HAVE_PORTAUDIO 1)
1184         set(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1185         set(ALC_OBJS  ${ALC_OBJS} alc/backends/portaudio.cpp alc/backends/portaudio.h)
1186         add_backend_libs(${PORTAUDIO_LIBRARIES})
1187         set(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1188     endif()
1189 endif()
1190 if(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1191     message(FATAL_ERROR "Failed to enable required PortAudio backend")
1192 endif()
1193
1194 # Check for SDL2 backend
1195 # Off by default, since it adds a runtime dependency
1196 option(ALSOFT_BACKEND_SDL2 "Enable SDL2 backend" OFF)
1197 option(ALSOFT_REQUIRE_SDL2 "Require SDL2 backend" OFF)
1198 if(ALSOFT_BACKEND_SDL2)
1199     if(SDL2_FOUND)
1200         set(HAVE_SDL2 1)
1201         set(ALC_OBJS  ${ALC_OBJS} alc/backends/sdl2.cpp alc/backends/sdl2.h)
1202         set(BACKENDS  "${BACKENDS} SDL2,")
1203         set(EXTRA_LIBS ${EXTRA_LIBS} SDL2::SDL2)
1204     else()
1205         message(STATUS "Could NOT find SDL2")
1206     endif()
1207 endif()
1208 if(ALSOFT_REQUIRE_SDL2 AND NOT SDL2_FOUND)
1209     message(FATAL_ERROR "Failed to enable required SDL2 backend")
1210 endif()
1211
1212 # Optionally enable the Wave Writer backend
1213 option(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1214 if(ALSOFT_BACKEND_WAVE)
1215     set(HAVE_WAVE 1)
1216     set(ALC_OBJS  ${ALC_OBJS} alc/backends/wave.cpp alc/backends/wave.h)
1217     set(BACKENDS  "${BACKENDS} WaveFile,")
1218 endif()
1219
1220 # This is always available
1221 set(BACKENDS  "${BACKENDS} Null")
1222
1223
1224 find_package(Git)
1225 if(ALSOFT_UPDATE_BUILD_VERSION AND GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1226     set(GIT_DIR "${OpenAL_SOURCE_DIR}/.git")
1227
1228     # Check if this is a submodule, if it is then find the .git directory
1229     if(NOT IS_DIRECTORY "${OpenAL_SOURCE_DIR}/.git")
1230         file(READ ${GIT_DIR} submodule)
1231         string(REGEX REPLACE "gitdir: (.*)$" "\\1" GIT_DIR_RELATIVE ${submodule})
1232         string(STRIP ${GIT_DIR_RELATIVE} GIT_DIR_RELATIVE)
1233         get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
1234         get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE} ABSOLUTE)
1235     endif()
1236
1237     # Get the current working branch and its latest abbreviated commit hash
1238     add_custom_command(OUTPUT "${OpenAL_BINARY_DIR}/version_witness.txt"
1239         BYPRODUCTS "${OpenAL_BINARY_DIR}/version.h"
1240         COMMAND ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE} -D LIB_VERSION=${LIB_VERSION}
1241             -D LIB_VERSION_NUM=${LIB_VERSION_NUM} -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1242             -D DST=${OpenAL_BINARY_DIR}/version.h -P ${OpenAL_SOURCE_DIR}/version.cmake
1243         COMMAND ${CMAKE_COMMAND} -E touch "${OpenAL_BINARY_DIR}/version_witness.txt"
1244         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1245         MAIN_DEPENDENCY "${OpenAL_SOURCE_DIR}/version.h.in"
1246         DEPENDS "${GIT_DIR}/index" "${OpenAL_SOURCE_DIR}/version.cmake"
1247         VERBATIM
1248     )
1249
1250     add_custom_target(build_version DEPENDS "${OpenAL_BINARY_DIR}/version_witness.txt")
1251 else()
1252     set(GIT_BRANCH "UNKNOWN")
1253     set(GIT_COMMIT_HASH "unknown")
1254     configure_file(
1255         "${OpenAL_SOURCE_DIR}/version.h.in"
1256         "${OpenAL_BINARY_DIR}/version.h")
1257 endif()
1258
1259
1260 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" ON)
1261 if(ALSOFT_EMBED_HRTF_DATA)
1262     macro(make_hrtf_header FILENAME VARNAME)
1263         set(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1264         set(outfile  "${OpenAL_BINARY_DIR}/${VARNAME}.txt")
1265
1266         add_custom_command(OUTPUT "${outfile}"
1267             COMMAND ${CMAKE_COMMAND} -D "INPUT_FILE=${infile}" -D "OUTPUT_FILE=${outfile}"
1268                 -P "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1269             WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1270             DEPENDS "${infile}" "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1271             VERBATIM
1272         )
1273         set(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1274     endmacro()
1275
1276     make_hrtf_header("Default HRTF.mhr" "default_hrtf")
1277 endif()
1278
1279
1280 if(ALSOFT_UTILS)
1281     find_package(MySOFA)
1282     if(NOT ALSOFT_NO_CONFIG_UTIL)
1283         find_package(Qt5Widgets QUIET)
1284         if(NOT Qt5Widgets_FOUND)
1285             message(STATUS "Could NOT find Qt5Widgets")
1286         endif()
1287     endif()
1288 endif()
1289 if(ALSOFT_UTILS OR ALSOFT_EXAMPLES)
1290     find_package(SndFile)
1291     if(SDL2_FOUND)
1292         find_package(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1293     endif()
1294 endif()
1295
1296 if(NOT WIN32)
1297     set(LIBNAME "openal")
1298 else()
1299     set(LIBNAME "OpenAL32")
1300 endif()
1301
1302 # Needed for openal.pc.in
1303 set(prefix ${CMAKE_INSTALL_PREFIX})
1304 set(exec_prefix "\${prefix}")
1305 set(libdir "${CMAKE_INSTALL_FULL_LIBDIR}")
1306 set(bindir "${CMAKE_INSTALL_FULL_BINDIR}")
1307 set(includedir "${CMAKE_INSTALL_FULL_INCLUDEDIR}")
1308 set(PACKAGE_VERSION "${LIB_VERSION}")
1309 set(PKG_CONFIG_CFLAGS )
1310 set(PKG_CONFIG_PRIVATE_LIBS )
1311 if(LIBTYPE STREQUAL "STATIC")
1312     set(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC)
1313     foreach(FLAG  ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1314         # If this is already a linker flag, or is a full path+file, add it
1315         # as-is. If it's an SDL2 target, add the link flag for it. Otherwise,
1316         # it's a name intended to be dressed as -lname.
1317         if(FLAG MATCHES "^-.*" OR EXISTS "${FLAG}")
1318             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} ${FLAG}")
1319         elseif(FLAG MATCHES "^SDL2::SDL2")
1320             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} -lSDL2")
1321         else()
1322             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} -l${FLAG}")
1323         endif()
1324     endforeach()
1325 endif()
1326
1327 # End configuration
1328 configure_file(
1329     "${OpenAL_SOURCE_DIR}/config.h.in"
1330     "${OpenAL_BINARY_DIR}/config.h")
1331 configure_file(
1332     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1333     "${OpenAL_BINARY_DIR}/openal.pc"
1334     @ONLY)
1335
1336
1337 add_library(alcommon STATIC EXCLUDE_FROM_ALL ${COMMON_OBJS})
1338 target_include_directories(alcommon PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/include
1339     PUBLIC ${OpenAL_SOURCE_DIR}/common)
1340 target_compile_definitions(alcommon PRIVATE ${CPP_DEFS})
1341 target_compile_options(alcommon PRIVATE ${C_FLAGS})
1342 set_target_properties(alcommon PROPERTIES ${DEFAULT_TARGET_PROPS} POSITION_INDEPENDENT_CODE TRUE)
1343
1344
1345 unset(HAS_ROUTER)
1346 set(IMPL_TARGET OpenAL) # Either OpenAL or soft_oal.
1347
1348 # Build main library
1349 if(LIBTYPE STREQUAL "STATIC")
1350     add_library(${IMPL_TARGET} STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS} ${CORE_OBJS})
1351     target_compile_definitions(${IMPL_TARGET} PUBLIC AL_LIBTYPE_STATIC)
1352     target_link_libraries(${IMPL_TARGET} PRIVATE ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1353
1354     if(WIN32)
1355         # This option is for static linking OpenAL Soft into another project
1356         # that already defines the IDs. It is up to that project to ensure all
1357         # required IDs are defined.
1358         option(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
1359         if(ALSOFT_NO_UID_DEFS)
1360             target_compile_definitions(${IMPL_TARGET} PRIVATE AL_NO_UID_DEFS)
1361         endif()
1362     endif()
1363 else()
1364     set(RC_CONFIG resources/openal32.rc)
1365     if(WIN32 AND ALSOFT_BUILD_ROUTER)
1366         add_library(OpenAL SHARED
1367             resources/router.rc
1368             router/router.cpp
1369             router/router.h
1370             router/alc.cpp
1371             router/al.cpp
1372         )
1373         target_compile_definitions(OpenAL
1374             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES "ALC_API=${EXPORT_DECL}"
1375             "AL_API=${EXPORT_DECL}" ${CPP_DEFS})
1376         target_compile_options(OpenAL PRIVATE ${C_FLAGS})
1377         target_link_libraries(OpenAL PRIVATE alcommon ${LINKER_FLAGS})
1378         target_include_directories(OpenAL
1379           PUBLIC
1380             $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1381             $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
1382           PRIVATE
1383             ${OpenAL_SOURCE_DIR}/common
1384             ${OpenAL_BINARY_DIR}
1385         )
1386         set_target_properties(OpenAL PROPERTIES ${DEFAULT_TARGET_PROPS} PREFIX ""
1387             OUTPUT_NAME ${LIBNAME})
1388         if(TARGET build_version)
1389             add_dependencies(OpenAL build_version)
1390         endif()
1391         set(HAS_ROUTER 1)
1392
1393         set(LIBNAME "soft_oal")
1394         set(IMPL_TARGET soft_oal)
1395         set(RC_CONFIG resources/soft_oal.rc)
1396     endif()
1397
1398     # !important: for osx framework public header works, the headers must be in
1399     # the project
1400     set(TARGET_PUBLIC_HEADERS include/AL/al.h include/AL/alc.h include/AL/alext.h include/AL/efx.h
1401         include/AL/efx-presets.h)
1402
1403     add_library(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS} ${CORE_OBJS} ${RC_CONFIG}
1404         ${TARGET_PUBLIC_HEADERS})
1405     if(WIN32)
1406         set_target_properties(${IMPL_TARGET} PROPERTIES PREFIX "")
1407     endif()
1408     target_link_libraries(${IMPL_TARGET} PRIVATE alcommon ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1409
1410     if(ALSOFT_UWP)
1411         set(ALSOFT_CPPWINRT_VERSION "2.0.230706.1" CACHE STRING "The soft-oal default cppwinrt version")
1412
1413         find_program(NUGET_EXE NAMES nuget)
1414         if(NOT NUGET_EXE)
1415             message("NUGET.EXE not found.")
1416             message(FATAL_ERROR "Please install this executable, and run CMake again.")
1417         endif()
1418
1419         exec_program(${NUGET_EXE}
1420             ARGS install "Microsoft.Windows.CppWinRT" -Version ${ALSOFT_CPPWINRT_VERSION} -ExcludeVersion -OutputDirectory "\"${CMAKE_BINARY_DIR}/packages\"")
1421
1422         set_target_properties(${IMPL_TARGET} PROPERTIES
1423             VS_PROJECT_IMPORT ${CMAKE_BINARY_DIR}/packages/Microsoft.Windows.CppWinRT/build/native/Microsoft.Windows.CppWinRT.props
1424         )
1425         target_link_libraries(${IMPL_TARGET} PRIVATE ${CMAKE_BINARY_DIR}/packages/Microsoft.Windows.CppWinRT/build/native/Microsoft.Windows.CppWinRT.targets)
1426     endif()
1427
1428     if(NOT WIN32 AND NOT APPLE)
1429         # FIXME: This doesn't put a dependency on the version script. Changing
1430         # the version script will not cause a relink as it should.
1431         target_link_options(${IMPL_TARGET} PRIVATE
1432             "-Wl,--version-script=${OpenAL_SOURCE_DIR}/libopenal.version")
1433     endif()
1434
1435     if(APPLE AND ALSOFT_OSX_FRAMEWORK)
1436         # Sets framework name to soft_oal to avoid ambiguity with the system OpenAL.framework
1437         set(LIBNAME "soft_oal")
1438         if(GIT_FOUND)
1439             execute_process(COMMAND ${GIT_EXECUTABLE} rev-list --count HEAD
1440                 TIMEOUT 5
1441                 OUTPUT_VARIABLE BUNDLE_VERSION
1442                 OUTPUT_STRIP_TRAILING_WHITESPACE)
1443         else()
1444             set(BUNDLE_VERSION 1)
1445         endif()
1446
1447         # Build: Fix rpath in iOS shared libraries
1448         # If this flag is not set, the final dylib binary ld path will be
1449         # /User/xxx/*/soft_oal.framework/soft_oal, which can't be loaded by iOS devices.
1450         # See also: https://github.com/libjpeg-turbo/libjpeg-turbo/commit/c80ddef7a4ce21ace9e3ca0fd190d320cc8cdaeb
1451         if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG)
1452             set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG "-Wl,-rpath,")
1453         endif()
1454
1455         set_target_properties(${IMPL_TARGET} PROPERTIES
1456             FRAMEWORK TRUE
1457             FRAMEWORK_VERSION C
1458             MACOSX_FRAMEWORK_NAME "${IMPL_TARGET}"
1459             MACOSX_FRAMEWORK_IDENTIFIER "org.openal-soft.openal"
1460             MACOSX_FRAMEWORK_SHORT_VERSION_STRING "${LIB_VERSION}"
1461             MACOSX_FRAMEWORK_BUNDLE_VERSION "${BUNDLE_VERSION}"
1462             XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY ""
1463             XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED "NO"
1464             XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED "NO"
1465             PUBLIC_HEADER "${TARGET_PUBLIC_HEADERS}"
1466             MACOSX_RPATH TRUE)
1467     endif()
1468 endif()
1469
1470 target_include_directories(${IMPL_TARGET}
1471   PUBLIC
1472     $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1473   INTERFACE
1474     $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include/AL>
1475     $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
1476     $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/AL>
1477   PRIVATE
1478     ${INC_PATHS}
1479     ${OpenAL_BINARY_DIR}
1480     ${OpenAL_SOURCE_DIR}
1481     ${OpenAL_SOURCE_DIR}/common
1482 )
1483
1484 set_target_properties(${IMPL_TARGET} PROPERTIES ${DEFAULT_TARGET_PROPS}
1485     OUTPUT_NAME ${LIBNAME}
1486     VERSION ${LIB_VERSION}
1487     SOVERSION ${LIB_MAJOR_VERSION}
1488 )
1489 target_compile_definitions(${IMPL_TARGET}
1490     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES "ALC_API=${EXPORT_DECL}" "AL_API=${EXPORT_DECL}"
1491     ${CPP_DEFS})
1492 target_compile_options(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1493
1494 if(TARGET build_version)
1495     add_dependencies(${IMPL_TARGET} build_version)
1496 endif()
1497
1498 if(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1499     find_program(SED_EXECUTABLE NAMES sed DOC "sed executable")
1500     if(NOT SED_EXECUTABLE OR NOT CMAKE_DLLTOOL)
1501         message(STATUS "")
1502         if(NOT SED_EXECUTABLE)
1503             message(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1504         endif()
1505         if(NOT CMAKE_DLLTOOL)
1506             message(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1507         endif()
1508     else()
1509         target_link_options(OpenAL PRIVATE "-Wl,--output-def,OpenAL32.def")
1510         add_custom_command(TARGET OpenAL POST_BUILD
1511             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1512             COMMAND "${CMAKE_DLLTOOL}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1513             # Technically OpenAL32.def was created by the build, but cmake
1514             # doesn't recognize it due to -Wl,--output-def,OpenAL32.def being
1515             # manually specified. But declaring the file here allows it to be
1516             # properly cleaned, e.g. during make clean.
1517             BYPRODUCTS OpenAL32.def OpenAL32.lib
1518             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1519             VERBATIM
1520         )
1521     endif()
1522 endif()
1523
1524 if(HAS_ROUTER)
1525     message(STATUS "")
1526     message(STATUS "Building DLL router")
1527 endif()
1528
1529 message(STATUS "")
1530 message(STATUS "Building OpenAL with support for the following backends:")
1531 message(STATUS "   ${BACKENDS}")
1532 message(STATUS "")
1533 message(STATUS "Building with support for CPU extensions:")
1534 message(STATUS "    ${CPU_EXTS}")
1535 message(STATUS "")
1536 if(FPMATH_SET)
1537     message(STATUS "Building with SSE${FPMATH_SET} codegen")
1538     message(STATUS "")
1539 endif()
1540 if(ALSOFT_UWP)
1541     message(STATUS "Building with UWP support")
1542     message(STATUS "")
1543 endif()
1544 if(ALSOFT_EAX)
1545     message(STATUS "Building with legacy EAX extension support")
1546     message(STATUS "")
1547 endif()
1548
1549 if(ALSOFT_EMBED_HRTF_DATA)
1550     message(STATUS "Embedding HRTF datasets")
1551     message(STATUS "")
1552 endif()
1553
1554 # An alias for sub-project builds
1555 add_library(OpenAL::OpenAL ALIAS OpenAL)
1556
1557 # Install main library
1558 if(ALSOFT_INSTALL)
1559     configure_package_config_file(OpenALConfig.cmake.in OpenALConfig.cmake
1560         INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL)
1561     install(TARGETS OpenAL EXPORT OpenAL
1562         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1563         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1564         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1565         FRAMEWORK DESTINATION ${CMAKE_INSTALL_LIBDIR}
1566         INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL)
1567     export(TARGETS OpenAL
1568         NAMESPACE OpenAL::
1569         FILE OpenALTargets.cmake)
1570     install(EXPORT OpenAL
1571         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1572         NAMESPACE OpenAL::
1573         FILE OpenALTargets.cmake)
1574     install(DIRECTORY include/AL
1575         DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
1576     install(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1577         DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1578     install(FILES "${OpenAL_BINARY_DIR}/OpenALConfig.cmake"
1579         DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL")
1580     if(TARGET soft_oal)
1581         install(TARGETS soft_oal
1582             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
1583     endif()
1584     message(STATUS "Installing library and headers")
1585 else()
1586     message(STATUS "NOT installing library and headers")
1587 endif()
1588
1589 if(ALSOFT_INSTALL_CONFIG)
1590     install(FILES alsoftrc.sample
1591         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1592     message(STATUS "Installing sample configuration")
1593 endif()
1594
1595 if(ALSOFT_INSTALL_HRTF_DATA)
1596     install(DIRECTORY hrtf
1597         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1598     message(STATUS "Installing HRTF data files")
1599 endif()
1600
1601 if(ALSOFT_INSTALL_AMBDEC_PRESETS)
1602     install(DIRECTORY presets
1603         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1604     message(STATUS "Installing AmbDec presets")
1605 endif()
1606 message(STATUS "")
1607
1608 set(UNICODE_FLAG )
1609 if(MINGW)
1610     set(UNICODE_FLAG ${UNICODE_FLAG} -municode)
1611 endif()
1612 set(EXTRA_INSTALLS )
1613 if(ALSOFT_UTILS)
1614     add_executable(openal-info utils/openal-info.c)
1615     target_include_directories(openal-info PRIVATE ${OpenAL_SOURCE_DIR}/common)
1616     target_compile_options(openal-info PRIVATE ${C_FLAGS})
1617     target_link_libraries(openal-info PRIVATE ${LINKER_FLAGS} OpenAL ${UNICODE_FLAG})
1618     set_target_properties(openal-info PROPERTIES ${DEFAULT_TARGET_PROPS})
1619     if(ALSOFT_INSTALL_EXAMPLES)
1620         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} openal-info)
1621     endif()
1622
1623     if(SNDFILE_FOUND)
1624         add_executable(uhjdecoder utils/uhjdecoder.cpp)
1625         target_compile_definitions(uhjdecoder PRIVATE ${CPP_DEFS})
1626         target_include_directories(uhjdecoder
1627             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/common)
1628         target_compile_options(uhjdecoder PRIVATE ${C_FLAGS})
1629         target_link_libraries(uhjdecoder PUBLIC alcommon
1630             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ${UNICODE_FLAG})
1631         set_target_properties(uhjdecoder PROPERTIES ${DEFAULT_TARGET_PROPS})
1632
1633         add_executable(uhjencoder utils/uhjencoder.cpp)
1634         target_compile_definitions(uhjencoder PRIVATE ${CPP_DEFS})
1635         target_include_directories(uhjencoder
1636             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/common)
1637         target_compile_options(uhjencoder PRIVATE ${C_FLAGS})
1638         target_link_libraries(uhjencoder PUBLIC alcommon
1639             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ${UNICODE_FLAG})
1640         set_target_properties(uhjencoder PROPERTIES ${DEFAULT_TARGET_PROPS})
1641     endif()
1642
1643     if(MYSOFA_FOUND)
1644         set(SOFA_SUPPORT_SRCS
1645             utils/sofa-support.cpp
1646             utils/sofa-support.h)
1647         add_library(sofa-support STATIC EXCLUDE_FROM_ALL ${SOFA_SUPPORT_SRCS})
1648         target_compile_definitions(sofa-support PRIVATE ${CPP_DEFS})
1649         target_include_directories(sofa-support PUBLIC ${OpenAL_SOURCE_DIR}/common)
1650         target_compile_options(sofa-support PRIVATE ${C_FLAGS})
1651         target_link_libraries(sofa-support PUBLIC alcommon MySOFA::MySOFA PRIVATE ${LINKER_FLAGS})
1652         set_target_properties(sofa-support PROPERTIES ${DEFAULT_TARGET_PROPS})
1653
1654         set(MAKEMHR_SRCS
1655             utils/makemhr/loaddef.cpp
1656             utils/makemhr/loaddef.h
1657             utils/makemhr/loadsofa.cpp
1658             utils/makemhr/loadsofa.h
1659             utils/makemhr/makemhr.cpp
1660             utils/makemhr/makemhr.h)
1661         if(NOT HAVE_GETOPT)
1662             set(MAKEMHR_SRCS  ${MAKEMHR_SRCS} utils/getopt.c utils/getopt.h)
1663         endif()
1664         add_executable(makemhr ${MAKEMHR_SRCS})
1665         target_compile_definitions(makemhr PRIVATE ${CPP_DEFS})
1666         target_include_directories(makemhr
1667             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/utils)
1668         target_compile_options(makemhr PRIVATE ${C_FLAGS})
1669         target_link_libraries(makemhr PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1670         set_target_properties(makemhr PROPERTIES ${DEFAULT_TARGET_PROPS})
1671         if(ALSOFT_INSTALL_EXAMPLES)
1672             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} makemhr)
1673         endif()
1674
1675         set(SOFAINFO_SRCS  utils/sofa-info.cpp)
1676         add_executable(sofa-info ${SOFAINFO_SRCS})
1677         target_compile_definitions(sofa-info PRIVATE ${CPP_DEFS})
1678         target_include_directories(sofa-info PRIVATE ${OpenAL_SOURCE_DIR}/utils)
1679         target_compile_options(sofa-info PRIVATE ${C_FLAGS})
1680         target_link_libraries(sofa-info PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1681         set_target_properties(sofa-info PROPERTIES ${DEFAULT_TARGET_PROPS})
1682     endif()
1683     message(STATUS "Building utility programs")
1684
1685     if(NOT ALSOFT_NO_CONFIG_UTIL)
1686         add_subdirectory(utils/alsoft-config)
1687     endif()
1688     message(STATUS "")
1689 endif()
1690
1691
1692 # Add a static library with common functions used by multiple example targets
1693 add_library(al-excommon STATIC EXCLUDE_FROM_ALL
1694     examples/common/alhelpers.c
1695     examples/common/alhelpers.h)
1696 target_compile_definitions(al-excommon PUBLIC ${CPP_DEFS})
1697 target_include_directories(al-excommon PUBLIC ${OpenAL_SOURCE_DIR}/common)
1698 target_compile_options(al-excommon PUBLIC ${C_FLAGS})
1699 target_link_libraries(al-excommon PUBLIC OpenAL PRIVATE ${RT_LIB})
1700 set_target_properties(al-excommon PROPERTIES ${DEFAULT_TARGET_PROPS})
1701
1702 if(ALSOFT_EXAMPLES)
1703     add_executable(altonegen examples/altonegen.c)
1704     target_link_libraries(altonegen PRIVATE ${LINKER_FLAGS} ${MATH_LIB} al-excommon ${UNICODE_FLAG})
1705     set_target_properties(altonegen PROPERTIES ${DEFAULT_TARGET_PROPS})
1706
1707     add_executable(alrecord examples/alrecord.c)
1708     target_link_libraries(alrecord PRIVATE ${LINKER_FLAGS} al-excommon ${UNICODE_FLAG})
1709     set_target_properties(alrecord PROPERTIES ${DEFAULT_TARGET_PROPS})
1710
1711     if(ALSOFT_INSTALL_EXAMPLES)
1712         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} altonegen alrecord)
1713     endif()
1714
1715     message(STATUS "Building example programs")
1716
1717     if(SNDFILE_FOUND)
1718         add_executable(alplay examples/alplay.c)
1719         target_link_libraries(alplay PRIVATE ${LINKER_FLAGS} SndFile::SndFile al-excommon
1720             ${UNICODE_FLAG})
1721         set_target_properties(alplay PROPERTIES ${DEFAULT_TARGET_PROPS})
1722
1723         add_executable(alstream examples/alstream.c)
1724         target_link_libraries(alstream PRIVATE ${LINKER_FLAGS} SndFile::SndFile al-excommon
1725             ${UNICODE_FLAG})
1726         set_target_properties(alstream PROPERTIES ${DEFAULT_TARGET_PROPS})
1727
1728         add_executable(alreverb examples/alreverb.c)
1729         target_link_libraries(alreverb PRIVATE ${LINKER_FLAGS} SndFile::SndFile al-excommon
1730             ${UNICODE_FLAG})
1731         set_target_properties(alreverb PROPERTIES ${DEFAULT_TARGET_PROPS})
1732
1733         add_executable(almultireverb examples/almultireverb.c)
1734         target_link_libraries(almultireverb
1735             PRIVATE ${LINKER_FLAGS} SndFile::SndFile al-excommon ${MATH_LIB} ${UNICODE_FLAG})
1736         set_target_properties(almultireverb PROPERTIES ${DEFAULT_TARGET_PROPS})
1737
1738         add_executable(allatency examples/allatency.c)
1739         target_link_libraries(allatency PRIVATE ${LINKER_FLAGS} SndFile::SndFile al-excommon
1740             ${UNICODE_FLAG})
1741         set_target_properties(allatency PROPERTIES ${DEFAULT_TARGET_PROPS})
1742
1743         add_executable(alhrtf examples/alhrtf.c)
1744         target_link_libraries(alhrtf
1745             PRIVATE ${LINKER_FLAGS} SndFile::SndFile al-excommon ${MATH_LIB} ${UNICODE_FLAG})
1746         set_target_properties(alhrtf PROPERTIES ${DEFAULT_TARGET_PROPS})
1747
1748         add_executable(alstreamcb examples/alstreamcb.cpp)
1749         target_link_libraries(alstreamcb PRIVATE ${LINKER_FLAGS} SndFile::SndFile al-excommon
1750             ${UNICODE_FLAG})
1751         set_target_properties(alstreamcb PROPERTIES ${DEFAULT_TARGET_PROPS})
1752
1753         add_executable(alconvolve examples/alconvolve.c)
1754         target_link_libraries(alconvolve PRIVATE ${LINKER_FLAGS} alcommon SndFile::SndFile
1755             al-excommon ${UNICODE_FLAG})
1756         set_target_properties(alconvolve PROPERTIES ${DEFAULT_TARGET_PROPS})
1757
1758         if(ALSOFT_INSTALL_EXAMPLES)
1759             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alplay alstream alreverb almultireverb allatency
1760                 alhrtf)
1761         endif()
1762
1763         message(STATUS "Building SndFile example programs")
1764     endif()
1765
1766     if(SDL2_FOUND)
1767         add_executable(alloopback examples/alloopback.c)
1768         target_link_libraries(alloopback
1769             PRIVATE ${LINKER_FLAGS} SDL2::SDL2 al-excommon ${MATH_LIB})
1770         set_target_properties(alloopback PROPERTIES ${DEFAULT_TARGET_PROPS})
1771
1772         if(ALSOFT_INSTALL_EXAMPLES)
1773             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alloopback)
1774         endif()
1775
1776         message(STATUS "Building SDL example programs")
1777
1778         set(FFVER_OK FALSE)
1779         if(FFMPEG_FOUND)
1780             set(FFVER_OK TRUE)
1781             if(AVFORMAT_VERSION VERSION_LESS "59.27.100")
1782                 message(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 59.27.100)")
1783                 set(FFVER_OK FALSE)
1784             endif()
1785             if(AVCODEC_VERSION VERSION_LESS "59.37.100")
1786                 message(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 59.37.100)")
1787                 set(FFVER_OK FALSE)
1788             endif()
1789             if(AVUTIL_VERSION VERSION_LESS "57.28.100")
1790                 message(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 57.28.100)")
1791                 set(FFVER_OK FALSE)
1792             endif()
1793             if(SWSCALE_VERSION VERSION_LESS "6.7.100")
1794                 message(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 6.7.100)")
1795                 set(FFVER_OK FALSE)
1796             endif()
1797             if(SWRESAMPLE_VERSION VERSION_LESS "4.7.100")
1798                 message(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 4.7.100)")
1799                 set(FFVER_OK FALSE)
1800             endif()
1801         endif()
1802         if(FFVER_OK)
1803             add_executable(alffplay examples/alffplay.cpp)
1804             target_include_directories(alffplay PRIVATE ${FFMPEG_INCLUDE_DIRS})
1805             target_link_libraries(alffplay
1806                 PRIVATE ${LINKER_FLAGS} SDL2::SDL2 ${FFMPEG_LIBRARIES} al-excommon)
1807             set_target_properties(alffplay PROPERTIES ${DEFAULT_TARGET_PROPS})
1808
1809             if(ALSOFT_INSTALL_EXAMPLES)
1810                 set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alffplay)
1811             endif()
1812             message(STATUS "Building SDL+FFmpeg example programs")
1813         endif()
1814     endif()
1815     message(STATUS "")
1816 endif()
1817
1818 if (ALSOFT_TESTS)
1819 add_subdirectory(tests)
1820 endif()
1821
1822 if(EXTRA_INSTALLS)
1823     install(TARGETS ${EXTRA_INSTALLS}
1824         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1825         BUNDLE  DESTINATION ${CMAKE_INSTALL_BINDIR}
1826         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1827         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
1828 endif()