libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:14:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # -fno-builtin must be present here so that a non-conflicting form of
  82 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  83
  84 save_CXXFLAGS="$CXXFLAGS"
  85 CXXFLAGS="$CXXFLAGS -fno-builtin"
  86 AC_PROG_CC
  87 AC_PROG_CXX
  88 CXXFLAGS="$save_CXXFLAGS"
  89
  90 # Runs configure.host, and assorted other critical bits.  Sets
  91 # up critical shell variables.
  92 GLIBCXX_CONFIGURE
  93
  94 if test "x${with_newlib}" != "xyes"; then
  95   AC_LIBTOOL_DLOPEN
  96 fi
  97 AM_PROG_LIBTOOL
  98 AC_SUBST(enable_shared)
  99 AC_SUBST(enable_static)
 100
 101 # Possibly disable most of the library.
 102 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 103 ## than just ignoring the results.  Faster /and/ more correct, win win.
 104 GLIBCXX_ENABLE_HOSTED
 105
 106 # Enable compiler support that doesn't require linking.
 107 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 108 GLIBCXX_ENABLE_PCH($is_hosted)
 109 GLIBCXX_ENABLE_THREADS
 110 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 111 GLIBCXX_ENABLE_DECIMAL_FLOAT
 112
 113 # Checks for compiler support that doesn't require linking.
 114 GLIBCXX_CHECK_COMPILER_FEATURES
 115
 116 # Enable all the variable C++ runtime options that don't require linking.
 117 GLIBCXX_ENABLE_CSTDIO
 118 GLIBCXX_ENABLE_CLOCALE
 119 GLIBCXX_ENABLE_ALLOCATOR
 120 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 121 GLIBCXX_ENABLE_LONG_LONG([yes])
 122 GLIBCXX_ENABLE_WCHAR_T([yes])
 123 GLIBCXX_ENABLE_C99([yes])
 124 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 125 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 126 GLIBCXX_ENABLE_DEBUG([no])
 127 GLIBCXX_ENABLE_PARALLEL([yes])
 128 GLIBCXX_ENABLE_CXX_FLAGS
 129 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 130
 131 # Checks for operating systems support that doesn't require linking.
 132 GLIBCXX_CHECK_SYSTEM_ERROR
 133
 134 # For the streamoff typedef.
 135 GLIBCXX_CHECK_INT64_T
 136
 137 # For LFS support.
 138 GLIBCXX_CHECK_LFS
 139
 140 # For showmanyc_helper().
 141 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 142 GLIBCXX_CHECK_POLL
 143 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 144
 145 # For xsputn_2().
 146 AC_CHECK_HEADERS(sys/uio.h)
 147 GLIBCXX_CHECK_WRITEV
 148
 149 # For C99 support to TR1.
 150 GLIBCXX_CHECK_C99_TR1
 151
 152 # For common values of EOF, SEEK_CUR, SEEK_END.
 153 GLIBCXX_CHECK_STDIO_MACROS
 154
 155 # For gettimeofday support.
 156 GLIBCXX_CHECK_GETTIMEOFDAY
 157
 158 # For clock_gettime, nanosleep and sched_yield support.
 159 # NB: The default is [no], because otherwise it requires linking.
 160 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 161
 162 # For gthread support
 163 GLIBCXX_CHECK_GTHREADS
 164
 165 AC_LC_MESSAGES
 166
 167 # Check for available headers.
 168 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 169 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 170 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 171 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 172 wchar.h wctype.h])
 173
 174 # Only do link tests if native. Else, hardcode.
 175 if $GLIBCXX_IS_NATIVE; then
 176
 177   # We can do more elaborate tests that assume a working linker.
 178   CANADIAN=no
 179
 180   GLIBCXX_CHECK_LINKER_FEATURES
 181   GLIBCXX_CHECK_MATH_SUPPORT
 182   GLIBCXX_CHECK_STDLIB_SUPPORT
 183
 184   # For /dev/random and /dev/urandom for TR1.
 185   GLIBCXX_CHECK_RANDOM_TR1
 186
 187   # For TLS support.
 188   GCC_CHECK_TLS
 189
 190   # For iconv support.
 191   AM_ICONV
 192
 193 else
 194
 195   # This lets us hard-code the functionality we know we'll have in the cross
 196   # target environment.  "Let" is a sugar-coated word placed on an especially
 197   # dull and tedious hack, actually.
 198   #
 199   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 200   # that involve linking, can't be used:
 201   #    "cannot open sim-crt0.o"
 202   #    "cannot open crt0.o"
 203   # etc.  All this is because there currently exists no unified, consistent
 204   # way for top level CC information to be passed down to target directories:
 205   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 206   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 207   # crosses can be removed.
 208
 209   # If Canadian cross, then don't pick up tools from the build directory.
 210   # Used only in GLIBCXX_EXPORT_INCLUDES.
 211   if test -n "$with_cross_host" &&
 212      test x"$build_alias" != x"$with_cross_host" &&
 213      test x"$build" != x"$target";
 214   then
 215     CANADIAN=yes
 216   else
 217     CANADIAN=no
 218   fi
 219
 220   # Construct crosses by hand, eliminating bits that need ld...
 221   # GLIBCXX_CHECK_MATH_SUPPORT
 222
 223   # First, test for "known" system libraries.  We may be using newlib even
 224   # on a hosted environment.
 225   if test "x${with_newlib}" = "xyes"; then
 226     os_include_dir="os/newlib"
 227     AC_DEFINE(HAVE_HYPOT)
 228
 229     # GLIBCXX_CHECK_STDLIB_SUPPORT
 230     AC_DEFINE(HAVE_STRTOF)
 231
 232     AC_DEFINE(HAVE_ACOSF)
 233     AC_DEFINE(HAVE_ASINF)
 234     AC_DEFINE(HAVE_ATAN2F)
 235     AC_DEFINE(HAVE_ATANF)
 236     AC_DEFINE(HAVE_CEILF)
 237     AC_DEFINE(HAVE_COSF)
 238     AC_DEFINE(HAVE_COSHF)
 239     AC_DEFINE(HAVE_EXPF)
 240     AC_DEFINE(HAVE_FABSF)
 241     AC_DEFINE(HAVE_FLOORF)
 242     AC_DEFINE(HAVE_FMODF)
 243     AC_DEFINE(HAVE_FREXPF)
 244     AC_DEFINE(HAVE_LDEXPF)
 245     AC_DEFINE(HAVE_LOG10F)
 246     AC_DEFINE(HAVE_LOGF)
 247     AC_DEFINE(HAVE_MODFF)
 248     AC_DEFINE(HAVE_POWF)
 249     AC_DEFINE(HAVE_SINF)
 250     AC_DEFINE(HAVE_SINHF)
 251     AC_DEFINE(HAVE_SQRTF)
 252     AC_DEFINE(HAVE_TANF)
 253     AC_DEFINE(HAVE_TANHF)
 254
 255     AC_DEFINE(HAVE_ICONV)
 256   else
 257     GLIBCXX_CROSSCONFIG
 258   fi
 259
 260   # At some point, we should differentiate between architectures
 261   # like x86, which have long double versions, and alpha/powerpc/etc.,
 262   # which don't. For the time being, punt.
 263   if test x"long_double_math_on_this_cpu" = x"yes"; then
 264     AC_DEFINE(HAVE_ACOSL)
 265     AC_DEFINE(HAVE_ASINL)
 266     AC_DEFINE(HAVE_ATAN2L)
 267     AC_DEFINE(HAVE_ATANL)
 268     AC_DEFINE(HAVE_CEILL)
 269     AC_DEFINE(HAVE_COSL)
 270     AC_DEFINE(HAVE_COSHL)
 271     AC_DEFINE(HAVE_EXPL)
 272     AC_DEFINE(HAVE_FABSL)
 273     AC_DEFINE(HAVE_FLOORL)
 274     AC_DEFINE(HAVE_FMODL)
 275     AC_DEFINE(HAVE_FREXPL)
 276     AC_DEFINE(HAVE_LDEXPL)
 277     AC_DEFINE(HAVE_LOG10L)
 278     AC_DEFINE(HAVE_LOGL)
 279     AC_DEFINE(HAVE_MODFL)
 280     AC_DEFINE(HAVE_POWL)
 281     AC_DEFINE(HAVE_SINCOSL)
 282     AC_DEFINE(HAVE_SINL)
 283     AC_DEFINE(HAVE_SINHL)
 284     AC_DEFINE(HAVE_SQRTL)
 285     AC_DEFINE(HAVE_TANL)
 286     AC_DEFINE(HAVE_TANHL)
 287   fi
 288 fi
 289
 290 # Check for _Unwind_GetIPInfo.
 291 GCC_CHECK_UNWIND_GETIPINFO
 292
 293
 294 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 295
 296 GCC_HEADER_STDINT(include/gstdint.h)
 297
 298 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 299 GLIBCXX_ENABLE_SYMVERS([yes])
 300 GLIBCXX_ENABLE_VISIBILITY([yes])
 301
 302 ac_ldbl_compat=no
 303 case "$target" in
 304   powerpc*-*-linux* | \
 305   powerpc*-*-gnu* | \
 306   sparc*-*-linux* | \
 307   s390*-*-linux* | \
 308   alpha*-*-linux*)
 309   AC_TRY_COMPILE(, [
 310 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 311 #error no need for long double compatibility
 312 #endif
 313   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 314   if test "$ac_ldbl_compat" = yes; then
 315     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 316               [Define if compatibility should be provided for -mlong-double-64.])
 317     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 318   fi
 319 esac
 320 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 321
 322 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 323 GLIBCXX_CONFIGURE_TESTSUITE
 324
 325 # Propagate the target-specific source directories through the build chain.
 326 ATOMICITY_SRCDIR=config/${atomicity_dir}
 327 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 328 ATOMIC_FLAGS=${atomic_flags}
 329 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 330 OS_INC_SRCDIR=config/${os_include_dir}
 331 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 332 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 333 AC_SUBST(ATOMICITY_SRCDIR)
 334 AC_SUBST(ATOMIC_WORD_SRCDIR)
 335 AC_SUBST(ATOMIC_FLAGS)
 336 AC_SUBST(CPU_DEFINES_SRCDIR)
 337 AC_SUBST(ABI_TWEAKS_SRCDIR)
 338 AC_SUBST(OS_INC_SRCDIR)
 339 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 340
 341
 342 # Determine cross-compile flags and AM_CONDITIONALs.
 343 #AC_SUBST(GLIBCXX_IS_NATIVE)
 344 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 345 GLIBCXX_EVALUATE_CONDITIONALS
 346
 347 AC_CACHE_SAVE
 348
 349 if test ${multilib} = yes; then
 350   multilib_arg="--enable-multilib"
 351 else
 352   multilib_arg=
 353 fi
 354
 355 # Export all the install information.
 356 GLIBCXX_EXPORT_INSTALL_INFO
 357
 358 # Export all the include and flag information to Makefiles.
 359 GLIBCXX_EXPORT_INCLUDES
 360 GLIBCXX_EXPORT_FLAGS
 361
 362 if test "$enable_shared" = yes; then
 363   LIBSUPCXX_PICFLAGS="-prefer-pic"
 364 else
 365   LIBSUPCXX_PICFLAGS=
 366 fi
 367 AC_SUBST(LIBSUPCXX_PICFLAGS)
 368
 369 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 370 dnl which can all be called multiple times as needed, plus one (different)
 371 dnl AC_OUTPUT macro.  This one lists the files to be created:
 372 AC_CONFIG_FILES(Makefile)
 373 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 374
 375 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 376 # that multilib installs will end up installed in the correct place.
 377 # The testsuite needs it for multilib-aware ABI baseline files.
 378 # To work around this not being passed down from config-ml.in ->
 379 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 380 # append it here.  Only modify Makefiles that have just been created.
 381 #
 382 # Also, get rid of this simulated-VPATH thing that automake does.
 383 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 384   [cat > vpsed$$ << \_EOF
 385 s!`test -f '$<' || echo '$(srcdir)/'`!!
 386 _EOF
 387    sed -f vpsed$$ $ac_file > tmp$$
 388    mv tmp$$ $ac_file
 389    rm vpsed$$
 390    echo 'MULTISUBDIR =' >> $ac_file
 391    ml_norecursion=yes
 392    . ${multi_basedir}/config-ml.in
 393    AS_UNSET([ml_norecursion])
 394 ])
 395
 396 AC_CONFIG_COMMANDS([generate-headers],
 397   [(cd include && ${MAKE-make} pch_build= )])
 398
 399 dnl And this actually makes things happen:
 400 AC_OUTPUT