CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23 include(CheckFileOffsetBits)
  24
  25
  26 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  27
  28
  29 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  30
  31 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  32
  33 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  34 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  35
  36 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  37
  38 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  39 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  40
  41
  42 IF(WIN32)
  43     SET(LIBNAME OpenAL32)
  44     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  45
  46     # This option is mainly for static linking OpenAL Soft into another project
  47     # that already defines the IDs. It is up to that project to ensure all
  48     # required IDs are defined.
  49     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  50
  51     IF(MINGW)
  52         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  53         IF(NOT DLLTOOL)
  54             IF(HOST)
  55                 SET(DLLTOOL "${HOST}-dlltool")
  56             ELSE()
  57                 SET(DLLTOOL "dlltool")
  58             ENDIF()
  59         ENDIF()
  60     ENDIF()
  61 ELSE()
  62     SET(LIBNAME openal)
  63
  64     # These are needed on non-Windows systems for extra features
  65     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
  66     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
  67 ENDIF()
  68
  69 # Set defines for large file support
  70 CHECK_FILE_OFFSET_BITS()
  71 IF(_FILE_OFFSET_BITS)
  72     ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS})
  73     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
  74 ENDIF()
  75 ADD_DEFINITIONS(-D_LARGEFILE_SOURCE -D_LARGE_FILES)
  76 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
  77
  78
  79 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  80 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  81     ADD_DEFINITIONS("-I/usr/include")
  82     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  83 ENDIF()
  84
  85 IF(NOT LIBTYPE)
  86     SET(LIBTYPE SHARED)
  87 ENDIF()
  88
  89 SET(LIB_MAJOR_VERSION "1")
  90 SET(LIB_MINOR_VERSION "15")
  91 SET(LIB_REVISION "1")
  92 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
  93
  94 SET(EXPORT_DECL "")
  95 SET(ALIGN_DECL "")
  96
  97
  98 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  99 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 100
 101
 102 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 103 IF(HAVE_STD_C99)
 104     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 105 ENDIF()
 106
 107 # MSVC may need workarounds for C99 restrict and inline
 108 IF(MSVC)
 109     # TODO: Once we truly require C99, these restrict and inline checks should go
 110     # away.
 111     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 112                              int main() {return 0;}" HAVE_RESTRICT)
 113     IF(NOT HAVE_RESTRICT)
 114         ADD_DEFINITIONS("-Drestrict=")
 115         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 116     ENDIF()
 117
 118     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 119                              int main() {return 0;}" HAVE_INLINE)
 120     IF(NOT HAVE_INLINE)
 121         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 122                                  int main() {return 0;}" HAVE___INLINE)
 123         IF(NOT HAVE___INLINE)
 124             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 125         ENDIF()
 126
 127         ADD_DEFINITIONS(-Dinline=__inline)
 128         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 129     ENDIF()
 130 ENDIF()
 131
 132 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 133 IF(CMAKE_COMPILER_IS_GNUCC)
 134     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 135     # Force no inlining for the next test.
 136     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 137
 138     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 139                              int main() {return foo();}" INLINE_IS_C99)
 140     IF(NOT INLINE_IS_C99)
 141         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 142                              Please update your compiler for better C99 compliance.")
 143     ENDIF()
 144
 145     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 146 ENDIF()
 147
 148 # Check if we have C99 variable length arrays
 149 CHECK_C_SOURCE_COMPILES(
 150 "int main(int argc, char *argv[])
 151  {
 152      volatile int tmp[argc];
 153      tmp[0] = argv[0][0];
 154      return tmp[0];
 155  }"
 156 HAVE_C99_VLA)
 157
 158 # Check if we have C99 bool
 159 CHECK_C_SOURCE_COMPILES(
 160 "int main(int argc, char *argv[])
 161  {
 162      volatile _Bool ret;
 163      ret = (argc > 1) ? 1 : 0;
 164      return ret ? -1 : 0;
 165  }"
 166 HAVE_C99_BOOL)
 167
 168 # Check if we have C11 static_assert
 169 CHECK_C_SOURCE_COMPILES(
 170 "int main()
 171  {
 172      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 173      return 0;
 174  }"
 175 HAVE_C11_STATIC_ASSERT)
 176
 177 # Check if we have C11 alignas
 178 CHECK_C_SOURCE_COMPILES(
 179 "_Alignas(16) int foo;
 180  int main()
 181  {
 182      return 0;
 183  }"
 184 HAVE_C11_ALIGNAS)
 185
 186 # Check if we have C11 _Atomic
 187 CHECK_C_SOURCE_COMPILES(
 188 "#include <stdatomic.h>
 189  int _Atomic foo;
 190  int main()
 191  {
 192      return atomic_load(&foo);
 193  }"
 194 HAVE_C11_ATOMIC)
 195
 196 # Add definitions, compiler switches, etc.
 197 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 198 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 199     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 200     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 201         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 202     ENDIF()
 203 ENDIF()
 204
 205 IF(NOT CMAKE_BUILD_TYPE)
 206     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 207         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 208         FORCE)
 209 ENDIF()
 210 IF(NOT CMAKE_DEBUG_POSTFIX)
 211     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 212         "Library postfix for debug builds. Normally left blank."
 213         FORCE)
 214 ENDIF()
 215
 216 IF(MSVC)
 217     # ???
 218     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 219     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 220     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 221     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 222     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 223     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 224     ADD_DEFINITIONS("/wd4098")
 225
 226     IF(NOT DXSDK_DIR)
 227         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 228     ELSE()
 229         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 230     ENDIF()
 231     IF(DXSDK_DIR)
 232         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 233         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 234         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 235         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 236     ENDIF()
 237
 238     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 239     IF(FORCE_STATIC_VCRT)
 240         FOREACH(flag_var
 241                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 242                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 243             IF(${flag_var} MATCHES "/MD")
 244                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 245             ENDIF()
 246         ENDFOREACH(flag_var)
 247     ENDIF()
 248 ELSE()
 249     ADD_DEFINITIONS(-Winline -Wall)
 250     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 251     IF(HAVE_W_EXTRA)
 252         ADD_DEFINITIONS(-Wextra)
 253     ENDIF()
 254
 255     IF(ALSOFT_WERROR)
 256         ADD_DEFINITIONS(-Werror)
 257     ENDIF()
 258
 259     # Force enable PIC if available. The static common library will be linked
 260     # into the dynamic openal library, which requires all its code to be
 261     # position-independent, and CMake doesn't automatically enable PIC for
 262     # static library targets (Windows code is always position-independent).
 263     CHECK_C_COMPILER_FLAG(-fPIC HAVE_FPIC_SWITCH)
 264     IF(HAVE_FPIC_SWITCH AND NOT WIN32)
 265         ADD_DEFINITIONS(-fPIC)
 266     ENDIF()
 267
 268     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 269         "Flags used by the compiler during Release with Debug Info builds."
 270         FORCE)
 271     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 272         "Flags used by the compiler during release minsize builds."
 273         FORCE)
 274     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 275         "Flags used by the compiler during release builds"
 276         FORCE)
 277     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 278         "Flags used by the compiler during debug builds."
 279         FORCE)
 280
 281     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 282                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 283 ENDIF()
 284
 285 # Set visibility/export options if available
 286 IF(WIN32)
 287     SET(EXPORT_DECL "__declspec(dllexport)")
 288     IF(NOT MINGW)
 289         SET(ALIGN_DECL "__declspec(align(x))")
 290     ELSE()
 291         SET(ALIGN_DECL "__declspec(aligned(x))")
 292     ENDIF()
 293 ELSE()
 294     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 295     # Yes GCC, really don't accept visibility modes you don't support
 296     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 297
 298     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 299                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 300     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 301         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 302     ELSE()
 303         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 304                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 305         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 306             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 307         ENDIF()
 308     ENDIF()
 309
 310     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 311         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 312         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 313             ADD_DEFINITIONS(-fvisibility=hidden)
 314         ENDIF()
 315     ENDIF()
 316
 317     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 318                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 319     IF(HAVE_ATTRIBUTE_ALIGNED)
 320         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 321     ENDIF()
 322
 323     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 324 ENDIF()
 325
 326 SET(SSE_SWITCH "")
 327 SET(SSE2_SWITCH "")
 328 SET(SSE4_1_SWITCH "")
 329 IF(NOT MSVC)
 330     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 331     IF(HAVE_MSSE_SWITCH)
 332         SET(SSE_SWITCH "-msse")
 333     ENDIF()
 334     CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 335     IF(HAVE_MSSE2_SWITCH)
 336         SET(SSE2_SWITCH "-msse2")
 337     ENDIF()
 338     CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 339     IF(HAVE_MSSE4_1_SWITCH)
 340         SET(SSE4_1_SWITCH "-msse4.1")
 341     ENDIF()
 342 ENDIF()
 343
 344 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 345                          int main() {return 0;}" HAVE_GCC_FORMAT)
 346
 347 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 348 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 349 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 350 CHECK_INCLUDE_FILE(ftw.h HAVE_FTW_H)
 351 CHECK_INCLUDE_FILE(io.h HAVE_IO_H)
 352 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 353 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 354 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 355 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 356 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 357 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 358 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 359 IF(NOT HAVE_GUIDDEF_H)
 360     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 361 ENDIF()
 362
 363 # Some systems need libm for some of the following math functions to work
 364 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 365 IF(HAVE_LIBM)
 366     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 367     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 368 ENDIF()
 369
 370
 371 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 372 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 373 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 374 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 375 IF(NOT HAVE_C99_VLA)
 376     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 377     IF(NOT HAVE_ALLOCA)
 378         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 379     ENDIF()
 380 ENDIF()
 381
 382 IF(HAVE_FLOAT_H)
 383     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 384     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 385 ENDIF()
 386 IF(HAVE_FTW_H)
 387     CHECK_SYMBOL_EXISTS(ftw ftw.h HAVE_FTW)
 388 ENDIF()
 389 IF(HAVE_IO_H)
 390     CHECK_SYMBOL_EXISTS(_wfindfirst io.h HAVE__WFINDFIRST)
 391 ENDIF()
 392
 393 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 394 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 395 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 396 IF(NOT HAVE_STRCASECMP)
 397     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 398     IF(NOT HAVE__STRICMP)
 399         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 400     ENDIF()
 401
 402     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 403 ENDIF()
 404
 405 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 406 IF(NOT HAVE_STRNCASECMP)
 407     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 408     IF(NOT HAVE__STRNICMP)
 409         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 410     ENDIF()
 411
 412     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 413 ENDIF()
 414
 415 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 416 IF(NOT HAVE_SNPRINTF)
 417     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 418     IF(NOT HAVE__SNPRINTF)
 419         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 420     ENDIF()
 421
 422     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 423 ENDIF()
 424
 425 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 426 IF(NOT HAVE_ISFINITE)
 427     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 428     IF(NOT HAVE_FINITE)
 429         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 430         IF(NOT HAVE__FINITE)
 431             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 432         ENDIF()
 433         ADD_DEFINITIONS(-Disfinite=_finite)
 434     ELSE()
 435         ADD_DEFINITIONS(-Disfinite=finite)
 436     ENDIF()
 437 ENDIF()
 438
 439 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 440 IF(NOT HAVE_ISNAN)
 441     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 442     IF(NOT HAVE__ISNAN)
 443         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 444     ENDIF()
 445
 446     ADD_DEFINITIONS(-Disnan=_isnan)
 447 ENDIF()
 448
 449
 450 # Check for the dlopen API (for dynamicly loading backend libs)
 451 IF(ALSOFT_DLOPEN)
 452     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 453     IF(HAVE_DLFCN_H)
 454         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 455         IF(HAVE_LIBDL)
 456             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 457         ENDIF()
 458     ENDIF()
 459 ENDIF()
 460
 461 # Check if we have Windows headers
 462 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 463 IF(NOT HAVE_WINDOWS_H)
 464     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 465     IF(NOT HAVE_GETTIMEOFDAY)
 466         MESSAGE(FATAL_ERROR "No timing function found!")
 467     ENDIF()
 468
 469     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 470     IF(NOT HAVE_NANOSLEEP)
 471         MESSAGE(FATAL_ERROR "No sleep function found!")
 472     ENDIF()
 473
 474     # We need pthreads outside of Windows
 475     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 476     IF(NOT HAVE_PTHREAD_H)
 477         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 478     ENDIF()
 479     # Some systems need pthread_np.h to get recursive mutexes
 480     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 481
 482     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 483     IF(HAVE_PTHREAD)
 484         ADD_DEFINITIONS(-pthread)
 485         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 486         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 487     ENDIF()
 488
 489     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 490     IF(HAVE_LIBPTHREAD)
 491         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 492     ENDIF()
 493
 494     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 495
 496     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 497     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 498         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 499     ENDIF()
 500     IF(HAVE_PTHREAD_NP_H)
 501         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 502     ENDIF()
 503
 504     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 505
 506     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 507     IF(HAVE_LIBRT)
 508         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 509     ENDIF()
 510 ENDIF()
 511
 512 # Check for a 64-bit type
 513 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 514 IF(NOT HAVE_STDINT_H)
 515     IF(HAVE_WINDOWS_H)
 516         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 517                                  #include <windows.h>
 518                                  __int64 foo;
 519                                  int main() {return 0;}" HAVE___INT64)
 520     ENDIF()
 521     IF(NOT HAVE___INT64)
 522         IF(NOT SIZEOF_LONG MATCHES "8")
 523             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 524                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 525             ENDIF()
 526         ENDIF()
 527     ENDIF()
 528 ENDIF()
 529
 530
 531 SET(COMMON_OBJS  common/atomic.c
 532                  common/rwlock.c
 533                  common/threads.c
 534                  common/uintmap.c
 535 )
 536 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 537                  OpenAL32/alBuffer.c
 538                  OpenAL32/alEffect.c
 539                  OpenAL32/alError.c
 540                  OpenAL32/alExtension.c
 541                  OpenAL32/alFilter.c
 542                  OpenAL32/alFontsound.c
 543                  OpenAL32/alListener.c
 544                  OpenAL32/alMidi.c
 545                  OpenAL32/alPreset.c
 546                  OpenAL32/alSoundfont.c
 547                  OpenAL32/alSource.c
 548                  OpenAL32/alState.c
 549                  OpenAL32/alThunk.c
 550                  OpenAL32/sample_cvt.c
 551 )
 552 SET(ALC_OBJS  Alc/ALc.c
 553               Alc/ALu.c
 554               Alc/alcConfig.c
 555               Alc/alcRing.c
 556               Alc/bs2b.c
 557               Alc/effects/autowah.c
 558               Alc/effects/chorus.c
 559               Alc/effects/compressor.c
 560               Alc/effects/dedicated.c
 561               Alc/effects/distortion.c
 562               Alc/effects/echo.c
 563               Alc/effects/equalizer.c
 564               Alc/effects/flanger.c
 565               Alc/effects/modulator.c
 566               Alc/effects/null.c
 567               Alc/effects/reverb.c
 568               Alc/helpers.c
 569               Alc/hrtf.c
 570               Alc/panning.c
 571               Alc/mixer.c
 572               Alc/mixer_c.c
 573 )
 574
 575
 576 SET(CPU_EXTS "Default")
 577 SET(HAVE_SSE        0)
 578 SET(HAVE_SSE2       0)
 579 SET(HAVE_SSE4_1     0)
 580 SET(HAVE_NEON       0)
 581
 582 SET(HAVE_FLUIDSYNTH 0)
 583
 584 SET(HAVE_ALSA       0)
 585 SET(HAVE_OSS        0)
 586 SET(HAVE_SOLARIS    0)
 587 SET(HAVE_SNDIO      0)
 588 SET(HAVE_QSA        0)
 589 SET(HAVE_DSOUND     0)
 590 SET(HAVE_MMDEVAPI   0)
 591 SET(HAVE_WINMM      0)
 592 SET(HAVE_PORTAUDIO  0)
 593 SET(HAVE_PULSEAUDIO 0)
 594 SET(HAVE_COREAUDIO  0)
 595 SET(HAVE_OPENSL     0)
 596 SET(HAVE_WAVE       0)
 597
 598 # Check for SSE support
 599 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 600 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 601 IF(HAVE_XMMINTRIN_H)
 602     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 603     IF(ALSOFT_CPUEXT_SSE)
 604         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 605             SET(HAVE_SSE 1)
 606             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 607             IF(SSE_SWITCH)
 608                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 609                                             COMPILE_FLAGS "${SSE_SWITCH}")
 610             ENDIF()
 611             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 612         ENDIF()
 613     ENDIF()
 614 ENDIF()
 615 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 616     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 617 ENDIF()
 618
 619 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 620 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 621 IF(HAVE_EMMINTRIN_H)
 622     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 623     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 624         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 625             SET(HAVE_SSE2 1)
 626             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 627             IF(SSE2_SWITCH)
 628                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 629                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 630             ENDIF()
 631             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 632         ENDIF()
 633     ENDIF()
 634 ENDIF()
 635 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 636     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 637 ENDIF()
 638
 639 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 640 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 641 IF(HAVE_SMMINTRIN_H)
 642     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 643     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 644         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 645             SET(HAVE_SSE4_1 1)
 646             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 647             IF(SSE4_1_SWITCH)
 648                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 649                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 650             ENDIF()
 651             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 652         ENDIF()
 653     ENDIF()
 654 ENDIF()
 655 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 656     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 657 ENDIF()
 658
 659 # Check for ARM Neon support
 660 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 661 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 662 IF(HAVE_ARM_NEON_H)
 663     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 664     IF(ALSOFT_CPUEXT_NEON)
 665         SET(HAVE_NEON 1)
 666         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 667         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 668     ENDIF()
 669 ENDIF()
 670 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 671     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 672 ENDIF()
 673
 674
 675 IF(WIN32 OR HAVE_DLFCN_H)
 676     SET(IS_LINKED "")
 677     MACRO(ADD_BACKEND_LIBS _LIBS)
 678     ENDMACRO()
 679 ELSE()
 680     SET(IS_LINKED " (linked)")
 681     MACRO(ADD_BACKEND_LIBS _LIBS)
 682         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 683     ENDMACRO()
 684 ENDIF()
 685
 686 SET(ALC_OBJS  ${ALC_OBJS}
 687               Alc/midi/base.c
 688               Alc/midi/sf2load.c
 689               Alc/midi/dummy.c
 690               Alc/midi/fluidsynth.c
 691               Alc/midi/soft.c
 692 )
 693
 694 # Check for FluidSynth support
 695 OPTION(ALSOFT_REQUIRE_FLUIDSYNTH "Require FluidSynth MIDI" OFF)
 696 FIND_PACKAGE(FluidSynth)
 697 IF(FLUIDSYNTH_FOUND)
 698     OPTION(ALSOFT_MIDI_FLUIDSYNTH "Enable FluidSynth MIDI" ON)
 699     IF(ALSOFT_MIDI_FLUIDSYNTH)
 700         SET(HAVE_FLUIDSYNTH 1)
 701         ADD_BACKEND_LIBS(${FLUIDSYNTH_LIBRARIES})
 702         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 703             INCLUDE_DIRECTORIES(${FLUIDSYNTH_INCLUDE_DIR})
 704         ENDIF()
 705     ENDIF()
 706 ENDIF()
 707 IF(ALSOFT_REQUIRE_FLUIDSYNTH AND NOT HAVE_FLUIDSYNTH)
 708     MESSAGE(FATAL_ERROR "Failed to enabled required FluidSynth support")
 709 ENDIF()
 710
 711
 712 SET(BACKENDS "")
 713 SET(ALC_OBJS  ${ALC_OBJS}
 714               Alc/backends/base.c
 715               # Default backends, always available
 716               Alc/backends/loopback.c
 717               Alc/backends/null.c
 718 )
 719
 720 # Check ALSA backend
 721 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 722 FIND_PACKAGE(ALSA)
 723 IF(ALSA_FOUND)
 724     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 725     IF(ALSOFT_BACKEND_ALSA)
 726         SET(HAVE_ALSA 1)
 727         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 728         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 729         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 730         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 731             INCLUDE_DIRECTORIES(${ALSA_INCLUDE_DIRS})
 732         ENDIF()
 733     ENDIF()
 734 ENDIF()
 735 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 736     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 737 ENDIF()
 738
 739 # Check OSS backend
 740 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 741 FIND_PACKAGE(OSS)
 742 IF(OSS_FOUND)
 743     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 744     IF(ALSOFT_BACKEND_OSS)
 745         SET(HAVE_OSS 1)
 746         SET(BACKENDS  "${BACKENDS} OSS,")
 747         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 748         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 749             INCLUDE_DIRECTORIES(${OSS_INCLUDE_DIRS})
 750         ENDIF()
 751     ENDIF()
 752 ENDIF()
 753 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 754     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 755 ENDIF()
 756
 757 # Check Solaris backend
 758 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 759 FIND_PACKAGE(AudioIO)
 760 IF(AUDIOIO_FOUND)
 761     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 762     IF(ALSOFT_BACKEND_SOLARIS)
 763         SET(HAVE_SOLARIS 1)
 764         SET(BACKENDS  "${BACKENDS} Solaris,")
 765         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 766         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 767             INCLUDE_DIRECTORIES(${AUDIOIO_INCLUDE_DIRS})
 768         ENDIF()
 769     ENDIF()
 770 ENDIF()
 771 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 772     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 773 ENDIF()
 774
 775 # Check SndIO backend
 776 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 777 FIND_PACKAGE(SoundIO)
 778 IF(SOUNDIO_FOUND)
 779     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 780     IF(ALSOFT_BACKEND_SNDIO)
 781         SET(HAVE_SNDIO 1)
 782         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 783         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 784         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 785         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 786             INCLUDE_DIRECTORIES(${SOUNDIO_INCLUDE_DIRS})
 787         ENDIF()
 788     ENDIF()
 789 ENDIF()
 790 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 791     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 792 ENDIF()
 793
 794 # Check QSA backend
 795 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 796 FIND_PACKAGE(QSA)
 797 IF(QSA_FOUND)
 798     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 799     IF(ALSOFT_BACKEND_QSA)
 800         SET(HAVE_QSA 1)
 801         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 802         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 803         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 804         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 805             INCLUDE_DIRECTORIES(${QSA_INCLUDE_DIRS})
 806         ENDIF()
 807     ENDIF()
 808 ENDIF()
 809 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 810     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 811 ENDIF()
 812
 813 # Check DSound backend
 814 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 815 FIND_PACKAGE(DSound)
 816 IF(DSOUND_FOUND)
 817     OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 818     IF(ALSOFT_BACKEND_DSOUND)
 819         SET(HAVE_DSOUND 1)
 820         SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 821         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 822         ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 823         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 824             INCLUDE_DIRECTORIES(${DSOUND_INCLUDE_DIRS})
 825         ENDIF()
 826     ENDIF()
 827 ENDIF()
 828 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 829     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 830 ENDIF()
 831
 832 # Check for MMDevApi backend
 833 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 834 IF(HAVE_WINDOWS_H)
 835     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 836     IF(HAVE_MMDEVICEAPI_H)
 837         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 838         IF(ALSOFT_BACKEND_MMDEVAPI)
 839             SET(HAVE_MMDEVAPI 1)
 840             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 841             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 842         ENDIF()
 843     ENDIF()
 844 ENDIF()
 845 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 846     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 847 ENDIF()
 848
 849 # Check MMSystem backend
 850 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 851 IF(HAVE_WINDOWS_H)
 852     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 853     IF(HAVE_MMSYSTEM_H)
 854         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 855         IF(HAVE_LIBWINMM)
 856             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 857             IF(ALSOFT_BACKEND_WINMM)
 858                 SET(HAVE_WINMM 1)
 859                 SET(BACKENDS  "${BACKENDS} WinMM,")
 860                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 861                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 862             ENDIF()
 863         ENDIF()
 864     ENDIF()
 865 ENDIF()
 866 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 867     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 868 ENDIF()
 869
 870 # Check PortAudio backend
 871 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 872 FIND_PACKAGE(PortAudio)
 873 IF(PORTAUDIO_FOUND)
 874     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 875     IF(ALSOFT_BACKEND_PORTAUDIO)
 876         SET(HAVE_PORTAUDIO 1)
 877         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
 878         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 879         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
 880         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 881             INCLUDE_DIRECTORIES(${PORTAUDIO_INCLUDE_DIRS})
 882         ENDIF()
 883     ENDIF()
 884 ENDIF()
 885 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 886     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 887 ENDIF()
 888
 889 # Check PulseAudio backend
 890 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
 891 FIND_PACKAGE(PulseAudio)
 892 IF(PULSEAUDIO_FOUND)
 893     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
 894     IF(ALSOFT_BACKEND_PULSEAUDIO)
 895         SET(HAVE_PULSEAUDIO 1)
 896         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
 897         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 898         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
 899         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 900             INCLUDE_DIRECTORIES(${PULSEAUDIO_INCLUDE_DIRS})
 901         ENDIF()
 902     ENDIF()
 903 ENDIF()
 904 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 905     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 906 ENDIF()
 907
 908 # Check CoreAudio backend
 909 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
 910 FIND_LIBRARY(COREAUDIO_FRAMEWORK
 911              NAMES CoreAudio
 912              PATHS /System/Library/Frameworks
 913 )
 914 IF(COREAUDIO_FRAMEWORK)
 915     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
 916     IF(ALSOFT_BACKEND_COREAUDIO)
 917         SET(HAVE_COREAUDIO 1)
 918         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 919         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 920         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
 921         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 922         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 923
 924         # Some versions of OSX may need the AudioToolbox framework. Add it if
 925         # it's found.
 926         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 927                      NAMES AudioToolbox
 928                      PATHS ~/Library/Frameworks
 929                            /Library/Frameworks
 930                            /System/Library/Frameworks
 931                     )
 932         IF(AUDIOTOOLBOX_LIBRARY)
 933             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 934         ENDIF()
 935     ENDIF()
 936 ENDIF()
 937 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 938     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 939 ENDIF()
 940
 941 # Check for OpenSL (Android) backend
 942 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
 943 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 944 IF(HAVE_SLES_OPENSLES_ANDROID_H)
 945     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 946     IF(HAVE_LIBOPENSLES)
 947         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
 948         IF(ALSOFT_BACKEND_OPENSL)
 949             SET(HAVE_OPENSL 1)
 950             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 951             SET(BACKENDS  "${BACKENDS} OpenSL,")
 952             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 953         ENDIF()
 954     ENDIF()
 955 ENDIF()
 956 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 957     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 958 ENDIF()
 959
 960 # Optionally enable the Wave Writer backend
 961 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
 962 IF(ALSOFT_BACKEND_WAVE)
 963     SET(HAVE_WAVE 1)
 964     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 965     SET(BACKENDS  "${BACKENDS} WaveFile,")
 966 ENDIF()
 967
 968 # This is always available
 969 SET(BACKENDS  "${BACKENDS} Null")
 970
 971 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 972     add_subdirectory(utils/alsoft-config)
 973 ENDIF()
 974 IF(ALSOFT_EXAMPLES)
 975     FIND_PACKAGE(SDL2)
 976     IF(SDL2_FOUND)
 977         FIND_PACKAGE(SDL_sound)
 978         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 979             INCLUDE_DIRECTORIES(${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 980         ENDIF()
 981         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
 982         IF(FFMPEG_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 983             INCLUDE_DIRECTORIES(${FFMPEG_INCLUDE_DIRS})
 984         ENDIF()
 985     ENDIF()
 986 ENDIF()
 987
 988 IF(LIBTYPE STREQUAL "STATIC")
 989     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 990     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 991 ENDIF()
 992
 993 # Needed for openal.pc.in
 994 SET(prefix ${CMAKE_INSTALL_PREFIX})
 995 SET(exec_prefix "\${prefix}")
 996 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 997 SET(bindir "\${exec_prefix}/bin")
 998 SET(includedir "\${prefix}/include")
 999 SET(PACKAGE_VERSION "${LIB_VERSION}")
1000
1001 # End configuration
1002 CONFIGURE_FILE(
1003     "${OpenAL_SOURCE_DIR}/config.h.in"
1004     "${OpenAL_BINARY_DIR}/config.h")
1005 CONFIGURE_FILE(
1006     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1007     "${OpenAL_BINARY_DIR}/openal.pc"
1008     @ONLY)
1009
1010 # Build a common library with reusable helpers
1011 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
1012
1013 # Build main library
1014 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
1015 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
1016 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1017     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
1018 ENDIF()
1019 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
1020 IF(FLUIDSYNTH_FOUND)
1021     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${FLUIDSYNTH_INCLUDE_DIR})
1022 ENDIF()
1023 IF(HAVE_ALSA)
1024     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIRS})
1025 ENDIF()
1026 IF(HAVE_OSS)
1027     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${OSS_INCLUDE_DIRS})
1028 ENDIF()
1029 IF(HAVE_SOLARIS)
1030     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${AUDIOIO_INCLUDE_DIRS})
1031 ENDIF()
1032 IF(HAVE_SNDIO)
1033     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${SOUNDIO_INCLUDE_DIRS})
1034 ENDIF()
1035 IF(HAVE_QSA)
1036     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${QSA_INCLUDE_DIRS})
1037 ENDIF()
1038 IF(HAVE_DSOUND)
1039     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${DSOUND_INCLUDE_DIRS})
1040 ENDIF()
1041 IF(HAVE_PORTAUDIO)
1042     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PORTAUDIO_INCLUDE_DIRS})
1043 ENDIF()
1044 IF(HAVE_PULSEAUDIO)
1045     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PULSEAUDIO_INCLUDE_DIRS})
1046 ENDIF()
1047 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
1048                                             SOVERSION ${LIB_MAJOR_VERSION})
1049 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
1050     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
1051
1052     IF(MINGW AND ALSOFT_BUILD_IMPORT_LIB)
1053         FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1054         FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1055         IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1056             MESSAGE(STATUS "")
1057             IF(NOT SED_EXECUTABLE)
1058                 MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1059             ENDIF()
1060             IF(NOT DLLTOOL_EXECUTABLE)
1061                 MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1062             ENDIF()
1063         ELSE()
1064             SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES LINK_FLAGS "-Wl,--output-def,${LIBNAME}.def")
1065             ADD_CUSTOM_COMMAND(TARGET ${LIBNAME} POST_BUILD
1066                 COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" ${LIBNAME}.def
1067                 COMMAND "${DLLTOOL_EXECUTABLE}" -d ${LIBNAME}.def -l ${LIBNAME}.lib -D ${LIBNAME}.dll
1068                 COMMENT "Stripping ordinals from ${LIBNAME}.def and generating ${LIBNAME}.lib..."
1069                 VERBATIM
1070             )
1071         ENDIF()
1072     ENDIF()
1073 ENDIF()
1074
1075 TARGET_LINK_LIBRARIES(${LIBNAME} common ${EXTRA_LIBS})
1076
1077 # Add an install target here
1078 INSTALL(TARGETS ${LIBNAME}
1079         RUNTIME DESTINATION bin
1080         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1081         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1082 )
1083 INSTALL(FILES include/AL/al.h
1084               include/AL/alc.h
1085               include/AL/alext.h
1086               include/AL/efx.h
1087               include/AL/efx-creative.h
1088               include/AL/efx-presets.h
1089         DESTINATION include/AL
1090 )
1091 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1092         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
1093
1094
1095 MESSAGE(STATUS "")
1096 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1097 MESSAGE(STATUS "    ${BACKENDS}")
1098 MESSAGE(STATUS "")
1099 MESSAGE(STATUS "Building with support for CPU extensions:")
1100 MESSAGE(STATUS "    ${CPU_EXTS}")
1101 MESSAGE(STATUS "")
1102 IF(HAVE_FLUIDSYNTH)
1103     MESSAGE(STATUS "FluidSynth support for ALC_SOFT_midi_interface enabled")
1104     MESSAGE(STATUS "")
1105 ENDIF()
1106
1107 IF(WIN32)
1108     IF(NOT HAVE_DSOUND)
1109         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1110         MESSAGE(STATUS "         This is probably NOT what you want!")
1111         MESSAGE(STATUS "")
1112     ENDIF()
1113 ENDIF()
1114
1115 # Install alsoft.conf configuration file
1116 IF(ALSOFT_CONFIG)
1117     INSTALL(FILES alsoftrc.sample
1118             DESTINATION share/openal
1119     )
1120     MESSAGE(STATUS "Installing sample configuration")
1121     MESSAGE(STATUS "")
1122 ENDIF()
1123
1124 # Install HRTF definitions
1125 IF(ALSOFT_HRTF_DEFS)
1126     INSTALL(FILES hrtf/default-44100.mhr
1127                   hrtf/default-48000.mhr
1128             DESTINATION share/openal/hrtf
1129     )
1130     MESSAGE(STATUS "Installing HRTF definitions")
1131     MESSAGE(STATUS "")
1132 ENDIF()
1133
1134 IF(ALSOFT_UTILS)
1135     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1136     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
1137
1138     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1139     IF(HAVE_LIBM)
1140         TARGET_LINK_LIBRARIES(makehrtf m)
1141     ENDIF()
1142
1143     INSTALL(TARGETS openal-info makehrtf
1144             RUNTIME DESTINATION bin
1145             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1146             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1147     )
1148
1149     MESSAGE(STATUS "Building utility programs")
1150     IF(TARGET alsoft-config)
1151         MESSAGE(STATUS "Building configuration program")
1152     ENDIF()
1153     MESSAGE(STATUS "")
1154 ENDIF()
1155
1156 IF(ALSOFT_EXAMPLES)
1157     IF(SDL2_FOUND AND SDL_SOUND_FOUND)
1158         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
1159                                      examples/common/sdl_sound.c)
1160         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1161                                                                           ${SDL_SOUND_INCLUDE_DIR})
1162
1163         ADD_EXECUTABLE(alstream examples/alstream.c)
1164         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ${LIBNAME})
1165         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1166                                                                          ${SDL_SOUND_INCLUDE_DIR})
1167
1168         ADD_EXECUTABLE(alreverb examples/alreverb.c)
1169         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ${LIBNAME})
1170         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1171                                                                          ${SDL_SOUND_INCLUDE_DIR})
1172
1173         ADD_EXECUTABLE(allatency examples/allatency.c)
1174         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ${LIBNAME})
1175         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1176                                                                           ${SDL_SOUND_INCLUDE_DIR})
1177
1178         ADD_EXECUTABLE(alloopback examples/alloopback.c)
1179         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ${LIBNAME})
1180         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1181                                                                            ${SDL_SOUND_INCLUDE_DIR})
1182
1183         INSTALL(TARGETS alstream alreverb allatency alloopback
1184                 RUNTIME DESTINATION bin
1185                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1186                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1187         )
1188
1189         SET(FFVER_OK FALSE)
1190         IF(FFMPEG_FOUND)
1191             SET(FFVER_OK TRUE)
1192             IF(AVFORMAT_VERSION VERSION_LESS "55.33.100")
1193                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 55.33.100)")
1194                 SET(FFVER_OK FALSE)
1195             ENDIF()
1196             IF(AVCODEC_VERSION VERSION_LESS "55.52.102")
1197                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 55.52.102)")
1198                 SET(FFVER_OK FALSE)
1199             ENDIF()
1200             IF(AVUTIL_VERSION VERSION_LESS "52.66.100")
1201                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 52.66.100)")
1202                 SET(FFVER_OK FALSE)
1203             ENDIF()
1204             IF(SWSCALE_VERSION VERSION_LESS "2.5.102")
1205                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 2.5.102)")
1206                 SET(FFVER_OK FALSE)
1207             ENDIF()
1208             IF(SWRESAMPLE_VERSION VERSION_LESS "0.18.100")
1209                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 0.18.100)")
1210                 SET(FFVER_OK FALSE)
1211             ENDIF()
1212         ENDIF()
1213         IF(FFVER_OK AND NOT MSVC)
1214             ADD_EXECUTABLE(alffplay examples/alffplay.c)
1215             TARGET_LINK_LIBRARIES(alffplay common ex-common ${SDL2_LIBRARY} ${LIBNAME} ${FFMPEG_LIBRARIES})
1216             SET_PROPERTY(TARGET alffplay APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1217                                                                              ${FFMPEG_INCLUDE_DIRS})
1218
1219             INSTALL(TARGETS alffplay
1220                     RUNTIME DESTINATION bin
1221                     LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1222                     ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1223             )
1224             MESSAGE(STATUS "Building SDL and FFmpeg example programs")
1225         ELSE()
1226             MESSAGE(STATUS "Building SDL example programs")
1227         ENDIF()
1228         MESSAGE(STATUS "")
1229     ENDIF()
1230 ENDIF()