gcc/ada/exp_prag.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ P R A G                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Casing;   use Casing;
  28 with Debug;    use Debug;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Exp_Ch11; use Exp_Ch11;
  32 with Exp_Util; use Exp_Util;
  33 with Expander; use Expander;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Opt;      use Opt;
  38 with Restrict; use Restrict;
  39 with Rident;   use Rident;
  40 with Rtsfind;  use Rtsfind;
  41 with Sem;      use Sem;
  42 with Sem_Res;  use Sem_Res;
  43 with Sem_Util; use Sem_Util;
  44 with Sinfo;    use Sinfo;
  45 with Sinput;   use Sinput;
  46 with Snames;   use Snames;
  47 with Stringt;  use Stringt;
  48 with Stand;    use Stand;
  49 with Targparm; use Targparm;
  50 with Tbuild;   use Tbuild;
  51 with Uintp;    use Uintp;
  52
  53 package body Exp_Prag is
  54
  55    -----------------------
  56    -- Local Subprograms --
  57    -----------------------
  58
  59    function Arg1 (N : Node_Id) return Node_Id;
  60    function Arg2 (N : Node_Id) return Node_Id;
  61    function Arg3 (N : Node_Id) return Node_Id;
  62    --  Obtain specified pragma argument expression
  63
  64    procedure Expand_Pragma_Abort_Defer             (N : Node_Id);
  65    procedure Expand_Pragma_Check                   (N : Node_Id);
  66    procedure Expand_Pragma_Common_Object           (N : Node_Id);
  67    procedure Expand_Pragma_Import_Or_Interface     (N : Node_Id);
  68    procedure Expand_Pragma_Import_Export_Exception (N : Node_Id);
  69    procedure Expand_Pragma_Inspection_Point        (N : Node_Id);
  70    procedure Expand_Pragma_Interrupt_Priority      (N : Node_Id);
  71    procedure Expand_Pragma_Psect_Object            (N : Node_Id);
  72    procedure Expand_Pragma_Relative_Deadline       (N : Node_Id);
  73
  74    ----------
  75    -- Arg1 --
  76    ----------
  77
  78    function Arg1 (N : Node_Id) return Node_Id is
  79       Arg : constant Node_Id := First (Pragma_Argument_Associations (N));
  80    begin
  81       if Present (Arg)
  82         and then Nkind (Arg) = N_Pragma_Argument_Association
  83       then
  84          return Expression (Arg);
  85       else
  86          return Arg;
  87       end if;
  88    end Arg1;
  89
  90    ----------
  91    -- Arg2 --
  92    ----------
  93
  94    function Arg2 (N : Node_Id) return Node_Id is
  95       Arg1 : constant Node_Id := First (Pragma_Argument_Associations (N));
  96
  97    begin
  98       if No (Arg1) then
  99          return Empty;
 100
 101       else
 102          declare
 103             Arg : constant Node_Id := Next (Arg1);
 104          begin
 105             if Present (Arg)
 106               and then Nkind (Arg) = N_Pragma_Argument_Association
 107             then
 108                return Expression (Arg);
 109             else
 110                return Arg;
 111             end if;
 112          end;
 113       end if;
 114    end Arg2;
 115
 116    ----------
 117    -- Arg3 --
 118    ----------
 119
 120    function Arg3 (N : Node_Id) return Node_Id is
 121       Arg1 : constant Node_Id := First (Pragma_Argument_Associations (N));
 122
 123    begin
 124       if No (Arg1) then
 125          return Empty;
 126
 127       else
 128          declare
 129             Arg : Node_Id := Next (Arg1);
 130          begin
 131             if No (Arg) then
 132                return Empty;
 133
 134             else
 135                Next (Arg);
 136
 137                if Present (Arg)
 138                  and then Nkind (Arg) = N_Pragma_Argument_Association
 139                then
 140                   return Expression (Arg);
 141                else
 142                   return Arg;
 143                end if;
 144             end if;
 145          end;
 146       end if;
 147    end Arg3;
 148
 149    ---------------------
 150    -- Expand_N_Pragma --
 151    ---------------------
 152
 153    procedure Expand_N_Pragma (N : Node_Id) is
 154       Pname : constant Name_Id := Pragma_Name (N);
 155
 156    begin
 157       --  Note: we may have a pragma whose Pragma_Identifier field is not a
 158       --  recognized pragma, and we must ignore it at this stage.
 159
 160       if Is_Pragma_Name (Pname) then
 161          case Get_Pragma_Id (Pname) is
 162
 163             --  Pragmas requiring special expander action
 164
 165             when Pragma_Abort_Defer =>
 166                Expand_Pragma_Abort_Defer (N);
 167
 168             when Pragma_Check =>
 169                Expand_Pragma_Check (N);
 170
 171             when Pragma_Common_Object =>
 172                Expand_Pragma_Common_Object (N);
 173
 174             when Pragma_Export_Exception =>
 175                Expand_Pragma_Import_Export_Exception (N);
 176
 177             when Pragma_Import =>
 178                Expand_Pragma_Import_Or_Interface (N);
 179
 180             when Pragma_Import_Exception =>
 181                Expand_Pragma_Import_Export_Exception (N);
 182
 183             when Pragma_Inspection_Point =>
 184                Expand_Pragma_Inspection_Point (N);
 185
 186             when Pragma_Interface =>
 187                Expand_Pragma_Import_Or_Interface (N);
 188
 189             when Pragma_Interrupt_Priority =>
 190                Expand_Pragma_Interrupt_Priority (N);
 191
 192             when Pragma_Psect_Object =>
 193                Expand_Pragma_Psect_Object (N);
 194
 195             when Pragma_Relative_Deadline =>
 196                Expand_Pragma_Relative_Deadline (N);
 197
 198             --  All other pragmas need no expander action
 199
 200             when others => null;
 201          end case;
 202       end if;
 203
 204    end Expand_N_Pragma;
 205
 206    -------------------------------
 207    -- Expand_Pragma_Abort_Defer --
 208    -------------------------------
 209
 210    --  An Abort_Defer pragma appears as the first statement in a handled
 211    --  statement sequence (right after the begin). It defers aborts for
 212    --  the entire statement sequence, but not for any declarations or
 213    --  handlers (if any) associated with this statement sequence.
 214
 215    --  The transformation is to transform
 216
 217    --    pragma Abort_Defer;
 218    --    statements;
 219
 220    --  into
 221
 222    --    begin
 223    --       Abort_Defer.all;
 224    --       statements
 225    --    exception
 226    --       when all others =>
 227    --          Abort_Undefer.all;
 228    --          raise;
 229    --    at end
 230    --       Abort_Undefer_Direct;
 231    --    end;
 232
 233    procedure Expand_Pragma_Abort_Defer (N : Node_Id) is
 234       Loc  : constant Source_Ptr := Sloc (N);
 235       Stm  : Node_Id;
 236       Stms : List_Id;
 237       HSS  : Node_Id;
 238       Blk  : constant Entity_Id :=
 239         New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 240
 241    begin
 242       Stms := New_List (Build_Runtime_Call (Loc, RE_Abort_Defer));
 243
 244       loop
 245          Stm := Remove_Next (N);
 246          exit when No (Stm);
 247          Append (Stm, Stms);
 248       end loop;
 249
 250       HSS :=
 251         Make_Handled_Sequence_Of_Statements (Loc,
 252           Statements => Stms,
 253           At_End_Proc =>
 254             New_Occurrence_Of (RTE (RE_Abort_Undefer_Direct), Loc));
 255
 256       Rewrite (N,
 257         Make_Block_Statement (Loc,
 258           Handled_Statement_Sequence => HSS));
 259
 260       Set_Scope (Blk, Current_Scope);
 261       Set_Etype (Blk, Standard_Void_Type);
 262       Set_Identifier (N, New_Occurrence_Of (Blk, Sloc (N)));
 263       Expand_At_End_Handler (HSS, Blk);
 264       Analyze (N);
 265    end Expand_Pragma_Abort_Defer;
 266
 267    --------------------------
 268    -- Expand_Pragma_Check --
 269    --------------------------
 270
 271    procedure Expand_Pragma_Check (N : Node_Id) is
 272       Cond : constant Node_Id    := Arg2 (N);
 273       Loc  : constant Source_Ptr := Sloc (Cond);
 274       Nam  : constant Name_Id    := Chars (Arg1 (N));
 275       Msg  : Node_Id;
 276
 277    begin
 278       --  We already know that this check is enabled, because otherwise the
 279       --  semantic pass dealt with rewriting the assertion (see Sem_Prag)
 280
 281       --  Since this check is enabled, we rewrite the pragma into a
 282       --  corresponding if statement, and then analyze the statement
 283
 284       --  The normal case expansion transforms:
 285
 286       --    pragma Check (name, condition [,message]);
 287
 288       --  into
 289
 290       --    if not condition then
 291       --       System.Assertions.Raise_Assert_Failure (Str);
 292       --    end if;
 293
 294       --  where Str is the message if one is present, or the default of
 295       --  name failed at file:line if no message is given (the "name failed
 296       --  at" is omitted for name = Assertion, since it is redundant, given
 297       --  that the name of the exception is Assert_Failure.
 298
 299       --  An alternative expansion is used when the No_Exception_Propagation
 300       --  restriction is active and there is a local Assert_Failure handler.
 301       --  This is not a common combination of circumstances, but it occurs in
 302       --  the context of Aunit and the zero footprint profile. In this case we
 303       --  generate:
 304
 305       --    if not condition then
 306       --       raise Assert_Failure;
 307       --    end if;
 308
 309       --  This will then be transformed into a goto, and the local handler will
 310       --  be able to handle the assert error (which would not be the case if a
 311       --  call is made to the Raise_Assert_Failure procedure).
 312
 313       --  Note that the reason we do not always generate a direct raise is that
 314       --  the form in which the procedure is called allows for more efficient
 315       --  breakpointing of assertion errors.
 316
 317       --  Generate the appropriate if statement. Note that we consider this to
 318       --  be an explicit conditional in the source, not an implicit if, so we
 319       --  do not call Make_Implicit_If_Statement.
 320
 321       --  Case where we generate a direct raise
 322
 323       if (Debug_Flag_Dot_G
 324            or else Restriction_Active (No_Exception_Propagation))
 325         and then Present (Find_Local_Handler (RTE (RE_Assert_Failure), N))
 326       then
 327          Rewrite (N,
 328            Make_If_Statement (Loc,
 329              Condition =>
 330                Make_Op_Not (Loc,
 331                  Right_Opnd => Cond),
 332              Then_Statements => New_List (
 333                Make_Raise_Statement (Loc,
 334                  Name =>
 335                    New_Reference_To (RTE (RE_Assert_Failure), Loc)))));
 336
 337       --  Case where we call the procedure
 338
 339       else
 340          --  First, we need to prepare the string argument
 341
 342          --  If we have a message given, use it
 343
 344          if Present (Arg3 (N)) then
 345             Msg := Arg3 (N);
 346
 347          --  Otherwise string is "name failed at location" except in the case
 348          --  of Assertion where "name failed at" is omitted.
 349
 350          else
 351             if Nam = Name_Assertion then
 352                Name_Len := 0;
 353             else
 354                Get_Name_String (Nam);
 355                Set_Casing (Identifier_Casing (Current_Source_File));
 356                Add_Str_To_Name_Buffer (" failed at ");
 357             end if;
 358
 359             Build_Location_String (Loc);
 360             Msg :=
 361               Make_String_Literal (Loc,
 362                 Strval => String_From_Name_Buffer);
 363          end if;
 364
 365          --  Now rewrite as an if statement
 366
 367          Rewrite (N,
 368            Make_If_Statement (Loc,
 369              Condition =>
 370                Make_Op_Not (Loc,
 371                  Right_Opnd => Cond),
 372              Then_Statements => New_List (
 373                Make_Procedure_Call_Statement (Loc,
 374                  Name =>
 375                    New_Reference_To (RTE (RE_Raise_Assert_Failure), Loc),
 376                  Parameter_Associations => New_List (Msg)))));
 377       end if;
 378
 379       Analyze (N);
 380
 381       --  If new condition is always false, give a warning
 382
 383       if Warn_On_Assertion_Failure
 384         and then Nkind (N) = N_Procedure_Call_Statement
 385         and then Is_RTE (Entity (Name (N)), RE_Raise_Assert_Failure)
 386       then
 387          --  If original condition was a Standard.False, we assume that this is
 388          --  indeed intended to raise assert error and no warning is required.
 389
 390          if Is_Entity_Name (Original_Node (Cond))
 391            and then Entity (Original_Node (Cond)) = Standard_False
 392          then
 393             return;
 394          elsif Nam = Name_Assertion then
 395             Error_Msg_N ("?assertion will fail at run-time", N);
 396          else
 397             Error_Msg_N ("?check will fail at run time", N);
 398          end if;
 399       end if;
 400    end Expand_Pragma_Check;
 401
 402    ---------------------------------
 403    -- Expand_Pragma_Common_Object --
 404    ---------------------------------
 405
 406    --  Use a machine attribute to replicate semantic effect in DEC Ada
 407
 408    --    pragma Machine_Attribute (intern_name, "common_object", extern_name);
 409
 410    --  For now we do nothing with the size attribute ???
 411
 412    --  Note: Psect_Object shares this processing
 413
 414    procedure Expand_Pragma_Common_Object (N : Node_Id) is
 415       Loc : constant Source_Ptr := Sloc (N);
 416
 417       Internal : constant Node_Id := Arg1 (N);
 418       External : constant Node_Id := Arg2 (N);
 419
 420       Psect : Node_Id;
 421       --  Psect value upper cased as string literal
 422
 423       Iloc : constant Source_Ptr := Sloc (Internal);
 424       Eloc : constant Source_Ptr := Sloc (External);
 425       Ploc : Source_Ptr;
 426
 427    begin
 428       --  Acquire Psect value and fold to upper case
 429
 430       if Present (External) then
 431          if Nkind (External) = N_String_Literal then
 432             String_To_Name_Buffer (Strval (External));
 433          else
 434             Get_Name_String (Chars (External));
 435          end if;
 436
 437          Set_All_Upper_Case;
 438
 439          Psect :=
 440            Make_String_Literal (Eloc,
 441              Strval => String_From_Name_Buffer);
 442
 443       else
 444          Get_Name_String (Chars (Internal));
 445          Set_All_Upper_Case;
 446          Psect :=
 447            Make_String_Literal (Iloc,
 448              Strval => String_From_Name_Buffer);
 449       end if;
 450
 451       Ploc := Sloc (Psect);
 452
 453       --  Insert the pragma
 454
 455       Insert_After_And_Analyze (N,
 456          Make_Pragma (Loc,
 457            Chars => Name_Machine_Attribute,
 458            Pragma_Argument_Associations => New_List (
 459              Make_Pragma_Argument_Association (Iloc,
 460                Expression => New_Copy_Tree (Internal)),
 461              Make_Pragma_Argument_Association (Eloc,
 462                Expression =>
 463                  Make_String_Literal (Sloc => Ploc,
 464                    Strval => "common_object")),
 465              Make_Pragma_Argument_Association (Ploc,
 466                Expression => New_Copy_Tree (Psect)))));
 467
 468    end Expand_Pragma_Common_Object;
 469
 470    ---------------------------------------
 471    -- Expand_Pragma_Import_Or_Interface --
 472    ---------------------------------------
 473
 474    --  When applied to a variable, the default initialization must not be
 475    --  done. As it is already done when the pragma is found, we just get rid
 476    --  of the call the initialization procedure which followed the object
 477    --  declaration. The call is inserted after the declaration, but validity
 478    --  checks may also have been inserted and the initialization call does
 479    --  not necessarily appear immediately after the object declaration.
 480
 481    --  We can't use the freezing mechanism for this purpose, since we
 482    --  have to elaborate the initialization expression when it is first
 483    --  seen (i.e. this elaboration cannot be deferred to the freeze point).
 484
 485    procedure Expand_Pragma_Import_Or_Interface (N : Node_Id) is
 486       Def_Id    : constant Entity_Id := Entity (Arg2 (N));
 487       Init_Call : Node_Id;
 488
 489    begin
 490       if Ekind (Def_Id) = E_Variable then
 491
 492          --  Find generated initialization call for object, if any
 493
 494          Init_Call := Find_Init_Call (Def_Id, Rep_Clause => N);
 495          if Present (Init_Call) then
 496             Remove (Init_Call);
 497          end if;
 498
 499          --  Any default initialization expression should be removed
 500          --  (e.g., null defaults for access objects, zero initialization
 501          --  of packed bit arrays). Imported objects aren't allowed to
 502          --  have explicit initialization, so the expression must have
 503          --  been generated by the compiler.
 504
 505          if No (Init_Call) and then Present (Expression (Parent (Def_Id))) then
 506             Set_Expression (Parent (Def_Id), Empty);
 507          end if;
 508       end if;
 509    end Expand_Pragma_Import_Or_Interface;
 510
 511    -------------------------------------------
 512    -- Expand_Pragma_Import_Export_Exception --
 513    -------------------------------------------
 514
 515    --  For a VMS exception fix up the language field with "VMS"
 516    --  instead of "Ada" (gigi needs this), create a constant that will be the
 517    --  value of the VMS condition code and stuff the Interface_Name field
 518    --  with the unexpanded name of the exception (if not already set).
 519    --  For a Ada exception, just stuff the Interface_Name field
 520    --  with the unexpanded name of the exception (if not already set).
 521
 522    procedure Expand_Pragma_Import_Export_Exception (N : Node_Id) is
 523    begin
 524       --  This pragma is only effective on OpenVMS systems, it was ignored
 525       --  on non-VMS systems, and we need to ignore it here as well.
 526
 527       if not OpenVMS_On_Target then
 528          return;
 529       end if;
 530
 531       declare
 532          Id     : constant Entity_Id := Entity (Arg1 (N));
 533          Call   : constant Node_Id := Register_Exception_Call (Id);
 534          Loc    : constant Source_Ptr := Sloc (N);
 535
 536       begin
 537          if Present (Call) then
 538             declare
 539                Excep_Internal : constant Node_Id := Make_Temporary (Loc, 'V');
 540                Export_Pragma  : Node_Id;
 541                Excep_Alias    : Node_Id;
 542                Excep_Object   : Node_Id;
 543                Excep_Image    : String_Id;
 544                Exdata         : List_Id;
 545                Lang_Char      : Node_Id;
 546                Code           : Node_Id;
 547
 548             begin
 549                if Present (Interface_Name (Id)) then
 550                   Excep_Image := Strval (Interface_Name (Id));
 551                else
 552                   Get_Name_String (Chars (Id));
 553                   Set_All_Upper_Case;
 554                   Excep_Image := String_From_Name_Buffer;
 555                end if;
 556
 557                Exdata := Component_Associations (Expression (Parent (Id)));
 558
 559                if Is_VMS_Exception (Id) then
 560                   Lang_Char := Next (First (Exdata));
 561
 562                   --  Change the one-character language designator to 'V'
 563
 564                   Rewrite (Expression (Lang_Char),
 565                     Make_Character_Literal (Loc,
 566                       Chars => Name_uV,
 567                       Char_Literal_Value =>
 568                         UI_From_Int (Character'Pos ('V'))));
 569                   Analyze (Expression (Lang_Char));
 570
 571                   if Exception_Code (Id) /= No_Uint then
 572                      Code :=
 573                        Make_Integer_Literal (Loc,
 574                          Intval => Exception_Code (Id));
 575
 576                      Excep_Object :=
 577                        Make_Object_Declaration (Loc,
 578                          Defining_Identifier => Excep_Internal,
 579                          Object_Definition   =>
 580                            New_Reference_To (RTE (RE_Exception_Code), Loc));
 581
 582                      Insert_Action (N, Excep_Object);
 583                      Analyze (Excep_Object);
 584
 585                      Start_String;
 586                      Store_String_Int
 587                        (UI_To_Int (Exception_Code (Id)) / 8 * 8);
 588
 589                      Excep_Alias :=
 590                        Make_Pragma
 591                          (Loc,
 592                           Name_Linker_Alias,
 593                           New_List
 594                             (Make_Pragma_Argument_Association
 595                                (Sloc => Loc,
 596                                 Expression =>
 597                                   New_Reference_To (Excep_Internal, Loc)),
 598
 599                              Make_Pragma_Argument_Association
 600                                (Sloc => Loc,
 601                                 Expression =>
 602                                   Make_String_Literal
 603                                     (Sloc => Loc,
 604                                      Strval => End_String))));
 605
 606                      Insert_Action (N, Excep_Alias);
 607                      Analyze (Excep_Alias);
 608
 609                      Export_Pragma :=
 610                        Make_Pragma
 611                          (Loc,
 612                           Name_Export,
 613                           New_List
 614                             (Make_Pragma_Argument_Association
 615                                (Sloc => Loc,
 616                                 Expression => Make_Identifier (Loc, Name_C)),
 617
 618                              Make_Pragma_Argument_Association
 619                                (Sloc => Loc,
 620                                 Expression =>
 621                                   New_Reference_To (Excep_Internal, Loc)),
 622
 623                              Make_Pragma_Argument_Association
 624                                (Sloc => Loc,
 625                                 Expression =>
 626                                   Make_String_Literal
 627                                     (Sloc => Loc,
 628                                      Strval => Excep_Image)),
 629
 630                              Make_Pragma_Argument_Association
 631                                (Sloc => Loc,
 632                                 Expression =>
 633                                   Make_String_Literal
 634                                     (Sloc => Loc,
 635                                      Strval => Excep_Image))));
 636
 637                      Insert_Action (N, Export_Pragma);
 638                      Analyze (Export_Pragma);
 639
 640                   else
 641                      Code :=
 642                         Unchecked_Convert_To (RTE (RE_Exception_Code),
 643                           Make_Function_Call (Loc,
 644                             Name =>
 645                               New_Reference_To (RTE (RE_Import_Value), Loc),
 646                             Parameter_Associations => New_List
 647                               (Make_String_Literal (Loc,
 648                                 Strval => Excep_Image))));
 649                   end if;
 650
 651                   Rewrite (Call,
 652                     Make_Procedure_Call_Statement (Loc,
 653                       Name => New_Reference_To
 654                                 (RTE (RE_Register_VMS_Exception), Loc),
 655                       Parameter_Associations => New_List (
 656                         Code,
 657                         Unchecked_Convert_To (RTE (RE_Exception_Data_Ptr),
 658                           Make_Attribute_Reference (Loc,
 659                             Prefix         => New_Occurrence_Of (Id, Loc),
 660                             Attribute_Name => Name_Unrestricted_Access)))));
 661
 662                   Analyze_And_Resolve (Code, RTE (RE_Exception_Code));
 663                   Analyze (Call);
 664                end if;
 665
 666                if No (Interface_Name (Id)) then
 667                   Set_Interface_Name (Id,
 668                      Make_String_Literal
 669                        (Sloc => Loc,
 670                         Strval => Excep_Image));
 671                end if;
 672             end;
 673          end if;
 674       end;
 675    end Expand_Pragma_Import_Export_Exception;
 676
 677    ------------------------------------
 678    -- Expand_Pragma_Inspection_Point --
 679    ------------------------------------
 680
 681    --  If no argument is given, then we supply a default argument list that
 682    --  includes all objects declared at the source level in all subprograms
 683    --  that enclose the inspection point pragma.
 684
 685    procedure Expand_Pragma_Inspection_Point (N : Node_Id) is
 686       Loc : constant Source_Ptr := Sloc (N);
 687       A     : List_Id;
 688       Assoc : Node_Id;
 689       S     : Entity_Id;
 690       E     : Entity_Id;
 691
 692    begin
 693       if No (Pragma_Argument_Associations (N)) then
 694          A := New_List;
 695          S := Current_Scope;
 696
 697          while S /= Standard_Standard loop
 698             E := First_Entity (S);
 699             while Present (E) loop
 700                if Comes_From_Source (E)
 701                  and then Is_Object (E)
 702                  and then not Is_Entry_Formal (E)
 703                  and then Ekind (E) /= E_Component
 704                  and then Ekind (E) /= E_Discriminant
 705                  and then Ekind (E) /= E_Generic_In_Parameter
 706                  and then Ekind (E) /= E_Generic_In_Out_Parameter
 707                then
 708                   Append_To (A,
 709                     Make_Pragma_Argument_Association (Loc,
 710                       Expression => New_Occurrence_Of (E, Loc)));
 711                end if;
 712
 713                Next_Entity (E);
 714             end loop;
 715
 716             S := Scope (S);
 717          end loop;
 718
 719          Set_Pragma_Argument_Associations (N, A);
 720       end if;
 721
 722       --  Expand the arguments of the pragma. Expanding an entity reference
 723       --  is a noop, except in a protected operation, where a reference may
 724       --  have to be transformed into a reference to the corresponding prival.
 725       --  Are there other pragmas that may require this ???
 726
 727       Assoc := First (Pragma_Argument_Associations (N));
 728
 729       while Present (Assoc) loop
 730          Expand (Expression (Assoc));
 731          Next (Assoc);
 732       end loop;
 733    end Expand_Pragma_Inspection_Point;
 734
 735    --------------------------------------
 736    -- Expand_Pragma_Interrupt_Priority --
 737    --------------------------------------
 738
 739    --  Supply default argument if none exists (System.Interrupt_Priority'Last)
 740
 741    procedure Expand_Pragma_Interrupt_Priority (N : Node_Id) is
 742       Loc : constant Source_Ptr := Sloc (N);
 743
 744    begin
 745       if No (Pragma_Argument_Associations (N)) then
 746          Set_Pragma_Argument_Associations (N, New_List (
 747            Make_Pragma_Argument_Association (Loc,
 748              Expression =>
 749                Make_Attribute_Reference (Loc,
 750                  Prefix =>
 751                    New_Occurrence_Of (RTE (RE_Interrupt_Priority), Loc),
 752                  Attribute_Name => Name_Last))));
 753       end if;
 754    end Expand_Pragma_Interrupt_Priority;
 755
 756    --------------------------------
 757    -- Expand_Pragma_Psect_Object --
 758    --------------------------------
 759
 760    --  Convert to Common_Object, and expand the resulting pragma
 761
 762    procedure Expand_Pragma_Psect_Object (N : Node_Id)
 763      renames Expand_Pragma_Common_Object;
 764
 765    -------------------------------------
 766    -- Expand_Pragma_Relative_Deadline --
 767    -------------------------------------
 768
 769    procedure Expand_Pragma_Relative_Deadline (N : Node_Id) is
 770       P    : constant Node_Id    := Parent (N);
 771       Loc  : constant Source_Ptr := Sloc (N);
 772
 773    begin
 774       --  Expand the pragma only in the case of the main subprogram. For tasks
 775       --  the expansion is done in exp_ch9. Generate a call to Set_Deadline
 776       --  at Clock plus the relative deadline specified in the pragma. Time
 777       --  values are translated into Duration to allow for non-private
 778       --  addition operation.
 779
 780       if Nkind (P) = N_Subprogram_Body then
 781          Rewrite
 782            (N,
 783             Make_Procedure_Call_Statement (Loc,
 784               Name => New_Reference_To (RTE (RE_Set_Deadline), Loc),
 785               Parameter_Associations => New_List (
 786                 Unchecked_Convert_To (RTE (RO_RT_Time),
 787                   Make_Op_Add (Loc,
 788                     Left_Opnd  =>
 789                       Make_Function_Call (Loc,
 790                         New_Reference_To (RTE (RO_RT_To_Duration), Loc),
 791                         New_List (Make_Function_Call (Loc,
 792                           New_Reference_To (RTE (RE_Clock), Loc)))),
 793                     Right_Opnd  =>
 794                       Unchecked_Convert_To (Standard_Duration, Arg1 (N)))))));
 795
 796          Analyze (N);
 797       end if;
 798    end Expand_Pragma_Relative_Deadline;
 799
 800 end Exp_Prag;