gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 _GCC_TOPLEV_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # ----------------------
 215 # Find default assembler
 216 # ----------------------
 217
 218 # With GNU as
 219 AC_ARG_WITH(gnu-as,
 220 [  --with-gnu-as           arrange to work with GNU as],
 221 gas_flag="$with_gnu_as",
 222 gas_flag=no)
 223
 224 AC_ARG_WITH(as,
 225 [  --with-as               arrange to use the specified as (full pathname)],
 226 DEFAULT_ASSEMBLER="$with_as")
 227 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 228   if test ! -x "$DEFAULT_ASSEMBLER"; then
 229     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 230   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 231     gas_flag=yes
 232   fi
 233   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 234         [Define to enable the use of a default assembler.])
 235 fi
 236
 237 AC_MSG_CHECKING([whether a default assembler was specified])
 238 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 239   if test x"$gas_flag" = x"no"; then
 240     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 241   else
 242     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 243   fi
 244 else
 245   AC_MSG_RESULT(no)
 246 fi
 247
 248 # ---------------
 249 # Find C compiler
 250 # ---------------
 251
 252 # If a non-executable a.out is present (e.g. created by GNU as above even if
 253 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 254 # file, even when creating an executable, so an execution test fails.
 255 # Remove possible default executable files to avoid this.
 256 #
 257 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 258 # Autoconf includes it.
 259 rm -f a.out a.exe b.out
 260
 261 # Find the native compiler
 262 AC_PROG_CC
 263 AC_PROG_CC_C_O
 264 # autoconf is lame and doesn't give us any substitution variable for this.
 265 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 266   NO_MINUS_C_MINUS_O=yes
 267 else
 268   OUTPUT_OPTION='-o $@'
 269 fi
 270 AC_SUBST(NO_MINUS_C_MINUS_O)
 271 AC_SUBST(OUTPUT_OPTION)
 272
 273 # -------------------------
 274 # Check C compiler features
 275 # -------------------------
 276
 277 AC_PROG_CPP
 278 AC_C_INLINE
 279
 280 gcc_AC_C_LONG_LONG
 281 gcc_AC_C__BOOL
 282
 283 # sizeof(char) is 1 by definition.
 284 AC_COMPILE_CHECK_SIZEOF(void *)
 285 AC_COMPILE_CHECK_SIZEOF(short)
 286 AC_COMPILE_CHECK_SIZEOF(int)
 287 AC_COMPILE_CHECK_SIZEOF(long)
 288 if test $ac_cv_c_long_long = yes; then
 289   AC_COMPILE_CHECK_SIZEOF(long long)
 290 fi
 291 if test $ac_cv_c___int64 = yes; then
 292   AC_COMPILE_CHECK_SIZEOF(__int64)
 293 fi
 294
 295 # ---------------------
 296 # Warnings and checking
 297 # ---------------------
 298
 299 # Check $CC warning features (if it's GCC).
 300 # We want to use -pedantic, but we don't want warnings about
 301 # * 'long long'
 302 # * variadic macros
 303 # So, we only use -pedantic if we can disable those warnings.
 304
 305 AC_CACHE_CHECK(
 306   [whether ${CC} accepts -Wno-long-long],
 307   [ac_cv_prog_cc_w_no_long_long],
 308   [save_CFLAGS="$CFLAGS"
 309   CFLAGS="-Wno-long-long"
 310   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 311                     [ac_cv_prog_cc_w_no_long_long=yes],
 312                     [ac_cv_prog_cc_w_no_long_long=no])
 313   CFLAGS="$save_CFLAGS"
 314   ])
 315
 316 AC_CACHE_CHECK(
 317   [whether ${CC} accepts -Wno-variadic-macros],
 318   [ac_cv_prog_cc_w_no_variadic_macros],
 319   [save_CFLAGS="$CFLAGS"
 320   CFLAGS="-Wno-variadic-macros"
 321   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 322                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 323                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 324   CFLAGS="$save_CFLAGS"
 325   ])
 326
 327 strict1_warn=
 328 if test $ac_cv_prog_cc_w_no_long_long = yes \
 329    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 330   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 331 fi
 332 AC_SUBST(strict1_warn)
 333
 334 # Add -Wold-style-definition if it's accepted
 335 AC_CACHE_CHECK(
 336   [whether ${CC} accepts -Wold-style-definition],
 337   [ac_cv_prog_cc_w_old_style_definition],
 338   [save_CFLAGS="$CFLAGS"
 339   CFLAGS="-Wold-style-definition"
 340   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 341                     [ac_cv_prog_cc_w_old_style_definition=yes],
 342                     [ac_cv_prog_cc_w_old_style_definition=no])
 343   CFLAGS="$save_CFLAGS"
 344   ])
 345 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 346   strict1_warn="${strict1_warn} -Wold-style-definition"
 347 fi
 348
 349 # Enable -Werror, period.
 350 AC_ARG_ENABLE(werror_always,
 351 [  --enable-werror-always         enable -Werror always], [],
 352 [enable_werror_always=no])
 353 if test x${enable_werror_always} = xyes ; then
 354   strict1_warn="${strict1_warn} -Werror"
 355   WERROR=-Werror
 356 fi
 357
 358 # If the native compiler is GCC, we can enable warnings even in stage1.
 359 # That's useful for people building cross-compilers, or just running a
 360 # quick `make'.
 361 warn_cflags=
 362 if test "x$GCC" = "xyes"; then
 363   warn_cflags='$(GCC_WARN_CFLAGS)'
 364 fi
 365 AC_SUBST(warn_cflags)
 366
 367 # Enable -Werror in bootstrap stage2 and later.
 368 # Change the default to "no" on release branches.
 369 AC_ARG_ENABLE(werror,
 370 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 371 [enable_werror=yes])
 372 if test x$enable_werror = xyes ; then
 373   WERROR=-Werror
 374 fi
 375 AC_SUBST(WERROR)
 376
 377 # Enable expensive internal checks
 378 AC_ARG_ENABLE(checking,
 379 [  --enable-checking[=LIST]
 380                           enable expensive run-time checks.  With LIST,
 381                           enable only specific categories of checks.
 382                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
 383                           default is misc,tree,gc,rtlflag],
 384 [ac_checking=
 385 ac_tree_checking=
 386 ac_rtl_checking=
 387 ac_rtlflag_checking=
 388 ac_gc_checking=
 389 ac_gc_always_collect=
 390 ac_fold_checking=
 391 case "${enableval}" in
 392 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 393         ac_rtlflag_checking=1 ;;
 394 no)     ;;
 395 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 396         set fnord $enableval; shift
 397         IFS="$ac_save_IFS"
 398         for check
 399         do
 400                 case $check in
 401                 misc)   ac_checking=1 ;;
 402                 tree)   ac_tree_checking=1 ;;
 403                 rtlflag)        ac_rtlflag_checking=1 ;;
 404                 rtl)    ac_rtl_checking=1 ;;
 405                 gc)     ac_gc_checking=1 ;;
 406                 gcac)   ac_gc_always_collect=1 ;;
 407                 fold)   ac_fold_checking=1 ;;
 408                 valgrind)       ac_checking_valgrind=1 ;;
 409                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 410                 esac
 411         done
 412         ;;
 413 esac
 414 ],
 415 # Enable some checks by default for development versions of GCC
 416 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 417 nocommon_flag=""
 418 if test x$ac_checking != x ; then
 419   AC_DEFINE(ENABLE_CHECKING, 1,
 420 [Define if you want more run-time sanity checks.  This one gets a grab
 421    bag of miscellaneous but relatively cheap checks.])
 422   nocommon_flag=-fno-common
 423 fi
 424 AC_SUBST(nocommon_flag)
 425 if test x$ac_tree_checking != x ; then
 426   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 427 [Define if you want all operations on trees (the basic data
 428    structure of the front ends) to be checked for dynamic type safety
 429    at runtime.  This is moderately expensive.])
 430 fi
 431 if test x$ac_rtl_checking != x ; then
 432   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 433 [Define if you want all operations on RTL (the basic data structure
 434    of the optimizer and back end) to be checked for dynamic type safety
 435    at runtime.  This is quite expensive.])
 436 fi
 437 if test x$ac_rtlflag_checking != x ; then
 438   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 439 [Define if you want RTL flag accesses to be checked against the RTL
 440    codes that are supported for each access macro.  This is relatively
 441    cheap.])
 442 fi
 443 if test x$ac_gc_checking != x ; then
 444   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 445 [Define if you want the garbage collector to do object poisoning and
 446    other memory allocation checks.  This is quite expensive.])
 447 fi
 448 if test x$ac_gc_always_collect != x ; then
 449   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 450 [Define if you want the garbage collector to operate in maximally
 451    paranoid mode, validating the entire heap and collecting garbage at
 452    every opportunity.  This is extremely expensive.])
 453 fi
 454 if test x$ac_fold_checking != x ; then
 455   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 456 [Define if you want fold checked that it never destructs its argument.
 457    This is quite expensive.])
 458 fi
 459 valgrind_path_defines=
 460 valgrind_command=
 461
 462 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 463 dnl # an if statement.  This was the source of very frustrating bugs
 464 dnl # in converting to autoconf 2.5x!
 465 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 466
 467 if test x$ac_checking_valgrind != x ; then
 468   # It is certainly possible that there's valgrind but no valgrind.h.
 469   # GCC relies on making annotations so we must have both.
 470   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 471   AC_TRY_CPP(
 472     [#include <valgrind/memcheck.h>
 473 #ifndef VALGRIND_DISCARD
 474 #error VALGRIND_DISCARD not defined
 475 #endif],
 476   [gcc_cv_header_valgrind_memcheck_h=yes],
 477   [gcc_cv_header_valgrind_memcheck_h=no])
 478   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 479   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 480   AC_TRY_CPP(
 481     [#include <memcheck.h>
 482 #ifndef VALGRIND_DISCARD
 483 #error VALGRIND_DISCARD not defined
 484 #endif],
 485   [gcc_cv_header_memcheck_h=yes],
 486   gcc_cv_header_memcheck_h=no)
 487   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 488   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 489         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 490   if test "x$valgrind_path" = "x" \
 491     || (test $have_valgrind_h = no \
 492         && test $gcc_cv_header_memcheck_h = no \
 493         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 494         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 495   fi
 496   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 497   valgrind_command="$valgrind_path -q"
 498   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 499 [Define if you want to run subprograms and generated programs
 500    through valgrind (a memory checker).  This is extremely expensive.])
 501   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 502     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 503         [Define if valgrind's valgrind/memcheck.h header is installed.])
 504   fi
 505   if test $gcc_cv_header_memcheck_h = yes; then
 506     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 507         [Define if valgrind's memcheck.h header is installed.])
 508   fi
 509 fi
 510 AC_SUBST(valgrind_path_defines)
 511 AC_SUBST(valgrind_command)
 512
 513 # Enable code coverage collection
 514 AC_ARG_ENABLE(coverage,
 515 [  --enable-coverage[=LEVEL]
 516                           enable compiler\'s code coverage collection.
 517                           Use to measure compiler performance and locate
 518                           unused parts of the compiler. With LEVEL, specify
 519                           optimization. Values are opt, noopt,
 520                           default is noopt],
 521 [case "${enableval}" in
 522   yes|noopt)
 523     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 524     ;;
 525   opt)
 526     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 527     ;;
 528   no)
 529     # a.k.a. --disable-coverage
 530     coverage_flags=""
 531     ;;
 532   *)
 533     AC_MSG_ERROR(unknown coverage setting $enableval)
 534     ;;
 535 esac],
 536 [coverage_flags=""])
 537 AC_SUBST(coverage_flags)
 538
 539 AC_ARG_ENABLE(gather-detailed-mem-stats,
 540 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 541 [enable_gather_detailed_mem_stats=no])
 542 if test x$enable_gather_detailed_mem_stats = xyes ; then
 543   AC_DEFINE(GATHER_STATISTICS, 1,
 544         [Define to enable detailed memory allocation stats gathering.])
 545 fi
 546
 547 AC_ARG_ENABLE(tree-browser,
 548 [  --enable-tree-browser   enable the tree browsing routines for debugging], [],
 549 [enable_tree_browser=no])
 550 if test x$enable_tree_browser = xyes ; then
 551   TREEBROWSER=tree-browser.o
 552 fi
 553 AC_SUBST(TREEBROWSER)
 554
 555 # -------------------------------
 556 # Miscenalleous configure options
 557 # -------------------------------
 558
 559 # With stabs
 560 AC_ARG_WITH(stabs,
 561 [  --with-stabs            arrange to use stabs instead of host debug format],
 562 stabs="$with_stabs",
 563 stabs=no)
 564
 565 # Determine whether or not multilibs are enabled.
 566 AC_ARG_ENABLE(multilib,
 567 [  --enable-multilib       enable library support for multiple ABIs],
 568 [], [enable_multilib=yes])
 569 AC_SUBST(enable_multilib)
 570
 571 # Enable __cxa_atexit for C++.
 572 AC_ARG_ENABLE(__cxa_atexit,
 573 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 574 [], [])
 575
 576 # Enable threads
 577 # Pass with no value to take the default
 578 # Pass with a value to specify a thread package
 579 AC_ARG_ENABLE(threads,
 580 [  --enable-threads        enable thread usage for target GCC
 581   --enable-threads=LIB    use LIB thread package for target GCC],,
 582 [enable_threads=''])
 583
 584 AC_ARG_ENABLE(objc-gc,
 585 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 586                           the GNU Objective-C runtime],
 587 if test x$enable_objc_gc = xno; then
 588         objc_boehm_gc=''
 589 else
 590         objc_boehm_gc=1
 591 fi,
 592 objc_boehm_gc='')
 593
 594 AC_ARG_WITH(dwarf2,
 595 [  --with-dwarf2           force the default debug format to be DWARF 2],
 596 dwarf2="$with_dwarf2",
 597 dwarf2=no)
 598
 599 AC_ARG_ENABLE(shared,
 600 [  --disable-shared        don't provide a shared libgcc],
 601 [
 602   case $enable_shared in
 603   yes | no) ;;
 604   *)
 605     enable_shared=no
 606     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 607     for pkg in $enableval; do
 608       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 609         enable_shared=yes
 610       fi
 611     done
 612     IFS="$ac_save_ifs"
 613     ;;
 614   esac
 615 ], [enable_shared=yes])
 616 AC_SUBST(enable_shared)
 617
 618 AC_ARG_WITH(sysroot,
 619 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 620 [
 621  case ${with_sysroot} in
 622  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 623  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 624  esac
 625
 626  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 627  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 628
 629  if test "x$exec_prefix" = xNONE; then
 630   if test "x$prefix" = xNONE; then
 631    test_prefix=/usr/local
 632   else
 633    test_prefix=$prefix
 634   fi
 635  else
 636   test_prefix=$exec_prefix
 637  fi
 638  case ${TARGET_SYSTEM_ROOT} in
 639  "${test_prefix}"|"${test_prefix}/"*|\
 640  '${exec_prefix}'|'${exec_prefix}/'*)
 641    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 642    TARGET_SYSTEM_ROOT_DEFINE="$t"
 643    ;;
 644  esac
 645 ], [
 646  TARGET_SYSTEM_ROOT=
 647  TARGET_SYSTEM_ROOT_DEFINE=
 648  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 649 ])
 650 AC_SUBST(TARGET_SYSTEM_ROOT)
 651 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 652 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 653
 654 # Build with intermodule optimisations
 655 AC_ARG_ENABLE(intermodule,
 656 [  --enable-intermodule    build the compiler in one step],
 657 [case ${enable_intermodule} in
 658   yes) onestep="-onestep";;
 659   *) onestep="";;
 660 esac],
 661 [onestep=""])
 662 AC_SUBST(onestep)
 663
 664 # Sanity check enable_languages in case someone does not run the toplevel
 665 # configure # script.
 666 AC_ARG_ENABLE(languages,
 667 [  --enable-languages=LIST specify which front-ends to build],
 668 [case ,${enable_languages}, in
 669        ,,|,yes,)
 670                 # go safe -- we cannot be much sure without the toplevel
 671                 # configure's
 672                 # analysis of which target libs are present and usable
 673                 enable_languages=c
 674                 ;;
 675          *,all,*)
 676                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 677                 ;;
 678         *,c,*)
 679                 ;;
 680         *)
 681                 enable_languages=c,${enable_languages}
 682                 ;;
 683 esac],
 684 [enable_languages=c])
 685
 686 subdirs=
 687 for lang in ${srcdir}/*/config-lang.in
 688 do
 689         case $lang in
 690         # The odd quoting in the next line works around
 691         # an apparent bug in bash 1.12 on linux.
 692 changequote(,)dnl
 693         ${srcdir}/[*]/config-lang.in) ;;
 694         *)
 695           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 696           if test "x$lang_alias" = x
 697           then
 698                 echo "$lang doesn't set \$language." 1>&2
 699                 exit 1
 700           fi
 701           case ",$enable_languages," in
 702           *,$lang_alias,*)
 703             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 704           esac
 705           ;;
 706 changequote([,])dnl
 707         esac
 708 done
 709
 710
 711 # -------------------------
 712 # Checks for other programs
 713 # -------------------------
 714
 715 AC_PROG_MAKE_SET
 716
 717 # Find some useful tools
 718 AC_PROG_AWK
 719 # We need awk to run opts.sh (to create options.c and options.h).
 720 # Bail out if it's missing.
 721 case ${AWK} in
 722   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 723 esac
 724
 725 gcc_AC_PROG_LN
 726 gcc_AC_PROG_LN_S
 727 AC_PROG_RANLIB
 728 gcc_AC_PROG_INSTALL
 729
 730 # See if cmp has --ignore-initial.
 731 gcc_AC_PROG_CMP_IGNORE_INITIAL
 732
 733 # See if we have the mktemp command.
 734 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 735
 736 # Do we have a single-tree copy of texinfo?
 737 if test -f $srcdir/../texinfo/Makefile.in; then
 738   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 739   gcc_cv_prog_makeinfo_modern=yes
 740   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 741 else
 742   # See if makeinfo has been installed and is modern enough
 743   # that we can use it.
 744   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 745   [GNU texinfo.* \([0-9][0-9.]*\)],
 746   [4.[2-9]*])
 747 fi
 748
 749 if test $gcc_cv_prog_makeinfo_modern = no; then
 750   AC_MSG_WARN([
 751 *** Makeinfo is missing or too old.
 752 *** Info documentation will not be built.])
 753   BUILD_INFO=
 754 else
 755   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 756 fi
 757
 758 # Is pod2man recent enough to regenerate manpages?
 759 AC_MSG_CHECKING([for recent Pod::Man])
 760 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 761   AC_MSG_RESULT(yes)
 762   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 763 else
 764   AC_MSG_RESULT(no)
 765   GENERATED_MANPAGES=
 766 fi
 767
 768 # How about lex?
 769 dnl Don't use AC_PROG_LEX; we insist on flex.
 770 dnl LEXLIB is not useful in gcc.
 771 if test x${build} = x${host} && test -f $srcdir/../flex/skel.c; then
 772   FLEX='$(objdir)/../flex/flex'
 773 else
 774   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 775 fi
 776
 777 # Bison?
 778 # The -L switch is so bison can find its skeleton file.
 779 if test x${build} = x${host} && test -f $srcdir/../bison/bison.simple; then
 780   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 781 else
 782   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 783 fi
 784
 785 # --------------------
 786 # Checks for C headers
 787 # --------------------
 788
 789 AC_MSG_CHECKING(for GNU C library)
 790 AC_CACHE_VAL(gcc_cv_glibc,
 791 [AC_TRY_COMPILE(
 792   [#include <features.h>],[
 793 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 794 #error Not a GNU C library system
 795 #endif],
 796   [gcc_cv_glibc=yes],
 797   gcc_cv_glibc=no)])
 798 AC_MSG_RESULT($gcc_cv_glibc)
 799 if test $gcc_cv_glibc = yes; then
 800   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 801 fi
 802
 803 # Need to reject headers which give warnings, so that the -Werror bootstrap
 804 # works later. *sigh*  This needs to come before all header checks.
 805 AC_PROG_CPP_WERROR
 806
 807 AC_HEADER_STDC
 808 AC_HEADER_TIME
 809 gcc_AC_HEADER_STDBOOL
 810 gcc_AC_HEADER_STRING
 811 AC_HEADER_SYS_WAIT
 812 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 813                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 814                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 815                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 816
 817 # Check for thread headers.
 818 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 819 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 820
 821 # These tests can't be done till we know if we have limits.h.
 822 gcc_AC_C_CHAR_BIT
 823 AC_C_BIGENDIAN_CROSS
 824
 825 # --------
 826 # UNSORTED
 827 # --------
 828
 829 # Stage specific cflags for build.
 830 stage1_cflags=
 831 case $build in
 832 vax-*-*)
 833   if test x$GCC = xyes
 834   then
 835     stage1_cflags="-Wa,-J"
 836   else
 837     stage1_cflags="-J"
 838   fi
 839   ;;
 840 powerpc-*-darwin*)
 841   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 842   # sources; use -no-cpp-precomp to get to GNU cpp.
 843   # Apple's GCC has bugs in designated initializer handling, so disable
 844   # that too.
 845   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 846   ;;
 847 esac
 848 AC_SUBST(stage1_cflags)
 849
 850 # These libraries may be used by collect2.
 851 # We may need a special search path to get them linked.
 852 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 853 [save_LIBS="$LIBS"
 854 for libs in '' -lld -lmld \
 855                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 856                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 857 do
 858         LIBS="$libs"
 859         AC_TRY_LINK_FUNC(ldopen,
 860                 [gcc_cv_collect2_libs="$libs"; break])
 861 done
 862 LIBS="$save_LIBS"
 863 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 864 case $gcc_cv_collect2_libs in
 865         "none required")        ;;
 866         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 867 esac
 868 AC_SUBST(COLLECT2_LIBS)
 869
 870 # When building Ada code on Alpha, we need exc_resume which is usually in
 871 # -lexc.  So test for it.
 872 save_LIBS="$LIBS"
 873 LIBS=
 874 AC_SEARCH_LIBS(exc_resume, exc)
 875 GNAT_LIBEXC="$LIBS"
 876 LIBS="$save_LIBS"
 877 AC_SUBST(GNAT_LIBEXC)
 878
 879 # Some systems put ldexp and frexp in libm instead of libc; assume
 880 # they're both in the same place.  jcf-dump needs them.
 881 save_LIBS="$LIBS"
 882 LIBS=
 883 AC_SEARCH_LIBS(ldexp, m)
 884 LDEXP_LIB="$LIBS"
 885 LIBS="$save_LIBS"
 886 AC_SUBST(LDEXP_LIB)
 887
 888 # Use <inttypes.h> only if it exists,
 889 # doesn't clash with <sys/types.h>, and declares intmax_t.
 890 AC_MSG_CHECKING(for inttypes.h)
 891 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 892 [AC_TRY_COMPILE(
 893   [#include <sys/types.h>
 894 #include <inttypes.h>],
 895   [intmax_t i = -1;],
 896   [gcc_cv_header_inttypes_h=yes],
 897   gcc_cv_header_inttypes_h=no)])
 898 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 899 if test $gcc_cv_header_inttypes_h = yes; then
 900   AC_DEFINE(HAVE_INTTYPES_H, 1,
 901         [Define if you have a working <inttypes.h> header file.])
 902 fi
 903
 904 dnl Disabled until we have a complete test for buggy enum bitfields.
 905 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 906
 907 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 908         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 909         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 910         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 911         setlocale)
 912
 913 if test x$ac_cv_func_mbstowcs = xyes; then
 914   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 915 [    AC_TRY_RUN([#include <stdlib.h>
 916 int main()
 917 {
 918   mbstowcs(0, "", 0);
 919   return 0;
 920 }],
 921     gcc_cv_func_mbstowcs_works=yes,
 922     gcc_cv_func_mbstowcs_works=no,
 923     gcc_cv_func_mbstowcs_works=yes)])
 924   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 925     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 926   [Define this macro if mbstowcs does not crash when its
 927    first argument is NULL.])
 928   fi
 929 fi
 930
 931 AC_CHECK_TYPE(ssize_t, int)
 932
 933 # Try to determine the array type of the second argument of getgroups
 934 # for the target system (int or gid_t).
 935 AC_TYPE_GETGROUPS
 936 if test "${target}" = "${build}"; then
 937   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 938 else
 939   case "${target}" in
 940         # This condition may need some tweaking.  It should include all
 941         # targets where the array type of the second argument of getgroups
 942         # is int and the type of gid_t is not equivalent to int.
 943         *-*-sunos* | *-*-ultrix*)
 944                 TARGET_GETGROUPS_T=int
 945                 ;;
 946         *)
 947                 TARGET_GETGROUPS_T=gid_t
 948                 ;;
 949   esac
 950 fi
 951 AC_SUBST(TARGET_GETGROUPS_T)
 952
 953 gcc_AC_FUNC_PRINTF_PTR
 954 gcc_AC_FUNC_MMAP_BLACKLIST
 955
 956 case "${host}" in
 957 *-*-*vms*)
 958   # Under VMS, vfork works very differently than on Unix. The standard test
 959   # won't work, and it isn't easily adaptable. It makes more sense to
 960   # just force it.
 961   ac_cv_func_vfork_works=yes
 962   ;;
 963 esac
 964 AC_FUNC_VFORK
 965
 966 AM_ICONV
 967 # Until we have in-tree GNU iconv:
 968 LIBICONV_DEP=
 969 AC_SUBST(LIBICONV_DEP)
 970
 971 AM_LC_MESSAGES
 972
 973 # We will need to find libiberty.h and ansidecl.h
 974 saved_CFLAGS="$CFLAGS"
 975 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 976 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 977         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 978         fprintf_unlocked strstr errno snprintf vasprintf \
 979         malloc realloc calloc free basename getopt clock, , ,[
 980 #include "ansidecl.h"
 981 #include "system.h"])
 982
 983 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 984 #include "ansidecl.h"
 985 #include "system.h"
 986 #ifdef HAVE_SYS_RESOURCE_H
 987 #include <sys/resource.h>
 988 #endif
 989 ])
 990
 991 AC_TRY_COMPILE([
 992 #include "ansidecl.h"
 993 #include "system.h"
 994 #ifdef HAVE_SYS_RESOURCE_H
 995 #include <sys/resource.h>
 996 #endif
 997 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 998 [Define to \`long' if <sys/resource.h> doesn't define.])])
 999
1000 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1001 #include "ansidecl.h"
1002 #include "system.h"
1003 #ifdef HAVE_LDFCN_H
1004 #include <ldfcn.h>
1005 #endif
1006 ])
1007
1008 gcc_AC_CHECK_DECLS(times, , ,[
1009 #include "ansidecl.h"
1010 #include "system.h"
1011 #ifdef HAVE_SYS_TIMES_H
1012 #include <sys/times.h>
1013 #endif
1014 ])
1015
1016 # More time-related stuff.
1017 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1018 AC_TRY_COMPILE([
1019 #include "ansidecl.h"
1020 #include "system.h"
1021 #ifdef HAVE_SYS_TIMES_H
1022 #include <sys/times.h>
1023 #endif
1024 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1025 if test $ac_cv_struct_tms = yes; then
1026   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1027   [Define if <sys/times.h> defines struct tms.])
1028 fi
1029
1030 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1031 # revisit after autoconf 2.50.
1032 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1033 AC_TRY_COMPILE([
1034 #include "ansidecl.h"
1035 #include "system.h"
1036 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1037 if test $gcc_cv_type_clock_t = yes; then
1038   AC_DEFINE(HAVE_CLOCK_T, 1,
1039   [Define if <time.h> defines clock_t.])
1040 fi
1041
1042 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
1043 [AC_TRY_COMPILE([
1044 #include "ansidecl.h"
1045 #include "system.h"
1046 ],
1047 [if ((uchar *)0) return 0;
1048  if (sizeof(uchar)) return 0;],
1049 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
1050 if test $ac_cv_type_uchar = yes; then
1051   AC_DEFINE(HAVE_UCHAR, 1,
1052   [Define if <sys/types.h> defines \`uchar'.])
1053 fi
1054
1055 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1056 CFLAGS="$saved_CFLAGS"
1057
1058 gcc_AC_INITFINI_ARRAY
1059
1060 # mkdir takes a single argument on some systems.
1061 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1062
1063 # File extensions
1064 manext='.1'
1065 objext='.o'
1066 AC_SUBST(manext)
1067 AC_SUBST(objext)
1068
1069 # With Setjmp/Longjmp based exception handling.
1070 AC_ARG_ENABLE(sjlj-exceptions,
1071 [  --enable-sjlj-exceptions
1072                           arrange to use setjmp/longjmp exception handling],
1073 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1074 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1075   [Define 0/1 to force the choice for exception handling model.])])
1076
1077 if test x$host = x$target; then
1078    AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
1079 else
1080    use_libunwind_default=no
1081 fi
1082 # Use libunwind based exception handling.
1083 AC_ARG_ENABLE(libunwind-exceptions,
1084 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
1085 use_libunwind_exceptions=$enableval,
1086 use_libunwind_exceptions=$use_libunwind_default)
1087 if test x"$use_libunwind_exceptions" = xyes; then
1088    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
1089         [Define if gcc should use -lunwind.])
1090 fi
1091
1092 # --------------------------------------------------------
1093 # Build, host, and target specific configuration fragments
1094 # --------------------------------------------------------
1095
1096 # Collect build-machine-specific information.
1097 . ${srcdir}/config.build
1098
1099 # Collect host-machine-specific information.
1100 . ${srcdir}/config.host
1101
1102 target_gtfiles=
1103
1104 # Collect target-machine-specific information.
1105 . ${srcdir}/config.gcc
1106
1107 extra_objs="${host_extra_objs} ${extra_objs}"
1108 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1109
1110 # Default the target-machine variables that were not explicitly set.
1111 if test x"$tm_file" = x
1112 then tm_file=$cpu_type/$cpu_type.h; fi
1113
1114 if test x"$extra_headers" = x
1115 then extra_headers=; fi
1116
1117 if test x$md_file = x
1118 then md_file=$cpu_type/$cpu_type.md; fi
1119
1120 if test x$out_file = x
1121 then out_file=$cpu_type/$cpu_type.c; fi
1122
1123 if test x"$tmake_file" = x
1124 then tmake_file=$cpu_type/t-$cpu_type
1125 fi
1126
1127 if test x"$dwarf2" = xyes
1128 then tm_file="$tm_file tm-dwarf2.h"
1129 fi
1130
1131 # Say what files are being used for the output code and MD file.
1132 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1133 echo "Using \`$srcdir/config/$md_file' as machine description file."
1134
1135 # If any of the xm_file variables contain nonexistent files, warn
1136 # about them and drop them.
1137
1138 bx=
1139 for x in $build_xm_file; do
1140   if    test -f $srcdir/config/$x
1141   then      bx="$bx $x"
1142   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1143   fi
1144 done
1145 build_xm_file="$bx"
1146
1147 hx=
1148 for x in $host_xm_file; do
1149   if    test -f $srcdir/config/$x
1150   then      hx="$hx $x"
1151   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1152   fi
1153 done
1154 host_xm_file="$hx"
1155
1156 tx=
1157 for x in $xm_file; do
1158   if    test -f $srcdir/config/$x
1159   then      tx="$tx $x"
1160   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1161   fi
1162 done
1163 xm_file="$tx"
1164
1165 count=a
1166 for f in $tm_file; do
1167         count=${count}x
1168 done
1169 if test $count = ax; then
1170         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1171 else
1172         echo "Using the following target machine macro files:"
1173         for f in $tm_file; do
1174                 echo "  $srcdir/config/$f"
1175         done
1176 fi
1177
1178 if test x$need_64bit_hwint = xyes; then
1179         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1180 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1181 fi
1182
1183 count=a
1184 for f in $host_xm_file; do
1185         count=${count}x
1186 done
1187 if test $count = a; then
1188         :
1189 elif test $count = ax; then
1190         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1191 else
1192         echo "Using the following host machine macro files:"
1193         for f in $host_xm_file; do
1194                 echo "  $srcdir/config/$f"
1195         done
1196 fi
1197 echo "Using ${out_host_hook_obj} for host machine hooks."
1198
1199 if test "$host_xm_file" != "$build_xm_file"; then
1200         count=a
1201         for f in $build_xm_file; do
1202                 count=${count}x
1203         done
1204         if test $count = a; then
1205                 :
1206         elif test $count = ax; then
1207                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1208         else
1209                 echo "Using the following build machine macro files:"
1210                 for f in $build_xm_file; do
1211                         echo "  $srcdir/config/$f"
1212                 done
1213         fi
1214 fi
1215
1216 # ---------
1217 # Threading
1218 # ---------
1219
1220 # Check if a valid thread package
1221 case ${enable_threads} in
1222   "" | no)
1223     # No threads
1224     target_thread_file='single'
1225     ;;
1226   yes)
1227     # default
1228     target_thread_file='single'
1229     ;;
1230   aix | dce | gnat | irix | posix | rtems | \
1231   single | solaris | vxworks | win32 )
1232     target_thread_file=${enable_threads}
1233     ;;
1234   *)
1235     echo "${enable_threads} is an unknown thread package" 1>&2
1236     exit 1
1237     ;;
1238 esac
1239
1240 if test x${thread_file} = x; then
1241   # No thread file set by target-specific clauses in config.gcc,
1242   # so use file chosen by default logic above
1243   thread_file=${target_thread_file}
1244 fi
1245
1246 # Make gthr-default.h if we have a thread file.
1247 gthread_flags=
1248 if test $thread_file != single; then
1249   rm -f gthr-default.h
1250   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1251   gthread_flags=-DHAVE_GTHR_DEFAULT
1252 fi
1253 AC_SUBST(gthread_flags)
1254
1255 # --------
1256 # UNSORTED
1257 # --------
1258
1259 if test x$enable___cxa_atexit = xyes || \
1260    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1261    AC_CHECK_FUNC(__cxa_atexit,
1262         [AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1263         [Define if you want to use __cxa_atexit, rather than atexit, to
1264         register C++ destructors for local statics and global objects.
1265         This is essential for fully standards-compliant handling of
1266         destructors, but requires __cxa_atexit in libc.])],
1267         echo "__cxa_atexit can't be enabled on this target")
1268 fi
1269
1270 # Look for a file containing extra machine modes.
1271 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1272   extra_modes_file='$(srcdir)'/config/${extra_modes}
1273   AC_SUBST(extra_modes_file)
1274   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1275   [Define to the name of a file containing a list of extra machine modes
1276    for this architecture.])
1277 fi
1278
1279 # auto-host.h is the file containing items generated by autoconf and is
1280 # the first file included by config.h.
1281 # If host=build, it is correct to have bconfig include auto-host.h
1282 # as well.  If host!=build, we are in error and need to do more
1283 # work to find out the build config parameters.
1284 if test x$host = x$build
1285 then
1286         build_auto=auto-host.h
1287         FORBUILD=..
1288 else
1289         # We create a subdir, then run autoconf in the subdir.
1290         # To prevent recursion we set host and build for the new
1291         # invocation of configure to the build for this invocation
1292         # of configure.
1293         tempdir=build.$$
1294         rm -rf $tempdir
1295         mkdir $tempdir
1296         cd $tempdir
1297         case ${srcdir} in
1298         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1299         *) realsrcdir=../${srcdir};;
1300         esac
1301         saved_CFLAGS="${CFLAGS}"
1302         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1303         ${realsrcdir}/configure \
1304                 --enable-languages=${enable_languages-all} \
1305                 --target=$target_alias --host=$build_alias --build=$build_alias
1306         CFLAGS="${saved_CFLAGS}"
1307
1308         # We just finished tests for the build machine, so rename
1309         # the file auto-build.h in the gcc directory.
1310         mv auto-host.h ../auto-build.h
1311         cd ..
1312         rm -rf $tempdir
1313         build_auto=auto-build.h
1314         FORBUILD=../${build_subdir}
1315 fi
1316 AC_SUBST(FORBUILD)
1317
1318 tm_file="${tm_file} defaults.h"
1319 tm_p_file="${tm_p_file} tm-preds.h"
1320 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1321 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1322 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1323 # put this back in temporarily.
1324 xm_file="ansidecl.h ${xm_file}"
1325
1326 # --------
1327 # UNSORTED
1328 # --------
1329
1330 # Get the version trigger filename from the toplevel
1331 if test "${with_gcc_version_trigger+set}" = set; then
1332         gcc_version_trigger=$with_gcc_version_trigger
1333 else
1334         gcc_version_trigger=${srcdir}/version.c
1335 fi
1336 changequote(,)dnl
1337 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1338 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1339
1340 # Compile in configure arguments.
1341 if test -f configargs.h ; then
1342         # Being re-configured.
1343         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1344         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1345 else
1346         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1347 fi
1348
1349 # Double all backslashes and backslash all quotes to turn
1350 # gcc_config_arguments into a C string.
1351 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1352 $gcc_config_arguments
1353 EOF
1354 gcc_config_arguments_str=`cat conftest.out`
1355 rm -f conftest.out
1356
1357 cat > configargs.h <<EOF
1358 /* Generated automatically. */
1359 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1360 static const char thread_model[] = "$thread_file";
1361
1362 static const struct {
1363   const char *name, *value;
1364 } configure_default_options[] = $configure_default_options;
1365 EOF
1366 changequote([,])dnl
1367
1368 # Internationalization
1369 PACKAGE=gcc
1370 VERSION="$gcc_version"
1371 AC_SUBST(PACKAGE)
1372 AC_SUBST(VERSION)
1373
1374 ZW_GNU_GETTEXT_SISTER_DIR
1375
1376 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1377 # -liconv on the link line twice.
1378 case "$LIBINTL" in *$LIBICONV*)
1379         LIBICONV= ;;
1380 esac
1381
1382 # Windows32 Registry support for specifying GCC installation paths.
1383 AC_ARG_ENABLE(win32-registry,
1384 [  --disable-win32-registry
1385                           disable lookup of installation paths in the
1386                           Registry on Windows hosts
1387   --enable-win32-registry enable registry lookup (default)
1388   --enable-win32-registry=KEY
1389                           use KEY instead of GCC version as the last portion
1390                           of the registry key],,)
1391 case $host_os in
1392         win32 | pe | cygwin* | mingw32* | uwin*)
1393 AC_MSG_CHECKING(whether windows registry support is requested)
1394 if test "x$enable_win32_registry" != xno; then
1395   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1396 [Define to 1 if installation paths should be looked up in Windows32
1397    Registry. Ignored on non windows32 hosts.])
1398   AC_MSG_RESULT(yes)
1399   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1400 else
1401   AC_MSG_RESULT(no)
1402 fi
1403
1404 # Check if user specified a different registry key.
1405 case "x${enable_win32_registry}" in
1406 x | xyes)
1407   # default.
1408   gcc_cv_win32_registry_key="$VERSION"
1409   ;;
1410 xno)
1411   # no registry lookup.
1412   gcc_cv_win32_registry_key=''
1413   ;;
1414 *)
1415   # user-specified key.
1416   gcc_cv_win32_registry_key="$enable_win32_registry"
1417   ;;
1418 esac
1419
1420 if test "x$enable_win32_registry" != xno; then
1421   AC_MSG_CHECKING(registry key on windows hosts)
1422   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1423         [Define to be the last portion of registry key on windows hosts.])
1424   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1425 fi
1426 ;;
1427 esac
1428
1429 # Get an absolute path to the GCC top-level source directory
1430 holddir=`${PWDCMD-pwd}`
1431 cd $srcdir
1432 topdir=`${PWDCMD-pwd}`
1433 cd $holddir
1434
1435 # Conditionalize the makefile for this host machine.
1436 xmake_file=
1437 for f in ${host_xmake_file}
1438 do
1439         if test -f ${srcdir}/config/$f
1440         then
1441                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1442         fi
1443 done
1444
1445 # Conditionalize the makefile for this target machine.
1446 tmake_file_=
1447 for f in ${tmake_file}
1448 do
1449         if test -f ${srcdir}/config/$f
1450         then
1451                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1452         fi
1453 done
1454 tmake_file="${tmake_file_}"
1455
1456 symbolic_link='ln -s'
1457
1458 # If the host doesn't support symlinks, modify CC in
1459 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1460 # Otherwise, we can use "CC=$(CC)".
1461 rm -f symtest.tem
1462 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1463 then
1464         cc_set_by_configure="\$(CC)"
1465         quoted_cc_set_by_configure="\$(CC)"
1466         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1467         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1468 else
1469         rm -f symtest.tem
1470         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1471         then
1472                 symbolic_link="cp -p"
1473         else
1474                 symbolic_link="cp"
1475         fi
1476         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1477         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1478         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1479         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1480 fi
1481 rm -f symtest.tem
1482
1483 out_object_file=`basename $out_file .c`.o
1484
1485 tm_file_list=
1486 tm_include_list=
1487 for f in $tm_file; do
1488   case $f in
1489     defaults.h )
1490        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1491        tm_include_list="${tm_include_list} $f"
1492        ;;
1493     * )
1494        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1495        tm_include_list="${tm_include_list} config/$f"
1496        ;;
1497   esac
1498 done
1499
1500 tm_p_file_list=
1501 tm_p_include_list=
1502 for f in $tm_p_file; do
1503   case $f in
1504     tm-preds.h )
1505        tm_p_file_list="${tm_p_file_list} $f"
1506        tm_p_include_list="${tm_p_include_list} $f"
1507        ;;
1508     * )
1509        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1510        tm_p_include_list="${tm_p_include_list} config/$f"
1511   esac
1512 done
1513
1514 xm_file_list=
1515 xm_include_list=
1516 for f in $xm_file; do
1517   case $f in
1518     ansidecl.h )
1519        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1520        xm_include_list="${xm_include_list} $f"
1521        ;;
1522     auto-host.h )
1523        xm_file_list="${xm_file_list} $f"
1524        xm_include_list="${xm_include_list} $f"
1525        ;;
1526     * )
1527        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1528        xm_include_list="${xm_include_list} config/$f"
1529        ;;
1530   esac
1531 done
1532
1533 host_xm_file_list=
1534 host_xm_include_list=
1535 for f in $host_xm_file; do
1536   case $f in
1537     ansidecl.h )
1538        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1539        host_xm_include_list="${host_xm_include_list} $f"
1540        ;;
1541     auto-host.h )
1542        host_xm_file_list="${host_xm_file_list} $f"
1543        host_xm_include_list="${host_xm_include_list} $f"
1544        ;;
1545     * )
1546        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1547        host_xm_include_list="${host_xm_include_list} config/$f"
1548        ;;
1549   esac
1550 done
1551
1552 build_xm_file_list=
1553 for f in $build_xm_file; do
1554   case $f in
1555     ansidecl.h )
1556        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1557        build_xm_include_list="${build_xm_include_list} $f"
1558        ;;
1559     auto-build.h | auto-host.h )
1560        build_xm_file_list="${build_xm_file_list} $f"
1561        build_xm_include_list="${build_xm_include_list} $f"
1562        ;;
1563     * )
1564        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1565        build_xm_include_list="${build_xm_include_list} config/$f"
1566        ;;
1567   esac
1568 done
1569
1570 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1571 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1572 CROSS=                                          AC_SUBST(CROSS)
1573 ALL=all.internal                                AC_SUBST(ALL)
1574 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1575 if test x$host != x$target
1576 then
1577         CROSS="-DCROSS_COMPILE"
1578         ALL=all.cross
1579         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1580         case "$host","$target" in
1581         # Darwin crosses can use the host system's libraries and headers,
1582         # because of the fat library support.  Of course, it must be the
1583         # same version of Darwin on both sides.  Allow the user to
1584         # just say --target=foo-darwin without a version number to mean
1585         # "the version on this system".
1586             *-*-darwin*,*-*-darwin*)
1587                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1588                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1589                 if test $hostos = $targetos -o $targetos = darwin ; then
1590                     CROSS=
1591                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1592                     with_headers=yes
1593                 fi
1594                 ;;
1595
1596             i?86-*-*,x86_64-*-* \
1597             | powerpc*-*-*,powerpc64*-*-*)
1598                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1599         esac
1600 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1601         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1602         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1603 fi
1604
1605 # If this is a cross-compiler that does not
1606 # have its own set of headers then define
1607 # inhibit_libc
1608
1609 # If this is using newlib, without having the headers available now,
1610 # then define inhibit_libc in LIBGCC2_CFLAGS.
1611 # This prevents libgcc2 from containing any code which requires libc
1612 # support.
1613 inhibit_libc=
1614 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1615        test x$with_newlib = xyes ; } &&
1616      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1617        inhibit_libc=-Dinhibit_libc
1618 fi
1619 AC_SUBST(inhibit_libc)
1620
1621 # When building gcc with a cross-compiler, we need to adjust things so
1622 # that the generator programs are still built with the native compiler.
1623 # Also, we cannot run fixincludes or fix-header.
1624
1625 # These are the normal (build=host) settings:
1626 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1627 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1628 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1629 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1630
1631 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1632
1633 # Possibly disable fixproto, on a per-target basis.
1634 case ${use_fixproto} in
1635   no)
1636     STMP_FIXPROTO=
1637     ;;
1638   yes)
1639     STMP_FIXPROTO=stmp-fixproto
1640     ;;
1641 esac
1642 AC_SUBST(STMP_FIXPROTO)
1643
1644 # And these apply if build != host, or we are generating coverage data
1645 if test x$build != x$host || test "x$coverage_flags" != x
1646 then
1647     BUILD_PREFIX=build-
1648     BUILD_PREFIX_1=build-
1649     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1650
1651     if test "x$TARGET_SYSTEM_ROOT" = x; then
1652         STMP_FIXINC=
1653         STMP_FIXPROTO=
1654     fi
1655 fi
1656
1657 # Expand extra_headers to include complete path.
1658 # This substitutes for lots of t-* files.
1659 extra_headers_list=
1660 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1661 for file in ${extra_headers} ; do
1662   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1663 done
1664
1665 # Define collect2 in Makefile.
1666 case $host_can_use_collect2 in
1667   no) collect2= ;;
1668   *) collect2='collect2$(exeext)' ;;
1669 esac
1670 AC_SUBST([collect2])
1671
1672 # Add a definition of USE_COLLECT2 if system wants one.
1673 case $use_collect2 in
1674   no) use_collect2= ;;
1675   "") ;;
1676   *)
1677     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1678     xm_defines="${xm_defines} USE_COLLECT2"
1679     case $host_can_use_collect2 in
1680       no)
1681         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1682         ;;
1683     esac
1684     ;;
1685 esac
1686
1687 # ---------------------------
1688 # Assembler & linker features
1689 # ---------------------------
1690
1691 # Identify the assembler which will work hand-in-glove with the newly
1692 # built GCC, so that we can examine its features.  This is the assembler
1693 # which will be driven by the driver program.
1694 #
1695 # If build != host, and we aren't building gas in-tree, we identify a
1696 # build->target assembler and hope that it will have the same features
1697 # as the host->target assembler we'll be using.
1698 AC_MSG_CHECKING(what assembler to use)
1699 in_tree_gas=no
1700 gcc_cv_as=
1701 gcc_cv_gas_major_version=
1702 gcc_cv_gas_minor_version=
1703 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1704 if test -x "$DEFAULT_ASSEMBLER"; then
1705         gcc_cv_as="$DEFAULT_ASSEMBLER"
1706 elif test -x "$AS"; then
1707         gcc_cv_as="$AS"
1708 elif test -x as$host_exeext; then
1709         # Build using assembler in the current directory.
1710         gcc_cv_as=./as$host_exeext
1711 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1712      && test -f ../gas/Makefile; then
1713   # Single tree build which includes gas.
1714   in_tree_gas=yes
1715   _gcc_COMPUTE_GAS_VERSION
1716   rm -f as$host_exeext
1717   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1718   in_tree_gas_is_elf=no
1719   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1720      || (grep 'obj_format = multi' ../gas/Makefile \
1721          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1722   then
1723     in_tree_gas_is_elf=yes
1724   fi
1725 fi
1726
1727 if test "x$gcc_cv_as" = x; then
1728         # Search the same directories that the installed compiler will
1729         # search.  Else we may find the wrong assembler and lose.  If we
1730         # do not find a suitable assembler binary, then try the user's
1731         # path.
1732         #
1733         # Also note we have to check MD_EXEC_PREFIX before checking the
1734         # user's path.  Unfortunately, there is no good way to get at the
1735         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1736         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1737         # to be fixed as part of the make/configure rewrite too.
1738
1739         if test "x$exec_prefix" = xNONE; then
1740                 if test "x$prefix" = xNONE; then
1741                         test_prefix=/usr/local
1742                 else
1743                         test_prefix=$prefix
1744                 fi
1745         else
1746                 test_prefix=$exec_prefix
1747         fi
1748
1749         # If the loop below does not find an assembler, then use whatever
1750         # one we can find in the users's path.
1751         # user's path.
1752         if test "x$program_prefix" != xNONE; then
1753                 gcc_cv_as=${program_prefix}as$host_exeext
1754         else
1755                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$host_exeext
1756         fi
1757
1758         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1759                    $test_prefix/libexec/gcc/$target_noncanonical \
1760                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1761                    /usr/lib/gcc/$target_noncanonical \
1762                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1763                    $test_prefix/$target_noncanonical/bin"
1764
1765         if test x$host = x$target; then
1766             test_dirs="$test_dirs \
1767                    /usr/libexec \
1768                    /usr/ccs/gcc \
1769                    /usr/ccs/bin \
1770                    /udk/usr/ccs/bin \
1771                    /bsd43/usr/lib/cmplrs/cc \
1772                    /usr/cross64/usr/bin \
1773                    /usr/lib/cmplrs/cc \
1774                    /sysv/usr/lib/cmplrs/cc \
1775                    /svr4/usr/lib/cmplrs/cc \
1776                    /usr/bin"
1777         fi
1778
1779         for dir in $test_dirs; do
1780                 if test -x $dir/as$host_exeext; then
1781                         gcc_cv_as=$dir/as$host_exeext
1782                         break;
1783                 fi
1784         done
1785 fi
1786 case $in_tree_gas in
1787   yes)
1788     AC_MSG_RESULT("newly built gas")
1789     ;;
1790   no)
1791     AC_MSG_RESULT($gcc_cv_as)
1792     ;;
1793 esac
1794
1795 # Identify the linker which will work hand-in-glove with the newly
1796 # built GCC, so that we can examine its features.  This is the linker
1797 # which will be driven by the driver program.
1798 #
1799 # If build != host, and we aren't building gas in-tree, we identify a
1800 # build->target linker and hope that it will have the same features
1801 # as the host->target linker we'll be using.
1802 AC_MSG_CHECKING(what linker to use)
1803 in_tree_ld=no
1804 gcc_cv_ld=
1805 gcc_cv_gld_major_version=
1806 gcc_cv_gld_minor_version=
1807 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1808 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1809 if test -x "$DEFAULT_LINKER"; then
1810         gcc_cv_ld="$DEFAULT_LINKER"
1811 elif test -x "$LD_FOR_TARGET"; then
1812         gcc_cv_ld="$LD_FOR_TARGET"
1813 elif test -x "$LD" && test x$host = x$target; then
1814         gcc_cv_ld="$LD"
1815 elif test -x collect-ld$host_exeext; then
1816         # Build using linker in the current directory.
1817         gcc_cv_ld=./collect-ld$host_exeext
1818 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1819      && test -f ../ld/Makefile; then
1820         # Single tree build which includes ld.
1821         in_tree_ld=yes
1822         in_tree_ld_is_elf=no
1823         if (grep 'EMUL = .*elf' ../ld/Makefile \
1824             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1825           in_tree_ld_is_elf=yes
1826         fi
1827         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1828         do
1829 changequote(,)dnl
1830                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1831 changequote([,])dnl
1832                 if test x$gcc_cv_gld_version != x; then
1833                         break
1834                 fi
1835         done
1836 changequote(,)dnl
1837         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1838         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1839 changequote([,])dnl
1840         rm -f collect-ld$host_exeext
1841         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1842                 2>/dev/null
1843 fi
1844
1845 if test "x$gcc_cv_ld" = x; then
1846         # Search the same directories that the installed compiler will
1847         # search.  Else we may find the wrong linker and lose.  If we
1848         # do not find a suitable linker binary, then try the user's
1849         # path.
1850         #
1851         # Also note we have to check MD_EXEC_PREFIX before checking the
1852         # user's path.  Unfortunately, there is no good way to get at the
1853         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1854         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1855         # to be fixed as part of the make/configure rewrite too.
1856
1857         if test "x$exec_prefix" = xNONE; then
1858                 if test "x$prefix" = xNONE; then
1859                         test_prefix=/usr/local
1860                 else
1861                         test_prefix=$prefix
1862                 fi
1863         else
1864                 test_prefix=$exec_prefix
1865         fi
1866
1867         # If the loop below does not find an linker, then use whatever
1868         # one we can find in the users's path.
1869         # user's path.
1870         if test "x$program_prefix" != xNONE; then
1871                 gcc_cv_ld=${program_prefix}ld$host_exeext
1872         else
1873                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$host_exeext
1874         fi
1875
1876         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1877                    $test_prefix/libexec/gcc/$target_noncanonical \
1878                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1879                    /usr/lib/gcc/$target_noncanonical \
1880                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1881                    $test_prefix/$target_noncanonical/bin"
1882
1883         if test x$host = x$target; then
1884             test_dirs="$test_dirs \
1885                    /usr/libexec \
1886                    /usr/ccs/gcc \
1887                    /usr/ccs/bin \
1888                    /udk/usr/ccs/bin \
1889                    /bsd43/usr/lib/cmplrs/cc \
1890                    /usr/cross64/usr/bin \
1891                    /usr/lib/cmplrs/cc \
1892                    /sysv/usr/lib/cmplrs/cc \
1893                    /svr4/usr/lib/cmplrs/cc \
1894                    /usr/bin"
1895         fi
1896
1897         for dir in $test_dirs; do
1898                 if test -x $dir/ld$host_exeext; then
1899                         gcc_cv_ld=$dir/ld$host_exeext
1900                         break;
1901                 fi
1902         done
1903 fi
1904 case $in_tree_ld in
1905   yes)
1906     AC_MSG_RESULT("newly built ld")
1907     ;;
1908   no)
1909     AC_MSG_RESULT($gcc_cv_ld)
1910     ;;
1911 esac
1912
1913 # Figure out what nm we will be using.
1914 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1915 AC_MSG_CHECKING(what nm to use)
1916 in_tree_nm=no
1917 if test -x nm$host_exeext; then
1918         gcc_cv_nm=./nm$host_exeext
1919 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1920      && test -f ../binutils/Makefile; then
1921         # Single tree build which includes binutils.
1922         in_tree_nm=yes
1923         gcc_cv_nm=./nm$host_exeext
1924         rm -f nm$host_exeext
1925         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1926 elif test "x$program_prefix" != xNONE; then
1927         gcc_cv_nm=${program_prefix}nm$host_exeext
1928 else
1929         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$host_exeext
1930 fi
1931 case $in_tree_nm in
1932   yes) AC_MSG_RESULT("newly built nm") ;;
1933   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1934 esac
1935
1936 # Figure out what objdump we will be using.
1937 AC_MSG_CHECKING(what objdump to use)
1938 in_tree_objdump=no
1939 if test -x objdump$host_exeext; then
1940         gcc_cv_objdump=./objdump$host_exeext
1941 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1942      && test -f ../binutils/Makefile; then
1943         # Single tree build which includes binutils.
1944         in_tree_objdump=yes
1945         gcc_cv_objdump=./objdump$host_exeext
1946         rm -f objdump$host_exeext
1947         $symbolic_link ../binutils/objdump$host_exeext \
1948                 objdump$host_exeext 2>/dev/null
1949 elif test "x$program_prefix" != xNONE; then
1950         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1951 else
1952         gcc_cv_objdump=`echo objdump | \
1953                 sed "${program_transform_name}"`$host_exeext
1954 fi
1955 case $in_tree_objdump in
1956   yes) AC_MSG_RESULT("newly built objdump") ;;
1957   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1958 esac
1959
1960 # Figure out what assembler alignment features are present.
1961 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1962  [2,6,0],,
1963 [.balign 4
1964 .p2align 2],,
1965 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1966   [Define if your assembler supports .balign and .p2align.])])
1967
1968 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1969  [2,8,0],,
1970  [.p2align 4,,7],,
1971 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1972   [Define if your assembler supports specifying the maximum number
1973    of bytes to skip when using the GAS .p2align command.])])
1974
1975 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1976  [elf,2,9,0],,
1977  [conftest_label1: .word 0
1978 .subsection -1
1979 conftest_label2: .word 0
1980 .previous],
1981  [if test x$gcc_cv_nm != x; then
1982     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1983     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1984     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1985     then :
1986     else gcc_cv_as_subsection_m1=yes
1987     fi
1988     rm -f conftest.nm1 conftest.nm2
1989   fi],
1990  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1991   [Define if your assembler supports .subsection and .subsection -1 starts
1992    emitting at the beginning of your section.])])
1993
1994 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1995  [2,2,0],,
1996  [      .weak foobar],,
1997 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1998
1999 # .hidden needs to be supported in both the assembler and the linker,
2000 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2001 # This is irritatingly difficult to feature test for; we have to check the
2002 # date string after the version number.  If we've got an in-tree
2003 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2004 # to be safe.
2005 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2006 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2007  [elf,2,13,0],,
2008 [       .hidden foobar
2009 foobar:])
2010
2011 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2012 [if test $in_tree_ld = yes ; then
2013   gcc_cv_ld_hidden=no
2014   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2015      && test $in_tree_ld_is_elf = yes; then
2016      gcc_cv_ld_hidden=yes
2017   fi
2018 else
2019   gcc_cv_ld_hidden=yes
2020   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2021   if echo "$ld_ver" | grep GNU > /dev/null; then
2022 changequote(,)dnl
2023     ld_vers=`echo $ld_ver | sed -n \
2024         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2025         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2026         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2027         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2028         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2029         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2030     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2031     if test 0"$ld_date" -lt 20020404; then
2032       if test -n "$ld_date"; then
2033         # If there was date string, but was earlier than 2002-04-04, fail
2034         gcc_cv_ld_hidden=no
2035       elif test -z "$ld_vers"; then
2036         # If there was no date string nor ld version number, something is wrong
2037         gcc_cv_ld_hidden=no
2038       else
2039         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2040         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2041         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2042         test -z "$ld_vers_patch" && ld_vers_patch=0
2043         if test "$ld_vers_major" -lt 2; then
2044           gcc_cv_ld_hidden=no
2045         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2046           gcc_cv_ld_hidden="no"
2047         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2048           gcc_cv_ld_hidden=no
2049         fi
2050       fi
2051 changequote([,])dnl
2052     fi
2053   else
2054     case "${target}" in
2055       hppa64*-*-hpux* | ia64*-*-hpux*)
2056         gcc_cv_ld_hidden=yes
2057         ;;
2058       *)
2059         gcc_cv_ld_hidden=no
2060         ;;
2061     esac
2062   fi
2063 fi])
2064 libgcc_visibility=no
2065 AC_SUBST(libgcc_visibility)
2066 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2067   libgcc_visibility=yes
2068   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2069   [Define if your assembler and linker support .hidden.])
2070 fi
2071
2072 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2073 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2074   [elf,2,11,0],,
2075 [       .data
2076         .uleb128 L2 - L1
2077 L1:
2078         .uleb128 1280
2079         .sleb128 -1010
2080 L2:],
2081  [# GAS versions before 2.11 do not support uleb128,
2082   # despite appearing to.
2083   # ??? There exists an elf-specific test that will crash
2084   # the assembler.  Perhaps it's better to figure out whether
2085   # arbitrary sections are supported and try the test.
2086   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2087   if echo "$as_ver" | grep GNU > /dev/null; then
2088 changequote(,)dnl
2089     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2090     as_major=`echo $as_ver | sed 's/\..*//'`
2091     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2092 changequote([,])dnl
2093     if test $as_major -eq 2 && test $as_minor -lt 11
2094     then :
2095     else gcc_cv_as_leb128=yes
2096     fi
2097   fi],
2098   [AC_DEFINE(HAVE_AS_LEB128, 1,
2099     [Define if your assembler supports .sleb128 and .uleb128.])])
2100
2101 # GAS versions up to and including 2.11.0 may mis-optimize
2102 # .eh_frame data.
2103 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2104   [elf,2,12,0],,
2105 [       .text
2106 .LFB1:
2107         .4byte  0
2108 .L1:
2109         .4byte  0
2110 .LFE1:
2111         .section        .eh_frame,"aw",@progbits
2112 __FRAME_BEGIN__:
2113         .4byte  .LECIE1-.LSCIE1
2114 .LSCIE1:
2115         .4byte  0x0
2116         .byte   0x1
2117         .ascii "z\0"
2118         .byte   0x1
2119         .byte   0x78
2120         .byte   0x1a
2121         .byte   0x0
2122         .byte   0x4
2123         .4byte  1
2124         .p2align 1
2125 .LECIE1:
2126 .LSFDE1:
2127         .4byte  .LEFDE1-.LASFDE1
2128 .LASFDE1:
2129         .4byte  .LASFDE1-__FRAME_BEGIN__
2130         .4byte  .LFB1
2131         .4byte  .LFE1-.LFB1
2132         .byte   0x4
2133         .4byte  .LFE1-.LFB1
2134         .byte   0x4
2135         .4byte  .L1-.LFB1
2136 .LEFDE1:],
2137 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2138 cat > conftest.lit <<EOF
2139  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2140  0010 01000000 12000000 18000000 00000000  ................
2141  0020 08000000 04080000 0044               .........D      @&t@
2142 EOF
2143 cat > conftest.big <<EOF
2144  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2145  0010 00000001 00000012 00000018 00000000  ................
2146  0020 00000008 04000000 0844               .........D      @&t@
2147 EOF
2148   # If the assembler didn't choke, and we can objdump,
2149   # and we got the correct data, then succeed.
2150   if test x$gcc_cv_objdump != x \
2151   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2152      | tail -3 > conftest.got \
2153   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2154     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2155   then
2156     gcc_cv_as_eh_frame=yes
2157   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2158     gcc_cv_as_eh_frame=buggy
2159   else
2160     # Uh oh, what do we do now?
2161     gcc_cv_as_eh_frame=no
2162   fi])
2163
2164 if test $gcc_cv_as_eh_frame = buggy; then
2165   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2166   [Define if your assembler mis-optimizes .eh_frame data.])
2167 fi
2168
2169 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2170  [elf,2,12,0], [--fatal-warnings],
2171  [.section .rodata.str, "aMS", @progbits, 1])
2172 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2173   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2174 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2175
2176 # Thread-local storage - the check is heavily parametrized.
2177 conftest_s=
2178 tls_first_major=
2179 tls_first_minor=
2180 tls_as_opt=
2181 case "$target" in
2182 changequote(,)dnl
2183   alpha*-*-*)
2184     conftest_s='
2185         .section ".tdata","awT",@progbits
2186 foo:    .long   25
2187         .text
2188         ldq     $27,__tls_get_addr($29)         !literal!1
2189         lda     $16,foo($29)                    !tlsgd!1
2190         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2191         ldq     $27,__tls_get_addr($29)         !literal!2
2192         lda     $16,foo($29)                    !tlsldm!2
2193         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2194         ldq     $1,foo($29)                     !gotdtprel
2195         ldah    $2,foo($29)                     !dtprelhi
2196         lda     $3,foo($2)                      !dtprello
2197         lda     $4,foo($29)                     !dtprel
2198         ldq     $1,foo($29)                     !gottprel
2199         ldah    $2,foo($29)                     !tprelhi
2200         lda     $3,foo($2)                      !tprello
2201         lda     $4,foo($29)                     !tprel'
2202         tls_first_major=2
2203         tls_first_minor=13
2204         tls_as_opt=--fatal-warnings
2205         ;;
2206   i[34567]86-*-*)
2207     conftest_s='
2208         .section ".tdata","awT",@progbits
2209 foo:    .long   25
2210         .text
2211         movl    %gs:0, %eax
2212         leal    foo@TLSGD(,%ebx,1), %eax
2213         leal    foo@TLSLDM(%ebx), %eax
2214         leal    foo@DTPOFF(%eax), %edx
2215         movl    foo@GOTTPOFF(%ebx), %eax
2216         subl    foo@GOTTPOFF(%ebx), %eax
2217         addl    foo@GOTNTPOFF(%ebx), %eax
2218         movl    foo@INDNTPOFF, %eax
2219         movl    $foo@TPOFF, %eax
2220         subl    $foo@TPOFF, %eax
2221         leal    foo@NTPOFF(%ecx), %eax'
2222         tls_first_major=2
2223         tls_first_minor=14
2224         tls_as_opt=--fatal-warnings
2225         ;;
2226   x86_64-*-*)
2227     conftest_s='
2228         .section ".tdata","awT",@progbits
2229 foo:    .long   25
2230         .text
2231         movq    %fs:0, %rax
2232         leaq    foo@TLSGD(%rip), %rdi
2233         leaq    foo@TLSLD(%rip), %rdi
2234         leaq    foo@DTPOFF(%rax), %rdx
2235         movq    foo@GOTTPOFF(%rip), %rax
2236         movq    $foo@TPOFF, %rax'
2237         tls_first_major=2
2238         tls_first_minor=14
2239         tls_as_opt=--fatal-warnings
2240         ;;
2241   ia64-*-*)
2242     conftest_s='
2243         .section ".tdata","awT",@progbits
2244 foo:    data8   25
2245         .text
2246         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2247         addl    r17 = @ltoff(@dtprel(foo#)), gp
2248         addl    r18 = @ltoff(@tprel(foo#)), gp
2249         addl    r19 = @dtprel(foo#), gp
2250         adds    r21 = @dtprel(foo#), r13
2251         movl    r23 = @dtprel(foo#)
2252         addl    r20 = @tprel(foo#), gp
2253         adds    r22 = @tprel(foo#), r13
2254         movl    r24 = @tprel(foo#)'
2255         tls_first_major=2
2256         tls_first_minor=13
2257         tls_as_opt=--fatal-warnings
2258         ;;
2259   powerpc-*-*)
2260     conftest_s='
2261         .section ".tdata","awT",@progbits
2262         .align 2
2263 ld0:    .space 4
2264 ld1:    .space 4
2265 x1:     .space 4
2266 x2:     .space 4
2267 x3:     .space 4
2268         .text
2269         addi 3,31,ld0@got@tlsgd
2270         bl __tls_get_addr
2271         addi 3,31,x1@got@tlsld
2272         bl __tls_get_addr
2273         addi 9,3,x1@dtprel
2274         addis 9,3,x2@dtprel@ha
2275         addi 9,9,x2@dtprel@l
2276         lwz 9,x3@got@tprel(31)
2277         add 9,9,x@tls
2278         addi 9,2,x1@tprel
2279         addis 9,2,x2@tprel@ha
2280         addi 9,9,x2@tprel@l'
2281         tls_first_major=2
2282         tls_first_minor=14
2283         tls_as_opt="-a32 --fatal-warnings"
2284         ;;
2285   powerpc64-*-*)
2286     conftest_s='
2287         .section ".tdata","awT",@progbits
2288         .align 3
2289 ld0:    .space 8
2290 ld1:    .space 8
2291 x1:     .space 8
2292 x2:     .space 8
2293 x3:     .space 8
2294         .text
2295         addi 3,2,ld0@got@tlsgd
2296         bl .__tls_get_addr
2297         nop
2298         addi 3,2,ld1@toc
2299         bl .__tls_get_addr
2300         nop
2301         addi 3,2,x1@got@tlsld
2302         bl .__tls_get_addr
2303         nop
2304         addi 9,3,x1@dtprel
2305         bl .__tls_get_addr
2306         nop
2307         addis 9,3,x2@dtprel@ha
2308         addi 9,9,x2@dtprel@l
2309         bl .__tls_get_addr
2310         nop
2311         ld 9,x3@got@dtprel(2)
2312         add 9,9,3
2313         bl .__tls_get_addr
2314         nop'
2315         tls_first_major=2
2316         tls_first_minor=14
2317         tls_as_opt="-a64 --fatal-warnings"
2318         ;;
2319   s390-*-*)
2320     conftest_s='
2321         .section ".tdata","awT",@progbits
2322 foo:    .long   25
2323         .text
2324         .long   foo@TLSGD
2325         .long   foo@TLSLDM
2326         .long   foo@DTPOFF
2327         .long   foo@NTPOFF
2328         .long   foo@GOTNTPOFF
2329         .long   foo@INDNTPOFF
2330         l       %r1,foo@GOTNTPOFF(%r12)
2331         l       %r1,0(%r1):tls_load:foo
2332         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2333         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2334         tls_first_major=2
2335         tls_first_minor=14
2336         tls_as_opt="-m31 --fatal-warnings"
2337         ;;
2338   s390x-*-*)
2339     conftest_s='
2340         .section ".tdata","awT",@progbits
2341 foo:    .long   25
2342         .text
2343         .quad   foo@TLSGD
2344         .quad   foo@TLSLDM
2345         .quad   foo@DTPOFF
2346         .quad   foo@NTPOFF
2347         .quad   foo@GOTNTPOFF
2348         lg      %r1,foo@GOTNTPOFF(%r12)
2349         larl    %r1,foo@INDNTPOFF
2350         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2351         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2352         tls_first_major=2
2353         tls_first_minor=14
2354         tls_as_opt="-m64 -Aesame --fatal-warnings"
2355         ;;
2356   sh-*-* | sh[34]-*-*)
2357     conftest_s='
2358         .section ".tdata","awT",@progbits
2359 foo:    .long   25
2360         .text
2361         .long   foo@TLSGD
2362         .long   foo@TLSLDM
2363         .long   foo@DTPOFF
2364         .long   foo@GOTTPOFF
2365         .long   foo@TPOFF'
2366         tls_first_major=2
2367         tls_first_minor=13
2368         tls_as_opt=--fatal-warnings
2369         ;;
2370   sparc*-*-*)
2371     case "$target" in
2372       sparc*-sun-solaris2.*)
2373         on_solaris=yes
2374         ;;
2375       *)
2376         on_solaris=no
2377         ;;
2378     esac
2379     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2380       conftest_s='
2381         .section ".tdata",#alloc,#write,#tls
2382 foo:    .long   25
2383         .text
2384         sethi   %tgd_hi22(foo), %o0
2385         add     %o0, %tgd_lo10(foo), %o1
2386         add     %l7, %o1, %o0, %tgd_add(foo)
2387         call    __tls_get_addr, %tgd_call(foo)
2388         sethi   %tldm_hi22(foo), %l1
2389         add     %l1, %tldm_lo10(foo), %l2
2390         add     %l7, %l2, %o0, %tldm_add(foo)
2391         call    __tls_get_addr, %tldm_call(foo)
2392         sethi   %tldo_hix22(foo), %l3
2393         xor     %l3, %tldo_lox10(foo), %l4
2394         add     %o0, %l4, %l5, %tldo_add(foo)
2395         sethi   %tie_hi22(foo), %o3
2396         add     %o3, %tie_lo10(foo), %o3
2397         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2398         add     %g7, %o2, %o4, %tie_add(foo)
2399         sethi   %tle_hix22(foo), %l1
2400         xor     %l1, %tle_lox10(foo), %o5
2401         ld      [%g7 + %o5], %o1'
2402         tls_first_major=0
2403         tls_first_minor=0
2404     else
2405       conftest_s='
2406         .section ".tdata","awT",@progbits
2407 foo:    .long   25
2408         .text
2409         sethi   %tgd_hi22(foo), %o0
2410         add     %o0, %tgd_lo10(foo), %o1
2411         add     %l7, %o1, %o0, %tgd_add(foo)
2412         call    __tls_get_addr, %tgd_call(foo)
2413         sethi   %tldm_hi22(foo), %l1
2414         add     %l1, %tldm_lo10(foo), %l2
2415         add     %l7, %l2, %o0, %tldm_add(foo)
2416         call    __tls_get_addr, %tldm_call(foo)
2417         sethi   %tldo_hix22(foo), %l3
2418         xor     %l3, %tldo_lox10(foo), %l4
2419         add     %o0, %l4, %l5, %tldo_add(foo)
2420         sethi   %tie_hi22(foo), %o3
2421         add     %o3, %tie_lo10(foo), %o3
2422         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2423         add     %g7, %o2, %o4, %tie_add(foo)
2424         sethi   %tle_hix22(foo), %l1
2425         xor     %l1, %tle_lox10(foo), %o5
2426         ld      [%g7 + %o5], %o1'
2427         tls_first_major=2
2428         tls_first_minor=14
2429         tls_as_opt="-32 --fatal-warnings"
2430       fi
2431         ;;
2432 changequote([,])dnl
2433 esac
2434 if test -z "$tls_first_major"; then
2435   : # If we don't have a check, assume no support.
2436 else
2437   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2438   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2439   [AC_DEFINE(HAVE_AS_TLS, 1,
2440             [Define if your assembler supports thread-local storage.])])
2441 fi
2442
2443 # Target-specific assembler checks.
2444
2445 case "$target" in
2446   # All TARGET_ABI_OSF targets.
2447   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2448     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2449         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2450 [       .set nomacro
2451         .text
2452         extbl   $3, $2, $3      !lituse_bytoff!1
2453         ldq     $2, a($29)      !literal!1
2454         ldq     $4, b($29)      !literal!2
2455         ldq_u   $3, 0($2)       !lituse_base!1
2456         ldq     $27, f($29)     !literal!5
2457         jsr     $26, ($27), f   !lituse_jsr!5
2458         ldah    $29, 0($26)     !gpdisp!3
2459         lda     $0, c($29)      !gprel
2460         ldah    $1, d($29)      !gprelhigh
2461         lda     $1, d($1)       !gprellow
2462         lda     $29, 0($29)     !gpdisp!3],,
2463     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2464   [Define if your assembler supports explicit relocations.])])
2465     ;;
2466
2467   cris-*-*)
2468     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2469       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2470       [-no-mul-bug-abort], [.text],,
2471       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2472                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2473     ;;
2474
2475   sparc*-*-*)
2476     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2477       [.register %g2, #scratch],,
2478       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2479                 [Define if your assembler supports .register.])])
2480
2481     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2482       [-relax], [.text],,
2483       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2484                 [Define if your assembler supports -relax option.])])
2485
2486     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2487       gcc_cv_as_sparc_ua_pcrel,,
2488       [-K PIC],
2489 [.text
2490 foo:
2491         nop
2492 .data
2493 .align 4
2494 .byte 0
2495 .uaword %r_disp32(foo)],
2496       [if test x$gcc_cv_ld != x \
2497        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2498          gcc_cv_as_sparc_ua_pcrel=yes
2499        fi
2500        rm -f conftest],
2501       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2502                 [Define if your assembler and linker support unaligned PC relative relocs.])
2503
2504       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2505         gcc_cv_as_sparc_ua_pcrel_hidden,,
2506         [-K PIC],
2507 [.data
2508 .align 4
2509 .byte 0x31
2510 .uaword %r_disp32(foo)
2511 .byte 0x32, 0x33, 0x34
2512 .global foo
2513 .hidden foo
2514 foo:
2515 .skip 4],
2516         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2517          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2518          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2519             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2520             if $gcc_cv_objdump -R conftest 2> /dev/null \
2521                | grep 'DISP32' > /dev/null 2>&1; then
2522                 :
2523             else
2524                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2525             fi
2526          fi
2527          rm -f conftest],
2528          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2529                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2530     ]) # unaligned pcrel relocs
2531
2532     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2533       gcc_cv_as_sparc_offsetable_lo10,,
2534       [-xarch=v9],
2535 [.text
2536         or %g1, %lo(ab) + 12, %g1
2537         or %g1, %lo(ab + 12), %g1],
2538       [if test x$gcc_cv_objdump != x \
2539        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2540           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2541          gcc_cv_as_offsetable_lo10=yes
2542        fi],
2543        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2544                  [Define if your assembler supports offsetable %lo().])])
2545     ;;
2546
2547 changequote(,)dnl
2548   i[34567]86-*-* | x86_64-*-*)
2549 changequote([,])dnl
2550     case $target_os in
2551       cygwin* | pe | mingw32*)
2552         # Used for DWARF 2 in PE
2553         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2554           gcc_cv_as_ix86_pe_secrel32,
2555           [2,15,91],,
2556 [.text
2557 foo:    nop
2558 .data
2559         .secrel32 foo],
2560           [if test x$gcc_cv_ld != x \
2561            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2562              gcc_cv_as_ix86_pe_secrel32=yes
2563            fi
2564            rm -f conftest],
2565           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2566             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2567         ;;
2568     esac
2569
2570     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2571        gcc_cv_as_ix86_filds_fists,
2572       [2,9,0],, [filds mem; fists mem],,
2573       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2574         [Define if your assembler uses the new HImode fild and fist notation.])])
2575
2576     gcc_GAS_CHECK_FEATURE([cmov syntax],
2577       gcc_cv_as_ix86_cmov_sun_syntax,,,
2578       [cmovl.l %edx, %eax],,
2579       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2580         [Define if your assembler supports the Sun syntax for cmov.])])
2581
2582     # This one is used unconditionally by i386.[ch]; it is to be defined
2583     # to 1 if the feature is present, 0 otherwise.
2584     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2585         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2586 [       .text
2587 .L0:
2588         nop
2589         .data
2590         .long .L0@GOTOFF])
2591     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2592       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2593       [Define true if the assembler supports '.long foo@GOTOFF'.])
2594     ;;
2595
2596   ia64*-*-*)
2597     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2598         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2599 [       .text
2600         addl r15 = @ltoffx(x#), gp
2601         ;;
2602         ld8.mov r16 = [[r15]], x#],,
2603     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2604           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2605
2606     ;;
2607
2608   powerpc*-*-*)
2609     case $target in
2610       *-*-aix*) conftest_s='    .csect .text[[PR]]
2611         mfcr 3,128';;
2612       *-*-darwin*) conftest_s=' .text
2613         mfcr r3,128';;
2614       *)       conftest_s='     .text
2615         mfcr 3,128';;
2616     esac
2617
2618     gcc_GAS_CHECK_FEATURE([mfcr field support],
2619       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2620       [$conftest_s],,
2621       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2622           [Define if your assembler supports mfcr field.])])
2623     ;;
2624
2625   mips*-*-*)
2626     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2627       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2628 [       lw $4,%gp_rel(foo)($4)],,
2629       [if test x$target_cpu_default = x
2630        then target_cpu_default=MASK_EXPLICIT_RELOCS
2631        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2632        fi])
2633
2634     ;;
2635 esac
2636 # ??? Not all targets support dwarf2 debug_line, even within a version
2637 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2638 # info to the output file.  So, as supported targets are added to gas 2.11,
2639 # add some instruction here to (also) show we expect this might work.
2640 # ??? Once 2.11 is released, probably need to add first known working
2641 # version to the per-target configury.
2642 case "$target" in
2643   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2644   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2645   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2646     insn="nop"
2647     ;;
2648   ia64*-*-* | s390*-*-*)
2649     insn="nop 0"
2650     ;;
2651   mmix-*-*)
2652     insn="swym 0"
2653     ;;
2654 esac
2655 if test x"$insn" != x; then
2656  conftest_s="\
2657         .file 1 \"conftest.s\"
2658         .loc 1 3 0
2659         $insn"
2660  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2661   gcc_cv_as_dwarf2_debug_line,
2662   [elf,2,11,0],, [$conftest_s],
2663   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2664    if grep debug_line conftest.o > /dev/null 2>&1; then
2665      gcc_cv_as_dwarf2_debug_line=yes
2666    fi])
2667
2668 # The .debug_line file table must be in the exact order that
2669 # we specified the files, since these indices are also used
2670 # by DW_AT_decl_file.  Approximate this test by testing if
2671 # the assembler bitches if the same index is assigned twice.
2672  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2673   gcc_cv_as_dwarf2_file_buggy,,,
2674 [       .file 1 "foo.s"
2675         .file 1 "bar.s"])
2676
2677  if test $gcc_cv_as_dwarf2_debug_line = yes \
2678  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2679         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2680   [Define if your assembler supports dwarf2 .file/.loc directives,
2681    and preserves file table indices exactly as given.])
2682  fi
2683
2684  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2685   gcc_cv_as_gdwarf2_flag,
2686   [elf,2,11,0], [--gdwarf2], [$insn],,
2687   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2688 [Define if your assembler supports the --gdwarf2 option.])])
2689
2690  gcc_GAS_CHECK_FEATURE([--gstabs option],
2691   gcc_cv_as_gstabs_flag,
2692   [elf,2,11,0], [--gstabs], [$insn],
2693   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2694    # and warns about it, but still exits successfully.  So check for
2695    # this.
2696    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2697    then :
2698    else gcc_cv_as_gstabs_flag=yes
2699    fi],
2700   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2701 [Define if your assembler supports the --gstabs option.])])
2702 fi
2703
2704 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2705 gcc_cv_ld_ro_rw_mix=unknown
2706 if test $in_tree_ld = yes ; then
2707   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2708      && test $in_tree_ld_is_elf = yes; then
2709     gcc_cv_ld_ro_rw_mix=read-write
2710   fi
2711 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2712   echo '.section myfoosect, "a"' > conftest1.s
2713   echo '.section myfoosect, "aw"' > conftest2.s
2714   echo '.byte 1' >> conftest2.s
2715   echo '.section myfoosect, "a"' > conftest3.s
2716   echo '.byte 0' >> conftest3.s
2717   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2718      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2719      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2720      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2721         conftest2.o conftest3.o > /dev/null 2>&1; then
2722     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2723                          | sed -e '/myfoosect/!d' -e N`
2724     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2725       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2726         gcc_cv_ld_ro_rw_mix=read-only
2727       else
2728         gcc_cv_ld_ro_rw_mix=read-write
2729       fi
2730     fi
2731   fi
2732 changequote(,)dnl
2733   rm -f conftest.* conftest[123].*
2734 changequote([,])dnl
2735 fi
2736 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2737         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2738   [Define if your linker links a mix of read-only
2739    and read-write sections into a read-write section.])
2740 fi
2741 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2742
2743 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2744 gcc_cv_ld_eh_frame_hdr=no
2745 if test $in_tree_ld = yes ; then
2746   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2747      && test $in_tree_ld_is_elf = yes; then
2748     gcc_cv_ld_eh_frame_hdr=yes
2749   fi
2750 elif test x$gcc_cv_ld != x; then
2751         # Check if linker supports --eh-frame-hdr option
2752         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2753                 gcc_cv_ld_eh_frame_hdr=yes
2754         fi
2755 fi
2756 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2757         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2758 [Define if your linker supports --eh-frame-hdr option.])
2759 fi
2760 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2761
2762 AC_MSG_CHECKING(linker position independent executable support)
2763 gcc_cv_ld_pie=no
2764 if test $in_tree_ld = yes ; then
2765   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2766      && test $in_tree_ld_is_elf = yes; then
2767     gcc_cv_ld_pie=yes
2768   fi
2769 elif test x$gcc_cv_ld != x; then
2770         # Check if linker supports -pie option
2771         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2772                 gcc_cv_ld_pie=yes
2773         fi
2774 fi
2775 if test x"$gcc_cv_ld_pie" = xyes; then
2776         AC_DEFINE(HAVE_LD_PIE, 1,
2777 [Define if your linker supports -pie option.])
2778 fi
2779 AC_MSG_RESULT($gcc_cv_ld_pie)
2780
2781 # --------
2782 # UNSORTED
2783 # --------
2784
2785 AC_CACHE_CHECK(linker --as-needed support,
2786 gcc_cv_ld_as_needed,
2787 [gcc_cv_ld_as_needed=no
2788 if test $in_tree_ld = yes ; then
2789   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2790      && test $in_tree_ld_is_elf = yes; then
2791     gcc_cv_ld_as_needed=yes
2792   fi
2793 elif test x$gcc_cv_ld != x; then
2794         # Check if linker supports --as-needed and --no-as-needed options
2795         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2796                 gcc_cv_ld_as_needed=yes
2797         fi
2798 fi
2799 ])
2800 if test x"$gcc_cv_ld_as_needed" = xyes; then
2801         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2802 [Define if your linker supports --as-needed and --no-as-needed options.])
2803 fi
2804
2805 if test x$with_sysroot = x && test x$host = x$target \
2806    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2807   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2808 [Define to PREFIX/include if cpp should also search that directory.])
2809 fi
2810
2811 # Find out what GC implementation we want, or may, use.
2812 AC_ARG_WITH(gc,
2813 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2814                           with the compiler],
2815 [case "$withval" in
2816   page | zone)
2817     GGC=ggc-$withval
2818     ;;
2819   *)
2820     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2821     ;;
2822 esac],
2823 [GGC=ggc-page])
2824 AC_SUBST(GGC)
2825 echo "Using $GGC for garbage collection."
2826
2827 # Use the system's zlib library.
2828 zlibdir=-L../zlib
2829 zlibinc="-I\$(srcdir)/../zlib"
2830 AC_ARG_WITH(system-zlib,
2831 [  --with-system-zlib      use installed libz],
2832 zlibdir=
2833 zlibinc=
2834 )
2835 AC_SUBST(zlibdir)
2836 AC_SUBST(zlibinc)
2837
2838 dnl Very limited version of automake's enable-maintainer-mode
2839
2840 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2841   dnl maintainer-mode is disabled by default
2842   AC_ARG_ENABLE(maintainer-mode,
2843 [  --enable-maintainer-mode
2844                           enable make rules and dependencies not useful
2845                           (and sometimes confusing) to the casual installer],
2846       maintainer_mode=$enableval,
2847       maintainer_mode=no)
2848
2849 AC_MSG_RESULT($maintainer_mode)
2850
2851 if test "$maintainer_mode" = "yes"; then
2852   MAINT=''
2853 else
2854   MAINT='#'
2855 fi
2856 AC_SUBST(MAINT)dnl
2857
2858 AC_MSG_CHECKING([whether to use libbanshee for points-to alias analysis])
2859 AC_ARG_WITH(libbanshee,
2860 [  --with-libbanshee      enable libbanshee],
2861 libbanshee="$with_libbanshee",
2862 libbanshee=no)
2863
2864 if test x"$libbanshee" = xyes; then
2865         BANSHEELIB="../libbanshee/points-to/libandersen.a ../libbanshee/engine/libbansheeengine.a ../libbanshee/libcompat/libbansheecompat.a "
2866         BANSHEEINC="-I\$(srcdir)/../libbanshee/libcompat -I\$(srcdir)/../libbanshee -I\$(srcdir)/../libbanshee/points-to"
2867         ANDER="tree-alias-ander.o"
2868         AC_DEFINE(HAVE_BANSHEE, 1, [Define if BANSHEE is available])
2869 else
2870         BANSHEELIB=""
2871         BANSHEEINC=""
2872         ANDER=""
2873 fi
2874 AC_MSG_RESULT($with_libbanshee)
2875
2876 AC_SUBST(ANDER)
2877 AC_SUBST(BANSHEEINC)
2878 AC_SUBST(BANSHEELIB)
2879
2880 # --------------
2881 # Language hooks
2882 # --------------
2883
2884 # Make empty files to contain the specs and options for each language.
2885 # Then add #include lines to for a compiler that has specs and/or options.
2886
2887 lang_opt_files=
2888 lang_specs_files=
2889 lang_tree_files=
2890 for subdir in . $subdirs
2891 do
2892         if test -f $srcdir/$subdir/lang.opt; then
2893             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2894         fi
2895         if test -f $srcdir/$subdir/lang-specs.h; then
2896             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2897         fi
2898         if test -f $srcdir/$subdir/$subdir-tree.def; then
2899             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2900         fi
2901 done
2902
2903 # These (without "all_") are set in each config-lang.in.
2904 # `language' must be a single word so is spelled singularly.
2905 all_languages=
2906 all_boot_languages=
2907 all_compilers=
2908 all_stagestuff=
2909 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders libada-mk'
2910 # List of language makefile fragments.
2911 all_lang_makefrags=
2912 # List of language subdirectory makefiles.  Deprecated.
2913 all_lang_makefiles=
2914 # Files for gengtype
2915 all_gtfiles="$target_gtfiles"
2916 # Files for gengtype with language
2917 all_gtfiles_files_langs=
2918 all_gtfiles_files_files=
2919
2920 # Add the language fragments.
2921 # Languages are added via two mechanisms.  Some information must be
2922 # recorded in makefile variables, these are defined in config-lang.in.
2923 # We accumulate them and plug them into the main Makefile.
2924 # The other mechanism is a set of hooks for each of the main targets
2925 # like `clean', `install', etc.
2926
2927 language_hooks="Make-hooks"
2928
2929 for s in $subdirs
2930 do
2931                 language=
2932                 boot_language=
2933                 compilers=
2934                 stagestuff=
2935                 outputs=
2936                 gtfiles=
2937                 . ${srcdir}/$s/config-lang.in
2938                 if test "x$language" = x
2939                 then
2940                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2941                         exit 1
2942                 fi
2943                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2944                 if test -f ${srcdir}/$s/Makefile.in
2945                 then all_lang_makefiles="$s/Makefile"
2946                 fi
2947                 all_languages="$all_languages $language"
2948                 if test "x$boot_language" = xyes
2949                 then
2950                         all_boot_languages="$all_boot_languages $language"
2951                 fi
2952                 all_compilers="$all_compilers $compilers"
2953                 all_stagestuff="$all_stagestuff $stagestuff"
2954                 all_outputs="$all_outputs $outputs"
2955                 all_gtfiles="$all_gtfiles $gtfiles"
2956                 for f in $gtfiles
2957                 do
2958                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2959                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2960                 done
2961 done
2962
2963 # Pick up gtfiles for c
2964 gtfiles=
2965 s="c"
2966 . ${srcdir}/c-config-lang.in
2967 all_gtfiles="$all_gtfiles $gtfiles"
2968 for f in $gtfiles
2969 do
2970         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2971         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2972 done
2973
2974 check_languages=
2975 for language in $all_languages
2976 do
2977                 check_languages="$check_languages check-$language"
2978 done
2979
2980 # We link each language in with a set of hooks, reached indirectly via
2981 # lang.${target}.
2982
2983 rm -f Make-hooks
2984 touch Make-hooks
2985 target_list="all.build all.cross start.encap rest.encap tags \
2986         install-normal install-common install-man \
2987         uninstall info man srcextra srcman srcinfo \
2988         mostlyclean clean distclean maintainer-clean \
2989         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2990 for t in $target_list
2991 do
2992         x=
2993         for lang in $all_languages
2994         do
2995                         x="$x $lang.$t"
2996         done
2997         echo "lang.$t: $x" >> Make-hooks
2998 done
2999
3000 # --------
3001 # UNSORTED
3002 # --------
3003
3004 # Create .gdbinit.
3005
3006 echo "dir ." > .gdbinit
3007 echo "dir ${srcdir}" >> .gdbinit
3008 if test x$gdb_needs_out_file_path = xyes
3009 then
3010         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3011 fi
3012 if test "x$subdirs" != x; then
3013         for s in $subdirs
3014         do
3015                 echo "dir ${srcdir}/$s" >> .gdbinit
3016         done
3017 fi
3018 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3019
3020 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3021 # absolute path for gcc_tooldir based on inserting the number of up-directory
3022 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3023 # $(libsubdir)/@(unlibsubdir) based path.
3024 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3025 # make and thus we'd get different behavior depending on where we built the
3026 # sources.
3027 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3028     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3029 else
3030 changequote(<<, >>)dnl
3031 # An explanation of the sed strings:
3032 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3033 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3034 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3035 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3036 #
3037 # (*) Note this pattern overwrites the first character of the string
3038 # with a forward slash if one is not already present.  This is not a
3039 # problem because the exact names of the sub-directories concerned is
3040 # unimportant, just the number of them matters.
3041 #
3042 # The practical upshot of these patterns is like this:
3043 #
3044 #  prefix     exec_prefix        result
3045 #  ------     -----------        ------
3046 #   /foo        /foo/bar          ../
3047 #   /foo/       /foo/bar          ../
3048 #   /foo        /foo/bar/         ../
3049 #   /foo/       /foo/bar/         ../
3050 #   /foo        /foo/bar/ugg      ../../
3051 #
3052     dollar='$$'
3053     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3054 changequote([, ])dnl
3055 fi
3056 AC_SUBST(gcc_tooldir)
3057 AC_SUBST(dollar)
3058
3059 # Find a directory in which to install a shared libgcc.
3060
3061 AC_ARG_ENABLE(version-specific-runtime-libs,
3062 [  --enable-version-specific-runtime-libs
3063                           specify that runtime libraries should be
3064                           installed in a compiler-specific directory])
3065
3066 AC_ARG_WITH(slibdir,
3067 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3068 slibdir="$with_slibdir",
3069 if test "${enable_version_specific_runtime_libs+set}" = set; then
3070   slibdir='$(libsubdir)'
3071 elif test "$host" != "$target"; then
3072   slibdir='$(build_tooldir)/lib'
3073 else
3074   slibdir='$(libdir)'
3075 fi)
3076 AC_SUBST(slibdir)
3077
3078 objdir=`${PWDCMD-pwd}`
3079 AC_SUBST(objdir)
3080
3081 # Substitute configuration variables
3082 AC_SUBST(subdirs)
3083 AC_SUBST(srcdir)
3084 AC_SUBST(all_boot_languages)
3085 AC_SUBST(all_compilers)
3086 AC_SUBST(all_gtfiles)
3087 AC_SUBST(all_gtfiles_files_langs)
3088 AC_SUBST(all_gtfiles_files_files)
3089 AC_SUBST(all_lang_makefrags)
3090 AC_SUBST(all_lang_makefiles)
3091 AC_SUBST(all_languages)
3092 AC_SUBST(all_stagestuff)
3093 AC_SUBST(build_exeext)
3094 AC_SUBST(build_install_headers_dir)
3095 AC_SUBST(build_xm_file_list)
3096 AC_SUBST(build_xm_include_list)
3097 AC_SUBST(build_xm_defines)
3098 AC_SUBST(check_languages)
3099 AC_SUBST(cc_set_by_configure)
3100 AC_SUBST(quoted_cc_set_by_configure)
3101 AC_SUBST(cpp_install_dir)
3102 AC_SUBST(xmake_file)
3103 AC_SUBST(tmake_file)
3104 AC_SUBST(extra_gcc_objs)
3105 AC_SUBST(extra_headers_list)
3106 AC_SUBST(extra_objs)
3107 AC_SUBST(extra_parts)
3108 AC_SUBST(extra_passes)
3109 AC_SUBST(extra_programs)
3110 AC_SUBST(float_h_file)
3111 AC_SUBST(gcc_config_arguments)
3112 AC_SUBST(gcc_gxx_include_dir)
3113 AC_SUBST(libstdcxx_incdir)
3114 AC_SUBST(gcc_version)
3115 AC_SUBST(gcc_version_full)
3116 AC_SUBST(gcc_version_trigger)
3117 AC_SUBST(host_exeext)
3118 AC_SUBST(host_xm_file_list)
3119 AC_SUBST(host_xm_include_list)
3120 AC_SUBST(host_xm_defines)
3121 AC_SUBST(out_host_hook_obj)
3122 AC_SUBST(install)
3123 AC_SUBST(lang_opt_files)
3124 AC_SUBST(lang_specs_files)
3125 AC_SUBST(lang_tree_files)
3126 AC_SUBST(local_prefix)
3127 AC_SUBST(md_file)
3128 AC_SUBST(objc_boehm_gc)
3129 AC_SUBST(out_file)
3130 AC_SUBST(out_object_file)
3131 AC_SUBST(stage_prefix_set_by_configure)
3132 AC_SUBST(quoted_stage_prefix_set_by_configure)
3133 AC_SUBST(symbolic_link)
3134 AC_SUBST(thread_file)
3135 AC_SUBST(tm_file_list)
3136 AC_SUBST(tm_include_list)
3137 AC_SUBST(tm_defines)
3138 AC_SUBST(tm_p_file_list)
3139 AC_SUBST(tm_p_include_list)
3140 AC_SUBST(xm_file_list)
3141 AC_SUBST(xm_include_list)
3142 AC_SUBST(xm_defines)
3143 AC_SUBST(target_noncanonical)
3144 AC_SUBST(c_target_objs)
3145 AC_SUBST(cxx_target_objs)
3146 AC_SUBST(target_cpu_default)
3147
3148 AC_SUBST_FILE(language_hooks)
3149
3150 # If it doesn't already exist, create document directory
3151 echo "checking for the document directory." 1>&2
3152 if test -d doc ; then
3153   true
3154 else
3155   mkdir doc
3156 fi
3157
3158 # Echo link setup.
3159 if test x${build} = x${host} ; then
3160   if test x${host} = x${target} ; then
3161     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3162   else
3163     echo "Links are now set up to build a cross-compiler" 1>&2
3164     echo " from ${host} to ${target}." 1>&2
3165   fi
3166 else
3167   if test x${host} = x${target} ; then
3168     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3169     echo " for ${target}." 1>&2
3170   else
3171     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3172     echo " from ${host} to ${target}." 1>&2
3173   fi
3174 fi
3175
3176 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3177 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3178
3179 # Configure the subdirectories
3180 # AC_CONFIG_SUBDIRS($subdirs)
3181
3182 # Create the Makefile
3183 # and configure language subdirectories
3184 AC_CONFIG_FILES($all_outputs)
3185
3186 AC_CONFIG_COMMANDS([default],
3187 [
3188 case ${CONFIG_HEADERS} in
3189   *auto-host.h:config.in*)
3190   echo > cstamp-h ;;
3191 esac
3192 # Make sure all the subdirs exist.
3193 for d in $subdirs
3194 do
3195     test -d $d || mkdir $d
3196 done
3197 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3198 # bootstrapping and the installation procedure can still use
3199 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3200 # FLAGS_TO_PASS has been modified to solve the problem there.
3201 # This is virtually a duplicate of what happens in configure.lang; we do
3202 # an extra check to make sure this only happens if ln -s can be used.
3203 if test "$symbolic_link" = "ln -s"; then
3204  for d in ${subdirs} fixinc ; do
3205         STARTDIR=`${PWDCMD-pwd}`
3206         cd $d
3207         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3208         do
3209                 rm -f $t
3210                 $symbolic_link ../$t $t 2>/dev/null
3211         done
3212         cd $STARTDIR
3213  done
3214 else true ; fi
3215 ],
3216 [subdirs='$subdirs'
3217 symbolic_link='$symbolic_link'
3218 ])
3219 AC_OUTPUT