CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 OPTION(ALSOFT_CPUEXT_SSE  "Check for SSE/SSE2 support" ON)
  29 OPTION(ALSOFT_CPUEXT_NEON "Check for ARM Neon support" ON)
  30
  31 OPTION(ALSOFT_REQUIRE_SSE  "Require SSE/SSE2 support" OFF)
  32 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
  33
  34 IF(WIN32)
  35     # This option is mainly for static linking OpenAL Soft into another project
  36     # that already defines the IDs. It is up to that project to ensure all
  37     # required IDs are defined.
  38     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  39 ENDIF()
  40
  41
  42 OPTION(ALSOFT_BACKEND_ALSA    "Check for ALSA backend"                ON)
  43 OPTION(ALSOFT_BACKEND_OSS     "Check for OSS backend"                 ON)
  44 OPTION(ALSOFT_BACKEND_SOLARIS "Check for Solaris backend"             ON)
  45 OPTION(ALSOFT_BACKEND_SNDIO   "Check for SndIO backend"               ON)
  46 OPTION(ALSOFT_BACKEND_QSA     "Check for QSA backend"                 ON)
  47 OPTION(ALSOFT_BACKEND_MMDEVAPI "Check for MMDevApi backend"           ON)
  48 OPTION(ALSOFT_BACKEND_DSOUND   "Check for DirectSound backend"        ON)
  49 OPTION(ALSOFT_BACKEND_WINMM    "Check for Windows Multimedia backend" ON)
  50 OPTION(ALSOFT_BACKEND_PORTAUDIO  "Check for PortAudio backend"        ON)
  51 OPTION(ALSOFT_BACKEND_PULSEAUDIO "Check for PulseAudio backend"       ON)
  52 OPTION(ALSOFT_BACKEND_COREAUDIO  "Check for CoreAudio backend"        ON)
  53 OPTION(ALSOFT_BACKEND_OPENSL     "Check for OpenSL backend"           ON)
  54 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend"               ON)
  55
  56 OPTION(ALSOFT_MIDI_FLUIDSYNTH "Check for FluidSynth MIDI"             ON)
  57
  58 OPTION(ALSOFT_REQUIRE_ALSA       "Require ALSA backend"               OFF)
  59 OPTION(ALSOFT_REQUIRE_OSS        "Require OSS backend"                OFF)
  60 OPTION(ALSOFT_REQUIRE_SOLARIS    "Require Solaris backend"            OFF)
  61 OPTION(ALSOFT_REQUIRE_SNDIO      "Require SndIO backend"              OFF)
  62 OPTION(ALSOFT_REQUIRE_QSA        "Require QSA backend"                OFF)
  63 OPTION(ALSOFT_REQUIRE_MMDEVAPI   "Require MMDevApi"                   OFF)
  64 OPTION(ALSOFT_REQUIRE_DSOUND     "Require DirectSound backend"        OFF)
  65 OPTION(ALSOFT_REQUIRE_WINMM      "Require Windows Multimedia backend" OFF)
  66 OPTION(ALSOFT_REQUIRE_PORTAUDIO  "Require PortAudio backend"          OFF)
  67 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend"         OFF)
  68 OPTION(ALSOFT_REQUIRE_COREAUDIO  "Require CoreAudio backend"          OFF)
  69 OPTION(ALSOFT_REQUIRE_OPENSL     "Require OpenSL backend"             OFF)
  70
  71 OPTION(ALSOFT_REQUIRE_FLUIDSYNTH "Require FluidSynth MIDI"            OFF)
  72
  73 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  74
  75 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  76
  77 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  78 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  79
  80 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  81
  82 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  83 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  84
  85
  86 IF(WIN32)
  87     SET(LIBNAME OpenAL32)
  88     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0501")
  89 ELSE()
  90     SET(LIBNAME openal)
  91 ENDIF()
  92
  93 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  94 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  95     ADD_DEFINITIONS("-I/usr/include")
  96     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  97 ENDIF()
  98
  99 IF(NOT LIBTYPE)
 100     SET(LIBTYPE SHARED)
 101 ENDIF()
 102
 103 SET(LIB_MAJOR_VERSION "1")
 104 SET(LIB_MINOR_VERSION "15")
 105 SET(LIB_REVISION "1")
 106 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 107
 108 SET(EXPORT_DECL "")
 109 SET(ALIGN_DECL "")
 110
 111
 112 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 113 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 114
 115
 116 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 117 IF(HAVE_STD_C99)
 118     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 119 ENDIF()
 120
 121 # MSVC may need workarounds for C99 restrict and inline
 122 IF(MSVC)
 123     # TODO: Once we truly require C99, these restrict and inline checks should go
 124     # away.
 125     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 126                              int main() {return 0;}" HAVE_RESTRICT)
 127     IF(NOT HAVE_RESTRICT)
 128         # Slightly convoluted way to do this, because MSVC may barf if restrict is
 129         # defined to __restrict.
 130         CHECK_C_SOURCE_COMPILES("#define restrict __restrict
 131                                  #include <stdlib.h>
 132                                  int *restrict foo;
 133                                  int main() {return 0;}" HAVE___RESTRICT)
 134         IF(HAVE___RESTRICT)
 135             ADD_DEFINITIONS(-Drestrict=__restrict)
 136             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=__restrict")
 137         ELSE()
 138             ADD_DEFINITIONS("-Drestrict=")
 139             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 140         ENDIF()
 141     ENDIF()
 142
 143     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 144                              int main() {return 0;}" HAVE_INLINE)
 145     IF(NOT HAVE_INLINE)
 146         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 147                                  int main() {return 0;}" HAVE___INLINE)
 148         IF(NOT HAVE___INLINE)
 149             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 150         ENDIF()
 151
 152         ADD_DEFINITIONS(-Dinline=__inline)
 153         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 154     ENDIF()
 155 ENDIF()
 156
 157 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 158 IF(CMAKE_COMPILER_IS_GNUCC)
 159     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 160     # Force no inlining for the next test.
 161     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 162
 163     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 164                              int main() {return foo();}" INLINE_IS_C99)
 165     IF(NOT INLINE_IS_C99)
 166         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 167                              Please update your compiler for better C99 compliance.")
 168     ENDIF()
 169
 170     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 171 ENDIF()
 172
 173 # Add definitions, compiler switches, etc.
 174 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 175 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 176     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 177     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 178         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 179     ENDIF()
 180 ENDIF()
 181
 182 IF(NOT CMAKE_BUILD_TYPE)
 183     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 184         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 185         FORCE)
 186 ENDIF()
 187 IF(NOT CMAKE_DEBUG_POSTFIX)
 188     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 189         "Library postfix for debug builds. Normally left blank."
 190         FORCE)
 191 ENDIF()
 192
 193 IF(MSVC)
 194     # ???
 195     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 196     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 197     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 198     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 199     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 200     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 201     ADD_DEFINITIONS("/wd4098")
 202
 203     IF(NOT DXSDK_DIR)
 204         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 205     ELSE()
 206         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 207     ENDIF()
 208     IF(DXSDK_DIR)
 209         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 210         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 211         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 212         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 213     ENDIF()
 214
 215     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 216     IF(FORCE_STATIC_VCRT)
 217         FOREACH(flag_var
 218                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 219                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 220             IF(${flag_var} MATCHES "/MD")
 221                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 222             ENDIF()
 223         ENDFOREACH(flag_var)
 224     ENDIF()
 225 ELSE()
 226     ADD_DEFINITIONS(-Winline -Wall)
 227     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 228     IF(HAVE_W_EXTRA)
 229         ADD_DEFINITIONS(-Wextra)
 230     ENDIF()
 231
 232     IF(ALSOFT_WERROR)
 233         ADD_DEFINITIONS(-Werror)
 234     ENDIF()
 235
 236     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 237         "Flags used by the compiler during Release with Debug Info builds."
 238         FORCE)
 239     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 240         "Flags used by the compiler during release minsize builds."
 241         FORCE)
 242     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 243         "Flags used by the compiler during release builds"
 244         FORCE)
 245     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 246         "Flags used by the compiler during debug builds."
 247         FORCE)
 248
 249     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 250                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 251 ENDIF()
 252
 253 # Set visibility/export options if available
 254 IF(WIN32)
 255     SET(EXPORT_DECL "__declspec(dllexport)")
 256     IF(NOT MINGW)
 257         SET(ALIGN_DECL "__declspec(align(x))")
 258     ELSE()
 259         SET(ALIGN_DECL "__declspec(aligned(x))")
 260     ENDIF()
 261 ELSE()
 262     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 263     # Yes GCC, really don't accept visibility modes you don't support
 264     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 265
 266     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 267                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 268     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 269         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 270     ELSE()
 271         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 272                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 273         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 274             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 275         ENDIF()
 276     ENDIF()
 277
 278     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 279         CHECK_C_COMPILER_FLAG(-fvisibility=internal HAVE_VISIBILITY_INTERNAL_SWITCH)
 280         IF(HAVE_VISIBILITY_INTERNAL_SWITCH)
 281             ADD_DEFINITIONS(-fvisibility=internal)
 282         ELSE()
 283             CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 284             IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 285                 ADD_DEFINITIONS(-fvisibility=hidden)
 286             ENDIF()
 287         ENDIF()
 288     ENDIF()
 289
 290     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 291                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 292     IF(HAVE_ATTRIBUTE_ALIGNED)
 293         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 294     ENDIF()
 295
 296     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 297 ENDIF()
 298
 299 SET(SSE_SWITCH "")
 300 IF(MSVC)
 301     CHECK_C_COMPILER_FLAG(/arch:SSE HAVE_ARCHSSE_SWITCH)
 302     IF(HAVE_ARCHSSE_SWITCH)
 303         SET(SSE_SWITCH "/arch:SSE")
 304     ENDIF()
 305 ENDIF()
 306 IF(NOT SSE_SWITCH)
 307     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 308     IF(HAVE_MSSE_SWITCH)
 309         SET(SSE_SWITCH "-msse")
 310     ENDIF()
 311 ENDIF()
 312
 313 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 314                          int main() {return 0;}" HAVE_GCC_FORMAT)
 315
 316 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 317 CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 318 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 319 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 320 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 321 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 322 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 323 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 324 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 325 IF(NOT HAVE_GUIDDEF_H)
 326     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 327 ENDIF()
 328
 329 # Some systems need libm for some of the following math functions to work
 330 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 331 IF(HAVE_LIBM)
 332     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 333     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 334 ENDIF()
 335
 336
 337 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 338 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 339 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 340 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 341 IF(HAVE_ALLOCA_H)
 342     CHECK_SYMBOL_EXISTS(alloca alloca.h HAVE_ALLOCA)
 343 ELSEIF(HAVE_MALLOC_H)
 344     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 345 ENDIF()
 346 IF(NOT HAVE_ALLOCA)
 347     CHECK_SYMBOL_EXISTS(_alloca malloc.h HAVE__ALLOCA)
 348     IF(NOT HAVE__ALLOCA)
 349         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 350     ENDIF()
 351
 352     ADD_DEFINITIONS(-Dalloca=_alloca)
 353 ENDIF()
 354
 355 IF(HAVE_FLOAT_H)
 356     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 357     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 358 ENDIF()
 359
 360 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 361 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 362 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 363 IF(NOT HAVE_STRCASECMP)
 364     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 365     IF(NOT HAVE__STRICMP)
 366         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 367     ENDIF()
 368
 369     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 370 ENDIF()
 371
 372 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 373 IF(NOT HAVE_STRNCASECMP)
 374     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 375     IF(NOT HAVE__STRNICMP)
 376         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 377     ENDIF()
 378
 379     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 380 ENDIF()
 381
 382 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 383 IF(NOT HAVE_SNPRINTF)
 384     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 385     IF(NOT HAVE__SNPRINTF)
 386         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 387     ENDIF()
 388
 389     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 390 ENDIF()
 391
 392 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 393 IF(NOT HAVE_ISFINITE)
 394     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 395     IF(NOT HAVE_FINITE)
 396         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 397         IF(NOT HAVE__FINITE)
 398             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 399         ENDIF()
 400         ADD_DEFINITIONS(-Disfinite=_finite)
 401     ELSE()
 402         ADD_DEFINITIONS(-Disfinite=finite)
 403     ENDIF()
 404 ENDIF()
 405
 406 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 407 IF(NOT HAVE_ISNAN)
 408     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 409     IF(NOT HAVE__ISNAN)
 410         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 411     ENDIF()
 412
 413     ADD_DEFINITIONS(-Disnan=_isnan)
 414 ENDIF()
 415
 416
 417 # Check for the dlopen API (for dynamicly loading backend libs)
 418 IF(ALSOFT_DLOPEN)
 419     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 420     IF(HAVE_DLFCN_H)
 421         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 422         IF(HAVE_LIBDL)
 423             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 424         ENDIF()
 425     ENDIF()
 426 ENDIF()
 427
 428 # Check if we have Windows headers
 429 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0501)
 430 IF(NOT HAVE_WINDOWS_H)
 431     # These are needed on some systems for extra features
 432     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
 433     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
 434
 435     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 436     IF(NOT HAVE_GETTIMEOFDAY)
 437         MESSAGE(FATAL_ERROR "No timing function found!")
 438     ENDIF()
 439
 440     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 441     IF(NOT HAVE_NANOSLEEP)
 442         MESSAGE(FATAL_ERROR "No sleep function found!")
 443     ENDIF()
 444
 445     # We need pthreads outside of Windows
 446     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 447     IF(NOT HAVE_PTHREAD_H)
 448         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 449     ENDIF()
 450     # Some systems need pthread_np.h to get recursive mutexes
 451     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 452
 453     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 454     IF(HAVE_PTHREAD)
 455         ADD_DEFINITIONS(-pthread)
 456         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 457         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 458     ENDIF()
 459
 460     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 461     IF(HAVE_LIBPTHREAD)
 462         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 463     ENDIF()
 464
 465     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 466
 467     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 468     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 469         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 470     ENDIF()
 471
 472     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 473     IF(HAVE_LIBRT)
 474         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 475     ENDIF()
 476 ENDIF()
 477
 478 # Check for a 64-bit type
 479 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 480 IF(NOT HAVE_STDINT_H)
 481     IF(HAVE_WINDOWS_H)
 482         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0501
 483                                  #include <windows.h>
 484                                  __int64 foo;
 485                                  int main() {return 0;}" HAVE___INT64)
 486     ENDIF()
 487     IF(NOT HAVE___INT64)
 488         IF(NOT SIZEOF_LONG MATCHES "8")
 489             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 490                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 491             ENDIF()
 492         ENDIF()
 493     ENDIF()
 494 ENDIF()
 495
 496 # Windows needs winmm for timeGetTime, even if the backend is disabled
 497 CHECK_SHARED_FUNCTION_EXISTS(timeGetTime "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 498 IF(HAVE_LIBWINMM)
 499     SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 500     SET(PKG_CONFIG_LIBS ${PKG_CONFIG_LIBS} -lwinmm)
 501 ENDIF()
 502
 503
 504 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 505                  OpenAL32/alBuffer.c
 506                  OpenAL32/alEffect.c
 507                  OpenAL32/alError.c
 508                  OpenAL32/alExtension.c
 509                  OpenAL32/alFilter.c
 510                  OpenAL32/alFontsound.c
 511                  OpenAL32/alListener.c
 512                  OpenAL32/alMidi.c
 513                  OpenAL32/alPreset.c
 514                  OpenAL32/alSoundfont.c
 515                  OpenAL32/alSource.c
 516                  OpenAL32/alState.c
 517                  OpenAL32/alThunk.c
 518                  OpenAL32/sample_cvt.c
 519 )
 520 SET(ALC_OBJS  Alc/ALc.c
 521               Alc/ALu.c
 522               Alc/alcConfig.c
 523               Alc/alcRing.c
 524               Alc/bs2b.c
 525               Alc/effects/autowah.c
 526               Alc/effects/chorus.c
 527               Alc/effects/compressor.c
 528               Alc/effects/dedicated.c
 529               Alc/effects/distortion.c
 530               Alc/effects/echo.c
 531               Alc/effects/equalizer.c
 532               Alc/effects/flanger.c
 533               Alc/effects/modulator.c
 534               Alc/effects/null.c
 535               Alc/effects/reverb.c
 536               Alc/helpers.c
 537               Alc/hrtf.c
 538               Alc/panning.c
 539               Alc/threads.c
 540               Alc/mixer.c
 541               Alc/mixer_c.c
 542 )
 543
 544
 545 SET(CPU_EXTS "Default")
 546 SET(HAVE_SSE  0)
 547 SET(HAVE_NEON 0)
 548
 549 # Check for SSE support
 550 IF(ALSOFT_CPUEXT_SSE AND ALIGN_DECL)
 551     CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 552     IF(HAVE_XMMINTRIN_H)
 553         SET(HAVE_SSE 1)
 554         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 555         IF(SSE_SWITCH)
 556             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 557                                         COMPILE_FLAGS "${SSE_SWITCH}")
 558         ENDIF()
 559         SET(CPU_EXTS "${CPU_EXTS}, SSE")
 560     ENDIF()
 561 ENDIF()
 562 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 563     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 564 ENDIF()
 565
 566 # Check for ARM Neon support
 567 IF(ALSOFT_CPUEXT_NEON)
 568     CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 569     IF(HAVE_ARM_NEON_H)
 570         SET(HAVE_NEON 1)
 571         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 572         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 573     ENDIF()
 574 ENDIF()
 575 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 576     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 577 ENDIF()
 578
 579
 580 SET(ALC_OBJS  ${ALC_OBJS}
 581               Alc/midi/base.c
 582               Alc/midi/sf2load.c
 583               Alc/midi/dummy.c
 584               Alc/midi/fluidsynth.c
 585               Alc/midi/soft.c
 586 )
 587
 588 SET(HAVE_FLUIDSYNTH  0)
 589
 590 # Check for FluidSynth support
 591 IF(ALSOFT_MIDI_FLUIDSYNTH)
 592     FIND_PACKAGE(FluidSynth)
 593     IF(FLUIDSYNTH_FOUND)
 594         SET(HAVE_FLUIDSYNTH 1)
 595         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 596             INCLUDE_DIRECTORIES(${FLUIDSYNTH_INCLUDE_DIR})
 597         ENDIF()
 598         SET(EXTRA_LIBS ${FLUIDSYNTH_LIBRARIES} ${EXTRA_LIBS})
 599     ENDIF()
 600 ENDIF()
 601 IF(ALSOFT_REQUIRE_FLUIDSYNTH AND NOT HAVE_FLUIDSYNTH)
 602     MESSAGE(FATAL_ERROR "Failed to enabled required FluidSynth support")
 603 ENDIF()
 604
 605
 606 SET(ALC_OBJS  ${ALC_OBJS}
 607               Alc/backends/base.c
 608               # Default backends, always available
 609               Alc/backends/loopback.c
 610               Alc/backends/null.c
 611 )
 612
 613 SET(BACKENDS "")
 614 SET(HAVE_ALSA       0)
 615 SET(HAVE_OSS        0)
 616 SET(HAVE_SOLARIS    0)
 617 SET(HAVE_SNDIO      0)
 618 SET(HAVE_QSA        0)
 619 SET(HAVE_DSOUND     0)
 620 SET(HAVE_MMDEVAPI   0)
 621 SET(HAVE_WINMM      0)
 622 SET(HAVE_PORTAUDIO  0)
 623 SET(HAVE_PULSEAUDIO 0)
 624 SET(HAVE_COREAUDIO  0)
 625 SET(HAVE_OPENSL     0)
 626 SET(HAVE_WAVE       0)
 627
 628 # Check ALSA backend
 629 IF(ALSOFT_BACKEND_ALSA)
 630     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 631     IF(HAVE_ALSA_ASOUNDLIB_H)
 632         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "alsa/asoundlib.h" asound "" HAVE_LIBASOUND)
 633         IF(HAVE_LIBASOUND OR HAVE_DLFCN_H OR WIN32)
 634             SET(HAVE_ALSA 1)
 635             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 636             IF(HAVE_DLFCN_H OR WIN32)
 637                 SET(BACKENDS  "${BACKENDS} ALSA,")
 638             ELSE()
 639                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 640                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 641             ENDIF()
 642         ENDIF()
 643     ENDIF()
 644 ENDIF()
 645 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 646     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 647 ENDIF()
 648
 649 # Check OSS backend
 650 IF(ALSOFT_BACKEND_OSS)
 651     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 652     IF(HAVE_SYS_SOUNDCARD_H)
 653         SET(HAVE_OSS 1)
 654         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 655         SET(BACKENDS  "${BACKENDS} OSS,")
 656     ENDIF()
 657 ENDIF()
 658 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 659     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 660 ENDIF()
 661
 662 # Check Solaris backend
 663 IF(ALSOFT_BACKEND_SOLARIS)
 664     CHECK_INCLUDE_FILE(sys/audioio.h HAVE_SYS_AUDIOIO_H)
 665     IF(HAVE_SYS_AUDIOIO_H)
 666         SET(HAVE_SOLARIS 1)
 667         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 668         SET(BACKENDS  "${BACKENDS} Solaris,")
 669     ENDIF()
 670 ENDIF()
 671 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 672     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 673 ENDIF()
 674
 675 # Check SndIO backend
 676 IF(ALSOFT_BACKEND_SNDIO)
 677     CHECK_INCLUDE_FILE(sndio.h HAVE_SNDIO_H)
 678     IF(HAVE_SNDIO_H)
 679         CHECK_SHARED_FUNCTION_EXISTS(sio_open "sndio.h" sndio "" HAVE_LIBSNDIO)
 680         IF(HAVE_LIBSNDIO)
 681             SET(HAVE_SNDIO 1)
 682             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 683             SET(BACKENDS  "${BACKENDS} SndIO \(linked\),")
 684             SET(EXTRA_LIBS sndio ${EXTRA_LIBS})
 685         ENDIF()
 686     ENDIF()
 687 ENDIF()
 688 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 689     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 690 ENDIF()
 691
 692 # Check QSA backend
 693 IF (ALSOFT_BACKEND_QSA AND "${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 694     CHECK_INCLUDE_FILE(sys/asoundlib.h HAVE_SYS_ASOUNDLIB_H)
 695     IF(HAVE_SYS_ASOUNDLIB_H)
 696         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "sys/asoundlib.h" asound "" HAVE_LIBASOUND)
 697         IF(HAVE_LIBASOUND)
 698             SET(HAVE_QSA 1)
 699             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 700             SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 701             SET(BACKENDS  "${BACKENDS} QSA \(linked\),")
 702         ENDIF()
 703     ENDIF()
 704 ENDIF()
 705 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 706     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 707 ENDIF()
 708
 709 # Check for MMDevApi backend
 710 IF(HAVE_WINDOWS_H)
 711     IF(ALSOFT_BACKEND_MMDEVAPI)
 712         CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 713         IF(HAVE_MMDEVICEAPI_H)
 714             SET(HAVE_MMDEVAPI 1)
 715             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 716
 717             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 718         ENDIF()
 719     ENDIF()
 720 ENDIF()
 721 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 722     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 723 ENDIF()
 724
 725 # Check DSound/MMSystem backend
 726 IF(ALSOFT_BACKEND_DSOUND)
 727     CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 728     IF(HAVE_DSOUND_H)
 729         CHECK_SHARED_FUNCTION_EXISTS(DirectSoundCreate "dsound.h" dsound "" HAVE_LIBDSOUND)
 730         IF(HAVE_LIBDSOUND OR HAVE_DLFCN_H OR WIN32)
 731             SET(HAVE_DSOUND 1)
 732             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 733
 734             IF(HAVE_DLFCN_H OR WIN32)
 735                 SET(BACKENDS  "${BACKENDS} DirectSound,")
 736             ELSE()
 737                 SET(BACKENDS  "${BACKENDS} DirectSound \(linked\),")
 738                 SET(EXTRA_LIBS dsound ${EXTRA_LIBS})
 739             ENDIF()
 740         ENDIF()
 741     ENDIF()
 742 ENDIF()
 743 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 744     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 745 ENDIF()
 746
 747 IF(HAVE_WINDOWS_H)
 748     IF(ALSOFT_BACKEND_WINMM)
 749         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0501)
 750         IF(HAVE_MMSYSTEM_H AND HAVE_LIBWINMM)
 751             SET(HAVE_WINMM 1)
 752             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 753             SET(BACKENDS  "${BACKENDS} WinMM,")
 754         ENDIF()
 755     ENDIF()
 756 ENDIF()
 757 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 758     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 759 ENDIF()
 760
 761 # Check PortAudio backend
 762 IF(ALSOFT_BACKEND_PORTAUDIO)
 763     CHECK_INCLUDE_FILE(portaudio.h HAVE_PORTAUDIO_H)
 764     IF(HAVE_PORTAUDIO_H)
 765         CHECK_SHARED_FUNCTION_EXISTS(Pa_Initialize "portaudio.h" portaudio "" HAVE_LIBPORTAUDIO)
 766         IF(HAVE_LIBPORTAUDIO OR HAVE_DLFCN_H OR WIN32)
 767             SET(HAVE_PORTAUDIO 1)
 768             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 769             IF(HAVE_DLFCN_H OR WIN32)
 770                 SET(BACKENDS  "${BACKENDS} PortAudio,")
 771             ELSE()
 772                 SET(BACKENDS  "${BACKENDS} PortAudio \(linked\),")
 773                 SET(EXTRA_LIBS portaudio ${EXTRA_LIBS})
 774             ENDIF()
 775         ENDIF()
 776     ENDIF()
 777 ENDIF()
 778 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 779     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 780 ENDIF()
 781
 782 # Check PulseAudio backend
 783 IF(ALSOFT_BACKEND_PULSEAUDIO)
 784     CHECK_INCLUDE_FILE(pulse/pulseaudio.h HAVE_PULSE_PULSEAUDIO_H)
 785     IF(HAVE_PULSE_PULSEAUDIO_H)
 786         CHECK_SHARED_FUNCTION_EXISTS(pa_context_new "pulse/pulseaudio.h" pulse "" HAVE_LIBPULSE)
 787         IF(HAVE_LIBPULSE OR HAVE_DLFCN_H OR WIN32)
 788             SET(HAVE_PULSEAUDIO 1)
 789             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 790             IF(HAVE_DLFCN_H OR WIN32)
 791                 SET(BACKENDS  "${BACKENDS} PulseAudio,")
 792             ELSE()
 793                 SET(BACKENDS  "${BACKENDS} PulseAudio \(linked\),")
 794                 SET(EXTRA_LIBS pulse ${EXTRA_LIBS})
 795             ENDIF()
 796         ENDIF()
 797     ENDIF()
 798 ENDIF()
 799 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 800     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 801 ENDIF()
 802
 803 # Check CoreAudio backend
 804 IF(ALSOFT_BACKEND_COREAUDIO)
 805     CHECK_INCLUDE_FILE(/System/Library/Frameworks/CoreAudio.framework/Headers/CoreAudio.h HAVE_COREAUDIO_FRAMEWORK)
 806     IF(HAVE_COREAUDIO_FRAMEWORK)
 807         SET(HAVE_COREAUDIO 1)
 808         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 809         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 810         SET(EXTRA_LIBS /System/Library/Frameworks/CoreAudio.framework ${EXTRA_LIBS})
 811         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 812         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 813
 814         # Some versions of OSX may need the AudioToolbox framework. Add it if
 815         # it's found.
 816         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 817                      NAMES AudioToolbox
 818                      PATHS ~/Library/Frameworks
 819                            /Library/Frameworks
 820                            /System/Library/Frameworks
 821                     )
 822         IF(AUDIOTOOLBOX_LIBRARY)
 823             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 824         ENDIF()
 825     ENDIF()
 826 ENDIF()
 827 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 828     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 829 ENDIF()
 830
 831 # Check for OpenSL (Android) backend
 832 IF(ALSOFT_BACKEND_OPENSL)
 833     CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 834     IF(HAVE_SLES_OPENSLES_ANDROID_H)
 835         CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 836         IF(HAVE_LIBOPENSLES)
 837             SET(HAVE_OPENSL 1)
 838             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 839             SET(BACKENDS  "${BACKENDS} OpenSL,")
 840             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 841         ENDIF()
 842     ENDIF()
 843 ENDIF()
 844 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 845     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 846 ENDIF()
 847
 848 # Optionally enable the Wave Writer backend
 849 IF(ALSOFT_BACKEND_WAVE)
 850     SET(HAVE_WAVE 1)
 851     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 852     SET(BACKENDS  "${BACKENDS} WaveFile,")
 853 ENDIF()
 854
 855 # This is always available
 856 SET(BACKENDS  "${BACKENDS} Null")
 857
 858 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 859     add_subdirectory(utils/alsoft-config)
 860 ENDIF()
 861 IF(ALSOFT_EXAMPLES)
 862     FIND_PACKAGE(SDL)
 863     IF(SDL_FOUND)
 864         FIND_PACKAGE(SDL_sound)
 865         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 866             INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 867         ENDIF()
 868     ENDIF()
 869 ENDIF()
 870
 871 IF(LIBTYPE STREQUAL "STATIC")
 872     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 873     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 874 ENDIF()
 875
 876 # Needed for openal.pc.in
 877 SET(prefix ${CMAKE_INSTALL_PREFIX})
 878 SET(exec_prefix "\${prefix}")
 879 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 880 SET(bindir "\${exec_prefix}/bin")
 881 SET(includedir "\${prefix}/include")
 882 SET(PACKAGE_VERSION "${LIB_VERSION}")
 883
 884 # End configuration
 885 CONFIGURE_FILE(
 886     "${OpenAL_SOURCE_DIR}/config.h.in"
 887     "${OpenAL_BINARY_DIR}/config.h")
 888 CONFIGURE_FILE(
 889     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 890     "${OpenAL_BINARY_DIR}/openal.pc"
 891     @ONLY)
 892
 893 # Build a library
 894 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 895 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
 896 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 897     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
 898 ENDIF()
 899 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 900 IF(FLUIDSYNTH_FOUND)
 901     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${FLUIDSYNTH_INCLUDE_DIR})
 902 ENDIF()
 903 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 904                                             SOVERSION ${LIB_MAJOR_VERSION})
 905 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
 906     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 907 ENDIF()
 908
 909 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 910
 911 # Add an install target here
 912 INSTALL(TARGETS ${LIBNAME}
 913         RUNTIME DESTINATION bin
 914         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 915         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 916 )
 917 INSTALL(FILES include/AL/al.h
 918               include/AL/alc.h
 919               include/AL/alext.h
 920               include/AL/efx.h
 921               include/AL/efx-creative.h
 922               include/AL/efx-presets.h
 923         DESTINATION include/AL
 924 )
 925 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 926         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
 927
 928
 929 MESSAGE(STATUS "")
 930 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 931 MESSAGE(STATUS "    ${BACKENDS}")
 932 MESSAGE(STATUS "")
 933 MESSAGE(STATUS "Building with support for CPU extensions:")
 934 MESSAGE(STATUS "    ${CPU_EXTS}")
 935 MESSAGE(STATUS "")
 936 IF(HAVE_FLUIDSYNTH)
 937     MESSAGE(STATUS "FluidSynth support for ALC_SOFT_midi_interface enabled")
 938     MESSAGE(STATUS "")
 939 ENDIF()
 940
 941 IF(WIN32)
 942     IF(NOT HAVE_DSOUND)
 943         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
 944         MESSAGE(STATUS "         This is probably NOT what you want!")
 945         MESSAGE(STATUS "")
 946     ENDIF()
 947 ENDIF()
 948
 949 # Install alsoft.conf configuration file
 950 IF(ALSOFT_CONFIG)
 951     INSTALL(FILES alsoftrc.sample
 952             DESTINATION share/openal
 953     )
 954     MESSAGE(STATUS "Installing sample configuration")
 955     MESSAGE(STATUS "")
 956 ENDIF()
 957
 958 # Install HRTF definitions
 959 IF(ALSOFT_HRTF_DEFS)
 960     INSTALL(FILES hrtf/default-44100.mhr
 961             DESTINATION share/openal/hrtf
 962     )
 963     MESSAGE(STATUS "Installing HRTF definitions")
 964     MESSAGE(STATUS "")
 965 ENDIF()
 966
 967 IF(ALSOFT_UTILS)
 968     ADD_EXECUTABLE(openal-info utils/openal-info.c)
 969     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
 970
 971     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
 972     IF(HAVE_LIBM)
 973         TARGET_LINK_LIBRARIES(makehrtf m)
 974     ENDIF()
 975
 976     INSTALL(TARGETS openal-info makehrtf
 977             RUNTIME DESTINATION bin
 978             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 979             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 980     )
 981
 982     MESSAGE(STATUS "Building utility programs")
 983     IF(TARGET alsoft-config)
 984         MESSAGE(STATUS "Building configuration program")
 985     ENDIF()
 986     MESSAGE(STATUS "")
 987 ENDIF()
 988
 989 IF(ALSOFT_EXAMPLES)
 990     IF(SDL_FOUND AND SDL_SOUND_FOUND)
 991         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
 992                                      examples/common/sdl_sound.c)
 993         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 994
 995         ADD_EXECUTABLE(alstream examples/alstream.c)
 996         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 997         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 998
 999         ADD_EXECUTABLE(alreverb examples/alreverb.c)
1000         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
1001         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1002
1003         ADD_EXECUTABLE(allatency examples/allatency.c)
1004         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
1005         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1006
1007         ADD_EXECUTABLE(alloopback examples/alloopback.c)
1008         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL_LIBRARY} ${LIBNAME})
1009         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_INCLUDE_DIR}
1010                                                                            ${SDL_SOUND_INCLUDE_DIR})
1011
1012         INSTALL(TARGETS alstream alreverb allatency alloopback
1013                 RUNTIME DESTINATION bin
1014                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1015                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1016         )
1017
1018         MESSAGE(STATUS "Building example programs")
1019         MESSAGE(STATUS "")
1020     ENDIF()
1021 ENDIF()