gcc/ada/par-util.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             P A R . U T I L                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Csets;    use Csets;
  27 with Namet.Sp; use Namet.Sp;
  28 with Stylesw;  use Stylesw;
  29 with Uintp;    use Uintp;
  30
  31 with GNAT.Spelling_Checker; use GNAT.Spelling_Checker;
  32
  33 separate (Par)
  34 package body Util is
  35
  36    ---------------------
  37    -- Bad_Spelling_Of --
  38    ---------------------
  39
  40    function Bad_Spelling_Of (T : Token_Type) return Boolean is
  41       Tname : constant String := Token_Type'Image (T);
  42       --  Characters of token name
  43
  44       S : String (1 .. Tname'Last - 4);
  45       --  Characters of token name folded to lower case, omitting TOK_ at start
  46
  47       M1 : String (1 .. 42) := "incorrect spelling of keyword ************";
  48       M2 : String (1 .. 44) := "illegal abbreviation of keyword ************";
  49       --  Buffers used to construct error message
  50
  51       P1 : constant := 30;
  52       P2 : constant := 32;
  53       --  Starting subscripts in M1, M2 for keyword name
  54
  55       SL : constant Natural := S'Length;
  56       --  Length of expected token name excluding TOK_ at start
  57
  58    begin
  59       if Token /= Tok_Identifier then
  60          return False;
  61       end if;
  62
  63       for J in S'Range loop
  64          S (J) := Fold_Lower (Tname (J + 4));
  65       end loop;
  66
  67       Get_Name_String (Token_Name);
  68
  69       --  A special check for case of PROGRAM used for PROCEDURE
  70
  71       if T = Tok_Procedure
  72         and then Name_Len = 7
  73         and then Name_Buffer (1 .. 7) = "program"
  74       then
  75          Error_Msg_SC -- CODEFIX
  76            ("PROCEDURE expected");
  77          Token := T;
  78          return True;
  79
  80       --  A special check for an illegal abbreviation
  81
  82       elsif Name_Len < S'Length
  83         and then Name_Len >= 4
  84         and then Name_Buffer (1 .. Name_Len) = S (1 .. Name_Len)
  85       then
  86          for J in 1 .. S'Last loop
  87             M2 (P2 + J - 1) := Fold_Upper (S (J));
  88          end loop;
  89
  90          Error_Msg_SC (M2 (1 .. P2 - 1 + S'Last));
  91          Token := T;
  92          return True;
  93       end if;
  94
  95       --  Now we go into the full circuit to check for a misspelling
  96
  97       --  Never consider something a misspelling if either the actual or
  98       --  expected string is less than 3 characters (before this check we
  99       --  used to consider i to be a misspelled if in some cases!)
 100
 101       if SL < 3 or else Name_Len < 3 then
 102          return False;
 103
 104       --  Special case: prefix matches, i.e. the leading characters of the
 105       --  token that we have exactly match the required keyword. If there
 106       --  are at least two characters left over, assume that we have a case
 107       --  of two keywords joined together which should not be joined.
 108
 109       elsif Name_Len > SL + 1
 110         and then S = Name_Buffer (1 .. SL)
 111       then
 112          Scan_Ptr := Token_Ptr + S'Length;
 113          Error_Msg_S ("|missing space");
 114          Token := T;
 115          return True;
 116       end if;
 117
 118       if Is_Bad_Spelling_Of (Name_Buffer (1 .. Name_Len), S) then
 119          for J in 1 .. S'Last loop
 120             M1 (P1 + J - 1) := Fold_Upper (S (J));
 121          end loop;
 122
 123          Error_Msg_SC -- CODFIX
 124            (M1 (1 .. P1 - 1 + S'Last));
 125          Token := T;
 126          return True;
 127
 128       else
 129          return False;
 130       end if;
 131    end Bad_Spelling_Of;
 132
 133    ----------------------
 134    -- Check_95_Keyword --
 135    ----------------------
 136
 137    --  On entry, the caller has checked that current token is an identifier
 138    --  whose name matches the name of the 95 keyword New_Tok.
 139
 140    procedure Check_95_Keyword (Token_95, Next : Token_Type) is
 141       Scan_State : Saved_Scan_State;
 142
 143    begin
 144       Save_Scan_State (Scan_State); -- at identifier/keyword
 145       Scan; -- past identifier/keyword
 146
 147       if Token = Next then
 148          Restore_Scan_State (Scan_State); -- to identifier
 149          Error_Msg_Name_1 := Token_Name;
 150          Error_Msg_SC ("(Ada 83) keyword* cannot be used!");
 151          Token := Token_95;
 152       else
 153          Restore_Scan_State (Scan_State); -- to identifier
 154       end if;
 155    end Check_95_Keyword;
 156
 157    ----------------------
 158    -- Check_Bad_Layout --
 159    ----------------------
 160
 161    procedure Check_Bad_Layout is
 162    begin
 163       if RM_Column_Check and then Token_Is_At_Start_Of_Line
 164         and then Start_Column <= Scope.Table (Scope.Last).Ecol
 165       then
 166          Error_Msg_BC -- CODEFIX
 167            ("(style) incorrect layout");
 168       end if;
 169    end Check_Bad_Layout;
 170
 171    --------------------------
 172    -- Check_Misspelling_Of --
 173    --------------------------
 174
 175    procedure Check_Misspelling_Of (T : Token_Type) is
 176    begin
 177       if Bad_Spelling_Of (T) then
 178          null;
 179       end if;
 180    end Check_Misspelling_Of;
 181
 182    -----------------------------
 183    -- Check_Simple_Expression --
 184    -----------------------------
 185
 186    procedure Check_Simple_Expression (E : Node_Id) is
 187    begin
 188       if Expr_Form = EF_Non_Simple then
 189          Error_Msg_N ("this expression must be parenthesized", E);
 190       end if;
 191    end Check_Simple_Expression;
 192
 193    ---------------------------------------
 194    -- Check_Simple_Expression_In_Ada_83 --
 195    ---------------------------------------
 196
 197    procedure Check_Simple_Expression_In_Ada_83 (E : Node_Id) is
 198    begin
 199       if Expr_Form = EF_Non_Simple then
 200          if Ada_Version = Ada_83 then
 201             Error_Msg_N ("(Ada 83) this expression must be parenthesized!", E);
 202          end if;
 203       end if;
 204    end Check_Simple_Expression_In_Ada_83;
 205
 206    ------------------------
 207    -- Check_Subtype_Mark --
 208    ------------------------
 209
 210    function Check_Subtype_Mark (Mark : Node_Id) return Node_Id is
 211    begin
 212       if Nkind (Mark) = N_Identifier
 213         or else Nkind (Mark) = N_Selected_Component
 214         or else (Nkind (Mark) = N_Attribute_Reference
 215                   and then Is_Type_Attribute_Name (Attribute_Name (Mark)))
 216         or else Mark = Error
 217       then
 218          return Mark;
 219       else
 220          Error_Msg ("subtype mark expected", Sloc (Mark));
 221          return Error;
 222       end if;
 223    end Check_Subtype_Mark;
 224
 225    -------------------
 226    -- Comma_Present --
 227    -------------------
 228
 229    function Comma_Present return Boolean is
 230       Scan_State  : Saved_Scan_State;
 231       Paren_Count : Nat;
 232
 233    begin
 234       --  First check, if a comma is present, then a comma is present!
 235
 236       if Token = Tok_Comma then
 237          T_Comma;
 238          return True;
 239
 240       --  If we have a right paren, then that is taken as ending the list
 241       --  i.e. no comma is present.
 242
 243       elsif Token = Tok_Right_Paren then
 244          return False;
 245
 246       --  If pragmas, then get rid of them and make a recursive call
 247       --  to process what follows these pragmas.
 248
 249       elsif Token = Tok_Pragma then
 250          P_Pragmas_Misplaced;
 251          return Comma_Present;
 252
 253       --  At this stage we have an error, and the goal is to decide on whether
 254       --  or not we should diagnose an error and report a (non-existent)
 255       --  comma as being present, or simply to report no comma is present
 256
 257       --  If we are a semicolon, then the question is whether we have a missing
 258       --  right paren, or whether the semicolon should have been a comma. To
 259       --  guess the right answer, we scan ahead keeping track of the paren
 260       --  level, looking for a clue that helps us make the right decision.
 261
 262       --  This approach is highly accurate in the single error case, and does
 263       --  not make bad mistakes in the multiple error case (indeed we can't
 264       --  really make a very bad decision at this point in any case).
 265
 266       elsif Token = Tok_Semicolon then
 267          Save_Scan_State (Scan_State);
 268          Scan; -- past semicolon
 269
 270          --  Check for being followed by identifier => which almost certainly
 271          --  means we are still in a parameter list and the comma should have
 272          --  been a semicolon (such a sequence could not follow a semicolon)
 273
 274          if Token = Tok_Identifier then
 275             Scan;
 276
 277             if Token = Tok_Arrow then
 278                goto Assume_Comma;
 279             end if;
 280          end if;
 281
 282          --  If that test didn't work, loop ahead looking for a comma or
 283          --  semicolon at the same parenthesis level. Always remember that
 284          --  we can't go badly wrong in an error situation like this!
 285
 286          Paren_Count := 0;
 287
 288          --  Here is the look ahead loop, Paren_Count tells us whether the
 289          --  token we are looking at is at the same paren level as the
 290          --  suspicious semicolon that we are trying to figure out.
 291
 292          loop
 293
 294             --  If we hit another semicolon or an end of file, and we have
 295             --  not seen a right paren or another comma on the way, then
 296             --  probably the semicolon did end the list. Indeed that is
 297             --  certainly the only single error correction possible here.
 298
 299             if Token = Tok_Semicolon or else Token = Tok_EOF then
 300                Restore_Scan_State (Scan_State);
 301                return False;
 302
 303             --  A comma at the same paren level as the semicolon is a strong
 304             --  indicator that the semicolon should have been a comma, indeed
 305             --  again this is the only possible single error correction.
 306
 307             elsif Token = Tok_Comma then
 308                exit when Paren_Count = 0;
 309
 310             --  A left paren just bumps the paren count
 311
 312             elsif Token = Tok_Left_Paren then
 313                Paren_Count := Paren_Count + 1;
 314
 315             --  A right paren that is at the same paren level as the semicolon
 316             --  also means that the only possible single error correction is
 317             --  to assume that the semicolon should have been a comma. If we
 318             --  are not at the same paren level, then adjust the paren level.
 319
 320             elsif Token = Tok_Right_Paren then
 321                exit when Paren_Count = 0;
 322                Paren_Count := Paren_Count - 1;
 323             end if;
 324
 325             --  Keep going, we haven't made a decision yet
 326
 327             Scan;
 328          end loop;
 329
 330          --  If we fall through the loop, it means that we found a terminating
 331          --  right paren or another comma. In either case it is reasonable to
 332          --  assume that the semicolon was really intended to be a comma. Also
 333          --  come here for the identifier arrow case.
 334
 335          <<Assume_Comma>>
 336             Restore_Scan_State (Scan_State);
 337             Error_Msg_SC -- CODEFIX
 338               ("|"";"" should be "",""");
 339             Scan; -- past the semicolon
 340             return True;
 341
 342       --  If we are not at semicolon or a right paren, then we base the
 343       --  decision on whether or not the next token can be part of an
 344       --  expression. If not, then decide that no comma is present (the
 345       --  caller will eventually generate a missing right parent message)
 346
 347       elsif Token in Token_Class_Eterm then
 348          return False;
 349
 350       --  Otherwise we assume a comma is present, even if none is present,
 351       --  since the next token must be part of an expression, so if we were
 352       --  at the end of the list, then there is more than one error present.
 353
 354       else
 355          T_Comma; -- to give error
 356          return True;
 357       end if;
 358    end Comma_Present;
 359
 360    -----------------------
 361    -- Discard_Junk_List --
 362    -----------------------
 363
 364    procedure Discard_Junk_List (L : List_Id) is
 365       pragma Warnings (Off, L);
 366    begin
 367       null;
 368    end Discard_Junk_List;
 369
 370    -----------------------
 371    -- Discard_Junk_Node --
 372    -----------------------
 373
 374    procedure Discard_Junk_Node (N : Node_Id) is
 375       pragma Warnings (Off, N);
 376    begin
 377       null;
 378    end Discard_Junk_Node;
 379
 380    ------------
 381    -- Ignore --
 382    ------------
 383
 384    procedure Ignore (T : Token_Type) is
 385    begin
 386       while Token = T loop
 387          if T = Tok_Comma then
 388             Error_Msg_SC -- CODEFIX
 389               ("|extra "","" ignored");
 390
 391          elsif T = Tok_Left_Paren then
 392             Error_Msg_SC -- CODEFIX
 393               ("|extra ""("" ignored");
 394
 395          elsif T = Tok_Right_Paren then
 396             Error_Msg_SC -- CODEFIX
 397               ("|extra "")"" ignored");
 398
 399          elsif T = Tok_Semicolon then
 400             Error_Msg_SC -- CODEFIX
 401               ("|extra "";"" ignored");
 402
 403          elsif T = Tok_Colon then
 404             Error_Msg_SC -- CODEFIX
 405               ("|extra "":"" ignored");
 406
 407          else
 408             declare
 409                Tname : constant String := Token_Type'Image (Token);
 410             begin
 411                Error_Msg_SC ("|extra " & Tname (5 .. Tname'Last) & "ignored");
 412             end;
 413          end if;
 414
 415          Scan; -- Scan past ignored token
 416       end loop;
 417    end Ignore;
 418
 419    ----------------------------
 420    -- Is_Reserved_Identifier --
 421    ----------------------------
 422
 423    function Is_Reserved_Identifier (C : Id_Check := None) return Boolean is
 424    begin
 425       if not Is_Reserved_Keyword (Token) then
 426          return False;
 427
 428       else
 429          declare
 430             Ident_Casing : constant Casing_Type :=
 431                              Identifier_Casing (Current_Source_File);
 432             Key_Casing   : constant Casing_Type :=
 433                              Keyword_Casing (Current_Source_File);
 434
 435          begin
 436             --  If the casing of identifiers and keywords is different in
 437             --  this source file, and the casing of this token matches the
 438             --  keyword casing, then we return False, since it is pretty
 439             --  clearly intended to be a keyword.
 440
 441             if Ident_Casing = Unknown
 442               or else Key_Casing = Unknown
 443               or else Ident_Casing = Key_Casing
 444               or else Determine_Token_Casing /= Key_Casing
 445             then
 446                return True;
 447
 448             --  Here we have a keyword written clearly with keyword casing.
 449             --  In default mode, we would not be willing to consider this as
 450             --  a reserved identifier, but if C is set, we may still accept it
 451
 452             elsif C /= None then
 453                declare
 454                   Scan_State  : Saved_Scan_State;
 455                   OK_Next_Tok : Boolean;
 456
 457                begin
 458                   Save_Scan_State (Scan_State);
 459                   Scan;
 460
 461                   if Token_Is_At_Start_Of_Line then
 462                      return False;
 463                   end if;
 464
 465                   case C is
 466                      when None =>
 467                         raise Program_Error;
 468
 469                      when C_Comma_Right_Paren =>
 470                         OK_Next_Tok :=
 471                           Token = Tok_Comma or else Token = Tok_Right_Paren;
 472
 473                      when C_Comma_Colon =>
 474                         OK_Next_Tok :=
 475                           Token = Tok_Comma or else Token = Tok_Colon;
 476
 477                      when C_Do =>
 478                         OK_Next_Tok :=
 479                           Token = Tok_Do;
 480
 481                      when C_Dot =>
 482                         OK_Next_Tok :=
 483                           Token = Tok_Dot;
 484
 485                      when C_Greater_Greater =>
 486                         OK_Next_Tok :=
 487                           Token = Tok_Greater_Greater;
 488
 489                      when C_In =>
 490                         OK_Next_Tok :=
 491                           Token = Tok_In;
 492
 493                      when C_Is =>
 494                         OK_Next_Tok :=
 495                           Token = Tok_Is;
 496
 497                      when C_Left_Paren_Semicolon =>
 498                         OK_Next_Tok :=
 499                           Token = Tok_Left_Paren or else Token = Tok_Semicolon;
 500
 501                      when C_Use =>
 502                         OK_Next_Tok :=
 503                           Token = Tok_Use;
 504
 505                      when C_Vertical_Bar_Arrow =>
 506                         OK_Next_Tok :=
 507                           Token = Tok_Vertical_Bar or else Token = Tok_Arrow;
 508                   end case;
 509
 510                   Restore_Scan_State (Scan_State);
 511
 512                   if OK_Next_Tok then
 513                      return True;
 514                   end if;
 515                end;
 516             end if;
 517          end;
 518       end if;
 519
 520       --  If we fall through it is not a reserved identifier
 521
 522       return False;
 523    end Is_Reserved_Identifier;
 524
 525    ----------------------
 526    -- Merge_Identifier --
 527    ----------------------
 528
 529    procedure Merge_Identifier (Prev : Node_Id; Nxt : Token_Type) is
 530    begin
 531       if Token /= Tok_Identifier then
 532          return;
 533       end if;
 534
 535       declare
 536          S : Saved_Scan_State;
 537          T : Token_Type;
 538
 539       begin
 540          Save_Scan_State (S);
 541          Scan;
 542          T := Token;
 543          Restore_Scan_State (S);
 544
 545          if T /= Nxt then
 546             return;
 547          end if;
 548       end;
 549
 550       --  Check exactly one space between identifiers
 551
 552       if Source (Token_Ptr - 1) /= ' '
 553         or else Int (Token_Ptr) /=
 554                   Int (Prev_Token_Ptr) + Length_Of_Name (Chars (Prev)) + 1
 555       then
 556          return;
 557       end if;
 558
 559       --  Do the merge
 560
 561       Get_Name_String (Chars (Token_Node));
 562
 563       declare
 564          Buf : constant String (1 .. Name_Len) :=
 565                  Name_Buffer (1 .. Name_Len);
 566
 567       begin
 568          Get_Name_String (Chars (Prev));
 569          Add_Char_To_Name_Buffer ('_');
 570          Add_Str_To_Name_Buffer (Buf);
 571          Set_Chars (Prev, Name_Find);
 572       end;
 573
 574       Error_Msg_Node_1 := Prev;
 575       Error_Msg_SC ("unexpected identifier, possibly & was meant here");
 576       Scan;
 577    end Merge_Identifier;
 578
 579    -------------------
 580    -- Next_Token_Is --
 581    -------------------
 582
 583    function Next_Token_Is (Tok : Token_Type) return Boolean is
 584       Scan_State : Saved_Scan_State;
 585       Result     : Boolean;
 586    begin
 587       Save_Scan_State (Scan_State);
 588       Scan;
 589       Result := (Token = Tok);
 590       Restore_Scan_State (Scan_State);
 591       return Result;
 592    end Next_Token_Is;
 593
 594    -------------------
 595    -- No_Constraint --
 596    -------------------
 597
 598    procedure No_Constraint is
 599    begin
 600       if Token in Token_Class_Consk then
 601          Error_Msg_SC ("constraint not allowed here");
 602          Discard_Junk_Node (P_Constraint_Opt);
 603       end if;
 604    end No_Constraint;
 605
 606    ---------------------
 607    -- Pop_Scope_Stack --
 608    ---------------------
 609
 610    procedure Pop_Scope_Stack is
 611    begin
 612       pragma Assert (Scope.Last > 0);
 613       Scope.Decrement_Last;
 614
 615       if Debug_Flag_P then
 616          Error_Msg_Uint_1 := UI_From_Int (Scope.Last);
 617          Error_Msg_SC ("decrement scope stack ptr, new value = ^!");
 618       end if;
 619    end Pop_Scope_Stack;
 620
 621    ----------------------
 622    -- Push_Scope_Stack --
 623    ----------------------
 624
 625    procedure Push_Scope_Stack is
 626    begin
 627       Scope.Increment_Last;
 628
 629       if Style_Check_Max_Nesting_Level
 630         and then Scope.Last = Style_Max_Nesting_Level + 1
 631       then
 632          Error_Msg
 633            ("(style) maximum nesting level exceeded",
 634             First_Non_Blank_Location);
 635       end if;
 636
 637       Scope.Table (Scope.Last).Junk := False;
 638       Scope.Table (Scope.Last).Node := Empty;
 639
 640       if Debug_Flag_P then
 641          Error_Msg_Uint_1 := UI_From_Int (Scope.Last);
 642          Error_Msg_SC ("increment scope stack ptr, new value = ^!");
 643       end if;
 644    end Push_Scope_Stack;
 645
 646    ----------------------
 647    -- Separate_Present --
 648    ----------------------
 649
 650    function Separate_Present return Boolean is
 651       Scan_State : Saved_Scan_State;
 652
 653    begin
 654       if Token = Tok_Separate then
 655          return True;
 656
 657       elsif Token /= Tok_Identifier then
 658          return False;
 659
 660       else
 661          Save_Scan_State (Scan_State);
 662          Scan; -- past identifier
 663
 664          if Token = Tok_Semicolon then
 665             Restore_Scan_State (Scan_State);
 666             return Bad_Spelling_Of (Tok_Separate);
 667
 668          else
 669             Restore_Scan_State (Scan_State);
 670             return False;
 671          end if;
 672       end if;
 673    end Separate_Present;
 674
 675    --------------------------
 676    -- Signal_Bad_Attribute --
 677    --------------------------
 678
 679    procedure Signal_Bad_Attribute is
 680    begin
 681       Error_Msg_N ("unrecognized attribute&", Token_Node);
 682
 683       --  Check for possible misspelling
 684
 685       Error_Msg_Name_1 := First_Attribute_Name;
 686       while Error_Msg_Name_1 <= Last_Attribute_Name loop
 687          if Is_Bad_Spelling_Of (Token_Name, Error_Msg_Name_1) then
 688             Error_Msg_N -- CODEFIX
 689               ("\possible misspelling of %", Token_Node);
 690             exit;
 691          end if;
 692
 693          Error_Msg_Name_1 := Error_Msg_Name_1 + 1;
 694       end loop;
 695    end Signal_Bad_Attribute;
 696
 697    -----------------------------
 698    -- Token_Is_At_End_Of_Line --
 699    -----------------------------
 700
 701    function Token_Is_At_End_Of_Line return Boolean is
 702       S : Source_Ptr;
 703
 704    begin
 705       --  Skip past blanks and horizontal tabs
 706
 707       S := Scan_Ptr;
 708       while Source (S) = ' ' or else Source (S) = ASCII.HT loop
 709          S := S + 1;
 710       end loop;
 711
 712       --  We are at end of line if at a control character (CR/LF/VT/FF/EOF)
 713       --  or if we are at the start of an end of line comment sequence.
 714
 715       return Source (S) < ' '
 716         or else (Source (S) = '-' and then Source (S + 1) = '-');
 717    end Token_Is_At_End_Of_Line;
 718
 719    -------------------------------
 720    -- Token_Is_At_Start_Of_Line --
 721    -------------------------------
 722
 723    function Token_Is_At_Start_Of_Line return Boolean is
 724    begin
 725       return (Token_Ptr = First_Non_Blank_Location or else Token = Tok_EOF);
 726    end Token_Is_At_Start_Of_Line;
 727
 728 end Util;