libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # (1) We use an abnormal CXX (without library references), so we
 146 # must cache it under a different name.
 147 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 148 # the non-multilib-adjusted value will be used in multilibs.
 149 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 150 # (4) As another side effect, automake doesn't automatically include them
 151 # in Makefile.in.
 152 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 153 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 154 # used in later tests.  This may not be necessary in libjava; I don't know.
 155 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 156 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 157 save_CXXFLAGS="$CXXFLAGS"
 158 CXXFLAGS="$CXXFLAGS -fno-builtin"
 159 AC_PROG_CC
 160 AC_PROG_CXX
 161 CXXFLAGS="$save_CXXFLAGS"
 162 m4_rename_force([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 163 AC_SUBST(CFLAGS)
 164 AC_SUBST(CXXFLAGS)
 165 AC_SUBST(LDFLAGS)
 166
 167 AM_INIT_AUTOMAKE([1.9.0])
 168
 169 AC_CHECK_TOOL(AS, as)
 170 AC_CHECK_TOOL(LD, ld)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_AWK
 174 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 175 AC_PATH_PROG([ZIP], [zip], no)
 176 AC_PATH_PROG([UNZIP], [unzip], unzip)
 177
 178 # We need a jar that supports -@.  This is a GNU extension.
 179 if test "$JAR" != no; then
 180    rm -f config-test.jar
 181    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 182    if test -f config-test.jar; then
 183      rm -f config-test.jar
 184    else
 185      JAR=no
 186    fi
 187 fi
 188
 189 # Prefer the jar we found, but fall back to our jar script.
 190 if test "$JAR" = no; then
 191   if test "$ZIP" = no; then
 192     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 193   else
 194     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 195     JAR=`pwd`/scripts/jar
 196   fi
 197 fi
 198
 199 AC_PROG_INSTALL
 200
 201 AM_MAINTAINER_MODE
 202
 203 AC_EXEEXT
 204
 205 # configure.host sets the following important variables
 206 #       libgcj_cflags    - host specific C compiler flags
 207 #       libgcj_cxxflags  - host specific C++ compiler flags
 208 #       libgcj_javaflags - host specific Java compiler flags
 209 # and a number of others; see the list at the start of the file.
 210
 211 libgcj_cflags=
 212 libgcj_cxxflags=
 213 libgcj_javaflags=
 214
 215 . ${srcdir}/configure.host
 216
 217 ACX_PROG_LD_GNU_SYMBOLIC
 218 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 219 if test -z "$libgcj_ld_symbolic"; then
 220   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 221 fi
 222
 223 LIBGCJ_CFLAGS="${libgcj_cflags}"
 224 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 225 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 226 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 227 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 228 AC_SUBST(LIBGCJ_CFLAGS)
 229 AC_SUBST(LIBGCJ_CXXFLAGS)
 230 AC_SUBST(LIBGCJ_JAVAFLAGS)
 231 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 232 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 233
 234 # Only use libltdl for non-newlib builds.
 235 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 236    AC_LTDL_SHLIBPATH
 237 fi
 238
 239 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 240
 241 # Possibly build libgcj as many sub-libraries.
 242 AC_ARG_ENABLE(libgcj-sublibs,
 243   AS_HELP_STRING([--enable-libgcj-sublibs],
 244                  [build libgcj as many sub-libraries]))
 245
 246 if test -z "$enable_libgcj_sublibs"; then
 247    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 248 fi
 249 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 250 if test "$enable_libgcj_sublibs" = yes ; then
 251   # In theory we could make do with only one override and simply
 252   # tag "_bc" onto the end of it when we use it to generate the
 253   # spec, but that's an ugly thing to do when there are multiple
 254   # words in the string and you're relying on the ordering to
 255   # append the correct one.
 256   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 257   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 258 fi
 259
 260
 261 # See if the user has requested runtime debugging.
 262 LIBGCJDEBUG="disable"
 263 AC_SUBST(LIBGCJDEBUG)
 264 AC_ARG_ENABLE(libgcj-debug,
 265   AS_HELP_STRING([--enable-libgcj-debug],
 266                  [enable runtime debugging code]),
 267   [if test "$enable_libgcj_debug" = yes; then
 268     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 269     LIBGCJDEBUG="enable"
 270   fi])
 271
 272 AC_ARG_WITH([escher],
 273          AS_HELP_STRING([--with-escher=ABS.PATH],
 274                         [specify path to escher dir or JAR for X peers]))
 275 case "$with_escher" in
 276 "")
 277         use_escher=false
 278         ;;
 279 "no")
 280         use_escher=false
 281         ;;
 282 "yes")
 283         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 284         ;;
 285 *)
 286         use_escher=true
 287         ;;
 288 esac
 289
 290 # Determine which AWT peer libraries to build
 291 AC_ARG_ENABLE(java-awt,
 292   AS_HELP_STRING([--enable-java-awt],
 293                  [list of AWT peer implementations to be built]))
 294
 295 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 296 use_xlib_awt=""
 297 use_gtk_awt=""
 298 use_qt_awt=""
 299 use_x_awt=""
 300 # The default toolkit to use is the first one specified.
 301 TOOLKIT=
 302 AC_SUBST(TOOLKIT)
 303
 304 for peer in $peerlibs ; do
 305   case $peer in
 306     xlib)
 307       if test "$no_x" = yes; then
 308         echo "*** xlib peers requested but no X library available" 1>&2
 309         exit 1
 310       else
 311         use_xlib_awt="yes"
 312         if test -z "$TOOLKIT"; then
 313            TOOLKIT=gnu.awt.xlib.XToolkit
 314         fi
 315       fi
 316       ;;
 317     gtk)
 318       if test "$no_x" = yes; then
 319          echo "*** gtk peers requested but no X library available" 1>&2
 320          exit 1
 321       else
 322          use_gtk_awt=yes
 323          if test -z "$TOOLKIT"; then
 324             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 325          fi
 326       fi
 327       ;;
 328     qt)
 329       if test "$no_x" = yes; then
 330          # Perhaps we should admit the possibility of embedded Qt.
 331          echo "*** Qt peers requested but no X library available" 1>&2
 332          exit 1
 333       else
 334          use_qt_awt=yes
 335          if test -z "$TOOLKIT"; then
 336             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 337          fi
 338       fi
 339       ;;
 340     x)
 341       use_x_awt=yes
 342       if test -z "$TOOLKIT"; then
 343          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 344       fi
 345       ;;
 346     no)
 347       use_xlib_awt=
 348       use_gtk_awt=
 349       use_qt_awt=
 350       use_x_awt=
 351       break
 352       ;;
 353     *)
 354       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 355       exit 1
 356   esac
 357 done
 358
 359 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 360 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 361
 362 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 363
 364 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 365
 366 # Create standard.omit based on decisions we just made.
 367 cp $srcdir/standard.omit.in standard.omit
 368 if test "$use_xlib_awt" != yes; then
 369    echo gnu/awt/xlib >> standard.omit
 370    echo gnu/gcj/xlib >> standard.omit
 371 fi
 372 if test "$use_x_awt" != yes; then
 373    echo gnu/java/awt/peer/x >> standard.omit
 374 fi
 375
 376 # Tools that need to be compiled against classpath's tools classes
 377 : > vm-tools-packages
 378 for package in gnu/gcj/tools/gc_analyze ; do
 379     echo $package >> standard.omit
 380     echo $package >> vm-tools-packages
 381 done
 382
 383 if test -z "${with_multisubdir}"; then
 384    builddotdot=.
 385 else
 386    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 387 fi
 388
 389 NATIVE=yes
 390
 391 # Which gcj and host gcj (for ecjx) do we use?
 392 which_gcj=default
 393 host_exeext=${ac_exeext}
 394 GCJ_FOR_ECJX=
 395 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 396 if test -n "${with_cross_host}"; then
 397   # We are being configured with a cross compiler. We can't
 398   # use ac_exeext, because that is for the target platform.
 399   NATIVE=no
 400   cross_host_exeext=
 401   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 402   case "${with_cross_host}" in
 403      *mingw* | *cygwin*)
 404          cross_host_exeext=.exe
 405      ;;
 406   esac
 407   host_exeext=${cross_host_exeext}
 408   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 409      if test x"$build_noncanonical" = x"$with_cross_host"; then
 410         # Ordinary cross (host!=target and host=build)
 411         which_gcj=built
 412      else
 413         # Canadian cross (host!=target and host!=build)
 414         which_gcj=cross
 415      fi
 416   else
 417      which_gcj=cross
 418   fi
 419 else
 420   # We are being configured with a native or crossed-native compiler
 421   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 422      if test x"$build" = x"$host"; then
 423         # True native build (host=target and host=build)
 424         which_gcj=built
 425      else
 426         # Crossed-native build (host=target and host!=build)
 427         which_gcj=cross
 428      fi
 429   else
 430      which_gcj=path
 431   fi
 432 fi
 433 libgcjdir=`${PWDCMD-pwd}`
 434 case $GCJ in
 435 *" -B"*)
 436   # Just in case there is a comma in the build dir, quote it for the
 437   # sed command below.
 438   case $libgcjdir in
 439   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 440   *) qlibgcjdir=$libgcjdir;;
 441   esac
 442   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 443   ;;
 444 *)
 445   GCJ=$GCJ" -B$libgcjdir/"
 446   ;;
 447 esac
 448 case "${which_gcj}" in
 449    built)
 450       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 451    ;;
 452    cross)
 453       if test "x${with_newlib}" = "xyes"; then
 454          # FIXME (comment): Why is this needed?
 455          GCC_UNWIND_INCLUDE=
 456       fi
 457       GCJH='$(target_noncanonical)-gcjh'
 458    ;;
 459    path)
 460       GCJH=gcjh
 461    ;;
 462 esac
 463 JAVAC="$GCJ -C"
 464 export JAVAC
 465
 466 AC_SUBST(GCJ_FOR_ECJX)
 467 AC_SUBST(GCJH)
 468 AC_SUBST(host_exeext)
 469
 470 # Create it, so that compile/link tests don't fail
 471 test -f libgcj.spec || touch libgcj.spec
 472
 473
 474
 475 # Set up to configure Classpath.
 476 # FIXME: no supported way to pass args in autoconf.
 477 # Disable tool wrappers to avoid ltdl.h configure check.
 478 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 479 ac_configure_args="$ac_configure_args --disable-load-library"
 480 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 481 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 482 dir1=`cd $srcdir && pwd`
 483 dir2=`pwd`
 484 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 485 ac_configure_args="$ac_configure_args --disable-core-jni"
 486 dnl FIXME?
 487 ac_configure_args="$ac_configure_args --disable-examples"
 488 ac_configure_args="$ac_configure_args --with-glibj=build"
 489 if test "$plugin_enabled" != yes; then
 490   ac_configure_args="$ac_configure_args --disable-plugin"
 491 fi
 492 if test "$gconf_enabled" != yes; then
 493   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 494   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 495 fi
 496 if test "$use_gtk_awt" != yes; then
 497   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 498 fi
 499 if test "$use_qt_awt" != yes; then
 500   ac_configure_args="$ac_configure_args --disable-qt-peer"
 501 else
 502   # We need this as qt is disabled by default in classpath.
 503   ac_configure_args="$ac_configure_args --enable-qt-peer"
 504 fi
 505 if test "$use_x_awt" != yes; then
 506   ac_configure_args="$ac_configure_args --without-escher"
 507 else
 508   # We need this as escher is disabled by default in classpath.
 509   if test "$use_escher" != true; then
 510     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 511   else
 512     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 513   fi
 514 fi
 515 if test "x$BUILD_GJDOC" = xno; then
 516   ac_configure_args="$ac_configure_args --disable-gjdoc"
 517 fi
 518 # -Werror causes unavoidable problems in code using alsa.
 519 ac_configure_args="$ac_configure_args --disable-regen-headers"
 520 ac_configure_args="$ac_configure_args --disable-Werror"
 521 dnl --with-gcj=$GCJ
 522 dnl --with-javah=$GCJH
 523 dnl gtk-cairo -- just export here...
 524 dnl --enable-regen-headers?
 525
 526 # Only use libltdl for non-newlib builds.
 527 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 528    AC_LIBLTDL_CONVENIENCE
 529    AC_LIBTOOL_DLOPEN
 530    DIRLTDL=libltdl
 531    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 532    # Sigh.  Libtool's macro doesn't do the right thing.
 533    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 534    # FIXME: this is a hack.
 535    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 536    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 537 fi
 538 AC_SUBST(INCLTDL)
 539 AC_SUBST(LIBLTDL)
 540 AC_SUBST(DIRLTDL)
 541 AC_PROG_LIBTOOL
 542 AM_PROG_GCJ
 543 AM_PROG_CC_C_O
 544
 545 AC_CONFIG_SUBDIRS(classpath libltdl)
 546
 547 # The -no-testsuite modules omit the test subdir.
 548 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 549
 550 # Should the runtime set system properties by examining the
 551 # environment variable GCJ_PROPERTIES?
 552 AC_ARG_ENABLE(getenv-properties,
 553   AS_HELP_STRING([--disable-getenv-properties],
 554                  [don't set system properties from GCJ_PROPERTIES]))
 555
 556 # Whether GCJ_PROPERTIES is used depends on the target.
 557 if test -z "$enable_getenv_properties"; then
 558    enable_getenv_properties=${enable_getenv_properties_default-yes}
 559 fi
 560 if test "$enable_getenv_properties" = no; then
 561    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 562      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 563 fi
 564
 565 # Whether we should use arguments to main()
 566 if test -z "$enable_main_args"; then
 567    enable_main_args=${enable_main_args_default-yes}
 568 fi
 569 if test "$enable_main_args" = no; then
 570    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 571 fi
 572
 573
 574 # Should we use hashtable-based synchronization?
 575 # Currently works only for Linux X86/ia64
 576 # Typically faster and more space-efficient
 577 AC_ARG_ENABLE(hash-synchronization,
 578   AS_HELP_STRING([--enable-hash-synchronization],
 579                  [use global hash table for monitor locks]))
 580
 581 if test -z "$enable_hash_synchronization"; then
 582    enable_hash_synchronization=$enable_hash_synchronization_default
 583 fi
 584
 585
 586 install_ecj_jar=no
 587 ECJ_BUILD_JAR=
 588 ECJ_JAR=
 589 AC_ARG_WITH(ecj-jar,
 590         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 591         [ECJ_JAR=$withval],
 592         [if test -f $multi_basedir/ecj.jar; then
 593            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 594            ECJ_JAR='$(jardir)/ecj.jar'
 595            install_ecj_jar=yes
 596          fi])
 597 AC_SUBST(ECJ_BUILD_JAR)
 598 AC_SUBST(ECJ_JAR)
 599 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 600 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 601
 602 AC_ARG_WITH(java-home,
 603   AS_HELP_STRING([--with-java-home=DIRECTORY],
 604                  [value of java.home system property]),
 605                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 606 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 607 AC_SUBST(JAVA_HOME)
 608
 609 suppress_libgcj_bc=no
 610 AC_ARG_ENABLE(libgcj-bc,
 611   AS_HELP_STRING([--enable-libgcj-bc],
 612                  [enable(default) or disable BC ABI for portions of libgcj]),
 613   [if test "$enable_libgcj_bc" = "no"; then
 614      suppress_libgcj_bc=yes
 615    fi])
 616 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 617
 618 build_libgcj_reduced_reflection=no
 619 AC_ARG_ENABLE(reduced-reflection,
 620   AS_HELP_STRING([--enable-reduced-reflection],
 621                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 622   [if test "$enable_reduced_reflection" = "yes"; then
 623      build_libgcj_reduced_reflection=yes
 624    fi])
 625 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 626
 627 # What is the native OS API for MinGW?
 628 AC_ARG_WITH(win32-nlsapi,
 629   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 630                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 631 [case "${withval}" in
 632   ansi) with_win32_nlsapi=ansi ;;
 633   unicows) with_win32_nlsapi=unicows ;;
 634   unicode) with_win32_nlsapi=unicode ;;
 635   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 636 esac],[with_win32_nlsapi=ansi])
 637
 638 case "${with_win32_nlsapi}" in
 639   unicows | unicode)
 640     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 641       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 642     ;;
 643 esac
 644
 645 # configure.host sets slow_pthread_self if the synchronization code should
 646 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 647 if test "${slow_pthread_self}" = "yes"; then
 648   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 649     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 650 fi
 651
 652 # Check for gc debugging.  This option is handled both here and in the GC.
 653 AC_ARG_ENABLE(gc-debug,
 654    AS_HELP_STRING([--enable-gc-debug],
 655                   [include full support for pointer backtracing etc.]),
 656 [ if test "$enable_gc_debug" = "yes"; then
 657     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 658               [Define if we want to use debug calls into the garbage collector.])
 659   fi])
 660
 661 # See if the user has the interpreter included.
 662 AC_ARG_ENABLE(interpreter,
 663   AS_HELP_STRING([--enable-interpreter],
 664                  [enable interpreter]),
 665   [if test "$enable_interpreter" = yes; then
 666     # This can also be set in configure.host.
 667     libgcj_interpreter=yes
 668   elif test "$enable_interpreter" = no; then
 669     libgcj_interpreter=no
 670   fi])
 671
 672 if test "$libgcj_interpreter" = yes; then
 673    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 674 fi
 675 INTERPRETER="$libgcj_interpreter"
 676 AC_SUBST(INTERPRETER)
 677 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 678
 679 AC_MSG_CHECKING([for exception model to use])
 680 AC_LANG_PUSH(C++)
 681 AC_ARG_ENABLE(sjlj-exceptions,
 682   AS_HELP_STRING([--enable-sjlj-exceptions],
 683                  [force use of builtin_setjmp for exceptions]),
 684 [:],
 685 [dnl Botheration.  Now we've got to detect the exception model.
 686 dnl Link tests against libgcc.a are problematic since -- at least
 687 dnl as of this writing -- we've not been given proper -L bits for
 688 dnl single-tree newlib and libgloss.
 689 dnl
 690 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 691 dnl conftest files before we got a change to grep them first.
 692 cat > conftest.$ac_ext << EOF
 693 [#]line __oline__ "configure"
 694 struct S { ~S(); };
 695 void bar();
 696 void foo()
 697 {
 698   S s;
 699   bar();
 700 }
 701 EOF
 702 old_CXXFLAGS="$CXXFLAGS"
 703 CXXFLAGS=-S
 704 if AC_TRY_EVAL(ac_compile); then
 705   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 706     enable_sjlj_exceptions=yes
 707   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 708     enable_sjlj_exceptions=no
 709   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 710     # ARM EH ABI.
 711     enable_sjlj_exceptions=no
 712   fi
 713 fi
 714 CXXFLAGS="$old_CXXFLAGS"
 715 rm -f conftest*])
 716 if test x$enable_sjlj_exceptions = xyes; then
 717   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 718         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 719   ac_exception_model_name=sjlj
 720 elif test x$enable_sjlj_exceptions = xno; then
 721   ac_exception_model_name="call frame"
 722 else
 723   AC_MSG_ERROR([unable to detect exception model])
 724 fi
 725 AC_LANG_POP(C++)
 726 AC_MSG_RESULT($ac_exception_model_name)
 727
 728 # If we are non using SJLJ exceptions, and this host does not have support
 729 # for unwinding from a signal handler, enable checked dereferences and divides.
 730 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 731   CHECKREFSPEC=-fcheck-references
 732   DIVIDESPEC=-fuse-divide-subroutine
 733   EXCEPTIONSPEC=
 734 fi
 735
 736 # See if the user wants to disable java.net.  This is the mildly
 737 # ugly way that we admit that target-side configuration sucks.
 738 AC_ARG_ENABLE(java-net,
 739   AS_HELP_STRING([--disable-java-net],
 740                  [disable java.net]))
 741
 742 # Whether java.net is built by default can depend on the target.
 743 if test -z "$enable_java_net"; then
 744    enable_java_net=${enable_java_net_default-yes}
 745 fi
 746 if test "$enable_java_net" = no; then
 747    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 748 fi
 749
 750 # See if the user wants to configure without libffi.  Some
 751 # architectures don't support it, and default values are set in
 752 # configure.host.
 753 AC_ARG_WITH(libffi,
 754   AS_HELP_STRING([--without-libffi],
 755                  [don't use libffi]),
 756   [:],
 757   [with_libffi=${with_libffi_default-yes}])
 758
 759 LIBFFI=
 760 LIBFFIINCS=
 761 if test "$with_libffi" != no; then
 762    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 763    LIBFFI=../libffi/libffi_convenience.la
 764    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 765 fi
 766 AC_SUBST(LIBFFI)
 767 AC_SUBST(LIBFFIINCS)
 768
 769 # See if the user wants to disable JVMPI support.
 770 AC_ARG_ENABLE(jvmpi,
 771   AS_HELP_STRING([--disable-jvmpi],
 772                  [disable JVMPI support]))
 773
 774 if test "$enable_jvmpi" != no; then
 775     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 776 fi
 777
 778 # If the target is an eCos system, use the appropriate eCos
 779 # I/O routines.
 780 # FIXME: this should not be a local option but a global target
 781 # system; at present there is no eCos target.
 782 TARGET_ECOS=${PROCESS-"no"}
 783 AC_ARG_WITH(ecos,
 784 [  --with-ecos             enable runtime eCos target support],
 785 TARGET_ECOS="$with_ecos"
 786 )
 787
 788 case "$TARGET_ECOS" in
 789    no) case "$host" in
 790       *mingw*)
 791             PLATFORM=Win32
 792             PLATFORMNET=Win32
 793             PLATFORMH=win32.h
 794         CHECK_FOR_BROKEN_MINGW_LD
 795       ;;
 796       *)
 797             PLATFORM=Posix
 798             PLATFORMNET=Posix
 799             PLATFORMH=posix.h
 800       ;;
 801       esac
 802       ;;
 803    *)
 804       PLATFORM=Ecos
 805       PLATFORMNET=NoNet
 806       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 807       PLATFORMH=posix.h
 808       ;;
 809 esac
 810 AC_SUBST(PLATFORM)
 811 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 812
 813 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 814                                       [Define if you have int32_t and uint32_t.]))
 815 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 816                                         [Define if you have int32_t and uint32_t.]))
 817 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 818                                           [Define if you have u_int32_t]))
 819 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 820                                            [Define if you have u_int32_t]))
 821
 822 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 823 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 824
 825 case "$host" in
 826   *-darwin*) DARWIN_CRT=true ;;
 827   *) DARWIN_CRT=false ;;
 828 esac
 829 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 830
 831 # This may not be defined in a non-ANS conformant embedded system.
 832 # FIXME: Should these case a runtime exception in that case?
 833 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 834                                   [Define is you have 'localtime' in <time.h>]))
 835
 836 # Create the subdirectory for natFile.cc, or the attempt
 837 # to create the link will fail.
 838 test -d java || mkdir java
 839 test -d java/io || mkdir java/io
 840 test -d gnu || mkdir gnu
 841 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 842
 843 # Likewise for natConcreteProcess.cc.
 844 test -d java/lang || mkdir java/lang
 845 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 846
 847 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 848 test -d java/net || mkdir java/net
 849 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 850 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 851
 852 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 853 test -d gnu/java || mkdir gnu/java
 854 test -d gnu/java/net || mkdir gnu/java/net
 855 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 856 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 857
 858 # Likewise for natVMPipe.cc and natVMSelector.cc.
 859 test -d gnu/java/nio || mkdir gnu/java/nio
 860 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 861 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 862
 863 # Likewise for natFileChannelImpl.cc
 864 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 865 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 866
 867 # Likewise for natVMSecureRandom.cc
 868 test -d gnu/java/security || mkdir gnu/java/security
 869 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 870 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 871 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 872
 873 case "${host}" in
 874     *mingw*)
 875       SYSTEMSPEC="-lgdi32 -lws2_32"
 876       if test "${with_win32_nlsapi}" = "unicows"; then
 877         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 878       fi
 879     ;;
 880     *)
 881       SYSTEMSPEC=
 882     ;;
 883 esac
 884 AC_SUBST(SYSTEMSPEC)
 885
 886 AC_ARG_WITH(system-zlib,
 887   AS_HELP_STRING([--with-system-zlib],
 888                  [use installed libz]))
 889 ZLIBSPEC=
 890 AC_SUBST(ZLIBSPEC)
 891 ZLIBTESTSPEC=
 892 AC_SUBST(ZLIBTESTSPEC)
 893
 894 AC_PATH_XTRA
 895
 896 # FIXME: this should be _libs on some hosts.
 897 libsubdir=.libs
 898
 899 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 900
 901 LIBSTDCXXSPEC=
 902 # extra LD Flags which are required for targets
 903 case "${host}" in
 904 *-*-darwin[[0-7]].*)
 905     # For now we have to disable it on darwin[8-9] because it slows down
 906     # the linking phase. A possible bug in ld?
 907     # on Darwin -single_module speeds up loading of the dynamic libraries.
 908     extra_ldflags_libjava=-Wl,-single_module
 909     ;;
 910 *-*-darwin[[912]]*)
 911     extra_gij_ldflags=-Wl,-allow_stack_execute
 912     ;;
 913 arm*linux*eabi)
 914     # Some of the ARM unwinder code is actually in libstdc++.  We
 915     # could in principle replicate it in libgcj, but it's better to
 916     # have a dependency on libstdc++.
 917     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 918     LIBSTDCXXSPEC=-lstdc++
 919     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 920     ;;
 921 *-*-cygwin)
 922     extra_ldflags_libjava=-liconv
 923     ;;
 924 esac
 925 AC_SUBST(extra_ldflags_libjava)
 926 AC_SUBST(extra_gij_ldflags)
 927 AC_SUBST(extra_ldflags)
 928 AC_SUBST(LIBSTDCXXSPEC)
 929
 930 AC_SUBST(LIBGCJTESTSPEC)
 931
 932 # Allow the GC to be disabled.  Can be useful when debugging.
 933 AC_MSG_CHECKING([for garbage collector to use])
 934 AC_ARG_ENABLE(java-gc,
 935   AS_HELP_STRING([--enable-java-gc=TYPE],
 936                  [choose garbage collector (default is boehm)]),
 937   [GC=$enableval],
 938   [GC=boehm])
 939 GCLIBS=
 940 GCINCS=
 941 GCDEPS=
 942 GCSPEC=
 943 JC1GCSPEC=
 944 GCTESTSPEC=
 945 case "$GC" in
 946  boehm)
 947     AC_MSG_RESULT(boehm)
 948     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 949     JC1GCSPEC='-fuse-boehm-gc'
 950     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 951     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 952     GCOBJS=boehm.lo
 953     GCHDR=boehm-gc.h
 954     # The POSIX thread support needs to know this.
 955     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 956     ;;
 957  no)
 958     AC_MSG_RESULT(none)
 959     GCHDR=no-gc.h
 960     ;;
 961  *)
 962     AC_MSG_ERROR([unrecognized collector "$GC"])
 963     ;;
 964 esac
 965 AC_SUBST(GCLIBS)
 966 AC_SUBST(GCINCS)
 967 AC_SUBST(GCDEPS)
 968 AC_SUBST(GCSPEC)
 969 AC_SUBST(JC1GCSPEC)
 970 AC_SUBST(GCTESTSPEC)
 971 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 972 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 973 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 974
 975
 976 AC_MSG_CHECKING([for thread model used by GCC])
 977 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 978 AC_MSG_RESULT([$THREADS])
 979
 980 case "$THREADS" in
 981  no | none | single)
 982     THREADS=none
 983     ;;
 984  aix | posix | posix95 | pthreads)
 985     THREADS=posix
 986     case "$host" in
 987      *-*-linux*)
 988         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 989         ;;
 990     esac
 991     ;;
 992  win32)
 993     ;;
 994  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 995     AC_MSG_ERROR(thread package $THREADS not yet supported)
 996     ;;
 997  *)
 998     AC_MSG_ERROR($THREADS is an unknown thread package)
 999     ;;
