gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 ACX_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     libstdcxx_incdir='c++/$(version)'
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # With demangler in GNU ld
 215 AC_ARG_WITH(demangler-in-ld,
 216 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 217 demangler_in_ld="$with_demangler_in_ld",
 218 demangler_in_ld=no)
 219
 220 # ----------------------
 221 # Find default assembler
 222 # ----------------------
 223
 224 # With GNU as
 225 AC_ARG_WITH(gnu-as,
 226 [  --with-gnu-as           arrange to work with GNU as],
 227 gas_flag="$with_gnu_as",
 228 gas_flag=no)
 229
 230 AC_ARG_WITH(as,
 231 [  --with-as               arrange to use the specified as (full pathname)],
 232 DEFAULT_ASSEMBLER="$with_as")
 233 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 234   if test ! -x "$DEFAULT_ASSEMBLER"; then
 235     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 236   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 237     gas_flag=yes
 238   fi
 239   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 240         [Define to enable the use of a default assembler.])
 241 fi
 242
 243 AC_MSG_CHECKING([whether a default assembler was specified])
 244 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 245   if test x"$gas_flag" = x"no"; then
 246     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 247   else
 248     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 249   fi
 250 else
 251   AC_MSG_RESULT(no)
 252 fi
 253
 254 # ---------------
 255 # Find C compiler
 256 # ---------------
 257
 258 # If a non-executable a.out is present (e.g. created by GNU as above even if
 259 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 260 # file, even when creating an executable, so an execution test fails.
 261 # Remove possible default executable files to avoid this.
 262 #
 263 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 264 # Autoconf includes it.
 265 rm -f a.out a.exe b.out
 266
 267 # Find the native compiler
 268 AC_PROG_CC
 269 AM_PROG_CC_C_O
 270 # autoconf is lame and doesn't give us any substitution variable for this.
 271 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 272   NO_MINUS_C_MINUS_O=yes
 273 else
 274   OUTPUT_OPTION='-o $@'
 275 fi
 276 AC_SUBST(NO_MINUS_C_MINUS_O)
 277 AC_SUBST(OUTPUT_OPTION)
 278
 279 # -------------------------
 280 # Check C compiler features
 281 # -------------------------
 282
 283 AC_PROG_CPP
 284 AC_C_INLINE
 285
 286 gcc_AC_C_LONG_LONG
 287
 288 # sizeof(char) is 1 by definition.
 289 AC_CHECK_SIZEOF(void *)
 290 AC_CHECK_SIZEOF(short)
 291 AC_CHECK_SIZEOF(int)
 292 AC_CHECK_SIZEOF(long)
 293 if test $ac_cv_c_long_long = yes; then
 294   AC_CHECK_SIZEOF(long long)
 295 fi
 296 if test $ac_cv_c___int64 = yes; then
 297   AC_CHECK_SIZEOF(__int64)
 298 fi
 299
 300 # ---------------------
 301 # Warnings and checking
 302 # ---------------------
 303
 304 # Check $CC warning features (if it's GCC).
 305 # We want to use -pedantic, but we don't want warnings about
 306 # * 'long long'
 307 # * variadic macros
 308 # So, we only use -pedantic if we can disable those warnings.
 309
 310 AC_CACHE_CHECK(
 311   [whether ${CC} accepts -Wno-long-long],
 312   [ac_cv_prog_cc_w_no_long_long],
 313   [save_CFLAGS="$CFLAGS"
 314   CFLAGS="-Wno-long-long"
 315   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 316                     [ac_cv_prog_cc_w_no_long_long=yes],
 317                     [ac_cv_prog_cc_w_no_long_long=no])
 318   CFLAGS="$save_CFLAGS"
 319   ])
 320
 321 AC_CACHE_CHECK(
 322   [whether ${CC} accepts -Wno-variadic-macros],
 323   [ac_cv_prog_cc_w_no_variadic_macros],
 324   [save_CFLAGS="$CFLAGS"
 325   CFLAGS="-Wno-variadic-macros"
 326   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 327                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 328                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 329   CFLAGS="$save_CFLAGS"
 330   ])
 331
 332 strict1_warn=
 333 if test $ac_cv_prog_cc_w_no_long_long = yes \
 334    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 335   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 336 fi
 337 AC_SUBST(strict1_warn)
 338
 339 # Add -Wold-style-definition if it's accepted
 340 AC_CACHE_CHECK(
 341   [whether ${CC} accepts -Wold-style-definition],
 342   [ac_cv_prog_cc_w_old_style_definition],
 343   [save_CFLAGS="$CFLAGS"
 344   CFLAGS="-Wold-style-definition"
 345   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 346                     [ac_cv_prog_cc_w_old_style_definition=yes],
 347                     [ac_cv_prog_cc_w_old_style_definition=no])
 348   CFLAGS="$save_CFLAGS"
 349   ])
 350 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 351   strict1_warn="${strict1_warn} -Wold-style-definition"
 352 fi
 353
 354 # Enable -Werror, period.
 355 AC_ARG_ENABLE(werror_always,
 356 [  --enable-werror-always         enable -Werror always], [],
 357 [enable_werror_always=no])
 358 if test x${enable_werror_always} = xyes ; then
 359   strict1_warn="${strict1_warn} -Werror"
 360   WERROR=-Werror
 361 fi
 362
 363 # If the native compiler is GCC, we can enable warnings even in stage1.
 364 # That's useful for people building cross-compilers, or just running a
 365 # quick `make'.
 366 warn_cflags=
 367 if test "x$GCC" = "xyes"; then
 368   warn_cflags='$(GCC_WARN_CFLAGS)'
 369 fi
 370 AC_SUBST(warn_cflags)
 371
 372 # Enable -Werror in bootstrap stage2 and later.
 373 is_release=
 374 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 375   is_release=yes
 376 fi
 377 AC_ARG_ENABLE(werror,
 378 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 379 [if test x$is_release = x ; then
 380   # Default to "yes" on development branches.
 381   enable_werror=yes
 382 else
 383   # Default to "no" on release branches.
 384   enable_werror=no
 385 fi])
 386 if test x$enable_werror = xyes ; then
 387   WERROR=-Werror
 388 fi
 389 AC_SUBST(WERROR)
 390
 391 # Enable expensive internal checks
 392 AC_ARG_ENABLE(checking,
 393 [  --enable-checking[=LIST]
 394                           enable expensive run-time checks.  With LIST,
 395                           enable only specific categories of checks.
 396                           Categories are: yes,no,all,none,release.
 397                           Flags are: assert,fold,gc,gcac,misc,
 398                           rtlflag,rtl,runtime,tree,valgrind.],
 399 [ac_checking_flags="${enableval}"],[
 400 # Determine the default checks.
 401 if test x$is_release = x ; then
 402   ac_checking_flags=yes
 403 else
 404   ac_checking_flags=release
 405 fi])
 406 ac_assert_checking=1
 407 ac_checking=
 408 ac_fold_checking=
 409 ac_gc_checking=
 410 ac_gc_always_collect=
 411 ac_rtl_checking=
 412 ac_rtlflag_checking=
 413 ac_runtime_checking=1
 414 ac_tree_checking=
 415 ac_valgrind_checking=
 416 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 417 for check in $ac_checking_flags
 418 do
 419         case $check in
 420         # these set all the flags to specific states
 421         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 422                         ac_fold_checking= ; ac_gc_checking=1 ;
 423                         ac_gc_always_collect= ; ac_rtl_checking= ;
 424                         ac_rtlflag_checking=1 ; ac_runtime_chacking=1 ;
 425                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 426         no|none)        ac_assert_checking= ; ac_checking= ;
 427                         ac_fold_checking= ; ac_gc_checking= ;
 428                         ac_gc_always_collect= ; ac_rtl_checking= ;
 429                         ac_rtlflag_checking= ; ac_runtime_chacking= ;
 430                         ac_tree_checking= ; ac_valgrind_checking= ;;
 431         all)            ac_assert_checking=1 ; ac_checking=1 ;
 432                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 433                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 434                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 435                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 436         release)        ac_assert_checking=1 ; ac_checking= ;
 437                         ac_fold_checking= ; ac_gc_checking= ;
 438                         ac_gc_always_collect= ; ac_rtl_checking= ;
 439                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 440                         ac_tree_checking= ; ac_valgrind_checking= ;;
 441         # these enable particular checks
 442         assert)         ac_assert_checking=1 ;;
 443         fold)           ac_fold_checking=1 ;;
 444         gc)             ac_gc_checking=1 ;;
 445         gcac)           ac_gc_always_collect=1 ;;
 446         misc)           ac_checking=1 ;;
 447         rtl)            ac_rtl_checking=1 ;;
 448         rtlflag)        ac_rtlflag_checking=1 ;;
 449         runtime)        ac_runtime_checking=1 ;;
 450         tree)           ac_tree_checking=1 ;;
 451         valgrind)       ac_valgrind_checking=1 ;;
 452         *)      AC_MSG_ERROR(unknown check category $check) ;;
 453         esac
 454 done
 455 IFS="$ac_save_IFS"
 456
 457 nocommon_flag=""
 458 if test x$ac_checking != x ; then
 459   AC_DEFINE(ENABLE_CHECKING, 1,
 460 [Define if you want more run-time sanity checks.  This one gets a grab
 461    bag of miscellaneous but relatively cheap checks.])
 462   nocommon_flag=-fno-common
 463 fi
 464 AC_SUBST(nocommon_flag)
 465 if test x$ac_assert_checking != x ; then
 466   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 467 [Define if you want assertions enabled.  This is a cheap check.])
 468 fi
 469 if test x$ac_runtime_checking != x ; then
 470   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 471 [Define if you want runtime assertions enabled.  This is a cheap check.])
 472 fi
 473 if test x$ac_tree_checking != x ; then
 474   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 475 [Define if you want all operations on trees (the basic data
 476    structure of the front ends) to be checked for dynamic type safety
 477    at runtime.  This is moderately expensive.  The tree browser debugging
 478    routines will also be enabled by this option.
 479    ])
 480   TREEBROWSER=tree-browser.o
 481 fi
 482 AC_SUBST(TREEBROWSER)
 483 if test x$ac_rtl_checking != x ; then
 484   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 485 [Define if you want all operations on RTL (the basic data structure
 486    of the optimizer and back end) to be checked for dynamic type safety
 487    at runtime.  This is quite expensive.])
 488 fi
 489 if test x$ac_rtlflag_checking != x ; then
 490   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 491 [Define if you want RTL flag accesses to be checked against the RTL
 492    codes that are supported for each access macro.  This is relatively
 493    cheap.])
 494 fi
 495 if test x$ac_gc_checking != x ; then
 496   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 497 [Define if you want the garbage collector to do object poisoning and
 498    other memory allocation checks.  This is quite expensive.])
 499 fi
 500 if test x$ac_gc_always_collect != x ; then
 501   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 502 [Define if you want the garbage collector to operate in maximally
 503    paranoid mode, validating the entire heap and collecting garbage at
 504    every opportunity.  This is extremely expensive.])
 505 fi
 506 if test x$ac_fold_checking != x ; then
 507   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 508 [Define if you want fold checked that it never destructs its argument.
 509    This is quite expensive.])
 510 fi
 511 valgrind_path_defines=
 512 valgrind_command=
 513
 514 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 515 dnl # an if statement.  This was the source of very frustrating bugs
 516 dnl # in converting to autoconf 2.5x!
 517 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 518
 519 if test x$ac_valgrind_checking != x ; then
 520   # It is certainly possible that there's valgrind but no valgrind.h.
 521   # GCC relies on making annotations so we must have both.
 522   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 523   AC_TRY_CPP(
 524     [#include <valgrind/memcheck.h>
 525 #ifndef VALGRIND_DISCARD
 526 #error VALGRIND_DISCARD not defined
 527 #endif],
 528   [gcc_cv_header_valgrind_memcheck_h=yes],
 529   [gcc_cv_header_valgrind_memcheck_h=no])
 530   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 531   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 532   AC_TRY_CPP(
 533     [#include <memcheck.h>
 534 #ifndef VALGRIND_DISCARD
 535 #error VALGRIND_DISCARD not defined
 536 #endif],
 537   [gcc_cv_header_memcheck_h=yes],
 538   gcc_cv_header_memcheck_h=no)
 539   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 540   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 541         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 542   if test "x$valgrind_path" = "x" \
 543     || (test $have_valgrind_h = no \
 544         && test $gcc_cv_header_memcheck_h = no \
 545         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 546         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 547   fi
 548   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 549   valgrind_command="$valgrind_path -q"
 550   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 551 [Define if you want to run subprograms and generated programs
 552    through valgrind (a memory checker).  This is extremely expensive.])
 553   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 554     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 555         [Define if valgrind's valgrind/memcheck.h header is installed.])
 556   fi
 557   if test $gcc_cv_header_memcheck_h = yes; then
 558     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 559         [Define if valgrind's memcheck.h header is installed.])
 560   fi
 561 fi
 562 AC_SUBST(valgrind_path_defines)
 563 AC_SUBST(valgrind_command)
 564
 565 AC_ARG_ENABLE(mapped-location,
 566 [  --enable-mapped-location   location_t is fileline integer cookie],,
 567 enable_mapped_location=no)
 568
 569 if test "$enable_mapped_location" = yes ; then
 570   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 571 [Define if location_t is fileline integer cookie.])
 572 fi
 573
 574 # Enable code coverage collection
 575 AC_ARG_ENABLE(coverage,
 576 [  --enable-coverage[=LEVEL]
 577                           enable compiler's code coverage collection.
 578                           Use to measure compiler performance and locate
 579                           unused parts of the compiler. With LEVEL, specify
 580                           optimization. Values are opt, noopt,
 581                           default is noopt],
 582 [case "${enableval}" in
 583   yes|noopt)
 584     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 585     ;;
 586   opt)
 587     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 588     ;;
 589   no)
 590     # a.k.a. --disable-coverage
 591     coverage_flags=""
 592     ;;
 593   *)
 594     AC_MSG_ERROR(unknown coverage setting $enableval)
 595     ;;
 596 esac],
 597 [coverage_flags=""])
 598 AC_SUBST(coverage_flags)
 599
 600 AC_ARG_ENABLE(gather-detailed-mem-stats,
 601 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 602 [enable_gather_detailed_mem_stats=no])
 603 if test x$enable_gather_detailed_mem_stats = xyes ; then
 604   AC_DEFINE(GATHER_STATISTICS, 1,
 605         [Define to enable detailed memory allocation stats gathering.])
 606 fi
 607
 608 # -------------------------------
 609 # Miscenalleous configure options
 610 # -------------------------------
 611
 612 # With stabs
 613 AC_ARG_WITH(stabs,
 614 [  --with-stabs            arrange to use stabs instead of host debug format],
 615 stabs="$with_stabs",
 616 stabs=no)
 617
 618 # Determine whether or not multilibs are enabled.
 619 AC_ARG_ENABLE(multilib,
 620 [  --enable-multilib       enable library support for multiple ABIs],
 621 [], [enable_multilib=yes])
 622 AC_SUBST(enable_multilib)
 623
 624 # Enable __cxa_atexit for C++.
 625 AC_ARG_ENABLE(__cxa_atexit,
 626 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 627 [], [])
 628
 629 # Enable threads
 630 # Pass with no value to take the default
 631 # Pass with a value to specify a thread package
 632 AC_ARG_ENABLE(threads,
 633 [  --enable-threads        enable thread usage for target GCC
 634   --enable-threads=LIB    use LIB thread package for target GCC],,
 635 [enable_threads=''])
 636
 637 AC_ARG_ENABLE(objc-gc,
 638 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 639                           the GNU Objective-C runtime],
 640 if test x$enable_objc_gc = xno; then
 641         objc_boehm_gc=''
 642 else
 643         objc_boehm_gc=1
 644 fi,
 645 objc_boehm_gc='')
 646
 647 AC_ARG_WITH(dwarf2,
 648 [  --with-dwarf2           force the default debug format to be DWARF 2],
 649 dwarf2="$with_dwarf2",
 650 dwarf2=no)
 651
 652 AC_ARG_ENABLE(shared,
 653 [  --disable-shared        don't provide a shared libgcc],
 654 [
 655   case $enable_shared in
 656   yes | no) ;;
 657   *)
 658     enable_shared=no
 659     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 660     for pkg in $enableval; do
 661       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 662         enable_shared=yes
 663       fi
 664     done
 665     IFS="$ac_save_ifs"
 666     ;;
 667   esac
 668 ], [enable_shared=yes])
 669 AC_SUBST(enable_shared)
 670
 671 AC_ARG_WITH(sysroot,
 672 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 673 [
 674  case ${with_sysroot} in
 675  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 676  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 677  esac
 678
 679  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 680  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 681
 682  if test "x$exec_prefix" = xNONE; then
 683   if test "x$prefix" = xNONE; then
 684    test_prefix=/usr/local
 685   else
 686    test_prefix=$prefix
 687   fi
 688  else
 689   test_prefix=$exec_prefix
 690  fi
 691  case ${TARGET_SYSTEM_ROOT} in
 692  "${test_prefix}"|"${test_prefix}/"*|\
 693  '${exec_prefix}'|'${exec_prefix}/'*)
 694    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 695    TARGET_SYSTEM_ROOT_DEFINE="$t"
 696    ;;
 697  esac
 698 ], [
 699  TARGET_SYSTEM_ROOT=
 700  TARGET_SYSTEM_ROOT_DEFINE=
 701  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 702 ])
 703 AC_SUBST(TARGET_SYSTEM_ROOT)
 704 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 705 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 706
 707 # Build with intermodule optimisations
 708 AC_ARG_ENABLE(intermodule,
 709 [  --enable-intermodule    build the compiler in one step],
 710 [case ${enable_intermodule} in
 711   yes) onestep="-onestep";;
 712   *) onestep="";;
 713 esac],
 714 [onestep=""])
 715 AC_SUBST(onestep)
 716
 717 # Sanity check enable_languages in case someone does not run the toplevel
 718 # configure # script.
 719 AC_ARG_ENABLE(languages,
 720 [  --enable-languages=LIST specify which front-ends to build],
 721 [case ,${enable_languages}, in
 722        ,,|,yes,)
 723                 # go safe -- we cannot be much sure without the toplevel
 724                 # configure's
 725                 # analysis of which target libs are present and usable
 726                 enable_languages=c
 727                 ;;
 728          *,all,*)
 729                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 730                 ;;
 731         *,c,*)
 732                 ;;
 733         *)
 734                 enable_languages=c,${enable_languages}
 735                 ;;
 736 esac],
 737 [enable_languages=c])
 738
 739 subdirs=
 740 for lang in ${srcdir}/*/config-lang.in
 741 do
 742         case $lang in
 743         # The odd quoting in the next line works around
 744         # an apparent bug in bash 1.12 on linux.
 745 changequote(,)dnl
 746         ${srcdir}/[*]/config-lang.in) ;;
 747         *)
 748           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 749           if test "x$lang_alias" = x
 750           then
 751                 echo "$lang doesn't set \$language." 1>&2
 752                 exit 1
 753           fi
 754           case ",$enable_languages," in
 755           *,$lang_alias,*)
 756             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 757           esac
 758           ;;
 759 changequote([,])dnl
 760         esac
 761 done
 762
 763
 764 # -------------------------
 765 # Checks for other programs
 766 # -------------------------
 767
 768 AC_PROG_MAKE_SET
 769
 770 # Find some useful tools
 771 AC_PROG_AWK
 772 # We need awk to create options.c and options.h.
 773 # Bail out if it's missing.
 774 case ${AWK} in
 775   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 776 esac
 777
 778 gcc_AC_PROG_LN_S
 779 ACX_PROG_LN($LN_S)
 780 AC_PROG_RANLIB
 781 case "${host}" in
 782 *-*-darwin*)
 783   # By default, the Darwin ranlib will not treat common symbols as
 784   # definitions when  building the archive table of contents.  Other
 785   # ranlibs do that; pass an option to the Darwin ranlib that makes
 786   # it behave similarly.
 787   ranlib_flags="-c"
 788   ;;
 789 *)
 790   ranlib_flags=""
 791 esac
 792 AC_SUBST(ranlib_flags)
 793
 794 gcc_AC_PROG_INSTALL
 795
 796 # See if cmp has --ignore-initial.
 797 gcc_AC_PROG_CMP_IGNORE_INITIAL
 798
 799 # See if we have the mktemp command.
 800 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 801
 802 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 803
 804 # See if makeinfo has been installed and is modern enough
 805 # that we can use it.
 806 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 807   [GNU texinfo.* \([0-9][0-9.]*\)],
 808   [4.[2-9]*])
 809 if test $gcc_cv_prog_makeinfo_modern = no; then
 810   MAKEINFO="$MISSING makeinfo"
 811   AC_MSG_WARN([
 812 *** Makeinfo is missing or too old.
 813 *** Info documentation will not be built.])
 814   BUILD_INFO=
 815 else
 816   BUILD_INFO=info
 817 fi
 818 AC_SUBST(BUILD_INFO)
 819
 820 # Is pod2man recent enough to regenerate manpages?
 821 AC_MSG_CHECKING([for recent Pod::Man])
 822 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 823   AC_MSG_RESULT(yes)
 824   GENERATED_MANPAGES=generated-manpages
 825 else
 826   AC_MSG_RESULT(no)
 827   GENERATED_MANPAGES=
 828 fi
 829 AC_SUBST(GENERATED_MANPAGES)
 830
 831 # How about lex?
 832 dnl Don't use AC_PROG_LEX; we insist on flex.
 833 dnl LEXLIB is not useful in gcc.
 834 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 835
 836 # Bison?
 837 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 838
 839 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 840 # check for build == host before using them.
 841
 842 # NM
 843 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 844   && test -d ../binutils ; then
 845   NM='$(objdir)/../binutils/nm-new'
 846 else
 847   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 848 fi
 849
 850 # AR
 851 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 852   && test -d ../binutils ; then
 853   AR='$(objdir)/../binutils/ar'
 854 else
 855   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 856 fi
 857
 858
 859 # --------------------
 860 # Checks for C headers
 861 # --------------------
 862
 863 AC_MSG_CHECKING(for GNU C library)
 864 AC_CACHE_VAL(gcc_cv_glibc,
 865 [AC_TRY_COMPILE(
 866   [#include <features.h>],[
 867 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 868 #error Not a GNU C library system
 869 #endif],
 870   [gcc_cv_glibc=yes],
 871   gcc_cv_glibc=no)])
 872 AC_MSG_RESULT($gcc_cv_glibc)
 873 if test $gcc_cv_glibc = yes; then
 874   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 875 fi
 876
 877 # Need to reject headers which give warnings, so that the -Werror bootstrap
 878 # works later. *sigh*  This needs to come before all header checks.
 879 AC_PROG_CPP_WERROR
 880
 881 AC_HEADER_STDC
 882 AC_HEADER_TIME
 883 ACX_HEADER_STRING
 884 AC_HEADER_SYS_WAIT
 885 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 886                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 887                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 888                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 889
 890 # Check for thread headers.
 891 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 892 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 893
 894 # These tests can't be done till we know if we have limits.h.
 895 gcc_AC_C_CHAR_BIT
 896 AC_C_BIGENDIAN_CROSS
 897
 898 # --------
 899 # UNSORTED
 900 # --------
 901
 902 # Stage specific cflags for build.
 903 stage1_cflags=
 904 case $build in
 905 vax-*-*)
 906   if test x$GCC = xyes
 907   then
 908     stage1_cflags="-Wa,-J"
 909   else
 910     stage1_cflags="-J"
 911   fi
 912   ;;
 913 powerpc-*-darwin*)
 914   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 915   # sources; use -no-cpp-precomp to get to GNU cpp.
 916   # Apple's GCC has bugs in designated initializer handling, so disable
 917   # that too.
 918   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 919   ;;
 920 esac
 921 AC_SUBST(stage1_cflags)
 922
 923 # These libraries may be used by collect2.
 924 # We may need a special search path to get them linked.
 925 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 926 [save_LIBS="$LIBS"
 927 for libs in '' -lld -lmld \
 928                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 929                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 930 do
 931         LIBS="$libs"
 932         AC_TRY_LINK_FUNC(ldopen,
 933                 [gcc_cv_collect2_libs="$libs"; break])
 934 done
 935 LIBS="$save_LIBS"
 936 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 937 case $gcc_cv_collect2_libs in
 938         "none required")        ;;
 939         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 940 esac
 941 AC_SUBST(COLLECT2_LIBS)
 942
 943 # When building Ada code on Alpha, we need exc_resume which is usually in
 944 # -lexc.  So test for it.
 945 save_LIBS="$LIBS"
 946 LIBS=
 947 AC_SEARCH_LIBS(exc_resume, exc)
 948 GNAT_LIBEXC="$LIBS"
 949 LIBS="$save_LIBS"
 950 AC_SUBST(GNAT_LIBEXC)
 951
 952 # Some systems put ldexp and frexp in libm instead of libc; assume
 953 # they're both in the same place.  jcf-dump needs them.
 954 save_LIBS="$LIBS"
 955 LIBS=
 956 AC_SEARCH_LIBS(ldexp, m)
 957 LDEXP_LIB="$LIBS"
 958 LIBS="$save_LIBS"
 959 AC_SUBST(LDEXP_LIB)
 960
 961 # Use <inttypes.h> only if it exists,
 962 # doesn't clash with <sys/types.h>, and declares intmax_t.
 963 AC_MSG_CHECKING(for inttypes.h)
 964 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 965 [AC_TRY_COMPILE(
 966   [#include <sys/types.h>
 967 #include <inttypes.h>],
 968   [intmax_t i = -1;],
 969   [gcc_cv_header_inttypes_h=yes],
 970   gcc_cv_header_inttypes_h=no)])
 971 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 972 if test $gcc_cv_header_inttypes_h = yes; then
 973   AC_DEFINE(HAVE_INTTYPES_H, 1,
 974         [Define if you have a working <inttypes.h> header file.])
 975 fi
 976
 977 dnl Disabled until we have a complete test for buggy enum bitfields.
 978 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 979
 980 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 981   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 982   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 983   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 984   putchar_unlocked putc_unlocked)
 985 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 986         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 987         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 988         gcc_UNLOCKED_FUNCS)
 989
 990 if test x$ac_cv_func_mbstowcs = xyes; then
 991   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 992 [    AC_TRY_RUN([#include <stdlib.h>
 993 int main()
 994 {
 995   mbstowcs(0, "", 0);
 996   return 0;
 997 }],
 998     gcc_cv_func_mbstowcs_works=yes,
 999     gcc_cv_func_mbstowcs_works=no,
1000     gcc_cv_func_mbstowcs_works=yes)])
1001   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1002     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1003   [Define this macro if mbstowcs does not crash when its
1004    first argument is NULL.])
1005   fi
1006 fi
1007
1008 AC_CHECK_TYPE(ssize_t, int)
1009
1010 # Try to determine the array type of the second argument of getgroups
1011 # for the target system (int or gid_t).
1012 AC_TYPE_GETGROUPS
1013 if test "${target}" = "${build}"; then
1014   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1015 else
1016   case "${target}" in
1017         # This condition may need some tweaking.  It should include all
1018         # targets where the array type of the second argument of getgroups
1019         # is int and the type of gid_t is not equivalent to int.
1020         *-*-sunos* | *-*-ultrix*)
1021                 TARGET_GETGROUPS_T=int
1022                 ;;
1023         *)
1024                 TARGET_GETGROUPS_T=gid_t
1025                 ;;
1026   esac
1027 fi
1028 AC_SUBST(TARGET_GETGROUPS_T)
1029
1030 gcc_AC_FUNC_PRINTF_PTR
1031 gcc_AC_FUNC_MMAP_BLACKLIST
1032
1033 case "${host}" in
1034 *-*-*vms*)
1035   # Under VMS, vfork works very differently than on Unix. The standard test
1036   # won't work, and it isn't easily adaptable. It makes more sense to
1037   # just force it.
1038   ac_cv_func_vfork_works=yes
1039   ;;
1040 esac
1041 AC_FUNC_VFORK
1042
1043 AM_ICONV
1044 # Until we have in-tree GNU iconv:
1045 LIBICONV_DEP=
1046 AC_SUBST(LIBICONV_DEP)
1047
1048 AM_LC_MESSAGES
1049
1050 AM_LANGINFO_CODESET
1051
1052 # We will need to find libiberty.h and ansidecl.h
1053 saved_CFLAGS="$CFLAGS"
1054 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1055 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd strsignal \
1056         strstr errno snprintf vsnprintf vasprintf malloc realloc calloc \
1057         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1058 #include "ansidecl.h"
1059 #include "system.h"])
1060
1061 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1062 #include "ansidecl.h"
1063 #include "system.h"
1064 #ifdef HAVE_SYS_RESOURCE_H
1065 #include <sys/resource.h>
1066 #endif
1067 ])
1068
1069 AC_TRY_COMPILE([
1070 #include "ansidecl.h"
1071 #include "system.h"
1072 #ifdef HAVE_SYS_RESOURCE_H
1073 #include <sys/resource.h>
1074 #endif
1075 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1076 [Define to \`long' if <sys/resource.h> doesn't define.])])
1077
1078 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1079 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1080 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1081 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1082 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1083 #include "ansidecl.h"
1084 #include "system.h"
1085 #ifdef HAVE_LDFCN_H
1086 #undef FREAD
1087 #undef FWRITE
1088 #include <ldfcn.h>
1089 #endif
1090 ])
1091
1092 gcc_AC_CHECK_DECLS(times, , ,[
1093 #include "ansidecl.h"
1094 #include "system.h"
1095 #ifdef HAVE_SYS_TIMES_H
1096 #include <sys/times.h>
1097 #endif
1098 ])
1099
1100 # More time-related stuff.
1101 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1102 AC_TRY_COMPILE([
1103 #include "ansidecl.h"
1104 #include "system.h"
1105 #ifdef HAVE_SYS_TIMES_H
1106 #include <sys/times.h>
1107 #endif
1108 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1109 if test $ac_cv_struct_tms = yes; then
1110   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1111   [Define if <sys/times.h> defines struct tms.])
1112 fi
1113
1114 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1115 # revisit after autoconf 2.50.
1116 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1117 AC_TRY_COMPILE([
1118 #include "ansidecl.h"
1119 #include "system.h"
1120 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1121 if test $gcc_cv_type_clock_t = yes; then
1122   AC_DEFINE(HAVE_CLOCK_T, 1,
1123   [Define if <time.h> defines clock_t.])
1124 fi
1125
1126 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1127 CFLAGS="$saved_CFLAGS"
1128
1129 gcc_AC_INITFINI_ARRAY
1130
1131 # mkdir takes a single argument on some systems.
1132 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1133
1134 # File extensions
1135 manext='.1'
1136 objext='.o'
1137 AC_SUBST(manext)
1138 AC_SUBST(objext)
1139
1140 # With Setjmp/Longjmp based exception handling.
1141 AC_ARG_ENABLE(sjlj-exceptions,
1142 [  --enable-sjlj-exceptions
1143                           arrange to use setjmp/longjmp exception handling],
1144 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1145 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1146   [Define 0/1 to force the choice for exception handling model.])])
1147
1148 # For platforms with the unwind ABI which includes an unwind library,
1149 # libunwind, we can choose to use the system libunwind.
1150 AC_ARG_WITH(system-libunwind,
1151 [  --with-system-libunwind use installed libunwind])
1152
1153 # --------------------------------------------------------
1154 # Build, host, and target specific configuration fragments
1155 # --------------------------------------------------------
1156
1157 # Collect build-machine-specific information.
1158 . ${srcdir}/config.build
1159
1160 # Collect host-machine-specific information.
1161 . ${srcdir}/config.host
1162
1163 target_gtfiles=
1164
1165 # Collect target-machine-specific information.
1166 . ${srcdir}/config.gcc
1167
1168 extra_objs="${host_extra_objs} ${extra_objs}"
1169 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1170
1171 # Default the target-machine variables that were not explicitly set.
1172 if test x"$tm_file" = x
1173 then tm_file=$cpu_type/$cpu_type.h; fi
1174
1175 if test x"$extra_headers" = x
1176 then extra_headers=; fi
1177
1178 if test x$md_file = x
1179 then md_file=$cpu_type/$cpu_type.md; fi
1180
1181 if test x$out_file = x
1182 then out_file=$cpu_type/$cpu_type.c; fi
1183
1184 if test x"$tmake_file" = x
1185 then tmake_file=$cpu_type/t-$cpu_type
1186 fi
1187
1188 if test x"$dwarf2" = xyes
1189 then tm_file="$tm_file tm-dwarf2.h"
1190 fi
1191
1192 # Say what files are being used for the output code and MD file.
1193 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1194 echo "Using \`$srcdir/config/$md_file' as machine description file."
1195
1196 # If any of the xm_file variables contain nonexistent files, warn
1197 # about them and drop them.
1198
1199 bx=
1200 for x in $build_xm_file; do
1201   if    test -f $srcdir/config/$x
1202   then      bx="$bx $x"
1203   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1204   fi
1205 done
1206 build_xm_file="$bx"
1207
1208 hx=
1209 for x in $host_xm_file; do
1210   if    test -f $srcdir/config/$x
1211   then      hx="$hx $x"
1212   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1213   fi
1214 done
1215 host_xm_file="$hx"
1216
1217 tx=
1218 for x in $xm_file; do
1219   if    test -f $srcdir/config/$x
1220   then      tx="$tx $x"
1221   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1222   fi
1223 done
1224 xm_file="$tx"
1225
1226 count=a
1227 for f in $tm_file; do
1228         count=${count}x
1229 done
1230 if test $count = ax; then
1231         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1232 else
1233         echo "Using the following target machine macro files:"
1234         for f in $tm_file; do
1235                 echo "  $srcdir/config/$f"
1236         done
1237 fi
1238
1239 if test x$need_64bit_hwint = xyes; then
1240         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1241 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1242 fi
1243
1244 if test x$use_long_long_for_widest_fast_int = xyes; then
1245         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1246 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1247 efficiently supported by the host hardware.])
1248 fi
1249
1250 count=a
1251 for f in $host_xm_file; do
1252         count=${count}x
1253 done
1254 if test $count = a; then
1255         :
1256 elif test $count = ax; then
1257         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1258 else
1259         echo "Using the following host machine macro files:"
1260         for f in $host_xm_file; do
1261                 echo "  $srcdir/config/$f"
1262         done
1263 fi
1264 echo "Using ${out_host_hook_obj} for host machine hooks."
1265
1266 if test "$host_xm_file" != "$build_xm_file"; then
1267         count=a
1268         for f in $build_xm_file; do
1269                 count=${count}x
1270         done
1271         if test $count = a; then
1272                 :
1273         elif test $count = ax; then
1274                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1275         else
1276                 echo "Using the following build machine macro files:"
1277                 for f in $build_xm_file; do
1278                         echo "  $srcdir/config/$f"
1279                 done
1280         fi
1281 fi
1282
1283 # ---------
1284 # Threading
1285 # ---------
1286
1287 # Check if a valid thread package
1288 case ${enable_threads} in
1289   "" | no)
1290     # No threads
1291     target_thread_file='single'
1292     ;;
1293   yes)
1294     # default
1295     target_thread_file='single'
1296     ;;
1297   aix | dce | gnat | irix | posix | posix95 | rtems | \
1298   single | solaris | vxworks | win32 )
1299     target_thread_file=${enable_threads}
1300     ;;
1301   *)
1302     echo "${enable_threads} is an unknown thread package" 1>&2
1303     exit 1
1304     ;;
1305 esac
1306
1307 if test x${thread_file} = x; then
1308   # No thread file set by target-specific clauses in config.gcc,
1309   # so use file chosen by default logic above
1310   thread_file=${target_thread_file}
1311 fi
1312
1313 # Make gthr-default.h if we have a thread file.
1314 gthread_flags=
1315 if test $thread_file != single; then
1316   rm -f gthr-default.h
1317   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1318   gthread_flags=-DHAVE_GTHR_DEFAULT
1319 fi
1320 AC_SUBST(gthread_flags)
1321
1322 # --------
1323 # UNSORTED
1324 # --------
1325
1326 use_cxa_atexit=no
1327 if test x$enable___cxa_atexit = xyes || \
1328    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1329   if test x$host = x$target; then
1330     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1331         [echo "__cxa_atexit can't be enabled on this target"])
1332   else
1333     # We can't check for __cxa_atexit when building a cross, so assume
1334     # it is available
1335     use_cxa_atexit=yes
1336   fi
1337   if test x$use_cxa_atexit = xyes; then
1338     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1339       [Define if you want to use __cxa_atexit, rather than atexit, to
1340       register C++ destructors for local statics and global objects.
1341       This is essential for fully standards-compliant handling of
1342       destructors, but requires __cxa_atexit in libc.])
1343   fi
1344 fi
1345
1346 # Look for a file containing extra machine modes.
1347 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1348   extra_modes_file='$(srcdir)'/config/${extra_modes}
1349   AC_SUBST(extra_modes_file)
1350   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1351   [Define to the name of a file containing a list of extra machine modes
1352    for this architecture.])
1353 fi
1354
1355 # Convert extra_options into a form suitable for Makefile use.
1356 extra_opt_files=
1357 for f in $extra_options; do
1358   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1359 done
1360 AC_SUBST(extra_opt_files)
1361
1362 # auto-host.h is the file containing items generated by autoconf and is
1363 # the first file included by config.h.
1364 # If host=build, it is correct to have bconfig include auto-host.h
1365 # as well.  If host!=build, we are in error and need to do more
1366 # work to find out the build config parameters.
1367 if test x$host = x$build
1368 then
1369         build_auto=auto-host.h
1370 else
1371         # We create a subdir, then run autoconf in the subdir.
1372         # To prevent recursion we set host and build for the new
1373         # invocation of configure to the build for this invocation
1374         # of configure.
1375         tempdir=build.$$
1376         rm -rf $tempdir
1377         mkdir $tempdir
1378         cd $tempdir
1379         case ${srcdir} in
1380         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1381         *) realsrcdir=../${srcdir};;
1382         esac
1383         saved_CFLAGS="${CFLAGS}"
1384         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1385         ${realsrcdir}/configure \
1386                 --enable-languages=${enable_languages-all} \
1387                 --target=$target_alias --host=$build_alias --build=$build_alias
1388         CFLAGS="${saved_CFLAGS}"
1389
1390         # We just finished tests for the build machine, so rename
1391         # the file auto-build.h in the gcc directory.
1392         mv auto-host.h ../auto-build.h
1393         cd ..
1394         rm -rf $tempdir
1395         build_auto=auto-build.h
1396 fi
1397 AC_SUBST(build_subdir)
1398
1399 tm_file="${tm_file} defaults.h"
1400 tm_p_file="${tm_p_file} tm-preds.h"
1401 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1402 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1403 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1404 # put this back in temporarily.
1405 xm_file="ansidecl.h ${xm_file}"
1406
1407 # --------
1408 # UNSORTED
1409 # --------
1410
1411 changequote(,)dnl
1412 # Compile in configure arguments.
1413 if test -f configargs.h ; then
1414         # Being re-configured.
1415         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1416         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1417 else
1418         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1419 fi
1420
1421 # Double all backslashes and backslash all quotes to turn
1422 # gcc_config_arguments into a C string.
1423 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1424 $gcc_config_arguments
1425 EOF
1426 gcc_config_arguments_str=`cat conftest.out`
1427 rm -f conftest.out
1428
1429 cat > configargs.h <<EOF
1430 /* Generated automatically. */
1431 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1432 static const char thread_model[] = "$thread_file";
1433
1434 static const struct {
1435   const char *name, *value;
1436 } configure_default_options[] = $configure_default_options;
1437 EOF
1438 changequote([,])dnl
1439
1440 # Internationalization
1441 ZW_GNU_GETTEXT_SISTER_DIR
1442
1443 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1444 # -liconv on the link line twice.
1445 case "$LIBINTL" in *$LIBICONV*)
1446         LIBICONV= ;;
1447 esac
1448
1449 # Windows32 Registry support for specifying GCC installation paths.
1450 AC_ARG_ENABLE(win32-registry,
1451 [  --disable-win32-registry
1452                           disable lookup of installation paths in the
1453                           Registry on Windows hosts
1454   --enable-win32-registry enable registry lookup (default)
1455   --enable-win32-registry=KEY
1456                           use KEY instead of GCC version as the last portion
1457                           of the registry key],,)
1458
1459 case $host_os in
1460   win32 | pe | cygwin* | mingw32* | uwin*)
1461     if test "x$enable_win32_registry" != xno; then
1462       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1463     fi
1464
1465     if test "x$enable_win32_registry" != xno; then
1466       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1467   [Define to 1 if installation paths should be looked up in the Windows
1468    Registry. Ignored on non-Windows hosts.])
1469
1470       if test "x$enable_win32_registry" != xyes \
1471          && test "x$enable_win32_registry" != x; then
1472         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1473   [Define to be the last component of the Windows registry key under which
1474    to look for installation paths.  The full key used will be
1475    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1476    The default is the GCC version number.])
1477       fi
1478     fi
1479   ;;
1480 esac
1481
1482 # Get an absolute path to the GCC top-level source directory
1483 holddir=`${PWDCMD-pwd}`
1484 cd $srcdir
1485 topdir=`${PWDCMD-pwd}`
1486 cd $holddir
1487
1488 # Conditionalize the makefile for this host machine.
1489 xmake_file=
1490 for f in ${host_xmake_file}
1491 do
1492         if test -f ${srcdir}/config/$f
1493         then
1494                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1495         fi
1496 done
1497
1498 # Conditionalize the makefile for this target machine.
1499 tmake_file_=
1500 for f in ${tmake_file}
1501 do
1502         if test -f ${srcdir}/config/$f
1503         then
1504                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1505         fi
1506 done
1507 tmake_file="${tmake_file_}"
1508
1509 # If the host doesn't support symlinks, modify CC in
1510 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1511 # Otherwise, we can use "CC=$(CC)".
1512 rm -f symtest.tem
1513 case "$LN_S" in
1514         *-s*)
1515                 cc_set_by_configure="\$(CC)"
1516                 quoted_cc_set_by_configure="\$(CC)"
1517                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1518                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1519                 ;;
1520         *)
1521                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1522                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1523                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1524                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1525                 ;;
1526 esac
1527
1528 # This is a terrible hack which will go away some day.
1529 host_cc_for_libada=${CC}
1530 AC_SUBST(host_cc_for_libada)
1531
1532 out_object_file=`basename $out_file .c`.o
1533
1534 tm_file_list="options.h"
1535 tm_include_list="options.h"
1536 for f in $tm_file; do
1537   case $f in
1538     defaults.h )
1539        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1540        tm_include_list="${tm_include_list} $f"
1541        ;;
1542     * )
1543        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1544        tm_include_list="${tm_include_list} config/$f"
1545        ;;
1546   esac
1547 done
1548
1549 tm_p_file_list=
1550 tm_p_include_list=
1551 for f in $tm_p_file; do
1552   case $f in
1553     tm-preds.h )
1554        tm_p_file_list="${tm_p_file_list} $f"
1555        tm_p_include_list="${tm_p_include_list} $f"
1556        ;;
1557     * )
1558        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1559        tm_p_include_list="${tm_p_include_list} config/$f"
1560   esac
1561 done
1562
1563 xm_file_list=
1564 xm_include_list=
1565 for f in $xm_file; do
1566   case $f in
1567     ansidecl.h )
1568        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1569        xm_include_list="${xm_include_list} $f"
1570        ;;
1571     auto-host.h )
1572        xm_file_list="${xm_file_list} $f"
1573        xm_include_list="${xm_include_list} $f"
1574        ;;
1575     * )
1576        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1577        xm_include_list="${xm_include_list} config/$f"
1578        ;;
1579   esac
1580 done
1581
1582 host_xm_file_list=
1583 host_xm_include_list=
1584 for f in $host_xm_file; do
1585   case $f in
1586     ansidecl.h )
1587        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1588        host_xm_include_list="${host_xm_include_list} $f"
1589        ;;
1590     auto-host.h )
1591        host_xm_file_list="${host_xm_file_list} $f"
1592        host_xm_include_list="${host_xm_include_list} $f"
1593        ;;
1594     * )
1595        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1596        host_xm_include_list="${host_xm_include_list} config/$f"
1597        ;;
1598   esac
1599 done
1600
1601 build_xm_file_list=
1602 for f in $build_xm_file; do
1603   case $f in
1604     ansidecl.h )
1605        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1606        build_xm_include_list="${build_xm_include_list} $f"
1607        ;;
1608     auto-build.h | auto-host.h )
1609        build_xm_file_list="${build_xm_file_list} $f"
1610        build_xm_include_list="${build_xm_include_list} $f"
1611        ;;
1612     * )
1613        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1614        build_xm_include_list="${build_xm_include_list} config/$f"
1615        ;;
1616   esac
1617 done
1618
1619 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1620 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1621 CROSS=                                          AC_SUBST(CROSS)
1622 ALL=all.internal                                AC_SUBST(ALL)
1623 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1624 if test x$host != x$target
1625 then
1626         CROSS="-DCROSS_COMPILE"
1627         ALL=all.cross
1628         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1629         case "$host","$target" in
1630         # Darwin crosses can use the host system's libraries and headers,
1631         # because of the fat library support.  Of course, it must be the
1632         # same version of Darwin on both sides.  Allow the user to
1633         # just say --target=foo-darwin without a version number to mean
1634         # "the version on this system".
1635             *-*-darwin*,*-*-darwin*)
1636                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1637                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1638                 if test $hostos = $targetos -o $targetos = darwin ; then
1639                     CROSS=
1640                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1641                     with_headers=yes
1642                 fi
1643                 ;;
1644
1645             i?86-*-*,x86_64-*-* \
1646             | powerpc*-*-*,powerpc64*-*-*)
1647                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1648         esac
1649 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1650         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1651         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1652 fi
1653
1654 # If this is a cross-compiler that does not
1655 # have its own set of headers then define
1656 # inhibit_libc
1657
1658 # If this is using newlib, without having the headers available now,
1659 # then define inhibit_libc in LIBGCC2_CFLAGS.
1660 # This prevents libgcc2 from containing any code which requires libc
1661 # support.
1662 inhibit_libc=
1663 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1664        test x$with_newlib = xyes ; } &&
1665      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1666        inhibit_libc=-Dinhibit_libc
1667 fi
1668 AC_SUBST(inhibit_libc)
1669
1670 # When building gcc with a cross-compiler, we need to adjust things so
1671 # that the generator programs are still built with the native compiler.
1672 # Also, we cannot run fixincludes or fix-header.
1673
1674 # These are the normal (build=host) settings:
1675 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1676 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1677 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1678
1679 # Possibly disable fixproto, on a per-target basis.
1680 case ${use_fixproto} in
1681   no)
1682     STMP_FIXPROTO=
1683     ;;
1684   yes)
1685     STMP_FIXPROTO=stmp-fixproto
1686     ;;
1687 esac
1688 AC_SUBST(STMP_FIXPROTO)
1689
1690 # And these apply if build != host, or we are generating coverage data
1691 if test x$build != x$host || test "x$coverage_flags" != x
1692 then
1693     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1694
1695     if test "x$TARGET_SYSTEM_ROOT" = x; then
1696         if [ "x$STMP_FIXPROTO" != x ] ; then
1697           STMP_FIXPROTO=stmp-install-fixproto
1698         fi
1699     fi
1700 fi
1701
1702 # Expand extra_headers to include complete path.
1703 # This substitutes for lots of t-* files.
1704 extra_headers_list=
1705 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1706 for file in ${extra_headers} ; do
1707   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1708 done
1709
1710 # Define collect2 in Makefile.
1711 case $host_can_use_collect2 in
1712   no) collect2= ;;
1713   *) collect2='collect2$(exeext)' ;;
1714 esac
1715 AC_SUBST([collect2])
1716
1717 # Add a definition of USE_COLLECT2 if system wants one.
1718 case $use_collect2 in
1719   no) use_collect2= ;;
1720   "") ;;
1721   *)
1722     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1723     xm_defines="${xm_defines} USE_COLLECT2"
1724     case $host_can_use_collect2 in
1725       no)
1726         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1727         ;;
1728     esac
1729     ;;
1730 esac
1731
1732 # ---------------------------
1733 # Assembler & linker features
1734 # ---------------------------
1735
1736 # Identify the assembler which will work hand-in-glove with the newly
1737 # built GCC, so that we can examine its features.  This is the assembler
1738 # which will be driven by the driver program.
1739 #
1740 # If build != host, and we aren't building gas in-tree, we identify a
1741 # build->target assembler and hope that it will have the same features
1742 # as the host->target assembler we'll be using.
1743 AC_MSG_CHECKING(what assembler to use)
1744 in_tree_gas=no
1745 gcc_cv_as=
1746 gcc_cv_gas_major_version=
1747 gcc_cv_gas_minor_version=
1748 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1749 if test -x "$DEFAULT_ASSEMBLER"; then
1750         gcc_cv_as="$DEFAULT_ASSEMBLER"
1751 elif test -x as$build_exeext; then
1752         # Build using assembler in the current directory.
1753         gcc_cv_as=./as$build_exeext
1754 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1755      && test -f ../gas/Makefile \
1756      && test x$build = x$host; then
1757   # Single tree build which includes gas.  We want to prefer it
1758   # over whatever linker top-level may have detected, since
1759   # we'll use what we're building after installation anyway.
1760   in_tree_gas=yes
1761   _gcc_COMPUTE_GAS_VERSION
1762   rm -f as$build_exeext
1763   $LN_S ../gas/as-new$build_exeext as$build_exeext 2>/dev/null
1764   in_tree_gas_is_elf=no
1765   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1766      || (grep 'obj_format = multi' ../gas/Makefile \
1767          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1768   then
1769     in_tree_gas_is_elf=yes
1770   fi
1771 m4_pattern_allow([AS_FOR_TARGET])dnl
1772 elif test -x "$AS_FOR_TARGET"; then
1773         gcc_cv_as="$AS_FOR_TARGET"
1774 elif test -x "$AS" && test x$host = x$target; then
1775         gcc_cv_as="$AS"
1776 fi
1777
1778 gcc_version=`cat $srcdir/BASE-VER`
1779
1780 if test "x$gcc_cv_as" = x; then
1781         # Search the same directories that the installed compiler will
1782         # search.  Else we may find the wrong assembler and lose.  If we
1783         # do not find a suitable assembler binary, then try the user's
1784         # path.
1785         #
1786         # Also note we have to check MD_EXEC_PREFIX before checking the
1787         # user's path.  Unfortunately, there is no good way to get at the
1788         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1789         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1790         # to be fixed as part of the make/configure rewrite too.
1791
1792         if test "x$exec_prefix" = xNONE; then
1793                 if test "x$prefix" = xNONE; then
1794                         test_prefix=/usr/local
1795                 else
1796                         test_prefix=$prefix
1797                 fi
1798         else
1799                 test_prefix=$exec_prefix
1800         fi
1801
1802         # If the loop below does not find an assembler, then use whatever
1803         # one we can find in the users's path.  We are looking for a
1804         # ${build} -> ${target} assembler.
1805         if test "x$program_prefix" != xNONE; then
1806                 gcc_cv_as=${program_prefix}as$build_exeext
1807         elif test x$build != x$host && test x$build != x$target; then
1808                 gcc_cv_as=${target_noncanonical}-as$build_exeext
1809         else
1810                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$build_exeext
1811         fi
1812
1813         if test x$host = x$build; then
1814             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1815                        $test_prefix/libexec/gcc/$target_noncanonical \
1816                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1817                        /usr/lib/gcc/$target_noncanonical \
1818                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1819                        $test_prefix/$target_noncanonical/bin"
1820         else
1821             test_dirs=
1822         fi
1823
1824         if test x$build = x$target; then
1825             test_dirs="$test_dirs \
1826                    /usr/libexec \
1827                    /usr/ccs/gcc \
1828                    /usr/ccs/bin \
1829                    /udk/usr/ccs/bin \
1830                    /bsd43/usr/lib/cmplrs/cc \
1831                    /usr/cross64/usr/bin \
1832                    /usr/lib/cmplrs/cc \
1833                    /sysv/usr/lib/cmplrs/cc \
1834                    /svr4/usr/lib/cmplrs/cc \
1835                    /usr/bin"
1836         fi
1837
1838         for dir in $test_dirs; do
1839                 if test -x $dir/as$build_exeext; then
1840                         gcc_cv_as=$dir/as$build_exeext
1841                         break;
1842                 fi
1843         done
1844 fi
1845 case $in_tree_gas in
1846   yes)
1847     AC_MSG_RESULT("newly built gas")
1848     ;;
1849   no)
1850     AC_MSG_RESULT($gcc_cv_as)
1851     ;;
1852 esac
1853
1854 # Identify the linker which will work hand-in-glove with the newly
1855 # built GCC, so that we can examine its features.  This is the linker
1856 # which will be driven by the driver program.
1857 #
1858 # If build != host, and we aren't building gas in-tree, we identify a
1859 # build->target linker and hope that it will have the same features
1860 # as the host->target linker we'll be using.
1861 AC_MSG_CHECKING(what linker to use)
1862 in_tree_ld=no
1863 gcc_cv_ld=
1864 gcc_cv_gld_major_version=
1865 gcc_cv_gld_minor_version=
1866 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1867 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1868 if test -x "$DEFAULT_LINKER"; then
1869         gcc_cv_ld="$DEFAULT_LINKER"
1870 elif test -x collect-ld$build_exeext; then
1871         # Build using linker in the current directory.
1872         gcc_cv_ld=./collect-ld$build_exeext
1873 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1874      && test -f ../ld/Makefile \
1875      && test x$build = x$host; then
1876         # Single tree build which includes ld.  We want to prefer it
1877         # over whatever linker top-level may have detected, since
1878         # we'll use what we're building after installation anyway.
1879         in_tree_ld=yes
1880         in_tree_ld_is_elf=no
1881         if (grep 'EMUL = .*elf' ../ld/Makefile \
1882             || grep 'EMUL = .*linux' ../ld/Makefile \
1883             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1884           in_tree_ld_is_elf=yes
1885         fi
1886         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1887         do
1888 changequote(,)dnl
1889                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1890 changequote([,])dnl
1891                 if test x$gcc_cv_gld_version != x; then
1892                         break
1893                 fi
1894         done
1895 changequote(,)dnl
1896         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1897         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1898 changequote([,])dnl
1899         rm -f collect-ld$build_exeext
1900         $LN_S ../ld/ld-new$build_exeext collect-ld$build_exeext 2>/dev/null
1901 elif test -x "$LD_FOR_TARGET"; then
1902         gcc_cv_ld="$LD_FOR_TARGET"
1903 elif test -x "$LD" && test x$host = x$target; then
1904         gcc_cv_ld="$LD"
1905 fi
1906
1907 if test "x$gcc_cv_ld" = x; then
1908         # Search the same directories that the installed compiler will
1909         # search.  Else we may find the wrong linker and lose.  If we
1910         # do not find a suitable linker binary, then try the user's
1911         # path.
1912         #
1913         # Also note we have to check MD_EXEC_PREFIX before checking the
1914         # user's path.  Unfortunately, there is no good way to get at the
1915         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1916         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1917         # to be fixed as part of the make/configure rewrite too.
1918
1919         if test "x$exec_prefix" = xNONE; then
1920                 if test "x$prefix" = xNONE; then
1921                         test_prefix=/usr/local
1922                 else
1923                         test_prefix=$prefix
1924                 fi
1925         else
1926                 test_prefix=$exec_prefix
1927         fi
1928
1929         # If the loop below does not find a linker, then use whatever
1930         # one we can find in the users's path.  We are looking for a
1931         # ${build} -> ${target} linker.
1932         if test "x$program_prefix" != xNONE; then
1933                 gcc_cv_ld=${program_prefix}ld$build_exeext
1934         elif test x$build != x$host && test x$build != x$target; then
1935                 gcc_cv_ld=${target_noncanonical}-ld$build_exeext
1936         else
1937                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$build_exeext
1938         fi
1939
1940         if test x$host = x$build; then
1941             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1942                        $test_prefix/libexec/gcc/$target_noncanonical \
1943                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1944                        /usr/lib/gcc/$target_noncanonical \
1945                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1946                        $test_prefix/$target_noncanonical/bin"
1947         else
1948             test_dirs=
1949         fi
1950
1951         if test x$build = x$target; then
1952             test_dirs="$test_dirs \
1953                    /usr/libexec \
1954                    /usr/ccs/gcc \
1955                    /usr/ccs/bin \
1956                    /udk/usr/ccs/bin \
1957                    /bsd43/usr/lib/cmplrs/cc \
1958                    /usr/cross64/usr/bin \
1959                    /usr/lib/cmplrs/cc \
1960                    /sysv/usr/lib/cmplrs/cc \
1961                    /svr4/usr/lib/cmplrs/cc \
1962                    /usr/bin"
1963         fi
1964
1965         for dir in $test_dirs; do
1966                 if test -x $dir/ld$build_exeext; then
1967                         gcc_cv_ld=$dir/ld$build_exeext
1968                         break;
1969                 fi
1970         done
1971 fi
1972 case $in_tree_ld in
1973   yes)
1974     AC_MSG_RESULT("newly built ld")
1975     ;;
1976   no)
1977     AC_MSG_RESULT($gcc_cv_ld)
1978     ;;
1979 esac
1980
1981 # Figure out what nm we will be using.
1982 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1983 AC_MSG_CHECKING(what nm to use)
1984 in_tree_nm=no
1985 if test -x nm$build_exeext; then
1986         gcc_cv_nm=./nm$build_exeext
1987 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1988      && test -f ../binutils/Makefile; then
1989         # Single tree build which includes binutils.
1990         in_tree_nm=yes
1991         gcc_cv_nm=./nm$build_exeext
1992         rm -f nm$build_exeext
1993         $LN_S ../binutils/nm-new$build_exeext nm$build_exeext 2>/dev/null
1994 elif test "x$program_prefix" != xNONE; then
1995         gcc_cv_nm=${program_prefix}nm$build_exeext
1996 elif test x$build != x$host && test x$build != x$target; then
1997         gcc_cv_nm=${target_noncanonical}-nm$build_exeext
1998 else
1999         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$build_exeext
2000 fi
2001 case $in_tree_nm in
2002   yes) AC_MSG_RESULT("newly built nm") ;;
2003   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
2004 esac
2005
2006 # Figure out what objdump we will be using.
2007 AC_MSG_CHECKING(what objdump to use)
2008 in_tree_objdump=no
2009 if test -x objdump$build_exeext; then
2010         gcc_cv_objdump=./objdump$build_exeext
2011 elif test -f $gcc_cv_binutils_srcdir/configure.in \
2012      && test -f ../binutils/Makefile; then
2013         # Single tree build which includes binutils.
2014         in_tree_objdump=yes
2015         gcc_cv_objdump=./objdump$build_exeext
2016         rm -f objdump$build_exeext
2017         $LN_S ../binutils/objdump$build_exeext objdump$build_exeext 2>/dev/null
2018 elif test "x$program_prefix" != xNONE; then
2019         gcc_cv_objdump=${program_prefix}objdump$build_exeext
2020 elif test x$build != x$host && test x$build != x$target; then
2021         gcc_cv_objdump=${target_noncanonical}-objdump$build_exeext
2022 else
2023         gcc_cv_objdump=`echo objdump | \
2024                 sed "${program_transform_name}"`$build_exeext
2025 fi
2026 case $in_tree_objdump in
2027   yes) AC_MSG_RESULT("newly built objdump") ;;
2028   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
2029 esac
2030
2031 # Figure out what assembler alignment features are present.
2032 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2033  [2,6,0],,
2034 [.balign 4
2035 .p2align 2],,
2036 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2037   [Define if your assembler supports .balign and .p2align.])])
2038
2039 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2040  [2,8,0],,
2041  [.p2align 4,,7],,
2042 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2043   [Define if your assembler supports specifying the maximum number
2044    of bytes to skip when using the GAS .p2align command.])])
2045
2046 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2047  [elf,2,9,0],,
2048  [conftest_label1: .word 0
2049 .subsection -1
2050 conftest_label2: .word 0
2051 .previous],
2052  [if test x$gcc_cv_nm != x; then
2053     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2054     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2055     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2056     then :
2057     else gcc_cv_as_subsection_m1=yes
2058     fi
2059     rm -f conftest.nm1 conftest.nm2
2060   fi],
2061  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2062   [Define if your assembler supports .subsection and .subsection -1 starts
2063    emitting at the beginning of your section.])])
2064
2065 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2066  [2,2,0],,
2067  [      .weak foobar],,
2068 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2069
2070 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2071  [2,15,91],,
2072  [      .SPACE $TEXT$
2073         .NSUBSPA $CODE$,COMDAT],,
2074 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2075
2076 # .hidden needs to be supported in both the assembler and the linker,
2077 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2078 # This is irritatingly difficult to feature test for; we have to check the
2079 # date string after the version number.  If we've got an in-tree
2080 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2081 # to be safe.
2082 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2083 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2084  [elf,2,13,0],,
2085 [       .hidden foobar
2086 foobar:])
2087
2088 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2089 [if test $in_tree_ld = yes ; then
2090   gcc_cv_ld_hidden=no
2091   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2092      && test $in_tree_ld_is_elf = yes; then
2093      gcc_cv_ld_hidden=yes
2094   fi
2095 else
2096   gcc_cv_ld_hidden=yes
2097   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2098   if echo "$ld_ver" | grep GNU > /dev/null; then
2099 changequote(,)dnl
2100     ld_vers=`echo $ld_ver | sed -n \
2101         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2102         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2103         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2104         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2105         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2106         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2107     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2108     if test 0"$ld_date" -lt 20020404; then
2109       if test -n "$ld_date"; then
2110         # If there was date string, but was earlier than 2002-04-04, fail
2111         gcc_cv_ld_hidden=no
2112       elif test -z "$ld_vers"; then
2113         # If there was no date string nor ld version number, something is wrong
2114         gcc_cv_ld_hidden=no
2115       else
2116         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2117         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2118         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2119         test -z "$ld_vers_patch" && ld_vers_patch=0
2120         if test "$ld_vers_major" -lt 2; then
2121           gcc_cv_ld_hidden=no
2122         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2123           gcc_cv_ld_hidden="no"
2124         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2125           gcc_cv_ld_hidden=no
2126         fi
2127       fi
2128 changequote([,])dnl
2129     fi
2130   else
2131     case "${target}" in
2132       hppa64*-*-hpux* | ia64*-*-hpux*)
2133         gcc_cv_ld_hidden=yes
2134         ;;
2135       *)
2136         gcc_cv_ld_hidden=no
2137         ;;
2138     esac
2139   fi
2140 fi])
2141 libgcc_visibility=no
2142 AC_SUBST(libgcc_visibility)
2143 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2144   libgcc_visibility=yes
2145   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2146   [Define if your assembler and linker support .hidden.])
2147 fi
2148
2149 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2150 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2151   [elf,2,11,0],,
2152 [       .data
2153         .uleb128 L2 - L1
2154 L1:
2155         .uleb128 1280
2156         .sleb128 -1010
2157 L2:],
2158  [# GAS versions before 2.11 do not support uleb128,
2159   # despite appearing to.
2160   # ??? There exists an elf-specific test that will crash
2161   # the assembler.  Perhaps it's better to figure out whether
2162   # arbitrary sections are supported and try the test.
2163   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2164   if echo "$as_ver" | grep GNU > /dev/null; then
2165 changequote(,)dnl
2166     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2167     as_major=`echo $as_ver | sed 's/\..*//'`
2168     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2169 changequote([,])dnl
2170     if test $as_major -eq 2 && test $as_minor -lt 11
2171     then :
2172     else gcc_cv_as_leb128=yes
2173     fi
2174   fi],
2175   [AC_DEFINE(HAVE_AS_LEB128, 1,
2176     [Define if your assembler supports .sleb128 and .uleb128.])])
2177
2178 # GAS versions up to and including 2.11.0 may mis-optimize
2179 # .eh_frame data.
2180 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2181   [elf,2,12,0],,
2182 [       .text
2183 .LFB1:
2184         .4byte  0
2185 .L1:
2186         .4byte  0
2187 .LFE1:
2188         .section        .eh_frame,"aw",@progbits
2189 __FRAME_BEGIN__:
2190         .4byte  .LECIE1-.LSCIE1
2191 .LSCIE1:
2192         .4byte  0x0
2193         .byte   0x1
2194         .ascii "z\0"
2195         .byte   0x1
2196         .byte   0x78
2197         .byte   0x1a
2198         .byte   0x0
2199         .byte   0x4
2200         .4byte  1
2201         .p2align 1
2202 .LECIE1:
2203 .LSFDE1:
2204         .4byte  .LEFDE1-.LASFDE1
2205 .LASFDE1:
2206         .4byte  .LASFDE1-__FRAME_BEGIN__
2207         .4byte  .LFB1
2208         .4byte  .LFE1-.LFB1
2209         .byte   0x4
2210         .4byte  .LFE1-.LFB1
2211         .byte   0x4
2212         .4byte  .L1-.LFB1
2213 .LEFDE1:],
2214 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2215 cat > conftest.lit <<EOF
2216  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2217  0010 01000000 12000000 18000000 00000000  ................
2218  0020 08000000 04080000 0044               .........D      @&t@
2219 EOF
2220 cat > conftest.big <<EOF
2221  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2222  0010 00000001 00000012 00000018 00000000  ................
2223  0020 00000008 04000000 0844               .........D      @&t@
2224 EOF
2225   # If the assembler didn't choke, and we can objdump,
2226   # and we got the correct data, then succeed.
2227   if test x$gcc_cv_objdump != x \
2228   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2229      | tail -3 > conftest.got \
2230   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2231     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2232   then
2233     gcc_cv_as_eh_frame=yes
2234   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2235     gcc_cv_as_eh_frame=buggy
2236   else
2237     # Uh oh, what do we do now?
2238     gcc_cv_as_eh_frame=no
2239   fi])
2240
2241 if test $gcc_cv_as_eh_frame = buggy; then
2242   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2243   [Define if your assembler mis-optimizes .eh_frame data.])
2244 fi
2245
2246 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2247  [elf,2,12,0], [--fatal-warnings],
2248  [.section .rodata.str, "aMS", @progbits, 1])
2249 if test $gcc_cv_as_shf_merge = no; then
2250   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2251     [elf,2,12,0], [--fatal-warnings],
2252     [.section .rodata.str, "aMS", %progbits, 1])
2253 fi
2254 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2255   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2256 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2257
2258 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2259  [elf,2,15,91], [--fatal-warnings],
2260  [.section .text,"axG",@progbits,.foo,comdat])
2261 if test $gcc_cv_as_comdat_group = yes; then
2262   gcc_cv_as_comdat_group_percent=no
2263 else
2264  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2265    [elf,2,15,91], [--fatal-warnings],
2266    [.section .text,"axG",%progbits,.foo,comdat])
2267 fi
2268 AC_DEFINE_UNQUOTED(HAVE_GAS_COMDAT_GROUP,
2269   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2270 [Define 0/1 if your assembler supports COMDAT group.])
2271
2272 # Thread-local storage - the check is heavily parametrized.
2273 conftest_s=
2274 tls_first_major=
2275 tls_first_minor=
2276 tls_as_opt=
2277 case "$target" in
2278 changequote(,)dnl
2279   alpha*-*-*)
2280     conftest_s='
2281         .section ".tdata","awT",@progbits
2282 foo:    .long   25
2283         .text
2284         ldq     $27,__tls_get_addr($29)         !literal!1
2285         lda     $16,foo($29)                    !tlsgd!1
2286         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2287         ldq     $27,__tls_get_addr($29)         !literal!2
2288         lda     $16,foo($29)                    !tlsldm!2
2289         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2290         ldq     $1,foo($29)                     !gotdtprel
2291         ldah    $2,foo($29)                     !dtprelhi
2292         lda     $3,foo($2)                      !dtprello
2293         lda     $4,foo($29)                     !dtprel
2294         ldq     $1,foo($29)                     !gottprel
2295         ldah    $2,foo($29)                     !tprelhi
2296         lda     $3,foo($2)                      !tprello
2297         lda     $4,foo($29)                     !tprel'
2298         tls_first_major=2
2299         tls_first_minor=13
2300         tls_as_opt=--fatal-warnings
2301         ;;
2302   frv*-*-*)
2303     conftest_s='
2304         .section ".tdata","awT",@progbits
2305 x:      .long   25
2306         .text
2307         call    #gettlsoff(x)'
2308         tls_first_major=2
2309         tls_first_minor=14
2310         ;;
2311   i[34567]86-*-*)
2312     conftest_s='
2313         .section ".tdata","awT",@progbits
2314 foo:    .long   25
2315         .text
2316         movl    %gs:0, %eax
2317         leal    foo@TLSGD(,%ebx,1), %eax
2318         leal    foo@TLSLDM(%ebx), %eax
2319         leal    foo@DTPOFF(%eax), %edx
2320         movl    foo@GOTTPOFF(%ebx), %eax
2321         subl    foo@GOTTPOFF(%ebx), %eax
2322         addl    foo@GOTNTPOFF(%ebx), %eax
2323         movl    foo@INDNTPOFF, %eax
2324         movl    $foo@TPOFF, %eax
2325         subl    $foo@TPOFF, %eax
2326         leal    foo@NTPOFF(%ecx), %eax'
2327         tls_first_major=2
2328         tls_first_minor=14
2329         tls_as_opt=--fatal-warnings
2330         ;;
2331   x86_64-*-*)
2332     conftest_s='
2333         .section ".tdata","awT",@progbits
2334 foo:    .long   25
2335         .text
2336         movq    %fs:0, %rax
2337         leaq    foo@TLSGD(%rip), %rdi
2338         leaq    foo@TLSLD(%rip), %rdi
2339         leaq    foo@DTPOFF(%rax), %rdx
2340         movq    foo@GOTTPOFF(%rip), %rax
2341         movq    $foo@TPOFF, %rax'
2342         tls_first_major=2
2343         tls_first_minor=14
2344         tls_as_opt=--fatal-warnings
2345         ;;
2346   ia64-*-*)
2347     conftest_s='
2348         .section ".tdata","awT",@progbits
2349 foo:    data8   25
2350         .text
2351         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2352         addl    r17 = @ltoff(@dtprel(foo#)), gp
2353         addl    r18 = @ltoff(@tprel(foo#)), gp
2354         addl    r19 = @dtprel(foo#), gp
2355         adds    r21 = @dtprel(foo#), r13
2356         movl    r23 = @dtprel(foo#)
2357         addl    r20 = @tprel(foo#), gp
2358         adds    r22 = @tprel(foo#), r13
2359         movl    r24 = @tprel(foo#)'
2360         tls_first_major=2
2361         tls_first_minor=13
2362         tls_as_opt=--fatal-warnings
2363         ;;
2364   mips*-*-*)
2365     conftest_s='
2366         .section .tdata,"awT",@progbits
2367 x:
2368         .word 2
2369         .text
2370         addiu $4, $28, %tlsgd(x)
2371         addiu $4, $28, %tlsldm(x)
2372         lui $4, %dtprel_hi(x)
2373         addiu $4, $4, %dtprel_lo(x)
2374         lw $4, %gottprel(x)($28)
2375         lui $4, %tprel_hi(x)
2376         addiu $4, $4, %tprel_lo(x)'
2377         tls_first_major=2
2378         tls_first_minor=16
2379         tls_as_opt='-32 --fatal-warnings'
2380         ;;
2381   powerpc-*-*)
2382     conftest_s='
2383         .section ".tdata","awT",@progbits
2384         .align 2
2385 ld0:    .space 4
2386 ld1:    .space 4
2387 x1:     .space 4
2388 x2:     .space 4
2389 x3:     .space 4
2390         .text
2391         addi 3,31,ld0@got@tlsgd
2392         bl __tls_get_addr
2393         addi 3,31,x1@got@tlsld
2394         bl __tls_get_addr
2395         addi 9,3,x1@dtprel
2396         addis 9,3,x2@dtprel@ha
2397         addi 9,9,x2@dtprel@l
2398         lwz 9,x3@got@tprel(31)
2399         add 9,9,x@tls
2400         addi 9,2,x1@tprel
2401         addis 9,2,x2@tprel@ha
2402         addi 9,9,x2@tprel@l'
2403         tls_first_major=2
2404         tls_first_minor=14
2405         tls_as_opt="-a32 --fatal-warnings"
2406         ;;
2407   powerpc64-*-*)
2408     conftest_s='
2409         .section ".tdata","awT",@progbits
2410         .align 3
2411 ld0:    .space 8
2412 ld1:    .space 8
2413 x1:     .space 8
2414 x2:     .space 8
2415 x3:     .space 8
2416         .text
2417         addi 3,2,ld0@got@tlsgd
2418         bl .__tls_get_addr
2419         nop
2420         addi 3,2,ld1@toc
2421         bl .__tls_get_addr
2422         nop
2423         addi 3,2,x1@got@tlsld
2424         bl .__tls_get_addr
2425         nop
2426         addi 9,3,x1@dtprel
2427         bl .__tls_get_addr
2428         nop
2429         addis 9,3,x2@dtprel@ha
2430         addi 9,9,x2@dtprel@l
2431         bl .__tls_get_addr
2432         nop
2433         ld 9,x3@got@dtprel(2)
2434         add 9,9,3
2435         bl .__tls_get_addr
2436         nop'
2437         tls_first_major=2
2438         tls_first_minor=14
2439         tls_as_opt="-a64 --fatal-warnings"
2440         ;;
2441   s390-*-*)
2442     conftest_s='
2443         .section ".tdata","awT",@progbits
2444 foo:    .long   25
2445         .text
2446         .long   foo@TLSGD
2447         .long   foo@TLSLDM
2448         .long   foo@DTPOFF
2449         .long   foo@NTPOFF
2450         .long   foo@GOTNTPOFF
2451         .long   foo@INDNTPOFF
2452         l       %r1,foo@GOTNTPOFF(%r12)
2453         l       %r1,0(%r1):tls_load:foo
2454         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2455         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2456         tls_first_major=2
2457         tls_first_minor=14
2458         tls_as_opt="-m31 --fatal-warnings"
2459         ;;
2460   s390x-*-*)
2461     conftest_s='
2462         .section ".tdata","awT",@progbits
2463 foo:    .long   25
2464         .text
2465         .quad   foo@TLSGD
2466         .quad   foo@TLSLDM
2467         .quad   foo@DTPOFF
2468         .quad   foo@NTPOFF
2469         .quad   foo@GOTNTPOFF
2470         lg      %r1,foo@GOTNTPOFF(%r12)
2471         larl    %r1,foo@INDNTPOFF
2472         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2473         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2474         tls_first_major=2
2475         tls_first_minor=14
2476         tls_as_opt="-m64 -Aesame --fatal-warnings"
2477         ;;
2478   sh-*-* | sh[34]-*-*)
2479     conftest_s='
2480         .section ".tdata","awT",@progbits
2481 foo:    .long   25
2482         .text
2483         .long   foo@TLSGD
2484         .long   foo@TLSLDM
2485         .long   foo@DTPOFF
2486         .long   foo@GOTTPOFF
2487         .long   foo@TPOFF'
2488         tls_first_major=2
2489         tls_first_minor=13
2490         tls_as_opt=--fatal-warnings
2491         ;;
2492   sparc*-*-*)
2493     case "$target" in
2494       sparc*-sun-solaris2.*)
2495         on_solaris=yes
2496         ;;
2497       *)
2498         on_solaris=no
2499         ;;
2500     esac
2501     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2502       conftest_s='
2503         .section ".tdata",#alloc,#write,#tls
2504 foo:    .long   25
2505         .text
2506         sethi   %tgd_hi22(foo), %o0
2507         add     %o0, %tgd_lo10(foo), %o1
2508         add     %l7, %o1, %o0, %tgd_add(foo)
2509         call    __tls_get_addr, %tgd_call(foo)
2510         sethi   %tldm_hi22(foo), %l1
2511         add     %l1, %tldm_lo10(foo), %l2
2512         add     %l7, %l2, %o0, %tldm_add(foo)
2513         call    __tls_get_addr, %tldm_call(foo)
2514         sethi   %tldo_hix22(foo), %l3
2515         xor     %l3, %tldo_lox10(foo), %l4
2516         add     %o0, %l4, %l5, %tldo_add(foo)
2517         sethi   %tie_hi22(foo), %o3
2518         add     %o3, %tie_lo10(foo), %o3
2519         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2520         add     %g7, %o2, %o4, %tie_add(foo)
2521         sethi   %tle_hix22(foo), %l1
2522         xor     %l1, %tle_lox10(foo), %o5
2523         ld      [%g7 + %o5], %o1'
2524         tls_first_major=0
2525         tls_first_minor=0
2526     else
2527       conftest_s='
2528         .section ".tdata","awT",@progbits
2529 foo:    .long   25
2530         .text
2531         sethi   %tgd_hi22(foo), %o0
2532         add     %o0, %tgd_lo10(foo), %o1
2533         add     %l7, %o1, %o0, %tgd_add(foo)
2534         call    __tls_get_addr, %tgd_call(foo)
2535         sethi   %tldm_hi22(foo), %l1
2536         add     %l1, %tldm_lo10(foo), %l2
2537         add     %l7, %l2, %o0, %tldm_add(foo)
2538         call    __tls_get_addr, %tldm_call(foo)
2539         sethi   %tldo_hix22(foo), %l3
2540         xor     %l3, %tldo_lox10(foo), %l4
2541         add     %o0, %l4, %l5, %tldo_add(foo)
2542         sethi   %tie_hi22(foo), %o3
2543         add     %o3, %tie_lo10(foo), %o3
2544         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2545         add     %g7, %o2, %o4, %tie_add(foo)
2546         sethi   %tle_hix22(foo), %l1
2547         xor     %l1, %tle_lox10(foo), %o5
2548         ld      [%g7 + %o5], %o1'
2549         tls_first_major=2
2550         tls_first_minor=14
2551         tls_as_opt="-32 --fatal-warnings"
2552       fi
2553         ;;
2554 changequote([,])dnl
2555 esac
2556 if test -z "$tls_first_major"; then
2557   : # If we don't have a check, assume no support.
2558 else
2559   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2560   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2561   [AC_DEFINE(HAVE_AS_TLS, 1,
2562             [Define if your assembler supports thread-local storage.])])
2563 fi
2564
2565 # Target-specific assembler checks.
2566
2567 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2568 gcc_cv_ld_static_dynamic=no
2569 if test $in_tree_ld = yes ; then
2570   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2571     gcc_cv_ld_static_dynamic=yes
2572   fi
2573 elif test x$gcc_cv_ld != x; then
2574         # Check if linker supports -Bstatic/-Bdynamic option
2575         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2576           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2577                 gcc_cv_ld_static_dynamic=yes
2578         fi
2579 fi
2580 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2581         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2582 [Define if your linker supports -Bstatic/-Bdynamic option.])
2583 fi
2584 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2585
2586 if test x"$demangler_in_ld" = xyes; then
2587   AC_MSG_CHECKING(linker --demangle support)
2588   gcc_cv_ld_demangle=no
2589   if test $in_tree_ld = yes; then
2590     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2591       gcc_cv_ld_demangle=yes
2592     fi
2593   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2594     # Check if the GNU linker supports --demangle option
2595     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2596       gcc_cv_ld_demangle=yes
2597     fi
2598   fi
2599   if test x"$gcc_cv_ld_demangle" = xyes; then
2600     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2601 [Define if your linker supports --demangle option.])
2602   fi
2603   AC_MSG_RESULT($gcc_cv_ld_demangle)
2604 fi
2605
2606 case "$target" in
2607   # All TARGET_ABI_OSF targets.
2608   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2609     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2610         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2611 [       .set nomacro
2612         .text
2613         extbl   $3, $2, $3      !lituse_bytoff!1
2614         ldq     $2, a($29)      !literal!1
2615         ldq     $4, b($29)      !literal!2
2616         ldq_u   $3, 0($2)       !lituse_base!1
2617         ldq     $27, f($29)     !literal!5
2618         jsr     $26, ($27), f   !lituse_jsr!5
2619         ldah    $29, 0($26)     !gpdisp!3
2620         lda     $0, c($29)      !gprel
2621         ldah    $1, d($29)      !gprelhigh
2622         lda     $1, d($1)       !gprellow
2623         lda     $29, 0($29)     !gpdisp!3],,
2624     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2625   [Define if your assembler supports explicit relocations.])])
2626     ;;
2627
2628   cris-*-*)
2629     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2630       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2631       [-no-mul-bug-abort], [.text],,
2632       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2633                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2634     ;;
2635
2636   sparc*-*-*)
2637     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2638       [.register %g2, #scratch],,
2639       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2640                 [Define if your assembler supports .register.])])
2641
2642     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2643       [-relax], [.text],,
2644       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2645                 [Define if your assembler supports -relax option.])])
2646
2647     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2648       gcc_cv_as_sparc_ua_pcrel,,
2649       [-K PIC],
2650 [.text
2651 foo:
2652         nop
2653 .data
2654 .align 4
2655 .byte 0
2656 .uaword %r_disp32(foo)],
2657       [if test x$gcc_cv_ld != x \
2658        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2659          gcc_cv_as_sparc_ua_pcrel=yes
2660        fi
2661        rm -f conftest],
2662       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2663                 [Define if your assembler and linker support unaligned PC relative relocs.])
2664
2665       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2666         gcc_cv_as_sparc_ua_pcrel_hidden,,
2667         [-K PIC],
2668 [.data
2669 .align 4
2670 .byte 0x31
2671 .uaword %r_disp32(foo)
2672 .byte 0x32, 0x33, 0x34
2673 .global foo
2674 .hidden foo
2675 foo:
2676 .skip 4],
2677         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2678          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2679          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2680             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2681             if $gcc_cv_objdump -R conftest 2> /dev/null \
2682                | grep 'DISP32' > /dev/null 2>&1; then
2683                 :
2684             else
2685                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2686             fi
2687          fi
2688          rm -f conftest],
2689          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2690                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2691     ]) # unaligned pcrel relocs
2692
2693     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2694       gcc_cv_as_sparc_offsetable_lo10,,
2695       [-xarch=v9],
2696 [.text
2697         or %g1, %lo(ab) + 12, %g1
2698         or %g1, %lo(ab + 12), %g1],
2699       [if test x$gcc_cv_objdump != x \
2700        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2701           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2702          gcc_cv_as_sparc_offsetable_lo10=yes
2703        fi],
2704        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2705                  [Define if your assembler supports offsetable %lo().])])
2706     ;;
2707
2708 changequote(,)dnl
2709   i[34567]86-*-* | x86_64-*-*)
2710 changequote([,])dnl
2711     case $target_os in
2712       cygwin* | pe | mingw32*)
2713         # Used for DWARF 2 in PE
2714         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2715           gcc_cv_as_ix86_pe_secrel32,
2716           [2,15,91],,
2717 [.text
2718 foo:    nop
2719 .data
2720         .secrel32 foo],
2721           [if test x$gcc_cv_ld != x \
2722            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2723              gcc_cv_as_ix86_pe_secrel32=yes
2724            fi
2725            rm -f conftest],
2726           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2727             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2728         ;;
2729     esac
2730
2731     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2732        gcc_cv_as_ix86_filds_fists,
2733       [2,9,0],, [filds mem; fists mem],,
2734       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2735         [Define if your assembler uses the new HImode fild and fist notation.])])
2736
2737     gcc_GAS_CHECK_FEATURE([cmov syntax],
2738       gcc_cv_as_ix86_cmov_sun_syntax,,,
2739       [cmovl.l %edx, %eax],,
2740       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2741         [Define if your assembler supports the Sun syntax for cmov.])])
2742
2743     # This one is used unconditionally by i386.[ch]; it is to be defined
2744     # to 1 if the feature is present, 0 otherwise.
2745     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2746         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2747 [       .text
2748 .L0:
2749         nop
2750         .data
2751         .long .L0@GOTOFF])
2752     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2753       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2754       [Define true if the assembler supports '.long foo@GOTOFF'.])
2755     ;;
2756
2757   ia64*-*-*)
2758     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2759         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2760 [       .text
2761         addl r15 = @ltoffx(x#), gp
2762         ;;
2763         ld8.mov r16 = [[r15]], x#],,
2764     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2765           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2766
2767     ;;
2768
2769   powerpc*-*-*)
2770     case $target in
2771       *-*-aix*) conftest_s='    .csect .text[[PR]]
2772         mfcr 3,128';;
2773       *-*-darwin*)
2774         gcc_GAS_CHECK_FEATURE([.machine directive support],
2775           gcc_cv_as_machine_directive,,,
2776           [     .machine ppc7400])
2777         if test x$gcc_cv_as_machine_directive != xyes; then
2778           echo "*** This target requires an assembler supporting \".machine\"" >&2
2779           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2780           test x$build = x$target && exit 1
2781         fi
2782         conftest_s='    .text
2783         mfcr r3,128';;
2784       *) conftest_s='   .machine power4
2785         .text
2786         mfcr 3,128';;
2787     esac
2788
2789     gcc_GAS_CHECK_FEATURE([mfcr field support],
2790       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2791       [$conftest_s],,
2792       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2793           [Define if your assembler supports mfcr field.])])
2794     ;;
2795
2796   mips*-*-*)
2797     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2798       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2799 [       lw $4,%gp_rel(foo)($4)],,
2800       [if test x$target_cpu_default = x
2801        then target_cpu_default=MASK_EXPLICIT_RELOCS
2802        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2803        fi])
2804
2805     if test x$gas_flag = xyes \
2806        || test x"$host" != x"$build" \
2807        || test ! -x "$gcc_cv_as" \
2808        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2809       :
2810     else
2811       echo "*** This configuration requires the GNU assembler" >&2
2812       exit 1
2813     fi
2814     ;;
2815 esac
2816 # ??? Not all targets support dwarf2 debug_line, even within a version
2817 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2818 # info to the output file.  So, as supported targets are added to gas 2.11,
2819 # add some instruction here to (also) show we expect this might work.
2820 # ??? Once 2.11 is released, probably need to add first known working
2821 # version to the per-target configury.
2822 case "$target" in
2823   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2824   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2825   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2826     insn="nop"
2827     ;;
2828   ia64*-*-* | s390*-*-*)
2829     insn="nop 0"
2830     ;;
2831   mmix-*-*)
2832     insn="swym 0"
2833     ;;
2834 esac
2835 if test x"$insn" != x; then
2836  conftest_s="\
2837         .file 1 \"conftest.s\"
2838         .loc 1 3 0
2839         $insn"
2840  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2841   gcc_cv_as_dwarf2_debug_line,
2842   [elf,2,11,0],, [$conftest_s],
2843   [if test x$gcc_cv_objdump != x \
2844    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2845       | grep debug_line > /dev/null 2>&1; then
2846      gcc_cv_as_dwarf2_debug_line=yes
2847    fi])
2848
2849 # The .debug_line file table must be in the exact order that
2850 # we specified the files, since these indices are also used
2851 # by DW_AT_decl_file.  Approximate this test by testing if
2852 # the assembler bitches if the same index is assigned twice.
2853  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2854   gcc_cv_as_dwarf2_file_buggy,,,
2855 [       .file 1 "foo.s"
2856         .file 1 "bar.s"])
2857
2858  if test $gcc_cv_as_dwarf2_debug_line = yes \
2859  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2860         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2861   [Define if your assembler supports dwarf2 .file/.loc directives,
2862    and preserves file table indices exactly as given.])
2863  fi
2864
2865  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2866   gcc_cv_as_gdwarf2_flag,
2867   [elf,2,11,0], [--gdwarf2], [$insn],,
2868   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2869 [Define if your assembler supports the --gdwarf2 option.])])
2870
2871  gcc_GAS_CHECK_FEATURE([--gstabs option],
2872   gcc_cv_as_gstabs_flag,
2873   [elf,2,11,0], [--gstabs], [$insn],
2874   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2875    # and warns about it, but still exits successfully.  So check for
2876    # this.
2877    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2878    then :
2879    else gcc_cv_as_gstabs_flag=yes
2880    fi],
2881   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2882 [Define if your assembler supports the --gstabs option.])])
2883 fi
2884
2885 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2886 gcc_cv_ld_ro_rw_mix=unknown
2887 if test $in_tree_ld = yes ; then
2888   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2889      && test $in_tree_ld_is_elf = yes; then
2890     gcc_cv_ld_ro_rw_mix=read-write
2891   fi
2892 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2893   echo '.section myfoosect, "a"' > conftest1.s
2894   echo '.section myfoosect, "aw"' > conftest2.s
2895   echo '.byte 1' >> conftest2.s
2896   echo '.section myfoosect, "a"' > conftest3.s
2897   echo '.byte 0' >> conftest3.s
2898   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2899      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2900      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2901      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2902         conftest2.o conftest3.o > /dev/null 2>&1; then
2903     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2904                          | sed -e '/myfoosect/!d' -e N`
2905     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2906       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2907         gcc_cv_ld_ro_rw_mix=read-only
2908       else
2909         gcc_cv_ld_ro_rw_mix=read-write
2910       fi
2911     fi
2912   fi
2913 changequote(,)dnl
2914   rm -f conftest.* conftest[123].*
2915 changequote([,])dnl
2916 fi
2917 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2918         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2919   [Define if your linker links a mix of read-only
2920    and read-write sections into a read-write section.])
2921 fi
2922 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2923
2924 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2925 gcc_cv_ld_eh_frame_hdr=no
2926 if test $in_tree_ld = yes ; then
2927   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2928      && test $in_tree_ld_is_elf = yes; then
2929     gcc_cv_ld_eh_frame_hdr=yes
2930   fi
2931 elif test x$gcc_cv_ld != x; then
2932         # Check if linker supports --eh-frame-hdr option
2933         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2934                 gcc_cv_ld_eh_frame_hdr=yes
2935         fi
2936 fi
2937 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2938         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2939 [Define if your linker supports --eh-frame-hdr option.])
2940 fi
2941 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2942
2943 AC_MSG_CHECKING(linker position independent executable support)
2944 gcc_cv_ld_pie=no
2945 if test $in_tree_ld = yes ; then
2946   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2947      && test $in_tree_ld_is_elf = yes; then
2948     gcc_cv_ld_pie=yes
2949   fi
2950 elif test x$gcc_cv_ld != x; then
2951         # Check if linker supports -pie option
2952         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2953                 gcc_cv_ld_pie=yes
2954         fi
2955 fi
2956 if test x"$gcc_cv_ld_pie" = xyes; then
2957         AC_DEFINE(HAVE_LD_PIE, 1,
2958 [Define if your linker supports -pie option.])
2959 fi
2960 AC_MSG_RESULT($gcc_cv_ld_pie)
2961
2962 # --------
2963 # UNSORTED
2964 # --------
2965
2966 AC_CACHE_CHECK(linker --as-needed support,
2967 gcc_cv_ld_as_needed,
2968 [gcc_cv_ld_as_needed=no
2969 if test $in_tree_ld = yes ; then
2970   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2971      && test $in_tree_ld_is_elf = yes; then
2972     gcc_cv_ld_as_needed=yes
2973   fi
2974 elif test x$gcc_cv_ld != x; then
2975         # Check if linker supports --as-needed and --no-as-needed options
2976         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2977                 gcc_cv_ld_as_needed=yes
2978         fi
2979 fi
2980 ])
2981 if test x"$gcc_cv_ld_as_needed" = xyes; then
2982         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2983 [Define if your linker supports --as-needed and --no-as-needed options.])
2984 fi
2985
2986 case "$target" in
2987   powerpc64*-*-linux*)
2988     AC_CACHE_CHECK(linker support for omitting dot symbols,
2989     gcc_cv_ld_no_dot_syms,
2990     [gcc_cv_ld_no_dot_syms=no
2991     if test $in_tree_ld = yes ; then
2992       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
2993         gcc_cv_ld_no_dot_syms=yes
2994       fi
2995     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
2996       cat > conftest1.s <<EOF
2997         .text
2998         bl .foo
2999 EOF
3000       cat > conftest2.s <<EOF
3001         .section ".opd","aw"
3002         .align 3
3003         .globl foo
3004         .type foo,@function
3005 foo:
3006         .quad .LEfoo,.TOC.@tocbase,0
3007         .text
3008 .LEfoo:
3009         blr
3010         .size foo,.-.LEfoo
3011 EOF
3012       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3013          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3014          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3015         gcc_cv_ld_no_dot_syms=yes
3016       fi
3017       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3018     fi
3019     ])
3020     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3021       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3022     [Define if your PowerPC64 linker only needs function descriptor syms.])
3023     fi
3024     ;;
3025 esac
3026
3027 if test x$with_sysroot = x && test x$host = x$target \
3028    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
3029   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3030 [Define to PREFIX/include if cpp should also search that directory.])
3031 fi
3032
3033 # Find out what GC implementation we want, or may, use.
3034 AC_ARG_WITH(gc,
3035 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3036                           with the compiler],
3037 [case "$withval" in
3038   page)
3039     GGC=ggc-$withval
3040     ;;
3041   zone)
3042     GGC=ggc-$withval
3043     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3044     ;;
3045   *)
3046     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3047     ;;
3048 esac],
3049 [GGC=ggc-page])
3050 AC_SUBST(GGC)
3051 echo "Using $GGC for garbage collection."
3052
3053 # Use the system's zlib library.
3054 zlibdir=-L../zlib
3055 zlibinc="-I\$(srcdir)/../zlib"
3056 AC_ARG_WITH(system-zlib,
3057 [  --with-system-zlib      use installed libz],
3058 zlibdir=
3059 zlibinc=
3060 )
3061 AC_SUBST(zlibdir)
3062 AC_SUBST(zlibinc)
3063
3064 dnl Very limited version of automake's enable-maintainer-mode
3065
3066 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3067   dnl maintainer-mode is disabled by default
3068   AC_ARG_ENABLE(maintainer-mode,
3069 [  --enable-maintainer-mode
3070                           enable make rules and dependencies not useful
3071                           (and sometimes confusing) to the casual installer],
3072       maintainer_mode=$enableval,
3073       maintainer_mode=no)
3074
3075 AC_MSG_RESULT($maintainer_mode)
3076
3077 if test "$maintainer_mode" = "yes"; then
3078   MAINT=''
3079 else
3080   MAINT='#'
3081 fi
3082 AC_SUBST(MAINT)dnl
3083
3084 # --------------
3085 # Language hooks
3086 # --------------
3087
3088 # Make empty files to contain the specs and options for each language.
3089 # Then add #include lines to for a compiler that has specs and/or options.
3090
3091 lang_opt_files=
3092 lang_specs_files=
3093 lang_tree_files=
3094 for subdir in . $subdirs
3095 do
3096         if test -f $srcdir/$subdir/lang.opt; then
3097             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3098         fi
3099         if test -f $srcdir/$subdir/lang-specs.h; then
3100             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3101         fi
3102         if test -f $srcdir/$subdir/$subdir-tree.def; then
3103             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3104         fi
3105 done
3106
3107 # These (without "all_") are set in each config-lang.in.
3108 # `language' must be a single word so is spelled singularly.
3109 all_languages=
3110 all_boot_languages=
3111 all_compilers=
3112 all_stagestuff=
3113 all_outputs='Makefile gccbug mklibgcc libada-mk'
3114 # List of language makefile fragments.
3115 all_lang_makefrags=
3116 # List of language subdirectory makefiles.  Deprecated.
3117 all_lang_makefiles=
3118 # Files for gengtype
3119 all_gtfiles="$target_gtfiles"
3120 # Files for gengtype with language
3121 all_gtfiles_files_langs=
3122 all_gtfiles_files_files=
3123
3124 # Add the language fragments.
3125 # Languages are added via two mechanisms.  Some information must be
3126 # recorded in makefile variables, these are defined in config-lang.in.
3127 # We accumulate them and plug them into the main Makefile.
3128 # The other mechanism is a set of hooks for each of the main targets
3129 # like `clean', `install', etc.
3130
3131 language_hooks="Make-hooks"
3132
3133 for s in $subdirs
3134 do
3135                 language=
3136                 boot_language=
3137                 compilers=
3138                 stagestuff=
3139                 outputs=
3140                 gtfiles=
3141                 . ${srcdir}/$s/config-lang.in
3142                 if test "x$language" = x
3143                 then
3144                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3145                         exit 1
3146                 fi
3147                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3148                 if test -f ${srcdir}/$s/Makefile.in
3149                 then all_lang_makefiles="$s/Makefile"
3150                 fi
3151                 all_languages="$all_languages $language"
3152                 if test "x$boot_language" = xyes
3153                 then
3154                         all_boot_languages="$all_boot_languages $language"
3155                 fi
3156                 all_compilers="$all_compilers $compilers"
3157                 all_stagestuff="$all_stagestuff $stagestuff"
3158                 all_outputs="$all_outputs $outputs"
3159                 all_gtfiles="$all_gtfiles $gtfiles"
3160                 for f in $gtfiles
3161                 do
3162                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3163                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3164                 done
3165 done
3166
3167 # Pick up gtfiles for c
3168 gtfiles=
3169 s="c"
3170 . ${srcdir}/c-config-lang.in
3171 all_gtfiles="$all_gtfiles $gtfiles"
3172 for f in $gtfiles
3173 do
3174         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3175         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3176 done
3177
3178 check_languages=
3179 for language in $all_languages
3180 do
3181                 check_languages="$check_languages check-$language"
3182 done
3183
3184 # We link each language in with a set of hooks, reached indirectly via
3185 # lang.${target}.
3186
3187 rm -f Make-hooks
3188 touch Make-hooks
3189 target_list="all.build all.cross start.encap rest.encap tags \
3190         install-normal install-common install-man \
3191         uninstall info man srcextra srcman srcinfo \
3192         mostlyclean clean distclean maintainer-clean \
3193         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3194 for t in $target_list
3195 do
3196         x=
3197         for lang in $all_languages
3198         do
3199                         x="$x $lang.$t"
3200         done
3201         echo "lang.$t: $x" >> Make-hooks
3202 done
3203
3204 # --------
3205 # UNSORTED
3206 # --------
3207
3208 # Create .gdbinit.
3209
3210 echo "dir ." > .gdbinit
3211 echo "dir ${srcdir}" >> .gdbinit
3212 if test x$gdb_needs_out_file_path = xyes
3213 then
3214         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3215 fi
3216 if test "x$subdirs" != x; then
3217         for s in $subdirs
3218         do
3219                 echo "dir ${srcdir}/$s" >> .gdbinit
3220         done
3221 fi
3222 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3223
3224 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3225 # absolute path for gcc_tooldir based on inserting the number of up-directory
3226 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3227 # $(libsubdir)/@(unlibsubdir) based path.
3228 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3229 # make and thus we'd get different behavior depending on where we built the
3230 # sources.
3231 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3232     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3233 else
3234 changequote(<<, >>)dnl
3235 # An explanation of the sed strings:
3236 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3237 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3238 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3239 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3240 #
3241 # (*) Note this pattern overwrites the first character of the string
3242 # with a forward slash if one is not already present.  This is not a
3243 # problem because the exact names of the sub-directories concerned is
3244 # unimportant, just the number of them matters.
3245 #
3246 # The practical upshot of these patterns is like this:
3247 #
3248 #  prefix     exec_prefix        result
3249 #  ------     -----------        ------
3250 #   /foo        /foo/bar          ../
3251 #   /foo/       /foo/bar          ../
3252 #   /foo        /foo/bar/         ../
3253 #   /foo/       /foo/bar/         ../
3254 #   /foo        /foo/bar/ugg      ../../
3255 #
3256     dollar='$$'
3257     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3258 changequote([, ])dnl
3259 fi
3260 AC_SUBST(gcc_tooldir)
3261 AC_SUBST(dollar)
3262
3263 # Find a directory in which to install a shared libgcc.
3264
3265 AC_ARG_ENABLE(version-specific-runtime-libs,
3266 [  --enable-version-specific-runtime-libs
3267                           specify that runtime libraries should be
3268                           installed in a compiler-specific directory])
3269
3270 AC_ARG_WITH(slibdir,
3271 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3272 slibdir="$with_slibdir",
3273 if test "${enable_version_specific_runtime_libs+set}" = set; then
3274   slibdir='$(libsubdir)'
3275 elif test "$host" != "$target"; then
3276   slibdir='$(build_tooldir)/lib'
3277 else
3278   slibdir='$(libdir)'
3279 fi)
3280 AC_SUBST(slibdir)
3281
3282 objdir=`${PWDCMD-pwd}`
3283 AC_SUBST(objdir)
3284
3285 # Substitute configuration variables
3286 AC_SUBST(subdirs)
3287 AC_SUBST(srcdir)
3288 AC_SUBST(all_boot_languages)
3289 AC_SUBST(all_compilers)
3290 AC_SUBST(all_gtfiles)
3291 AC_SUBST(all_gtfiles_files_langs)
3292 AC_SUBST(all_gtfiles_files_files)
3293 AC_SUBST(all_lang_makefrags)
3294 AC_SUBST(all_lang_makefiles)
3295 AC_SUBST(all_languages)
3296 AC_SUBST(all_stagestuff)
3297 AC_SUBST(build_exeext)
3298 AC_SUBST(build_install_headers_dir)
3299 AC_SUBST(build_xm_file_list)
3300 AC_SUBST(build_xm_include_list)
3301 AC_SUBST(build_xm_defines)
3302 AC_SUBST(check_languages)
3303 AC_SUBST(cc_set_by_configure)
3304 AC_SUBST(quoted_cc_set_by_configure)
3305 AC_SUBST(cpp_install_dir)
3306 AC_SUBST(xmake_file)
3307 AC_SUBST(tmake_file)
3308 AC_SUBST(extra_gcc_objs)
3309 AC_SUBST(extra_headers_list)
3310 AC_SUBST(extra_objs)
3311 AC_SUBST(extra_parts)
3312 AC_SUBST(extra_passes)
3313 AC_SUBST(extra_programs)
3314 AC_SUBST(float_h_file)
3315 AC_SUBST(gcc_config_arguments)
3316 AC_SUBST(gcc_gxx_include_dir)
3317 AC_SUBST(libstdcxx_incdir)
3318 AC_SUBST(host_exeext)
3319 AC_SUBST(host_xm_file_list)
3320 AC_SUBST(host_xm_include_list)
3321 AC_SUBST(host_xm_defines)
3322 AC_SUBST(out_host_hook_obj)
3323 AC_SUBST(install)
3324 AC_SUBST(lang_opt_files)
3325 AC_SUBST(lang_specs_files)
3326 AC_SUBST(lang_tree_files)
3327 AC_SUBST(local_prefix)
3328 AC_SUBST(md_file)
3329 AC_SUBST(objc_boehm_gc)
3330 AC_SUBST(out_file)
3331 AC_SUBST(out_object_file)
3332 AC_SUBST(stage_prefix_set_by_configure)
3333 AC_SUBST(quoted_stage_prefix_set_by_configure)
3334 AC_SUBST(thread_file)
3335 AC_SUBST(tm_file_list)
3336 AC_SUBST(tm_include_list)
3337 AC_SUBST(tm_defines)
3338 AC_SUBST(tm_p_file_list)
3339 AC_SUBST(tm_p_include_list)
3340 AC_SUBST(xm_file_list)
3341 AC_SUBST(xm_include_list)
3342 AC_SUBST(xm_defines)
3343 AC_SUBST(c_target_objs)
3344 AC_SUBST(cxx_target_objs)
3345 AC_SUBST(target_cpu_default)
3346
3347 AC_SUBST_FILE(language_hooks)
3348
3349 # Echo link setup.
3350 if test x${build} = x${host} ; then
3351   if test x${host} = x${target} ; then
3352     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3353   else
3354     echo "Links are now set up to build a cross-compiler" 1>&2
3355     echo " from ${host} to ${target}." 1>&2
3356   fi
3357 else
3358   if test x${host} = x${target} ; then
3359     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3360     echo " for ${target}." 1>&2
3361   else
3362     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3363     echo " from ${host} to ${target}." 1>&2
3364   fi
3365 fi
3366
3367 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3368 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3369
3370 # Configure the subdirectories
3371 # AC_CONFIG_SUBDIRS($subdirs)
3372
3373 # Create the Makefile
3374 # and configure language subdirectories
3375 AC_CONFIG_FILES($all_outputs)
3376
3377 AC_CONFIG_COMMANDS([default],
3378 [
3379 case ${CONFIG_HEADERS} in
3380   *auto-host.h:config.in*)
3381   echo > cstamp-h ;;
3382 esac
3383 # Make sure all the subdirs exist.
3384 for d in $subdirs doc build
3385 do
3386     test -d $d || mkdir $d
3387 done
3388 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3389 # bootstrapping and the installation procedure can still use
3390 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3391 # FLAGS_TO_PASS has been modified to solve the problem there.
3392 # This is virtually a duplicate of what happens in configure.lang; we do
3393 # an extra check to make sure this only happens if ln -s can be used.
3394 case "$LN_S" in
3395   *-s*)
3396     for d in ${subdirs} ; do
3397         STARTDIR=`${PWDCMD-pwd}`
3398         cd $d
3399         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3400         do
3401                 rm -f $t
3402                 $LN_S ../$t $t 2>/dev/null
3403         done
3404         cd $STARTDIR
3405     done
3406   ;;
3407 esac
3408 ],
3409 [subdirs='$subdirs'])
3410 AC_OUTPUT