CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 SET(CPP_DEFS ) # C pre-process, not C++
  66 SET(INC_PATHS )
  67 SET(C_FLAGS )
  68 SET(LINKER_FLAGS )
  69 SET(EXTRA_LIBS )
  70
  71 IF(WIN32)
  72     SET(CPP_DEFS ${CPP_DEFS} _WIN32 _WIN32_WINNT=0x0502)
  73
  74     OPTION(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
  75
  76     # This option is mainly for static linking OpenAL Soft into another project
  77     # that already defines the IDs. It is up to that project to ensure all
  78     # required IDs are defined.
  79     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  80
  81     IF(MINGW)
  82         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  83         IF(NOT DLLTOOL)
  84             IF(HOST)
  85                 SET(DLLTOOL "${HOST}-dlltool")
  86             ELSE()
  87                 SET(DLLTOOL "dlltool")
  88             ENDIF()
  89         ENDIF()
  90     ENDIF()
  91 ENDIF()
  92
  93
  94 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  95 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  96     SET(INC_PATHS ${INC_PATHS} /usr/include)
  97     SET(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
  98 ENDIF()
  99
 100 IF(NOT LIBTYPE)
 101     SET(LIBTYPE SHARED)
 102 ENDIF()
 103
 104 SET(LIB_MAJOR_VERSION "1")
 105 SET(LIB_MINOR_VERSION "18")
 106 SET(LIB_REVISION "2")
 107 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 108
 109 SET(EXPORT_DECL "")
 110 SET(ALIGN_DECL "")
 111
 112
 113 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 114 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 115
 116
 117 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 118 IF(HAVE_STD_C11)
 119     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 120 ELSE()
 121     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 122     IF(HAVE_STD_C99)
 123         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 124     ENDIF()
 125 ENDIF()
 126
 127 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 128 IF(HAVE_STD_CXX11)
 129     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 130 ENDIF()
 131
 132 if(NOT WIN32)
 133     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 134     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 135     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 136         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 137         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 138         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 139         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 140             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 141         ELSE()
 142             SET(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 143         ENDIF()
 144     ENDIF()
 145     UNSET(OLD_REQUIRED_FLAGS)
 146 ENDIF()
 147
 148 # Set defines for large file support
 149 CHECK_FILE_OFFSET_BITS()
 150 IF(_FILE_OFFSET_BITS)
 151     SET(CPP_DEFS ${CPP_DEFS} "_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 152     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 153 ENDIF()
 154 SET(CPP_DEFS ${CPP_DEFS} _LARGEFILE_SOURCE _LARGE_FILES)
 155 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 156
 157 # MSVC may need workarounds for C99 restrict and inline
 158 IF(MSVC)
 159     # TODO: Once we truly require C99, these restrict and inline checks should go
 160     # away.
 161     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 162                              int main() {return 0;}" HAVE_RESTRICT)
 163     IF(NOT HAVE_RESTRICT)
 164         SET(CPP_DEFS ${CPP_DEFS} "restrict=")
 165         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 166     ENDIF()
 167
 168     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 169                              int main() {return 0;}" HAVE_INLINE)
 170     IF(NOT HAVE_INLINE)
 171         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 172                                  int main() {return 0;}" HAVE___INLINE)
 173         IF(NOT HAVE___INLINE)
 174             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 175         ENDIF()
 176
 177         SET(CPP_DEFS ${CPP_DEFS} inline=__inline)
 178         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 179     ENDIF()
 180 ENDIF()
 181
 182 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 183 IF(CMAKE_COMPILER_IS_GNUCC)
 184     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 185
 186     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 187     # Force no inlining for the next test.
 188     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 189
 190     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 191                              int main() {return foo();}" INLINE_IS_C99)
 192     IF(NOT INLINE_IS_C99)
 193         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 194                              Please update your compiler for better C99 compliance.")
 195     ENDIF()
 196
 197     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 198 ENDIF()
 199
 200 # Check if we have a proper timespec declaration
 201 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 202 IF(HAVE_STRUCT_TIMESPEC)
 203     # Define it here so we don't have to include config.h for it
 204     SET(CPP_DEFS ${CPP_DEFS} HAVE_STRUCT_TIMESPEC)
 205 ENDIF()
 206
 207 # Some systems may need libatomic for C11 atomic functions to work
 208 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 209 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 210 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 211 int _Atomic foo = ATOMIC_VAR_INIT(0);
 212 int main()
 213 {
 214     return atomic_fetch_add(&foo, 2);
 215 }"
 216 HAVE_LIBATOMIC)
 217 IF(NOT HAVE_LIBATOMIC)
 218     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 219 ELSE()
 220     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 221 ENDIF()
 222 UNSET(OLD_REQUIRED_LIBRARIES)
 223
 224 # Include liblog for Android logging
 225 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 226 IF(HAVE_LIBLOG)
 227     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 228     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 229 ENDIF()
 230
 231 # Check if we have C99 bool
 232 CHECK_C_SOURCE_COMPILES(
 233 "int main(int argc, char *argv[])
 234  {
 235      volatile _Bool ret;
 236      ret = (argc > 1) ? 1 : 0;
 237      return ret ? -1 : 0;
 238  }"
 239 HAVE_C99_BOOL)
 240
 241 # Check if we have C11 static_assert
 242 CHECK_C_SOURCE_COMPILES(
 243 "int main()
 244  {
 245      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 246      return 0;
 247  }"
 248 HAVE_C11_STATIC_ASSERT)
 249
 250 # Check if we have C11 alignas
 251 CHECK_C_SOURCE_COMPILES(
 252 "_Alignas(16) int foo;
 253  int main()
 254  {
 255      return 0;
 256  }"
 257 HAVE_C11_ALIGNAS)
 258
 259 # Check if we have C11 _Atomic
 260 CHECK_C_SOURCE_COMPILES(
 261 "#include <stdatomic.h>
 262  int _Atomic foo = ATOMIC_VAR_INIT(0);
 263  int main()
 264  {
 265      atomic_fetch_add(&foo, 2);
 266      return 0;
 267  }"
 268 HAVE_C11_ATOMIC)
 269
 270 # Add definitions, compiler switches, etc.
 271 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 272
 273 IF(NOT CMAKE_BUILD_TYPE)
 274     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 275         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 276         FORCE)
 277 ENDIF()
 278 IF(NOT CMAKE_DEBUG_POSTFIX)
 279     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 280         "Library postfix for debug builds. Normally left blank."
 281         FORCE)
 282 ENDIF()
 283
 284 IF(MSVC)
 285     SET(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_DEPRECATE)
 286     SET(C_FLAGS ${C_FLAGS} /wd4098)
 287
 288     IF(NOT DXSDK_DIR)
 289         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 290     ELSE()
 291         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 292     ENDIF()
 293     IF(DXSDK_DIR)
 294         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 295     ENDIF()
 296
 297     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 298     IF(FORCE_STATIC_VCRT)
 299         FOREACH(flag_var
 300                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 301                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 302             IF(${flag_var} MATCHES "/MD")
 303                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 304             ENDIF()
 305         ENDFOREACH(flag_var)
 306     ENDIF()
 307 ELSE()
 308     SET(C_FLAGS ${C_FLAGS} -Winline -Wall)
 309     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 310     IF(HAVE_W_EXTRA)
 311         SET(C_FLAGS ${C_FLAGS} -Wextra)
 312     ENDIF()
 313
 314     IF(ALSOFT_WERROR)
 315         SET(C_FLAGS ${C_FLAGS} -Werror)
 316     ENDIF()
 317
 318     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 319     # instead of NDEBUG)
 320     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 321         IF(${flag_var} MATCHES "-DNDEBUG")
 322             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 323         ENDIF()
 324     ENDFOREACH()
 325
 326     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 327     IF(HAVE_FNO_MATH_ERRNO)
 328         SET(C_FLAGS ${C_FLAGS} -fno-math-errno)
 329     ENDIF()
 330
 331     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 332                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 333
 334     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 335     if(ALSOFT_STATIC_LIBGCC)
 336         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 337         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 338         check_c_source_compiles(
 339 "#include <stdlib.h>
 340 int main()
 341 {
 342     return 0;
 343 }"
 344             HAVE_STATIC_LIBGCC_SWITCH
 345         )
 346         if(HAVE_STATIC_LIBGCC_SWITCH)
 347             SET(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 348         endif()
 349         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 350         unset(OLD_REQUIRED_LIBRARIES)
 351     endif()
 352 ENDIF()
 353
 354 # Set visibility/export options if available
 355 IF(WIN32)
 356     SET(EXPORT_DECL "__declspec(dllexport)")
 357     IF(NOT MINGW)
 358         SET(ALIGN_DECL "__declspec(align(x))")
 359     ELSE()
 360         SET(ALIGN_DECL "__declspec(aligned(x))")
 361     ENDIF()
 362 ELSE()
 363     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 364     # Yes GCC, really don't accept visibility modes you don't support
 365     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 366
 367     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 368                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 369     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 370         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 371     ELSE()
 372         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 373                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 374         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 375             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 376         ENDIF()
 377     ENDIF()
 378
 379     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 380         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 381         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 382             SET(C_FLAGS ${C_FLAGS} -fvisibility=hidden)
 383         ENDIF()
 384     ENDIF()
 385
 386     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 387                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 388     IF(HAVE_ATTRIBUTE_ALIGNED)
 389         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 390     ENDIF()
 391
 392     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 393 ENDIF()
 394
 395 CHECK_C_SOURCE_COMPILES("
 396 int main()
 397 {
 398     float *ptr;
 399     ptr = __builtin_assume_aligned(ptr, 16);
 400     return 0;
 401 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 402 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 403     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 404 ELSE()
 405     SET(ASSUME_ALIGNED_DECL "x")
 406 ENDIF()
 407
 408 SET(SSE_SWITCH "")
 409 SET(SSE2_SWITCH "")
 410 SET(SSE3_SWITCH "")
 411 SET(SSE4_1_SWITCH "")
 412 SET(FPU_NEON_SWITCH "")
 413
 414 CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 415 IF(HAVE_MSSE_SWITCH)
 416     SET(SSE_SWITCH "-msse")
 417 ENDIF()
 418 CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 419 IF(HAVE_MSSE2_SWITCH)
 420     SET(SSE2_SWITCH "-msse2")
 421 ENDIF()
 422 CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 423 IF(HAVE_MSSE3_SWITCH)
 424     SET(SSE3_SWITCH "-msse3")
 425 ENDIF()
 426 CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 427 IF(HAVE_MSSE4_1_SWITCH)
 428     SET(SSE4_1_SWITCH "-msse4.1")
 429 ENDIF()
 430 CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 431 IF(HAVE_MFPU_NEON_SWITCH)
 432     SET(FPU_NEON_SWITCH "-mfpu=neon")
 433 ENDIF()
 434
 435 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 436                          int main() {return 0;}" HAVE_GCC_FORMAT)
 437
 438 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 439 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 440 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 441 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 442 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 443 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 444 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 445 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 446 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 447 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 448 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 449 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 450 IF(NOT HAVE_GUIDDEF_H)
 451     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 452 ENDIF()
 453
 454 # Some systems need libm for some of the following math functions to work
 455 SET(MATH_LIB )
 456 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 457 IF(HAVE_LIBM)
 458     SET(MATH_LIB ${MATH_LIB} m)
 459     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 460 ENDIF()
 461
 462 # Check for the dlopen API (for dynamicly loading backend libs)
 463 IF(ALSOFT_DLOPEN)
 464     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 465     IF(HAVE_LIBDL)
 466         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 467         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 468     ENDIF()
 469
 470     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 471 ENDIF()
 472
 473 # Check for a cpuid intrinsic
 474 IF(HAVE_CPUID_H)
 475     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 476         int main()
 477         {
 478             unsigned int eax, ebx, ecx, edx;
 479             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 480         }" HAVE_GCC_GET_CPUID)
 481 ENDIF()
 482 IF(HAVE_INTRIN_H)
 483     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 484         int main()
 485         {
 486             int regs[4];
 487             __cpuid(regs, 0);
 488             return regs[0];
 489         }" HAVE_CPUID_INTRINSIC)
 490     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 491         int main()
 492         {
 493             unsigned long idx = 0;
 494             _BitScanForward64(&idx, 1);
 495             return idx;
 496         }" HAVE_BITSCANFORWARD64_INTRINSIC)
 497     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 498         int main()
 499         {
 500             unsigned long idx = 0;
 501             _BitScanForward(&idx, 1);
 502             return idx;
 503         }" HAVE_BITSCANFORWARD_INTRINSIC)
 504 ENDIF()
 505
 506 CHECK_SYMBOL_EXISTS(sysconf          unistd.h HAVE_SYSCONF)
 507 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 508 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 509 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 510 CHECK_SYMBOL_EXISTS(proc_pidpath     libproc.h HAVE_PROC_PIDPATH)
 511 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 512 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 513 CHECK_SYMBOL_EXISTS(log2f  math.h HAVE_LOG2F)
 514 CHECK_SYMBOL_EXISTS(cbrtf  math.h HAVE_CBRTF)
 515
 516 IF(HAVE_FLOAT_H)
 517     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 518     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 519 ENDIF()
 520
 521 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 522 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 523 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 524 IF(NOT HAVE_STRCASECMP)
 525     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 526     IF(NOT HAVE__STRICMP)
 527         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 528     ENDIF()
 529
 530     SET(CPP_DEFS ${CPP_DEFS} strcasecmp=_stricmp)
 531 ENDIF()
 532
 533 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 534 IF(NOT HAVE_STRNCASECMP)
 535     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 536     IF(NOT HAVE__STRNICMP)
 537         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 538     ENDIF()
 539
 540     SET(CPP_DEFS ${CPP_DEFS} strncasecmp=_strnicmp)
 541 ENDIF()
 542
 543 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 544 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 545 IF(NOT HAVE_SNPRINTF)
 546     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 547     IF(NOT HAVE__SNPRINTF)
 548         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 549     ENDIF()
 550
 551     SET(CPP_DEFS ${CPP_DEFS} snprintf=_snprintf)
 552 ENDIF()
 553
 554 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 555 IF(NOT HAVE_ISFINITE)
 556     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 557     IF(NOT HAVE_FINITE)
 558         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 559         IF(NOT HAVE__FINITE)
 560             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 561         ENDIF()
 562         SET(CPP_DEFS ${CPP_DEFS} isfinite=_finite)
 563     ELSE()
 564         SET(CPP_DEFS ${CPP_DEFS} isfinite=finite)
 565     ENDIF()
 566 ENDIF()
 567
 568 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 569 IF(NOT HAVE_ISNAN)
 570     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 571     IF(NOT HAVE__ISNAN)
 572         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 573     ENDIF()
 574
 575     SET(CPP_DEFS ${CPP_DEFS} isnan=_isnan)
 576 ENDIF()
 577
 578
 579 # Check if we have Windows headers
 580 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 581 IF(NOT HAVE_WINDOWS_H)
 582     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 583     IF(NOT HAVE_GETTIMEOFDAY)
 584         MESSAGE(FATAL_ERROR "No timing function found!")
 585     ENDIF()
 586
 587     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 588     IF(NOT HAVE_NANOSLEEP)
 589         MESSAGE(FATAL_ERROR "No sleep function found!")
 590     ENDIF()
 591
 592     # We need pthreads outside of Windows
 593     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 594     IF(NOT HAVE_PTHREAD_H)
 595         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 596     ENDIF()
 597     # Some systems need pthread_np.h to get recursive mutexes
 598     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 599
 600     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 601     IF(HAVE_PTHREAD)
 602         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 603         SET(C_FLAGS ${C_FLAGS} -pthread)
 604         SET(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 605     ENDIF()
 606
 607     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 608     IF(HAVE_LIBPTHREAD)
 609         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 610     ENDIF()
 611
 612     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 613
 614     IF(HAVE_PTHREAD_NP_H)
 615         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 616         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 617             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 618         ELSE()
 619             CHECK_C_SOURCE_COMPILES("
 620 #include <pthread.h>
 621 #include <pthread_np.h>
 622 int main()
 623 {
 624     pthread_setname_np(\"testname\");
 625     return 0;
 626 }"
 627                 PTHREAD_SETNAME_NP_ONE_PARAM
 628             )
 629             CHECK_C_SOURCE_COMPILES("
 630 #include <pthread.h>
 631 #include <pthread_np.h>
 632 int main()
 633 {
 634     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 635     return 0;
 636 }"
 637                 PTHREAD_SETNAME_NP_THREE_PARAMS
 638             )
 639         ENDIF()
 640         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 641     ELSE()
 642         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 643         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 644             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 645         ELSE()
 646             CHECK_C_SOURCE_COMPILES("
 647 #include <pthread.h>
 648 int main()
 649 {
 650     pthread_setname_np(\"testname\");
 651     return 0;
 652 }"
 653                 PTHREAD_SETNAME_NP_ONE_PARAM
 654             )
 655             CHECK_C_SOURCE_COMPILES("
 656 #include <pthread.h>
 657 int main()
 658 {
 659     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 660     return 0;
 661 }"
 662                 PTHREAD_SETNAME_NP_THREE_PARAMS
 663             )
 664         ENDIF()
 665         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 666     ENDIF()
 667
 668     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 669
 670     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 671     IF(HAVE_LIBRT)
 672         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 673     ENDIF()
 674 ENDIF()
 675
 676 CHECK_SYMBOL_EXISTS(getopt unistd.h HAVE_GETOPT)
 677
 678 # Check for a 64-bit type
 679 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 680 IF(NOT HAVE_STDINT_H)
 681     IF(HAVE_WINDOWS_H)
 682         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 683                                  #include <windows.h>
 684                                  __int64 foo;
 685                                  int main() {return 0;}" HAVE___INT64)
 686     ENDIF()
 687     IF(NOT HAVE___INT64)
 688         IF(NOT SIZEOF_LONG MATCHES "8")
 689             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 690                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 691             ENDIF()
 692         ENDIF()
 693     ENDIF()
 694 ENDIF()
 695
 696
 697 SET(COMMON_OBJS  common/almalloc.c
 698                  common/atomic.c
 699                  common/rwlock.c
 700                  common/threads.c
 701                  common/uintmap.c
 702 )
 703 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 704                  OpenAL32/alBuffer.c
 705                  OpenAL32/alEffect.c
 706                  OpenAL32/alError.c
 707                  OpenAL32/alExtension.c
 708                  OpenAL32/alFilter.c
 709                  OpenAL32/alListener.c
 710                  OpenAL32/alSource.c
 711                  OpenAL32/alState.c
 712                  OpenAL32/event.c
 713                  OpenAL32/sample_cvt.c
 714 )
 715 SET(ALC_OBJS  Alc/ALc.c
 716               Alc/ALu.c
 717               Alc/alconfig.c
 718               Alc/bs2b.c
 719               Alc/converter.c
 720               Alc/mastering.c
 721               Alc/ringbuffer.c
 722               Alc/effects/chorus.c
 723               Alc/effects/compressor.c
 724               Alc/effects/dedicated.c
 725               Alc/effects/distortion.c
 726               Alc/effects/echo.c
 727               Alc/effects/equalizer.c
 728               Alc/effects/modulator.c
 729               Alc/effects/null.c
 730               Alc/effects/pshifter.c
 731               Alc/effects/reverb.c
 732               Alc/filters/filter.c
 733               Alc/filters/nfc.c
 734               Alc/helpers.c
 735               Alc/hrtf.c
 736               Alc/uhjfilter.c
 737               Alc/ambdec.c
 738               Alc/bformatdec.c
 739               Alc/panning.c
 740               Alc/mixvoice.c
 741               Alc/mixer/mixer_c.c
 742 )
 743
 744
 745 SET(CPU_EXTS "Default")
 746 SET(HAVE_SSE        0)
 747 SET(HAVE_SSE2       0)
 748 SET(HAVE_SSE3       0)
 749 SET(HAVE_SSE4_1     0)
 750 SET(HAVE_NEON       0)
 751
 752 SET(HAVE_ALSA       0)
 753 SET(HAVE_OSS        0)
 754 SET(HAVE_SOLARIS    0)
 755 SET(HAVE_SNDIO      0)
 756 SET(HAVE_QSA        0)
 757 SET(HAVE_DSOUND     0)
 758 SET(HAVE_WASAPI     0)
 759 SET(HAVE_WINMM      0)
 760 SET(HAVE_PORTAUDIO  0)
 761 SET(HAVE_PULSEAUDIO 0)
 762 SET(HAVE_COREAUDIO  0)
 763 SET(HAVE_OPENSL     0)
 764 SET(HAVE_WAVE       0)
 765 SET(HAVE_SDL2       0)
 766
 767 # Check for SSE support
 768 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 769 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 770 IF(HAVE_XMMINTRIN_H)
 771     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 772     IF(ALSOFT_CPUEXT_SSE)
 773         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 774             SET(HAVE_SSE 1)
 775             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse.c)
 776             IF(SSE_SWITCH)
 777                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse.c PROPERTIES
 778                                             COMPILE_FLAGS "${SSE_SWITCH}")
 779             ENDIF()
 780             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 781         ENDIF()
 782     ENDIF()
 783 ENDIF()
 784 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 785     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 786 ENDIF()
 787
 788 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 789 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 790 IF(HAVE_EMMINTRIN_H)
 791     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 792     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 793         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 794             SET(HAVE_SSE2 1)
 795             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse2.c)
 796             IF(SSE2_SWITCH)
 797                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse2.c PROPERTIES
 798                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 799             ENDIF()
 800             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 801         ENDIF()
 802     ENDIF()
 803 ENDIF()
 804 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 805     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 806 ENDIF()
 807
 808 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 809 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 810 IF(HAVE_EMMINTRIN_H)
 811     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 812     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 813         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 814             SET(HAVE_SSE3 1)
 815             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse3.c)
 816             IF(SSE2_SWITCH)
 817                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse3.c PROPERTIES
 818                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 819             ENDIF()
 820             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 821         ENDIF()
 822     ENDIF()
 823 ENDIF()
 824 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 825     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 826 ENDIF()
 827
 828 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 829 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 830 IF(HAVE_SMMINTRIN_H)
 831     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 832     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 833         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 834             SET(HAVE_SSE4_1 1)
 835             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse41.c)
 836             IF(SSE4_1_SWITCH)
 837                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse41.c PROPERTIES
 838                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 839             ENDIF()
 840             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 841         ENDIF()
 842     ENDIF()
 843 ENDIF()
 844 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 845     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 846 ENDIF()
 847
 848 # Check for ARM Neon support
 849 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 850 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H ${FPU_NEON_SWITCH})
 851 IF(HAVE_ARM_NEON_H)
 852     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 853     IF(ALSOFT_CPUEXT_NEON)
 854         SET(HAVE_NEON 1)
 855         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_neon.c)
 856         IF(FPU_NEON_SWITCH)
 857             SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_neon.c PROPERTIES
 858                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 859         ENDIF()
 860         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 861     ENDIF()
 862 ENDIF()
 863 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 864     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 865 ENDIF()
 866
 867
 868 IF(WIN32 OR HAVE_DLFCN_H)
 869     SET(IS_LINKED "")
 870     MACRO(ADD_BACKEND_LIBS _LIBS)
 871     ENDMACRO()
 872 ELSE()
 873     SET(IS_LINKED " (linked)")
 874     MACRO(ADD_BACKEND_LIBS _LIBS)
 875         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 876     ENDMACRO()
 877 ENDIF()
 878
 879 SET(BACKENDS "")
 880 SET(ALC_OBJS  ${ALC_OBJS}
 881               Alc/backends/base.c
 882               # Default backends, always available
 883               Alc/backends/loopback.c
 884               Alc/backends/null.c
 885 )
 886
 887 # Check ALSA backend
 888 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 889 FIND_PACKAGE(ALSA)
 890 IF(ALSA_FOUND)
 891     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 892     IF(ALSOFT_BACKEND_ALSA)
 893         SET(HAVE_ALSA 1)
 894         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 895         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 896         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 897         SET(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 898     ENDIF()
 899 ENDIF()
 900 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 901     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 902 ENDIF()
 903
 904 # Check OSS backend
 905 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 906 FIND_PACKAGE(OSS)
 907 IF(OSS_FOUND)
 908     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 909     IF(ALSOFT_BACKEND_OSS)
 910         SET(HAVE_OSS 1)
 911         SET(BACKENDS  "${BACKENDS} OSS,")
 912         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 913         IF(OSS_LIBRARIES)
 914             SET(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 915         ENDIF()
 916         SET(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 917     ENDIF()
 918 ENDIF()
 919 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 920     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 921 ENDIF()
 922
 923 # Check Solaris backend
 924 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 925 FIND_PACKAGE(AudioIO)
 926 IF(AUDIOIO_FOUND)
 927     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 928     IF(ALSOFT_BACKEND_SOLARIS)
 929         SET(HAVE_SOLARIS 1)
 930         SET(BACKENDS  "${BACKENDS} Solaris,")
 931         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 932         SET(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 933     ENDIF()
 934 ENDIF()
 935 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 936     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 937 ENDIF()
 938
 939 # Check SndIO backend
 940 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 941 FIND_PACKAGE(SoundIO)
 942 IF(SOUNDIO_FOUND)
 943     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 944     IF(ALSOFT_BACKEND_SNDIO)
 945         SET(HAVE_SNDIO 1)
 946         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 947         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 948         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 949         SET(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 950     ENDIF()
 951 ENDIF()
 952 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 953     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 954 ENDIF()
 955
 956 # Check QSA backend
 957 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 958 FIND_PACKAGE(QSA)
 959 IF(QSA_FOUND)
 960     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 961     IF(ALSOFT_BACKEND_QSA)
 962         SET(HAVE_QSA 1)
 963         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 964         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 965         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 966         SET(INC_PATHS ${INC_PATHS} ${QSA_INCLUDE_DIRS})
 967     ENDIF()
 968 ENDIF()
 969 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 970     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 971 ENDIF()
 972
 973 # Check Windows-only backends
 974 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 975 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 976 OPTION(ALSOFT_REQUIRE_WASAPI "Require WASAPI backend" OFF)
 977 IF(HAVE_WINDOWS_H)
 978     # Check MMSystem backend
 979     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 980     IF(HAVE_MMSYSTEM_H)
 981         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 982         IF(HAVE_LIBWINMM)
 983             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 984             IF(ALSOFT_BACKEND_WINMM)
 985                 SET(HAVE_WINMM 1)
 986                 SET(BACKENDS  "${BACKENDS} WinMM,")
 987                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 988                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 989             ENDIF()
 990         ENDIF()
 991     ENDIF()
 992
 993     # Check DSound backend
 994     FIND_PACKAGE(DSound)
 995     IF(DSOUND_FOUND)
 996         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 997         IF(ALSOFT_BACKEND_DSOUND)
 998             SET(HAVE_DSOUND 1)
 999             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
1000             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
1001             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
1002             SET(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIRS})
1003         ENDIF()
1004     ENDIF()
1005
1006     # Check for WASAPI backend
1007     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
1008     IF(HAVE_MMDEVICEAPI_H)
1009         OPTION(ALSOFT_BACKEND_WASAPI "Enable WASAPI backend" ON)
1010         IF(ALSOFT_BACKEND_WASAPI)
1011             SET(HAVE_WASAPI 1)
1012             SET(BACKENDS  "${BACKENDS} WASAPI,")
1013             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wasapi.c)
1014         ENDIF()
1015     ENDIF()
1016 ENDIF()
1017 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1018     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
1019 ENDIF()
1020 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1021     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
1022 ENDIF()
1023 IF(ALSOFT_REQUIRE_WASAPI AND NOT HAVE_WASAPI)
1024     MESSAGE(FATAL_ERROR "Failed to enabled required WASAPI backend")
1025 ENDIF()
1026
1027 # Check PortAudio backend
1028 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1029 FIND_PACKAGE(PortAudio)
1030 IF(PORTAUDIO_FOUND)
1031     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1032     IF(ALSOFT_BACKEND_PORTAUDIO)
1033         SET(HAVE_PORTAUDIO 1)
1034         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1035         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
1036         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1037         SET(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1038     ENDIF()
1039 ENDIF()
1040 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1041     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1042 ENDIF()
1043
1044 # Check PulseAudio backend
1045 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1046 FIND_PACKAGE(PulseAudio)
1047 IF(PULSEAUDIO_FOUND)
1048     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1049     IF(ALSOFT_BACKEND_PULSEAUDIO)
1050         SET(HAVE_PULSEAUDIO 1)
1051         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1052         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1053         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1054         SET(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIRS})
1055     ENDIF()
1056 ENDIF()
1057 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1058     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1059 ENDIF()
1060
1061 # Check JACK backend
1062 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1063 FIND_PACKAGE(JACK)
1064 IF(JACK_FOUND)
1065     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1066     IF(ALSOFT_BACKEND_JACK)
1067         SET(HAVE_JACK 1)
1068         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1069         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1070         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1071         SET(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1072     ENDIF()
1073 ENDIF()
1074 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1075     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1076 ENDIF()
1077
1078 # Check CoreAudio backend
1079 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1080 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1081              NAMES CoreAudio
1082              PATHS /System/Library/Frameworks
1083 )
1084 IF(COREAUDIO_FRAMEWORK)
1085     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1086     IF(ALSOFT_BACKEND_COREAUDIO)
1087         SET(HAVE_COREAUDIO 1)
1088         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1089         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1090         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1091         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1092         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1093
1094         # Some versions of OSX may need the AudioToolbox framework. Add it if
1095         # it's found.
1096         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1097                      NAMES AudioToolbox
1098                      PATHS ~/Library/Frameworks
1099                            /Library/Frameworks
1100                            /System/Library/Frameworks
1101                     )
1102         IF(AUDIOTOOLBOX_LIBRARY)
1103             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1104         ENDIF()
1105     ENDIF()
1106 ENDIF()
1107 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1108     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1109 ENDIF()
1110
1111 # Check for OpenSL (Android) backend
1112 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1113 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1114 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1115     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1116     IF(HAVE_LIBOPENSLES)
1117         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1118         IF(ALSOFT_BACKEND_OPENSL)
1119             SET(HAVE_OPENSL 1)
1120             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1121             SET(BACKENDS  "${BACKENDS} OpenSL,")
1122             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1123         ENDIF()
1124     ENDIF()
1125 ENDIF()
1126 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1127     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1128 ENDIF()
1129
1130 # Check for SDL2 backend
1131 OPTION(ALSOFT_REQUIRE_SDL2 "Require SDL2 backend" OFF)
1132 FIND_PACKAGE(SDL2)
1133 IF(SDL2_FOUND)
1134     # Off by default, since it adds a runtime dependency
1135     OPTION(ALSOFT_BACKEND_SDL2 "Enable SDL2 backend" OFF)
1136     IF(ALSOFT_BACKEND_SDL2)
1137         SET(HAVE_SDL2 1)
1138         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sdl2.c)
1139         SET(BACKENDS  "${BACKENDS} SDL2,")
1140         SET(EXTRA_LIBS ${SDL2_LIBRARY} ${EXTRA_LIBS})
1141         SET(INC_PATHS ${INC_PATHS} ${SDL2_INCLUDE_DIR})
1142     ENDIF()
1143 ENDIF()
1144 IF(ALSOFT_REQUIRE_SDL2 AND NOT SDL2_FOUND)
1145     MESSAGE(FATAL_ERROR "Failed to enabled required SDL2 backend")
1146 ENDIF()
1147
1148 # Optionally enable the Wave Writer backend
1149 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1150 IF(ALSOFT_BACKEND_WAVE)
1151     SET(HAVE_WAVE 1)
1152     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1153     SET(BACKENDS  "${BACKENDS} WaveFile,")
1154 ENDIF()
1155
1156 # This is always available
1157 SET(BACKENDS  "${BACKENDS} Null")
1158
1159
1160 FIND_PACKAGE(Git)
1161 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1162     # Get the current working branch and its latest abbreviated commit hash
1163     ADD_CUSTOM_TARGET(build_version
1164         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1165                          -D LIB_VERSION=${LIB_VERSION}
1166                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1167                          -D DST=${OpenAL_BINARY_DIR}/version.h
1168                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1169         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1170         VERBATIM
1171     )
1172 ELSE()
1173     SET(GIT_BRANCH "UNKNOWN")
1174     SET(GIT_COMMIT_HASH "unknown")
1175     CONFIGURE_FILE(
1176         "${OpenAL_SOURCE_DIR}/version.h.in"
1177         "${OpenAL_BINARY_DIR}/version.h")
1178 ENDIF()
1179
1180 SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools/")
1181 SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools/")
1182 FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1183
1184 SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}bin2h")
1185 SET(BSINCGEN_COMMAND  "${NATIVE_BIN_DIR}bsincgen")
1186 ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1187     COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" "${NATIVE_SRC_DIR}"
1188     COMMAND ${CMAKE_COMMAND} -E remove "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1189     COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1190     WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1191     DEPENDS "${NATIVE_SRC_DIR}CMakeLists.txt"
1192     IMPLICIT_DEPENDS C "${NATIVE_SRC_DIR}bin2h.c"
1193                      C "${NATIVE_SRC_DIR}bsincgen.c"
1194     VERBATIM
1195 )
1196 ADD_CUSTOM_TARGET(native-tools
1197     DEPENDS "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1198     VERBATIM
1199 )
1200
1201 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1202 if(ALSOFT_EMBED_HRTF_DATA)
1203     MACRO(make_hrtf_header FILENAME VARNAME)
1204         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1205         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1206
1207         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1208             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1209             DEPENDS native-tools "${infile}"
1210             VERBATIM
1211         )
1212         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1213     ENDMACRO()
1214
1215     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1216     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1217 endif()
1218
1219 ADD_CUSTOM_COMMAND(OUTPUT "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1220     COMMAND "${BSINCGEN_COMMAND}" "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1221     DEPENDS native-tools "${NATIVE_SRC_DIR}bsincgen.c"
1222     VERBATIM
1223 )
1224 SET(ALC_OBJS  ${ALC_OBJS} "${OpenAL_BINARY_DIR}/bsinc_inc.h")
1225
1226
1227 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1228     add_subdirectory(utils/alsoft-config)
1229 ENDIF()
1230 IF(ALSOFT_EXAMPLES)
1231     IF(NOT SDL2_FOUND)
1232         FIND_PACKAGE(SDL2)
1233     ENDIF()
1234     IF(SDL2_FOUND)
1235         FIND_PACKAGE(SDL_sound)
1236         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1237     ENDIF()
1238 ENDIF()
1239
1240 IF(NOT WIN32)
1241     SET(LIBNAME "openal")
1242 ELSE()
1243     SET(LIBNAME "OpenAL32")
1244 ENDIF()
1245
1246 # Needed for openal.pc.in
1247 SET(prefix ${CMAKE_INSTALL_PREFIX})
1248 SET(exec_prefix "\${prefix}")
1249 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1250 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1251 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1252 SET(PACKAGE_VERSION "${LIB_VERSION}")
1253 IF(LIBTYPE STREQUAL "STATIC")
1254     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1255 ENDIF()
1256
1257 # End configuration
1258 CONFIGURE_FILE(
1259     "${OpenAL_SOURCE_DIR}/config.h.in"
1260     "${OpenAL_BINARY_DIR}/config.h")
1261 CONFIGURE_FILE(
1262     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1263     "${OpenAL_BINARY_DIR}/openal.pc"
1264     @ONLY)
1265
1266
1267 # Add a static library with common functions used by multiple targets
1268 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
1269 TARGET_COMPILE_DEFINITIONS(common PRIVATE ${CPP_DEFS})
1270 TARGET_COMPILE_OPTIONS(common PRIVATE ${C_FLAGS})
1271
1272
1273 UNSET(HAS_ROUTER)
1274 SET(IMPL_TARGET OpenAL)
1275 SET(COMMON_LIB )
1276 SET(SUBSYS_FLAG )
1277
1278 # Build main library
1279 IF(LIBTYPE STREQUAL "STATIC")
1280     SET(CPP_DEFS ${CPP_DEFS} AL_LIBTYPE_STATIC)
1281     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1282         SET(CPP_DEFS ${CPP_DEFS} AL_NO_UID_DEFS)
1283     ENDIF()
1284     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1285 ELSE()
1286     # Make sure to compile the common code with PIC, since it'll be linked into
1287     # shared libs that needs it.
1288     SET_PROPERTY(TARGET common PROPERTY POSITION_INDEPENDENT_CODE TRUE)
1289     SET(COMMON_LIB common)
1290
1291     IF(WIN32)
1292         IF(MSVC)
1293             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "/SUBSYSTEM:WINDOWS")
1294         ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1295             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "-mwindows")
1296         ENDIF()
1297     ENDIF()
1298
1299     IF(WIN32 AND ALSOFT_BUILD_ROUTER)
1300         ADD_LIBRARY(OpenAL SHARED router/router.c router/alc.c router/al.c)
1301         TARGET_COMPILE_DEFINITIONS(OpenAL
1302             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1303         TARGET_COMPILE_OPTIONS(OpenAL PRIVATE ${C_FLAGS})
1304         TARGET_LINK_LIBRARIES(OpenAL PRIVATE ${LINKER_FLAGS} ${COMMON_LIB})
1305         SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1306         SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1307         IF(TARGET build_version)
1308             ADD_DEPENDENCIES(OpenAL build_version)
1309         ENDIF()
1310         SET(HAS_ROUTER 1)
1311
1312         SET(LIBNAME "soft_oal")
1313         SET(IMPL_TARGET soft_oal)
1314     ENDIF()
1315
1316     ADD_LIBRARY(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
1317     IF(WIN32)
1318         SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES PREFIX "")
1319     ENDIF()
1320 ENDIF()
1321 SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1322     VERSION ${LIB_VERSION}
1323     SOVERSION ${LIB_MAJOR_VERSION}
1324 )
1325 TARGET_COMPILE_DEFINITIONS(${IMPL_TARGET}
1326     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1327 TARGET_INCLUDE_DIRECTORIES(${IMPL_TARGET}
1328     PRIVATE "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc" ${INC_PATHS})
1329 TARGET_COMPILE_OPTIONS(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1330 TARGET_LINK_LIBRARIES(${IMPL_TARGET}
1331     PRIVATE ${LINKER_FLAGS} ${COMMON_LIB} ${EXTRA_LIBS} ${MATH_LIB})
1332 IF(TARGET build_version)
1333     ADD_DEPENDENCIES(${IMPL_TARGET} build_version)
1334 ENDIF()
1335
1336 IF(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1337     FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1338     FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1339     IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1340         MESSAGE(STATUS "")
1341         IF(NOT SED_EXECUTABLE)
1342             MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1343         ENDIF()
1344         IF(NOT DLLTOOL_EXECUTABLE)
1345             MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1346         ENDIF()
1347     ELSE()
1348         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS
1349                         " -Wl,--output-def,OpenAL32.def")
1350         ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1351             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1352             COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1353             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1354             VERBATIM
1355         )
1356     ENDIF()
1357 ENDIF()
1358
1359 IF(ALSOFT_INSTALL)
1360     INSTALL(TARGETS OpenAL EXPORT OpenAL
1361             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1362             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1363             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1364             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1365     )
1366     EXPORT(TARGETS OpenAL
1367            NAMESPACE OpenAL::
1368            FILE OpenALConfig.cmake)
1369     INSTALL(EXPORT OpenAL
1370             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1371             NAMESPACE OpenAL::
1372             FILE OpenALConfig.cmake)
1373     INSTALL(FILES include/AL/al.h
1374                   include/AL/alc.h
1375                   include/AL/alext.h
1376                   include/AL/efx.h
1377                   include/AL/efx-creative.h
1378                   include/AL/efx-presets.h
1379             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1380     )
1381     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1382             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1383     IF(TARGET soft_oal)
1384         INSTALL(TARGETS soft_oal
1385                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1386         )
1387     ENDIF()
1388 ENDIF()
1389
1390
1391 if(HAS_ROUTER)
1392     message(STATUS "")
1393     message(STATUS "Building DLL router")
1394 endif()
1395
1396 MESSAGE(STATUS "")
1397 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1398 MESSAGE(STATUS "    ${BACKENDS}")
1399 MESSAGE(STATUS "")
1400 MESSAGE(STATUS "Building with support for CPU extensions:")
1401 MESSAGE(STATUS "    ${CPU_EXTS}")
1402 MESSAGE(STATUS "")
1403
1404 IF(WIN32)
1405     IF(NOT HAVE_DSOUND)
1406         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1407         MESSAGE(STATUS "         This is probably NOT what you want!")
1408         MESSAGE(STATUS "")
1409     ENDIF()
1410 ENDIF()
1411
1412 if(ALSOFT_EMBED_HRTF_DATA)
1413     message(STATUS "Embedding HRTF datasets")
1414     message(STATUS "")
1415 endif()
1416
1417 # Install alsoft.conf configuration file
1418 IF(ALSOFT_CONFIG)
1419     INSTALL(FILES alsoftrc.sample
1420             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1421     )
1422     MESSAGE(STATUS "Installing sample configuration")
1423     MESSAGE(STATUS "")
1424 ENDIF()
1425
1426 # Install HRTF definitions
1427 IF(ALSOFT_HRTF_DEFS)
1428     INSTALL(FILES hrtf/default-44100.mhr
1429                   hrtf/default-48000.mhr
1430             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1431     )
1432     MESSAGE(STATUS "Installing HRTF definitions")
1433     MESSAGE(STATUS "")
1434 ENDIF()
1435
1436 # Install AmbDec presets
1437 IF(ALSOFT_AMBDEC_PRESETS)
1438     INSTALL(FILES presets/3D7.1.ambdec
1439                   presets/hexagon.ambdec
1440                   presets/itu5.1.ambdec
1441                   presets/itu5.1-nocenter.ambdec
1442                   presets/rectangle.ambdec
1443                   presets/square.ambdec
1444                   presets/presets.txt
1445             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1446     )
1447     MESSAGE(STATUS "Installing AmbDec presets")
1448     MESSAGE(STATUS "")
1449 ENDIF()
1450
1451 IF(ALSOFT_UTILS)
1452     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1453     TARGET_COMPILE_OPTIONS(openal-info PRIVATE ${C_FLAGS})
1454     TARGET_LINK_LIBRARIES(openal-info PRIVATE ${LINKER_FLAGS} OpenAL)
1455
1456     SET(MAKEHRTF_SRCS  utils/makehrtf.c)
1457     IF(NOT HAVE_GETOPT)
1458         SET(MAKEHRTF_SRCS  ${MAKEHRTF_SRCS} utils/getopt.c)
1459     ENDIF()
1460     ADD_EXECUTABLE(makehrtf ${MAKEHRTF_SRCS})
1461     TARGET_COMPILE_DEFINITIONS(makehrtf PRIVATE ${CPP_DEFS})
1462     TARGET_COMPILE_OPTIONS(makehrtf PRIVATE ${C_FLAGS})
1463     IF(HAVE_LIBM)
1464         TARGET_LINK_LIBRARIES(makehrtf PRIVATE ${LINKER_FLAGS} m)
1465     ENDIF()
1466
1467     IF(ALSOFT_INSTALL)
1468         INSTALL(TARGETS openal-info makehrtf
1469                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1470                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1471                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1472         )
1473     ENDIF()
1474
1475     MESSAGE(STATUS "Building utility programs")
1476     IF(TARGET alsoft-config)
1477         MESSAGE(STATUS "Building configuration program")
1478     ENDIF()
1479     MESSAGE(STATUS "")
1480 ENDIF()
1481
1482 IF(ALSOFT_TESTS)
1483     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1484
1485     ADD_EXECUTABLE(altonegen examples/altonegen.c ${TEST_COMMON_OBJS})
1486     TARGET_COMPILE_DEFINITIONS(altonegen PRIVATE ${CPP_DEFS})
1487     TARGET_COMPILE_OPTIONS(altonegen PRIVATE ${C_FLAGS})
1488     TARGET_LINK_LIBRARIES(altonegen PRIVATE ${LINKER_FLAGS} common OpenAL ${MATH_LIB})
1489
1490     IF(ALSOFT_INSTALL)
1491         INSTALL(TARGETS altonegen
1492                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1493                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1494                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1495         )
1496     ENDIF()
1497
1498     MESSAGE(STATUS "Building test programs")
1499     MESSAGE(STATUS "")
1500 ENDIF()
1501
1502 IF(ALSOFT_EXAMPLES)
1503     ADD_EXECUTABLE(alrecord examples/alrecord.c)
1504     TARGET_COMPILE_DEFINITIONS(alrecord PRIVATE ${CPP_DEFS})
1505     TARGET_COMPILE_OPTIONS(alrecord PRIVATE ${C_FLAGS})
1506     TARGET_LINK_LIBRARIES(alrecord PRIVATE ${LINKER_FLAGS} common OpenAL)
1507
1508     IF(ALSOFT_INSTALL)
1509         INSTALL(TARGETS alrecord
1510                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1511                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1512                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1513         )
1514     ENDIF()
1515
1516     MESSAGE(STATUS "Building example programs")
1517
1518     IF(SDL2_FOUND)
1519         IF(SDL_SOUND_FOUND)
1520             # Add a static library with common functions used by multiple targets
1521             ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c)
1522             TARGET_COMPILE_DEFINITIONS(ex-common PRIVATE ${CPP_DEFS})
1523             TARGET_COMPILE_OPTIONS(ex-common PRIVATE ${C_FLAGS})
1524
1525             ADD_EXECUTABLE(alplay examples/alplay.c)
1526             TARGET_COMPILE_DEFINITIONS(alplay PRIVATE ${CPP_DEFS})
1527             TARGET_INCLUDE_DIRECTORIES(alplay
1528                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1529             TARGET_COMPILE_OPTIONS(alplay PRIVATE ${C_FLAGS})
1530             TARGET_LINK_LIBRARIES(alplay
1531                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1532                         OpenAL)
1533
1534             ADD_EXECUTABLE(alstream examples/alstream.c)
1535             TARGET_COMPILE_DEFINITIONS(alstream PRIVATE ${CPP_DEFS})
1536             TARGET_INCLUDE_DIRECTORIES(alstream
1537                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1538             TARGET_COMPILE_OPTIONS(alstream PRIVATE ${C_FLAGS})
1539             TARGET_LINK_LIBRARIES(alstream
1540                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1541                         OpenAL)
1542
1543             ADD_EXECUTABLE(alreverb examples/alreverb.c)
1544             TARGET_COMPILE_DEFINITIONS(alreverb PRIVATE ${CPP_DEFS})
1545             TARGET_INCLUDE_DIRECTORIES(alreverb
1546                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1547             TARGET_COMPILE_OPTIONS(alreverb PRIVATE ${C_FLAGS})
1548             TARGET_LINK_LIBRARIES(alreverb
1549                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1550                         OpenAL)
1551
1552             ADD_EXECUTABLE(almultireverb examples/almultireverb.c)
1553             TARGET_COMPILE_DEFINITIONS(almultireverb PRIVATE ${CPP_DEFS})
1554             TARGET_INCLUDE_DIRECTORIES(almultireverb
1555                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1556             TARGET_COMPILE_OPTIONS(almultireverb PRIVATE ${C_FLAGS})
1557             TARGET_LINK_LIBRARIES(almultireverb
1558                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1559                         OpenAL ${MATH_LIB})
1560
1561             ADD_EXECUTABLE(allatency examples/allatency.c)
1562             TARGET_COMPILE_DEFINITIONS(allatency PRIVATE ${CPP_DEFS})
1563             TARGET_INCLUDE_DIRECTORIES(allatency
1564                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1565             TARGET_COMPILE_OPTIONS(allatency PRIVATE ${C_FLAGS})
1566             TARGET_LINK_LIBRARIES(allatency
1567                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1568                         OpenAL)
1569
1570             ADD_EXECUTABLE(alloopback examples/alloopback.c)
1571             TARGET_COMPILE_DEFINITIONS(alloopback PRIVATE ${CPP_DEFS})
1572             TARGET_INCLUDE_DIRECTORIES(alloopback
1573                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1574             TARGET_COMPILE_OPTIONS(alloopback PRIVATE ${C_FLAGS})
1575             TARGET_LINK_LIBRARIES(alloopback
1576                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1577                         OpenAL ${MATH_LIB})
1578
1579             ADD_EXECUTABLE(alhrtf examples/alhrtf.c)
1580             TARGET_COMPILE_DEFINITIONS(alhrtf PRIVATE ${CPP_DEFS})
1581             TARGET_INCLUDE_DIRECTORIES(alhrtf
1582                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1583             TARGET_COMPILE_OPTIONS(alhrtf PRIVATE ${C_FLAGS})
1584             TARGET_LINK_LIBRARIES(alhrtf
1585                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1586                         OpenAL ${MATH_LIB})
1587
1588             IF(ALSOFT_INSTALL)
1589                 INSTALL(TARGETS alplay alstream alreverb almultireverb allatency alloopback alhrtf
1590                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1591                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1592                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1593                 )
1594             ENDIF()
1595
1596             MESSAGE(STATUS "Building SDL_sound example programs")
1597         ENDIF()
1598
1599         SET(FFVER_OK FALSE)
1600         IF(FFMPEG_FOUND)
1601             SET(FFVER_OK TRUE)
1602             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1603                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1604                 SET(FFVER_OK FALSE)
1605             ENDIF()
1606             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1607                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1608                 SET(FFVER_OK FALSE)
1609             ENDIF()
1610             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1611                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1612                 SET(FFVER_OK FALSE)
1613             ENDIF()
1614             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1615                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1616                 SET(FFVER_OK FALSE)
1617             ENDIF()
1618             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1619                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1620                 SET(FFVER_OK FALSE)
1621             ENDIF()
1622         ENDIF()
1623         IF(FFVER_OK)
1624             ADD_EXECUTABLE(alffplay examples/alffplay.cpp)
1625             TARGET_COMPILE_DEFINITIONS(alffplay PRIVATE ${CPP_DEFS})
1626             TARGET_INCLUDE_DIRECTORIES(alffplay
1627                 PRIVATE ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS})
1628             TARGET_COMPILE_OPTIONS(alffplay PRIVATE ${C_FLAGS})
1629             TARGET_LINK_LIBRARIES(alffplay
1630                 PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} common OpenAL)
1631
1632             IF(ALSOFT_INSTALL)
1633                 INSTALL(TARGETS alffplay
1634                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1635                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1636                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1637                 )
1638             ENDIF()
1639             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1640         ENDIF()
1641         MESSAGE(STATUS "")
1642     ENDIF()
1643 ENDIF()