gcc/ada/tbuild.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               T B U I L D                                --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package contains various utility procedures to assist in
  27 --  building specific types of tree nodes.
  28
  29 with Namet; use Namet;
  30 with Sinfo; use Sinfo;
  31 with Types; use Types;
  32
  33 package Tbuild is
  34
  35    function Checks_Off (N : Node_Id) return Node_Id;
  36    pragma Inline (Checks_Off);
  37    --  Returns an N_Unchecked_Expression node whose expression is the given
  38    --  argument. The results is a subexpression identical to the argument,
  39    --  except that it will be analyzed and resolved with checks off.
  40
  41    function Convert_To (Typ : Entity_Id; Expr : Node_Id) return Node_Id;
  42    --  Returns an expression that represents the result of a checked convert
  43    --  of expression Exp to type T. If the base type of Exp is T, then no
  44    --  conversion is required, and Exp is returned unchanged. Otherwise an
  45    --  N_Type_Conversion node is constructed to convert the expression.
  46    --  If an N_Type_Conversion node is required, Relocate_Node is used on
  47    --  Exp. This means that it is safe to replace a node by a Convert_To
  48    --  of itself to some other type.
  49
  50    procedure Discard_Node (N : Node_Or_Entity_Id);
  51    pragma Inline (Discard_Node);
  52    --  This is a dummy procedure that simply returns and does nothing. It is
  53    --  used when a function returning a Node_Id value is called for its side
  54    --  effect (e.g. a call to Make to construct a node) but the Node_Id value
  55    --  is not required.
  56
  57    procedure Discard_List (L : List_Id);
  58    pragma Inline (Discard_List);
  59    --  This is a dummy procedure that simply returns and does nothing. It is
  60    --  used when a function returning a Node_Id value is called for its side
  61    --  effect (e.g. a call to the parser to parse a list of compilation
  62    --  units), but the List_Id value is not required.
  63
  64    function Make_Byte_Aligned_Attribute_Reference
  65      (Sloc           : Source_Ptr;
  66       Prefix         : Node_Id;
  67       Attribute_Name : Name_Id) return Node_Id;
  68    pragma Inline (Make_Byte_Aligned_Attribute_Reference);
  69    --  Like the standard Make_Attribute_Reference but the special flag
  70    --  Must_Be_Byte_Aligned is set in the attribute reference node. The
  71    --  Attribute_Name must be Name_Address or Name_Unrestricted_Access.
  72
  73    function Make_DT_Access
  74      (Loc : Source_Ptr; Rec : Node_Id; Typ : Entity_Id) return Node_Id;
  75    --  Create an access to the Dispatch Table by using the Tag field of a
  76    --  tagged record : Acc_Dt (Rec.tag).all
  77
  78    function Make_Implicit_Exception_Handler
  79      (Sloc              : Source_Ptr;
  80       Choice_Parameter  : Node_Id := Empty;
  81       Exception_Choices : List_Id;
  82       Statements        : List_Id) return Node_Id;
  83    pragma Inline (Make_Implicit_Exception_Handler);
  84    --  This is just like Make_Exception_Handler, except that it also sets the
  85    --  Local_Raise_Statements field to No_Elist, ensuring that it is properly
  86    --  initialized. This should always be used when creating implicit exception
  87    --  handlers during expansion (i.e. handlers that do not correspond to user
  88    --  source program exception handlers).
  89
  90    function Make_Implicit_If_Statement
  91      (Node            : Node_Id;
  92       Condition       : Node_Id;
  93       Then_Statements : List_Id;
  94       Elsif_Parts     : List_Id := No_List;
  95       Else_Statements : List_Id := No_List) return Node_Id;
  96    pragma Inline (Make_Implicit_If_Statement);
  97    --  This function makes an N_If_Statement node whose fields are filled
  98    --  in with the indicated values (see Sinfo), and whose Sloc field is
  99    --  is set to Sloc (Node). The effect is identical to calling function
 100    --  Nmake.Make_If_Statement except that there is a check for restriction
 101    --  No_Implicit_Conditionals, and if this restriction is being violated,
 102    --  an error message is posted on Node.
 103
 104    function Make_Implicit_Label_Declaration
 105      (Loc                 : Source_Ptr;
 106       Defining_Identifier : Node_Id;
 107       Label_Construct     : Node_Id) return Node_Id;
 108    --  Used to construct an implicit label declaration node, including setting
 109    --  the proper Label_Construct field (since Label_Construct is a semantic
 110    --  field, the normal call to Make_Implicit_Label_Declaration does not
 111    --  set this field).
 112
 113    function Make_Implicit_Loop_Statement
 114      (Node                   : Node_Id;
 115       Statements             : List_Id;
 116       Identifier             : Node_Id := Empty;
 117       Iteration_Scheme       : Node_Id := Empty;
 118       Has_Created_Identifier : Boolean := False;
 119       End_Label              : Node_Id := Empty) return Node_Id;
 120    --  This function makes an N_Loop_Statement node whose fields are filled
 121    --  in with the indicated values (see Sinfo), and whose Sloc field is
 122    --  is set to Sloc (Node). The effect is identical to calling function
 123    --  Nmake.Make_Loop_Statement except that there is a check for restrictions
 124    --  No_Implicit_Loops and No_Implicit_Conditionals (the first applying in
 125    --  all cases, and the second only for while loops), and if one of these
 126    --  restrictions is being violated, an error message is posted on Node.
 127
 128    function Make_Integer_Literal
 129      (Loc    : Source_Ptr;
 130       Intval : Int) return Node_Id;
 131    pragma Inline (Make_Integer_Literal);
 132    --  A convenient form of Make_Integer_Literal taking Int instead of Uint
 133
 134    function Make_Linker_Section_Pragma
 135      (Ent : Entity_Id;
 136       Loc : Source_Ptr;
 137       Sec : String) return Node_Id;
 138    --  Construct a Linker_Section pragma for entity Ent, using string Sec as
 139    --  the section name. Loc is the Sloc value to use in building the pragma.
 140
 141    function Make_Pragma
 142      (Sloc                         : Source_Ptr;
 143       Chars                        : Name_Id;
 144       Pragma_Argument_Associations : List_Id := No_List;
 145       Debug_Statement              : Node_Id := Empty) return Node_Id;
 146    --  A convenient form of Make_Pragma not requiring a Pragma_Identifier
 147    --  argument (this argument is built from the value given for Chars).
 148
 149    function Make_Raise_Constraint_Error
 150      (Sloc      : Source_Ptr;
 151       Condition : Node_Id := Empty;
 152       Reason    : RT_Exception_Code) return Node_Id;
 153    pragma Inline (Make_Raise_Constraint_Error);
 154    --  A convenient form of Make_Raise_Constraint_Error where the Reason
 155    --  is given simply as an enumeration value, rather than a Uint code.
 156
 157    function Make_Raise_Program_Error
 158      (Sloc      : Source_Ptr;
 159       Condition : Node_Id := Empty;
 160       Reason    : RT_Exception_Code) return Node_Id;
 161    pragma Inline (Make_Raise_Program_Error);
 162    --  A convenient form of Make_Raise_Program_Error where the Reason
 163    --  is given simply as an enumeration value, rather than a Uint code.
 164
 165    function Make_Raise_Storage_Error
 166      (Sloc      : Source_Ptr;
 167       Condition : Node_Id := Empty;
 168       Reason    : RT_Exception_Code) return Node_Id;
 169    pragma Inline (Make_Raise_Storage_Error);
 170    --  A convenient form of Make_Raise_Storage_Error where the Reason
 171    --  is given simply as an enumeration value, rather than a Uint code.
 172
 173    function Make_String_Literal
 174      (Sloc   : Source_Ptr;
 175       Strval : String) return Node_Id;
 176    --  A convenient form of Make_String_Literal, where the string value
 177    --  is given as a normal string instead of a String_Id value.
 178
 179    function Make_Temporary
 180      (Loc          : Source_Ptr;
 181       Id           : Character;
 182       Related_Node : Node_Id := Empty) return Node_Id;
 183    --  Create a defining identifier to capture the value of an expression
 184    --  or aggregate, and link it to the expression that it replaces, in
 185    --  order to provide better CodePeer reports. The defining identifier
 186    --  name is obtained by Make_Internal_Name (Id).
 187
 188    function Make_Unsuppress_Block
 189      (Loc   : Source_Ptr;
 190       Check : Name_Id;
 191       Stmts : List_Id) return Node_Id;
 192    --  Build a block with a pragma Suppress on 'Check'. Stmts is the
 193    --  statements list that needs protection against the check
 194
 195    function New_Constraint_Error (Loc : Source_Ptr) return Node_Id;
 196    --  This function builds a tree corresponding to the Ada statement
 197    --  "raise Constraint_Error" and returns the root of this tree,
 198    --  the N_Raise_Statement node.
 199
 200    function New_Op_Node
 201      (New_Node_Kind : Node_Kind;
 202       New_Sloc      : Source_Ptr) return Node_Id;
 203    --  Create node using New_Node and, if its kind is in N_Op, set its Chars
 204    --  field accordingly.
 205
 206    function New_External_Name
 207      (Related_Id   : Name_Id;
 208       Suffix       : Character := ' ';
 209       Suffix_Index : Int       := 0;
 210       Prefix       : Character := ' ') return Name_Id;
 211    function New_External_Name
 212      (Related_Id   : Name_Id;
 213       Suffix       : String;
 214       Suffix_Index : Int       := 0;
 215       Prefix       : Character := ' ') return Name_Id;
 216    --  Builds a new entry in the names table of the form:
 217    --
 218    --    [Prefix  &] Related_Id [& Suffix] [& Suffix_Index]
 219    --
 220    --  Prefix is prepended only if Prefix is non-blank (in which case it
 221    --  must be an upper case letter other than O,Q,U,W (which are used for
 222    --  identifier encoding, see Namet), or an underscore, and T is reserved for
 223    --  use by implicit types, and X is reserved for use by debug type encoding
 224    --  (see package Exp_Dbug). Note: the reason that Prefix is last is that it
 225    --  is almost always omitted. The notable case of Prefix being non-null is
 226    --  when it is 'T' for an implicit type.
 227
 228    --  Suffix_Index'Image is appended only if the value of Suffix_Index is
 229    --  positive, or if Suffix_Index is negative 1, then a unique serialized
 230    --  suffix is added. If Suffix_Index is zero, then no index is appended.
 231
 232    --  Suffix is also a single upper case letter other than O,Q,U,W,X and is a
 233    --  required parameter (T is permitted). The constructed name is stored
 234    --  using Name_Find so that it can be located using a subsequent Name_Find
 235    --  operation (i.e. it is properly hashed into the names table). The upper
 236    --  case letter given as the Suffix argument ensures that the name does
 237    --  not clash with any Ada identifier name. These generated names are
 238    --  permitted, but not required, to be made public by setting the flag
 239    --  Is_Public in the associated entity.
 240
 241    function New_External_Name
 242      (Suffix       : Character;
 243       Suffix_Index : Nat) return Name_Id;
 244    --  Builds a new entry in the names table of the form
 245    --    Suffix & Suffix_Index'Image
 246    --  where Suffix is a single upper case letter other than O,Q,U,W,X and is
 247    --  a required parameter (T is permitted). The constructed name is stored
 248    --  using Name_Find so that it can be located using a subsequent Name_Find
 249    --  operation (i.e. it is properly hashed into the names table). The upper
 250    --  case letter given as the Suffix argument ensures that the name does
 251    --  not clash with any Ada identifier name. These generated names are
 252    --  permitted, but not required, to be made public by setting the flag
 253    --  Is_Public in the associated entity.
 254
 255    function New_Internal_Name (Id_Char : Character) return Name_Id;
 256    --  Id_Char is an upper case letter other than O,Q,U,W (which are reserved
 257    --  for identifier encoding (see Namet package for details) and X which is
 258    --  used for debug encoding (see Exp_Dbug). The letter T is permitted, but
 259    --  is reserved by convention for the case of internally generated types.
 260    --  The result of the call is a new generated unique name of the form XyyyU
 261    --  where X is Id_Char, yyy is a unique serial number, and U is either a
 262    --  lower case s or b indicating if the current unit is a spec or a body.
 263    --
 264    --  The name is entered into the names table using Name_Enter rather than
 265    --  Name_Find, because there can never be a need to locate the entry using
 266    --  the Name_Find procedure later on. Names created by New_Internal_Name
 267    --  are guaranteed to be consistent from one compilation to another (i.e.
 268    --  if the identical unit is compiled with a semantically consistent set
 269    --  of sources, the numbers will be consistent. This means that it is fine
 270    --  to use these as public symbols.
 271
 272    function New_Occurrence_Of
 273      (Def_Id : Entity_Id;
 274       Loc    : Source_Ptr) return Node_Id;
 275    --  New_Occurrence_Of creates an N_Identifier node which is an occurrence
 276    --  of the defining identifier which is passed as its argument. The Entity
 277    --  and Etype of the result are set from the given defining identifier as
 278    --  follows: Entity is simply a copy of Def_Id. Etype is a copy of Def_Id
 279    --  for types, and a copy of the Etype of Def_Id for other entities.
 280
 281    function New_Reference_To
 282      (Def_Id : Entity_Id;
 283       Loc    : Source_Ptr) return Node_Id;
 284    --  This is like New_Occurrence_Of, but it does not set the Etype field.
 285    --  It is used from the expander, where Etype fields are generally not set,
 286    --  since they are set when the expanded tree is reanalyzed.
 287
 288    function New_Suffixed_Name
 289      (Related_Id : Name_Id;
 290       Suffix     : String) return Name_Id;
 291    --  This function is used to create special suffixed names used by the
 292    --  debugger. Suffix is a string of upper case letters, used to construct
 293    --  the required name. For instance, the special type used to record the
 294    --  fixed-point small is called typ_SMALL where typ is the name of the
 295    --  fixed-point type (as passed in Related_Id), and Suffix is "SMALL".
 296
 297    function OK_Convert_To (Typ : Entity_Id; Expr : Node_Id) return Node_Id;
 298    --  Like Convert_To, except that a conversion node is always generated,
 299    --  and the Conversion_OK flag is set on this conversion node.
 300
 301    function Unchecked_Convert_To
 302      (Typ  : Entity_Id;
 303       Expr : Node_Id) return Node_Id;
 304    --  Like Convert_To, but if a conversion is actually needed, constructs
 305    --  an N_Unchecked_Type_Conversion node to do the required conversion.
 306
 307 end Tbuild;