gcc/ada/exp_tss.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              E X P _ T S S                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  Type Support Subprogram (TSS) handling
  27
  28 with Namet; use Namet;
  29 with Types; use Types;
  30
  31 package Exp_Tss is
  32
  33    --  A type support subprogram (TSS) is an internally generated function or
  34    --  procedure that is associated with a particular type. Examples are the
  35    --  implicit initialization procedure, and subprograms for the Input and
  36    --  Output attributes.
  37
  38    --  A given TSS is either generated once at the point of the declaration of
  39    --  the type, or it is generated as needed in clients, but only one copy is
  40    --  required in any one generated object file. The choice between these two
  41    --  possibilities is made on a TSS-by-TSS basis depending on the estimation
  42    --  of how likely the TSS is to be used. Initialization procedures fall in
  43    --  the first category, for example, since it is likely that any declared
  44    --  type will be used in a context requiring initialization, but the stream
  45    --  attributes use the second approach, since it is more likely that they
  46    --  will not be used at all, or will only be used in one client in any case.
  47
  48    -------------------------
  49    -- Current Limitations --
  50    -------------------------
  51
  52    --  In the current version of this package, only the case of generating a
  53    --  TSS at the point of declaration of the type is accommodated. A clear
  54    --  improvement would be to follow through with the full implementation
  55    --  as described above, and also accommodate the requirement of generating
  56    --  only one copy in a given object file.
  57
  58    --  For now, we deal with the local case by generating duplicate versions
  59    --  of the TSS routine, which is clearly rather inefficient in space usage.
  60    --  This is done by using Make_TSS_Name_Local to generate unique names
  61    --  for the different instances of TSS routines in a given scope.
  62
  63    ----------------
  64    -- TSS Naming --
  65    ----------------
  66
  67    --  A TSS is identified by its Chars name. The name has the form typXY or
  68    --  typ_<serial>XY, where typ is the type name, and XY are two characters
  69    --  that identify the particular TSS routine. A unique serial number is
  70    --  included for the case where several local instances of the same TSS
  71    --  must be generated (see discussion under Make_TSS_Name_Local).
  72
  73    --  The following codes are used to denote TSSs:
  74
  75    --  Note: When making additions to this list, make the corresponding change
  76    --  to the list in snames.adb-tmpl.
  77
  78    type TSS_Name_Type is new String (1 .. 2);
  79    subtype TNT is TSS_Name_Type;
  80
  81    TSS_Deep_Adjust        : constant TNT := "DA";  -- Deep Adjust
  82    TSS_Deep_Finalize      : constant TNT := "DF";  -- Deep Finalize
  83    TSS_Deep_Initialize    : constant TNT := "DI";  -- Deep Initialize
  84    TSS_Composite_Equality : constant TNT := "EQ";  -- Composite Equality
  85    TSS_From_Any           : constant TNT := "FA";  -- PolyORB/DSA From_Any
  86    TSS_Init_Proc          : constant TNT := "IP";  -- Initialization Procedure
  87    TSS_CPP_Init_Proc      : constant TNT := "IC";  -- Init C++ dispatch tables
  88    TSS_RAS_Access         : constant TNT := "RA";  -- RAS type access
  89    TSS_RAS_Dereference    : constant TNT := "RD";  -- RAS type dereference
  90    TSS_Rep_To_Pos         : constant TNT := "RP";  -- Rep to Pos conversion
  91    TSS_Slice_Assign       : constant TNT := "SA";  -- Slice assignment
  92    TSS_Stream_Input       : constant TNT := "SI";  -- Stream Input attribute
  93    TSS_Stream_Output      : constant TNT := "SO";  -- Stream Output attribute
  94    TSS_Stream_Read        : constant TNT := "SR";  -- Stream Read attribute
  95    TSS_Stream_Write       : constant TNT := "SW";  -- Stream Write attribute
  96    TSS_To_Any             : constant TNT := "TA";  -- PolyORB/DSA To_Any
  97    TSS_TypeCode           : constant TNT := "TC";  -- PolyORB/DSA TypeCode
  98
  99    --  The array below contains all valid TSS names
 100
 101    TSS_Names : constant array (Natural range <>) of TSS_Name_Type :=
 102      (TSS_Deep_Adjust,
 103       TSS_Deep_Finalize,
 104       TSS_Deep_Initialize,
 105       TSS_Composite_Equality,
 106       TSS_From_Any,
 107       TSS_Init_Proc,
 108       TSS_CPP_Init_Proc,
 109       TSS_RAS_Access,
 110       TSS_RAS_Dereference,
 111       TSS_Rep_To_Pos,
 112       TSS_Slice_Assign,
 113       TSS_Stream_Input,
 114       TSS_Stream_Output,
 115       TSS_Stream_Read,
 116       TSS_Stream_Write,
 117       TSS_To_Any,
 118       TSS_TypeCode);
 119
 120    TSS_Null : constant TNT := "  ";
 121    --  Dummy entry used to indicated that this is not really a TSS
 122
 123    function Get_TSS_Name (E : Entity_Id) return TSS_Name_Type;
 124    --  Given an entity, if it is a TSS, then return the corresponding TSS
 125    --  name type, otherwise return TSS_Null.
 126
 127    function Make_TSS_Name
 128      (Typ : Entity_Id;
 129       Nam : TSS_Name_Type) return Name_Id;
 130    --  Construct the name as described above for the given TSS routine
 131    --  identified by Nam for the type identified by Typ.
 132
 133    function Make_TSS_Name_Local
 134      (Typ : Entity_Id;
 135       Nam : TSS_Name_Type) return Name_Id;
 136    --  Similar to the above call, but a string of the form _nnn is inserted
 137    --  before the TSS code suffix, where nnn is a unique serial number. This
 138    --  is used when multiple instances of the same TSS routine may be
 139    --  generated in the same scope (see also discussion above of current
 140    --  limitations).
 141
 142    function Make_Init_Proc_Name (Typ : Entity_Id) return Name_Id;
 143    --  Version for init procs, same as Make_TSS_Name (Typ, TSS_Init_Proc)
 144
 145    function Is_CPP_Init_Proc (E : Entity_Id) return Boolean;
 146    --  Version for CPP init procs, same as Is_TSS (E, TSS_CPP_Init_Proc);
 147
 148    function Is_Init_Proc (E : Entity_Id) return Boolean;
 149    --  Version for init procs, same as Is_TSS (E, TSS_Init_Proc);
 150
 151    function Is_TSS (E : Entity_Id; Nam : TSS_Name_Type) return Boolean;
 152    --  Determines if given entity (E) is the name of a TSS identified by Nam
 153
 154    function Is_TSS (N : Name_Id; Nam : TSS_Name_Type) return Boolean;
 155    --  Same test applied directly to a Name_Id value
 156
 157    -----------------------------------------
 158    -- TSS Data structures and Subprograms --
 159    -----------------------------------------
 160
 161    --  The TSS's for a given type are stored in an element list associated with
 162    --  the type, and referenced from the TSS_Elist field of the N_Freeze_Entity
 163    --  node associated with the type (all types that need TSS's always need to
 164    --  be explicitly frozen, so the N_Freeze_Entity node always exists).
 165
 166    function TSS (Typ : Entity_Id; Nam : TSS_Name_Type) return Entity_Id;
 167    --  Finds the TSS with the given name associated with the given type
 168    --  If no such TSS exists, then Empty is returned;
 169
 170    function TSS (Typ : Entity_Id; Nam : Name_Id) return Entity_Id;
 171    --  Finds the TSS with the given name associated with the given type. If
 172    --  no such TSS exists, then Empty is returned.
 173
 174    function Same_TSS (E1, E2 : Entity_Id) return Boolean;
 175    --  Returns True if E1 and E2 are the same kind of TSS, even if the names
 176    --  are different (i.e. if the names of E1 and E2 end with two upper case
 177    --  letters that are the same).
 178
 179    procedure Set_TSS (Typ : Entity_Id; TSS : Entity_Id);
 180    --  This procedure is used to install a newly created TSS. The second
 181    --  argument is the entity for such a new TSS. This entity is placed in the
 182    --  TSS list for the type given as the first argument, replacing an old
 183    --  entry of the same name if one was present. The tree for the body of this
 184    --  TSS, which is not analyzed yet, is placed in the actions field of the
 185    --  freeze node for the type. All such bodies are inserted into the main
 186    --  tree and analyzed at the point at which the freeze node itself is
 187    --  expanded.
 188
 189    procedure Copy_TSS (TSS : Entity_Id; Typ : Entity_Id);
 190    --  Given an existing TSS for another type (which is already installed,
 191    --  analyzed and expanded), install it as the corresponding TSS for Typ.
 192    --  Note that this just copies a reference, not the tree. This can also be
 193    --  used to initially install a TSS in the case where the subprogram for the
 194    --  TSS has already been created and its declaration processed.
 195
 196    function CPP_Init_Proc (Typ : Entity_Id) return Entity_Id;
 197    --  Obtains the CPP_Init TSS entity the given type. The CPP_Init TSS is a
 198    --  procedure used to initialize the C++ part of the primary and secondary
 199    --  dispatch tables of a tagged type derived from CPP types.
 200
 201    function Init_Proc
 202      (Typ : Entity_Id;
 203       Ref : Entity_Id := Empty) return Entity_Id;
 204    --  Obtains the _init TSS entry for the given type. This function call is
 205    --  equivalent to TSS (Typ, Name_uInit). The _init TSS is the procedure
 206    --  used to initialize otherwise uninitialized instances of a type. If
 207    --  there is no _init TSS, then the type requires no initialization. Note
 208    --  that subtypes and implicit types never have an _init TSS since subtype
 209    --  objects are always initialized using the initialization procedure for
 210    --  the corresponding base type (see Base_Init_Proc function). A special
 211    --  case arises for concurrent types. Such types do not themselves have an
 212    --  init proc TSS, but initialization is required. The init proc used is
 213    --  the one for the corresponding record type (see Base_Init_Proc). If
 214    --  Ref is present it is call to a subprogram whose profile matches the
 215    --  profile of the required constructor (this argument is used to handle
 216    --  non-default CPP constructors).
 217
 218    function Base_Init_Proc
 219      (Typ : Entity_Id;
 220       Ref : Entity_Id := Empty) return Entity_Id;
 221    --  Obtains the _Init TSS entry from the base type of the entity, and also
 222    --  deals with going indirect through the Corresponding_Record_Type field
 223    --  for concurrent objects (which are initialized with the initialization
 224    --  routine for the corresponding record type). Returns Empty if there is no
 225    --  _Init TSS entry for the base type. If Ref is present it is a call to a
 226    --  subprogram whose profile matches the profile of the required constructor
 227    --  (this argument is used to handle non-default CPP constructors).
 228
 229    procedure Set_Init_Proc (Typ : Entity_Id; Init : Entity_Id);
 230    pragma Inline (Set_Init_Proc);
 231    --  The second argument is the _init TSS to be established for the type
 232    --  given as the first argument. Equivalent to Set_TSS (Typ, Init).
 233
 234    function Has_Non_Null_Base_Init_Proc (Typ : Entity_Id) return Boolean;
 235    --  Returns true if the given type has a defined Base_Init_Proc and
 236    --  this init proc is not a null init proc (null init procs occur as
 237    --  a result of the processing for Initialize_Scalars). This function
 238    --  is used to test for the presence of an init proc in cases where
 239    --  a null init proc is considered equivalent to no init proc.
 240
 241    function Find_Inherited_TSS
 242      (Typ : Entity_Id;
 243       Nam : TSS_Name_Type) return Entity_Id;
 244    --  Returns the TSS of name Nam of Typ, or of its closest ancestor defining
 245    --  such a TSS. Empty is returned is neither Typ nor any of its ancestors
 246    --  have such a TSS.
 247
 248 end Exp_Tss;