gcc/ada/makeutl.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              M A K E U T L                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with ALI;
  27 with Namet; use Namet;
  28 with Opt;
  29 with Osint;
  30 with Prj;   use Prj;
  31 with Prj.Tree;
  32 with Types; use Types;
  33
  34 with GNAT.OS_Lib; use GNAT.OS_Lib;
  35
  36 package Makeutl is
  37
  38    type Fail_Proc is access procedure (S : String);
  39    Do_Fail : Fail_Proc := Osint.Fail'Access;
  40    --  Failing procedure called from procedure Test_If_Relative_Path below. May
  41    --  be redirected.
  42
  43    Project_Tree : constant Project_Tree_Ref := new Project_Tree_Data;
  44    --  The project tree
  45
  46    Subdirs_Option : constant String := "--subdirs=";
  47    --  Switch used to indicate that the real directories (object, exec,
  48    --  library, ...) are subdirectories of those in the project file.
  49
  50    procedure Add
  51      (Option : String_Access;
  52       To     : in out String_List_Access;
  53       Last   : in out Natural);
  54    procedure Add
  55      (Option : String;
  56       To     : in out String_List_Access;
  57       Last   : in out Natural);
  58    --  Add a string to a list of strings
  59
  60    function Create_Name (Name : String) return File_Name_Type;
  61    function Create_Name (Name : String) return Name_Id;
  62    function Create_Name (Name : String) return Path_Name_Type;
  63    --  Get the Name_Id of a name
  64
  65    function Executable_Prefix_Path return String;
  66    --  Return the absolute path parent directory of the directory where the
  67    --  current executable resides, if its directory is named "bin", otherwise
  68    --  return an empty string. When a directory is returned, it is guaranteed
  69    --  to end with a directory separator.
  70
  71    procedure Inform (N : Name_Id := No_Name; Msg : String);
  72    procedure Inform (N : File_Name_Type; Msg : String);
  73    --  Prints out the program name followed by a colon, N and S
  74
  75    function File_Not_A_Source_Of
  76      (Uname : Name_Id;
  77       Sfile : File_Name_Type) return Boolean;
  78    --  Check that file name Sfile is one of the source of unit Uname. Returns
  79    --  True if the unit is in one of the project file, but the file name is not
  80    --  one of its source. Returns False otherwise.
  81
  82    function Check_Source_Info_In_ALI (The_ALI : ALI.ALI_Id) return Boolean;
  83    --  Check whether all file references in ALI are still valid (ie the
  84    --  source files are still associated with the same units). Return True
  85    --  if everything is still valid
  86
  87    function Is_External_Assignment
  88      (Tree : Prj.Tree.Project_Node_Tree_Ref;
  89       Argv : String) return Boolean;
  90    --  Verify that an external assignment switch is syntactically correct
  91    --
  92    --  Correct forms are:
  93    --
  94    --      -Xname=value
  95    --      -X"name=other value"
  96    --
  97    --  Assumptions: 'First = 1, Argv (1 .. 2) = "-X"
  98    --
  99    --  When this function returns True, the external assignment has been
 100    --  entered by a call to Prj.Ext.Add, so that in a project file, External
 101    --  ("name") will return "value".
 102
 103    procedure Verbose_Msg
 104      (N1                : Name_Id;
 105       S1                : String;
 106       N2                : Name_Id := No_Name;
 107       S2                : String  := "";
 108       Prefix            : String  := "  -> ";
 109       Minimum_Verbosity : Opt.Verbosity_Level_Type := Opt.Low);
 110    procedure Verbose_Msg
 111      (N1                : File_Name_Type;
 112       S1                : String;
 113       N2                : File_Name_Type := No_File;
 114       S2                : String  := "";
 115       Prefix            : String  := "  -> ";
 116       Minimum_Verbosity : Opt.Verbosity_Level_Type := Opt.Low);
 117    --  If the verbose flag (Verbose_Mode) is set and the verbosity level is
 118    --  at least equal to Minimum_Verbosity, then print Prefix to standard
 119    --  output followed by N1 and S1. If N2 /= No_Name then N2 is printed after
 120    --  S1. S2 is printed last. Both N1 and N2 are printed in quotation marks.
 121    --  The two forms differ only in taking Name_Id or File_name_Type arguments.
 122
 123    function Linker_Options_Switches
 124      (Project  : Project_Id;
 125       In_Tree  : Project_Tree_Ref) return String_List;
 126    --  Collect the options specified in the Linker'Linker_Options attributes
 127    --  of project Project, in project tree In_Tree, and in the projects that
 128    --  it imports directly or indirectly, and returns the result.
 129
 130    --  Package Mains is used to store the mains specified on the command line
 131    --  and to retrieve them when a project file is used, to verify that the
 132    --  files exist and that they belong to a project file.
 133
 134    function Unit_Index_Of (ALI_File : File_Name_Type) return Int;
 135    --  Find the index of a unit in a source file. Return zero if the file is
 136    --  not a multi-unit source file.
 137
 138    package Mains is
 139
 140       --  Mains are stored in a table. An index is used to retrieve the mains
 141       --  from the table.
 142
 143       procedure Add_Main (Name : String);
 144       --  Add one main to the table
 145
 146       procedure Set_Location (Location : Source_Ptr);
 147       --  Set the location of the last main added. By default, the location is
 148       --  No_Location.
 149
 150       procedure Delete;
 151       --  Empty the table
 152
 153       procedure Reset;
 154       --  Reset the index to the beginning of the table
 155
 156       function Next_Main return String;
 157       --  Increase the index and return the next main. If table is exhausted,
 158       --  return an empty string.
 159
 160       function Get_Location return Source_Ptr;
 161       --  Get the location of the current main
 162
 163       procedure Update_Main (Name : String);
 164       --  Update the file name of the current main
 165
 166       function Number_Of_Mains return Natural;
 167       --  Returns the number of mains added with Add_Main since the last call
 168       --  to Delete.
 169
 170    end Mains;
 171
 172    procedure Test_If_Relative_Path
 173      (Switch               : in out String_Access;
 174       Parent               : String;
 175       Including_L_Switch   : Boolean := True;
 176       Including_Non_Switch : Boolean := True;
 177       Including_RTS        : Boolean := False);
 178    --  Test if Switch is a relative search path switch. If it is, fail if
 179    --  Parent is the empty string, otherwise prepend the path with Parent.
 180    --  This subprogram is only called when using project files. For gnatbind
 181    --  switches, Including_L_Switch is False, because the argument of the -L
 182    --  switch is not a path. If Including_RTS is True, process also switches
 183    --  --RTS=.
 184
 185    function Path_Or_File_Name (Path : Path_Name_Type) return String;
 186    --  Returns a file name if -df is used, otherwise return a path name
 187
 188    ----------------------
 189    -- Marking Routines --
 190    ----------------------
 191
 192    procedure Mark (Source_File : File_Name_Type; Index : Int := 0);
 193    --  Mark a unit, identified by its source file and, when Index is not 0, the
 194    --  index of the unit in the source file. Marking is used to signal that the
 195    --  unit has already been inserted in the Q.
 196
 197    function Is_Marked
 198      (Source_File : File_Name_Type;
 199       Index       : Int := 0) return Boolean;
 200    --  Returns True if the unit was previously marked
 201
 202    procedure Delete_All_Marks;
 203    --  Remove all file/index couples marked
 204
 205 end Makeutl;