CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10   CMAKE_POLICY(SET CMP0042 NEW)
  11 ENDIF(COMMAND CMAKE_POLICY)
  12
  13 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  14
  15 INCLUDE(CheckFunctionExists)
  16 INCLUDE(CheckLibraryExists)
  17 INCLUDE(CheckSharedFunctionExists)
  18 INCLUDE(CheckIncludeFile)
  19 INCLUDE(CheckIncludeFiles)
  20 INCLUDE(CheckSymbolExists)
  21 INCLUDE(CheckCCompilerFlag)
  22 INCLUDE(CheckCSourceCompiles)
  23 INCLUDE(CheckTypeSize)
  24 include(CheckFileOffsetBits)
  25
  26
  27 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  28
  29
  30 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  31
  32 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  33
  34 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  35 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  36
  37 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  38 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  39
  40 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  41 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  42 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  43
  44
  45 set(SHARE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/share" CACHE STRING "The share install dir")
  46
  47
  48 IF(NOT WIN32)
  49     SET(LIBNAME openal)
  50 ELSE()
  51     SET(LIBNAME OpenAL32)
  52     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  53
  54     # This option is mainly for static linking OpenAL Soft into another project
  55     # that already defines the IDs. It is up to that project to ensure all
  56     # required IDs are defined.
  57     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  58
  59     IF(MINGW)
  60         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  61         IF(NOT DLLTOOL)
  62             IF(HOST)
  63                 SET(DLLTOOL "${HOST}-dlltool")
  64             ELSE()
  65                 SET(DLLTOOL "dlltool")
  66             ENDIF()
  67         ENDIF()
  68     ENDIF()
  69 ENDIF()
  70
  71
  72 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  73 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  74     ADD_DEFINITIONS("-I/usr/include")
  75     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  76 ENDIF()
  77
  78 IF(NOT LIBTYPE)
  79     SET(LIBTYPE SHARED)
  80 ENDIF()
  81
  82 SET(LIB_MAJOR_VERSION "1")
  83 SET(LIB_MINOR_VERSION "17")
  84 SET(LIB_REVISION "1")
  85 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
  86
  87 SET(EXPORT_DECL "")
  88 SET(ALIGN_DECL "")
  89
  90
  91 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  92 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
  93
  94
  95 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
  96 IF(HAVE_STD_C11)
  97     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
  98 ELSE()
  99     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 100     IF(HAVE_STD_C99)
 101         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 102     ENDIF()
 103 ENDIF()
 104
 105 if(NOT WIN32)
 106     # Check if _POSIX_C_SOURCE needs to be set for POSIX functions
 107     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 108     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 109         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 110         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200809L")
 111         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 112         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 113             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 114         ELSE()
 115             ADD_DEFINITIONS(-D_POSIX_C_SOURCE=200809L)
 116         ENDIF()
 117     ENDIF()
 118
 119     # Check if _XOPEN_SOURCE needs to be set (if POSIX < 2008)
 120     CHECK_SYMBOL_EXISTS(scandir dirent.h HAVE_SCANDIR_DEFAULT)
 121     IF(NOT HAVE_SCANDIR_DEFAULT)
 122         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 123         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_XOPEN_SOURCE=700")
 124         CHECK_SYMBOL_EXISTS(scandir dirent.h HAVE_SCANDIR_XOPEN)
 125         IF(NOT HAVE_SCANDIR_XOPEN)
 126             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 127         ELSE()
 128             ADD_DEFINITIONS(-D_XOPEN_SOURCE=700)
 129         ENDIF()
 130     ENDIF()
 131     UNSET(OLD_REQUIRED_FLAGS)
 132 ENDIF()
 133
 134 # Set defines for large file support
 135 CHECK_FILE_OFFSET_BITS()
 136 IF(_FILE_OFFSET_BITS)
 137     ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS})
 138     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 139 ENDIF()
 140 ADD_DEFINITIONS(-D_LARGEFILE_SOURCE -D_LARGE_FILES)
 141 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 142
 143 # MSVC may need workarounds for C99 restrict and inline
 144 IF(MSVC)
 145     # TODO: Once we truly require C99, these restrict and inline checks should go
 146     # away.
 147     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 148                              int main() {return 0;}" HAVE_RESTRICT)
 149     IF(NOT HAVE_RESTRICT)
 150         ADD_DEFINITIONS("-Drestrict=")
 151         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 152     ENDIF()
 153
 154     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 155                              int main() {return 0;}" HAVE_INLINE)
 156     IF(NOT HAVE_INLINE)
 157         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 158                                  int main() {return 0;}" HAVE___INLINE)
 159         IF(NOT HAVE___INLINE)
 160             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 161         ENDIF()
 162
 163         ADD_DEFINITIONS(-Dinline=__inline)
 164         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 165     ENDIF()
 166 ENDIF()
 167
 168 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 169 IF(CMAKE_COMPILER_IS_GNUCC)
 170     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 171     # Force no inlining for the next test.
 172     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 173
 174     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 175                              int main() {return foo();}" INLINE_IS_C99)
 176     IF(NOT INLINE_IS_C99)
 177         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 178                              Please update your compiler for better C99 compliance.")
 179     ENDIF()
 180
 181     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 182 ENDIF()
 183
 184 # Check if we have C99 variable length arrays
 185 CHECK_C_SOURCE_COMPILES(
 186 "int main(int argc, char *argv[])
 187  {
 188      volatile int tmp[argc];
 189      tmp[0] = argv[0][0];
 190      return tmp[0];
 191  }"
 192 HAVE_C99_VLA)
 193
 194 # Check if we have C99 bool
 195 CHECK_C_SOURCE_COMPILES(
 196 "int main(int argc, char *argv[])
 197  {
 198      volatile _Bool ret;
 199      ret = (argc > 1) ? 1 : 0;
 200      return ret ? -1 : 0;
 201  }"
 202 HAVE_C99_BOOL)
 203
 204 # Check if we have C11 static_assert
 205 CHECK_C_SOURCE_COMPILES(
 206 "int main()
 207  {
 208      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 209      return 0;
 210  }"
 211 HAVE_C11_STATIC_ASSERT)
 212
 213 # Check if we have C11 alignas
 214 CHECK_C_SOURCE_COMPILES(
 215 "_Alignas(16) int foo;
 216  int main()
 217  {
 218      return 0;
 219  }"
 220 HAVE_C11_ALIGNAS)
 221
 222 # Check if we have C11 _Atomic
 223 CHECK_C_SOURCE_COMPILES(
 224 "#include <stdatomic.h>
 225  const int _Atomic foo = ATOMIC_VAR_INIT(~0);
 226  int main()
 227  {
 228      return atomic_load(&foo);
 229  }"
 230 HAVE_C11_ATOMIC)
 231
 232 # Add definitions, compiler switches, etc.
 233 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 234 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 235     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 236     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 237         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 238     ENDIF()
 239 ENDIF()
 240
 241 IF(NOT CMAKE_BUILD_TYPE)
 242     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 243         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 244         FORCE)
 245 ENDIF()
 246 IF(NOT CMAKE_DEBUG_POSTFIX)
 247     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 248         "Library postfix for debug builds. Normally left blank."
 249         FORCE)
 250 ENDIF()
 251
 252 IF(MSVC)
 253     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 254     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 255     ADD_DEFINITIONS("/wd4098")
 256
 257     IF(NOT DXSDK_DIR)
 258         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 259     ELSE()
 260         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 261     ENDIF()
 262     IF(DXSDK_DIR)
 263         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 264     ENDIF()
 265
 266     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 267     IF(FORCE_STATIC_VCRT)
 268         FOREACH(flag_var
 269                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 270                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 271             IF(${flag_var} MATCHES "/MD")
 272                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 273             ENDIF()
 274         ENDFOREACH(flag_var)
 275     ENDIF()
 276 ELSE()
 277     ADD_DEFINITIONS(-Winline -Wall)
 278     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 279     IF(HAVE_W_EXTRA)
 280         ADD_DEFINITIONS(-Wextra)
 281     ENDIF()
 282
 283     IF(ALSOFT_WERROR)
 284         ADD_DEFINITIONS(-Werror)
 285     ENDIF()
 286
 287     # Force enable -fPIC for CMake versions before 2.8.9 (later versions have
 288     # the POSITION_INDEPENDENT_CODE target property). The static common library
 289     # will be linked into the dynamic openal library, which requires all its
 290     # code to be position-independent.
 291     IF(CMAKE_VERSION VERSION_LESS "2.8.9" AND NOT WIN32)
 292         CHECK_C_COMPILER_FLAG(-fPIC HAVE_FPIC_SWITCH)
 293         IF(HAVE_FPIC_SWITCH)
 294             ADD_DEFINITIONS(-fPIC)
 295         ENDIF()
 296     ENDIF()
 297
 298     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 299     # instead of NDEBUG)
 300     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 301         IF(${flag_var} MATCHES "-DNDEBUG")
 302             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 303         ENDIF()
 304     ENDFOREACH()
 305
 306     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 307                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 308
 309     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 310     if(ALSOFT_STATIC_LIBGCC)
 311         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 312         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 313         check_c_source_compiles(
 314 "#include <stdlib.h>
 315 int main()
 316 {
 317     return 0;
 318 }"
 319             HAVE_STATIC_LIBGCC_SWITCH
 320         )
 321         if(HAVE_STATIC_LIBGCC_SWITCH)
 322             set(EXTRA_LIBS ${EXTRA_LIBS} -static-libgcc)
 323         endif()
 324         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 325         unset(OLD_REQUIRED_LIBRARIES)
 326     endif()
 327 ENDIF()
 328
 329 # Set visibility/export options if available
 330 IF(WIN32)
 331     SET(EXPORT_DECL "__declspec(dllexport)")
 332     IF(NOT MINGW)
 333         SET(ALIGN_DECL "__declspec(align(x))")
 334     ELSE()
 335         SET(ALIGN_DECL "__declspec(aligned(x))")
 336     ENDIF()
 337 ELSE()
 338     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 339     # Yes GCC, really don't accept visibility modes you don't support
 340     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 341
 342     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 343                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 344     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 345         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 346     ELSE()
 347         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 348                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 349         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 350             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 351         ENDIF()
 352     ENDIF()
 353
 354     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 355         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 356         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 357             ADD_DEFINITIONS(-fvisibility=hidden)
 358         ENDIF()
 359     ENDIF()
 360
 361     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 362                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 363     IF(HAVE_ATTRIBUTE_ALIGNED)
 364         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 365     ENDIF()
 366
 367     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 368 ENDIF()
 369
 370 SET(SSE_SWITCH "")
 371 SET(SSE2_SWITCH "")
 372 SET(SSE4_1_SWITCH "")
 373 IF(NOT MSVC)
 374     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 375     IF(HAVE_MSSE_SWITCH)
 376         SET(SSE_SWITCH "-msse")
 377     ENDIF()
 378     CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 379     IF(HAVE_MSSE2_SWITCH)
 380         SET(SSE2_SWITCH "-msse2")
 381     ENDIF()
 382     CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 383     IF(HAVE_MSSE3_SWITCH)
 384         SET(SSE3_SWITCH "-msse3")
 385     ENDIF()
 386     CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 387     IF(HAVE_MSSE4_1_SWITCH)
 388         SET(SSE4_1_SWITCH "-msse4.1")
 389     ENDIF()
 390 ENDIF()
 391
 392 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 393                          int main() {return 0;}" HAVE_GCC_FORMAT)
 394
 395 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 396 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 397 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 398 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 399 CHECK_INCLUDE_FILE(io.h HAVE_IO_H)
 400 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 401 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 402 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 403 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 404 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 405 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 406 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 407 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 408 IF(NOT HAVE_GUIDDEF_H)
 409     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 410 ENDIF()
 411
 412 IF(HAVE_CPUID_H)
 413     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 414         int main()
 415         {
 416             unsigned int eax, ebx, ecx, edx;
 417             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 418         }" HAVE_GCC_GET_CPUID)
 419 ENDIF()
 420
 421 IF(HAVE_INTRIN_H)
 422     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 423         int main()
 424         {
 425             int regs[4];
 426             __cpuid(regs, 0);
 427             return regs[0];
 428         }" HAVE_CPUID_INTRINSIC)
 429 ENDIF()
 430
 431 # Some systems need libm for some of the following math functions to work
 432 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 433 IF(HAVE_LIBM)
 434     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 435     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 436 ENDIF()
 437
 438
 439 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 440 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 441 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 442 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 443 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 444 IF(NOT HAVE_C99_VLA)
 445     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 446     IF(NOT HAVE_ALLOCA)
 447         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 448     ENDIF()
 449 ENDIF()
 450
 451 IF(HAVE_FLOAT_H)
 452     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 453     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 454 ENDIF()
 455
 456 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 457 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 458 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 459 IF(NOT HAVE_STRCASECMP)
 460     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 461     IF(NOT HAVE__STRICMP)
 462         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 463     ENDIF()
 464
 465     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 466 ENDIF()
 467
 468 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 469 IF(NOT HAVE_STRNCASECMP)
 470     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 471     IF(NOT HAVE__STRNICMP)
 472         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 473     ENDIF()
 474
 475     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 476 ENDIF()
 477
 478 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 479 IF(NOT HAVE_SNPRINTF)
 480     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 481     IF(NOT HAVE__SNPRINTF)
 482         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 483     ENDIF()
 484
 485     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 486 ENDIF()
 487
 488 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 489 IF(NOT HAVE_ISFINITE)
 490     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 491     IF(NOT HAVE_FINITE)
 492         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 493         IF(NOT HAVE__FINITE)
 494             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 495         ENDIF()
 496         ADD_DEFINITIONS(-Disfinite=_finite)
 497     ELSE()
 498         ADD_DEFINITIONS(-Disfinite=finite)
 499     ENDIF()
 500 ENDIF()
 501
 502 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 503 IF(NOT HAVE_ISNAN)
 504     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 505     IF(NOT HAVE__ISNAN)
 506         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 507     ENDIF()
 508
 509     ADD_DEFINITIONS(-Disnan=_isnan)
 510 ENDIF()
 511
 512
 513 # Check for the dlopen API (for dynamicly loading backend libs)
 514 IF(ALSOFT_DLOPEN)
 515     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 516     IF(HAVE_DLFCN_H)
 517         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 518         IF(HAVE_LIBDL)
 519             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 520         ENDIF()
 521     ENDIF()
 522 ENDIF()
 523
 524 # Check if we have Windows headers
 525 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 526 IF(NOT HAVE_WINDOWS_H)
 527     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 528     IF(NOT HAVE_GETTIMEOFDAY)
 529         MESSAGE(FATAL_ERROR "No timing function found!")
 530     ENDIF()
 531
 532     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 533     IF(NOT HAVE_NANOSLEEP)
 534         MESSAGE(FATAL_ERROR "No sleep function found!")
 535     ENDIF()
 536
 537     # We need pthreads outside of Windows
 538     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 539     IF(NOT HAVE_PTHREAD_H)
 540         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 541     ENDIF()
 542     # Some systems need pthread_np.h to get recursive mutexes
 543     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 544
 545     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 546     IF(HAVE_PTHREAD)
 547         ADD_DEFINITIONS(-pthread)
 548         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 549         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 550     ENDIF()
 551
 552     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 553     IF(HAVE_LIBPTHREAD)
 554         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 555     ENDIF()
 556
 557     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 558
 559     IF(HAVE_PTHREAD_NP_H)
 560         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 561         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 562             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 563         ENDIF()
 564         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 565     ELSE()
 566         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 567         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 568             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 569         ENDIF()
 570         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 571     ENDIF()
 572
 573     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 574
 575     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 576     IF(HAVE_LIBRT)
 577         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 578     ENDIF()
 579 ENDIF()
 580
 581 # Check for a 64-bit type
 582 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 583 IF(NOT HAVE_STDINT_H)
 584     IF(HAVE_WINDOWS_H)
 585         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 586                                  #include <windows.h>
 587                                  __int64 foo;
 588                                  int main() {return 0;}" HAVE___INT64)
 589     ENDIF()
 590     IF(NOT HAVE___INT64)
 591         IF(NOT SIZEOF_LONG MATCHES "8")
 592             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 593                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 594             ENDIF()
 595         ENDIF()
 596     ENDIF()
 597 ENDIF()
 598
 599
 600 SET(COMMON_OBJS  common/atomic.c
 601                  common/rwlock.c
 602                  common/threads.c
 603                  common/uintmap.c
 604 )
 605 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 606                  OpenAL32/alBuffer.c
 607                  OpenAL32/alEffect.c
 608                  OpenAL32/alError.c
 609                  OpenAL32/alExtension.c
 610                  OpenAL32/alFilter.c
 611                  OpenAL32/alListener.c
 612                  OpenAL32/alSource.c
 613                  OpenAL32/alState.c
 614                  OpenAL32/alThunk.c
 615                  OpenAL32/sample_cvt.c
 616 )
 617 SET(ALC_OBJS  Alc/ALc.c
 618               Alc/ALu.c
 619               Alc/alcConfig.c
 620               Alc/alcRing.c
 621               Alc/bs2b.c
 622               Alc/effects/autowah.c
 623               Alc/effects/chorus.c
 624               Alc/effects/compressor.c
 625               Alc/effects/dedicated.c
 626               Alc/effects/distortion.c
 627               Alc/effects/echo.c
 628               Alc/effects/equalizer.c
 629               Alc/effects/flanger.c
 630               Alc/effects/modulator.c
 631               Alc/effects/null.c
 632               Alc/effects/reverb.c
 633               Alc/helpers.c
 634               Alc/bsinc.c
 635               Alc/hrtf.c
 636               Alc/panning.c
 637               Alc/mixer.c
 638               Alc/mixer_c.c
 639 )
 640
 641
 642 SET(CPU_EXTS "Default")
 643 SET(HAVE_SSE        0)
 644 SET(HAVE_SSE2       0)
 645 SET(HAVE_SSE3       0)
 646 SET(HAVE_SSE4_1     0)
 647 SET(HAVE_NEON       0)
 648
 649 SET(HAVE_ALSA       0)
 650 SET(HAVE_OSS        0)
 651 SET(HAVE_SOLARIS    0)
 652 SET(HAVE_SNDIO      0)
 653 SET(HAVE_QSA        0)
 654 SET(HAVE_DSOUND     0)
 655 SET(HAVE_MMDEVAPI   0)
 656 SET(HAVE_WINMM      0)
 657 SET(HAVE_PORTAUDIO  0)
 658 SET(HAVE_PULSEAUDIO 0)
 659 SET(HAVE_COREAUDIO  0)
 660 SET(HAVE_OPENSL     0)
 661 SET(HAVE_WAVE       0)
 662
 663 # Check for SSE support
 664 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 665 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 666 IF(HAVE_XMMINTRIN_H)
 667     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 668     IF(ALSOFT_CPUEXT_SSE)
 669         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 670             SET(HAVE_SSE 1)
 671             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 672             IF(SSE_SWITCH)
 673                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 674                                             COMPILE_FLAGS "${SSE_SWITCH}")
 675             ENDIF()
 676             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 677         ENDIF()
 678     ENDIF()
 679 ENDIF()
 680 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 681     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 682 ENDIF()
 683
 684 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 685 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 686 IF(HAVE_EMMINTRIN_H)
 687     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 688     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 689         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 690             SET(HAVE_SSE2 1)
 691             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 692             IF(SSE2_SWITCH)
 693                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 694                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 695             ENDIF()
 696             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 697         ENDIF()
 698     ENDIF()
 699 ENDIF()
 700 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 701     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 702 ENDIF()
 703
 704 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 705 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 706 IF(HAVE_EMMINTRIN_H)
 707     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 708     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 709         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 710             SET(HAVE_SSE3 1)
 711             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse3.c)
 712             IF(SSE2_SWITCH)
 713                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse3.c PROPERTIES
 714                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 715             ENDIF()
 716             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 717         ENDIF()
 718     ENDIF()
 719 ENDIF()
 720 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 721     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 722 ENDIF()
 723
 724 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 725 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 726 IF(HAVE_SMMINTRIN_H)
 727     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 728     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 729         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 730             SET(HAVE_SSE4_1 1)
 731             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 732             IF(SSE4_1_SWITCH)
 733                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 734                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 735             ENDIF()
 736             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 737         ENDIF()
 738     ENDIF()
 739 ENDIF()
 740 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 741     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 742 ENDIF()
 743
 744 # Check for ARM Neon support
 745 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 746 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 747 IF(HAVE_ARM_NEON_H)
 748     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 749     IF(ALSOFT_CPUEXT_NEON)
 750         SET(HAVE_NEON 1)
 751         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 752         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 753     ENDIF()
 754 ENDIF()
 755 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 756     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 757 ENDIF()
 758
 759
 760 IF(WIN32 OR HAVE_DLFCN_H)
 761     SET(IS_LINKED "")
 762     MACRO(ADD_BACKEND_LIBS _LIBS)
 763     ENDMACRO()
 764 ELSE()
 765     SET(IS_LINKED " (linked)")
 766     MACRO(ADD_BACKEND_LIBS _LIBS)
 767         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 768     ENDMACRO()
 769 ENDIF()
 770
 771 SET(BACKENDS "")
 772 SET(ALC_OBJS  ${ALC_OBJS}
 773               Alc/backends/base.c
 774               # Default backends, always available
 775               Alc/backends/loopback.c
 776               Alc/backends/null.c
 777 )
 778
 779 # Check ALSA backend
 780 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 781 FIND_PACKAGE(ALSA)
 782 IF(ALSA_FOUND)
 783     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 784     IF(ALSOFT_BACKEND_ALSA)
 785         SET(HAVE_ALSA 1)
 786         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 787         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 788         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 789         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 790             INCLUDE_DIRECTORIES(${ALSA_INCLUDE_DIRS})
 791         ENDIF()
 792     ENDIF()
 793 ENDIF()
 794 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 795     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 796 ENDIF()
 797
 798 # Check OSS backend
 799 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 800 FIND_PACKAGE(OSS)
 801 IF(OSS_FOUND)
 802     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 803     IF(ALSOFT_BACKEND_OSS)
 804         SET(HAVE_OSS 1)
 805         SET(BACKENDS  "${BACKENDS} OSS,")
 806         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 807         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 808             INCLUDE_DIRECTORIES(${OSS_INCLUDE_DIRS})
 809         ENDIF()
 810     ENDIF()
 811 ENDIF()
 812 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 813     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 814 ENDIF()
 815
 816 # Check Solaris backend
 817 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 818 FIND_PACKAGE(AudioIO)
 819 IF(AUDIOIO_FOUND)
 820     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 821     IF(ALSOFT_BACKEND_SOLARIS)
 822         SET(HAVE_SOLARIS 1)
 823         SET(BACKENDS  "${BACKENDS} Solaris,")
 824         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 825         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 826             INCLUDE_DIRECTORIES(${AUDIOIO_INCLUDE_DIRS})
 827         ENDIF()
 828     ENDIF()
 829 ENDIF()
 830 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 831     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 832 ENDIF()
 833
 834 # Check SndIO backend
 835 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 836 FIND_PACKAGE(SoundIO)
 837 IF(SOUNDIO_FOUND)
 838     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 839     IF(ALSOFT_BACKEND_SNDIO)
 840         SET(HAVE_SNDIO 1)
 841         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 842         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 843         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 844         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 845             INCLUDE_DIRECTORIES(${SOUNDIO_INCLUDE_DIRS})
 846         ENDIF()
 847     ENDIF()
 848 ENDIF()
 849 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 850     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 851 ENDIF()
 852
 853 # Check QSA backend
 854 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 855 FIND_PACKAGE(QSA)
 856 IF(QSA_FOUND)
 857     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 858     IF(ALSOFT_BACKEND_QSA)
 859         SET(HAVE_QSA 1)
 860         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 861         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 862         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 863         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 864             INCLUDE_DIRECTORIES(${QSA_INCLUDE_DIRS})
 865         ENDIF()
 866     ENDIF()
 867 ENDIF()
 868 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 869     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 870 ENDIF()
 871
 872 # Check Windows-only backends
 873 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 874 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 875 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 876 IF(HAVE_WINDOWS_H)
 877     # Check MMSystem backend
 878     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 879     IF(HAVE_MMSYSTEM_H)
 880         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 881         IF(HAVE_LIBWINMM)
 882             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 883             IF(ALSOFT_BACKEND_WINMM)
 884                 SET(HAVE_WINMM 1)
 885                 SET(BACKENDS  "${BACKENDS} WinMM,")
 886                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 887                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 888             ENDIF()
 889         ENDIF()
 890     ENDIF()
 891
 892     # Check DSound backend
 893     FIND_PACKAGE(DSound)
 894     IF(DSOUND_FOUND)
 895         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 896         IF(ALSOFT_BACKEND_DSOUND)
 897             SET(HAVE_DSOUND 1)
 898             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 899             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 900             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 901             IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 902                 INCLUDE_DIRECTORIES(${DSOUND_INCLUDE_DIRS})
 903             ENDIF()
 904         ENDIF()
 905     ENDIF()
 906
 907     # Check for MMDevApi backend
 908     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 909     IF(HAVE_MMDEVICEAPI_H)
 910         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 911         IF(ALSOFT_BACKEND_MMDEVAPI)
 912             SET(HAVE_MMDEVAPI 1)
 913             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 914             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 915         ENDIF()
 916     ENDIF()
 917 ENDIF()
 918 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 919     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 920 ENDIF()
 921 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 922     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 923 ENDIF()
 924 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 925     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 926 ENDIF()
 927
 928 # Check PortAudio backend
 929 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 930 FIND_PACKAGE(PortAudio)
 931 IF(PORTAUDIO_FOUND)
 932     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 933     IF(ALSOFT_BACKEND_PORTAUDIO)
 934         SET(HAVE_PORTAUDIO 1)
 935         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
 936         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 937         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
 938         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 939             INCLUDE_DIRECTORIES(${PORTAUDIO_INCLUDE_DIRS})
 940         ENDIF()
 941     ENDIF()
 942 ENDIF()
 943 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 944     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 945 ENDIF()
 946
 947 # Check PulseAudio backend
 948 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
 949 FIND_PACKAGE(PulseAudio)
 950 IF(PULSEAUDIO_FOUND)
 951     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
 952     IF(ALSOFT_BACKEND_PULSEAUDIO)
 953         SET(HAVE_PULSEAUDIO 1)
 954         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
 955         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 956         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
 957         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 958             INCLUDE_DIRECTORIES(${PULSEAUDIO_INCLUDE_DIRS})
 959         ENDIF()
 960     ENDIF()
 961 ENDIF()
 962 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 963     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 964 ENDIF()
 965
 966 # Check JACK backend
 967 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
 968 FIND_PACKAGE(JACK)
 969 IF(JACK_FOUND)
 970     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
 971     IF(ALSOFT_BACKEND_JACK)
 972         SET(HAVE_JACK 1)
 973         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
 974         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
 975         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
 976         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 977             INCLUDE_DIRECTORIES(${JACK_INCLUDE_DIRS})
 978         ENDIF()
 979     ENDIF()
 980 ENDIF()
 981 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
 982     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
 983 ENDIF()
 984
 985 # Check CoreAudio backend
 986 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
 987 FIND_LIBRARY(COREAUDIO_FRAMEWORK
 988              NAMES CoreAudio
 989              PATHS /System/Library/Frameworks
 990 )
 991 IF(COREAUDIO_FRAMEWORK)
 992     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
 993     IF(ALSOFT_BACKEND_COREAUDIO)
 994         SET(HAVE_COREAUDIO 1)
 995         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 996         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 997         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
 998         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 999         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1000
