libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # For libstdc++-v3, -fno-builtin must be present here so that a
 146 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 147 # used in later tests.  This may not be necessary in libjava; I don't know.
 148 save_CXXFLAGS="$CXXFLAGS"
 149 CXXFLAGS="$CXXFLAGS -fno-builtin"
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 CXXFLAGS="$save_CXXFLAGS"
 153
 154 AM_INIT_AUTOMAKE([1.9.0])
 155
 156 AC_CHECK_TOOL(AS, as)
 157 AC_CHECK_TOOL(LD, ld)
 158 AC_CHECK_TOOL(AR, ar)
 159 AC_CHECK_TOOL(RANLIB, ranlib, :)
 160 AC_PROG_AWK
 161 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 162 AC_PATH_PROG([ZIP], [zip], no)
 163 AC_PATH_PROG([UNZIP], [unzip], unzip)
 164
 165 # We need a jar that supports -@.  This is a GNU extension.
 166 if test "$JAR" != no; then
 167    rm -f config-test.jar
 168    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 169    if test -f config-test.jar; then
 170      rm -f config-test.jar
 171    else
 172      JAR=no
 173    fi
 174 fi
 175
 176 # Prefer the jar we found, but fall back to our jar script.
 177 if test "$JAR" = no; then
 178   if test "$ZIP" = no; then
 179     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 180   else
 181     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 182     JAR=`pwd`/scripts/jar
 183   fi
 184 fi
 185
 186 AC_PROG_INSTALL
 187
 188 AM_MAINTAINER_MODE
 189
 190 AC_EXEEXT
 191
 192 # configure.host sets the following important variables
 193 #       libgcj_cflags    - host specific C compiler flags
 194 #       libgcj_cxxflags  - host specific C++ compiler flags
 195 #       libgcj_javaflags - host specific Java compiler flags
 196 #       libgcj_sublib_ltflags - host specific Libtool flags
 197 #                          (only used when building sublibs)
 198 # and a number of others; see the list at the start of the file.
 199
 200 libgcj_cflags=
 201 libgcj_cxxflags=
 202 libgcj_javaflags=
 203 libgcj_sublib_ltflags=
 204
 205 . ${srcdir}/configure.host
 206
 207 ACX_PROG_LD_GNU_SYMBOLIC
 208 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 209 if test -z "$libgcj_ld_symbolic"; then
 210   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 211 fi
 212
 213 LIBGCJ_CFLAGS="${libgcj_cflags}"
 214 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 215 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 216 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 217 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 218 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 219 AC_SUBST(LIBGCJ_CFLAGS)
 220 AC_SUBST(LIBGCJ_CXXFLAGS)
 221 AC_SUBST(LIBGCJ_JAVAFLAGS)
 222 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 223 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 224 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 225
 226 # Only use libltdl for non-newlib builds.
 227 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 228    AC_LTDL_SHLIBPATH
 229 fi
 230
 231 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 232
 233 # Possibly build libgcj as many sub-libraries.
 234 AC_ARG_ENABLE(libgcj-sublibs,
 235   AS_HELP_STRING([--enable-libgcj-sublibs],
 236                  [build libgcj as many sub-libraries]))
 237
 238 if test -z "$enable_libgcj_sublibs"; then
 239    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 240 fi
 241 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 242 if test "$enable_libgcj_sublibs" = yes ; then
 243   # In theory we could make do with only one override and simply
 244   # tag "_bc" onto the end of it when we use it to generate the
 245   # spec, but that's an ugly thing to do when there are multiple
 246   # words in the string and you're relying on the ordering to
 247   # append the correct one.
 248   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 249   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 250 fi
 251
 252
 253 # See if the user has requested runtime debugging.
 254 LIBGCJDEBUG="disable"
 255 AC_SUBST(LIBGCJDEBUG)
 256 AC_ARG_ENABLE(libgcj-debug,
 257   AS_HELP_STRING([--enable-libgcj-debug],
 258                  [enable runtime debugging code]),
 259   [if test "$enable_libgcj_debug" = yes; then
 260     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 261     LIBGCJDEBUG="enable"
 262   fi])
 263
 264 AC_ARG_WITH([escher],
 265          AS_HELP_STRING([--with-escher=ABS.PATH],
 266                         [specify path to escher dir or JAR for X peers]))
 267 case "$with_escher" in
 268 "")
 269         use_escher=false
 270         ;;
 271 "no")
 272         use_escher=false
 273         ;;
 274 "yes")
 275         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 276         ;;
 277 *)
 278         use_escher=true
 279         ;;
 280 esac
 281
 282 # Determine which AWT peer libraries to build
 283 AC_ARG_ENABLE(java-awt,
 284   AS_HELP_STRING([--enable-java-awt],
 285                  [list of AWT peer implementations to be built]))
 286
 287 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 288 use_xlib_awt=""
 289 use_gtk_awt=""
 290 use_qt_awt=""
 291 use_x_awt=""
 292 # The default toolkit to use is the first one specified.
 293 TOOLKIT=
 294 AC_SUBST(TOOLKIT)
 295
 296 for peer in $peerlibs ; do
 297   case $peer in
 298     xlib)
 299       if test "$no_x" = yes; then
 300         echo "*** xlib peers requested but no X library available" 1>&2
 301         exit 1
 302       else
 303         use_xlib_awt="yes"
 304         if test -z "$TOOLKIT"; then
 305            TOOLKIT=gnu.awt.xlib.XToolkit
 306         fi
 307       fi
 308       ;;
 309     gtk)
 310       if test "$no_x" = yes; then
 311          echo "*** gtk peers requested but no X library available" 1>&2
 312          exit 1
 313       else
 314          use_gtk_awt=yes
 315          if test -z "$TOOLKIT"; then
 316             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 317          fi
 318       fi
 319       ;;
 320     qt)
 321       if test "$no_x" = yes; then
 322          # Perhaps we should admit the possibility of embedded Qt.
 323          echo "*** Qt peers requested but no X library available" 1>&2
 324          exit 1
 325       else
 326          use_qt_awt=yes
 327          if test -z "$TOOLKIT"; then
 328             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 329          fi
 330       fi
 331       ;;
 332     x)
 333       use_x_awt=yes
 334       if test -z "$TOOLKIT"; then
 335          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 336       fi
 337       ;;
 338     no)
 339       use_xlib_awt=
 340       use_gtk_awt=
 341       use_qt_awt=
 342       use_x_awt=
 343       break
 344       ;;
 345     *)
 346       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 347       exit 1
 348   esac
 349 done
 350
 351 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 352 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 353
 354 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 355
 356 expanded_prefix=$prefix
 357 if test "X$prefix" = XNONE; then
 358   expanded_prefix=${ac_default_prefix}
 359 fi
 360
 361 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 362
 363 # Create standard.omit based on decisions we just made.
 364 cp $srcdir/standard.omit.in standard.omit
 365 if test "$use_xlib_awt" != yes; then
 366    echo gnu/awt/xlib >> standard.omit
 367    echo gnu/gcj/xlib >> standard.omit
 368 fi
 369 if test "$use_x_awt" != yes; then
 370    echo gnu/java/awt/peer/x >> standard.omit
 371 fi
 372
 373 # Tools that need to be compiled against classpath's tools classes
 374 : > vm-tools-packages
 375 for package in gnu/gcj/tools/gc_analyze ; do
 376     echo $package >> standard.omit
 377     echo $package >> vm-tools-packages
 378 done
 379
 380 if test -z "${with_multisubdir}"; then
 381    builddotdot=.
 382 else
 383    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 384 fi
 385
 386 NATIVE=yes
 387
 388 # Which gcj and host gcj (for ecjx) do we use?
 389 which_gcj=default
 390 host_exeext=${ac_exeext}
 391 GCJ_FOR_ECJX=
 392 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 393 if test -n "${with_cross_host}"; then
 394   # We are being configured with a cross compiler. We can't
 395   # use ac_exeext, because that is for the target platform.
 396   NATIVE=no
 397   cross_host_exeext=
 398   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 399   case "${with_cross_host}" in
 400      *mingw* | *cygwin*)
 401          cross_host_exeext=.exe
 402      ;;
 403   esac
 404   host_exeext=${cross_host_exeext}
 405   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 406      if test x"$build_noncanonical" = x"$with_cross_host"; then
 407         # Ordinary cross (host!=target and host=build)
 408         which_gcj=built
 409      else
 410         # Canadian cross (host!=target and host!=build)
 411         which_gcj=cross
 412      fi
 413   else
 414      which_gcj=cross
 415   fi
 416 else
 417   # We are being configured with a native or crossed-native compiler
 418   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 419      if test x"$build" = x"$host"; then
 420         # True native build (host=target and host=build)
 421         which_gcj=built
 422      else
 423         # Crossed-native build (host=target and host!=build)
 424         which_gcj=cross
 425      fi
 426   else
 427      which_gcj=path
 428   fi
 429 fi
 430 libgcjdir=`${PWDCMD-pwd}`
 431 case $GCJ in
 432 *" -B"*)
 433   # Just in case there is a comma in the build dir, quote it for the
 434   # sed command below.
 435   case $libgcjdir in
 436   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 437   *) qlibgcjdir=$libgcjdir;;
 438   esac
 439   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 440   ;;
 441 *)
 442   GCJ=$GCJ" -B$libgcjdir/"
 443   ;;
 444 esac
 445 case "${which_gcj}" in
 446    built)
 447       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 448    ;;
 449    cross)
 450       if test "x${with_newlib}" = "xyes"; then
 451          # FIXME (comment): Why is this needed?
 452          GCC_UNWIND_INCLUDE=
 453       fi
 454       GCJH='$(target_noncanonical)-gcjh'
 455    ;;
 456    path)
 457       GCJH=gcjh
 458    ;;
 459 esac
 460 JAVAC="$GCJ -C"
 461 export JAVAC
 462
 463 AC_SUBST(GCJ_FOR_ECJX)
 464 AC_SUBST(GCJH)
 465 AC_SUBST(host_exeext)
 466
 467 # Create it, so that compile/link tests don't fail
 468 test -f libgcj.spec || touch libgcj.spec
 469
 470
 471
 472 # Set up to configure Classpath.
 473 # FIXME: no supported way to pass args in autoconf.
 474 # Disable tool wrappers to avoid ltdl.h configure check.
 475 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 476 ac_configure_args="$ac_configure_args --disable-load-library"
 477 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 478 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 479 dir1=`cd $srcdir && pwd`
 480 dir2=`pwd`
 481 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 482 ac_configure_args="$ac_configure_args --disable-core-jni"
 483 dnl FIXME?
 484 ac_configure_args="$ac_configure_args --disable-examples"
 485 ac_configure_args="$ac_configure_args --with-glibj=build"
 486 if test "$browser_plugin_enabled" != yes; then
 487   ac_configure_args="$ac_configure_args --disable-plugin"
 488 else
 489   ac_configure_args="$ac_configure_args --enable-plugin"
 490 fi
 491 if test "$gconf_enabled" != yes; then
 492   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 493   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 494 fi
 495 if test "$use_gtk_awt" != yes; then
 496   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 497 fi
 498 if test "$use_qt_awt" != yes; then
 499   ac_configure_args="$ac_configure_args --disable-qt-peer"
 500 else
 501   # We need this as qt is disabled by default in classpath.
 502   ac_configure_args="$ac_configure_args --enable-qt-peer"
 503 fi
 504 if test "$use_x_awt" != yes; then
 505   ac_configure_args="$ac_configure_args --without-escher"
 506 else
 507   # We need this as escher is disabled by default in classpath.
 508   if test "$use_escher" != true; then
 509     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 510   else
 511     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 512   fi
 513 fi
 514 if test "x$BUILD_GJDOC" = xno; then
 515   ac_configure_args="$ac_configure_args --disable-gjdoc"
 516 fi
 517 # -Werror causes unavoidable problems in code using alsa.
 518 ac_configure_args="$ac_configure_args --disable-regen-headers"
 519 ac_configure_args="$ac_configure_args --disable-Werror"
 520 dnl --with-gcj=$GCJ
 521 dnl --with-javah=$GCJH
 522 dnl gtk-cairo -- just export here...
 523 dnl --enable-regen-headers?
 524
 525 # Only use libltdl for non-newlib builds.
 526 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 527    AC_LIBLTDL_CONVENIENCE
 528    AC_LIBTOOL_DLOPEN
 529    DIRLTDL=libltdl
 530    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 531    # Sigh.  Libtool's macro doesn't do the right thing.
 532    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 533    # FIXME: this is a hack.
 534    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 535    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 536 fi
 537 AC_SUBST(INCLTDL)
 538 AC_SUBST(LIBLTDL)
 539 AC_SUBST(DIRLTDL)
 540 AC_PROG_LIBTOOL
 541 AM_PROG_GCJ
 542 AM_PROG_CC_C_O
 543
 544 AC_CONFIG_SUBDIRS(classpath libltdl)
 545
 546 # The -no-testsuite modules omit the test subdir.
 547 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 548
 549 # Should the runtime set system properties by examining the
 550 # environment variable GCJ_PROPERTIES?
 551 AC_ARG_ENABLE(getenv-properties,
 552   AS_HELP_STRING([--disable-getenv-properties],
 553                  [don't set system properties from GCJ_PROPERTIES]))
 554
 555 # Whether GCJ_PROPERTIES is used depends on the target.
 556 if test -z "$enable_getenv_properties"; then
 557    enable_getenv_properties=${enable_getenv_properties_default-yes}
 558 fi
 559 if test "$enable_getenv_properties" = no; then
 560    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 561      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 562 fi
 563
 564 # Whether we should use arguments to main()
 565 if test -z "$enable_main_args"; then
 566    enable_main_args=${enable_main_args_default-yes}
 567 fi
 568 if test "$enable_main_args" = no; then
 569    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 570 fi
 571
 572
 573 # Should we use hashtable-based synchronization?
 574 # Currently works only for Linux X86/ia64
 575 # Typically faster and more space-efficient
 576 AC_ARG_ENABLE(hash-synchronization,
 577   AS_HELP_STRING([--enable-hash-synchronization],
 578                  [use global hash table for monitor locks]))
 579
 580 if test -z "$enable_hash_synchronization"; then
 581    enable_hash_synchronization=$enable_hash_synchronization_default
 582 fi
 583
 584
 585 install_ecj_jar=no
 586 ECJ_BUILD_JAR=
 587 ECJ_JAR=
 588 AC_ARG_WITH(ecj-jar,
 589         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 590         [ECJ_JAR=$withval],
 591         [if test -f $multi_basedir/ecj.jar; then
 592            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 593            ECJ_JAR='$(jardir)/ecj.jar'
 594            install_ecj_jar=yes
 595          fi])
 596 AC_SUBST(ECJ_BUILD_JAR)
 597 AC_SUBST(ECJ_JAR)
 598 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 599 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 600
 601 AC_ARG_WITH(java-home,
 602   AS_HELP_STRING([--with-java-home=DIRECTORY],
 603                  [value of java.home system property]),
 604                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 605 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 606 AC_SUBST(JAVA_HOME)
 607
 608 suppress_libgcj_bc=no
 609 AC_ARG_ENABLE(libgcj-bc,
 610   AS_HELP_STRING([--enable-libgcj-bc],
 611                  [enable(default) or disable BC ABI for portions of libgcj]),
 612   [if test "$enable_libgcj_bc" = "no"; then
 613      suppress_libgcj_bc=yes
 614    fi])
 615 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 616
 617 build_libgcj_reduced_reflection=no
 618 AC_ARG_ENABLE(reduced-reflection,
 619   AS_HELP_STRING([--enable-reduced-reflection],
 620                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 621   [if test "$enable_reduced_reflection" = "yes"; then
 622      build_libgcj_reduced_reflection=yes
 623    fi])
 624 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 625
 626 # What is the native OS API for MinGW?
 627 AC_ARG_WITH(win32-nlsapi,
 628   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 629                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 630 [case "${withval}" in
 631   ansi) with_win32_nlsapi=ansi ;;
 632   unicows) with_win32_nlsapi=unicows ;;
 633   unicode) with_win32_nlsapi=unicode ;;
 634   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 635 esac],[with_win32_nlsapi=ansi])
 636
 637 case "${with_win32_nlsapi}" in
 638   unicows | unicode)
 639     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 640       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 641     ;;
 642 esac
 643
 644 # configure.host sets slow_pthread_self if the synchronization code should
 645 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 646 if test "${slow_pthread_self}" = "yes"; then
 647   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 648     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 649 fi
 650
 651 # Check for gc debugging.  This option is handled both here and in the GC.
 652 AC_ARG_ENABLE(gc-debug,
 653    AS_HELP_STRING([--enable-gc-debug],
 654                   [include full support for pointer backtracing etc.]),
 655 [ if test "$enable_gc_debug" = "yes"; then
 656     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 657               [Define if we want to use debug calls into the garbage collector.])
 658   fi])
 659
 660 # See if the user has the interpreter included.
 661 AC_ARG_ENABLE(interpreter,
 662   AS_HELP_STRING([--enable-interpreter],
 663                  [enable interpreter]),
 664   [if test "$enable_interpreter" = yes; then
 665     # This can also be set in configure.host.
 666     libgcj_interpreter=yes
 667   elif test "$enable_interpreter" = no; then
 668     libgcj_interpreter=no
 669   fi])
 670
 671 if test "$libgcj_interpreter" = yes; then
 672    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 673 fi
 674 INTERPRETER="$libgcj_interpreter"
 675 AC_SUBST(INTERPRETER)
 676 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 677
 678 AC_MSG_CHECKING([for exception model to use])
 679 AC_LANG_PUSH(C++)
 680 AC_ARG_ENABLE(sjlj-exceptions,
 681   AS_HELP_STRING([--enable-sjlj-exceptions],
 682                  [force use of builtin_setjmp for exceptions]),
 683 [:],
 684 [dnl Botheration.  Now we've got to detect the exception model.
 685 dnl Link tests against libgcc.a are problematic since -- at least
 686 dnl as of this writing -- we've not been given proper -L bits for
 687 dnl single-tree newlib and libgloss.
 688 dnl
 689 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 690 dnl conftest files before we got a change to grep them first.
 691 cat > conftest.$ac_ext << EOF
 692 [#]line __oline__ "configure"
 693 struct S { ~S(); };
 694 void bar();
 695 void foo()
 696 {
 697   S s;
 698   bar();
 699 }
 700 EOF
 701 old_CXXFLAGS="$CXXFLAGS"
 702 CXXFLAGS=-S
 703 if AC_TRY_EVAL(ac_compile); then
 704   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 705     enable_sjlj_exceptions=yes
 706   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 707     enable_sjlj_exceptions=no
 708   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 709     # ARM EH ABI.
 710     enable_sjlj_exceptions=no
 711   fi
 712 fi
 713 CXXFLAGS="$old_CXXFLAGS"
 714 rm -f conftest*])
 715 if test x$enable_sjlj_exceptions = xyes; then
 716   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 717         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 718   ac_exception_model_name=sjlj
 719 elif test x$enable_sjlj_exceptions = xno; then
 720   ac_exception_model_name="call frame"
 721 else
 722   AC_MSG_ERROR([unable to detect exception model])
 723 fi
 724 AC_LANG_POP(C++)
 725 AC_MSG_RESULT($ac_exception_model_name)
 726
 727 # If we are non using SJLJ exceptions, and this host does not have support
 728 # for unwinding from a signal handler, enable checked dereferences and divides.
 729 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 730   CHECKREFSPEC=-fcheck-references
 731   DIVIDESPEC=-fuse-divide-subroutine
 732   EXCEPTIONSPEC=
 733 fi
 734
 735 # See if the user wants to disable java.net.  This is the mildly
 736 # ugly way that we admit that target-side configuration sucks.
 737 AC_ARG_ENABLE(java-net,
 738   AS_HELP_STRING([--disable-java-net],
 739                  [disable java.net]))
 740
 741 # Whether java.net is built by default can depend on the target.
 742 if test -z "$enable_java_net"; then
 743    enable_java_net=${enable_java_net_default-yes}
 744 fi
 745 if test "$enable_java_net" = no; then
 746    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 747 fi
 748
 749 # See if the user wants to configure without libffi.  Some
 750 # architectures don't support it, and default values are set in
 751 # configure.host.
 752 AC_ARG_WITH(libffi,
 753   AS_HELP_STRING([--without-libffi],
 754                  [don't use libffi]),
 755   [:],
 756   [with_libffi=${with_libffi_default-yes}])
 757
 758 LIBFFI=
 759 LIBFFIINCS=
 760 if test "$with_libffi" != no; then
 761    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 762    LIBFFI=../libffi/libffi_convenience.la
 763    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 764 fi
 765 AC_SUBST(LIBFFI)
 766 AC_SUBST(LIBFFIINCS)
 767
 768 # See if the user wants to disable JVMPI support.
 769 AC_ARG_ENABLE(jvmpi,
 770   AS_HELP_STRING([--disable-jvmpi],
 771                  [disable JVMPI support]))
 772
 773 if test "$enable_jvmpi" != no; then
 774     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 775 fi
 776
 777 # If the target is an eCos system, use the appropriate eCos
 778 # I/O routines.
 779 # FIXME: this should not be a local option but a global target
 780 # system; at present there is no eCos target.
 781 TARGET_ECOS=${PROCESS-"no"}
 782 AC_ARG_WITH(ecos,
 783 [  --with-ecos             enable runtime eCos target support],
 784 TARGET_ECOS="$with_ecos"
 785 )
 786
 787 case "$TARGET_ECOS" in
 788    no) case "$host" in
 789       *mingw*)
 790             PLATFORM=Win32
 791             PLATFORMNET=Win32
 792             PLATFORMH=win32.h
 793         CHECK_FOR_BROKEN_MINGW_LD
 794       ;;
 795       *)
 796             PLATFORM=Posix
 797             PLATFORMNET=Posix
 798             PLATFORMH=posix.h
 799       ;;
 800       esac
 801       ;;
 802    *)
 803       PLATFORM=Ecos
 804       PLATFORMNET=NoNet
 805       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 806       PLATFORMH=posix.h
 807       ;;
 808 esac
 809 AC_SUBST(PLATFORM)
 810 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 811
 812 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 813                                       [Define if you have int32_t and uint32_t.]))
 814 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 815                                         [Define if you have int32_t and uint32_t.]))
 816 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 817                                           [Define if you have u_int32_t]))
 818 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 819                                            [Define if you have u_int32_t]))
 820
 821 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 822 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 823
 824 case "$host" in
 825   *-darwin*) DARWIN_CRT=true ;;
 826   *) DARWIN_CRT=false ;;
 827 esac
 828 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 829
 830 # This may not be defined in a non-ANS conformant embedded system.
 831 # FIXME: Should these case a runtime exception in that case?
 832 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 833                                   [Define is you have 'localtime' in <time.h>]))
 834
 835 # Create the subdirectory for natFile.cc, or the attempt
 836 # to create the link will fail.
 837 test -d java || mkdir java
 838 test -d java/io || mkdir java/io
 839 test -d gnu || mkdir gnu
 840 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 841
 842 # Likewise for natConcreteProcess.cc.
 843 test -d java/lang || mkdir java/lang
 844 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 845
 846 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 847 test -d java/net || mkdir java/net
 848 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 849 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 850
 851 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 852 test -d gnu/java || mkdir gnu/java
 853 test -d gnu/java/net || mkdir gnu/java/net
 854 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 855 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 856
 857 # Likewise for natVMPipe.cc and natVMSelector.cc.
 858 test -d gnu/java/nio || mkdir gnu/java/nio
 859 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 860 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 861
 862 # Likewise for natFileChannelImpl.cc
 863 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 864 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 865
 866 # Likewise for natVMSecureRandom.cc
 867 test -d gnu/java/security || mkdir gnu/java/security
 868 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 869 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 870 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 871
 872 case "${host}" in
 873     *mingw*)
 874       SYSTEMSPEC="-lgdi32 -lws2_32"
 875       if test "${with_win32_nlsapi}" = "unicows"; then
 876         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 877       fi
 878     ;;
 879     *-*-darwin[[912]]*)
 880       SYSTEMSPEC="-allow_stack_execute"
 881     ;;
 882     *)
 883       SYSTEMSPEC=
 884     ;;
 885 esac
 886 AC_SUBST(SYSTEMSPEC)
 887
 888 AC_ARG_WITH(system-zlib,
 889   AS_HELP_STRING([--with-system-zlib],
 890                  [use installed libz]))
 891 ZLIBSPEC=
 892 AC_SUBST(ZLIBSPEC)
 893 ZLIBTESTSPEC=
 894 AC_SUBST(ZLIBTESTSPEC)
 895
 896 AC_PATH_XTRA
 897
 898 # FIXME: this should be _libs on some hosts.
 899 libsubdir=.libs
 900
 901 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 902
 903 LIBSTDCXXSPEC=
 904 # extra LD Flags which are required for targets
 905 case "${host}" in
 906 *-*-darwin[[0-7]].*)
 907     # For now we have to disable it on darwin[8-9] because it slows down
 908     # the linking phase. A possible bug in ld?
 909     # on Darwin -single_module speeds up loading of the dynamic libraries.
 910     extra_ldflags_libjava=-Wl,-single_module
 911     ;;
 912 arm*linux*eabi)
 913     # Some of the ARM unwinder code is actually in libstdc++.  We
 914     # could in principle replicate it in libgcj, but it's better to
 915     # have a dependency on libstdc++.
 916     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 917     LIBSTDCXXSPEC=-lstdc++
 918     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 919     ;;
 920 *-*-cygwin)
 921     extra_ldflags_libjava=-liconv
 922     ;;
 923 esac
 924 AC_SUBST(extra_ldflags_libjava)
 925 AC_SUBST(extra_ldflags)
 926 AC_SUBST(LIBSTDCXXSPEC)
 927
 928 AC_SUBST(LIBGCJTESTSPEC)
 929
 930 # Allow the GC to be disabled.  Can be useful when debugging.
 931 AC_MSG_CHECKING([for garbage collector to use])
 932 AC_ARG_ENABLE(java-gc,
 933   AS_HELP_STRING([--enable-java-gc=TYPE],
 934                  [choose garbage collector (default is boehm)]),
 935   [GC=$enableval],
 936   [GC=boehm])
 937 GCLIBS=
 938 GCINCS=
 939 GCDEPS=
 940 GCSPEC=
 941 JC1GCSPEC=
 942 GCTESTSPEC=
 943 case "$GC" in
 944  boehm)
 945     AC_MSG_RESULT(boehm)
 946     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 947     JC1GCSPEC='-fuse-boehm-gc'
 948     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 949     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 950     GCOBJS=boehm.lo
 951     GCHDR=boehm-gc.h
 952     # The POSIX thread support needs to know this.
 953     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 954     ;;
 955  no)
 956     AC_MSG_RESULT(none)
 957     GCHDR=no-gc.h
 958     ;;
 959  *)
 960     AC_MSG_ERROR([unrecognized collector "$GC"])
 961     ;;
 962 esac
 963 AC_SUBST(GCLIBS)
 964 AC_SUBST(GCINCS)
 965 AC_SUBST(GCDEPS)
 966 AC_SUBST(GCSPEC)
 967 AC_SUBST(JC1GCSPEC)
 968 AC_SUBST(GCTESTSPEC)
 969 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 970 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 971 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 972
 973
 974 AC_MSG_CHECKING([for thread model used by GCC])
 975 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 976 AC_MSG_RESULT([$THREADS])
 977
 978 case "$THREADS" in
 979  no | none | single)
 980     THREADS=none
 981     ;;
 982  aix | posix | posix95 | pthreads)
 983     THREADS=posix
 984     case "$host" in
 985      *-*-linux*)
 986         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 987         ;;
 988     esac
 989     ;;
 990  win32)
 991     ;;
 992  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 993     AC_MSG_ERROR(thread package $THREADS not yet supported)
 994     ;;
 995  *)
 996     AC_MSG_ERROR($THREADS is an unknown thread package)
 997     ;;
 998 esac
 999
