CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19     IF(POLICY CMP0075)
  20         CMAKE_POLICY(SET CMP0075 NEW)
  21     ENDIF(POLICY CMP0075)
  22 ENDIF(COMMAND CMAKE_POLICY)
  23
  24 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  25
  26 INCLUDE(CheckFunctionExists)
  27 INCLUDE(CheckLibraryExists)
  28 INCLUDE(CheckSharedFunctionExists)
  29 INCLUDE(CheckIncludeFile)
  30 INCLUDE(CheckIncludeFiles)
  31 INCLUDE(CheckSymbolExists)
  32 INCLUDE(CheckCCompilerFlag)
  33 INCLUDE(CheckCXXCompilerFlag)
  34 INCLUDE(CheckCSourceCompiles)
  35 INCLUDE(CheckCXXSourceCompiles)
  36 INCLUDE(CheckTypeSize)
  37 include(CheckStructHasMember)
  38 include(CheckFileOffsetBits)
  39 include(GNUInstallDirs)
  40
  41 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  42
  43
  44 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  45
  46 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  47
  48 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  49 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  50
  51 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  52 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  53
  54 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  55 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  56 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  57 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  58
  59 if(DEFINED SHARE_INSTALL_DIR)
  60     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  61     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  62 endif()
  63
  64 if(DEFINED LIB_SUFFIX)
  65     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  66 endif()
  67
  68
  69 SET(CPP_DEFS ) # C pre-process, not C++
  70 SET(INC_PATHS )
  71 SET(C_FLAGS )
  72 SET(LINKER_FLAGS )
  73 SET(EXTRA_LIBS )
  74
  75 IF(WIN32)
  76     SET(CPP_DEFS ${CPP_DEFS} _WIN32 _WIN32_WINNT=0x0502)
  77
  78     OPTION(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
  79
  80     # This option is mainly for static linking OpenAL Soft into another project
  81     # that already defines the IDs. It is up to that project to ensure all
  82     # required IDs are defined.
  83     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  84
  85     IF(MINGW)
  86         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  87         IF(NOT DLLTOOL)
  88             IF(HOST)
  89                 SET(DLLTOOL "${HOST}-dlltool")
  90             ELSE()
  91                 SET(DLLTOOL "dlltool")
  92             ENDIF()
  93         ENDIF()
  94     ENDIF()
  95 ENDIF()
  96
  97
  98 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  99 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 100     SET(INC_PATHS ${INC_PATHS} /usr/include)
 101     SET(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
 102 ENDIF()
 103
 104 IF(NOT LIBTYPE)
 105     SET(LIBTYPE SHARED)
 106 ENDIF()
 107
 108 SET(LIB_MAJOR_VERSION "1")
 109 SET(LIB_MINOR_VERSION "19")
 110 SET(LIB_REVISION "1")
 111 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 112
 113 SET(EXPORT_DECL "")
 114 SET(ALIGN_DECL "")
 115
 116
 117 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 118 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 119
 120
 121 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 122 IF(HAVE_STD_C11)
 123     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 124 ELSE()
 125     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 126     IF(HAVE_STD_C99)
 127         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 128     ENDIF()
 129 ENDIF()
 130
 131 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 132 IF(HAVE_STD_CXX11)
 133     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 134 ENDIF()
 135
 136 if(NOT WIN32)
 137     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 138     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 139     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 140         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 141         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 142         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 143         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 144             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 145         ELSE()
 146             SET(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 147         ENDIF()
 148     ENDIF()
 149     UNSET(OLD_REQUIRED_FLAGS)
 150 ENDIF()
 151
 152 # Set defines for large file support. Don't set this for Android targets. See:
 153 # https://android-developers.googleblog.com/2017/09/introducing-android-native-development.html
 154 IF(NOT ANDROID)
 155     CHECK_FILE_OFFSET_BITS()
 156     IF(_FILE_OFFSET_BITS)
 157         SET(CPP_DEFS ${CPP_DEFS} "_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 158         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 159     ENDIF()
 160     SET(CPP_DEFS ${CPP_DEFS} _LARGEFILE_SOURCE _LARGE_FILES)
 161     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 162 ENDIF()
 163
 164 # C99 has restrict, but C++ does not, so we can only utilize __restrict.
 165 SET(RESTRICT_DECL )
 166 CHECK_C_SOURCE_COMPILES("int *__restrict foo;
 167                          int main() {return 0;}" HAVE___RESTRICT)
 168 IF(HAVE___RESTRICT)
 169     SET(RESTRICT_DECL "__restrict")
 170 ENDIF()
 171
 172 # MSVC may need workarounds for C99 inline
 173 IF(MSVC)
 174     # TODO: Once we truly require C99, this inline check should go away.
 175     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 176                              int main() {return 0;}" HAVE_INLINE)
 177     IF(NOT HAVE_INLINE)
 178         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 179                                  int main() {return 0;}" HAVE___INLINE)
 180         IF(NOT HAVE___INLINE)
 181             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 182         ENDIF()
 183
 184         SET(CPP_DEFS ${CPP_DEFS} inline=__inline)
 185         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 186     ENDIF()
 187 ENDIF()
 188
 189 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 190 IF(CMAKE_COMPILER_IS_GNUCC)
 191     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 192
 193     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 194     # Force no inlining for the next test.
 195     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 196
 197     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 198                              int main() {return foo();}" INLINE_IS_C99)
 199     IF(NOT INLINE_IS_C99)
 200         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 201                              Please update your compiler for better C99 compliance.")
 202     ENDIF()
 203
 204     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 205 ENDIF()
 206
 207 # Some systems may need libatomic for C11 atomic functions to work
 208 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 209 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 210 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 211 int _Atomic foo = ATOMIC_VAR_INIT(0);
 212 int main()
 213 {
 214     return atomic_fetch_add(&foo, 2);
 215 }"
 216 HAVE_LIBATOMIC)
 217 IF(NOT HAVE_LIBATOMIC)
 218     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 219 ELSE()
 220     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 221 ENDIF()
 222 UNSET(OLD_REQUIRED_LIBRARIES)
 223
 224 # Include liblog for Android logging
 225 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 226 IF(HAVE_LIBLOG)
 227     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 228     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 229 ENDIF()
 230
 231 # Add definitions, compiler switches, etc.
 232 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 233
 234 IF(NOT CMAKE_BUILD_TYPE)
 235     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 236         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 237         FORCE)
 238 ENDIF()
 239 IF(NOT CMAKE_DEBUG_POSTFIX)
 240     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 241         "Library postfix for debug builds. Normally left blank."
 242         FORCE)
 243 ENDIF()
 244
 245 IF(MSVC)
 246     SET(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_DEPRECATE NOMINMAX)
 247     SET(C_FLAGS ${C_FLAGS} /wd4065 /wd4098 /wd4200)
 248
 249     IF(NOT DXSDK_DIR)
 250         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 251     ELSE()
 252         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 253     ENDIF()
 254     IF(DXSDK_DIR)
 255         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 256     ENDIF()
 257
 258     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 259     IF(FORCE_STATIC_VCRT)
 260         FOREACH(flag_var
 261                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 262                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 263             IF(${flag_var} MATCHES "/MD")
 264                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 265             ENDIF()
 266         ENDFOREACH(flag_var)
 267     ENDIF()
 268 ELSE()
 269     SET(C_FLAGS ${C_FLAGS} -Winline -Wall)
 270     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 271     IF(HAVE_W_EXTRA)
 272         SET(C_FLAGS ${C_FLAGS} -Wextra)
 273     ENDIF()
 274
 275     IF(ALSOFT_WERROR)
 276         SET(C_FLAGS ${C_FLAGS} -Werror)
 277     ENDIF()
 278
 279     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 280     # instead of NDEBUG)
 281     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 282         IF(${flag_var} MATCHES "-DNDEBUG")
 283             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 284         ENDIF()
 285     ENDFOREACH()
 286
 287     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 288     IF(HAVE_FNO_MATH_ERRNO)
 289         SET(C_FLAGS ${C_FLAGS} -fno-math-errno)
 290     ENDIF()
 291
 292     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 293                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 294
 295     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 296     if(ALSOFT_STATIC_LIBGCC)
 297         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 298         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 299         check_c_source_compiles(
 300 "#include <stdlib.h>
 301 int main()
 302 {
 303     return 0;
 304 }"
 305             HAVE_STATIC_LIBGCC_SWITCH
 306         )
 307         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 308         unset(OLD_REQUIRED_LIBRARIES)
 309
 310         if(NOT HAVE_STATIC_LIBGCC_SWITCH)
 311             message(FATAL_ERROR "Cannot static link libgcc")
 312         endif()
 313         set(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 314     endif()
 315
 316     option(ALSOFT_STATIC_STDCXX "Static link libstdc++" OFF)
 317     if(ALSOFT_STATIC_STDCXX)
 318         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 319         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 320         check_cxx_source_compiles(
 321 "#include <cstdlib>
 322 int main()
 323 {
 324     return 0;
 325 }"
 326             HAVE_STATIC_LIBSTDCXX_SWITCH
 327         )
 328         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 329         unset(OLD_REQUIRED_LIBRARIES)
 330
 331         if(NOT HAVE_STATIC_LIBSTDCXX_SWITCH)
 332             message(FATAL_ERROR "Cannot static link libstdc++")
 333         endif()
 334         set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 335     endif()
 336
 337     if(WIN32)
 338         option(ALSOFT_STATIC_WINPTHREAD "Static link libwinpthread" OFF)
 339         if(ALSOFT_STATIC_WINPTHREAD)
 340             set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 341             set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 342             check_cxx_source_compiles(
 343 "#include <cstdlib>
 344 int main()
 345 {
 346     return 0;
 347 }"
 348                 HAVE_STATIC_LIBWINPTHREAD_SWITCH
 349             )
 350             set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 351             unset(OLD_REQUIRED_LIBRARIES)
 352
 353             if(NOT HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 354                 message(FATAL_ERROR "Cannot static link libwinpthread")
 355             endif()
 356             set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 357         endif()
 358     endif()
 359 ENDIF()
 360
 361 # Set visibility/export options if available
 362 IF(WIN32)
 363     SET(EXPORT_DECL "__declspec(dllexport)")
 364     IF(NOT MINGW)
 365         SET(ALIGN_DECL "__declspec(align(x))")
 366     ELSE()
 367         SET(ALIGN_DECL "__declspec(aligned(x))")
 368     ENDIF()
 369 ELSE()
 370     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 371     # Yes GCC, really don't accept visibility modes you don't support
 372     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 373
 374     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 375                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 376     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 377         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 378     ELSE()
 379         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 380                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 381         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 382             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 383         ENDIF()
 384     ENDIF()
 385
 386     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 387         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 388         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 389             SET(C_FLAGS ${C_FLAGS} -fvisibility=hidden)
 390         ENDIF()
 391     ENDIF()
 392
 393     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 394                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 395     IF(HAVE_ATTRIBUTE_ALIGNED)
 396         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 397     ENDIF()
 398
 399     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 400 ENDIF()
 401
 402 SET(SSE_SWITCH "")
 403 SET(SSE2_SWITCH "")
 404 SET(SSE3_SWITCH "")
 405 SET(SSE4_1_SWITCH "")
 406 SET(FPU_NEON_SWITCH "")
 407
 408 CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 409 IF(HAVE_MSSE_SWITCH)
 410     SET(SSE_SWITCH "-msse")
 411 ENDIF()
 412 CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 413 IF(HAVE_MSSE2_SWITCH)
 414     SET(SSE2_SWITCH "-msse2")
 415 ENDIF()
 416 CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 417 IF(HAVE_MSSE3_SWITCH)
 418     SET(SSE3_SWITCH "-msse3")
 419 ENDIF()
 420 CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 421 IF(HAVE_MSSE4_1_SWITCH)
 422     SET(SSE4_1_SWITCH "-msse4.1")
 423 ENDIF()
 424 CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 425 IF(HAVE_MFPU_NEON_SWITCH)
 426     SET(FPU_NEON_SWITCH "-mfpu=neon")
 427 ENDIF()
 428
 429 SET(FPMATH_SET "0")
 430 IF(CMAKE_SIZEOF_VOID_P MATCHES "4")
 431     IF(SSE_SWITCH OR MSVC)
 432         OPTION(ALSOFT_ENABLE_SSE_CODEGEN "Enable SSE code generation instead of x87 for 32-bit targets." TRUE)
 433     ENDIF()
 434     IF(SSE2_SWITCH OR MSVC)
 435         OPTION(ALSOFT_ENABLE_SSE2_CODEGEN "Enable SSE2 code generation instead of x87 for 32-bit targets." TRUE)
 436     ENDIF()
 437
 438     IF(ALSOFT_ENABLE_SSE2_CODEGEN)
 439         IF(SSE2_SWITCH)
 440             CHECK_C_COMPILER_FLAG("${SSE2_SWITCH} -mfpmath=sse" HAVE_MFPMATH_SSE_2)
 441             IF(HAVE_MFPMATH_SSE_2)
 442                 SET(C_FLAGS ${C_FLAGS} ${SSE2_SWITCH} -mfpmath=sse)
 443                 SET(FPMATH_SET 2)
 444             ENDIF()
 445         ELSEIF(MSVC)
 446             CHECK_C_COMPILER_FLAG("/arch:SSE2" HAVE_ARCH_SSE2)
 447             IF(HAVE_ARCH_SSE2)
 448                 SET(C_FLAGS ${C_FLAGS} "/arch:SSE2")
 449                 SET(FPMATH_SET 2)
 450             ENDIF()
 451         ENDIF()
 452     ENDIF()
 453     IF(ALSOFT_ENABLE_SSE_CODEGEN AND NOT FPMATH_SET)
 454         IF(SSE_SWITCH)
 455             CHECK_C_COMPILER_FLAG("${SSE_SWITCH} -mfpmath=sse" HAVE_MFPMATH_SSE)
 456             IF(HAVE_MFPMATH_SSE)
 457                 SET(C_FLAGS ${C_FLAGS} ${SSE_SWITCH} -mfpmath=sse)
 458                 SET(FPMATH_SET 1)
 459             ENDIF()
 460         ELSEIF(MSVC)
 461             CHECK_C_COMPILER_FLAG("/arch:SSE" HAVE_ARCH_SSE)
 462             IF(HAVE_ARCH_SSE)
 463                 SET(C_FLAGS ${C_FLAGS} "/arch:SSE")
 464                 SET(FPMATH_SET 1)
 465             ENDIF()
 466         ENDIF()
 467     ENDIF()
 468 ENDIF()
 469
 470
 471 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 472                          int main() {return 0;}" HAVE_GCC_FORMAT)
 473
 474 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 475 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 476 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 477 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 478 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 479 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 480 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 481 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 482 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 483 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 484 IF(NOT HAVE_GUIDDEF_H)
 485     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 486 ENDIF()
 487
 488 # Some systems need libm for some of the following math functions to work
 489 SET(MATH_LIB )
 490 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 491 IF(HAVE_LIBM)
 492     SET(MATH_LIB ${MATH_LIB} m)
 493     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 494 ENDIF()
 495
 496 # Check for the dlopen API (for dynamicly loading backend libs)
 497 IF(ALSOFT_DLOPEN)
 498     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 499     IF(HAVE_LIBDL)
 500         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 501         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 502     ENDIF()
 503
 504     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 505 ENDIF()
 506
 507 # Check for a cpuid intrinsic
 508 IF(HAVE_CPUID_H)
 509     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 510         int main()
 511         {
 512             unsigned int eax, ebx, ecx, edx;
 513             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 514         }" HAVE_GCC_GET_CPUID)
 515 ENDIF()
 516 IF(HAVE_INTRIN_H)
 517     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 518         int main()
 519         {
 520             int regs[4];
 521             __cpuid(regs, 0);
 522             return regs[0];
 523         }" HAVE_CPUID_INTRINSIC)
 524     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 525         int main()
 526         {
 527             unsigned long idx = 0;
 528             _BitScanForward64(&idx, 1);
 529             return idx;
 530         }" HAVE_BITSCANFORWARD64_INTRINSIC)
 531     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 532         int main()
 533         {
 534             unsigned long idx = 0;
 535             _BitScanForward(&idx, 1);
 536             return idx;
 537         }" HAVE_BITSCANFORWARD_INTRINSIC)
 538 ENDIF()
 539
 540 CHECK_SYMBOL_EXISTS(sysconf          unistd.h HAVE_SYSCONF)
 541 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 542 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 543 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 544 CHECK_SYMBOL_EXISTS(proc_pidpath     libproc.h HAVE_PROC_PIDPATH)
 545
 546 IF(HAVE_FLOAT_H)
 547     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 548     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 549 ENDIF()
 550
 551 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 552 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 553 IF(NOT HAVE_STRCASECMP)
 554     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 555     IF(NOT HAVE__STRICMP)
 556         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 557     ENDIF()
 558
 559     SET(CPP_DEFS ${CPP_DEFS} strcasecmp=_stricmp)
 560 ENDIF()
 561
 562 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 563 IF(NOT HAVE_STRNCASECMP)
 564     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 565     IF(NOT HAVE__STRNICMP)
 566         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 567     ENDIF()
 568
 569     SET(CPP_DEFS ${CPP_DEFS} strncasecmp=_strnicmp)
 570 ENDIF()
 571
 572
 573 # Check if we have Windows headers
 574 SET(OLD_REQUIRED_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS})
 575 SET(CMAKE_REQUIRED_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS} -D_WIN32_WINNT=0x0502)
 576 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H)
 577 SET(CMAKE_REQUIRED_DEFINITIONS ${OLD_REQUIRED_DEFINITIONS})
 578 UNSET(OLD_REQUIRED_DEFINITIONS)
 579
 580 IF(NOT HAVE_WINDOWS_H)
 581     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 582     IF(NOT HAVE_GETTIMEOFDAY)
 583         MESSAGE(FATAL_ERROR "No timing function found!")
 584     ENDIF()
 585
 586     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 587     IF(NOT HAVE_NANOSLEEP)
 588         MESSAGE(FATAL_ERROR "No sleep function found!")
 589     ENDIF()
 590
 591     # We need pthreads outside of Windows
 592     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 593     IF(NOT HAVE_PTHREAD_H)
 594         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 595     ENDIF()
 596     # Some systems need pthread_np.h to get recursive mutexes
 597     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 598
 599     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 600     IF(HAVE_PTHREAD)
 601         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 602         SET(C_FLAGS ${C_FLAGS} -pthread)
 603         SET(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 604     ENDIF()
 605
 606     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 607     IF(HAVE_LIBPTHREAD)
 608         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 609     ENDIF()
 610
 611     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 612
 613     IF(HAVE_PTHREAD_NP_H)
 614         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 615         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 616             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 617         ELSE()
 618             CHECK_C_SOURCE_COMPILES("
 619 #include <pthread.h>
 620 #include <pthread_np.h>
 621 int main()
 622 {
 623     pthread_setname_np(\"testname\");
 624     return 0;
 625 }"
 626                 PTHREAD_SETNAME_NP_ONE_PARAM
 627             )
 628             CHECK_C_SOURCE_COMPILES("
 629 #include <pthread.h>
 630 #include <pthread_np.h>
 631 int main()
 632 {
 633     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 634     return 0;
 635 }"
 636                 PTHREAD_SETNAME_NP_THREE_PARAMS
 637             )
 638         ENDIF()
 639     ELSE()
 640         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 641         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 642             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 643         ELSE()
 644             CHECK_C_SOURCE_COMPILES("
 645 #include <pthread.h>
 646 int main()
 647 {
 648     pthread_setname_np(\"testname\");
 649     return 0;
 650 }"
 651                 PTHREAD_SETNAME_NP_ONE_PARAM
 652             )
 653             CHECK_C_SOURCE_COMPILES("
 654 #include <pthread.h>
 655 int main()
 656 {
 657     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 658     return 0;
 659 }"
 660                 PTHREAD_SETNAME_NP_THREE_PARAMS
 661             )
 662         ENDIF()
 663     ENDIF()
 664
 665     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 666     IF(HAVE_LIBRT)
 667         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 668     ENDIF()
 669 ENDIF()
 670
 671 CHECK_SYMBOL_EXISTS(getopt unistd.h HAVE_GETOPT)
 672
 673 # Check for a 64-bit type
 674 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 675 IF(NOT HAVE_STDINT_H)
 676     IF(HAVE_WINDOWS_H)
 677         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 678                                  #include <windows.h>
 679                                  __int64 foo;
 680                                  int main() {return 0;}" HAVE___INT64)
 681     ENDIF()
 682     IF(NOT HAVE___INT64)
 683         IF(NOT SIZEOF_LONG MATCHES "8")
 684             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 685                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 686             ENDIF()
 687         ENDIF()
 688     ENDIF()
 689 ENDIF()
 690
 691
 692 SET(COMMON_OBJS
 693     common/alcomplex.cpp
 694     common/alcomplex.h
 695     common/almalloc.cpp
 696     common/almalloc.h
 697     common/atomic.h
 698     common/math_defs.h
 699     common/threads.cpp
 700     common/threads.h
 701     common/vecmat.h
 702 )
 703 SET(OPENAL_OBJS
 704     OpenAL32/Include/alMain.h
 705     OpenAL32/Include/alu.h
 706
 707     OpenAL32/Include/alAuxEffectSlot.h
 708     OpenAL32/alAuxEffectSlot.cpp
 709     OpenAL32/Include/alBuffer.h
 710     OpenAL32/alBuffer.cpp
 711     OpenAL32/Include/alEffect.h
 712     OpenAL32/alEffect.cpp
 713     OpenAL32/Include/alError.h
 714     OpenAL32/alError.cpp
 715     OpenAL32/alExtension.cpp
 716     OpenAL32/Include/alFilter.h
 717     OpenAL32/alFilter.cpp
 718     OpenAL32/Include/alListener.h
 719     OpenAL32/alListener.cpp
 720     OpenAL32/Include/alSource.h
 721     OpenAL32/alSource.cpp
 722     OpenAL32/alState.cpp
 723     OpenAL32/event.cpp
 724     OpenAL32/Include/sample_cvt.h
 725     OpenAL32/sample_cvt.cpp
 726 )
 727 SET(ALC_OBJS
 728     Alc/alc.cpp
 729     Alc/alu.cpp
 730     Alc/alconfig.cpp
 731     Alc/alconfig.h
 732     Alc/alcontext.h
 733     Alc/bs2b.cpp
 734     Alc/bs2b.h
 735     Alc/converter.cpp
 736     Alc/converter.h
 737     Alc/inprogext.h
 738     Alc/mastering.cpp
 739     Alc/mastering.h
 740     Alc/ringbuffer.cpp
 741     Alc/ringbuffer.h
 742     Alc/effects/autowah.cpp
 743     Alc/effects/chorus.cpp
 744     Alc/effects/compressor.cpp
 745     Alc/effects/dedicated.cpp
 746     Alc/effects/distortion.cpp
 747     Alc/effects/echo.cpp
 748     Alc/effects/equalizer.cpp
 749     Alc/effects/fshifter.cpp
 750     Alc/effects/modulator.cpp
 751     Alc/effects/null.cpp
 752     Alc/effects/pshifter.cpp
 753     Alc/effects/reverb.cpp
 754     Alc/filters/defs.h
 755     Alc/filters/filter.cpp
 756     Alc/filters/nfc.cpp
 757     Alc/filters/nfc.h
 758     Alc/filters/splitter.cpp
 759     Alc/filters/splitter.h
 760     Alc/helpers.cpp
 761     Alc/compat.h
 762     Alc/cpu_caps.h
 763     Alc/fpu_modes.h
 764     Alc/logging.h
 765     Alc/vector.h
 766     Alc/hrtf.cpp
 767     Alc/hrtf.h
 768     Alc/uhjfilter.cpp
 769     Alc/uhjfilter.h
 770     Alc/ambdec.cpp
 771     Alc/ambdec.h
 772     Alc/bformatdec.cpp
 773     Alc/bformatdec.h
 774     Alc/panning.cpp
 775     Alc/polymorphism.h
 776     Alc/mixvoice.cpp
 777     Alc/mixer/defs.h
 778     Alc/mixer/mixer_c.cpp
 779 )
 780
 781
 782 SET(CPU_EXTS "Default")
 783 SET(HAVE_SSE        0)
 784 SET(HAVE_SSE2       0)
 785 SET(HAVE_SSE3       0)
 786 SET(HAVE_SSE4_1     0)
 787 SET(HAVE_NEON       0)
 788
 789 SET(HAVE_ALSA       0)
 790 SET(HAVE_OSS        0)
 791 SET(HAVE_SOLARIS    0)
 792 SET(HAVE_SNDIO      0)
 793 SET(HAVE_QSA        0)
 794 SET(HAVE_DSOUND     0)
 795 SET(HAVE_WASAPI     0)
 796 SET(HAVE_WINMM      0)
 797 SET(HAVE_PORTAUDIO  0)
 798 SET(HAVE_PULSEAUDIO 0)
 799 SET(HAVE_COREAUDIO  0)
 800 SET(HAVE_OPENSL     0)
 801 SET(HAVE_WAVE       0)
 802 SET(HAVE_SDL2       0)
 803
 804 # Check for SSE support
 805 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 806 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 807 IF(HAVE_XMMINTRIN_H)
 808     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 809     IF(ALSOFT_CPUEXT_SSE)
 810         SET(HAVE_SSE 1)
 811         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse.cpp)
 812         IF(SSE_SWITCH)
 813             SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse.cpp PROPERTIES
 814                                         COMPILE_FLAGS "${SSE_SWITCH}")
 815         ENDIF()
 816         SET(CPU_EXTS "${CPU_EXTS}, SSE")
 817     ENDIF()
 818 ENDIF()
 819 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 820     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 821 ENDIF()
 822
 823 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 824 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 825 IF(HAVE_EMMINTRIN_H)
 826     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 827     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 828         SET(HAVE_SSE2 1)
 829         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse2.cpp)
 830         IF(SSE2_SWITCH)
 831             SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse2.cpp PROPERTIES
 832                                         COMPILE_FLAGS "${SSE2_SWITCH}")
 833         ENDIF()
 834         SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 835     ENDIF()
 836 ENDIF()
 837 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 838     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 839 ENDIF()
 840
 841 OPTION(ALSOFT_REQUIRE_SSE3 "Require SSE3 support" OFF)
 842 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 843 IF(HAVE_EMMINTRIN_H)
 844     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 845     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 846         SET(HAVE_SSE3 1)
 847         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse3.cpp)
 848         IF(SSE2_SWITCH)
 849             SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse3.cpp PROPERTIES
 850                                         COMPILE_FLAGS "${SSE3_SWITCH}")
 851         ENDIF()
 852         SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 853     ENDIF()
 854 ENDIF()
 855 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 856     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 857 ENDIF()
 858
 859 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 860 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 861 IF(HAVE_SMMINTRIN_H)
 862     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 863     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 864         SET(HAVE_SSE4_1 1)
 865         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse41.cpp)
 866         IF(SSE4_1_SWITCH)
 867             SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse41.cpp PROPERTIES
 868                                         COMPILE_FLAGS "${SSE4_1_SWITCH}")
 869         ENDIF()
 870         SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 871     ENDIF()
 872 ENDIF()
 873 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 874     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 875 ENDIF()
 876
 877 # Check for ARM Neon support
 878 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 879 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H ${FPU_NEON_SWITCH})
 880 IF(HAVE_ARM_NEON_H)
 881     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 882     IF(ALSOFT_CPUEXT_NEON)
 883         SET(HAVE_NEON 1)
 884         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_neon.cpp)
 885         IF(FPU_NEON_SWITCH)
 886             SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_neon.cpp PROPERTIES
 887                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 888         ENDIF()
 889         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 890     ENDIF()
 891 ENDIF()
 892 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 893     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 894 ENDIF()
 895
 896
 897 IF(WIN32 OR HAVE_DLFCN_H)
 898     SET(IS_LINKED "")
 899     MACRO(ADD_BACKEND_LIBS _LIBS)
 900     ENDMACRO()
 901 ELSE()
 902     SET(IS_LINKED " (linked)")
 903     MACRO(ADD_BACKEND_LIBS _LIBS)
 904         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 905     ENDMACRO()
 906 ENDIF()
 907
 908 SET(BACKENDS "")
 909 SET(ALC_OBJS  ${ALC_OBJS}
 910     Alc/backends/base.cpp
 911     Alc/backends/base.h
 912     # Default backends, always available
 913     Alc/backends/loopback.cpp
 914     Alc/backends/loopback.h
 915     Alc/backends/null.cpp
 916     Alc/backends/null.h
 917 )
 918
 919 # Check ALSA backend
 920 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 921 FIND_PACKAGE(ALSA)
 922 IF(ALSA_FOUND)
 923     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 924     IF(ALSOFT_BACKEND_ALSA)
 925         SET(HAVE_ALSA 1)
 926         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 927         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.cpp Alc/backends/alsa.h)
 928         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 929         SET(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 930     ENDIF()
 931 ENDIF()
 932 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 933     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 934 ENDIF()
 935
 936 # Check OSS backend
 937 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 938 FIND_PACKAGE(OSS)
 939 IF(OSS_FOUND)
 940     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 941     IF(ALSOFT_BACKEND_OSS)
 942         SET(HAVE_OSS 1)
 943         SET(BACKENDS  "${BACKENDS} OSS,")
 944         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.cpp Alc/backends/oss.h)
 945         IF(OSS_LIBRARIES)
 946             SET(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 947         ENDIF()
 948         SET(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 949     ENDIF()
 950 ENDIF()
 951 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 952     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 953 ENDIF()
 954
 955 # Check Solaris backend
 956 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 957 FIND_PACKAGE(AudioIO)
 958 IF(AUDIOIO_FOUND)
 959     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 960     IF(ALSOFT_BACKEND_SOLARIS)
 961         SET(HAVE_SOLARIS 1)
 962         SET(BACKENDS  "${BACKENDS} Solaris,")
 963         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.cpp Alc/backends/solaris.h)
 964         SET(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 965     ENDIF()
 966 ENDIF()
 967 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 968     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 969 ENDIF()
 970
 971 # Check SndIO backend
 972 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 973 FIND_PACKAGE(SoundIO)
 974 IF(SOUNDIO_FOUND)
 975     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 976     IF(ALSOFT_BACKEND_SNDIO)
 977         SET(HAVE_SNDIO 1)
 978         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 979         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.cpp Alc/backends/sndio.h)
 980         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 981         SET(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 982     ENDIF()
 983 ENDIF()
 984 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 985     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 986 ENDIF()
 987
 988 # Check QSA backend
 989 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 990 FIND_PACKAGE(QSA)
 991 IF(QSA_FOUND)
 992     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 993     IF(ALSOFT_BACKEND_QSA)
 994         SET(HAVE_QSA 1)
 995         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 996         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.cpp Alc/backends/qsa.h)
 997         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 998         SET(INC_PATHS ${INC_PATHS} ${QSA_INCLUDE_DIRS})
 999     ENDIF()
1000 ENDIF()
1001 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
1002     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
1003 ENDIF()
1004
1005 # Check Windows-only backends
1006 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
1007 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
1008 OPTION(ALSOFT_REQUIRE_WASAPI "Require WASAPI backend" OFF)
1009 IF(HAVE_WINDOWS_H)
1010     SET(OLD_REQUIRED_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS})
1011     SET(CMAKE_REQUIRED_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS} -D_WIN32_WINNT=0x0502)
1012
1013     # Check MMSystem backend
1014     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H)
1015     IF(HAVE_MMSYSTEM_H)
1016         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
1017         IF(HAVE_LIBWINMM)
1018             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
1019             IF(ALSOFT_BACKEND_WINMM)
1020                 SET(HAVE_WINMM 1)
1021                 SET(BACKENDS  "${BACKENDS} WinMM,")
1022                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.cpp Alc/backends/winmm.h)
1023                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
1024             ENDIF()
1025         ENDIF()
1026     ENDIF()
1027
1028     # Check DSound backend
1029     FIND_PACKAGE(DSound)
1030     IF(DSOUND_FOUND)
1031         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
1032         IF(ALSOFT_BACKEND_DSOUND)
1033             SET(HAVE_DSOUND 1)
1034             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
1035             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.cpp Alc/backends/dsound.h)
1036             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
1037             SET(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIRS})
1038         ENDIF()
1039     ENDIF()
1040
1041     # Check for WASAPI backend
1042     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
1043     IF(HAVE_MMDEVICEAPI_H)
1044         OPTION(ALSOFT_BACKEND_WASAPI "Enable WASAPI backend" ON)
1045         IF(ALSOFT_BACKEND_WASAPI)
1046             SET(HAVE_WASAPI 1)
1047             SET(BACKENDS  "${BACKENDS} WASAPI,")
1048             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wasapi.cpp Alc/backends/wasapi.h)
1049         ENDIF()
1050     ENDIF()
1051
1052     SET(CMAKE_REQUIRED_DEFINITIONS ${OLD_REQUIRED_DEFINITIONS})
1053     UNSET(OLD_REQUIRED_DEFINITIONS)
1054 ENDIF()
1055 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1056     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
1057 ENDIF()
1058 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1059     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
1060 ENDIF()
1061 IF(ALSOFT_REQUIRE_WASAPI AND NOT HAVE_WASAPI)
1062     MESSAGE(FATAL_ERROR "Failed to enabled required WASAPI backend")
1063 ENDIF()
1064
1065 # Check PortAudio backend
1066 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1067 FIND_PACKAGE(PortAudio)
1068 IF(PORTAUDIO_FOUND)
1069     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1070     IF(ALSOFT_BACKEND_PORTAUDIO)
1071         SET(HAVE_PORTAUDIO 1)
1072         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1073         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.cpp Alc/backends/portaudio.h)
1074         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1075         SET(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1076     ENDIF()
1077 ENDIF()
1078 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1079     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1080 ENDIF()
1081
1082 # Check PulseAudio backend
1083 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1084 FIND_PACKAGE(PulseAudio)
1085 IF(PULSEAUDIO_FOUND)
1086     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1087     IF(ALSOFT_BACKEND_PULSEAUDIO)
1088         SET(HAVE_PULSEAUDIO 1)
1089         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1090         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.cpp Alc/backends/pulseaudio.h)
1091         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1092         SET(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIRS})
1093     ENDIF()
1094 ENDIF()
1095 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1096     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1097 ENDIF()
1098
1099 # Check JACK backend
1100 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1101 FIND_PACKAGE(JACK)
1102 IF(JACK_FOUND)
1103     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1104     IF(ALSOFT_BACKEND_JACK)
1105         SET(HAVE_JACK 1)
1106         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1107         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.cpp Alc/backends/jack.h)
1108         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1109         SET(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1110     ENDIF()
1111 ENDIF()
1112 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1113     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1114 ENDIF()
1115
1116 # Check CoreAudio backend
1117 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1118 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1119              NAMES CoreAudio
1120              PATHS /System/Library/Frameworks
1121 )
1122 IF(COREAUDIO_FRAMEWORK)
1123     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1124     IF(ALSOFT_BACKEND_COREAUDIO)
1125         SET(HAVE_COREAUDIO 1)
1126         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.cpp Alc/backends/coreaudio.h)
1127         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1128         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1129         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1130         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1131
1132         # Some versions of OSX may need the AudioToolbox framework. Add it if
1133         # it's found.
1134         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1135                      NAMES AudioToolbox
1136                      PATHS ~/Library/Frameworks
1137                            /Library/Frameworks
1138                            /System/Library/Frameworks
1139                     )
1140         IF(AUDIOTOOLBOX_LIBRARY)
1141             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1142         ENDIF()
1143     ENDIF()
1144 ENDIF()
1145 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1146     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1147 ENDIF()
1148
1149 # Check for OpenSL (Android) backend
1150 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1151 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1152 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1153     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1154     IF(HAVE_LIBOPENSLES)
1155         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1156         IF(ALSOFT_BACKEND_OPENSL)
1157             SET(HAVE_OPENSL 1)
1158             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.cpp Alc/backends/opensl.h)
1159             SET(BACKENDS  "${BACKENDS} OpenSL,")
1160             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1161         ENDIF()
1162     ENDIF()
1163 ENDIF()
1164 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1165     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1166 ENDIF()
1167
1168 # Check for SDL2 backend
1169 OPTION(ALSOFT_REQUIRE_SDL2 "Require SDL2 backend" OFF)
1170 FIND_PACKAGE(SDL2)
1171 IF(SDL2_FOUND)
1172     # Off by default, since it adds a runtime dependency
1173     OPTION(ALSOFT_BACKEND_SDL2 "Enable SDL2 backend" OFF)
1174     IF(ALSOFT_BACKEND_SDL2)
1175         SET(HAVE_SDL2 1)
1176         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sdl2.cpp Alc/backends/sdl2.h)
1177         SET(BACKENDS  "${BACKENDS} SDL2,")
1178         SET(EXTRA_LIBS ${SDL2_LIBRARY} ${EXTRA_LIBS})
1179         SET(INC_PATHS ${INC_PATHS} ${SDL2_INCLUDE_DIR})
1180     ENDIF()
1181 ENDIF()
1182 IF(ALSOFT_REQUIRE_SDL2 AND NOT SDL2_FOUND)
1183     MESSAGE(FATAL_ERROR "Failed to enabled required SDL2 backend")
1184 ENDIF()
1185
1186 # Optionally enable the Wave Writer backend
1187 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1188 IF(ALSOFT_BACKEND_WAVE)
1189     SET(HAVE_WAVE 1)
1190     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.cpp Alc/backends/wave.h)
1191     SET(BACKENDS  "${BACKENDS} WaveFile,")
1192 ENDIF()
1193
1194 # This is always available
1195 SET(BACKENDS  "${BACKENDS} Null")
1196
1197
1198 FIND_PACKAGE(Git)
1199 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1200     # Get the current working branch and its latest abbreviated commit hash
1201     ADD_CUSTOM_TARGET(build_version
1202         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1203                          -D LIB_VERSION=${LIB_VERSION}
1204                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1205                          -D DST=${OpenAL_BINARY_DIR}/version.h
1206                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1207         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1208         VERBATIM
1209     )
1210 ELSE()
1211     SET(GIT_BRANCH "UNKNOWN")
1212     SET(GIT_COMMIT_HASH "unknown")
1213     CONFIGURE_FILE(
1214         "${OpenAL_SOURCE_DIR}/version.h.in"
1215         "${OpenAL_BINARY_DIR}/version.h")
1216 ENDIF()
1217
1218
1219 SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools")
1220
1221 SET(ALSOFT_NATIVE_TOOLS_PATH "" CACHE STRING "Path to prebuilt native tools (leave blank to auto-build)")
1222 IF(ALSOFT_NATIVE_TOOLS_PATH)
1223     SET(BIN2H_COMMAND  "${ALSOFT_NATIVE_TOOLS_PATH}/bin2h")
1224     SET(BSINCGEN_COMMAND  "${ALSOFT_NATIVE_TOOLS_PATH}/bsincgen")
1225 ELSE()
1226     SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools")
1227     FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1228
1229     SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}/bin2h")
1230     SET(BSINCGEN_COMMAND  "${NATIVE_BIN_DIR}/bsincgen")
1231     ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1232         COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" "${NATIVE_SRC_DIR}"
1233         COMMAND ${CMAKE_COMMAND} -E remove "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1234         COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1235         WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1236         DEPENDS "${NATIVE_SRC_DIR}/CMakeLists.txt"
1237         IMPLICIT_DEPENDS C "${NATIVE_SRC_DIR}/bin2h.c"
1238                          C "${NATIVE_SRC_DIR}/bsincgen.c"
1239         VERBATIM
1240     )
1241 ENDIF()
1242 ADD_CUSTOM_TARGET(native-tools
1243     DEPENDS "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1244     VERBATIM
1245 )
1246
1247 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" ON)
1248 if(ALSOFT_EMBED_HRTF_DATA)
1249     MACRO(make_hrtf_header FILENAME VARNAME)
1250         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1251         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1252
1253         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1254             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1255             DEPENDS native-tools "${infile}"
1256             VERBATIM
1257         )
1258         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1259     ENDMACRO()
1260
1261     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1262     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1263 endif()
1264
1265 ADD_CUSTOM_COMMAND(OUTPUT "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1266     COMMAND "${BSINCGEN_COMMAND}" "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1267     DEPENDS native-tools "${NATIVE_SRC_DIR}/bsincgen.c"
1268     VERBATIM
1269 )
1270 SET(ALC_OBJS  ${ALC_OBJS} "${OpenAL_BINARY_DIR}/bsinc_inc.h")
1271
1272
1273 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1274     add_subdirectory(utils/alsoft-config)
1275 ENDIF()
1276 IF(ALSOFT_EXAMPLES)
1277     IF(NOT SDL2_FOUND)
1278         FIND_PACKAGE(SDL2)
1279     ENDIF()
1280     IF(SDL2_FOUND)
1281         FIND_PACKAGE(SDL_sound)
1282         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1283     ENDIF()
1284 ENDIF()
1285
1286 IF(NOT WIN32)
1287     SET(LIBNAME "openal")
1288 ELSE()
1289     SET(LIBNAME "OpenAL32")
1290 ENDIF()
1291
1292 # Needed for openal.pc.in
1293 SET(prefix ${CMAKE_INSTALL_PREFIX})
1294 SET(exec_prefix "\${prefix}")
1295 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1296 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1297 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1298 SET(PACKAGE_VERSION "${LIB_VERSION}")
1299 SET(PKG_CONFIG_CFLAGS )
1300 SET(PKG_CONFIG_PRIVATE_LIBS )
1301 IF(LIBTYPE STREQUAL "STATIC")
1302     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC)
1303     FOREACH(FLAG  ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1304         # If this is already a linker flag, or is a full path+file, add it
1305         # as-is. Otherwise, it's a name intended to be dressed as -lname.
1306         IF(FLAG MATCHES "^-.*" OR EXISTS "${FLAG}")
1307             SET(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} ${FLAG}")
1308         ELSE()
1309             SET(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} -l${FLAG}")
1310         ENDIF()
1311     ENDFOREACH()
1312 ENDIF()
1313
1314 # End configuration
1315 CONFIGURE_FILE(
1316     "${OpenAL_SOURCE_DIR}/config.h.in"
1317     "${OpenAL_BINARY_DIR}/config.h")
1318 CONFIGURE_FILE(
1319     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1320     "${OpenAL_BINARY_DIR}/openal.pc"
1321     @ONLY)
1322
1323
1324 # Add a static library with common functions used by multiple targets
1325 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
1326 TARGET_COMPILE_DEFINITIONS(common PRIVATE ${CPP_DEFS})
1327 TARGET_COMPILE_OPTIONS(common PRIVATE ${C_FLAGS})
1328
1329
1330 UNSET(HAS_ROUTER)
1331 SET(IMPL_TARGET OpenAL)
1332 SET(COMMON_LIB )
1333 SET(SUBSYS_FLAG )
1334
1335 # Build main library
1336 IF(LIBTYPE STREQUAL "STATIC")
1337     SET(CPP_DEFS ${CPP_DEFS} AL_LIBTYPE_STATIC)
1338     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1339         SET(CPP_DEFS ${CPP_DEFS} AL_NO_UID_DEFS)
1340     ENDIF()
1341     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1342 ELSE()
1343     # Make sure to compile the common code with PIC, since it'll be linked into
1344     # shared libs that needs it.
1345     SET_PROPERTY(TARGET common PROPERTY POSITION_INDEPENDENT_CODE TRUE)
1346     SET(COMMON_LIB common)
1347
1348     IF(WIN32)
1349         IF(MSVC)
1350             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "/SUBSYSTEM:WINDOWS")
1351         ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1352             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "-mwindows")
1353         ENDIF()
1354     ENDIF()
1355
1356     IF(WIN32 AND ALSOFT_BUILD_ROUTER)
1357         ADD_LIBRARY(OpenAL SHARED router/router.cpp router/router.h router/alc.cpp router/al.cpp)
1358         TARGET_COMPILE_DEFINITIONS(OpenAL
1359             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1360         TARGET_COMPILE_OPTIONS(OpenAL PRIVATE ${C_FLAGS})
1361         TARGET_LINK_LIBRARIES(OpenAL PRIVATE ${COMMON_LIB} ${LINKER_FLAGS})
1362         SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1363         SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1364         IF(TARGET build_version)
1365             ADD_DEPENDENCIES(OpenAL build_version)
1366         ENDIF()
1367         SET(HAS_ROUTER 1)
1368
1369         SET(LIBNAME "soft_oal")
1370         SET(IMPL_TARGET soft_oal)
1371     ENDIF()
1372
1373     ADD_LIBRARY(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
1374     IF(WIN32)
1375         SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES PREFIX "")
1376     ENDIF()
1377 ENDIF()
1378 SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1379     VERSION ${LIB_VERSION}
1380     SOVERSION ${LIB_MAJOR_VERSION}
1381 )
1382 TARGET_COMPILE_DEFINITIONS(${IMPL_TARGET}
1383     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1384 TARGET_INCLUDE_DIRECTORIES(${IMPL_TARGET}
1385     PRIVATE "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc" ${INC_PATHS})
1386 TARGET_COMPILE_OPTIONS(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1387 TARGET_LINK_LIBRARIES(${IMPL_TARGET}
1388     PRIVATE ${COMMON_LIB} ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1389 IF(TARGET build_version)
1390     ADD_DEPENDENCIES(${IMPL_TARGET} build_version)
1391 ENDIF()
1392
1393 IF(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1394     FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1395     FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1396     IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1397         MESSAGE(STATUS "")
1398         IF(NOT SED_EXECUTABLE)
1399             MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1400         ENDIF()
1401         IF(NOT DLLTOOL_EXECUTABLE)
1402             MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1403         ENDIF()
1404     ELSE()
1405         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS
1406                         " -Wl,--output-def,OpenAL32.def")
1407         ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1408             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1409             COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1410             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1411             VERBATIM
1412         )
1413     ENDIF()
1414 ENDIF()
1415
1416 IF(ALSOFT_INSTALL)
1417     INSTALL(TARGETS OpenAL EXPORT OpenAL
1418             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1419             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1420             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1421             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1422     )
1423     EXPORT(TARGETS OpenAL
1424            NAMESPACE OpenAL::
1425            FILE OpenALConfig.cmake)
1426     INSTALL(EXPORT OpenAL
1427             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1428             NAMESPACE OpenAL::
1429             FILE OpenALConfig.cmake)
1430     INSTALL(FILES include/AL/al.h
1431                   include/AL/alc.h
1432                   include/AL/alext.h
1433                   include/AL/efx.h
1434                   include/AL/efx-creative.h
1435                   include/AL/efx-presets.h
1436             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1437     )
1438     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1439             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1440     IF(TARGET soft_oal)
1441         INSTALL(TARGETS soft_oal
1442                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1443         )
1444     ENDIF()
1445 ENDIF()
1446
1447
1448 if(HAS_ROUTER)
1449     message(STATUS "")
1450     message(STATUS "Building DLL router")
1451 endif()
1452
1453 MESSAGE(STATUS "")
1454 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1455 MESSAGE(STATUS "    ${BACKENDS}")
1456 MESSAGE(STATUS "")
1457 MESSAGE(STATUS "Building with support for CPU extensions:")
1458 MESSAGE(STATUS "    ${CPU_EXTS}")
1459 MESSAGE(STATUS "")
1460 IF(FPMATH_SET)
1461     MESSAGE(STATUS "Building with SSE${FPMATH_SET} codegen")
1462     MESSAGE(STATUS "")
1463 ENDIF()
1464
1465 IF(WIN32)
1466     IF(NOT HAVE_DSOUND)
1467         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1468         MESSAGE(STATUS "         This is probably NOT what you want!")
1469         MESSAGE(STATUS "")
1470     ENDIF()
1471 ENDIF()
1472
1473 if(ALSOFT_EMBED_HRTF_DATA)
1474     message(STATUS "Embedding HRTF datasets")
1475     message(STATUS "")
1476 endif()
1477
1478 # Install alsoft.conf configuration file
1479 IF(ALSOFT_CONFIG)
1480     INSTALL(FILES alsoftrc.sample
1481             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1482     )
1483     MESSAGE(STATUS "Installing sample configuration")
1484     MESSAGE(STATUS "")
1485 ENDIF()
1486
1487 # Install HRTF definitions
1488 IF(ALSOFT_HRTF_DEFS)
1489     INSTALL(FILES hrtf/default-44100.mhr
1490                   hrtf/default-48000.mhr
1491             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1492     )
1493     MESSAGE(STATUS "Installing HRTF definitions")
1494     MESSAGE(STATUS "")
1495 ENDIF()
1496
1497 # Install AmbDec presets
1498 IF(ALSOFT_AMBDEC_PRESETS)
1499     INSTALL(FILES presets/3D7.1.ambdec
1500                   presets/hexagon.ambdec
1501                   presets/itu5.1.ambdec
1502                   presets/itu5.1-nocenter.ambdec
1503                   presets/rectangle.ambdec
1504                   presets/square.ambdec
1505                   presets/presets.txt
1506             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1507     )
1508     MESSAGE(STATUS "Installing AmbDec presets")
1509     MESSAGE(STATUS "")
1510 ENDIF()
1511
1512 IF(ALSOFT_UTILS)
1513     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1514     TARGET_COMPILE_OPTIONS(openal-info PRIVATE ${C_FLAGS})
1515     TARGET_LINK_LIBRARIES(openal-info PRIVATE ${LINKER_FLAGS} OpenAL)
1516
1517     SET(MAKEHRTF_SRCS  utils/makehrtf.c)
1518     IF(NOT HAVE_GETOPT)
1519         SET(MAKEHRTF_SRCS  ${MAKEHRTF_SRCS} utils/getopt.c utils/getopt.h)
1520     ENDIF()
1521     ADD_EXECUTABLE(makehrtf ${MAKEHRTF_SRCS})
1522     TARGET_COMPILE_DEFINITIONS(makehrtf PRIVATE ${CPP_DEFS})
1523     TARGET_COMPILE_OPTIONS(makehrtf PRIVATE ${C_FLAGS})
1524     IF(HAVE_LIBM)
1525         TARGET_LINK_LIBRARIES(makehrtf PRIVATE ${LINKER_FLAGS} m)
1526     ENDIF()
1527
1528     IF(ALSOFT_INSTALL)
1529         INSTALL(TARGETS openal-info makehrtf
1530                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1531                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1532                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1533         )
1534     ENDIF()
1535
1536     MESSAGE(STATUS "Building utility programs")
1537     IF(TARGET alsoft-config)
1538         MESSAGE(STATUS "Building configuration program")
1539     ENDIF()
1540     MESSAGE(STATUS "")
1541 ENDIF()
1542
1543 IF(ALSOFT_TESTS)
1544     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1545
1546     ADD_EXECUTABLE(altonegen examples/altonegen.c ${TEST_COMMON_OBJS})
1547     TARGET_COMPILE_DEFINITIONS(altonegen PRIVATE ${CPP_DEFS})
1548     TARGET_COMPILE_OPTIONS(altonegen PRIVATE ${C_FLAGS})
1549     TARGET_LINK_LIBRARIES(altonegen PRIVATE ${LINKER_FLAGS} common OpenAL ${MATH_LIB})
1550
1551     IF(ALSOFT_INSTALL)
1552         INSTALL(TARGETS altonegen
1553                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1554                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1555                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1556         )
1557     ENDIF()
1558
1559     MESSAGE(STATUS "Building test programs")
1560     MESSAGE(STATUS "")
1561 ENDIF()
1562
1563 IF(ALSOFT_EXAMPLES)
1564     # Add a static library with common functions used by multiple targets
1565     ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c)
1566     TARGET_COMPILE_DEFINITIONS(ex-common PRIVATE ${CPP_DEFS})
1567     TARGET_COMPILE_OPTIONS(ex-common PRIVATE ${C_FLAGS})
1568
1569     ADD_EXECUTABLE(alrecord examples/alrecord.c)
1570     TARGET_COMPILE_DEFINITIONS(alrecord PRIVATE ${CPP_DEFS})
1571     TARGET_COMPILE_OPTIONS(alrecord PRIVATE ${C_FLAGS})
1572     TARGET_LINK_LIBRARIES(alrecord PRIVATE ${LINKER_FLAGS} ex-common common OpenAL)
1573
1574     IF(ALSOFT_INSTALL)
1575         INSTALL(TARGETS alrecord
1576                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1577                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1578                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1579         )
1580     ENDIF()
1581
1582     MESSAGE(STATUS "Building example programs")
1583
1584     IF(SDL2_FOUND)
1585         IF(SDL_SOUND_FOUND)
1586             ADD_EXECUTABLE(alplay examples/alplay.c)
1587             TARGET_COMPILE_DEFINITIONS(alplay PRIVATE ${CPP_DEFS})
1588             TARGET_INCLUDE_DIRECTORIES(alplay
1589                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1590             TARGET_COMPILE_OPTIONS(alplay PRIVATE ${C_FLAGS})
1591             TARGET_LINK_LIBRARIES(alplay
1592                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1593                         OpenAL)
1594
1595             ADD_EXECUTABLE(alstream examples/alstream.c)
1596             TARGET_COMPILE_DEFINITIONS(alstream PRIVATE ${CPP_DEFS})
1597             TARGET_INCLUDE_DIRECTORIES(alstream
1598                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1599             TARGET_COMPILE_OPTIONS(alstream PRIVATE ${C_FLAGS})
1600             TARGET_LINK_LIBRARIES(alstream
1601                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1602                         OpenAL)
1603
1604             ADD_EXECUTABLE(alreverb examples/alreverb.c)
1605             TARGET_COMPILE_DEFINITIONS(alreverb PRIVATE ${CPP_DEFS})
1606             TARGET_INCLUDE_DIRECTORIES(alreverb
1607                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1608             TARGET_COMPILE_OPTIONS(alreverb PRIVATE ${C_FLAGS})
1609             TARGET_LINK_LIBRARIES(alreverb
1610                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1611                         OpenAL)
1612
1613             ADD_EXECUTABLE(almultireverb examples/almultireverb.c)
1614             TARGET_COMPILE_DEFINITIONS(almultireverb PRIVATE ${CPP_DEFS})
1615             TARGET_INCLUDE_DIRECTORIES(almultireverb
1616                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1617             TARGET_COMPILE_OPTIONS(almultireverb PRIVATE ${C_FLAGS})
1618             TARGET_LINK_LIBRARIES(almultireverb
1619                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1620                         OpenAL ${MATH_LIB})
1621
1622             ADD_EXECUTABLE(allatency examples/allatency.c)
1623             TARGET_COMPILE_DEFINITIONS(allatency PRIVATE ${CPP_DEFS})
1624             TARGET_INCLUDE_DIRECTORIES(allatency
1625                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1626             TARGET_COMPILE_OPTIONS(allatency PRIVATE ${C_FLAGS})
1627             TARGET_LINK_LIBRARIES(allatency
1628                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1629                         OpenAL)
1630
1631             ADD_EXECUTABLE(alloopback examples/alloopback.c)
1632             TARGET_COMPILE_DEFINITIONS(alloopback PRIVATE ${CPP_DEFS})
1633             TARGET_INCLUDE_DIRECTORIES(alloopback
1634                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1635             TARGET_COMPILE_OPTIONS(alloopback PRIVATE ${C_FLAGS})
1636             TARGET_LINK_LIBRARIES(alloopback
1637                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1638                         OpenAL ${MATH_LIB})
1639
1640             ADD_EXECUTABLE(alhrtf examples/alhrtf.c)
1641             TARGET_COMPILE_DEFINITIONS(alhrtf PRIVATE ${CPP_DEFS})
1642             TARGET_INCLUDE_DIRECTORIES(alhrtf
1643                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1644             TARGET_COMPILE_OPTIONS(alhrtf PRIVATE ${C_FLAGS})
1645             TARGET_LINK_LIBRARIES(alhrtf
1646                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1647                         OpenAL ${MATH_LIB})
1648
1649             IF(ALSOFT_INSTALL)
1650                 INSTALL(TARGETS alplay alstream alreverb almultireverb allatency alloopback alhrtf
1651                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1652                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1653                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1654                 )
1655             ENDIF()
1656
1657             MESSAGE(STATUS "Building SDL_sound example programs")
1658         ENDIF()
1659
1660         SET(FFVER_OK FALSE)
1661         IF(FFMPEG_FOUND)
1662             SET(FFVER_OK TRUE)
1663             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1664                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1665                 SET(FFVER_OK FALSE)
1666             ENDIF()
1667             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1668                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1669                 SET(FFVER_OK FALSE)
1670             ENDIF()
1671             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1672                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1673                 SET(FFVER_OK FALSE)
1674             ENDIF()
1675             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1676                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1677                 SET(FFVER_OK FALSE)
1678             ENDIF()
1679             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1680                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1681                 SET(FFVER_OK FALSE)
1682             ENDIF()
1683         ENDIF()
1684         IF(FFVER_OK)
1685             ADD_EXECUTABLE(alffplay examples/alffplay.cpp)
1686             TARGET_COMPILE_DEFINITIONS(alffplay PRIVATE ${CPP_DEFS})
1687             TARGET_INCLUDE_DIRECTORIES(alffplay
1688                 PRIVATE ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS})
1689             TARGET_COMPILE_OPTIONS(alffplay PRIVATE ${C_FLAGS})
1690             TARGET_LINK_LIBRARIES(alffplay
1691                 PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} ex-common common
1692                         OpenAL)
1693
1694             IF(ALSOFT_INSTALL)
1695                 INSTALL(TARGETS alffplay
1696                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1697                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1698                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1699                 )
1700             ENDIF()
1701             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1702         ENDIF()
1703         MESSAGE(STATUS "")
1704     ENDIF()
1705 ENDIF()