gcc/ada/s-strcom.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --                S Y S T E M . S T R I N G _ C O M P A R E                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Warnings (Off);
  35 pragma Compiler_Unit;
  36 pragma Warnings (On);
  37
  38 with Ada.Unchecked_Conversion;
  39
  40 package body System.String_Compare is
  41
  42    type Word is mod 2 ** 32;
  43    --  Used to process operands by words
  44
  45    type Big_Words is array (Natural) of Word;
  46    type Big_Words_Ptr is access Big_Words;
  47    for Big_Words_Ptr'Storage_Size use 0;
  48    --  Array type used to access by words
  49
  50    type Byte is mod 2 ** 8;
  51    --  Used to process operands by bytes
  52
  53    type Big_Bytes is array (Natural) of Byte;
  54    type Big_Bytes_Ptr is access Big_Bytes;
  55    for Big_Bytes_Ptr'Storage_Size use 0;
  56    --  Array type used to access by bytes
  57
  58    function To_Big_Words is new
  59      Ada.Unchecked_Conversion (System.Address, Big_Words_Ptr);
  60
  61    function To_Big_Bytes is new
  62      Ada.Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  63
  64    -----------------
  65    -- Str_Compare --
  66    -----------------
  67
  68    function Str_Compare
  69      (Left      : System.Address;
  70       Right     : System.Address;
  71       Left_Len  : Natural;
  72       Right_Len : Natural) return Integer
  73    is
  74       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  75
  76    begin
  77       --  If operands are non-aligned, or length is too short, go by bytes
  78
  79       if (((Left or Right) and 2#11#) /= 0) or else Compare_Len < 4 then
  80          return Str_Compare_Bytes (Left, Right, Left_Len, Right_Len);
  81       end if;
  82
  83       --  Here we can go by words
  84
  85       declare
  86          LeftP  : constant Big_Words_Ptr := To_Big_Words (Left);
  87          RightP : constant Big_Words_Ptr := To_Big_Words (Right);
  88          Clen4  : constant Natural       := Compare_Len / 4 - 1;
  89          Clen4F : constant Natural       := Clen4 * 4;
  90
  91       begin
  92          for J in 0 .. Clen4 loop
  93             if LeftP (J) /= RightP (J) then
  94                return Str_Compare_Bytes
  95                         (Left  + Address (4 * J),
  96                          Right + Address (4 * J),
  97                          4, 4);
  98             end if;
  99          end loop;
 100
 101          return Str_Compare_Bytes
 102                   (Left      + Address (Clen4F),
 103                    Right     + Address (Clen4F),
 104                    Left_Len  - Clen4F,
 105                    Right_Len - Clen4F);
 106       end;
 107    end Str_Compare;
 108
 109    -----------------------
 110    -- Str_Compare_Bytes --
 111    -----------------------
 112
 113    function Str_Compare_Bytes
 114      (Left      : System.Address;
 115       Right     : System.Address;
 116       Left_Len  : Natural;
 117       Right_Len : Natural) return Integer
 118    is
 119       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 120
 121       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 122       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 123
 124    begin
 125       for J in 0 .. Compare_Len - 1 loop
 126          if LeftP (J) /= RightP (J) then
 127             if LeftP (J) > RightP (J) then
 128                return +1;
 129             else
 130                return -1;
 131             end if;
 132          end if;
 133       end loop;
 134
 135       if Left_Len = Right_Len then
 136          return 0;
 137       elsif Left_Len > Right_Len then
 138          return +1;
 139       else
 140          return -1;
 141       end if;
 142    end Str_Compare_Bytes;
 143
 144 end System.String_Compare;