CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 IF(WIN32)
  66     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  67
  68     # This option is mainly for static linking OpenAL Soft into another project
  69     # that already defines the IDs. It is up to that project to ensure all
  70     # required IDs are defined.
  71     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  72
  73     IF(MINGW)
  74         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  75         IF(NOT DLLTOOL)
  76             IF(HOST)
  77                 SET(DLLTOOL "${HOST}-dlltool")
  78             ELSE()
  79                 SET(DLLTOOL "dlltool")
  80             ENDIF()
  81         ENDIF()
  82     ENDIF()
  83 ENDIF()
  84
  85
  86 SET(EXTRA_LIBS "")
  87 SET(EXTRA_LDFLAGS "")
  88
  89 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  90 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  91     ADD_DEFINITIONS("-I/usr/include")
  92     SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -L/usr/lib")
  93 ENDIF()
  94
  95 IF(NOT LIBTYPE)
  96     SET(LIBTYPE SHARED)
  97 ENDIF()
  98
  99 SET(LIB_MAJOR_VERSION "1")
 100 SET(LIB_MINOR_VERSION "17")
 101 SET(LIB_REVISION "2")
 102 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 103
 104 SET(EXPORT_DECL "")
 105 SET(ALIGN_DECL "")
 106
 107
 108 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 109 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 110
 111
 112 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 113 IF(HAVE_STD_C11)
 114     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 115 ELSE()
 116     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 117     IF(HAVE_STD_C99)
 118         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 119     ENDIF()
 120 ENDIF()
 121
 122 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 123 IF(HAVE_STD_CXX11)
 124     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 125 ENDIF()
 126
 127 if(NOT WIN32)
 128     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 129     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 130     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 131         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 132         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 133         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 134         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 135             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 136         ELSE()
 137             ADD_DEFINITIONS(-D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600)
 138         ENDIF()
 139     ENDIF()
 140     UNSET(OLD_REQUIRED_FLAGS)
 141 ENDIF()
 142
 143 # Set defines for large file support
 144 CHECK_FILE_OFFSET_BITS()
 145 IF(_FILE_OFFSET_BITS)
 146     ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS})
 147     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 148 ENDIF()
 149 ADD_DEFINITIONS(-D_LARGEFILE_SOURCE -D_LARGE_FILES)
 150 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 151
 152 # MSVC may need workarounds for C99 restrict and inline
 153 IF(MSVC)
 154     # TODO: Once we truly require C99, these restrict and inline checks should go
 155     # away.
 156     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 157                              int main() {return 0;}" HAVE_RESTRICT)
 158     IF(NOT HAVE_RESTRICT)
 159         ADD_DEFINITIONS("-Drestrict=")
 160         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 161     ENDIF()
 162
 163     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 164                              int main() {return 0;}" HAVE_INLINE)
 165     IF(NOT HAVE_INLINE)
 166         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 167                                  int main() {return 0;}" HAVE___INLINE)
 168         IF(NOT HAVE___INLINE)
 169             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 170         ENDIF()
 171
 172         ADD_DEFINITIONS(-Dinline=__inline)
 173         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 174     ENDIF()
 175 ENDIF()
 176
 177 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 178 IF(CMAKE_COMPILER_IS_GNUCC)
 179     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 180
 181     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 182     # Force no inlining for the next test.
 183     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 184
 185     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 186                              int main() {return foo();}" INLINE_IS_C99)
 187     IF(NOT INLINE_IS_C99)
 188         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 189                              Please update your compiler for better C99 compliance.")
 190     ENDIF()
 191
 192     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 193 ENDIF()
 194
 195 # Check if we have a proper timespec declaration
 196 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 197 IF(HAVE_STRUCT_TIMESPEC)
 198     # Define it here so we don't have to include config.h for it
 199     ADD_DEFINITIONS("-DHAVE_STRUCT_TIMESPEC")
 200 ENDIF()
 201
 202 # Some systems may need libatomic for C11 atomic functions to work
 203 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 204 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 205 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 206 int _Atomic foo = ATOMIC_VAR_INIT(0);
 207 int main()
 208 {
 209     return atomic_fetch_add(&foo, 2);
 210 }"
 211 HAVE_LIBATOMIC)
 212 IF(NOT HAVE_LIBATOMIC)
 213     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 214 ELSE()
 215     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 216 ENDIF()
 217 UNSET(OLD_REQUIRED_LIBRARIES)
 218
 219 # Include liblog for Android logging
 220 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 221 IF(HAVE_LIBLOG)
 222     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 223     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 224 ENDIF()
 225
 226 # Check if we have C99 variable length arrays
 227 CHECK_C_SOURCE_COMPILES(
 228 "int main(int argc, char *argv[])
 229  {
 230      volatile int tmp[argc];
 231      tmp[0] = argv[0][0];
 232      return tmp[0];
 233  }"
 234 HAVE_C99_VLA)
 235
 236 # Check if we have C99 bool
 237 CHECK_C_SOURCE_COMPILES(
 238 "int main(int argc, char *argv[])
 239  {
 240      volatile _Bool ret;
 241      ret = (argc > 1) ? 1 : 0;
 242      return ret ? -1 : 0;
 243  }"
 244 HAVE_C99_BOOL)
 245
 246 # Check if we have C11 static_assert
 247 CHECK_C_SOURCE_COMPILES(
 248 "int main()
 249  {
 250      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 251      return 0;
 252  }"
 253 HAVE_C11_STATIC_ASSERT)
 254
 255 # Check if we have C11 alignas
 256 CHECK_C_SOURCE_COMPILES(
 257 "_Alignas(16) int foo;
 258  int main()
 259  {
 260      return 0;
 261  }"
 262 HAVE_C11_ALIGNAS)
 263
 264 # Check if we have C11 _Atomic
 265 CHECK_C_SOURCE_COMPILES(
 266 "#include <stdatomic.h>
 267  const int _Atomic foo = ATOMIC_VAR_INIT(~0);
 268  int _Atomic bar = ATOMIC_VAR_INIT(0);
 269  int main()
 270  {
 271      atomic_fetch_add(&bar, 2);
 272      return atomic_load(&foo);
 273  }"
 274 HAVE_C11_ATOMIC)
 275
 276 # Add definitions, compiler switches, etc.
 277 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 278
 279 IF(NOT CMAKE_BUILD_TYPE)
 280     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 281         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 282         FORCE)
 283 ENDIF()
 284 IF(NOT CMAKE_DEBUG_POSTFIX)
 285     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 286         "Library postfix for debug builds. Normally left blank."
 287         FORCE)
 288 ENDIF()
 289
 290 SET(EXTRA_CFLAGS "")
 291 IF(MSVC)
 292     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 293     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 294     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} /wd4098")
 295
 296     IF(NOT DXSDK_DIR)
 297         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 298     ELSE()
 299         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 300     ENDIF()
 301     IF(DXSDK_DIR)
 302         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 303     ENDIF()
 304
 305     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 306     IF(FORCE_STATIC_VCRT)
 307         FOREACH(flag_var
 308                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 309                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 310             IF(${flag_var} MATCHES "/MD")
 311                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 312             ENDIF()
 313         ENDFOREACH(flag_var)
 314     ENDIF()
 315 ELSE()
 316     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Winline -Wall")
 317     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 318     IF(HAVE_W_EXTRA)
 319         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Wextra")
 320     ENDIF()
 321
 322     IF(ALSOFT_WERROR)
 323         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Werror")
 324     ENDIF()
 325
 326     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 327     # instead of NDEBUG)
 328     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 329         IF(${flag_var} MATCHES "-DNDEBUG")
 330             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 331         ENDIF()
 332     ENDFOREACH()
 333
 334     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 335                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 336
 337     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 338     if(ALSOFT_STATIC_LIBGCC)
 339         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 340         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 341         check_c_source_compiles(
 342 "#include <stdlib.h>
 343 int main()
 344 {
 345     return 0;
 346 }"
 347             HAVE_STATIC_LIBGCC_SWITCH
 348         )
 349         if(HAVE_STATIC_LIBGCC_SWITCH)
 350             set(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -static-libgcc")
 351         endif()
 352         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 353         unset(OLD_REQUIRED_LIBRARIES)
 354     endif()
 355 ENDIF()
 356
 357 # Set visibility/export options if available
 358 SET(HIDDEN_DECL "")
 359 IF(WIN32)
 360     SET(EXPORT_DECL "__declspec(dllexport)")
 361     IF(NOT MINGW)
 362         SET(ALIGN_DECL "__declspec(align(x))")
 363     ELSE()
 364         SET(ALIGN_DECL "__declspec(aligned(x))")
 365     ENDIF()
 366 ELSE()
 367     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 368     # Yes GCC, really don't accept visibility modes you don't support
 369     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 370
 371     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 372                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 373     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 374         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 375     ELSE()
 376         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 377                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 378         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 379             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 380         ENDIF()
 381     ENDIF()
 382
 383     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 384         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 385         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 386             SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fvisibility=hidden")
 387             SET(HIDDEN_DECL "__attribute__((visibility(\"hidden\")))")
 388         ENDIF()
 389     ENDIF()
 390
 391     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 392                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 393     IF(HAVE_ATTRIBUTE_ALIGNED)
 394         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 395     ENDIF()
 396
 397     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 398 ENDIF()
 399
 400 CHECK_C_SOURCE_COMPILES("
 401 int main()
 402 {
 403     float *ptr;
 404     ptr = __builtin_assume_aligned(ptr, 16);
 405     return 0;
 406 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 407 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 408     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 409 ELSE()
 410     SET(ASSUME_ALIGNED_DECL "x")
 411 ENDIF()
 412
 413 SET(SSE_SWITCH "")
 414 SET(SSE2_SWITCH "")
 415 SET(SSE3_SWITCH "")
 416 SET(SSE4_1_SWITCH "")
 417 SET(FPU_NEON_SWITCH "")
 418 IF(NOT MSVC)
 419     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 420     IF(HAVE_MSSE_SWITCH)
 421         SET(SSE_SWITCH "-msse")
 422     ENDIF()
 423     CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 424     IF(HAVE_MSSE2_SWITCH)
 425         SET(SSE2_SWITCH "-msse2")
 426     ENDIF()
 427     CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 428     IF(HAVE_MSSE3_SWITCH)
 429         SET(SSE3_SWITCH "-msse3")
 430     ENDIF()
 431     CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 432     IF(HAVE_MSSE4_1_SWITCH)
 433         SET(SSE4_1_SWITCH "-msse4.1")
 434     ENDIF()
 435     CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 436     IF(HAVE_MFPU_NEON_SWITCH)
 437         SET(FPU_NEON_SWITCH "-mfpu=neon")
 438     ENDIF()
 439 ENDIF()
 440
 441 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 442                          int main() {return 0;}" HAVE_GCC_FORMAT)
 443
 444 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 445 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 446 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 447 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 448 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 449 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 450 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 451 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 452 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 453 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 454 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 455 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 456 IF(NOT HAVE_GUIDDEF_H)
 457     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 458 ENDIF()
 459
 460 # Some systems need libm for some of the following math functions to work
 461 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 462 IF(HAVE_LIBM)
 463     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 464     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 465 ENDIF()
 466
 467 # Check for the dlopen API (for dynamicly loading backend libs)
 468 IF(ALSOFT_DLOPEN)
 469     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 470     IF(HAVE_LIBDL)
 471         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 472         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 473     ENDIF()
 474
 475     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 476 ENDIF()
 477
 478 # Check for a cpuid intrinsic
 479 IF(HAVE_CPUID_H)
 480     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 481         int main()
 482         {
 483             unsigned int eax, ebx, ecx, edx;
 484             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 485         }" HAVE_GCC_GET_CPUID)
 486 ENDIF()
 487 IF(HAVE_INTRIN_H)
 488     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 489         int main()
 490         {
 491             int regs[4];
 492             __cpuid(regs, 0);
 493             return regs[0];
 494         }" HAVE_CPUID_INTRINSIC)
 495 ENDIF()
 496
 497 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 498 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 499 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 500 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 501 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 502 IF(NOT HAVE_C99_VLA)
 503     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 504     IF(NOT HAVE_ALLOCA)
 505         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 506     ENDIF()
 507 ENDIF()
 508
 509 IF(HAVE_FLOAT_H)
 510     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 511     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 512 ENDIF()
 513
 514 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 515 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 516 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 517 IF(NOT HAVE_STRCASECMP)
 518     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 519     IF(NOT HAVE__STRICMP)
 520         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 521     ENDIF()
 522
 523     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 524 ENDIF()
 525
 526 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 527 IF(NOT HAVE_STRNCASECMP)
 528     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 529     IF(NOT HAVE__STRNICMP)
 530         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 531     ENDIF()
 532
 533     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 534 ENDIF()
 535
 536 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 537 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 538 IF(NOT HAVE_SNPRINTF)
 539     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 540     IF(NOT HAVE__SNPRINTF)
 541         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 542     ENDIF()
 543
 544     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 545 ENDIF()
 546
 547 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 548 IF(NOT HAVE_ISFINITE)
 549     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 550     IF(NOT HAVE_FINITE)
 551         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 552         IF(NOT HAVE__FINITE)
 553             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 554         ENDIF()
 555         ADD_DEFINITIONS(-Disfinite=_finite)
 556     ELSE()
 557         ADD_DEFINITIONS(-Disfinite=finite)
 558     ENDIF()
 559 ENDIF()
 560
 561 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 562 IF(NOT HAVE_ISNAN)
 563     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 564     IF(NOT HAVE__ISNAN)
 565         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 566     ENDIF()
 567
 568     ADD_DEFINITIONS(-Disnan=_isnan)
 569 ENDIF()
 570
 571
 572 # Check if we have Windows headers
 573 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 574 IF(NOT HAVE_WINDOWS_H)
 575     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 576     IF(NOT HAVE_GETTIMEOFDAY)
 577         MESSAGE(FATAL_ERROR "No timing function found!")
 578     ENDIF()
 579
 580     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 581     IF(NOT HAVE_NANOSLEEP)
 582         MESSAGE(FATAL_ERROR "No sleep function found!")
 583     ENDIF()
 584
 585     # We need pthreads outside of Windows
 586     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 587     IF(NOT HAVE_PTHREAD_H)
 588         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 589     ENDIF()
 590     # Some systems need pthread_np.h to get recursive mutexes
 591     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 592
 593     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 594     IF(HAVE_PTHREAD)
 595         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -pthread")
 596         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 597         SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -pthread")
 598     ENDIF()
 599
 600     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 601     IF(HAVE_LIBPTHREAD)
 602         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 603     ENDIF()
 604
 605     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 606
 607     IF(HAVE_PTHREAD_NP_H)
 608         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 609         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 610             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 611         ELSE()
 612             CHECK_C_SOURCE_COMPILES("
 613 #include <pthread.h>
 614 #include <pthread_np.h>
 615 int main()
 616 {
 617     pthread_setname_np(\"testname\");
 618     return 0;
 619 }"
 620                 PTHREAD_SETNAME_NP_ONE_PARAM
 621             )
 622         ENDIF()
 623         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 624     ELSE()
 625         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 626         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 627             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 628         ELSE()
 629             CHECK_C_SOURCE_COMPILES("
 630 #include <pthread.h>
 631 int main()
 632 {
 633     pthread_setname_np(\"testname\");
 634     return 0;
 635 }"
 636                 PTHREAD_SETNAME_NP_ONE_PARAM
 637             )
 638         ENDIF()
 639         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 640     ENDIF()
 641
 642     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 643
 644     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 645     IF(HAVE_LIBRT)
 646         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 647     ENDIF()
 648 ENDIF()
 649
 650 # Check for a 64-bit type
 651 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 652 IF(NOT HAVE_STDINT_H)
 653     IF(HAVE_WINDOWS_H)
 654         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 655                                  #include <windows.h>
 656                                  __int64 foo;
 657                                  int main() {return 0;}" HAVE___INT64)
 658     ENDIF()
 659     IF(NOT HAVE___INT64)
 660         IF(NOT SIZEOF_LONG MATCHES "8")
 661             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 662                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 663             ENDIF()
 664         ENDIF()
 665     ENDIF()
 666 ENDIF()
 667
 668
 669 SET(COMMON_OBJS  common/almalloc.c
 670                  common/atomic.c
 671                  common/rwlock.c
 672                  common/threads.c
 673                  common/uintmap.c
 674 )
 675 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 676                  OpenAL32/alBuffer.c
 677                  OpenAL32/alEffect.c
 678                  OpenAL32/alError.c
 679                  OpenAL32/alExtension.c
 680                  OpenAL32/alFilter.c
 681                  OpenAL32/alListener.c
 682                  OpenAL32/alSource.c
 683                  OpenAL32/alState.c
 684                  OpenAL32/alThunk.c
 685                  OpenAL32/sample_cvt.c
 686 )
 687 SET(ALC_OBJS  Alc/ALc.c
 688               Alc/ALu.c
 689               Alc/alcConfig.c
 690               Alc/alcRing.c
 691               Alc/bs2b.c
 692               Alc/effects/chorus.c
 693               Alc/effects/compressor.c
 694               Alc/effects/dedicated.c
 695               Alc/effects/distortion.c
 696               Alc/effects/echo.c
 697               Alc/effects/equalizer.c
 698               Alc/effects/flanger.c
 699               Alc/effects/modulator.c
 700               Alc/effects/null.c
 701               Alc/effects/reverb.c
 702               Alc/helpers.c
 703               Alc/bsinc.c
 704               Alc/hrtf.c
 705               Alc/uhjfilter.c
 706               Alc/ambdec.c
 707               Alc/bformatdec.c
 708               Alc/nfcfilter.c
 709               Alc/panning.c
 710               Alc/mixer.c
 711               Alc/mixer_c.c
 712 )
 713
 714
 715 SET(CPU_EXTS "Default")
 716 SET(HAVE_SSE        0)
 717 SET(HAVE_SSE2       0)
 718 SET(HAVE_SSE3       0)
 719 SET(HAVE_SSE4_1     0)
 720 SET(HAVE_NEON       0)
 721
 722 SET(HAVE_ALSA       0)
 723 SET(HAVE_OSS        0)
 724 SET(HAVE_SOLARIS    0)
 725 SET(HAVE_SNDIO      0)
 726 SET(HAVE_QSA        0)
 727 SET(HAVE_DSOUND     0)
 728 SET(HAVE_MMDEVAPI   0)
 729 SET(HAVE_WINMM      0)
 730 SET(HAVE_PORTAUDIO  0)
 731 SET(HAVE_PULSEAUDIO 0)
 732 SET(HAVE_COREAUDIO  0)
 733 SET(HAVE_OPENSL     0)
 734 SET(HAVE_WAVE       0)
 735
 736 # Check for SSE support
 737 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 738 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 739 IF(HAVE_XMMINTRIN_H)
 740     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 741     IF(ALSOFT_CPUEXT_SSE)
 742         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 743             SET(HAVE_SSE 1)
 744             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 745             IF(SSE_SWITCH)
 746                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 747                                             COMPILE_FLAGS "${SSE_SWITCH}")
 748             ENDIF()
 749             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 750         ENDIF()
 751     ENDIF()
 752 ENDIF()
 753 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 754     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 755 ENDIF()
 756
 757 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 758 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 759 IF(HAVE_EMMINTRIN_H)
 760     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 761     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 762         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 763             SET(HAVE_SSE2 1)
 764             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 765             IF(SSE2_SWITCH)
 766                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 767                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 768             ENDIF()
 769             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 770         ENDIF()
 771     ENDIF()
 772 ENDIF()
 773 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 774     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 775 ENDIF()
 776
 777 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 778 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 779 IF(HAVE_EMMINTRIN_H)
 780     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 781     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 782         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 783             SET(HAVE_SSE3 1)
 784             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse3.c)
 785             IF(SSE2_SWITCH)
 786                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse3.c PROPERTIES
 787                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 788             ENDIF()
 789             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 790         ENDIF()
 791     ENDIF()
 792 ENDIF()
 793 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 794     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 795 ENDIF()
 796
 797 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 798 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 799 IF(HAVE_SMMINTRIN_H)
 800     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 801     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 802         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 803             SET(HAVE_SSE4_1 1)
 804             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 805             IF(SSE4_1_SWITCH)
 806                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 807                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 808             ENDIF()
 809             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 810         ENDIF()
 811     ENDIF()
 812 ENDIF()
 813 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 814     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 815 ENDIF()
 816
 817 # Check for ARM Neon support
 818 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 819 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 820 IF(HAVE_ARM_NEON_H)
 821     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 822     IF(ALSOFT_CPUEXT_NEON)
 823         SET(HAVE_NEON 1)
 824         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 825         IF(FPU_NEON_SWITCH)
 826             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_neon.c PROPERTIES
 827                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 828         ENDIF()
 829         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 830     ENDIF()
 831 ENDIF()
 832 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 833     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 834 ENDIF()
 835
 836
 837 IF(WIN32 OR HAVE_DLFCN_H)
 838     SET(IS_LINKED "")
 839     MACRO(ADD_BACKEND_LIBS _LIBS)
 840     ENDMACRO()
 841 ELSE()
 842     SET(IS_LINKED " (linked)")
 843     MACRO(ADD_BACKEND_LIBS _LIBS)
 844         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 845     ENDMACRO()
 846 ENDIF()
 847
 848 SET(BACKENDS "")
 849 SET(ALC_OBJS  ${ALC_OBJS}
 850               Alc/backends/base.c
 851               # Default backends, always available
 852               Alc/backends/loopback.c
 853               Alc/backends/null.c
 854 )
 855
 856 # Check ALSA backend
 857 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 858 FIND_PACKAGE(ALSA)
 859 IF(ALSA_FOUND)
 860     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 861     IF(ALSOFT_BACKEND_ALSA)
 862         SET(HAVE_ALSA 1)
 863         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 864         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 865         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 866     ENDIF()
 867 ENDIF()
 868 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 869     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 870 ENDIF()
 871
 872 # Check OSS backend
 873 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 874 FIND_PACKAGE(OSS)
 875 IF(OSS_FOUND)
 876     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 877     IF(ALSOFT_BACKEND_OSS)
 878         SET(HAVE_OSS 1)
 879         SET(BACKENDS  "${BACKENDS} OSS,")
 880         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 881     ENDIF()
 882 ENDIF()
 883 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 884     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 885 ENDIF()
 886
 887 # Check Solaris backend
 888 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 889 FIND_PACKAGE(AudioIO)
 890 IF(AUDIOIO_FOUND)
 891     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 892     IF(ALSOFT_BACKEND_SOLARIS)
 893         SET(HAVE_SOLARIS 1)
 894         SET(BACKENDS  "${BACKENDS} Solaris,")
 895         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 896     ENDIF()
 897 ENDIF()
 898 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 899     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 900 ENDIF()
 901
 902 # Check SndIO backend
 903 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 904 FIND_PACKAGE(SoundIO)
 905 IF(SOUNDIO_FOUND)
 906     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 907     IF(ALSOFT_BACKEND_SNDIO)
 908         SET(HAVE_SNDIO 1)
 909         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 910         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 911         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 912     ENDIF()
 913 ENDIF()
 914 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 915     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 916 ENDIF()
 917
 918 # Check QSA backend
 919 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 920 FIND_PACKAGE(QSA)
 921 IF(QSA_FOUND)
 922     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 923     IF(ALSOFT_BACKEND_QSA)
 924         SET(HAVE_QSA 1)
 925         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 926         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 927         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 928     ENDIF()
 929 ENDIF()
 930 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 931     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 932 ENDIF()
 933
 934 # Check Windows-only backends
 935 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 936 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 937 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 938 IF(HAVE_WINDOWS_H)
 939     # Check MMSystem backend
 940     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 941     IF(HAVE_MMSYSTEM_H)
 942         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 943         IF(HAVE_LIBWINMM)
 944             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 945             IF(ALSOFT_BACKEND_WINMM)
 946                 SET(HAVE_WINMM 1)
 947                 SET(BACKENDS  "${BACKENDS} WinMM,")
 948                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 949                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 950             ENDIF()
 951         ENDIF()
 952     ENDIF()
 953
 954     # Check DSound backend
 955     FIND_PACKAGE(DSound)
 956     IF(DSOUND_FOUND)
 957         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 958         IF(ALSOFT_BACKEND_DSOUND)
 959             SET(HAVE_DSOUND 1)
 960             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 961             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 962             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 963         ENDIF()
 964     ENDIF()
 965
 966     # Check for MMDevApi backend
 967     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 968     IF(HAVE_MMDEVICEAPI_H)
 969         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 970         IF(ALSOFT_BACKEND_MMDEVAPI)
 971             SET(HAVE_MMDEVAPI 1)
 972             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 973             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 974         ENDIF()
 975     ENDIF()
 976 ENDIF()
 977 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 978     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 979 ENDIF()
 980 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 981     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 982 ENDIF()
 983 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 984     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 985 ENDIF()
 986
 987 # Check PortAudio backend
 988 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 989 FIND_PACKAGE(PortAudio)
 990 IF(PORTAUDIO_FOUND)
 991     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 992     IF(ALSOFT_BACKEND_PORTAUDIO)
 993         SET(HAVE_PORTAUDIO 1)
 994         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
 995         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 996         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
 997     ENDIF()
 998 ENDIF()
 999 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1000     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1001 ENDIF()
1002
1003 # Check PulseAudio backend
1004 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1005 FIND_PACKAGE(PulseAudio)
1006 IF(PULSEAUDIO_FOUND)
1007     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1008     IF(ALSOFT_BACKEND_PULSEAUDIO)
1009         SET(HAVE_PULSEAUDIO 1)
1010         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1011         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1012         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1013     ENDIF()
1014 ENDIF()
1015 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1016     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1017 ENDIF()
1018
1019 # Check JACK backend
1020 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1021 FIND_PACKAGE(JACK)
1022 IF(JACK_FOUND)
1023     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1024     IF(ALSOFT_BACKEND_JACK)
1025         SET(HAVE_JACK 1)
1026         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1027         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1028         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1029     ENDIF()
1030 ENDIF()
1031 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1032     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1033 ENDIF()
1034
1035 # Check CoreAudio backend
1036 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1037 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1038              NAMES CoreAudio
1039              PATHS /System/Library/Frameworks
1040 )
1041 IF(COREAUDIO_FRAMEWORK)
1042     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1043     IF(ALSOFT_BACKEND_COREAUDIO)
1044         SET(HAVE_COREAUDIO 1)
1045         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1046         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1047         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1048         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1049         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1050
1051         # Some versions of OSX may need the AudioToolbox framework. Add it if
1052         # it's found.
1053         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1054                      NAMES AudioToolbox
1055                      PATHS ~/Library/Frameworks
1056                            /Library/Frameworks
1057                            /System/Library/Frameworks
1058                     )
1059         IF(AUDIOTOOLBOX_LIBRARY)
1060             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1061         ENDIF()
1062     ENDIF()
1063 ENDIF()
1064 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1065     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1066 ENDIF()
1067
1068 # Check for OpenSL (Android) backend
1069 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1070 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1071 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1072     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1073     IF(HAVE_LIBOPENSLES)
1074         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1075         IF(ALSOFT_BACKEND_OPENSL)
1076             SET(HAVE_OPENSL 1)
1077             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1078             SET(BACKENDS  "${BACKENDS} OpenSL,")
1079             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1080         ENDIF()
1081     ENDIF()
1082 ENDIF()
1083 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1084     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1085 ENDIF()
1086
1087 # Optionally enable the Wave Writer backend
1088 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1089 IF(ALSOFT_BACKEND_WAVE)
1090     SET(HAVE_WAVE 1)
1091     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1092     SET(BACKENDS  "${BACKENDS} WaveFile,")
1093 ENDIF()
1094
1095 # This is always available
1096 SET(BACKENDS  "${BACKENDS} Null")
1097
1098 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1099 if(ALSOFT_EMBED_HRTF_DATA)
1100     if(WIN32)
1101         set(ALC_OBJS  ${ALC_OBJS} Alc/hrtf_res.rc)
1102     elseif(APPLE)
1103         macro(add_custom_binary FILENAME BIN_NAME)
1104             set(outfile ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${FILENAME}${CMAKE_C_OUTPUT_EXTENSION})
1105             set(stubsrcfile ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${FILENAME}.stub.c)
1106             set(stubfile ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${FILENAME}.stub${CMAKE_C_OUTPUT_EXTENSION})
1107             add_custom_command(OUTPUT ${outfile}
1108                 DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/hrtf/${FILENAME}"
1109                 WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/hrtf"
1110                 COMMAND touch "${stubsrcfile}"
1111                 COMMAND "${CMAKE_C_COMPILER}" -o "${stubfile}" -c "${stubsrcfile}"
1112                 COMMAND "${CMAKE_LINKER}" -r -o "${outfile}" -sectcreate binary ${BIN_NAME} ${FILENAME} "${stubfile}"
1113                 COMMAND rm "${stubsrcfile}" "${stubfile}"
1114                 COMMENT "Generating ${FILENAME}${CMAKE_C_OUTPUT_EXTENSION}"
1115                 VERBATIM
1116             )
1117             set(ALC_OBJS  ${ALC_OBJS} ${outfile})
1118         endmacro()
1119         add_custom_binary(default-44100.mhr "default_44100")
1120         add_custom_binary(default-48000.mhr "default_48000")
1121     else()
1122         set(FILENAMES default-44100.mhr default-48000.mhr)
1123         foreach(FILENAME ${FILENAMES})
1124             set(outfile ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${FILENAME}${CMAKE_C_OUTPUT_EXTENSION})
1125             add_custom_command(OUTPUT ${outfile}
1126                 DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/hrtf/${FILENAME}"
1127                 WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/hrtf"
1128                 COMMAND "${CMAKE_LINKER}" -r -b binary -o "${outfile}" ${FILENAME}
1129                 COMMAND "${CMAKE_OBJCOPY}" --rename-section .data=.rodata,alloc,load,readonly,data,contents "${outfile}" "${outfile}"
1130                 COMMENT "Generating ${FILENAME}${CMAKE_C_OUTPUT_EXTENSION}"
1131                 VERBATIM
1132             )
1133             set(ALC_OBJS  ${ALC_OBJS} ${outfile})
1134         endforeach()
1135         unset(outfile)
1136         unset(FILENAMES)
1137     endif()
1138 endif()
1139
1140
1141 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1142     add_subdirectory(utils/alsoft-config)
1143 ENDIF()
1144 IF(ALSOFT_EXAMPLES)
1145     FIND_PACKAGE(SDL2)
1146     IF(SDL2_FOUND)
1147         FIND_PACKAGE(SDL_sound)
1148         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1149     ENDIF()
1150 ENDIF()
1151
1152 IF(LIBTYPE STREQUAL "STATIC")
1153     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
1154     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1155 ENDIF()
1156
1157 IF(NOT WIN32)
1158     SET(LIBNAME "openal")
1159 ELSE()
1160     SET(LIBNAME "OpenAL32")
1161 ENDIF()
1162
1163 FIND_PACKAGE(Git)
1164 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1165     # Get the current working branch and its latest abbreviated commit hash
1166     ADD_CUSTOM_TARGET(build_version
1167         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1168                          -D LIB_VERSION=${LIB_VERSION}
1169                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1170                          -D DST=${OpenAL_BINARY_DIR}/version.h
1171                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1172         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1173         VERBATIM
1174     )
1175 ELSE()
1176     SET(GIT_BRANCH "UNKNOWN")
1177     SET(GIT_COMMIT_HASH "unknown")
1178     CONFIGURE_FILE(
1179         "${OpenAL_SOURCE_DIR}/version.h.in"
1180         "${OpenAL_BINARY_DIR}/version.h")
1181 ENDIF()
1182
1183 # Needed for openal.pc.in
1184 SET(prefix ${CMAKE_INSTALL_PREFIX})
1185 SET(exec_prefix "\${prefix}")
1186 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1187 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1188 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1189 SET(PACKAGE_VERSION "${LIB_VERSION}")
1190
1191 # End configuration
1192 CONFIGURE_FILE(
1193     "${OpenAL_SOURCE_DIR}/config.h.in"
1194     "${OpenAL_BINARY_DIR}/config.h")
1195 CONFIGURE_FILE(
1196     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1197     "${OpenAL_BINARY_DIR}/openal.pc"
1198     @ONLY)
1199
1200 # Build main library
1201 IF(LIBTYPE STREQUAL "STATIC")
1202     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1203 ELSE()
1204     ADD_LIBRARY(OpenAL SHARED ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1205 ENDIF()
1206 SET_PROPERTY(TARGET OpenAL APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1207 SET_PROPERTY(TARGET OpenAL APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
1208 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1209     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
1210 ENDIF()
1211 SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
1212 IF(HAVE_ALSA)
1213     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIRS})
1214 ENDIF()
1215 IF(HAVE_OSS)
1216     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${OSS_INCLUDE_DIRS})
1217 ENDIF()
1218 IF(HAVE_SOLARIS)
1219     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${AUDIOIO_INCLUDE_DIRS})
1220 ENDIF()
1221 IF(HAVE_SNDIO)
1222     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${SOUNDIO_INCLUDE_DIRS})
1223 ENDIF()
1224 IF(HAVE_QSA)
1225     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${QSA_INCLUDE_DIRS})
1226 ENDIF()
1227 IF(HAVE_DSOUND)
1228     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${DSOUND_INCLUDE_DIRS})
1229 ENDIF()
1230 IF(HAVE_PORTAUDIO)
1231     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${PORTAUDIO_INCLUDE_DIRS})
1232 ENDIF()
1233 IF(HAVE_PULSEAUDIO)
1234     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${PULSEAUDIO_INCLUDE_DIRS})
1235 ENDIF()
1236 IF(HAVE_JACK)
1237     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${JACK_INCLUDE_DIRS})
1238 ENDIF()
1239 IF(WIN32)
1240     IF(MSVC)
1241         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " /SUBSYSTEM:WINDOWS")
1242     ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1243         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " -mwindows")
1244     ENDIF()
1245 ENDIF()
1246
1247 SET_TARGET_PROPERTIES(OpenAL PROPERTIES VERSION ${LIB_VERSION}
1248                                         SOVERSION ${LIB_MAJOR_VERSION})
1249 SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1250
1251 if(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
1252     SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1253
1254     IF(MINGW AND ALSOFT_BUILD_IMPORT_LIB)
1255         FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1256         FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1257         IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1258             MESSAGE(STATUS "")
1259             IF(NOT SED_EXECUTABLE)
1260                 MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1261             ENDIF()
1262             IF(NOT DLLTOOL_EXECUTABLE)
1263                 MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1264             ENDIF()
1265         ELSE()
1266             SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -Wl,--output-def,OpenAL32.def")
1267             ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1268                 COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1269                 COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1270                 COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1271                 VERBATIM
1272             )
1273         ENDIF()
1274     ENDIF()
1275 ENDIF()
1276
1277 SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS ${EXTRA_LDFLAGS})
1278 TARGET_LINK_LIBRARIES(OpenAL ${EXTRA_LIBS})
1279 IF(TARGET build_version)
1280     ADD_DEPENDENCIES(OpenAL build_version)
1281 ENDIF()
1282
1283 IF(ALSOFT_INSTALL)
1284     # Add an install target here
1285     INSTALL(TARGETS OpenAL EXPORT OpenAL
1286             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1287             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1288             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1289             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1290     )
1291     EXPORT(TARGETS OpenAL
1292            NAMESPACE OpenAL::
1293            FILE OpenALConfig.cmake)
1294     INSTALL(EXPORT OpenAL
1295             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1296             NAMESPACE OpenAL::
1297             FILE OpenALConfig.cmake)
1298     INSTALL(FILES include/AL/al.h
1299                   include/AL/alc.h
1300                   include/AL/alext.h
1301                   include/AL/efx.h
1302                   include/AL/efx-creative.h
1303                   include/AL/efx-presets.h
1304             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1305     )
1306     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1307             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1308 ENDIF()
1309
1310
1311 MESSAGE(STATUS "")
1312 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1313 MESSAGE(STATUS "    ${BACKENDS}")
1314 MESSAGE(STATUS "")
1315 MESSAGE(STATUS "Building with support for CPU extensions:")
1316 MESSAGE(STATUS "    ${CPU_EXTS}")
1317 MESSAGE(STATUS "")
1318
1319 IF(WIN32)
1320     IF(NOT HAVE_DSOUND)
1321         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1322         MESSAGE(STATUS "         This is probably NOT what you want!")
1323         MESSAGE(STATUS "")
1324     ENDIF()
1325 ENDIF()
1326
1327 if(ALSOFT_EMBED_HRTF_DATA)
1328     message(STATUS "Embedding HRTF datasets")
1329     message(STATUS "")
1330 endif()
1331
1332 # Install alsoft.conf configuration file
1333 IF(ALSOFT_CONFIG)
1334     INSTALL(FILES alsoftrc.sample
1335             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1336     )
1337     MESSAGE(STATUS "Installing sample configuration")
1338     MESSAGE(STATUS "")
1339 ENDIF()
1340
1341 # Install HRTF definitions
1342 IF(ALSOFT_HRTF_DEFS)
1343     INSTALL(FILES hrtf/default-44100.mhr
1344                   hrtf/default-48000.mhr
1345             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1346     )
1347     MESSAGE(STATUS "Installing HRTF definitions")
1348     MESSAGE(STATUS "")
1349 ENDIF()
1350
1351 # Install AmbDec presets
1352 IF(ALSOFT_AMBDEC_PRESETS)
1353     INSTALL(FILES presets/3D7.1.ambdec
1354                   presets/hexagon.ambdec
1355                   presets/itu5.1.ambdec
1356                   presets/rectangle.ambdec
1357                   presets/square.ambdec
1358                   presets/presets.txt
1359             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1360     )
1361     MESSAGE(STATUS "Installing AmbDec presets")
1362     MESSAGE(STATUS "")
1363 ENDIF()
1364
1365 IF(ALSOFT_UTILS)
1366     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1367     SET_PROPERTY(TARGET openal-info APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1368     TARGET_LINK_LIBRARIES(openal-info OpenAL)
1369
1370     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1371     SET_PROPERTY(TARGET makehrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1372     IF(HAVE_LIBM)
1373         TARGET_LINK_LIBRARIES(makehrtf m)
1374     ENDIF()
1375
1376     ADD_EXECUTABLE(bsincgen utils/bsincgen.c)
1377     SET_PROPERTY(TARGET bsincgen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1378     IF(HAVE_LIBM)
1379         TARGET_LINK_LIBRARIES(bsincgen m)
1380     ENDIF()
1381
1382     IF(ALSOFT_INSTALL)
1383         INSTALL(TARGETS openal-info makehrtf bsincgen
1384                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1385                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1386                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1387         )
1388     ENDIF()
1389
1390     MESSAGE(STATUS "Building utility programs")
1391     IF(TARGET alsoft-config)
1392         MESSAGE(STATUS "Building configuration program")
1393     ENDIF()
1394     MESSAGE(STATUS "")
1395 ENDIF()
1396
1397 IF(ALSOFT_TESTS)
1398     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1399
1400     ADD_EXECUTABLE(altonegen examples/altonegen.c ${COMMON_OBJS} ${TEST_COMMON_OBJS})
1401     TARGET_LINK_LIBRARIES(altonegen OpenAL)
1402     SET_PROPERTY(TARGET altonegen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1403
1404     IF(ALSOFT_INSTALL)
1405         INSTALL(TARGETS altonegen
1406                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1407                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1408                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1409         )
1410     ENDIF()
1411
1412     MESSAGE(STATUS "Building test programs")
1413     MESSAGE(STATUS "")
1414 ENDIF()
1415
1416 IF(ALSOFT_EXAMPLES)
1417     IF(SDL2_FOUND)
1418         IF(SDL_SOUND_FOUND)
1419             SET(EX_COMMON_OBJS  examples/common/alhelpers.c)
1420
1421             ADD_EXECUTABLE(alstream examples/alstream.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1422             TARGET_LINK_LIBRARIES(alstream ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1423             SET_PROPERTY(TARGET alstream APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1424             SET_PROPERTY(TARGET alstream APPEND PROPERTY
1425                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1426             )
1427
1428             ADD_EXECUTABLE(alreverb examples/alreverb.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1429             TARGET_LINK_LIBRARIES(alreverb ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1430             SET_PROPERTY(TARGET alreverb APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1431             SET_PROPERTY(TARGET alreverb APPEND PROPERTY
1432                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1433             )
1434
1435             ADD_EXECUTABLE(allatency examples/allatency.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1436             TARGET_LINK_LIBRARIES(allatency ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1437             SET_PROPERTY(TARGET allatency APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1438             SET_PROPERTY(TARGET allatency APPEND PROPERTY
1439                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1440             )
1441
1442             ADD_EXECUTABLE(alloopback examples/alloopback.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1443             TARGET_LINK_LIBRARIES(alloopback ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1444             SET_PROPERTY(TARGET alloopback APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1445             SET_PROPERTY(TARGET alloopback APPEND PROPERTY
1446                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1447             )
1448
1449             ADD_EXECUTABLE(alhrtf examples/alhrtf.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1450             TARGET_LINK_LIBRARIES(alhrtf ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1451             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1452             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY
1453                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1454             )
1455
1456             IF(ALSOFT_INSTALL)
1457                 INSTALL(TARGETS alstream alreverb allatency alloopback alhrtf
1458                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1459                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1460                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1461                 )
1462             ENDIF()
1463
1464             MESSAGE(STATUS "Building SDL_sound example programs")
1465         ENDIF()
1466
1467         SET(FFVER_OK FALSE)
1468         IF(FFMPEG_FOUND)
1469             SET(FFVER_OK TRUE)
1470             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1471                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1472                 SET(FFVER_OK FALSE)
1473             ENDIF()
1474             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1475                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1476                 SET(FFVER_OK FALSE)
1477             ENDIF()
1478             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1479                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1480                 SET(FFVER_OK FALSE)
1481             ENDIF()
1482             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1483                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1484                 SET(FFVER_OK FALSE)
1485             ENDIF()
1486             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1487                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1488                 SET(FFVER_OK FALSE)
1489             ENDIF()
1490         ENDIF()
1491         IF(FFVER_OK)
1492             ADD_EXECUTABLE(alffplay examples/alffplay.cpp ${COMMON_OBJS})
1493             TARGET_LINK_LIBRARIES(alffplay ${SDL2_LIBRARY} OpenAL ${FFMPEG_LIBRARIES})
1494             SET_PROPERTY(TARGET alffplay APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1495             SET_PROPERTY(TARGET alffplay APPEND PROPERTY
1496                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS}
1497             )
1498
1499             IF(ALSOFT_INSTALL)
1500                 INSTALL(TARGETS alffplay
1501                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1502                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1503                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1504                 )
1505             ENDIF()
1506             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1507         ENDIF()
1508         MESSAGE(STATUS "")
1509     ENDIF()
1510 ENDIF()