?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
Merge from mainline (163495:164578).
[official-gcc/graphite-test-results.git] / gcc / ada / lib-load.adb
blob4b39c0a49135198c8d8894a19a8facffbeb5aac8
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT COMPILER COMPONENTS --
4 -- --
5 -- L I B . L O A D --
6 -- --
7 -- B o d y --
8 -- --
9 -- Copyright (C) 1992-2010, Free Software Foundation, Inc. --
10 -- --
11 -- GNAT is free software; you can redistribute it and/or modify it under --
12 -- terms of the GNU General Public License as published by the Free Soft- --
13 -- ware Foundation; either version 3, or (at your option) any later ver- --
14 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
15 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
16 -- or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License --
17 -- for more details. You should have received a copy of the GNU General --
18 -- Public License distributed with GNAT; see file COPYING3. If not, go to --
19 -- http://www.gnu.org/licenses for a complete copy of the license. --
20 -- --
21 -- GNAT was originally developed by the GNAT team at New York University. --
22 -- Extensive contributions were provided by Ada Core Technologies Inc. --
23 -- --
24 ------------------------------------------------------------------------------
25
26 with Atree; use Atree;
27 with Debug; use Debug;
28 with Einfo; use Einfo;
29 with Errout; use Errout;
30 with Fname; use Fname;
31 with Fname.UF; use Fname.UF;
32 with Nlists; use Nlists;
33 with Nmake; use Nmake;
34 with Opt; use Opt;
35 with Osint; use Osint;
36 with Osint.C; use Osint.C;
37 with Output; use Output;
38 with Par;
39 with Restrict; use Restrict;
40 with Scn; use Scn;
41 with Sinfo; use Sinfo;
42 with Sinput; use Sinput;
43 with Sinput.L; use Sinput.L;
44 with Stand; use Stand;
45 with Tbuild; use Tbuild;
46 with Uname; use Uname;
47
48 package body Lib.Load is
49
50 -----------------------
51 -- Local Subprograms --
52 -----------------------
53
54 function From_Limited_With_Chain return Boolean;
55 -- Check whether a possible circular dependence includes units that
56 -- have been loaded through limited_with clauses, in which case there
57 -- is no real circularity.
58
59 function Spec_Is_Irrelevant
60 (Spec_Unit : Unit_Number_Type;
61 Body_Unit : Unit_Number_Type) return Boolean;
62 -- The Spec_Unit and Body_Unit parameters are the unit numbers of the
63 -- spec file that corresponds to the main unit which is a body. This
64 -- function determines if the spec file is irrelevant and will be
65 -- overridden by the body as described in RM 10.1.4(4). See description
66 -- in "Special Handling of Subprogram Bodies" for further details.
67
68 procedure Write_Dependency_Chain;
69 -- This procedure is used to generate error message info lines that
70 -- trace the current dependency chain when a load error occurs.
71
72 ------------------------------
73 -- Change_Main_Unit_To_Spec --
74 ------------------------------
75
76 procedure Change_Main_Unit_To_Spec is
77 U : Unit_Record renames Units.Table (Main_Unit);
78 N : File_Name_Type;
79 X : Source_File_Index;
80
81 begin
82 -- Get name of unit body
83
84 Get_Name_String (U.Unit_File_Name);
85
86 -- Note: for the following we should really generalize and consult the
87 -- file name pattern data, but for now we just deal with the common
88 -- naming cases, which is probably good enough in practice ???
89
90 -- Change .adb to .ads
91
92 if Name_Len >= 5
93 and then Name_Buffer (Name_Len - 3 .. Name_Len) = ".adb"
94 then
95 Name_Buffer (Name_Len) := 's';
96
97 -- Change .2.ada to .1.ada (Rational convention)
98
99 elsif Name_Len >= 7
100 and then Name_Buffer (Name_Len - 5 .. Name_Len) = ".2.ada"
101 then
102 Name_Buffer (Name_Len - 4) := '1';
103
104 -- Change .ada to _.ada (DEC convention)
105
106 elsif Name_Len >= 5
107 and then Name_Buffer (Name_Len - 3 .. Name_Len) = ".ada"
108 then
109 Name_Buffer (Name_Len - 3 .. Name_Len + 1) := "_.ada";
110 Name_Len := Name_Len + 1;
111
112 -- No match, don't make the change
113
114 else
115 return;
116 end if;
117
118 -- Try loading the spec
119
120 N := Name_Find;
121 X := Load_Source_File (N);
122
123 -- No change if we did not find the spec
124
125 if X = No_Source_File then
126 return;
127 end if;
128
129 -- Otherwise modify Main_Unit entry to point to spec
130
131 U.Unit_File_Name := N;
132 U.Source_Index := X;
133 end Change_Main_Unit_To_Spec;
134
135 -------------------------------
136 -- Create_Dummy_Package_Unit --
137 -------------------------------
138
139 function Create_Dummy_Package_Unit
140 (With_Node : Node_Id;
141 Spec_Name : Unit_Name_Type) return Unit_Number_Type
142 is
143 Unum : Unit_Number_Type;
144 Cunit_Entity : Entity_Id;
145 Cunit : Node_Id;
146 Du_Name : Node_Or_Entity_Id;
147 End_Lab : Node_Id;
148 Save_CS : constant Boolean := Get_Comes_From_Source_Default;
149
150 begin
151 -- The created dummy package unit does not come from source
152
153 Set_Comes_From_Source_Default (False);
154
155 -- Normal package
156
157 if Nkind (Name (With_Node)) = N_Identifier then
158 Cunit_Entity :=
159 Make_Defining_Identifier (No_Location,
160 Chars => Chars (Name (With_Node)));
161 Du_Name := Cunit_Entity;
162 End_Lab := New_Occurrence_Of (Cunit_Entity, No_Location);
163
164 -- Child package
165
166 else
167 Cunit_Entity :=
168 Make_Defining_Identifier (No_Location,
169 Chars => Chars (Selector_Name (Name (With_Node))));
170 Du_Name :=
171 Make_Defining_Program_Unit_Name (No_Location,
172 Name => Copy_Separate_Tree (Prefix (Name (With_Node))),
173 Defining_Identifier => Cunit_Entity);
174
175 Set_Is_Child_Unit (Cunit_Entity);
176
177 End_Lab :=
178 Make_Designator (No_Location,
179 Name => Copy_Separate_Tree (Prefix (Name (With_Node))),
180 Identifier => New_Occurrence_Of (Cunit_Entity, No_Location));
181 end if;
182
183 Set_Scope (Cunit_Entity, Standard_Standard);
184
185 Cunit :=
186 Make_Compilation_Unit (No_Location,
187 Context_Items => Empty_List,
188 Unit =>
189 Make_Package_Declaration (No_Location,
190 Specification =>
191 Make_Package_Specification (No_Location,
192 Defining_Unit_Name => Du_Name,
193 Visible_Declarations => Empty_List,
194 End_Label => End_Lab)),
195 Aux_Decls_Node =>
196 Make_Compilation_Unit_Aux (No_Location));
197
198 -- Mark the dummy package as analyzed to prevent analysis of this
199 -- (non-existent) unit in -gnatQ mode because at the moment the
200 -- structure and attributes of this dummy package does not allow
201 -- a normal analysis of this unit
202
203 Set_Analyzed (Cunit);
204
205 Units.Increment_Last;
206 Unum := Units.Last;
207
208 Units.Table (Unum) := (
209 Cunit => Cunit,
210 Cunit_Entity => Cunit_Entity,
211 Dependency_Num => 0,
212 Dynamic_Elab => False,
213 Error_Location => Sloc (With_Node),
214 Expected_Unit => Spec_Name,
215 Fatal_Error => True,
216 Generate_Code => False,
217 Has_RACW => False,
218 Is_Compiler_Unit => False,
219 Ident_String => Empty,
220 Loading => False,
221 Main_Priority => Default_Main_Priority,
222 Munit_Index => 0,
223 Serial_Number => 0,
224 Source_Index => No_Source_File,
225 Unit_File_Name => Get_File_Name (Spec_Name, Subunit => False),
226 Unit_Name => Spec_Name,
227 Version => 0,
228 OA_Setting => 'O');
229
230 Set_Comes_From_Source_Default (Save_CS);
231 Set_Error_Posted (Cunit_Entity);
232 Set_Error_Posted (Cunit);
233 return Unum;
234 end Create_Dummy_Package_Unit;
235
236 -----------------------------
237 -- From_Limited_With_Chain --
238 -----------------------------
239
240 function From_Limited_With_Chain return Boolean is
241 Curr_Num : constant Unit_Number_Type :=
242 Load_Stack.Table (Load_Stack.Last).Unit_Number;
243
244 begin
245 -- True if the current load operation is through a limited_with clause
246 -- and we are not within a loop of regular with_clauses.
247
248 for U in reverse Load_Stack.First .. Load_Stack.Last - 1 loop
249 if Load_Stack.Table (U).Unit_Number = Curr_Num then
250 return False;
251
252 elsif Present (Load_Stack.Table (U).With_Node)
253 and then Limited_Present (Load_Stack.Table (U).With_Node)
254 then
255 return True;
256 end if;
257 end loop;
258
259 return False;
260 end From_Limited_With_Chain;
261
262 ----------------
263 -- Initialize --
264 ----------------
265
266 procedure Initialize is
267 begin
268 Units.Init;
269 Load_Stack.Init;
270 end Initialize;
271
272 ------------------------
273 -- Initialize_Version --
274 ------------------------
275
276 procedure Initialize_Version (U : Unit_Number_Type) is
277 begin
278 Units.Table (U).Version := Source_Checksum (Source_Index (U));
279 end Initialize_Version;
280
281 ----------------------
282 -- Load_Main_Source --
283 ----------------------
284
285 procedure Load_Main_Source is
286 Fname : File_Name_Type;
287 Version : Word := 0;
288
289 begin
290 Load_Stack.Increment_Last;
291 Load_Stack.Table (Load_Stack.Last) := (Main_Unit, Empty);
292
293 -- Initialize unit table entry for Main_Unit. Note that we don't know
294 -- the unit name yet, that gets filled in when the parser parses the
295 -- main unit, at which time a check is made that it matches the main
296 -- file name, and then the Unit_Name field is set. The Cunit and
297 -- Cunit_Entity fields also get filled in later by the parser.
298
299 Units.Increment_Last;
300 Fname := Next_Main_Source;
301
302 Units.Table (Main_Unit).Unit_File_Name := Fname;
303
304 if Fname /= No_File then
305 Main_Source_File := Load_Source_File (Fname);
306 Current_Error_Source_File := Main_Source_File;
307
308 if Main_Source_File /= No_Source_File then
309 Version := Source_Checksum (Main_Source_File);
310 end if;
311
312 Units.Table (Main_Unit) := (
313 Cunit => Empty,
314 Cunit_Entity => Empty,
315 Dependency_Num => 0,
316 Dynamic_Elab => False,
317 Error_Location => No_Location,
318 Expected_Unit => No_Unit_Name,
319 Fatal_Error => False,
320 Generate_Code => False,
321 Has_RACW => False,
322 Is_Compiler_Unit => False,
323 Ident_String => Empty,
324 Loading => True,
325 Main_Priority => Default_Main_Priority,
326 Munit_Index => 0,
327 Serial_Number => 0,
328 Source_Index => Main_Source_File,
329 Unit_File_Name => Fname,
330 Unit_Name => No_Unit_Name,
331 Version => Version,
332 OA_Setting => 'O');
333 end if;
334 end Load_Main_Source;
335
336 ---------------
337 -- Load_Unit --
338 ---------------
339
340 function Load_Unit
341 (Load_Name : Unit_Name_Type;
342 Required : Boolean;
343 Error_Node : Node_Id;
344 Subunit : Boolean;
345 Corr_Body : Unit_Number_Type := No_Unit;
346 Renamings : Boolean := False;
347 With_Node : Node_Id := Empty;
348 PMES : Boolean := False) return Unit_Number_Type
349 is
350 Calling_Unit : Unit_Number_Type;
351 Uname_Actual : Unit_Name_Type;
352 Unum : Unit_Number_Type;
353 Unump : Unit_Number_Type;
354 Fname : File_Name_Type;
355 Src_Ind : Source_File_Index;
356 Save_PMES : constant Boolean := Parsing_Main_Extended_Source;
357
358 begin
359 Parsing_Main_Extended_Source := PMES;
360
361 -- If renamings are allowed and we have a child unit name, then we
362 -- must first load the parent to deal with finding the real name.
363 -- Retain the with_clause that names the child, so that if it is
364 -- limited, the parent is loaded under the same condition.
365
366 if Renamings and then Is_Child_Name (Load_Name) then
367 Unump :=
368 Load_Unit
369 (Load_Name => Get_Parent_Spec_Name (Load_Name),
370 Required => Required,
371 Subunit => False,
372 Renamings => True,
373 Error_Node => Error_Node,
374 With_Node => With_Node);
375
376 if Unump = No_Unit then
377 Parsing_Main_Extended_Source := Save_PMES;
378 return No_Unit;
379 end if;
380
381 -- If parent is a renaming, then we use the renamed package as
382 -- the actual parent for the subsequent load operation.
383
384 if Nkind (Unit (Cunit (Unump))) = N_Package_Renaming_Declaration then
385 Uname_Actual :=
386 New_Child
387 (Load_Name, Get_Unit_Name (Name (Unit (Cunit (Unump)))));
388
389 -- Save the renaming entity, to establish its visibility when
390 -- installing the context. The implicit with is on this entity,
391 -- not on the package it renames.
392
393 if Nkind (Error_Node) = N_With_Clause
394 and then Nkind (Name (Error_Node)) = N_Selected_Component
395 then
396 declare
397 Par : Node_Id := Name (Error_Node);
398
399 begin
400 while Nkind (Par) = N_Selected_Component
401 and then Chars (Selector_Name (Par)) /=
402 Chars (Cunit_Entity (Unump))
403 loop
404 Par := Prefix (Par);
405 end loop;
406
407 -- Case of some intermediate parent is a renaming
408
409 if Nkind (Par) = N_Selected_Component then
410 Set_Entity (Selector_Name (Par), Cunit_Entity (Unump));
411
412 -- Case where the ultimate parent is a renaming
413
414 else
415 Set_Entity (Par, Cunit_Entity (Unump));
416 end if;
417 end;
418 end if;
419
420 -- If the parent is not a renaming, then get its name (this may
421 -- be different from the parent spec name obtained above because
422 -- of renamings higher up in the hierarchy).
423
424 else
425 Uname_Actual := New_Child (Load_Name, Unit_Name (Unump));
426 end if;
427
428 -- Here if unit to be loaded is not a child unit
429
430 else
431 Uname_Actual := Load_Name;
432 end if;
433
434 Fname := Get_File_Name (Uname_Actual, Subunit);
435
436 if Debug_Flag_L then
437 Write_Eol;
438 Write_Str ("*** Load request for unit: ");
439 Write_Unit_Name (Load_Name);
440
441 if Required then
442 Write_Str (" (Required = True)");
443 else
444 Write_Str (" (Required = False)");
445 end if;
446
447 Write_Eol;
448
449 if Uname_Actual /= Load_Name then
450 Write_Str ("*** Actual unit loaded: ");
451 Write_Unit_Name (Uname_Actual);
452 end if;
453 end if;
454
455 -- Capture error location if it is for the main unit. The idea is to
456 -- post errors on the main unit location, not the most recent unit.
457 -- Note: Unit_Name (Main_Unit) is not set if we are parsing gnat.adc.
458
459 if Present (Error_Node)
460 and then Unit_Name (Main_Unit) /= No_Unit_Name
461 then
462 -- It seems like In_Extended_Main_Source_Unit (Error_Node) would
463 -- do the trick here, but that's wrong, it is much too early to
464 -- call this routine. We are still in the parser, and the required
465 -- semantic information is not established yet. So we base the
466 -- judgment on unit names.
467
468 Get_External_Unit_Name_String (Unit_Name (Main_Unit));
469
470 declare
471 Main_Unit_Name : constant String := Name_Buffer (1 .. Name_Len);
472
473 begin
474 Get_External_Unit_Name_String
475 (Unit_Name (Get_Source_Unit (Error_Node)));
476
477 -- If the two names are identical, then for sure we are part
478 -- of the extended main unit
479
480 if Main_Unit_Name = Name_Buffer (1 .. Name_Len) then
481 Load_Msg_Sloc := Sloc (Error_Node);
482
483 -- If the load is called from a with_type clause, the error
484 -- node is correct.
485
486 -- Otherwise, check for the subunit case, and if so, consider
487 -- we have a match if one name is a prefix of the other name.
488
489 else
490 if Nkind (Unit (Cunit (Main_Unit))) = N_Subunit
491 or else
492 Nkind (Unit (Cunit (Get_Source_Unit (Error_Node)))) =
493 N_Subunit
494 then
495 Name_Len := Integer'Min (Name_Len, Main_Unit_Name'Length);
496
497 if Name_Buffer (1 .. Name_Len)
498 =
499 Main_Unit_Name (1 .. Name_Len)
500 then
501 Load_Msg_Sloc := Sloc (Error_Node);
502 end if;
503 end if;
504 end if;
505 end;
506 end if;
507
508 -- If we are generating error messages, then capture calling unit
509
510 if Present (Error_Node) then
511 Calling_Unit := Get_Source_Unit (Error_Node);
512 else
513 Calling_Unit := No_Unit;
514 end if;
515
516 -- See if we already have an entry for this unit
517
518 Unum := Main_Unit;
519 while Unum <= Units.Last loop
520 exit when Uname_Actual = Units.Table (Unum).Unit_Name;
521 Unum := Unum + 1;
522 end loop;
523
524 -- Whether or not the entry was found, Unum is now the right value,
525 -- since it is one more than Units.Last (i.e. the index of the new
526 -- entry we will create) in the not found case.
527
528 -- A special check is necessary in the unit not found case. If the unit
529 -- is not found, but the file in which it lives has already been loaded,
530 -- then we have the problem that the file does not contain the unit that
531 -- is needed. We simply treat this as a file not found condition.
532
533 -- We skip this test in multiple unit per file mode since in this
534 -- case we can have multiple units from the same source file.
535
536 if Unum > Units.Last and then Get_Unit_Index (Uname_Actual) = 0 then
537 for J in Units.First .. Units.Last loop
538 if Fname = Units.Table (J).Unit_File_Name then
539 if Debug_Flag_L then
540 Write_Str (" file does not contain unit, Unit_Number = ");
541 Write_Int (Int (Unum));
542 Write_Eol;
543 Write_Eol;
544 end if;
545
546 if Present (Error_Node) then
547 if Is_Predefined_File_Name (Fname) then
548 Error_Msg_Unit_1 := Uname_Actual;
549 Error_Msg
550 ("$$ is not a language defined unit", Load_Msg_Sloc);
551 else
552 Error_Msg_File_1 := Fname;
553 Error_Msg_Unit_1 := Uname_Actual;
554 Error_Msg ("File{ does not contain unit$", Load_Msg_Sloc);
555 end if;
556
557 Write_Dependency_Chain;
558 Unum := No_Unit;
559 goto Done;
560
561 else
562 Unum := No_Unit;
563 goto Done;
564 end if;
565 end if;
566 end loop;
567 end if;
568
569 -- If we are proceeding with load, then make load stack entry,
570 -- and indicate the kind of with_clause responsible for the load.
571
572 Load_Stack.Increment_Last;
573 Load_Stack.Table (Load_Stack.Last) := (Unum, With_Node);
574
575 -- Case of entry already in table
576
577 if Unum <= Units.Last then
578
579 -- Here is where we check for a circular dependency, which is
580 -- an attempt to load a unit which is currently in the process
581 -- of being loaded. We do *not* care about a circular chain that
582 -- leads back to a body, because this kind of circular dependence
583 -- legitimately occurs (e.g. two package bodies that contain
584 -- inlined subprogram referenced by the other).
585
586 -- Ada 2005 (AI-50217): We also ignore limited_with clauses, because
587 -- their purpose is precisely to create legal circular structures.
588
589 if Loading (Unum)
590 and then (Is_Spec_Name (Units.Table (Unum).Unit_Name)
591 or else Acts_As_Spec (Units.Table (Unum).Cunit))
592 and then (Nkind (Error_Node) /= N_With_Clause
593 or else not Limited_Present (Error_Node))
594 and then not From_Limited_With_Chain
595 then
596 if Debug_Flag_L then
597 Write_Str (" circular dependency encountered");
598 Write_Eol;
599 end if;
600
601 if Present (Error_Node) then
602 Error_Msg ("circular unit dependency", Load_Msg_Sloc);
603 Write_Dependency_Chain;
604 else
605 Load_Stack.Decrement_Last;
606 end if;
607
608 Unum := No_Unit;
609 goto Done;
610 end if;
611
612 if Debug_Flag_L then
613 Write_Str (" unit already in file table, Unit_Number = ");
614 Write_Int (Int (Unum));
615 Write_Eol;
616 end if;
617
618 Load_Stack.Decrement_Last;
619 goto Done;
620
621 -- Unit is not already in table, so try to open the file
622
623 else
624 if Debug_Flag_L then
625 Write_Str (" attempt unit load, Unit_Number = ");
626 Write_Int (Int (Unum));
627 Write_Eol;
628 end if;
629
630 Src_Ind := Load_Source_File (Fname);
631
632 -- Make a partial entry in the file table, used even in the file not
633 -- found case to print the dependency chain including the last entry
634
635 Units.Increment_Last;
636 Units.Table (Unum).Unit_Name := Uname_Actual;
637
638 -- File was found
639
640 if Src_Ind /= No_Source_File then
641 Units.Table (Unum) := (
642 Cunit => Empty,
643 Cunit_Entity => Empty,
644 Dependency_Num => 0,
645 Dynamic_Elab => False,
646 Error_Location => Sloc (Error_Node),
647 Expected_Unit => Uname_Actual,
648 Fatal_Error => False,
649 Generate_Code => False,
650 Has_RACW => False,
651 Is_Compiler_Unit => False,
652 Ident_String => Empty,
653 Loading => True,
654 Main_Priority => Default_Main_Priority,
655 Munit_Index => 0,
656 Serial_Number => 0,
657 Source_Index => Src_Ind,
658 Unit_File_Name => Fname,
659 Unit_Name => Uname_Actual,
660 Version => Source_Checksum (Src_Ind),
661 OA_Setting => 'O');
662
663 -- Parse the new unit
664
665 declare
666 Save_Index : constant Nat := Multiple_Unit_Index;
667 Save_PMES : constant Boolean := Parsing_Main_Extended_Source;
668
669 begin
670 Multiple_Unit_Index := Get_Unit_Index (Uname_Actual);
671 Units.Table (Unum).Munit_Index := Multiple_Unit_Index;
672 Initialize_Scanner (Unum, Source_Index (Unum));
673
674 if Calling_Unit = Main_Unit and then Subunit then
675 Parsing_Main_Extended_Source := True;
676 end if;
677
678 Discard_List (Par (Configuration_Pragmas => False));
679
680 Parsing_Main_Extended_Source := Save_PMES;
681
682 Multiple_Unit_Index := Save_Index;
683 Set_Loading (Unum, False);
684 end;
685
686 -- If spec is irrelevant, then post errors and quit
687
688 if Corr_Body /= No_Unit
689 and then Spec_Is_Irrelevant (Unum, Corr_Body)
690 then
691 Error_Msg_File_1 := Unit_File_Name (Corr_Body);
692 Error_Msg
693 ("cannot compile subprogram in file {!", Load_Msg_Sloc);
694 Error_Msg_File_1 := Unit_File_Name (Unum);
695 Error_Msg
696 ("\incorrect spec in file { must be removed first!",
697 Load_Msg_Sloc);
698 Unum := No_Unit;
699 goto Done;
700 end if;
701
702 -- If loaded unit had a fatal error, then caller inherits it!
703
704 if Units.Table (Unum).Fatal_Error
705 and then Present (Error_Node)
706 then
707 Units.Table (Calling_Unit).Fatal_Error := True;
708 end if;
709
710 -- Remove load stack entry and return the entry in the file table
711
712 Load_Stack.Decrement_Last;
713
714 -- All done, return unit number
715
716 goto Done;
717
718 -- Case of file not found
719
720 else
721 if Debug_Flag_L then
722 Write_Str (" file was not found, load failed");
723 Write_Eol;
724 end if;
725
726 -- Generate message if unit required
727
728 if Required and then Present (Error_Node) then
729 if Is_Predefined_File_Name (Fname) then
730
731 -- This is a predefined library unit which is not present
732 -- in the run time. If a predefined unit is not available
733 -- it may very likely be the case that there is also pragma
734 -- Restriction forbidding its usage. This is typically the
735 -- case when building a configurable run time, where the
736 -- usage of certain run-time units is restricted by means
737 -- of both the corresponding pragma Restriction (such as
738 -- No_Calendar), and by not including the unit. Hence, we
739 -- check whether this predefined unit is forbidden, so that
740 -- the message about the restriction violation is generated,
741 -- if needed.
742
743 Check_Restricted_Unit (Load_Name, Error_Node);
744
745 Error_Msg_Unit_1 := Uname_Actual;
746 Error_Msg -- CODEFIX
747 ("$$ is not a predefined library unit", Load_Msg_Sloc);
748
749 else
750 Error_Msg_File_1 := Fname;
751 Error_Msg ("file{ not found", Load_Msg_Sloc);
752 end if;
753
754 Write_Dependency_Chain;
755
756 -- Remove unit from stack, to avoid cascaded errors on
757 -- subsequent missing files.
758
759 Load_Stack.Decrement_Last;
760 Units.Decrement_Last;
761
762 -- If unit not required, remove load stack entry and the junk
763 -- file table entry, and return No_Unit to indicate not found,
764
765 else
766 Load_Stack.Decrement_Last;
767 Units.Decrement_Last;
768 end if;
769
770 Unum := No_Unit;
771 goto Done;
772 end if;
773 end if;
774
775 -- Here to exit, with result in Unum
776
777 <<Done>>
778 Parsing_Main_Extended_Source := Save_PMES;
779 return Unum;
780 end Load_Unit;
781
782 --------------------------
783 -- Make_Child_Decl_Unit --
784 --------------------------
785
786 procedure Make_Child_Decl_Unit (N : Node_Id) is
787 Unit_Decl : constant Node_Id := Library_Unit (N);
788
789 begin
790 Units.Increment_Last;
791 Units.Table (Units.Last) := Units.Table (Get_Cunit_Unit_Number (N));
792 Units.Table (Units.Last).Unit_Name :=
793 Get_Spec_Name (Unit_Name (Get_Cunit_Unit_Number (N)));
794 Units.Table (Units.Last).Cunit := Unit_Decl;
795 Units.Table (Units.Last).Cunit_Entity :=
796 Defining_Identifier
797 (Defining_Unit_Name (Specification (Unit (Unit_Decl))));
798
799 -- The library unit created for of a child subprogram unit plays no
800 -- role in code generation and binding, so label it accordingly.
801
802 Units.Table (Units.Last).Generate_Code := False;
803 Set_Has_No_Elaboration_Code (Unit_Decl);
804 end Make_Child_Decl_Unit;
805
806 ------------------------
807 -- Make_Instance_Unit --
808 ------------------------
809
810 -- If the unit is an instance, it appears as a package declaration, but
811 -- contains both declaration and body of the instance. The body becomes
812 -- the main unit of the compilation, and the declaration is inserted
813 -- at the end of the unit table. The main unit now has the name of a
814 -- body, which is constructed from the name of the original spec,
815 -- and is attached to the compilation node of the original unit. The
816 -- declaration has been attached to a new compilation unit node, and
817 -- code will have to be generated for it.
818
819 procedure Make_Instance_Unit (N : Node_Id; In_Main : Boolean) is
820 Sind : constant Source_File_Index := Source_Index (Main_Unit);
821
822 begin
823 Units.Increment_Last;
824
825 if In_Main then
826 Units.Table (Units.Last) := Units.Table (Main_Unit);
827 Units.Table (Units.Last).Cunit := Library_Unit (N);
828 Units.Table (Units.Last).Generate_Code := True;
829 Units.Table (Main_Unit).Cunit := N;
830 Units.Table (Main_Unit).Unit_Name :=
831 Get_Body_Name
832 (Unit_Name (Get_Cunit_Unit_Number (Library_Unit (N))));
833 Units.Table (Main_Unit).Version := Source_Checksum (Sind);
834
835 else
836 -- Duplicate information from instance unit, for the body. The unit
837 -- node N has been rewritten as a body, but it was placed in the
838 -- units table when first loaded as a declaration.
839
840 Units.Table (Units.Last) := Units.Table (Get_Cunit_Unit_Number (N));
841 Units.Table (Units.Last).Cunit := Library_Unit (N);
842 end if;
843 end Make_Instance_Unit;
844
845 ------------------------
846 -- Spec_Is_Irrelevant --
847 ------------------------
848
849 function Spec_Is_Irrelevant
850 (Spec_Unit : Unit_Number_Type;
851 Body_Unit : Unit_Number_Type) return Boolean
852 is
853 Sunit : constant Node_Id := Cunit (Spec_Unit);
854 Bunit : constant Node_Id := Cunit (Body_Unit);
855
856 begin
857 -- The spec is irrelevant if the body is a subprogram body, and the spec
858 -- is other than a subprogram spec or generic subprogram spec. Note that
859 -- the names must be the same, we don't need to check that, because we
860 -- already know that from the fact that the file names are the same.
861
862 return
863 Nkind (Unit (Bunit)) = N_Subprogram_Body
864 and then Nkind (Unit (Sunit)) /= N_Subprogram_Declaration
865 and then Nkind (Unit (Sunit)) /= N_Generic_Subprogram_Declaration;
866 end Spec_Is_Irrelevant;
867
868 --------------------
869 -- Version_Update --
870 --------------------
871
872 procedure Version_Update (U : Node_Id; From : Node_Id) is
873 Unum : constant Unit_Number_Type := Get_Cunit_Unit_Number (U);
874 Fnum : constant Unit_Number_Type := Get_Cunit_Unit_Number (From);
875 begin
876 if Source_Index (Fnum) /= No_Source_File then
877 Units.Table (Unum).Version :=
878 Units.Table (Unum).Version
879 xor
880 Source_Checksum (Source_Index (Fnum));
881 end if;
882 end Version_Update;
883
884 ----------------------------
885 -- Write_Dependency_Chain --
886 ----------------------------
887
888 procedure Write_Dependency_Chain is
889 begin
890 -- The dependency chain is only written if it is at least two entries
891 -- deep, otherwise it is trivial (the main unit depending on a unit
892 -- that it obviously directly depends on).
893
894 if Load_Stack.Last - 1 > Load_Stack.First then
895 for U in Load_Stack.First .. Load_Stack.Last - 1 loop
896 Error_Msg_Unit_1 :=
897 Unit_Name (Load_Stack.Table (U).Unit_Number);
898 Error_Msg_Unit_2 :=
899 Unit_Name (Load_Stack.Table (U + 1).Unit_Number);
900 Error_Msg ("$ depends on $!", Load_Msg_Sloc);
901 end loop;
902 end if;
903 end Write_Dependency_Chain;
904
905 end Lib.Load;
GCC graphite test results