1000 THREADCXXFLAGS=
1001 THREADLDFLAGS=
1002 THREADLIBS=
1003 THREADINCS=
1004 THREADDEPS=
1005 THREADH=
1006 THREADSPEC=
1007 THREADSTARTFILESPEC=
1008 case "$THREADS" in
1009  posix)
1010     case "$host" in
1011      *-*-cygwin*)
1012         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1013         ;;
1014      *-*-freebsd[[1234]]*)
1015         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1016         # merely adds pthread_* functions) but it does have a -pthread switch
1017         # which is required at link-time to select -lc_r *instead* of -lc.
1018         THREADLDFLAGS=-pthread
1019         # Don't set THREADSPEC here as might be expected since -pthread is
1020         # not processed when found within a spec file, it must come from
1021         # the command line.  For now, the user must provide the -pthread
1022         # switch to link code compiled with gcj.  In future, consider adding
1023         # support for weak references to pthread_* functions ala gthr.h API.
1024         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1025         ;;
1026      *-*-freebsd*)
1027         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1028         # systems which support threads and -lpthread.
1029         THREADLDFLAGS=-pthread
1030         THREADSPEC=-lpthread
1031         ;;
1032      alpha*-dec-osf* | hppa*-hp-hpux*)
1033         THREADCXXFLAGS=-pthread
1034         # boehm-gc needs some functions from librt, so link that too.
1035         THREADLIBS='-lpthread -lrt'
1036         THREADSPEC='-lpthread -lrt'
1037         ;;
1038      *)
1039         THREADLIBS=-lpthread
1040         THREADSPEC=-lpthread
1041         ;;
1042     esac
1043     THREADH=posix-threads.h
1044     # MIT pthreads doesn't seem to have the mutexattr functions.
1045     # But for now we don't check for it.  We just assume you aren't
1046     # using MIT pthreads.
1047     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1048
1049     # If we're using the Boehm GC, then we happen to know that it
1050     # defines _REENTRANT, so we don't bother.  Eww.
1051     if test "$GC" != boehm; then
1052        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1053     fi
1054     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1055     ;;
1056
1057  win32)
1058     THREADH=win32-threads.h
1059     THREADCXXFLAGS=-mthreads
1060     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1061     # But we do not want the executables created to be dependent on
1062     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1063     # exception handling contexts.  The following kludge achieves this effect
1064     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1065     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1066     # A workaround is to explicitly use -mthreads while linking Java programs.
1067     # See PR libgcj/28263.
1068     #
1069     # FIXME: In Java we are able to detect thread death at the end of
1070     # Thread.run() so we should be able to clean up the exception handling
1071     # contexts ourselves.
1072     THREADSTARTFILESPEC='crtmt%O%s'
1073     ;;
1074
1075  none)
1076     THREADH=no-threads.h
1077     ;;
1078 esac
1079 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1080 AC_SUBST(THREADLIBS)
1081 AC_SUBST(THREADINCS)
1082 AC_SUBST(THREADDEPS)
1083 AC_SUBST(THREADSPEC)
1084 AC_SUBST(THREADSTARTFILESPEC)
1085 AC_SUBST(THREADLDFLAGS)
1086 AC_SUBST(THREADCXXFLAGS)
1087 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1088 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1089 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1090 if test "$enable_shared" != yes; then
1091   use_libgcj_bc=no
1092 fi
1093 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1094
1095 if test -d sysdep; then true; else mkdir sysdep; fi
1096 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1097 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1098 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1099
1100 LIBGCJ_SPEC_LGCJ=-lgcj
1101 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1102 if test x"$libgcj_spec_lgcj_override" != x ; then
1103   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1104 fi
1105 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1106   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1107 fi
1108 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1109 if test "$use_libgcj_bc" = yes; then
1110   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1111   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1112 fi
1113 AC_SUBST(LIBGCJ_SPEC)
1114 AC_SUBST(LIBGCJ_BC_SPEC)
1115
1116 HASH_SYNC_SPEC=
1117 # Hash synchronization is only useful with posix threads right now.
1118 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1119    HASH_SYNC_SPEC=-fhash-synchronization
1120    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1121 fi
1122 AC_SUBST(HASH_SYNC_SPEC)
1123
1124 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1125
1126 # We're in the tree with gcc, and need to include some of its headers.
1127 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1128
1129 if test "x${with_newlib}" = "xyes"; then
1130    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1131    # may not work correctly, because the compiler may not be able to
1132    # link executables.
1133
1134    # We assume newlib.  This lets us hard-code the functions we know
1135    # we'll have.
1136    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1137    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1138    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1139    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1140    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1141    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1142    # This is only for POSIX threads.
1143    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1144
1145    # Assume we do not have getuid and friends.
1146    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1147    PLATFORMNET=NoNet
1148 else
1149    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1150                    localtime_r getpwuid_r getcwd \
1151                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1152                    nl_langinfo setlocale \
1153                    inet_pton uname inet_ntoa \
1154                    getrlimit sigaction ftruncate mmap \
1155                    getifaddrs])
1156    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1157    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1158    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1159    AC_CHECK_LIB(dl, dladdr, [
1160        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1161        AC_CHECK_LIB(dld, dladdr, [
1162        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1163
1164    if test x"$cross_compiling" = x"no"; then
1165      AC_CHECK_FILES(/proc/self/exe, [
1166        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1167      AC_CHECK_FILES(/proc/self/maps, [
1168        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1169          [Define if you have /proc/self/maps])])
1170    else
1171      case $host in
1172      *-linux*)
1173        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1174        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1175        ;;
1176      esac
1177    fi
1178
1179    AM_ICONV
1180    AM_LC_MESSAGES
1181    AC_STRUCT_TIMEZONE
1182
1183    AC_CHECK_FUNCS(gethostbyname_r, [
1184      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1185        [Define if you have the 'gethostbyname_r' function.])
1186      # There are two different kinds of gethostbyname_r.
1187      # We look for the one that returns `int'.
1188      # Hopefully this check is robust enough.
1189      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1190        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1191
1192      case " $GCINCS " in
1193      *" -D_REENTRANT "*) ;;
1194      *)
1195         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1196         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1197         [libjava_cv_gethostbyname_r_needs_reentrant],
1198         [ AC_LANG_PUSH(C++)
1199           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1200             [[gethostbyname_r("", 0, 0);]])],
1201             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1202                 CPPFLAGS_SAVE="$CPPFLAGS"
1203                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1204                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1205                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1206                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1207                 CPPFLAGS="$CPPFLAGS_SAVE"
1208           ])
1209           AC_LANG_POP(C++)
1210         ])
1211         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1212           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1213         fi
1214      ;;
1215      esac
1216
1217      AC_CACHE_CHECK([for struct hostent_data],
1218         [libjava_cv_struct_hostent_data], [dnl
1219         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1220 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1221 # define _REENTRANT 1
1222 #endif
1223 #include <netdb.h>]], [[struct hostent_data data;]])],
1224           [libjava_cv_struct_hostent_data=yes],
1225           [libjava_cv_struct_hostent_data=no])])
1226      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1227        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1228          [Define if struct hostent_data is defined in netdb.h])
1229      fi
1230    ])
1231
1232    # FIXME: libjava source code expects to find a prototype for
1233    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1234    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1235    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1236    # linkage check is enough, yet C++ code requires proper prototypes.)
1237    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1238    AC_CHECK_FUNCS(gethostbyaddr_r, [
1239      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1240        [Define if you have the 'gethostbyaddr_r' function.])
1241      # There are two different kinds of gethostbyaddr_r.
1242      # We look for the one that returns `int'.
1243      # Hopefully this check is robust enough.
1244      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1245        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1246          [Define if gethostbyaddr_r returns 'int'.])])])])
1247
1248    AC_CHECK_FUNCS(gethostname, [
1249      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1250        [Define if you have the 'gethostname' function.])
1251      AC_EGREP_HEADER(gethostname, unistd.h, [
1252        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1253          [Define if gethostname is declared in <unistd.h>.])])])
1254
1255    AC_CHECK_FUNCS(usleep, [
1256      AC_EGREP_HEADER(usleep, unistd.h, [
1257        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1258           [Define if usleep is declared in <unistd.h>.])])])
1259
1260    # Look for these functions in the thread library, but only bother
1261    # if using POSIX threads.
1262    if test "$THREADS" = posix; then
1263       save_LIBS="$LIBS"
1264       LIBS="$LIBS $THREADLIBS"
1265
1266       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1267       # Solaris 7 the name librt is preferred.
1268       AC_CHECK_FUNCS(sched_yield, , [
1269         AC_CHECK_LIB(rt, sched_yield, [
1270           AC_DEFINE(HAVE_SCHED_YIELD)
1271           THREADLIBS="$THREADLIBS -lrt"
1272           THREADSPEC="$THREADSPEC -lrt"], [
1273           AC_CHECK_LIB(posix4, sched_yield, [
1274             AC_DEFINE(HAVE_SCHED_YIELD)
1275             THREADLIBS="$THREADLIBS -lposix4"
1276             THREADSPEC="$THREADSPEC -lposix4"])])])
1277
1278       AC_CHECK_LIB(rt, clock_gettime, [
1279          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1280          case "$THREADSPEC" in
1281            *-lrt*) ;;
1282            *)
1283              THREADSPEC="$THREADSPEC -lrt"
1284              THREADLIBS="$THREADLIBS -lrt"
1285              ;;
1286          esac])
1287
1288       LIBS="$save_LIBS"
1289
1290       # We can save a little space at runtime if the mutex has m_count
1291       # or __m_count.  This is a nice hack for Linux.
1292       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1293           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1294         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1295              [Define if pthread_mutex_t has m_count member.]), [
1296         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1297             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1298           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1299             [Define if pthread_mutex_t has __m_count member.]))])
1300    fi
1301
1302    # We require a way to get the time.
1303    time_found=no
1304    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1305    if test "$time_found" = no; then
1306       AC_MSG_ERROR([no function found to get the time])
1307    fi
1308
1309    AC_CHECK_FUNCS(memmove)
1310
1311    # We require memcpy.
1312    memcpy_found=no
1313    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1314    if test "$memcpy_found" = no; then
1315       AC_MSG_ERROR([memcpy is required])
1316    fi
1317    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1318    AC_CHECK_LIB(dl, dlopen, [
1319        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1320        AC_CHECK_LIB(dld, dlopen, [
1321        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1322
1323    # Some library-finding code we stole from Tcl.
1324    #--------------------------------------------------------------------
1325    #    Check for the existence of the -lsocket and -lnsl libraries.
1326    #    The order here is important, so that they end up in the right
1327    #    order in the command line generated by make.  Here are some
1328    #    special considerations:
1329    #    1. Use "connect" and "accept" to check for -lsocket, and
1330    #       "gethostbyname" to check for -lnsl.
1331    #    2. Use each function name only once:  can't redo a check because
1332    #       autoconf caches the results of the last check and won't redo it.
1333    #    3. Use -lnsl and -lsocket only if they supply procedures that
1334    #       aren't already present in the normal libraries.  This is because
1335    #       IRIX 5.2 has libraries, but they aren't needed and they're
1336    #       bogus:  they goof up name resolution if used.
1337    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1338    #       To get around this problem, check for both libraries together
1339    #       if -lsocket doesn't work by itself.
1340    #--------------------------------------------------------------------
1341
1342    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1343     [gcj_cv_lib_sockets=
1344      gcj_checkBoth=0
1345      unset ac_cv_func_connect
1346      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1347      if test "$gcj_checkSocket" = 1; then
1348          unset ac_cv_func_connect
1349          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1350                       gcj_checkBoth=1)
1351      fi
1352      if test "$gcj_checkBoth" = 1; then
1353          gcj_oldLibs=$LIBS
1354          LIBS="$LIBS -lsocket -lnsl"
1355          unset ac_cv_func_accept
1356          AC_CHECK_FUNC(accept,
1357                        [gcj_checkNsl=0
1358                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1359          unset ac_cv_func_accept
1360          LIBS=$gcj_oldLibs
1361      fi
1362      unset ac_cv_func_gethostbyname
1363      gcj_oldLibs=$LIBS
1364      LIBS="$LIBS $gcj_cv_lib_sockets"
1365      AC_CHECK_FUNC(gethostbyname, ,
1366                    [AC_CHECK_LIB(nsl, main,
1367                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1368      unset ac_cv_func_gethostbyname
1369      LIBS=$gcj_oldLIBS
1370    ])
1371    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1372
1373    if test "$with_system_zlib" = yes; then
1374       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1375    fi
1376
1377    # Test for Gtk stuff, if asked for.
1378    if test "$use_gtk_awt" = yes; then
1379       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1380       AC_SUBST(GTK_CFLAGS)
1381       AC_SUBST(GTK_LIBS)
1382
1383       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1384       AC_SUBST(GLIB_CFLAGS)
1385       AC_SUBST(GLIB_LIBS)
1386
1387       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1388       AC_SUBST(LIBART_CFLAGS)
1389       AC_SUBST(LIBART_LIBS)
1390
1391       # We require the XTest Extension to support java.awt.Robot.
1392       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1393                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1394                    [${X_LIBS}])
1395    fi
1396
1397    # On Solaris, and maybe other architectures, the Boehm collector
1398    # requires -ldl.
1399    if test "$GC" = boehm; then
1400       case "${host}" in
1401           mips-sgi-irix6*)
1402             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1403             # libgcj.spec is used, so override here
1404             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1405           ;;
1406           *)
1407             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1408           ;;
1409       esac
1410    fi
1411 fi
1412
1413 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1414 case $build in
1415     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1416     *)         CLASSPATH_SEPARATOR=':' ;;
1417 esac
1418 AC_SUBST(CLASSPATH_SEPARATOR)
1419
1420 # We must search the source tree for java.lang, since we still don't
1421 # have libgcj.jar nor java/lang/*.class
1422 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1423 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1424
1425 # Since some classes depend on this one, we need its source available
1426 # before we can do any GCJ compilation test :-(
1427 if test ! -f gnu/classpath/Configuration.java; then
1428   test -d gnu || mkdir gnu
1429   test -d gnu/classpath || mkdir gnu/classpath
1430   # Note that it is not crucial that all the values here be correct.
1431   sed -e "s,@prefix@,$expanded_prefix," \
1432       -e "s,@VERSION@,$VERSION," \
1433       -e "s,@LIBDEBUG@,false," \
1434       -e "s,@INIT_LOAD_LIBRARY@,false," \
1435       -e "s,@@,$LIBGCJDEBUG," \
1436       -e "s,@default_toolkit@,$TOOLKIT," \
1437       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1438       -e "s,@GTK_CAIRO_ENABLED@,false," \
1439       -e "s,@ECJ_JAR@,," \
1440       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1441         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1442         > gnu/classpath/Configuration.java
1443   # We do not want to redirect the output of the grep below to /dev/null,
1444   # but we add /dev/null to the input list so that grep will print the
1445   # filename of Configuration.java in case it finds any matches.
1446   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1447     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1448   fi
1449 fi
1450
1451 LT_AC_PROG_GCJ
1452
1453 # Now remove it.
1454 rm -f gnu/classpath/Configuration.java
1455
1456 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1457
1458 AC_CHECK_SIZEOF(void *)
1459
1460 AC_C_BIGENDIAN
1461
1462 ZLIBS=
1463 SYS_ZLIBS=
1464 ZINCS=
1465
1466 if test -z "$ZLIBSPEC"; then
1467    # Use zlib from the GCC tree.
1468    ZINCS='-I$(top_srcdir)/../zlib'
1469    ZLIBS=../zlib/libzgcj_convenience.la
1470 else
1471    # System's zlib.
1472    SYS_ZLIBS="$ZLIBSPEC"
1473 fi
1474 AC_SUBST(ZLIBS)
1475 AC_SUBST(SYS_ZLIBS)
1476 AC_SUBST(ZINCS)
1477 AC_SUBST(DIVIDESPEC)
1478 AC_SUBST(CHECKREFSPEC)
1479 AC_SUBST(EXCEPTIONSPEC)
1480 AC_SUBST(BACKTRACESPEC)
1481 AC_SUBST(IEEESPEC)
1482 AC_SUBST(ATOMICSPEC)
1483
1484 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1485 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1486 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1487 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1488 AC_SUBST(GCC_UNWIND_INCLUDE)
1489
1490 # Process the option "--enable-version-specific-runtime-libs"
1491 # Calculate toolexeclibdir
1492 case ${version_specific_libs} in
1493   yes)
1494     # Need the gcc compiler version to know where to install libraries
1495     # and header files if --enable-version-specific-runtime-libs option
1496     # is selected.
1497     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1498     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1499     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1500     toolexeclibdir=$toolexecmainlibdir
1501     ;;
1502   no)
1503     if test -n "$with_cross_host" &&
1504        test x"$with_cross_host" != x"no"; then
1505       # Install a library built with a cross compiler in tooldir, not libdir.
1506       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1507       toolexecmainlibdir='$(toolexecdir)/lib'
1508     else
1509       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1510       toolexecmainlibdir='$(libdir)'
1511     fi
1512     multi_os_directory=`$CC -print-multi-os-directory`
1513     case $multi_os_directory in
1514       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1515       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1516     esac
1517     ;;
1518 esac
1519 AC_SUBST(toolexecdir)
1520 AC_SUBST(toolexecmainlibdir)
1521 AC_SUBST(toolexeclibdir)
1522
1523 # Determine gcj and libgcj version number.
1524 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1525 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1526 GCJVERSION=$gcjversion
1527 AC_SUBST(GCJVERSION)
1528 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1529
1530 # Determine where the standard .db file and GNU Classpath JNI
1531 # libraries are found.
1532 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1533 multi_os_directory=`$CC -print-multi-os-directory`
1534 case $multi_os_directory in
1535   .)
1536    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1537    ;;
1538   *)
1539    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1540    ;;
1541 esac
1542 AC_SUBST(dbexecdir)
1543 AC_SUBST(gcjsubdir)
1544
1545 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1546 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1547
1548 TL_AC_GXX_INCLUDE_DIR
1549
1550 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1551 # On that system, sys/ioctl.h will not include sys/filio.h unless
1552 # BSD_COMP is defined; just including sys/filio.h is simpler.
1553 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1554 # for now.  If you change this, you also must update natFile.cc.
1555 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1556                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1557                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1558                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1559                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1560
1561 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1562 AC_CHECK_HEADERS(net/if.h, [], [], [
1563 #ifdef HAVE_SYS_SOCKET_H
1564 #include <sys/socket.h>
1565 #endif
1566 ])
1567
1568 AC_CHECK_HEADERS(inttypes.h, [
1569     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1570     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1571 ])
1572
1573 AC_CHECK_TYPE([ssize_t], [int])
1574 AC_CHECK_TYPE([magic_t], [
1575     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1576 #ifdef HAVE_MAGIC_H
1577 #include <magic.h>
1578 #endif])
1579
1580 AC_MSG_CHECKING([for in_addr_t])
1581 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1582 #if STDC_HEADERS
1583 #include <stdlib.h>
1584 #include <stddef.h>
1585 #endif
1586 #if HAVE_NETINET_IN_H
1587 #include <netinet/in.h>
1588 #endif]], [[in_addr_t foo;]])],
1589   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1590      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1591    AC_MSG_RESULT(yes)],
1592   [AC_MSG_RESULT(no)])
1593
1594 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1595 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1596   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1597      [Define if struct ip_mreq is defined in netinet/in.h.])
1598    AC_MSG_RESULT(yes)],
1599   [AC_MSG_RESULT(no)])
1600
1601 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1602 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1603   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1604      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1605    AC_MSG_RESULT(yes)],
1606   [AC_MSG_RESULT(no)])
1607
1608 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1609 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1610   [AC_DEFINE(HAVE_INET6, 1,
1611      [Define if inet6 structures are defined in netinet/in.h.])
1612    AC_MSG_RESULT(yes)],
1613   [AC_MSG_RESULT(no)])
1614
1615 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1616 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1617 #include <sys/types.h>
1618 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1619   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1620    AC_MSG_RESULT(yes)],
1621   [AC_MSG_RESULT(no)])
1622
1623 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1624 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1625   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1626    AC_MSG_RESULT(yes)],
1627   [AC_MSG_RESULT(no)
1628    AC_MSG_CHECKING([for global timezone variable])
1629    dnl FIXME: we don't want a link check here because that won't work
1630    dnl when cross-compiling.  So instead we make an assumption that
1631    dnl the header file will mention timezone if it exists.
1632    dnl Don't find the win32 function timezone
1633    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1634      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1635       AC_MSG_RESULT(yes)],
1636      [AC_MSG_RESULT(no)
1637        AC_MSG_CHECKING([for global _timezone variable])
1638        dnl FIXME: As above, don't want link check
1639        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1640          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1641             [Define if your platform has the global _timezone variable.])
1642           AC_MSG_RESULT(yes)],
1643           [AC_MSG_RESULT(no)])])])
1644
1645 AC_CHECK_PROGS(PERL, perl, false)
1646
1647 SYSDEP_SOURCES=
1648 SIGNAL_HANDLER_AUX=
1649
1650 case "${host}" in
1651  i?86-*-linux*)
1652     SIGNAL_HANDLER=include/i386-signal.h
1653     ;;
1654  sparc*-sun-solaris*)
1655     SIGNAL_HANDLER=include/sparc-signal.h
1656     ;;
1657 # ia64-*)
1658 #    SYSDEP_SOURCES=sysdep/ia64.c
1659 #    test -d sysdep || mkdir sysdep
1660 #    ;;
1661  hppa*-*-linux*)
1662     SIGNAL_HANDLER=include/pa-signal.h
1663     ;;
1664  hppa*-hp-hpux*)
1665     SIGNAL_HANDLER=include/hppa-signal.h
1666     ;;
1667  ia64-*-linux*)
1668     SIGNAL_HANDLER=include/dwarf2-signal.h
1669     ;;
1670  powerpc*-*-linux*)
1671     SIGNAL_HANDLER=include/powerpc-signal.h
1672     ;;
1673  alpha*-*-linux*)
1674     SIGNAL_HANDLER=include/dwarf2-signal.h
1675     ;;
1676  s390*-*-linux*)
1677     SIGNAL_HANDLER=include/s390-signal.h
1678     ;;
1679  x86_64*-*-linux*)
1680     SIGNAL_HANDLER=include/x86_64-signal.h
1681     SIGNAL_HANDLER_AUX=include/i386-signal.h
1682     ;;
1683  sparc*-*-linux*)
1684     SIGNAL_HANDLER=include/dwarf2-signal.h
1685     ;;
1686  sh*-*-linux*)
1687     SIGNAL_HANDLER=include/sh-signal.h
1688     ;;
1689  *mingw*)
1690     SIGNAL_HANDLER=include/win32-signal.h
1691     ;;
1692  mips*-*-linux*)
1693     SIGNAL_HANDLER=include/mips-signal.h
1694     ;;
1695  m68*-*-linux*)
1696     SIGNAL_HANDLER=include/dwarf2-signal.h
1697     ;;
1698  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1699     SIGNAL_HANDLER=include/darwin-signal.h
1700     ;;
1701  powerpc*-*-aix*)
1702     SIGNAL_HANDLER=include/aix-signal.h
1703     ;;
1704  *)
1705     SIGNAL_HANDLER=include/default-signal.h
1706     ;;
1707 esac
1708
1709 # If we're using sjlj exceptions, forget what we just learned.
1710 if test "$enable_sjlj_exceptions" = yes; then
1711    SIGNAL_HANDLER=include/default-signal.h
1712    SIGNAL_HANDLER_AUX=
1713 fi
1714
1715 AC_SUBST(SYSDEP_SOURCES)
1716
1717 if test -z "$SIGNAL_HANDLER_AUX"; then
1718   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1719 fi
1720
1721 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1722                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1723
1724 if test "${multilib}" = "yes"; then
1725   multilib_arg="--enable-multilib"
1726 else
1727   multilib_arg=
1728 fi
1729
1730 # See if we support thread-local storage.
1731 GCC_CHECK_TLS
1732
1733 # For _Unwind_GetIPInfo.
1734 GCC_CHECK_UNWIND_GETIPINFO
1735
1736 # See if linker supports anonymous version scripts.
1737 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1738   [libjava_cv_anon_version_script],
1739   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1740    libjava_cv_anon_version_script=no
1741    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1742    echo '{ global: globalsymb*; local: *; };' > conftest.map
1743    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1744                [libjava_cv_anon_version_script=yes], [])
1745    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1746   ])
1747 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1748
1749 # Check if linker supports static linking on a per library basis
1750 LD_START_STATIC_SPEC=
1751 LD_FINISH_STATIC_SPEC=
1752 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1753   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1754     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1755     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1756   fi
1757 fi
1758 AC_SUBST(LD_START_STATIC_SPEC)
1759 AC_SUBST(LD_FINISH_STATIC_SPEC)
1760
1761 here=`${PWDCMD-pwd}`
1762 AC_SUBST(here)
1763
1764 # We get this from the environment.
1765 AC_SUBST(GCJFLAGS)
1766
1767 AC_ARG_WITH([python-dir],
1768             AS_HELP_STRING([--with-python-dir],
1769                            [the location to install Python modules. This path should NOT include the prefix.]),
1770             [with_python_dir=$withval], [with_python_dir=""])
1771
1772 if test "x${with_python_dir}" = "x"
1773 then
1774   # Needed for installing Python modules during make install.
1775   python_mod_dir="\${prefix}/share/python"
1776   # Needed for substituting into aot-compile*
1777   python_mod_dir_expanded="${expanded_prefix}/share/python"
1778 else
1779   python_mod_dir="\${prefix}${with_python_dir}"
1780   python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1781 fi
1782 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1783 AC_SUBST(python_mod_dir)
1784 AC_SUBST(python_mod_dir_expanded)
1785
1786 # needed for aot-compile-rpm
1787 MAKE=`which make`
1788 AC_SUBST(MAKE)
1789
1790 AC_ARG_ENABLE([aot-compile-rpm],
1791   [AS_HELP_STRING([--enable-aot-compile-rpm],
1792                  [enable installation of aot-compile-rpm [default=no]])],
1793   [case "${enableval}" in
1794     yes) AOT_RPM_ENABLED=yes ;;
1795     no)  AOT_RPM_ENABLED=no ;;
1796     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1797   esac],
1798   [AOT_RPM_ENABLED=no]
1799 )
1800 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1801
1802 AC_ARG_ENABLE([java-home],
1803   [AS_HELP_STRING([--enable-java-home],
1804                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1805   [case "${enableval}" in
1806     yes) JAVA_HOME_ENABLED=yes ;;
1807     no)  JAVA_HOME_ENABLED=no ;;
1808     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1809   esac],
1810   [JAVA_HOME_ENABLED=no]
1811 )
1812 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1813
1814 # Only do these checks if java-home above is enabled.
1815 if test "x${JAVA_HOME_ENABLED}" = xyes
1816 then
1817
1818   AC_ARG_WITH([gcc-suffix],
1819               AS_HELP_STRING([--with-gcc-suffix],
1820                              [the GCC tool suffix (defaults to empty string)]),
1821               [gcc_suffix=$withval], [gcc_suffix=""])
1822   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1823   AC_SUBST(gcc_suffix)
1824
1825   AC_ARG_WITH([arch-directory],
1826               AS_HELP_STRING([--with-arch-directory],
1827                              [the arch directory under jre/lib (defaults to auto-detect)]),
1828               [host_cpu=$withval], [host_cpu=""])
1829
1830   AC_ARG_WITH([os-directory],
1831               AS_HELP_STRING([--with-os-directory],
1832                              [the os directory under include (defaults to auto-detect)]),
1833               [host_os=$withval], [host_os=""])
1834
1835   AC_ARG_WITH([origin-name],
1836               AS_HELP_STRING([--with-origin-name],
1837                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1838               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1839   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1840
1841   AC_ARG_WITH([arch-suffix],
1842               AS_HELP_STRING([--with-arch-suffix],
1843                              [the arch directory suffix (default is the empty string]),
1844               [arch_suffix=$withval], [arch_suffix=""])
1845   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1846
1847   AC_ARG_WITH([jvm-root-dir],
1848               AS_HELP_STRING([--with-jvm-root-dir],
1849                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1850               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1851   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1852
1853   AC_ARG_WITH([jvm-jar-dir],
1854               AS_HELP_STRING([--with-jvm-jar-dir],
1855                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1856               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1857   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1858
1859   JAVA_VERSION=1.5.0
1860   BUILD_VERSION=0
1861   AC_SUBST(JAVA_VERSION)
1862   AC_SUBST(BUILD_VERSION)
1863   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1864
1865   jre_dir=jre
1866   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1867   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1868
1869   JVM_ROOT_DIR=${jvm_root_dir}
1870   AC_SUBST(JVM_ROOT_DIR)
1871   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1872
1873   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1874   AC_SUBST(JVM_JAR_ROOT_DIR)
1875   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1876
1877   JVM_JAR_DIR=${jvm_jar_dir}
1878   AC_SUBST(JVM_JAR_DIR)
1879   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1880
1881   JRE_DIR=${jre_dir}
1882   AC_SUBST(JRE_DIR)
1883
1884   JRE_LNK=${jre_lnk}
1885   AC_SUBST(JRE_LNK)
1886
1887   SDK_LNK=${sdk_lnk}
1888   AC_SUBST(SDK_LNK)
1889
1890   SDK_BIN_DIR=${jvm_root_dir}/bin
1891   AC_SUBST(SDK_BIN_DIR)
1892   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1893
1894   SDK_LIB_DIR=${jvm_root_dir}/lib
1895   AC_SUBST(SDK_LIB_DIR)
1896   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1897
1898   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1899   AC_SUBST(SDK_INCLUDE_DIR)
1900   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1901
1902   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1903   AC_SUBST(JRE_BIN_DIR)
1904   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1905
1906   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1907   AC_SUBST(JRE_LIB_DIR)
1908   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1909
1910   # Find gcj prefix using gcj found in PATH.
1911   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1912
1913   # Where do the gcj binaries live?
1914   # For jhbuild based builds, they all live in a sibling of bin called
1915   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1916   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1917   AC_SUBST(GCJ_BIN_DIR)
1918   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1919
1920   AC_MSG_RESULT(host is ${host})
1921   if test "x${host_cpu}" = "x"
1922   then
1923     case ${host} in
1924       *-mingw* | *-cygwin*)
1925         host_cpu=x86;;
1926       i486-* | i586-* | i686-*)
1927         host_cpu=i386;;
1928       x86_64-*)
1929         host_cpu=amd64;;
1930       *)
1931         host_cpu=${host_cpu};;
1932     esac
1933   fi
1934   AC_MSG_RESULT(arch directory: ${host_cpu})
1935   CPU=${host_cpu}
1936   AC_SUBST(CPU)
1937
1938   if test "x${host_os}" = "x"
1939   then
1940     case ${host} in
1941       *-mingw* | *-cygwin*)
1942         host_os=win32;;
1943       *-linux*)
1944         host_os=linux;;
1945       *)
1946         host_os=${host_os};;
1947     esac
1948   fi
1949   echo os directory: ${host_os}
1950   OS=${host_os}
1951   AC_SUBST(OS)
1952
1953   # make an expanded $libdir, for substituting into
1954   # scripts (and other non-Makefile things).
1955   LIBDIR=$libdir
1956   if test "x${exec_prefix}" = "xNONE"
1957   then
1958       lib_exec_prefix=$expanded_prefix
1959   else
1960       lib_exec_prefix=$exec_prefix
1961   fi
1962   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1963   AC_SUBST(LIBDIR)
1964 fi
1965
1966 AC_CONFIG_FILES([
1967 Makefile
1968 libgcj.pc
1969 libgcj.spec
1970 libgcj-test.spec
1971 gcj/Makefile
1972 include/Makefile
1973 testsuite/Makefile
1974 contrib/aotcompile.py
1975 contrib/aot-compile
1976 contrib/aot-compile-rpm
1977 contrib/generate-cacerts.pl
1978 contrib/rebuild-gcj-db
1979 ])
1980
1981 if test ${multilib} = yes; then
1982   multilib_arg="--enable-multilib"
1983 else
1984   multilib_arg=
1985 fi
1986
1987 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1988 AC_OUTPUT