CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 OPTION(ALSOFT_CPUEXT_SSE  "Check for SSE/SSE2 support" ON)
  29 OPTION(ALSOFT_CPUEXT_NEON "Check for ARM Neon support" ON)
  30
  31 OPTION(ALSOFT_REQUIRE_SSE  "Require SSE/SSE2 support" OFF)
  32 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
  33
  34 IF(WIN32)
  35     # This option is mainly for static linking OpenAL Soft into another project
  36     # that already defines the IDs. It is up to that project to ensure all
  37     # required IDs are defined.
  38     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  39 ENDIF()
  40
  41
  42 OPTION(ALSOFT_BACKEND_ALSA    "Check for ALSA backend"                ON)
  43 OPTION(ALSOFT_BACKEND_OSS     "Check for OSS backend"                 ON)
  44 OPTION(ALSOFT_BACKEND_SOLARIS "Check for Solaris backend"             ON)
  45 OPTION(ALSOFT_BACKEND_SNDIO   "Check for SndIO backend"               ON)
  46 OPTION(ALSOFT_BACKEND_QSA     "Check for QSA backend"                 ON)
  47 OPTION(ALSOFT_BACKEND_MMDEVAPI "Check for MMDevApi backend"           ON)
  48 OPTION(ALSOFT_BACKEND_DSOUND   "Check for DirectSound backend"        ON)
  49 OPTION(ALSOFT_BACKEND_WINMM    "Check for Windows Multimedia backend" ON)
  50 OPTION(ALSOFT_BACKEND_PORTAUDIO  "Check for PortAudio backend"        ON)
  51 OPTION(ALSOFT_BACKEND_PULSEAUDIO "Check for PulseAudio backend"       ON)
  52 OPTION(ALSOFT_BACKEND_COREAUDIO  "Check for CoreAudio backend"        ON)
  53 OPTION(ALSOFT_BACKEND_OPENSL     "Check for OpenSL backend"           ON)
  54 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend"               ON)
  55
  56 OPTION(ALSOFT_MIDI_FLUIDSYNTH "Check for FluidSynth MIDI"             ON)
  57
  58 OPTION(ALSOFT_REQUIRE_ALSA       "Require ALSA backend"               OFF)
  59 OPTION(ALSOFT_REQUIRE_OSS        "Require OSS backend"                OFF)
  60 OPTION(ALSOFT_REQUIRE_SOLARIS    "Require Solaris backend"            OFF)
  61 OPTION(ALSOFT_REQUIRE_SNDIO      "Require SndIO backend"              OFF)
  62 OPTION(ALSOFT_REQUIRE_QSA        "Require QSA backend"                OFF)
  63 OPTION(ALSOFT_REQUIRE_MMDEVAPI   "Require MMDevApi"                   OFF)
  64 OPTION(ALSOFT_REQUIRE_DSOUND     "Require DirectSound backend"        OFF)
  65 OPTION(ALSOFT_REQUIRE_WINMM      "Require Windows Multimedia backend" OFF)
  66 OPTION(ALSOFT_REQUIRE_PORTAUDIO  "Require PortAudio backend"          OFF)
  67 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend"         OFF)
  68 OPTION(ALSOFT_REQUIRE_COREAUDIO  "Require CoreAudio backend"          OFF)
  69 OPTION(ALSOFT_REQUIRE_OPENSL     "Require OpenSL backend"             OFF)
  70
  71 OPTION(ALSOFT_REQUIRE_FLUIDSYNTH "Require FluidSynth MIDI"            OFF)
  72
  73 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  74
  75 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  76
  77 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  78 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  79
  80 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  81
  82 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  83
  84
  85 IF(WIN32)
  86     SET(LIBNAME OpenAL32)
  87     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0501")
  88 ELSE()
  89     SET(LIBNAME openal)
  90 ENDIF()
  91
  92 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  93 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  94     ADD_DEFINITIONS("-I/usr/include")
  95     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  96 ENDIF()
  97
  98 IF(NOT LIBTYPE)
  99     SET(LIBTYPE SHARED)
 100 ENDIF()
 101
 102 SET(LIB_MAJOR_VERSION "1")
 103 SET(LIB_MINOR_VERSION "15")
 104 SET(LIB_REVISION "1")
 105 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 106
 107 SET(EXPORT_DECL "")
 108 SET(ALIGN_DECL "")
 109
 110
 111 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 112 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 113
 114
 115 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 116 IF(HAVE_STD_C99)
 117     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 118 ENDIF()
 119
 120 # MSVC may need workarounds for C99 restrict and inline
 121 IF(MSVC)
 122     # TODO: Once we truly require C99, these restrict and inline checks should go
 123     # away.
 124     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 125                              int main() {return 0;}" HAVE_RESTRICT)
 126     IF(NOT HAVE_RESTRICT)
 127         # Slightly convoluted way to do this, because MSVC may barf if restrict is
 128         # defined to __restrict.
 129         CHECK_C_SOURCE_COMPILES("#define restrict __restrict
 130                                  #include <stdlib.h>
 131                                  int *restrict foo;
 132                                  int main() {return 0;}" HAVE___RESTRICT)
 133         IF(HAVE___RESTRICT)
 134             ADD_DEFINITIONS(-Drestrict=__restrict)
 135             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=__restrict")
 136         ELSE()
 137             ADD_DEFINITIONS("-Drestrict=")
 138             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 139         ENDIF()
 140     ENDIF()
 141
 142     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 143                              int main() {return 0;}" HAVE_INLINE)
 144     IF(NOT HAVE_INLINE)
 145         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 146                                  int main() {return 0;}" HAVE___INLINE)
 147         IF(NOT HAVE___INLINE)
 148             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 149         ENDIF()
 150
 151         ADD_DEFINITIONS(-Dinline=__inline)
 152         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 153     ENDIF()
 154 ENDIF()
 155
 156 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 157 IF(CMAKE_COMPILER_IS_GNUCC)
 158     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 159     # Force no inlining for the next test.
 160     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 161
 162     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 163                              int main() {return foo();}" INLINE_IS_C99)
 164     IF(NOT INLINE_IS_C99)
 165         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 166                              Please update your compiler for better C99 compliance.")
 167     ENDIF()
 168
 169     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 170 ENDIF()
 171
 172 # Add definitions, compiler switches, etc.
 173 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 174 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 175     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 176     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 177         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 178     ENDIF()
 179 ENDIF()
 180
 181 IF(NOT CMAKE_BUILD_TYPE)
 182     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 183         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 184         FORCE)
 185 ENDIF()
 186 IF(NOT CMAKE_DEBUG_POSTFIX)
 187     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 188         "Library postfix for debug builds. Normally left blank."
 189         FORCE)
 190 ENDIF()
 191
 192 IF(MSVC)
 193     # ???
 194     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 195     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 196     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 197     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 198     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 199     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 200     ADD_DEFINITIONS("/wd4098")
 201
 202     IF(NOT DXSDK_DIR)
 203         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 204     ELSE()
 205         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 206     ENDIF()
 207     IF(DXSDK_DIR)
 208         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 209         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 210         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 211         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 212     ENDIF()
 213
 214     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 215     IF(FORCE_STATIC_VCRT)
 216         FOREACH(flag_var
 217                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 218                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 219             IF(${flag_var} MATCHES "/MD")
 220                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 221             ENDIF()
 222         ENDFOREACH(flag_var)
 223     ENDIF()
 224 ELSE()
 225     ADD_DEFINITIONS(-Winline -Wall)
 226     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 227     IF(HAVE_W_EXTRA)
 228         ADD_DEFINITIONS(-Wextra)
 229     ENDIF()
 230
 231     IF(ALSOFT_WERROR)
 232         ADD_DEFINITIONS(-Werror)
 233     ENDIF()
 234
 235     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 236         "Flags used by the compiler during Release with Debug Info builds."
 237         FORCE)
 238     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 239         "Flags used by the compiler during release minsize builds."
 240         FORCE)
 241     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 242         "Flags used by the compiler during release builds"
 243         FORCE)
 244     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 245         "Flags used by the compiler during debug builds."
 246         FORCE)
 247
 248     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 249                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 250 ENDIF()
 251
 252 # Set visibility/export options if available
 253 IF(WIN32)
 254     SET(EXPORT_DECL "__declspec(dllexport)")
 255     IF(NOT MINGW)
 256         SET(ALIGN_DECL "__declspec(align(x))")
 257     ELSE()
 258         SET(ALIGN_DECL "__declspec(aligned(x))")
 259     ENDIF()
 260 ELSE()
 261     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 262     # Yes GCC, really don't accept visibility modes you don't support
 263     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 264
 265     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 266                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 267     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 268         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 269     ELSE()
 270         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 271                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 272         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 273             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 274         ENDIF()
 275     ENDIF()
 276
 277     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 278         CHECK_C_COMPILER_FLAG(-fvisibility=internal HAVE_VISIBILITY_INTERNAL_SWITCH)
 279         IF(HAVE_VISIBILITY_INTERNAL_SWITCH)
 280             ADD_DEFINITIONS(-fvisibility=internal)
 281         ELSE()
 282             CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 283             IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 284                 ADD_DEFINITIONS(-fvisibility=hidden)
 285             ENDIF()
 286         ENDIF()
 287     ENDIF()
 288
 289     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 290                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 291     IF(HAVE_ATTRIBUTE_ALIGNED)
 292         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 293     ENDIF()
 294
 295     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 296 ENDIF()
 297
 298 SET(SSE_SWITCH "")
 299 IF(MSVC)
 300     CHECK_C_COMPILER_FLAG(/arch:SSE HAVE_ARCHSSE_SWITCH)
 301     IF(HAVE_ARCHSSE_SWITCH)
 302         SET(SSE_SWITCH "/arch:SSE")
 303     ENDIF()
 304 ENDIF()
 305 IF(NOT SSE_SWITCH)
 306     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 307     IF(HAVE_MSSE_SWITCH)
 308         SET(SSE_SWITCH "-msse")
 309     ENDIF()
 310 ENDIF()
 311
 312 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 313                          int main() {return 0;}" HAVE_GCC_FORMAT)
 314
 315 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 316 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 317 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 318 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 319 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 320 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 321 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 322 IF(NOT HAVE_GUIDDEF_H)
 323     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 324 ENDIF()
 325
 326 # Some systems need libm for some of the following math functions to work
 327 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 328 IF(HAVE_LIBM)
 329     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 330     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 331 ENDIF()
 332
 333
 334 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 335 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 336 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 337 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 338
 339 IF(HAVE_FLOAT_H)
 340     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 341     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 342 ENDIF()
 343
 344 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 345 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 346 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 347 IF(NOT HAVE_STRCASECMP)
 348     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 349     IF(NOT HAVE__STRICMP)
 350         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 351     ENDIF()
 352
 353     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 354 ENDIF()
 355
 356 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 357 IF(NOT HAVE_STRNCASECMP)
 358     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 359     IF(NOT HAVE__STRNICMP)
 360         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 361     ENDIF()
 362
 363     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 364 ENDIF()
 365
 366 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 367 IF(NOT HAVE_SNPRINTF)
 368     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 369     IF(NOT HAVE__SNPRINTF)
 370         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 371     ENDIF()
 372
 373     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 374 ENDIF()
 375
 376 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 377 IF(NOT HAVE_ISFINITE)
 378     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 379     IF(NOT HAVE_FINITE)
 380         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 381         IF(NOT HAVE__FINITE)
 382             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 383         ENDIF()
 384         ADD_DEFINITIONS(-Disfinite=_finite)
 385     ELSE()
 386         ADD_DEFINITIONS(-Disfinite=finite)
 387     ENDIF()
 388 ENDIF()
 389
 390 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 391 IF(NOT HAVE_ISNAN)
 392     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 393     IF(NOT HAVE__ISNAN)
 394         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 395     ENDIF()
 396
 397     ADD_DEFINITIONS(-Disnan=_isnan)
 398 ENDIF()
 399
 400
 401 # Check for the dlopen API (for dynamicly loading backend libs)
 402 IF(ALSOFT_DLOPEN)
 403     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 404     IF(HAVE_DLFCN_H)
 405         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 406         IF(HAVE_LIBDL)
 407             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 408         ENDIF()
 409     ENDIF()
 410 ENDIF()
 411
 412 # Check if we have Windows headers
 413 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0501)
 414 IF(NOT HAVE_WINDOWS_H)
 415     # These are needed on some systems for extra features
 416     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
 417     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
 418
 419     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 420     IF(NOT HAVE_GETTIMEOFDAY)
 421         MESSAGE(FATAL_ERROR "No timing function found!")
 422     ENDIF()
 423
 424     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 425     IF(NOT HAVE_NANOSLEEP)
 426         MESSAGE(FATAL_ERROR "No sleep function found!")
 427     ENDIF()
 428
 429     # We need pthreads outside of Windows
 430     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 431     IF(NOT HAVE_PTHREAD_H)
 432         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 433     ENDIF()
 434     # Some systems need pthread_np.h to get recursive mutexes
 435     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 436
 437     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 438     IF(HAVE_PTHREAD)
 439         ADD_DEFINITIONS(-pthread)
 440         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 441         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 442     ENDIF()
 443
 444     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 445     IF(HAVE_LIBPTHREAD)
 446         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 447     ENDIF()
 448
 449     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 450
 451     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 452     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 453         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 454     ENDIF()
 455
 456     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 457     IF(HAVE_LIBRT)
 458         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 459     ENDIF()
 460 ENDIF()
 461
 462 # Check for a 64-bit type
 463 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 464 IF(NOT HAVE_STDINT_H)
 465     IF(HAVE_WINDOWS_H)
 466         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0501
 467                                  #include <windows.h>
 468                                  __int64 foo;
 469                                  int main() {return 0;}" HAVE___INT64)
 470     ENDIF()
 471     IF(NOT HAVE___INT64)
 472         IF(NOT SIZEOF_LONG MATCHES "8")
 473             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 474                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 475             ENDIF()
 476         ENDIF()
 477     ENDIF()
 478 ENDIF()
 479
 480 # Windows needs winmm for timeGetTime, even if the backend is disabled
 481 CHECK_SHARED_FUNCTION_EXISTS(timeGetTime "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 482 IF(HAVE_LIBWINMM)
 483     SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 484     SET(PKG_CONFIG_LIBS ${PKG_CONFIG_LIBS} -lwinmm)
 485 ENDIF()
 486
 487
 488 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 489                  OpenAL32/alBuffer.c
 490                  OpenAL32/alEffect.c
 491                  OpenAL32/alError.c
 492                  OpenAL32/alExtension.c
 493                  OpenAL32/alFilter.c
 494                  OpenAL32/alFontsound.c
 495                  OpenAL32/alListener.c
 496                  OpenAL32/alMidi.c
 497                  OpenAL32/alPreset.c
 498                  OpenAL32/alSoundfont.c
 499                  OpenAL32/alSource.c
 500                  OpenAL32/alState.c
 501                  OpenAL32/alThunk.c
 502 )
 503 SET(ALC_OBJS  Alc/ALc.c
 504               Alc/ALu.c
 505               Alc/alcConfig.c
 506               Alc/alcRing.c
 507               Alc/bs2b.c
 508               Alc/effects/autowah.c
 509               Alc/effects/chorus.c
 510               Alc/effects/compressor.c
 511               Alc/effects/dedicated.c
 512               Alc/effects/distortion.c
 513               Alc/effects/echo.c
 514               Alc/effects/equalizer.c
 515               Alc/effects/flanger.c
 516               Alc/effects/modulator.c
 517               Alc/effects/null.c
 518               Alc/effects/reverb.c
 519               Alc/helpers.c
 520               Alc/hrtf.c
 521               Alc/panning.c
 522               Alc/threads.c
 523               Alc/mixer.c
 524               Alc/mixer_c.c
 525 )
 526
 527
 528 SET(CPU_EXTS "Default")
 529 SET(HAVE_SSE  0)
 530 SET(HAVE_NEON 0)
 531
 532 # Check for SSE support
 533 IF(ALSOFT_CPUEXT_SSE AND ALIGN_DECL)
 534     CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 535     IF(HAVE_XMMINTRIN_H)
 536         SET(HAVE_SSE 1)
 537         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 538         IF(SSE_SWITCH)
 539             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 540                                         COMPILE_FLAGS "${SSE_SWITCH}")
 541         ENDIF()
 542         SET(CPU_EXTS "${CPU_EXTS}, SSE")
 543     ENDIF()
 544 ENDIF()
 545 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 546     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 547 ENDIF()
 548
 549 # Check for ARM Neon support
 550 IF(ALSOFT_CPUEXT_NEON)
 551     CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 552     IF(HAVE_ARM_NEON_H)
 553         SET(HAVE_NEON 1)
 554         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 555         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 556     ENDIF()
 557 ENDIF()
 558 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 559     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 560 ENDIF()
 561
 562
 563 SET(ALC_OBJS  ${ALC_OBJS}
 564               Alc/midi/base.c
 565               Alc/midi/sf2load.c
 566               Alc/midi/dummy.c
 567               Alc/midi/fluidsynth.c
 568 )
 569
 570 SET(HAVE_FLUIDSYNTH  0)
 571
 572 # Check for FluidSynth support
 573 IF(ALSOFT_MIDI_FLUIDSYNTH)
 574     FIND_PACKAGE(FluidSynth)
 575     IF(FLUIDSYNTH_FOUND)
 576         SET(HAVE_FLUIDSYNTH 1)
 577         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 578             INCLUDE_DIRECTORIES(${FLUIDSYNTH_INCLUDE_DIR})
 579         ENDIF()
 580         SET(EXTRA_LIBS ${FLUIDSYNTH_LIBRARIES} ${EXTRA_LIBS})
 581     ENDIF()
 582 ENDIF()
 583 IF(ALSOFT_REQUIRE_FLUIDSYNTH AND NOT HAVE_FLUIDSYNTH)
 584     MESSAGE(FATAL_ERROR "Failed to enabled required FluidSynth support")
 585 ENDIF()
 586
 587
 588 SET(ALC_OBJS  ${ALC_OBJS}
 589               Alc/backends/base.c
 590               # Default backends, always available
 591               Alc/backends/loopback.c
 592               Alc/backends/null.c
 593 )
 594
 595 SET(BACKENDS "")
 596 SET(HAVE_ALSA       0)
 597 SET(HAVE_OSS        0)
 598 SET(HAVE_SOLARIS    0)
 599 SET(HAVE_SNDIO      0)
 600 SET(HAVE_QSA        0)
 601 SET(HAVE_DSOUND     0)
 602 SET(HAVE_MMDEVAPI   0)
 603 SET(HAVE_WINMM      0)
 604 SET(HAVE_PORTAUDIO  0)
 605 SET(HAVE_PULSEAUDIO 0)
 606 SET(HAVE_COREAUDIO  0)
 607 SET(HAVE_OPENSL     0)
 608 SET(HAVE_WAVE       0)
 609
 610 # Check ALSA backend
 611 IF(ALSOFT_BACKEND_ALSA)
 612     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 613     IF(HAVE_ALSA_ASOUNDLIB_H)
 614         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "alsa/asoundlib.h" asound "" HAVE_LIBASOUND)
 615         IF(HAVE_LIBASOUND OR HAVE_DLFCN_H OR WIN32)
 616             SET(HAVE_ALSA 1)
 617             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 618             IF(HAVE_DLFCN_H OR WIN32)
 619                 SET(BACKENDS  "${BACKENDS} ALSA,")
 620             ELSE()
 621                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 622                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 623             ENDIF()
 624         ENDIF()
 625     ENDIF()
 626 ENDIF()
 627 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 628     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 629 ENDIF()
 630
 631 # Check OSS backend
 632 IF(ALSOFT_BACKEND_OSS)
 633     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 634     IF(HAVE_SYS_SOUNDCARD_H)
 635         SET(HAVE_OSS 1)
 636         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 637         SET(BACKENDS  "${BACKENDS} OSS,")
 638     ENDIF()
 639 ENDIF()
 640 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 641     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 642 ENDIF()
 643
 644 # Check Solaris backend
 645 IF(ALSOFT_BACKEND_SOLARIS)
 646     CHECK_INCLUDE_FILE(sys/audioio.h HAVE_SYS_AUDIOIO_H)
 647     IF(HAVE_SYS_AUDIOIO_H)
 648         SET(HAVE_SOLARIS 1)
 649         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 650         SET(BACKENDS  "${BACKENDS} Solaris,")
 651     ENDIF()
 652 ENDIF()
 653 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 654     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 655 ENDIF()
 656
 657 # Check SndIO backend
 658 IF(ALSOFT_BACKEND_SNDIO)
 659     CHECK_INCLUDE_FILE(sndio.h HAVE_SNDIO_H)
 660     IF(HAVE_SNDIO_H)
 661         CHECK_SHARED_FUNCTION_EXISTS(sio_open "sndio.h" sndio "" HAVE_LIBSNDIO)
 662         IF(HAVE_LIBSNDIO)
 663             SET(HAVE_SNDIO 1)
 664             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 665             SET(BACKENDS  "${BACKENDS} SndIO \(linked\),")
 666             SET(EXTRA_LIBS sndio ${EXTRA_LIBS})
 667         ENDIF()
 668     ENDIF()
 669 ENDIF()
 670 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 671     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 672 ENDIF()
 673
 674 # Check QSA backend
 675 IF (ALSOFT_BACKEND_QSA AND "${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 676     CHECK_INCLUDE_FILE(sys/asoundlib.h HAVE_SYS_ASOUNDLIB_H)
 677     IF(HAVE_SYS_ASOUNDLIB_H)
 678         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "sys/asoundlib.h" asound "" HAVE_LIBASOUND)
 679         IF(HAVE_LIBASOUND)
 680             SET(HAVE_QSA 1)
 681             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 682             SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 683             SET(BACKENDS  "${BACKENDS} QSA \(linked\),")
 684         ENDIF()
 685     ENDIF()
 686 ENDIF()
 687 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 688     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 689 ENDIF()
 690
 691 # Check for MMDevApi backend
 692 IF(HAVE_WINDOWS_H)
 693     IF(ALSOFT_BACKEND_MMDEVAPI)
 694         CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 695         IF(HAVE_MMDEVICEAPI_H)
 696             SET(HAVE_MMDEVAPI 1)
 697             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 698
 699             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 700         ENDIF()
 701     ENDIF()
 702 ENDIF()
 703 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 704     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 705 ENDIF()
 706
 707 # Check DSound/MMSystem backend
 708 IF(ALSOFT_BACKEND_DSOUND)
 709     CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 710     IF(HAVE_DSOUND_H)
 711         CHECK_SHARED_FUNCTION_EXISTS(DirectSoundCreate "dsound.h" dsound "" HAVE_LIBDSOUND)
 712         IF(HAVE_LIBDSOUND OR HAVE_DLFCN_H OR WIN32)
 713             SET(HAVE_DSOUND 1)
 714             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 715
 716             IF(HAVE_DLFCN_H OR WIN32)
 717                 SET(BACKENDS  "${BACKENDS} DirectSound,")
 718             ELSE()
 719                 SET(BACKENDS  "${BACKENDS} DirectSound \(linked\),")
 720                 SET(EXTRA_LIBS dsound ${EXTRA_LIBS})
 721             ENDIF()
 722         ENDIF()
 723     ENDIF()
 724 ENDIF()
 725 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 726     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 727 ENDIF()
 728
 729 IF(HAVE_WINDOWS_H)
 730     IF(ALSOFT_BACKEND_WINMM)
 731         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0501)
 732         IF(HAVE_MMSYSTEM_H AND HAVE_LIBWINMM)
 733             SET(HAVE_WINMM 1)
 734             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 735             SET(BACKENDS  "${BACKENDS} WinMM,")
 736         ENDIF()
 737     ENDIF()
 738 ENDIF()
 739 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 740     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 741 ENDIF()
 742
 743 # Check PortAudio backend
 744 IF(ALSOFT_BACKEND_PORTAUDIO)
 745     CHECK_INCLUDE_FILE(portaudio.h HAVE_PORTAUDIO_H)
 746     IF(HAVE_PORTAUDIO_H)
 747         CHECK_SHARED_FUNCTION_EXISTS(Pa_Initialize "portaudio.h" portaudio "" HAVE_LIBPORTAUDIO)
 748         IF(HAVE_LIBPORTAUDIO OR HAVE_DLFCN_H OR WIN32)
 749             SET(HAVE_PORTAUDIO 1)
 750             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 751             IF(HAVE_DLFCN_H OR WIN32)
 752                 SET(BACKENDS  "${BACKENDS} PortAudio,")
 753             ELSE()
 754                 SET(BACKENDS  "${BACKENDS} PortAudio \(linked\),")
 755                 SET(EXTRA_LIBS portaudio ${EXTRA_LIBS})
 756             ENDIF()
 757         ENDIF()
 758     ENDIF()
 759 ENDIF()
 760 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 761     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 762 ENDIF()
 763
 764 # Check PulseAudio backend
 765 IF(ALSOFT_BACKEND_PULSEAUDIO)
 766     CHECK_INCLUDE_FILE(pulse/pulseaudio.h HAVE_PULSE_PULSEAUDIO_H)
 767     IF(HAVE_PULSE_PULSEAUDIO_H)
 768         CHECK_SHARED_FUNCTION_EXISTS(pa_context_new "pulse/pulseaudio.h" pulse "" HAVE_LIBPULSE)
 769         IF(HAVE_LIBPULSE OR HAVE_DLFCN_H OR WIN32)
 770             SET(HAVE_PULSEAUDIO 1)
 771             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 772             IF(HAVE_DLFCN_H OR WIN32)
 773                 SET(BACKENDS  "${BACKENDS} PulseAudio,")
 774             ELSE()
 775                 SET(BACKENDS  "${BACKENDS} PulseAudio \(linked\),")
 776                 SET(EXTRA_LIBS pulse ${EXTRA_LIBS})
 777             ENDIF()
 778         ENDIF()
 779     ENDIF()
 780 ENDIF()
 781 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 782     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 783 ENDIF()
 784
 785 # Check CoreAudio backend
 786 IF(ALSOFT_BACKEND_COREAUDIO)
 787     CHECK_INCLUDE_FILE(/System/Library/Frameworks/CoreAudio.framework/Headers/CoreAudio.h HAVE_COREAUDIO_FRAMEWORK)
 788     IF(HAVE_COREAUDIO_FRAMEWORK)
 789         SET(HAVE_COREAUDIO 1)
 790         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 791         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 792         SET(EXTRA_LIBS /System/Library/Frameworks/CoreAudio.framework ${EXTRA_LIBS})
 793         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 794         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 795
 796         # Some versions of OSX may need the AudioToolbox framework. Add it if
 797         # it's found.
 798         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 799                      NAMES AudioToolbox
 800                      PATHS ~/Library/Frameworks
 801                            /Library/Frameworks
 802                            /System/Library/Frameworks
 803                     )
 804         IF(AUDIOTOOLBOX_LIBRARY)
 805             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 806         ENDIF()
 807     ENDIF()
 808 ENDIF()
 809 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 810     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 811 ENDIF()
 812
 813 # Check for OpenSL (Android) backend
 814 IF(ALSOFT_BACKEND_OPENSL)
 815     CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 816     IF(HAVE_SLES_OPENSLES_ANDROID_H)
 817         CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 818         IF(HAVE_LIBOPENSLES)
 819             SET(HAVE_OPENSL 1)
 820             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 821             SET(BACKENDS  "${BACKENDS} OpenSL,")
 822             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 823         ENDIF()
 824     ENDIF()
 825 ENDIF()
 826 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 827     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 828 ENDIF()
 829
 830 # Optionally enable the Wave Writer backend
 831 IF(ALSOFT_BACKEND_WAVE)
 832     SET(HAVE_WAVE 1)
 833     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 834     SET(BACKENDS  "${BACKENDS} WaveFile,")
 835 ENDIF()
 836
 837 # This is always available
 838 SET(BACKENDS  "${BACKENDS} Null")
 839
 840 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 841     add_subdirectory(utils/alsoft-config)
 842 ENDIF()
 843 IF(ALSOFT_EXAMPLES)
 844     FIND_PACKAGE(SDL)
 845     IF(SDL_FOUND)
 846         FIND_PACKAGE(SDL_sound)
 847         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 848             INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 849         ENDIF()
 850     ENDIF()
 851 ENDIF()
 852
 853 IF(LIBTYPE STREQUAL "STATIC")
 854     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 855     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 856 ENDIF()
 857
 858 # Needed for openal.pc.in
 859 SET(prefix ${CMAKE_INSTALL_PREFIX})
 860 SET(exec_prefix "\${prefix}")
 861 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 862 SET(bindir "\${exec_prefix}/bin")
 863 SET(includedir "\${prefix}/include")
 864 SET(PACKAGE_VERSION "${LIB_VERSION}")
 865
 866 # End configuration
 867 CONFIGURE_FILE(
 868     "${OpenAL_SOURCE_DIR}/config.h.in"
 869     "${OpenAL_BINARY_DIR}/config.h")
 870 CONFIGURE_FILE(
 871     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 872     "${OpenAL_BINARY_DIR}/openal.pc"
 873     @ONLY)
 874
 875 # Build a library
 876 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 877 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
 878 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 879     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
 880 ENDIF()
 881 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 882 IF(FLUIDSYNTH_FOUND)
 883     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${FLUIDSYNTH_INCLUDE_DIR})
 884 ENDIF()
 885 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 886                                             SOVERSION ${LIB_MAJOR_VERSION})
 887 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
 888     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 889 ENDIF()
 890
 891 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 892
 893 # Add an install target here
 894 INSTALL(TARGETS ${LIBNAME}
 895         RUNTIME DESTINATION bin
 896         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 897         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 898 )
 899 INSTALL(FILES include/AL/al.h
 900               include/AL/alc.h
 901               include/AL/alext.h
 902               include/AL/efx.h
 903               include/AL/efx-creative.h
 904               include/AL/efx-presets.h
 905         DESTINATION include/AL
 906 )
 907 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 908         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
 909
 910
 911 MESSAGE(STATUS "")
 912 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 913 MESSAGE(STATUS "    ${BACKENDS}")
 914 MESSAGE(STATUS "")
 915 MESSAGE(STATUS "Building with support for CPU extensions:")
 916 MESSAGE(STATUS "    ${CPU_EXTS}")
 917 MESSAGE(STATUS "")
 918 IF(HAVE_FLUIDSYNTH)
 919     MESSAGE(STATUS "FluidSynth support for ALC_SOFT_midi_interface enabled")
 920     MESSAGE(STATUS "")
 921 ENDIF()
 922
 923 IF(WIN32)
 924     IF(NOT HAVE_DSOUND)
 925         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
 926         MESSAGE(STATUS "         This is probably NOT what you want!")
 927         MESSAGE(STATUS "")
 928     ENDIF()
 929 ENDIF()
 930
 931 # Install alsoft.conf configuration file
 932 IF(ALSOFT_CONFIG)
 933     INSTALL(FILES alsoftrc.sample
 934             DESTINATION share/openal
 935     )
 936     MESSAGE(STATUS "Installing sample configuration")
 937     MESSAGE(STATUS "")
 938 ENDIF()
 939
 940 IF(ALSOFT_UTILS)
 941     ADD_EXECUTABLE(openal-info utils/openal-info.c)
 942     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
 943
 944     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
 945     IF(HAVE_LIBM)
 946         TARGET_LINK_LIBRARIES(makehrtf m)
 947     ENDIF()
 948
 949     INSTALL(TARGETS openal-info makehrtf
 950             RUNTIME DESTINATION bin
 951             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 952             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 953     )
 954
 955     MESSAGE(STATUS "Building utility programs")
 956     IF(TARGET alsoft-config)
 957         MESSAGE(STATUS "Building configuration program")
 958     ENDIF()
 959     MESSAGE(STATUS "")
 960 ENDIF()
 961
 962 IF(ALSOFT_EXAMPLES)
 963     IF(SDL_FOUND AND SDL_SOUND_FOUND)
 964         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
 965                                      examples/common/sdl_sound.c)
 966         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 967
 968         ADD_EXECUTABLE(alstream examples/alstream.c)
 969         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 970         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 971
 972         ADD_EXECUTABLE(alreverb examples/alreverb.c)
 973         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 974         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 975
 976         ADD_EXECUTABLE(allatency examples/allatency.c)
 977         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 978         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 979
 980         ADD_EXECUTABLE(alloopback examples/alloopback.c)
 981         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL_LIBRARY} ${LIBNAME})
 982         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_INCLUDE_DIR}
 983                                                                            ${SDL_SOUND_INCLUDE_DIR})
 984
 985         INSTALL(TARGETS alstream alreverb allatency alloopback
 986                 RUNTIME DESTINATION bin
 987                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 988                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 989         )
 990
 991         MESSAGE(STATUS "Building example programs")
 992         MESSAGE(STATUS "")
 993     ENDIF()
 994 ENDIF()