1001         # Some versions of OSX may need the AudioToolbox framework. Add it if
1002         # it's found.
1003         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1004                      NAMES AudioToolbox
1005                      PATHS ~/Library/Frameworks
1006                            /Library/Frameworks
1007                            /System/Library/Frameworks
1008                     )
1009         IF(AUDIOTOOLBOX_LIBRARY)
1010             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1011         ENDIF()
1012     ENDIF()
1013 ENDIF()
1014 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1015     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1016 ENDIF()
1017
1018 # Check for OpenSL (Android) backend
1019 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1020 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1021 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1022     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1023     IF(HAVE_LIBOPENSLES)
1024         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1025         IF(ALSOFT_BACKEND_OPENSL)
1026             SET(HAVE_OPENSL 1)
1027             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1028             SET(BACKENDS  "${BACKENDS} OpenSL,")
1029             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1030         ENDIF()
1031     ENDIF()
1032 ENDIF()
1033 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1034     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1035 ENDIF()
1036
1037 # Optionally enable the Wave Writer backend
1038 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1039 IF(ALSOFT_BACKEND_WAVE)
1040     SET(HAVE_WAVE 1)
1041     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1042     SET(BACKENDS  "${BACKENDS} WaveFile,")
1043 ENDIF()
1044
1045 # This is always available
1046 SET(BACKENDS  "${BACKENDS} Null")
1047
1048 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1049     add_subdirectory(utils/alsoft-config)
1050 ENDIF()
1051 IF(ALSOFT_EXAMPLES)
1052     FIND_PACKAGE(SDL2)
1053     IF(SDL2_FOUND)
1054         FIND_PACKAGE(SDL_sound)
1055         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
1056             INCLUDE_DIRECTORIES(${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1057         ENDIF()
1058         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1059         IF(FFMPEG_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
1060             INCLUDE_DIRECTORIES(${FFMPEG_INCLUDE_DIRS})
1061         ENDIF()
1062     ENDIF()
1063 ENDIF()
1064
1065 IF(LIBTYPE STREQUAL "STATIC")
1066     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
1067     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1068 ENDIF()
1069
1070 # Needed for openal.pc.in
1071 SET(prefix ${CMAKE_INSTALL_PREFIX})
1072 SET(exec_prefix "\${prefix}")
1073 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
1074 SET(bindir "\${exec_prefix}/bin")
1075 SET(includedir "\${prefix}/include")
1076 SET(PACKAGE_VERSION "${LIB_VERSION}")
1077
1078 # End configuration
1079 CONFIGURE_FILE(
1080     "${OpenAL_SOURCE_DIR}/config.h.in"
1081     "${OpenAL_BINARY_DIR}/config.h")
1082 CONFIGURE_FILE(
1083     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1084     "${OpenAL_BINARY_DIR}/openal.pc"
1085     @ONLY)
1086
1087 # Build a common library with reusable helpers
1088 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
1089 IF(NOT LIBTYPE STREQUAL "STATIC")
1090     SET_PROPERTY(TARGET common PROPERTY POSITION_INDEPENDENT_CODE TRUE)
1091 ENDIF()
1092
1093 # Build main library
1094 IF(LIBTYPE STREQUAL "STATIC")
1095     ADD_LIBRARY(${LIBNAME} STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1096 ELSE()
1097     ADD_LIBRARY(${LIBNAME} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
1098 ENDIF()
1099 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
1100 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1101     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
1102 ENDIF()
1103 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
1104 IF(HAVE_ALSA)
1105     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIRS})
1106 ENDIF()
1107 IF(HAVE_OSS)
1108     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${OSS_INCLUDE_DIRS})
1109 ENDIF()
1110 IF(HAVE_SOLARIS)
1111     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${AUDIOIO_INCLUDE_DIRS})
1112 ENDIF()
1113 IF(HAVE_SNDIO)
1114     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${SOUNDIO_INCLUDE_DIRS})
1115 ENDIF()
1116 IF(HAVE_QSA)
1117     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${QSA_INCLUDE_DIRS})
1118 ENDIF()
1119 IF(HAVE_DSOUND)
1120     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${DSOUND_INCLUDE_DIRS})
1121 ENDIF()
1122 IF(HAVE_PORTAUDIO)
1123     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PORTAUDIO_INCLUDE_DIRS})
1124 ENDIF()
1125 IF(HAVE_PULSEAUDIO)
1126     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PULSEAUDIO_INCLUDE_DIRS})
1127 ENDIF()
1128 IF(HAVE_JACK)
1129     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${JACK_INCLUDE_DIRS})
1130 ENDIF()
1131 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
1132                                             SOVERSION ${LIB_MAJOR_VERSION})
1133 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
1134     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
1135
1136     IF(MINGW AND ALSOFT_BUILD_IMPORT_LIB)
1137         FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1138         FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1139         IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1140             MESSAGE(STATUS "")
1141             IF(NOT SED_EXECUTABLE)
1142                 MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1143             ENDIF()
1144             IF(NOT DLLTOOL_EXECUTABLE)
1145                 MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1146             ENDIF()
1147         ELSE()
1148             SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES LINK_FLAGS "-Wl,--output-def,${LIBNAME}.def")
1149             ADD_CUSTOM_COMMAND(TARGET ${LIBNAME} POST_BUILD
1150                 COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" ${LIBNAME}.def
1151                 COMMAND "${DLLTOOL_EXECUTABLE}" -d ${LIBNAME}.def -l ${LIBNAME}.lib -D ${LIBNAME}.dll
1152                 COMMENT "Stripping ordinals from ${LIBNAME}.def and generating ${LIBNAME}.lib..."
1153                 VERBATIM
1154             )
1155         ENDIF()
1156     ENDIF()
1157 ENDIF()
1158
1159 TARGET_LINK_LIBRARIES(${LIBNAME} common ${EXTRA_LIBS})
1160
1161 IF(ALSOFT_INSTALL)
1162     # Add an install target here
1163     INSTALL(TARGETS ${LIBNAME}
1164             RUNTIME DESTINATION bin
1165             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1166             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1167     )
1168     INSTALL(FILES include/AL/al.h
1169                   include/AL/alc.h
1170                   include/AL/alext.h
1171                   include/AL/efx.h
1172                   include/AL/efx-creative.h
1173                   include/AL/efx-presets.h
1174             DESTINATION include/AL
1175     )
1176     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1177             DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
1178 ENDIF()
1179
1180
1181 MESSAGE(STATUS "")
1182 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1183 MESSAGE(STATUS "    ${BACKENDS}")
1184 MESSAGE(STATUS "")
1185 MESSAGE(STATUS "Building with support for CPU extensions:")
1186 MESSAGE(STATUS "    ${CPU_EXTS}")
1187 MESSAGE(STATUS "")
1188
1189 IF(WIN32)
1190     IF(NOT HAVE_DSOUND)
1191         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1192         MESSAGE(STATUS "         This is probably NOT what you want!")
1193         MESSAGE(STATUS "")
1194     ENDIF()
1195 ENDIF()
1196
1197 # Install alsoft.conf configuration file
1198 IF(ALSOFT_CONFIG)
1199     INSTALL(FILES alsoftrc.sample
1200             DESTINATION ${SHARE_INSTALL_DIR}/openal
1201     )
1202     MESSAGE(STATUS "Installing sample configuration")
1203     MESSAGE(STATUS "")
1204 ENDIF()
1205
1206 # Install HRTF definitions
1207 IF(ALSOFT_HRTF_DEFS)
1208     INSTALL(FILES hrtf/default-44100.mhr
1209                   hrtf/default-48000.mhr
1210             DESTINATION ${SHARE_INSTALL_DIR}/openal/hrtf
1211     )
1212     MESSAGE(STATUS "Installing HRTF definitions")
1213     MESSAGE(STATUS "")
1214 ENDIF()
1215
1216 IF(ALSOFT_UTILS)
1217     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1218     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
1219
1220     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1221     IF(HAVE_LIBM)
1222         TARGET_LINK_LIBRARIES(makehrtf m)
1223     ENDIF()
1224
1225     ADD_EXECUTABLE(bsincgen utils/bsincgen.c)
1226     IF(HAVE_LIBM)
1227         TARGET_LINK_LIBRARIES(bsincgen m)
1228     ENDIF()
1229
1230     IF(ALSOFT_INSTALL)
1231         INSTALL(TARGETS openal-info makehrtf bsincgen
1232                 RUNTIME DESTINATION bin
1233                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1234                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1235         )
1236     ENDIF()
1237
1238     MESSAGE(STATUS "Building utility programs")
1239     IF(TARGET alsoft-config)
1240         MESSAGE(STATUS "Building configuration program")
1241     ENDIF()
1242     MESSAGE(STATUS "")
1243 ENDIF()
1244
1245 IF(ALSOFT_TESTS)
1246         ADD_LIBRARY(test-common STATIC examples/common/alhelpers.c)
1247
1248         ADD_EXECUTABLE(altonegen examples/altonegen.c)
1249         TARGET_LINK_LIBRARIES(altonegen test-common ${LIBNAME})
1250
1251         IF(ALSOFT_INSTALL)
1252             INSTALL(TARGETS altonegen
1253                     RUNTIME DESTINATION bin
1254                     LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1255                     ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1256             )
1257         ENDIF()
1258
1259         MESSAGE(STATUS "Building test programs")
1260         MESSAGE(STATUS "")
1261 ENDIF()
1262
1263 IF(ALSOFT_EXAMPLES)
1264     IF(SDL2_FOUND AND SDL_SOUND_FOUND)
1265         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
1266                                      examples/common/sdl_sound.c)
1267         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1268                                                                           ${SDL_SOUND_INCLUDE_DIR})
1269
1270         ADD_EXECUTABLE(alstream examples/alstream.c)
1271         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1272                                        common ${LIBNAME})
1273         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1274                                                                          ${SDL_SOUND_INCLUDE_DIR})
1275
1276         ADD_EXECUTABLE(alreverb examples/alreverb.c)
1277         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1278                                        common ${LIBNAME})
1279         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1280                                                                          ${SDL_SOUND_INCLUDE_DIR})
1281
1282         ADD_EXECUTABLE(allatency examples/allatency.c)
1283         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1284                                         common ${LIBNAME})
1285         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1286                                                                           ${SDL_SOUND_INCLUDE_DIR})
1287
1288         ADD_EXECUTABLE(alloopback examples/alloopback.c)
1289         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1290                                          common ${LIBNAME})
1291         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1292                                                                            ${SDL_SOUND_INCLUDE_DIR})
1293
1294         ADD_EXECUTABLE(alhrtf examples/alhrtf.c)
1295         TARGET_LINK_LIBRARIES(alhrtf ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1296                                      common ${LIBNAME})
1297         SET_PROPERTY(TARGET alhrtf APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1298                                                                        ${SDL_SOUND_INCLUDE_DIR})
1299
1300         IF(ALSOFT_INSTALL)
1301             INSTALL(TARGETS alstream alreverb allatency alloopback alhrtf
1302                     RUNTIME DESTINATION bin
1303                     LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1304                     ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1305             )
1306         ENDIF()
1307
1308         SET(FFVER_OK FALSE)
1309         IF(FFMPEG_FOUND)
1310             SET(FFVER_OK TRUE)
1311             IF(AVFORMAT_VERSION VERSION_LESS "55.33.100")
1312                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 55.33.100)")
1313                 SET(FFVER_OK FALSE)
1314             ENDIF()
1315             IF(AVCODEC_VERSION VERSION_LESS "55.52.102")
1316                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 55.52.102)")
1317                 SET(FFVER_OK FALSE)
1318             ENDIF()
1319             IF(AVUTIL_VERSION VERSION_LESS "52.66.100")
1320                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 52.66.100)")
1321                 SET(FFVER_OK FALSE)
1322             ENDIF()
1323             IF(SWSCALE_VERSION VERSION_LESS "2.5.102")
1324                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 2.5.102)")
1325                 SET(FFVER_OK FALSE)
1326             ENDIF()
1327             IF(SWRESAMPLE_VERSION VERSION_LESS "0.18.100")
1328                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 0.18.100)")
1329                 SET(FFVER_OK FALSE)
1330             ENDIF()
1331         ENDIF()
1332         IF(FFVER_OK AND NOT MSVC)
1333             ADD_EXECUTABLE(alffplay examples/alffplay.c)
1334             TARGET_LINK_LIBRARIES(alffplay common ex-common ${SDL2_LIBRARY} ${LIBNAME} ${FFMPEG_LIBRARIES})
1335             SET_PROPERTY(TARGET alffplay APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1336                                                                              ${FFMPEG_INCLUDE_DIRS})
1337
1338             IF(ALSOFT_INSTALL)
1339                 INSTALL(TARGETS alffplay
1340                         RUNTIME DESTINATION bin
1341                         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1342                         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1343                 )
1344             ENDIF()
1345             MESSAGE(STATUS "Building SDL and FFmpeg example programs")
1346         ELSE()
1347             MESSAGE(STATUS "Building SDL example programs")
1348         ENDIF()
1349         MESSAGE(STATUS "")
1350     ENDIF()
1351 ENDIF()