1000 esac
1001
1002 THREADCXXFLAGS=
1003 THREADLDFLAGS=
1004 THREADLIBS=
1005 THREADINCS=
1006 THREADDEPS=
1007 THREADH=
1008 THREADSPEC=
1009 THREADSTARTFILESPEC=
1010 case "$THREADS" in
1011  posix)
1012     case "$host" in
1013      *-*-cygwin*)
1014         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1015         ;;
1016      *-*-freebsd[[1234]]*)
1017         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1018         # merely adds pthread_* functions) but it does have a -pthread switch
1019         # which is required at link-time to select -lc_r *instead* of -lc.
1020         THREADLDFLAGS=-pthread
1021         # Don't set THREADSPEC here as might be expected since -pthread is
1022         # not processed when found within a spec file, it must come from
1023         # the command line.  For now, the user must provide the -pthread
1024         # switch to link code compiled with gcj.  In future, consider adding
1025         # support for weak references to pthread_* functions ala gthr.h API.
1026         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1027         ;;
1028      *-*-freebsd*)
1029         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1030         # systems which support threads and -lpthread.
1031         THREADLDFLAGS=-pthread
1032         THREADSPEC=-lpthread
1033         ;;
1034      alpha*-dec-osf* | hppa*-hp-hpux*)
1035         THREADCXXFLAGS=-pthread
1036         # boehm-gc needs some functions from librt, so link that too.
1037         THREADLIBS='-lpthread -lrt'
1038         THREADSPEC='-lpthread -lrt'
1039         ;;
1040      *)
1041         THREADLIBS=-lpthread
1042         THREADSPEC=-lpthread
1043         ;;
1044     esac
1045     THREADH=posix-threads.h
1046     # MIT pthreads doesn't seem to have the mutexattr functions.
1047     # But for now we don't check for it.  We just assume you aren't
1048     # using MIT pthreads.
1049     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1050
1051     # If we're using the Boehm GC, then we happen to know that it
1052     # defines _REENTRANT, so we don't bother.  Eww.
1053     if test "$GC" != boehm; then
1054        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1055     fi
1056     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1057     ;;
1058
1059  win32)
1060     THREADH=win32-threads.h
1061     THREADCXXFLAGS=-mthreads
1062     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1063     # But we do not want the executables created to be dependent on
1064     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1065     # exception handling contexts.  The following kludge achieves this effect
1066     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1067     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1068     # A workaround is to explicitly use -mthreads while linking Java programs.
1069     # See PR libgcj/28263.
1070     #
1071     # FIXME: In Java we are able to detect thread death at the end of
1072     # Thread.run() so we should be able to clean up the exception handling
1073     # contexts ourselves.
1074     THREADSTARTFILESPEC='crtmt%O%s'
1075     ;;
1076
1077  none)
1078     THREADH=no-threads.h
1079     ;;
1080 esac
1081 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1082 AC_SUBST(THREADLIBS)
1083 AC_SUBST(THREADINCS)
1084 AC_SUBST(THREADDEPS)
1085 AC_SUBST(THREADSPEC)
1086 AC_SUBST(THREADSTARTFILESPEC)
1087 AC_SUBST(THREADLDFLAGS)
1088 AC_SUBST(THREADCXXFLAGS)
1089 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1090 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1091 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1092 if test "$enable_shared" != yes; then
1093   use_libgcj_bc=no
1094 fi
1095 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1096
1097 if test -d sysdep; then true; else mkdir sysdep; fi
1098 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1099 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1100 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1101
1102 LIBGCJ_SPEC_LGCJ=-lgcj
1103 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1104 if test x"$libgcj_spec_lgcj_override" != x ; then
1105   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1106 fi
1107 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1108   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1109 fi
1110 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1111 if test "$use_libgcj_bc" = yes; then
1112   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1113   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1114 fi
1115 AC_SUBST(LIBGCJ_SPEC)
1116 AC_SUBST(LIBGCJ_BC_SPEC)
1117
1118 HASH_SYNC_SPEC=
1119 # Hash synchronization is only useful with posix threads right now.
1120 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1121    HASH_SYNC_SPEC=-fhash-synchronization
1122    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1123 fi
1124 AC_SUBST(HASH_SYNC_SPEC)
1125
1126 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1127
1128 # We're in the tree with gcc, and need to include some of its headers.
1129 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1130
1131 if test "x${with_newlib}" = "xyes"; then
1132    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1133    # may not work correctly, because the compiler may not be able to
1134    # link executables.
1135
1136    # We assume newlib.  This lets us hard-code the functions we know
1137    # we'll have.
1138    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1139    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1140    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1141    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1142    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1143    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1144    # This is only for POSIX threads.
1145    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1146
1147    # Assume we do not have getuid and friends.
1148    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1149    PLATFORMNET=NoNet
1150 else
1151    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1152                    localtime_r getpwuid_r getcwd \
1153                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1154                    nl_langinfo setlocale \
1155                    inet_pton uname inet_ntoa \
1156                    getrlimit sigaction ftruncate mmap \
1157                    getifaddrs])
1158    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1159    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1160    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1161    AC_CHECK_LIB(dl, dladdr, [
1162        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1163        AC_CHECK_LIB(dld, dladdr, [
1164        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1165
1166    if test x"$cross_compiling" = x"no"; then
1167      AC_CHECK_FILES(/proc/self/exe, [
1168        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1169      AC_CHECK_FILES(/proc/self/maps, [
1170        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1171          [Define if you have /proc/self/maps])])
1172    else
1173      case $host in
1174      *-linux*)
1175        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1176        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1177        ;;
1178      esac
1179    fi
1180
1181    AM_ICONV
1182    AM_LC_MESSAGES
1183    AC_STRUCT_TIMEZONE
1184
1185    AC_CHECK_FUNCS(gethostbyname_r, [
1186      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1187        [Define if you have the 'gethostbyname_r' function.])
1188      # There are two different kinds of gethostbyname_r.
1189      # We look for the one that returns `int'.
1190      # Hopefully this check is robust enough.
1191      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1192        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1193
1194      case " $GCINCS " in
1195      *" -D_REENTRANT "*) ;;
1196      *)
1197         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1198         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1199         [libjava_cv_gethostbyname_r_needs_reentrant],
1200         [ AC_LANG_PUSH(C++)
1201           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1202             [[gethostbyname_r("", 0, 0);]])],
1203             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1204                 CPPFLAGS_SAVE="$CPPFLAGS"
1205                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1206                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1207                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1208                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1209                 CPPFLAGS="$CPPFLAGS_SAVE"
1210           ])
1211           AC_LANG_POP(C++)
1212         ])
1213         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1214           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1215         fi
1216      ;;
1217      esac
1218
1219      AC_CACHE_CHECK([for struct hostent_data],
1220         [libjava_cv_struct_hostent_data], [dnl
1221         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1222 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1223 # define _REENTRANT 1
1224 #endif
1225 #include <netdb.h>]], [[struct hostent_data data;]])],
1226           [libjava_cv_struct_hostent_data=yes],
1227           [libjava_cv_struct_hostent_data=no])])
1228      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1229        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1230          [Define if struct hostent_data is defined in netdb.h])
1231      fi
1232    ])
1233
1234    # FIXME: libjava source code expects to find a prototype for
1235    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1236    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1237    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1238    # linkage check is enough, yet C++ code requires proper prototypes.)
1239    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1240    AC_CHECK_FUNCS(gethostbyaddr_r, [
1241      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1242        [Define if you have the 'gethostbyaddr_r' function.])
1243      # There are two different kinds of gethostbyaddr_r.
1244      # We look for the one that returns `int'.
1245      # Hopefully this check is robust enough.
1246      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1247        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1248          [Define if gethostbyaddr_r returns 'int'.])])])])
1249
1250    AC_CHECK_FUNCS(gethostname, [
1251      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1252        [Define if you have the 'gethostname' function.])
1253      AC_EGREP_HEADER(gethostname, unistd.h, [
1254        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1255          [Define if gethostname is declared in <unistd.h>.])])])
1256
1257    AC_CHECK_FUNCS(usleep, [
1258      AC_EGREP_HEADER(usleep, unistd.h, [
1259        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1260           [Define if usleep is declared in <unistd.h>.])])])
1261
1262    # Look for these functions in the thread library, but only bother
1263    # if using POSIX threads.
1264    if test "$THREADS" = posix; then
1265       save_LIBS="$LIBS"
1266       LIBS="$LIBS $THREADLIBS"
1267
1268       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1269       # Solaris 7 the name librt is preferred.
1270       AC_CHECK_FUNCS(sched_yield, , [
1271         AC_CHECK_LIB(rt, sched_yield, [
1272           AC_DEFINE(HAVE_SCHED_YIELD)
1273           THREADLIBS="$THREADLIBS -lrt"
1274           THREADSPEC="$THREADSPEC -lrt"], [
1275           AC_CHECK_LIB(posix4, sched_yield, [
1276             AC_DEFINE(HAVE_SCHED_YIELD)
1277             THREADLIBS="$THREADLIBS -lposix4"
1278             THREADSPEC="$THREADSPEC -lposix4"])])])
1279
1280       AC_CHECK_LIB(rt, clock_gettime, [
1281          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1282          case "$THREADSPEC" in
1283            *-lrt*) ;;
1284            *)
1285              THREADSPEC="$THREADSPEC -lrt"
1286              THREADLIBS="$THREADLIBS -lrt"
1287              ;;
1288          esac])
1289
1290       LIBS="$save_LIBS"
1291
1292       # We can save a little space at runtime if the mutex has m_count
1293       # or __m_count.  This is a nice hack for Linux.
1294       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1295           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1296         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1297              [Define if pthread_mutex_t has m_count member.]), [
1298         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1299             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1300           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1301             [Define if pthread_mutex_t has __m_count member.]))])
1302    fi
1303
1304    # We require a way to get the time.
1305    time_found=no
1306    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1307    if test "$time_found" = no; then
1308       AC_MSG_ERROR([no function found to get the time])
1309    fi
1310
1311    AC_CHECK_FUNCS(memmove)
1312
1313    # We require memcpy.
1314    memcpy_found=no
1315    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1316    if test "$memcpy_found" = no; then
1317       AC_MSG_ERROR([memcpy is required])
1318    fi
1319    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1320    AC_CHECK_LIB(dl, dlopen, [
1321        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1322        AC_CHECK_LIB(dld, dlopen, [
1323        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1324
1325    # Some library-finding code we stole from Tcl.
1326    #--------------------------------------------------------------------
1327    #    Check for the existence of the -lsocket and -lnsl libraries.
1328    #    The order here is important, so that they end up in the right
1329    #    order in the command line generated by make.  Here are some
1330    #    special considerations:
1331    #    1. Use "connect" and "accept" to check for -lsocket, and
1332    #       "gethostbyname" to check for -lnsl.
1333    #    2. Use each function name only once:  can't redo a check because
1334    #       autoconf caches the results of the last check and won't redo it.
1335    #    3. Use -lnsl and -lsocket only if they supply procedures that
1336    #       aren't already present in the normal libraries.  This is because
1337    #       IRIX 5.2 has libraries, but they aren't needed and they're
1338    #       bogus:  they goof up name resolution if used.
1339    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1340    #       To get around this problem, check for both libraries together
1341    #       if -lsocket doesn't work by itself.
1342    #--------------------------------------------------------------------
1343
1344    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1345     [gcj_cv_lib_sockets=
1346      gcj_checkBoth=0
1347      unset ac_cv_func_connect
1348      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1349      if test "$gcj_checkSocket" = 1; then
1350          unset ac_cv_func_connect
1351          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1352                       gcj_checkBoth=1)
1353      fi
1354      if test "$gcj_checkBoth" = 1; then
1355          gcj_oldLibs=$LIBS
1356          LIBS="$LIBS -lsocket -lnsl"
1357          unset ac_cv_func_accept
1358          AC_CHECK_FUNC(accept,
1359                        [gcj_checkNsl=0
1360                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1361          unset ac_cv_func_accept
1362          LIBS=$gcj_oldLibs
1363      fi
1364      unset ac_cv_func_gethostbyname
1365      gcj_oldLibs=$LIBS
1366      LIBS="$LIBS $gcj_cv_lib_sockets"
1367      AC_CHECK_FUNC(gethostbyname, ,
1368                    [AC_CHECK_LIB(nsl, main,
1369                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1370      unset ac_cv_func_gethostbyname
1371      LIBS=$gcj_oldLIBS
1372    ])
1373    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1374
1375    if test "$with_system_zlib" = yes; then
1376       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1377    fi
1378
1379    # Test for Gtk stuff, if asked for.
1380    if test "$use_gtk_awt" = yes; then
1381       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1382       AC_SUBST(GTK_CFLAGS)
1383       AC_SUBST(GTK_LIBS)
1384
1385       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1386       AC_SUBST(GLIB_CFLAGS)
1387       AC_SUBST(GLIB_LIBS)
1388
1389       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1390       AC_SUBST(LIBART_CFLAGS)
1391       AC_SUBST(LIBART_LIBS)
1392
1393       # We require the XTest Extension to support java.awt.Robot.
1394       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1395                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1396                    [${X_LIBS}])
1397    fi
1398
1399    # On Solaris, and maybe other architectures, the Boehm collector
1400    # requires -ldl.
1401    if test "$GC" = boehm; then
1402       case "${host}" in
1403           mips-sgi-irix6*)
1404             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1405             # libgcj.spec is used, so override here
1406             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1407           ;;
1408           *)
1409             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1410           ;;
1411       esac
1412    fi
1413 fi
1414
1415 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1416 case $build in
1417     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1418     *)         CLASSPATH_SEPARATOR=':' ;;
1419 esac
1420 AC_SUBST(CLASSPATH_SEPARATOR)
1421
1422 # We must search the source tree for java.lang, since we still don't
1423 # have libgcj.jar nor java/lang/*.class
1424 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1425 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1426
1427 # Since some classes depend on this one, we need its source available
1428 # before we can do any GCJ compilation test :-(
1429 if test ! -f gnu/classpath/Configuration.java; then
1430   test -d gnu || mkdir gnu
1431   test -d gnu/classpath || mkdir gnu/classpath
1432   # Note that it is not crucial that all the values here be correct.
1433   sed -e "s,@prefix@,$prefix," \
1434       -e "s,@VERSION@,$VERSION," \
1435       -e "s,@LIBDEBUG@,false," \
1436       -e "s,@INIT_LOAD_LIBRARY@,false," \
1437       -e "s,@@,$LIBGCJDEBUG," \
1438       -e "s,@default_toolkit@,$TOOLKIT," \
1439       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1440       -e "s,@GTK_CAIRO_ENABLED@,false," \
1441       -e "s,@ECJ_JAR@,," \
1442       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1443         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1444         > gnu/classpath/Configuration.java
1445   # We do not want to redirect the output of the grep below to /dev/null,
1446   # but we add /dev/null to the input list so that grep will print the
1447   # filename of Configuration.java in case it finds any matches.
1448   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1449     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1450   fi
1451 fi
1452
1453 LT_AC_PROG_GCJ
1454
1455 # Now remove it.
1456 rm -f gnu/classpath/Configuration.java
1457
1458 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1459
1460 AC_CHECK_SIZEOF(void *)
1461
1462 AC_C_BIGENDIAN
1463
1464 ZLIBS=
1465 SYS_ZLIBS=
1466 ZINCS=
1467
1468 if test -z "$ZLIBSPEC"; then
1469    # Use zlib from the GCC tree.
1470    ZINCS='-I$(top_srcdir)/../zlib'
1471    ZLIBS=../zlib/libzgcj_convenience.la
1472 else
1473    # System's zlib.
1474    SYS_ZLIBS="$ZLIBSPEC"
1475 fi
1476 AC_SUBST(ZLIBS)
1477 AC_SUBST(SYS_ZLIBS)
1478 AC_SUBST(ZINCS)
1479 AC_SUBST(DIVIDESPEC)
1480 AC_SUBST(CHECKREFSPEC)
1481 AC_SUBST(EXCEPTIONSPEC)
1482 AC_SUBST(BACKTRACESPEC)
1483 AC_SUBST(IEEESPEC)
1484 AC_SUBST(ATOMICSPEC)
1485
1486 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1487 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1488 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1489 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1490 AC_SUBST(GCC_UNWIND_INCLUDE)
1491
1492 # Process the option "--enable-version-specific-runtime-libs"
1493 # Calculate toolexeclibdir
1494 case ${version_specific_libs} in
1495   yes)
1496     # Need the gcc compiler version to know where to install libraries
1497     # and header files if --enable-version-specific-runtime-libs option
1498     # is selected.
1499     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1500     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1501     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1502     toolexeclibdir=$toolexecmainlibdir
1503     ;;
1504   no)
1505     if test -n "$with_cross_host" &&
1506        test x"$with_cross_host" != x"no"; then
1507       # Install a library built with a cross compiler in tooldir, not libdir.
1508       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1509       toolexecmainlibdir='$(toolexecdir)/lib'
1510     else
1511       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1512       toolexecmainlibdir='$(libdir)'
1513     fi
1514     multi_os_directory=`$CC -print-multi-os-directory`
1515     case $multi_os_directory in
1516       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1517       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1518     esac
1519     ;;
1520 esac
1521 AC_SUBST(toolexecdir)
1522 AC_SUBST(toolexecmainlibdir)
1523 AC_SUBST(toolexeclibdir)
1524
1525 # Determine gcj and libgcj version number.
1526 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1527 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1528 GCJVERSION=$gcjversion
1529 AC_SUBST(GCJVERSION)
1530 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1531
1532 # Determine where the standard .db file and GNU Classpath JNI
1533 # libraries are found.
1534 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1535 multi_os_directory=`$CC -print-multi-os-directory`
1536 case $multi_os_directory in
1537   .)
1538    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1539    ;;
1540   *)
1541    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1542    ;;
1543 esac
1544 AC_SUBST(dbexecdir)
1545 AC_SUBST(gcjsubdir)
1546
1547 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1548 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1549
1550 TL_AC_GXX_INCLUDE_DIR
1551
1552 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1553 # On that system, sys/ioctl.h will not include sys/filio.h unless
1554 # BSD_COMP is defined; just including sys/filio.h is simpler.
1555 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1556 # for now.  If you change this, you also must update natFile.cc.
1557 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1558                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1559                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1560                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1561                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1562 AC_CHECK_HEADERS(inttypes.h, [
1563     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1564     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1565 ])
1566
1567 AC_CHECK_TYPE([ssize_t], [int])
1568 AC_CHECK_TYPE([magic_t], [
1569     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1570 #ifdef HAVE_MAGIC_H
1571 #include <magic.h>
1572 #endif])
1573
1574 AC_MSG_CHECKING([for in_addr_t])
1575 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1576 #if STDC_HEADERS
1577 #include <stdlib.h>
1578 #include <stddef.h>
1579 #endif
1580 #if HAVE_NETINET_IN_H
1581 #include <netinet/in.h>
1582 #endif]], [[in_addr_t foo;]])],
1583   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1584      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1585    AC_MSG_RESULT(yes)],
1586   [AC_MSG_RESULT(no)])
1587
1588 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1589 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1590   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1591      [Define if struct ip_mreq is defined in netinet/in.h.])
1592    AC_MSG_RESULT(yes)],
1593   [AC_MSG_RESULT(no)])
1594
1595 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1596 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1597   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1598      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1599    AC_MSG_RESULT(yes)],
1600   [AC_MSG_RESULT(no)])
1601
1602 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1603 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1604   [AC_DEFINE(HAVE_INET6, 1,
1605      [Define if inet6 structures are defined in netinet/in.h.])
1606    AC_MSG_RESULT(yes)],
1607   [AC_MSG_RESULT(no)])
1608
1609 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1610 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1611 #include <sys/types.h>
1612 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1613   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1614    AC_MSG_RESULT(yes)],
1615   [AC_MSG_RESULT(no)])
1616
1617 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1618 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1619   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1620    AC_MSG_RESULT(yes)],
1621   [AC_MSG_RESULT(no)
1622    AC_MSG_CHECKING([for global timezone variable])
1623    dnl FIXME: we don't want a link check here because that won't work
1624    dnl when cross-compiling.  So instead we make an assumption that
1625    dnl the header file will mention timezone if it exists.
1626    dnl Don't find the win32 function timezone
1627    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1628      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1629       AC_MSG_RESULT(yes)],
1630      [AC_MSG_RESULT(no)
1631        AC_MSG_CHECKING([for global _timezone variable])
1632        dnl FIXME: As above, don't want link check
1633        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1634          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1635             [Define if your platform has the global _timezone variable.])
1636           AC_MSG_RESULT(yes)],
1637           [AC_MSG_RESULT(no)])])])
1638
1639 AC_CHECK_PROGS(PERL, perl, false)
1640
1641 SYSDEP_SOURCES=
1642 SIGNAL_HANDLER_AUX=
1643
1644 case "${host}" in
1645  i?86-*-linux*)
1646     SIGNAL_HANDLER=include/i386-signal.h
1647     ;;
1648  sparc*-sun-solaris*)
1649     SIGNAL_HANDLER=include/sparc-signal.h
1650     ;;
1651 # ia64-*)
1652 #    SYSDEP_SOURCES=sysdep/ia64.c
1653 #    test -d sysdep || mkdir sysdep
1654 #    ;;
1655  hppa*-*-linux*)
1656     SIGNAL_HANDLER=include/pa-signal.h
1657     ;;
1658  hppa*-hp-hpux*)
1659     SIGNAL_HANDLER=include/hppa-signal.h
1660     ;;
1661  ia64-*-linux*)
1662     SIGNAL_HANDLER=include/dwarf2-signal.h
1663     ;;
1664  powerpc*-*-linux*)
1665     SIGNAL_HANDLER=include/powerpc-signal.h
1666     ;;
1667  alpha*-*-linux*)
1668     SIGNAL_HANDLER=include/dwarf2-signal.h
1669     ;;
1670  s390*-*-linux*)
1671     SIGNAL_HANDLER=include/s390-signal.h
1672     ;;
1673  x86_64*-*-linux*)
1674     SIGNAL_HANDLER=include/x86_64-signal.h
1675     SIGNAL_HANDLER_AUX=include/i386-signal.h
1676     ;;
1677  sparc*-*-linux*)
1678     SIGNAL_HANDLER=include/dwarf2-signal.h
1679     ;;
1680  sh*-*-linux*)
1681     SIGNAL_HANDLER=include/sh-signal.h
1682     ;;
1683  *mingw*)
1684     SIGNAL_HANDLER=include/win32-signal.h
1685     ;;
1686  mips*-*-linux*)
1687     SIGNAL_HANDLER=include/mips-signal.h
1688     ;;
1689  m68*-*-linux*)
1690     SIGNAL_HANDLER=include/dwarf2-signal.h
1691     ;;
1692  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1693     SIGNAL_HANDLER=include/darwin-signal.h
1694     ;;
1695  powerpc*-*-aix*)
1696     SIGNAL_HANDLER=include/aix-signal.h
1697     ;;
1698  *)
1699     SIGNAL_HANDLER=include/default-signal.h
1700     ;;
1701 esac
1702
1703 # If we're using sjlj exceptions, forget what we just learned.
1704 if test "$enable_sjlj_exceptions" = yes; then
1705    SIGNAL_HANDLER=include/default-signal.h
1706    SIGNAL_HANDLER_AUX=
1707 fi
1708
1709 AC_SUBST(SYSDEP_SOURCES)
1710
1711 if test -z "$SIGNAL_HANDLER_AUX"; then
1712   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1713 fi
1714
1715 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1716                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1717
1718 if test "${multilib}" = "yes"; then
1719   multilib_arg="--enable-multilib"
1720 else
1721   multilib_arg=
1722 fi
1723
1724 # See if we support thread-local storage.
1725 GCC_CHECK_TLS
1726
1727 # For _Unwind_GetIPInfo.
1728 GCC_CHECK_UNWIND_GETIPINFO
1729
1730 # See if linker supports anonymous version scripts.
1731 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1732   [libjava_cv_anon_version_script],
1733   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1734    libjava_cv_anon_version_script=no
1735    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1736    echo '{ global: globalsymb*; local: *; };' > conftest.map
1737    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1738                [libjava_cv_anon_version_script=yes], [])
1739    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1740   ])
1741 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1742
1743 # Check if linker supports static linking on a per library basis
1744 LD_START_STATIC_SPEC=
1745 LD_FINISH_STATIC_SPEC=
1746 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1747   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1748     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1749     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1750   fi
1751 fi
1752 AC_SUBST(LD_START_STATIC_SPEC)
1753 AC_SUBST(LD_FINISH_STATIC_SPEC)
1754
1755 here=`${PWDCMD-pwd}`
1756 AC_SUBST(here)
1757
1758 # We get this from the environment.
1759 AC_SUBST(GCJFLAGS)
1760
1761 AC_ARG_WITH([python-dir],
1762             AS_HELP_STRING([--with-python-dir],
1763                            [the location to install Python modules. This path should NOT include the prefix.]),
1764             [with_python_dir=$withval], [with_python_dir=""])
1765
1766 if test "x${with_python_dir}" = "x"
1767 then
1768   # Needed for installing Python modules during make install.
1769   python_mod_dir="\${prefix}/share/python"
1770   # Needed for substituting into aot-compile*
1771   python_mod_dir_expanded="${prefix}/share/python"
1772 else
1773   python_mod_dir="\${prefix}${with_python_dir}"
1774   python_mod_dir_expanded="${prefix}${with_python_dir}"
1775 fi
1776 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1777 AC_SUBST(python_mod_dir)
1778 AC_SUBST(python_mod_dir_expanded)
1779
1780 # needed for aot-compile-rpm
1781 MAKE=`which make`
1782 AC_SUBST(MAKE)
1783
1784 AC_ARG_ENABLE([aot-compile-rpm],
1785   [AS_HELP_STRING([--enable-aot-compile-rpm],
1786                  [enable installation of aot-compile-rpm [default=no]])],
1787   [case "${enableval}" in
1788     yes) AOT_RPM_ENABLED=yes ;;
1789     no)  AOT_RPM_ENABLED=no ;;
1790     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1791   esac],
1792   [AOT_RPM_ENABLED=no]
1793 )
1794 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1795
1796 AC_ARG_ENABLE([java-home],
1797   [AS_HELP_STRING([--enable-java-home],
1798                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1799   [case "${enableval}" in
1800     yes) JAVA_HOME_ENABLED=yes ;;
1801     no)  JAVA_HOME_ENABLED=no ;;
1802     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1803   esac],
1804   [JAVA_HOME_ENABLED=no]
1805 )
1806 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1807
1808 # Only do these checks if java-home above is enabled.
1809 if test "x${JAVA_HOME_ENABLED}" = xyes
1810 then
1811
1812   AC_ARG_WITH([gcc-suffix],
1813               AS_HELP_STRING([--with-gcc-suffix],
1814                              [the GCC tool suffix (defaults to empty string)]),
1815               [gcc_suffix=$withval], [gcc_suffix=""])
1816   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1817   AC_SUBST(gcc_suffix)
1818
1819   AC_ARG_WITH([arch-directory],
1820               AS_HELP_STRING([--with-arch-directory],
1821                              [the arch directory under jre/lib (defaults to auto-detect)]),
1822               [host_cpu=$withval], [host_cpu=""])
1823
1824   AC_ARG_WITH([os-directory],
1825               AS_HELP_STRING([--with-os-directory],
1826                              [the os directory under include (defaults to auto-detect)]),
1827               [host_os=$withval], [host_os=""])
1828
1829   AC_ARG_WITH([origin-name],
1830               AS_HELP_STRING([--with-origin-name],
1831                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1832               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1833   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1834
1835   AC_ARG_WITH([arch-suffix],
1836               AS_HELP_STRING([--with-arch-suffix],
1837                              [the arch directory suffix (default is the empty string]),
1838               [arch_suffix=$withval], [arch_suffix=""])
1839   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1840
1841   AC_ARG_WITH([jvm-root-dir],
1842               AS_HELP_STRING([--with-jvm-root-dir],
1843                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1844               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1845   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1846
1847   AC_ARG_WITH([jvm-jar-dir],
1848               AS_HELP_STRING([--with-jvm-jar-dir],
1849                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1850               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1851   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1852
1853   JAVA_VERSION=1.5.0
1854   BUILD_VERSION=0
1855   AC_SUBST(JAVA_VERSION)
1856   AC_SUBST(BUILD_VERSION)
1857   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1858
1859   jre_dir=jre
1860   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1861   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1862
1863   JVM_ROOT_DIR=${jvm_root_dir}
1864   AC_SUBST(JVM_ROOT_DIR)
1865   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1866
1867   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1868   AC_SUBST(JVM_JAR_ROOT_DIR)
1869   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1870
1871   JVM_JAR_DIR=${jvm_jar_dir}
1872   AC_SUBST(JVM_JAR_DIR)
1873   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1874
1875   JRE_DIR=${jre_dir}
1876   AC_SUBST(JRE_DIR)
1877
1878   JRE_LNK=${jre_lnk}
1879   AC_SUBST(JRE_LNK)
1880
1881   SDK_LNK=${sdk_lnk}
1882   AC_SUBST(SDK_LNK)
1883
1884   SDK_BIN_DIR=${jvm_root_dir}/bin
1885   AC_SUBST(SDK_BIN_DIR)
1886   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1887
1888   SDK_LIB_DIR=${jvm_root_dir}/lib
1889   AC_SUBST(SDK_LIB_DIR)
1890   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1891
1892   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1893   AC_SUBST(SDK_INCLUDE_DIR)
1894   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1895
1896   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1897   AC_SUBST(JRE_BIN_DIR)
1898   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1899
1900   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1901   AC_SUBST(JRE_LIB_DIR)
1902   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1903
1904   # Find gcj prefix using gcj found in PATH.
1905   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1906
1907   # Where do the gcj binaries live?
1908   # For jhbuild based builds, they all live in a sibling of bin called
1909   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1910   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1911   AC_SUBST(GCJ_BIN_DIR)
1912   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1913
1914   AC_MSG_RESULT(host is ${host})
1915   if test "x${host_cpu}" = "x"
1916   then
1917     case ${host} in
1918       *-mingw* | *-cygwin*)
1919         host_cpu=x86;;
1920       i486-* | i586-* | i686-*)
1921         host_cpu=i386;;
1922       x86_64-*)
1923         host_cpu=amd64;;
1924       *)
1925         host_cpu=${host_cpu};;
1926     esac
1927   fi
1928   AC_MSG_RESULT(arch directory: ${host_cpu})
1929   CPU=${host_cpu}
1930   AC_SUBST(CPU)
1931
1932   if test "x${host_os}" = "x"
1933   then
1934     case ${host} in
1935       *-mingw* | *-cygwin*)
1936         host_os=win32;;
1937       *-linux*)
1938         host_os=linux;;
1939       *)
1940         host_os=${host_os};;
1941     esac
1942   fi
1943   echo os directory: ${host_os}
1944   OS=${host_os}
1945   AC_SUBST(OS)
1946
1947   # make an expanded $libdir, for substituting into
1948   # scripts (and other non-Makefile things).
1949   LIBDIR=$libdir
1950   if test "x${exec_prefix}" = "xNONE"
1951   then
1952       lib_exec_prefix=$prefix
1953   else
1954       lib_exec_prefix=$exec_prefix
1955   fi
1956   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1957   AC_SUBST(LIBDIR)
1958 fi
1959
1960 AC_CONFIG_FILES([
1961 Makefile
1962 libgcj.pc
1963 libgcj.spec
1964 libgcj-test.spec
1965 gcj/Makefile
1966 include/Makefile
1967 testsuite/Makefile
1968 contrib/aotcompile.py
1969 contrib/aot-compile
1970 contrib/aot-compile-rpm
1971 contrib/generate-cacerts.pl
1972 contrib/rebuild-gcj-db
1973 ])
1974
1975 if test ${multilib} = yes; then
1976   multilib_arg="--enable-multilib"
1977 else
1978   multilib_arg=
1979 fi
1980
1981 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1982 AC_OUTPUT