CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 OPTION(ALSOFT_CPUEXT_SSE  "Check for SSE/SSE2 support" ON)
  29 OPTION(ALSOFT_CPUEXT_NEON "Check for ARM Neon support" ON)
  30
  31 OPTION(ALSOFT_REQUIRE_SSE  "Require SSE/SSE2 support" OFF)
  32 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
  33
  34 IF(WIN32)
  35     # This option is mainly for static linking OpenAL Soft into another project
  36     # that already defines the IDs. It is up to that project to ensure all
  37     # required IDs are defined.
  38     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  39 ENDIF()
  40
  41
  42 OPTION(ALSOFT_BACKEND_ALSA    "Check for ALSA backend"                ON)
  43 OPTION(ALSOFT_BACKEND_OSS     "Check for OSS backend"                 ON)
  44 OPTION(ALSOFT_BACKEND_SOLARIS "Check for Solaris backend"             ON)
  45 OPTION(ALSOFT_BACKEND_SNDIO   "Check for SndIO backend"               ON)
  46 OPTION(ALSOFT_BACKEND_QSA     "Check for QSA backend"                 ON)
  47 OPTION(ALSOFT_BACKEND_MMDEVAPI "Check for MMDevApi backend"           ON)
  48 OPTION(ALSOFT_BACKEND_DSOUND   "Check for DirectSound backend"        ON)
  49 OPTION(ALSOFT_BACKEND_WINMM    "Check for Windows Multimedia backend" ON)
  50 OPTION(ALSOFT_BACKEND_PORTAUDIO  "Check for PortAudio backend"        ON)
  51 OPTION(ALSOFT_BACKEND_PULSEAUDIO "Check for PulseAudio backend"       ON)
  52 OPTION(ALSOFT_BACKEND_COREAUDIO  "Check for CoreAudio backend"        ON)
  53 OPTION(ALSOFT_BACKEND_OPENSL     "Check for OpenSL backend"           ON)
  54 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend"               ON)
  55
  56 OPTION(ALSOFT_REQUIRE_ALSA       "Require ALSA backend"               OFF)
  57 OPTION(ALSOFT_REQUIRE_OSS        "Require OSS backend"                OFF)
  58 OPTION(ALSOFT_REQUIRE_SOLARIS    "Require Solaris backend"            OFF)
  59 OPTION(ALSOFT_REQUIRE_SNDIO      "Require SndIO backend"              OFF)
  60 OPTION(ALSOFT_REQUIRE_QSA        "Require QSA backend"                OFF)
  61 OPTION(ALSOFT_REQUIRE_MMDEVAPI   "Require MMDevApi"                   OFF)
  62 OPTION(ALSOFT_REQUIRE_DSOUND     "Require DirectSound backend"        OFF)
  63 OPTION(ALSOFT_REQUIRE_WINMM      "Require Windows Multimedia backend" OFF)
  64 OPTION(ALSOFT_REQUIRE_PORTAUDIO  "Require PortAudio backend"          OFF)
  65 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend"         OFF)
  66 OPTION(ALSOFT_REQUIRE_COREAUDIO  "Require CoreAudio backend"          OFF)
  67 OPTION(ALSOFT_REQUIRE_OPENSL     "Require OpenSL backend"             OFF)
  68
  69 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  70
  71 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  72
  73 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  74 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  75
  76 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  77
  78 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  79
  80
  81 IF(WIN32)
  82     SET(LIBNAME OpenAL32)
  83     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0501")
  84 ELSE()
  85     SET(LIBNAME openal)
  86 ENDIF()
  87
  88 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  89 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  90     ADD_DEFINITIONS("-I/usr/include")
  91     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  92 ENDIF()
  93
  94 IF(NOT LIBTYPE)
  95     SET(LIBTYPE SHARED)
  96 ENDIF()
  97
  98 SET(LIB_MAJOR_VERSION "1")
  99 SET(LIB_MINOR_VERSION "15")
 100 SET(LIB_REVISION "1")
 101 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 102
 103 SET(EXPORT_DECL "")
 104 SET(ALIGN_DECL "")
 105
 106
 107 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 108 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 109
 110
 111 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 112 IF(HAVE_STD_C99)
 113     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 114 ENDIF()
 115
 116 # MSVC may need workarounds for C99 restrict and inline
 117 IF(MSVC)
 118     # TODO: Once we truly require C99, these restrict and inline checks should go
 119     # away.
 120     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 121                              int main() {return 0;}" HAVE_RESTRICT)
 122     IF(NOT HAVE_RESTRICT)
 123         # Slightly convoluted way to do this, because MSVC may barf if restrict is
 124         # defined to __restrict.
 125         CHECK_C_SOURCE_COMPILES("#define restrict __restrict
 126                                  #include <stdlib.h>
 127                                  int *restrict foo;
 128                                  int main() {return 0;}" HAVE___RESTRICT)
 129         IF(HAVE___RESTRICT)
 130             ADD_DEFINITIONS(-Drestrict=__restrict)
 131             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=__restrict")
 132         ELSE()
 133             ADD_DEFINITIONS("-Drestrict=")
 134             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 135         ENDIF()
 136     ENDIF()
 137
 138     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 139                              int main() {return 0;}" HAVE_INLINE)
 140     IF(NOT HAVE_INLINE)
 141         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 142                                  int main() {return 0;}" HAVE___INLINE)
 143         IF(NOT HAVE___INLINE)
 144             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 145         ENDIF()
 146
 147         ADD_DEFINITIONS(-Dinline=__inline)
 148         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 149     ENDIF()
 150 ENDIF()
 151
 152 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 153 IF(CMAKE_COMPILER_IS_GNUCC)
 154     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 155     # Force no inlining for the next test.
 156     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 157
 158     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 159                              int main() {return foo();}" INLINE_IS_C99)
 160     IF(NOT INLINE_IS_C99)
 161         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 162                              Please update your compiler for better C99 compliance.")
 163     ENDIF()
 164
 165     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 166 ENDIF()
 167
 168 # Add definitions, compiler switches, etc.
 169 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 170 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 171     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 172     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 173         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 174     ENDIF()
 175 ENDIF()
 176
 177 IF(NOT CMAKE_BUILD_TYPE)
 178     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 179         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 180         FORCE)
 181 ENDIF()
 182 IF(NOT CMAKE_DEBUG_POSTFIX)
 183     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 184         "Library postfix for debug builds. Normally left blank."
 185         FORCE)
 186 ENDIF()
 187
 188 IF(MSVC)
 189     # ???
 190     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 191     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 192     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 193     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 194     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 195     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 196     ADD_DEFINITIONS("/wd4098")
 197
 198     IF(NOT DXSDK_DIR)
 199         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 200     ELSE()
 201         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 202     ENDIF()
 203     IF(DXSDK_DIR)
 204         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 205         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 206         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 207         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 208     ENDIF()
 209
 210     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 211     IF(FORCE_STATIC_VCRT)
 212         FOREACH(flag_var
 213                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 214                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 215             IF(${flag_var} MATCHES "/MD")
 216                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 217             ENDIF()
 218         ENDFOREACH(flag_var)
 219     ENDIF()
 220 ELSE()
 221     ADD_DEFINITIONS(-Winline -Wall)
 222     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 223     IF(HAVE_W_EXTRA)
 224         ADD_DEFINITIONS(-Wextra)
 225     ENDIF()
 226
 227     IF(ALSOFT_WERROR)
 228         ADD_DEFINITIONS(-Werror)
 229     ENDIF()
 230
 231     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 232         "Flags used by the compiler during Release with Debug Info builds."
 233         FORCE)
 234     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 235         "Flags used by the compiler during release minsize builds."
 236         FORCE)
 237     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 238         "Flags used by the compiler during release builds"
 239         FORCE)
 240     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 241         "Flags used by the compiler during debug builds."
 242         FORCE)
 243
 244     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 245                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 246 ENDIF()
 247
 248 # Set visibility/export options if available
 249 IF(WIN32)
 250     SET(EXPORT_DECL "__declspec(dllexport)")
 251     IF(NOT MINGW)
 252         SET(ALIGN_DECL "__declspec(align(x))")
 253     ELSE()
 254         SET(ALIGN_DECL "__declspec(aligned(x))")
 255     ENDIF()
 256 ELSE()
 257     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 258     # Yes GCC, really don't accept visibility modes you don't support
 259     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 260
 261     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 262                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 263     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 264         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 265     ELSE()
 266         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 267                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 268         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 269             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 270         ENDIF()
 271     ENDIF()
 272
 273     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 274         CHECK_C_COMPILER_FLAG(-fvisibility=internal HAVE_VISIBILITY_INTERNAL_SWITCH)
 275         IF(HAVE_VISIBILITY_INTERNAL_SWITCH)
 276             ADD_DEFINITIONS(-fvisibility=internal)
 277         ELSE()
 278             CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 279             IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 280                 ADD_DEFINITIONS(-fvisibility=hidden)
 281             ENDIF()
 282         ENDIF()
 283     ENDIF()
 284
 285     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 286                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 287     IF(HAVE_ATTRIBUTE_ALIGNED)
 288         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 289     ENDIF()
 290
 291     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 292 ENDIF()
 293
 294 SET(SSE_SWITCH "")
 295 IF(MSVC)
 296     CHECK_C_COMPILER_FLAG(/arch:SSE HAVE_ARCHSSE_SWITCH)
 297     IF(HAVE_ARCHSSE_SWITCH)
 298         SET(SSE_SWITCH "/arch:SSE")
 299     ENDIF()
 300 ENDIF()
 301 IF(NOT SSE_SWITCH)
 302     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 303     IF(HAVE_MSSE_SWITCH)
 304         SET(SSE_SWITCH "-msse")
 305     ENDIF()
 306 ENDIF()
 307
 308 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 309                          int main() {return 0;}" HAVE_GCC_FORMAT)
 310
 311 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 312 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 313 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 314 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 315 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 316 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 317 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 318 IF(NOT HAVE_GUIDDEF_H)
 319     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 320 ENDIF()
 321
 322 # Some systems need libm for some of the following math functions to work
 323 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 324 IF(HAVE_LIBM)
 325     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 326     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 327 ENDIF()
 328
 329
 330 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 331 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 332 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 333 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 334
 335 IF(HAVE_FLOAT_H)
 336     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 337     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 338 ENDIF()
 339
 340 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 341 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 342 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 343 IF(NOT HAVE_STRCASECMP)
 344     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 345     IF(NOT HAVE__STRICMP)
 346         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 347     ENDIF()
 348
 349     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 350 ENDIF()
 351
 352 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 353 IF(NOT HAVE_STRNCASECMP)
 354     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 355     IF(NOT HAVE__STRNICMP)
 356         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 357     ENDIF()
 358
 359     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 360 ENDIF()
 361
 362 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 363 IF(NOT HAVE_SNPRINTF)
 364     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 365     IF(NOT HAVE__SNPRINTF)
 366         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 367     ENDIF()
 368
 369     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 370 ENDIF()
 371
 372 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 373 IF(NOT HAVE_ISFINITE)
 374     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 375     IF(NOT HAVE_FINITE)
 376         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 377         IF(NOT HAVE__FINITE)
 378             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 379         ENDIF()
 380         ADD_DEFINITIONS(-Disfinite=_finite)
 381     ELSE()
 382         ADD_DEFINITIONS(-Disfinite=finite)
 383     ENDIF()
 384 ENDIF()
 385
 386 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 387 IF(NOT HAVE_ISNAN)
 388     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 389     IF(NOT HAVE__ISNAN)
 390         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 391     ENDIF()
 392
 393     ADD_DEFINITIONS(-Disnan=_isnan)
 394 ENDIF()
 395
 396
 397 # Check for the dlopen API (for dynamicly loading backend libs)
 398 IF(ALSOFT_DLOPEN)
 399     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 400     IF(HAVE_DLFCN_H)
 401         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 402         IF(HAVE_LIBDL)
 403             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 404         ENDIF()
 405     ENDIF()
 406 ENDIF()
 407
 408 # Check if we have Windows headers
 409 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0501)
 410 IF(NOT HAVE_WINDOWS_H)
 411     # These are needed on some systems for extra features
 412     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
 413     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
 414
 415     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 416     IF(NOT HAVE_GETTIMEOFDAY)
 417         MESSAGE(FATAL_ERROR "No timing function found!")
 418     ENDIF()
 419
 420     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 421     IF(NOT HAVE_NANOSLEEP)
 422         MESSAGE(FATAL_ERROR "No sleep function found!")
 423     ENDIF()
 424
 425     # We need pthreads outside of Windows
 426     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 427     IF(NOT HAVE_PTHREAD_H)
 428         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 429     ENDIF()
 430     # Some systems need pthread_np.h to get recursive mutexes
 431     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 432
 433     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 434     IF(HAVE_PTHREAD)
 435         ADD_DEFINITIONS(-pthread)
 436         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 437         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 438     ENDIF()
 439
 440     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 441     IF(HAVE_LIBPTHREAD)
 442         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 443     ENDIF()
 444
 445     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 446
 447     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 448     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 449         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 450     ENDIF()
 451
 452     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 453     IF(HAVE_LIBRT)
 454         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 455     ENDIF()
 456 ENDIF()
 457
 458 # Check for a 64-bit type
 459 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 460 IF(NOT HAVE_STDINT_H)
 461     IF(HAVE_WINDOWS_H)
 462         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0501
 463                                  #include <windows.h>
 464                                  __int64 foo;
 465                                  int main() {return 0;}" HAVE___INT64)
 466     ENDIF()
 467     IF(NOT HAVE___INT64)
 468         IF(NOT SIZEOF_LONG MATCHES "8")
 469             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 470                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 471             ENDIF()
 472         ENDIF()
 473     ENDIF()
 474 ENDIF()
 475
 476 # Windows needs winmm for timeGetTime, even if the backend is disabled
 477 CHECK_SHARED_FUNCTION_EXISTS(timeGetTime "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 478 IF(HAVE_LIBWINMM)
 479     SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 480     SET(PKG_CONFIG_LIBS ${PKG_CONFIG_LIBS} -lwinmm)
 481 ENDIF()
 482
 483
 484 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 485                  OpenAL32/alBuffer.c
 486                  OpenAL32/alEffect.c
 487                  OpenAL32/alError.c
 488                  OpenAL32/alExtension.c
 489                  OpenAL32/alFilter.c
 490                  OpenAL32/alListener.c
 491                  OpenAL32/alSource.c
 492                  OpenAL32/alState.c
 493                  OpenAL32/alThunk.c
 494 )
 495 SET(ALC_OBJS  Alc/ALc.c
 496               Alc/ALu.c
 497               Alc/alcConfig.c
 498               Alc/alcRing.c
 499               Alc/bs2b.c
 500               Alc/effects/autowah.c
 501               Alc/effects/chorus.c
 502               Alc/effects/compressor.c
 503               Alc/effects/dedicated.c
 504               Alc/effects/distortion.c
 505               Alc/effects/echo.c
 506               Alc/effects/equalizer.c
 507               Alc/effects/flanger.c
 508               Alc/effects/modulator.c
 509               Alc/effects/null.c
 510               Alc/effects/reverb.c
 511               Alc/helpers.c
 512               Alc/hrtf.c
 513               Alc/panning.c
 514               Alc/threads.c
 515               Alc/mixer.c
 516               Alc/mixer_c.c
 517 )
 518
 519
 520 SET(CPU_EXTS "Default")
 521 SET(HAVE_SSE  0)
 522 SET(HAVE_NEON 0)
 523
 524 # Check for SSE support
 525 IF(ALSOFT_CPUEXT_SSE AND ALIGN_DECL)
 526     CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 527     IF(HAVE_XMMINTRIN_H)
 528         SET(HAVE_SSE 1)
 529         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 530         IF(SSE_SWITCH)
 531             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 532                                         COMPILE_FLAGS "${SSE_SWITCH}")
 533         ENDIF()
 534         SET(CPU_EXTS "${CPU_EXTS}, SSE")
 535     ENDIF()
 536 ENDIF()
 537 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 538     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 539 ENDIF()
 540
 541 # Check for ARM Neon support
 542 IF(ALSOFT_CPUEXT_NEON)
 543     CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 544     IF(HAVE_ARM_NEON_H)
 545         SET(HAVE_NEON 1)
 546         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 547         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 548     ENDIF()
 549 ENDIF()
 550 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 551     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 552 ENDIF()
 553
 554
 555 SET(ALC_OBJS  ${ALC_OBJS}
 556               Alc/backends/base.c
 557               # Default backends, always available
 558               Alc/backends/loopback.c
 559               Alc/backends/null.c
 560 )
 561
 562 SET(BACKENDS "")
 563 SET(HAVE_ALSA       0)
 564 SET(HAVE_OSS        0)
 565 SET(HAVE_SOLARIS    0)
 566 SET(HAVE_SNDIO      0)
 567 SET(HAVE_QSA        0)
 568 SET(HAVE_DSOUND     0)
 569 SET(HAVE_MMDEVAPI   0)
 570 SET(HAVE_WINMM      0)
 571 SET(HAVE_PORTAUDIO  0)
 572 SET(HAVE_PULSEAUDIO 0)
 573 SET(HAVE_COREAUDIO  0)
 574 SET(HAVE_OPENSL     0)
 575 SET(HAVE_WAVE       0)
 576
 577 # Check ALSA backend
 578 IF(ALSOFT_BACKEND_ALSA)
 579     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 580     IF(HAVE_ALSA_ASOUNDLIB_H)
 581         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "alsa/asoundlib.h" asound "" HAVE_LIBASOUND)
 582         IF(HAVE_LIBASOUND OR HAVE_DLFCN_H OR WIN32)
 583             SET(HAVE_ALSA 1)
 584             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 585             IF(HAVE_DLFCN_H OR WIN32)
 586                 SET(BACKENDS  "${BACKENDS} ALSA,")
 587             ELSE()
 588                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 589                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 590             ENDIF()
 591         ENDIF()
 592     ENDIF()
 593 ENDIF()
 594 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 595     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 596 ENDIF()
 597
 598 # Check OSS backend
 599 IF(ALSOFT_BACKEND_OSS)
 600     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 601     IF(HAVE_SYS_SOUNDCARD_H)
 602         SET(HAVE_OSS 1)
 603         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 604         SET(BACKENDS  "${BACKENDS} OSS,")
 605     ENDIF()
 606 ENDIF()
 607 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 608     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 609 ENDIF()
 610
 611 # Check Solaris backend
 612 IF(ALSOFT_BACKEND_SOLARIS)
 613     CHECK_INCLUDE_FILE(sys/audioio.h HAVE_SYS_AUDIOIO_H)
 614     IF(HAVE_SYS_AUDIOIO_H)
 615         SET(HAVE_SOLARIS 1)
 616         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 617         SET(BACKENDS  "${BACKENDS} Solaris,")
 618     ENDIF()
 619 ENDIF()
 620 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 621     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 622 ENDIF()
 623
 624 # Check SndIO backend
 625 IF(ALSOFT_BACKEND_SNDIO)
 626     CHECK_INCLUDE_FILE(sndio.h HAVE_SNDIO_H)
 627     IF(HAVE_SNDIO_H)
 628         CHECK_SHARED_FUNCTION_EXISTS(sio_open "sndio.h" sndio "" HAVE_LIBSNDIO)
 629         IF(HAVE_LIBSNDIO)
 630             SET(HAVE_SNDIO 1)
 631             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 632             SET(BACKENDS  "${BACKENDS} SndIO \(linked\),")
 633             SET(EXTRA_LIBS sndio ${EXTRA_LIBS})
 634         ENDIF()
 635     ENDIF()
 636 ENDIF()
 637 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 638     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 639 ENDIF()
 640
 641 # Check QSA backend
 642 IF (ALSOFT_BACKEND_QSA AND "${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 643     CHECK_INCLUDE_FILE(sys/asoundlib.h HAVE_SYS_ASOUNDLIB_H)
 644     IF(HAVE_SYS_ASOUNDLIB_H)
 645         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "sys/asoundlib.h" asound "" HAVE_LIBASOUND)
 646         IF(HAVE_LIBASOUND)
 647             SET(HAVE_QSA 1)
 648             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 649             SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 650             SET(BACKENDS  "${BACKENDS} QSA \(linked\),")
 651         ENDIF()
 652     ENDIF()
 653 ENDIF()
 654 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 655     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 656 ENDIF()
 657
 658 # Check for MMDevApi backend
 659 IF(HAVE_WINDOWS_H)
 660     IF(ALSOFT_BACKEND_MMDEVAPI)
 661         CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 662         IF(HAVE_MMDEVICEAPI_H)
 663             SET(HAVE_MMDEVAPI 1)
 664             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 665
 666             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 667         ENDIF()
 668     ENDIF()
 669 ENDIF()
 670 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 671     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 672 ENDIF()
 673
 674 # Check DSound/MMSystem backend
 675 IF(ALSOFT_BACKEND_DSOUND)
 676     CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 677     IF(HAVE_DSOUND_H)
 678         CHECK_SHARED_FUNCTION_EXISTS(DirectSoundCreate "dsound.h" dsound "" HAVE_LIBDSOUND)
 679         IF(HAVE_LIBDSOUND OR HAVE_DLFCN_H OR WIN32)
 680             SET(HAVE_DSOUND 1)
 681             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 682
 683             IF(HAVE_DLFCN_H OR WIN32)
 684                 SET(BACKENDS  "${BACKENDS} DirectSound,")
 685             ELSE()
 686                 SET(BACKENDS  "${BACKENDS} DirectSound \(linked\),")
 687                 SET(EXTRA_LIBS dsound ${EXTRA_LIBS})
 688             ENDIF()
 689         ENDIF()
 690     ENDIF()
 691 ENDIF()
 692 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 693     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 694 ENDIF()
 695
 696 IF(HAVE_WINDOWS_H)
 697     IF(ALSOFT_BACKEND_WINMM)
 698         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0501)
 699         IF(HAVE_MMSYSTEM_H AND HAVE_LIBWINMM)
 700             SET(HAVE_WINMM 1)
 701             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 702             SET(BACKENDS  "${BACKENDS} WinMM,")
 703         ENDIF()
 704     ENDIF()
 705 ENDIF()
 706 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 707     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 708 ENDIF()
 709
 710 # Check PortAudio backend
 711 IF(ALSOFT_BACKEND_PORTAUDIO)
 712     CHECK_INCLUDE_FILE(portaudio.h HAVE_PORTAUDIO_H)
 713     IF(HAVE_PORTAUDIO_H)
 714         CHECK_SHARED_FUNCTION_EXISTS(Pa_Initialize "portaudio.h" portaudio "" HAVE_LIBPORTAUDIO)
 715         IF(HAVE_LIBPORTAUDIO OR HAVE_DLFCN_H OR WIN32)
 716             SET(HAVE_PORTAUDIO 1)
 717             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 718             IF(HAVE_DLFCN_H OR WIN32)
 719                 SET(BACKENDS  "${BACKENDS} PortAudio,")
 720             ELSE()
 721                 SET(BACKENDS  "${BACKENDS} PortAudio \(linked\),")
 722                 SET(EXTRA_LIBS portaudio ${EXTRA_LIBS})
 723             ENDIF()
 724         ENDIF()
 725     ENDIF()
 726 ENDIF()
 727 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 728     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 729 ENDIF()
 730
 731 # Check PulseAudio backend
 732 IF(ALSOFT_BACKEND_PULSEAUDIO)
 733     CHECK_INCLUDE_FILE(pulse/pulseaudio.h HAVE_PULSE_PULSEAUDIO_H)
 734     IF(HAVE_PULSE_PULSEAUDIO_H)
 735         CHECK_SHARED_FUNCTION_EXISTS(pa_context_new "pulse/pulseaudio.h" pulse "" HAVE_LIBPULSE)
 736         IF(HAVE_LIBPULSE OR HAVE_DLFCN_H OR WIN32)
 737             SET(HAVE_PULSEAUDIO 1)
 738             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 739             IF(HAVE_DLFCN_H OR WIN32)
 740                 SET(BACKENDS  "${BACKENDS} PulseAudio,")
 741             ELSE()
 742                 SET(BACKENDS  "${BACKENDS} PulseAudio \(linked\),")
 743                 SET(EXTRA_LIBS pulse ${EXTRA_LIBS})
 744             ENDIF()
 745         ENDIF()
 746     ENDIF()
 747 ENDIF()
 748 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 749     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 750 ENDIF()
 751
 752 # Check CoreAudio backend
 753 IF(ALSOFT_BACKEND_COREAUDIO)
 754     CHECK_INCLUDE_FILE(/System/Library/Frameworks/CoreAudio.framework/Headers/CoreAudio.h HAVE_COREAUDIO_FRAMEWORK)
 755     IF(HAVE_COREAUDIO_FRAMEWORK)
 756         SET(HAVE_COREAUDIO 1)
 757         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 758         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 759         SET(EXTRA_LIBS /System/Library/Frameworks/CoreAudio.framework ${EXTRA_LIBS})
 760         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 761         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 762
 763         # Some versions of OSX may need the AudioToolbox framework. Add it if
 764         # it's found.
 765         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 766                      NAMES AudioToolbox
 767                      PATHS ~/Library/Frameworks
 768                            /Library/Frameworks
 769                            /System/Library/Frameworks
 770                     )
 771         IF(AUDIOTOOLBOX_LIBRARY)
 772             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 773         ENDIF()
 774     ENDIF()
 775 ENDIF()
 776 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 777     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 778 ENDIF()
 779
 780 # Check for OpenSL (Android) backend
 781 IF(ALSOFT_BACKEND_OPENSL)
 782     CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 783     IF(HAVE_SLES_OPENSLES_ANDROID_H)
 784         CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 785         IF(HAVE_LIBOPENSLES)
 786             SET(HAVE_OPENSL 1)
 787             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 788             SET(BACKENDS  "${BACKENDS} OpenSL,")
 789             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 790         ENDIF()
 791     ENDIF()
 792 ENDIF()
 793 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 794     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 795 ENDIF()
 796
 797 # Optionally enable the Wave Writer backend
 798 IF(ALSOFT_BACKEND_WAVE)
 799     SET(HAVE_WAVE 1)
 800     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 801     SET(BACKENDS  "${BACKENDS} WaveFile,")
 802 ENDIF()
 803
 804 # This is always available
 805 SET(BACKENDS  "${BACKENDS} Null")
 806
 807 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 808     add_subdirectory(utils/alsoft-config)
 809 ENDIF()
 810 IF(ALSOFT_EXAMPLES)
 811     FIND_PACKAGE(SDL)
 812     IF(SDL_FOUND)
 813         FIND_PACKAGE(SDL_sound)
 814         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 815             INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 816         ENDIF()
 817     ENDIF()
 818 ENDIF()
 819
 820 IF(LIBTYPE STREQUAL "STATIC")
 821     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 822     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 823 ENDIF()
 824
 825 # Needed for openal.pc.in
 826 SET(prefix ${CMAKE_INSTALL_PREFIX})
 827 SET(exec_prefix "\${prefix}")
 828 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 829 SET(bindir "\${exec_prefix}/bin")
 830 SET(includedir "\${prefix}/include")
 831 SET(PACKAGE_VERSION "${LIB_VERSION}")
 832
 833 # End configuration
 834 CONFIGURE_FILE(
 835     "${OpenAL_SOURCE_DIR}/config.h.in"
 836     "${OpenAL_BINARY_DIR}/config.h")
 837 CONFIGURE_FILE(
 838     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 839     "${OpenAL_BINARY_DIR}/openal.pc"
 840     @ONLY)
 841
 842 # Build a library
 843 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 844 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
 845 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 846     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
 847 ENDIF()
 848 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 849 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 850                                             SOVERSION ${LIB_MAJOR_VERSION})
 851 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
 852     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 853 ENDIF()
 854
 855 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 856
 857 # Add an install target here
 858 INSTALL(TARGETS ${LIBNAME}
 859         RUNTIME DESTINATION bin
 860         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 861         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 862 )
 863 INSTALL(FILES include/AL/al.h
 864               include/AL/alc.h
 865               include/AL/alext.h
 866               include/AL/efx.h
 867               include/AL/efx-creative.h
 868               include/AL/efx-presets.h
 869         DESTINATION include/AL
 870 )
 871 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 872         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
 873
 874
 875 MESSAGE(STATUS "")
 876 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 877 MESSAGE(STATUS "    ${BACKENDS}")
 878 MESSAGE(STATUS "")
 879 MESSAGE(STATUS "Building with support for CPU extensions:")
 880 MESSAGE(STATUS "    ${CPU_EXTS}")
 881 MESSAGE(STATUS "")
 882
 883 IF(WIN32)
 884     IF(NOT HAVE_DSOUND)
 885         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
 886         MESSAGE(STATUS "         This is probably NOT what you want!")
 887         MESSAGE(STATUS "")
 888     ENDIF()
 889 ENDIF()
 890
 891 # Install alsoft.conf configuration file
 892 IF(ALSOFT_CONFIG)
 893     INSTALL(FILES alsoftrc.sample
 894             DESTINATION share/openal
 895     )
 896     MESSAGE(STATUS "Installing sample configuration")
 897     MESSAGE(STATUS "")
 898 ENDIF()
 899
 900 IF(ALSOFT_UTILS)
 901     ADD_EXECUTABLE(openal-info utils/openal-info.c)
 902     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
 903
 904     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
 905     IF(HAVE_LIBM)
 906         TARGET_LINK_LIBRARIES(makehrtf m)
 907     ENDIF()
 908
 909     INSTALL(TARGETS openal-info makehrtf
 910             RUNTIME DESTINATION bin
 911             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 912             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 913     )
 914
 915     MESSAGE(STATUS "Building utility programs")
 916     IF(TARGET alsoft-config)
 917         MESSAGE(STATUS "Building configuration program")
 918     ENDIF()
 919     MESSAGE(STATUS "")
 920 ENDIF()
 921
 922 IF(ALSOFT_EXAMPLES)
 923     IF(SDL_FOUND AND SDL_SOUND_FOUND)
 924         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
 925                                      examples/common/sdl_sound.c)
 926         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 927
 928         ADD_EXECUTABLE(alstream examples/alstream.c)
 929         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 930         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 931
 932         ADD_EXECUTABLE(alreverb examples/alreverb.c)
 933         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 934         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 935
 936         ADD_EXECUTABLE(allatency examples/allatency.c)
 937         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 938         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 939
 940         ADD_EXECUTABLE(alloopback examples/alloopback.c)
 941         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL_LIBRARY} ${LIBNAME})
 942         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_INCLUDE_DIR}
 943                                                                            ${SDL_SOUND_INCLUDE_DIR})
 944
 945         INSTALL(TARGETS alstream alreverb allatency alloopback
 946                 RUNTIME DESTINATION bin
 947                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 948                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 949         )
 950
 951         MESSAGE(STATUS "Building example programs")
 952         MESSAGE(STATUS "")
 953     ENDIF()
 954 ENDIF()