CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 INCLUDE(CheckFunctionExists)
   4 INCLUDE(CheckLibraryExists)
   5 INCLUDE(CheckIncludeFile)
   6 INCLUDE(CheckIncludeFiles)
   7 INCLUDE(CheckCCompilerFlag)
   8 INCLUDE(CheckCSourceCompiles)
   9 INCLUDE(CheckTypeSize)
  10
  11
  12 PROJECT(OpenAL)
  13
  14
  15 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  16
  17
  18 OPTION(ALSA    "ALSA backend"                ON)
  19 OPTION(OSS     "OSS backend"                 ON)
  20 OPTION(DSOUND  "DirectSound backend"         ON)
  21 OPTION(WINMM   "Windows Multimedia backend"  ON)
  22
  23 OPTION(DLOPEN  "Use the dlopen API for loading optional libs"  ON)
  24
  25 OPTION(DEBUG    "Build lib in debug mode"                   OFF)
  26 OPTION(NODEBUG  "Disable all debug info for optimizations"  OFF)
  27 OPTION(WERROR   "Treat compile warnings as errors"          OFF)
  28
  29
  30 SET(LIB_MAJOR_VERSION "1")
  31 SET(LIB_MINOR_VERSION "0")
  32 SET(LIB_BUILD_VERSION "38")
  33 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_BUILD_VERSION}")
  34
  35
  36 IF("${WIN32}")
  37     SET(LIBNAME openal32)
  38     SET(TARGET_OPTS "PREFIX \"\"")
  39 ELSE()
  40     SET(LIBNAME openal)
  41     SET(TARGET_OPTS "")
  42 ENDIF()
  43
  44
  45 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  46 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
  47 CHECK_TYPE_SIZE("unsigned int" SIZEOF_UINT)
  48 CHECK_TYPE_SIZE("void*" SIZEOF_VOIDP)
  49
  50
  51 # Add definitions, compiler switches, etc.
  52 INCLUDE_DIRECTORIES(OpenAL32/Include include "${OpenAL_BINARY_DIR}")
  53 SET(EXTRA_LIBS m ${EXTRA_LIBS})
  54
  55 IF("${MSVC}")
  56     # ???
  57 ELSE()
  58     ADD_DEFINITIONS(-Wall)
  59     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
  60     IF("${HAVE_W_EXTRA}")
  61         ADD_DEFINITIONS(-Wextra)
  62     ENDIF()
  63
  64     IF(WERROR)
  65         ADD_DEFINITIONS(-Werror)
  66     ENDIF()
  67
  68     IF(DEBUG)
  69         ADD_DEFINITIONS(-g3)
  70     ELSEIF(NODEBUG)
  71         ADD_DEFINITIONS(-O2 -funroll-loops -fomit-frame-pointer)
  72     ELSE()
  73         ADD_DEFINITIONS(-g -O2 -funroll-loops)
  74     ENDIF()
  75
  76     # The mixer doesn't like GCC's strict aliasing optimizations. Make sure
  77     # it's turned off
  78     CHECK_C_COMPILER_FLAG(-fstrict-aliasing HAVE_STRICT_ALIASING)
  79     IF("${HAVE_STRICT_ALIASING}")
  80         ADD_DEFINITIONS(-fno-strict-aliasing)
  81     ENDIF()
  82
  83     # Set visibility options if available
  84     IF(NOT "${WIN32}")
  85         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
  86                                  int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
  87
  88         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_SWITCH)
  89         IF("${HAVE_VISIBILITY_SWITCH}")
  90             CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
  91                                      int main() {return 0;}" HAVE_GCC_VISIBILITY)
  92             IF("${HAVE_GCC_VISIBILITY}")
  93                 ADD_DEFINITIONS(-fvisibility=hidden -DHAVE_GCC_VISIBILITY)
  94             ENDIF()
  95         ENDIF()
  96     ENDIF()
  97 ENDIF()
  98
  99 IF(DEBUG)
 100     ADD_DEFINITIONS(-D_DEBUG)
 101 ELSEIF(NODEBUG)
 102     ADD_DEFINITIONS(-DNDEBUG)
 103 ENDIF()
 104
 105 CHECK_LIBRARY_EXISTS(m  sqrtf  "" HAVE_SQRTF)
 106 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 107
 108 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 109 IF(NOT "${HAVE_STRCASECMP}")
 110     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 111     IF(NOT "${HAVE__STRICMP}")
 112         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 113     ENDIF()
 114
 115     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 116 ENDIF()
 117
 118 # Check for the dlopen API (for dynamicly loading backend libs)
 119 IF(DLOPEN)
 120     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 121     IF("${HAVE_DLFCN_H}")
 122         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 123         IF("${HAVE_LIBDL}")
 124             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 125         ENDIF()
 126     ENDIF()
 127 ENDIF()
 128
 129 # Check if we have Windows headers
 130 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H)
 131 IF(NOT "${HAVE_WINDOWS_H}")
 132     # We need pthreads outside of Windows
 133     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 134     IF(NOT "${HAVE_PTHREAD_H}")
 135         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 136     ENDIF()
 137
 138     # _GNU_SOURCE is needed on some systems for extra attributes, and
 139     # _REENTRANT is needed for libc thread-safety
 140     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_REENTRANT)
 141     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 142     IF("${HAVE_LIBPTHREAD}")
 143         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 144     ENDIF()
 145 ENDIF()
 146
 147 # Check for a 64-bit type
 148 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 149 IF(NOT "${HAVE_STDINT_H}")
 150     IF("${HAVE_WINDOWS_H}")
 151         CHECK_C_SOURCE_COMPILES("\#include <windows.h>
 152                                  __int64 foo;
 153                                  int main() {return 0;}" HAVE___INT64)
 154     ENDIF()
 155     IF(NOT "${HAVE___INT64}")
 156         IF(NOT "${SIZEOF_LONG}" MATCHES "8")
 157             IF(NOT "${SIZEOF_LONG_LONG}" MATCHES "8")
 158                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 159             ENDIF()
 160         ENDIF()
 161     ENDIF()
 162 ENDIF()
 163
 164
 165 SET(OPENAL_OBJS  OpenAL32/alBuffer.c
 166                  OpenAL32/alError.c
 167                  OpenAL32/alExtension.c
 168                  OpenAL32/alListener.c
 169                  OpenAL32/alSource.c
 170                  OpenAL32/alState.c
 171                  OpenAL32/alThunk.c
 172                  OpenAL32/OpenAL32.c
 173 )
 174 SET(ALC_OBJS  Alc/ALc.c
 175               Alc/ALu.c
 176               Alc/alcConfig.c
 177               Alc/alcRing.c
 178               Alc/alcThread.c
 179 )
 180
 181 SET(BACKENDS "")
 182
 183 # Check ALSA backend
 184 IF(ALSA)
 185     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 186     IF("${HAVE_ALSA_ASOUNDLIB_H}")
 187         CHECK_LIBRARY_EXISTS(asound snd_pcm_open "" HAVE_LIBASOUND)
 188         IF("${HAVE_DLFCN_H}" OR "${HAVE_LIBASOUND}")
 189             SET(HAVE_ALSA 1)
 190             SET(ALC_OBJS  ${ALC_OBJS} Alc/alsa.c)
 191             IF("${HAVE_DLFCN_H}")
 192                 SET(BACKENDS  ${BACKENDS} ALSA)
 193             ELSE()
 194                 SET(BACKENDS  ${BACKENDS} ALSA\(linked\))
 195                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 196             ENDIF()
 197         ENDIF()
 198     ENDIF()
 199 ENDIF()
 200
 201 # Check OSS backend
 202 IF(OSS)
 203     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 204     IF("${HAVE_SYS_SOUNDCARD_H}")
 205         SET(HAVE_OSS 1)
 206         SET(ALC_OBJS  ${ALC_OBJS} Alc/oss.c)
 207         SET(BACKENDS  ${BACKENDS} OSS)
 208     ENDIF()
 209 ENDIF()
 210
 211 # Check DSound/MMSystem backend
 212 IF("${HAVE_WINDOWS_H}")
 213     SET(CMAKE_REQUIRED_LIBRARIES ole32)
 214     CHECK_C_SOURCE_COMPILES("int main() {return 0;}" HAVE_LIBOLE32)
 215     SET(CMAKE_REQUIRED_LIBRARIES "")
 216 #    CHECK_LIBRARY_EXISTS(ole32 CoInitialize "" HAVE_LIBOLE32)
 217     IF("${HAVE_LIBOLE32}")
 218         SET(EXTRA_LIBS ole32 ${EXTRA_LIBS})
 219     ENDIF()
 220
 221     IF(DSOUND)
 222         CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 223         IF("${HAVE_DSOUND_H}")
 224             SET(HAVE_DSOUND 1)
 225             SET(ALC_OBJS  ${ALC_OBJS} Alc/dsound.c)
 226             SET(BACKENDS  ${BACKENDS} DirectSound)
 227
 228             CHECK_LIBRARY_EXISTS(dxguid IID_IDirectSound "" HAVE_LIBDXGUID)
 229             IF("${HAVE_LIBDXGUID}")
 230                 SET(EXTRA_LIBS dxguid ${EXTRA_LIBS})
 231             ENDIF()
 232         ENDIF()
 233     ENDIF()
 234     IF(WINMM)
 235         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H)
 236         IF("${HAVE_MMSYSTEM_H}")
 237             SET(HAVE_WINMM 1)
 238             SET(ALC_OBJS  ${ALC_OBJS} Alc/winmm.c)
 239             SET(BACKENDS  ${BACKENDS} WinMM)
 240
 241             SET(CMAKE_REQUIRED_LIBRARIES winmm)
 242             CHECK_C_SOURCE_COMPILES("int main() {return 0;}" HAVE_LIBWINMM)
 243             SET(CMAKE_REQUIRED_LIBRARIES "")
 244 #            CHECK_LIBRARY_EXISTS(winmm waveInOpen "" HAVE_LIBWINMM)
 245             IF("${HAVE_LIBWINMM}")
 246                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 247             ENDIF()
 248         ENDIF()
 249     ENDIF()
 250 ENDIF()
 251
 252 # End configuration
 253 CONFIGURE_FILE(
 254     "${OpenAL_SOURCE_DIR}/config.h.in"
 255     "${OpenAL_BINARY_DIR}/config.h")
 256
 257 ADD_DEFINITIONS(-DAL_BUILD_LIBRARY)
 258
 259 # Build a shared library
 260 ADD_LIBRARY(${LIBNAME} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
 261 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 262                                             SOVERSION ${LIB_MAJOR_VERSION}
 263                                             ${TARGET_OPTS})
 264
 265 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 266
 267 # Add an install target here
 268 INSTALL(TARGETS ${LIBNAME}
 269         RUNTIME DESTINATION bin
 270         LIBRARY DESTINATION lib
 271         ARCHIVE DESTINATION lib
 272 )
 273 INSTALL(FILES include/AL/al.h
 274               include/AL/alc.h
 275         DESTINATION include/AL
 276 )
 277
 278 MESSAGE(STATUS "")
 279 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 280 MESSAGE(STATUS "    ${BACKENDS}")
 281 MESSAGE(STATUS "")