libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.64)
   4
   5 AC_INIT([libffi], [3.0.8], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   cris-*-*)
  59         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  60         ;;
  61
  62   frv-*-*)
  63         TARGET=FRV; TARGETDIR=frv
  64         ;;
  65
  66   hppa*-*-linux* | parisc*-*-linux*)
  67         TARGET=PA_LINUX; TARGETDIR=pa
  68         ;;
  69   hppa*64-*-hpux*)
  70         TARGET=PA64_HPUX; TARGETDIR=pa
  71         ;;
  72   hppa*-*-hpux*)
  73         TARGET=PA_HPUX; TARGETDIR=pa
  74         ;;
  75
  76   i386-*-freebsd* | i386-*-openbsd*)
  77         TARGET=X86_FREEBSD; TARGETDIR=x86
  78         ;;
  79   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  80         TARGET=X86_WIN32; TARGETDIR=x86
  81         ;;
  82   i?86-*-darwin*)
  83         TARGET=X86_DARWIN; TARGETDIR=x86
  84         ;;
  85   i?86-*-solaris2.1[[0-9]]*)
  86         TARGET=X86_64; TARGETDIR=x86
  87         ;;
  88   i?86-*-*)
  89         TARGET=X86; TARGETDIR=x86
  90         ;;
  91
  92   ia64*-*-*)
  93         TARGET=IA64; TARGETDIR=ia64
  94         ;;
  95
  96   m32r*-*-*)
  97         TARGET=M32R; TARGETDIR=m32r
  98         ;;
  99
 100   m68k-*-*)
 101         TARGET=M68K; TARGETDIR=m68k
 102         ;;
 103
 104   mips-sgi-irix5.* | mips-sgi-irix6.*)
 105         TARGET=MIPS; TARGETDIR=mips
 106         ;;
 107   mips*-*-linux*)
 108         TARGET=MIPS; TARGETDIR=mips
 109         ;;
 110
 111   powerpc*-*-linux* | powerpc-*-sysv*)
 112         TARGET=POWERPC; TARGETDIR=powerpc
 113         ;;
 114   powerpc-*-beos*)
 115         TARGET=POWERPC; TARGETDIR=powerpc
 116         ;;
 117   powerpc-*-darwin*)
 118         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 119         ;;
 120   powerpc-*-aix* | rs6000-*-aix*)
 121         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 122         ;;
 123   powerpc-*-freebsd*)
 124         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 125         ;;
 126   powerpc*-*-rtems*)
 127         TARGET=POWERPC; TARGETDIR=powerpc
 128         ;;
 129
 130   s390-*-* | s390x-*-*)
 131         TARGET=S390; TARGETDIR=s390
 132         ;;
 133
 134   sh-*-* | sh[[34]]*-*-*)
 135         TARGET=SH; TARGETDIR=sh
 136         ;;
 137   sh64-*-* | sh5*-*-*)
 138         TARGET=SH64; TARGETDIR=sh64
 139         ;;
 140
 141   sparc*-*-*)
 142         TARGET=SPARC; TARGETDIR=sparc
 143         ;;
 144
 145   x86_64-*-darwin*)
 146         TARGET=X86_DARWIN; TARGETDIR=x86
 147         ;;
 148
 149   x86_64-*-cygwin* | x86_64-*-mingw*)
 150         TARGET=X86_WIN64; TARGETDIR=x86
 151         ;;
 152
 153   x86_64-*-*)
 154         TARGET=X86_64; TARGETDIR=x86
 155         ;;
 156 esac
 157
 158 AC_SUBST(AM_RUNTESTFLAGS)
 159
 160 if test $TARGETDIR = unknown; then
 161   AC_MSG_ERROR(["libffi has not been ported to $host."])
 162 fi
 163
 164 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 165 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 166 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 167 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 168 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 169 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 170 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 171 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 172 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 173 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 174 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 175 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 176 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 177 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 178 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 179 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 180 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 181 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 182 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 183 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 184 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 185 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 186 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 187 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 188 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 189
 190 AC_HEADER_STDC
 191 AC_CHECK_FUNCS(memcpy)
 192 AC_FUNC_ALLOCA
 193
 194 AC_CHECK_SIZEOF(double)
 195 AC_CHECK_SIZEOF(long double)
 196
 197 # Also AC_SUBST this variable for ffi.h.
 198 if test -z "$HAVE_LONG_DOUBLE"; then
 199   HAVE_LONG_DOUBLE=0
 200   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 201     if test $ac_cv_sizeof_long_double != 0; then
 202       HAVE_LONG_DOUBLE=1
 203       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 204     fi
 205   fi
 206 fi
 207 AC_SUBST(HAVE_LONG_DOUBLE)
 208
 209 AC_C_BIGENDIAN
 210
 211 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 212     libffi_cv_as_cfi_pseudo_op, [
 213     libffi_cv_as_cfi_pseudo_op=unknown
 214     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 215                    [libffi_cv_as_cfi_pseudo_op=yes],
 216                    [libffi_cv_as_cfi_pseudo_op=no])
 217 ])
 218 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 219     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 220               [Define if your assembler supports .cfi_* directives.])
 221 fi
 222
 223 if test x$TARGET = xSPARC; then
 224     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 225         libffi_cv_as_sparc_ua_pcrel, [
 226         save_CFLAGS="$CFLAGS"
 227         save_LDFLAGS="$LDFLAGS"
 228         CFLAGS="$CFLAGS -fpic"
 229         LDFLAGS="$LDFLAGS -shared"
 230         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 231                     [libffi_cv_as_sparc_ua_pcrel=yes],
 232                     [libffi_cv_as_sparc_ua_pcrel=no])
 233         CFLAGS="$save_CFLAGS"
 234         LDFLAGS="$save_LDFLAGS"])
 235     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 236         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 237                   [Define if your assembler and linker support unaligned PC relative relocs.])
 238     fi
 239
 240     AC_CACHE_CHECK([assembler .register pseudo-op support],
 241        libffi_cv_as_register_pseudo_op, [
 242        libffi_cv_as_register_pseudo_op=unknown
 243        # Check if we have .register
 244        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 245                        [libffi_cv_as_register_pseudo_op=yes],
 246                        [libffi_cv_as_register_pseudo_op=no])
 247     ])
 248     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 249        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 250                [Define if your assembler supports .register.])
 251     fi
 252 fi
 253
 254 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 255     AC_CACHE_CHECK([assembler supports pc related relocs],
 256         libffi_cv_as_x86_pcrel, [
 257         libffi_cv_as_x86_pcrel=yes
 258         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 259         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 260             libffi_cv_as_x86_pcrel=no
 261         fi
 262         ])
 263     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 264         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 265                   [Define if your assembler supports PC relative relocs.])
 266     fi
 267 fi
 268
 269 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 270     libffi_cv_ro_eh_frame, [
 271         libffi_cv_ro_eh_frame=no
 272         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 273         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 274             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 275                 libffi_cv_ro_eh_frame=yes
 276             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 277                  | grep -v '#write' > /dev/null; then
 278                 libffi_cv_ro_eh_frame=yes
 279             fi
 280         fi
 281         rm -f conftest.*
 282     ])
 283 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 284     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 285               [Define if .eh_frame sections should be read-only.])
 286     AC_DEFINE(EH_FRAME_FLAGS, "a",
 287               [Define to the flags needed for the .section .eh_frame directive.])
 288 else
 289     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 290               [Define to the flags needed for the .section .eh_frame directive.])
 291 fi
 292
 293 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 294     libffi_cv_hidden_visibility_attribute, [
 295         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 296         libffi_cv_hidden_visibility_attribute=no
 297         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 298             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 299                 libffi_cv_hidden_visibility_attribute=yes
 300             fi
 301         fi
 302         rm -f conftest.*
 303     ])
 304 if test $libffi_cv_hidden_visibility_attribute = yes; then
 305     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 306               [Define if __attribute__((visibility("hidden"))) is supported.])
 307 fi
 308
 309 AH_BOTTOM([
 310 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 311 #ifdef LIBFFI_ASM
 312 #define FFI_HIDDEN(name) .hidden name
 313 #else
 314 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 315 #endif
 316 #else
 317 #ifdef LIBFFI_ASM
 318 #define FFI_HIDDEN(name)
 319 #else
 320 #define FFI_HIDDEN
 321 #endif
 322 #endif
 323 ])
 324
 325 AC_SUBST(TARGET)
 326 AC_SUBST(TARGETDIR)
 327
 328 AC_SUBST(SHELL)
 329
 330 AC_ARG_ENABLE(debug,
 331 [  --enable-debug          debugging mode],
 332   if test "$enable_debug" = "yes"; then
 333     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 334   fi)
 335
 336 AC_ARG_ENABLE(structs,
 337 [  --disable-structs       omit code for struct support],
 338   if test "$enable_structs" = "no"; then
 339     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 340   fi)
 341
 342 AC_ARG_ENABLE(raw-api,
 343 [  --disable-raw-api       make the raw api unavailable],
 344   if test "$enable_raw_api" = "no"; then
 345     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 346   fi)
 347
 348 AC_ARG_ENABLE(purify-safety,
 349 [  --enable-purify-safety  purify-safe mode],
 350   if test "$enable_purify_safety" = "yes"; then
 351     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 352   fi)
 353
 354 if test -n "$with_cross_host" &&
 355    test x"$with_cross_host" != x"no"; then
 356   toolexecdir='$(exec_prefix)/$(target_alias)'
 357   toolexeclibdir='$(toolexecdir)/lib'
 358 else
 359   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 360   toolexeclibdir='$(libdir)'
 361 fi
 362 multi_os_directory=`$CC -print-multi-os-directory`
 363 case $multi_os_directory in
 364   .) ;; # Avoid trailing /.
 365   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 366 esac
 367 AC_SUBST(toolexecdir)
 368 AC_SUBST(toolexeclibdir)
 369
 370 if test "${multilib}" = "yes"; then
 371   multilib_arg="--enable-multilib"
 372 else
 373   multilib_arg=
 374 fi
 375
 376 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 377 AC_CONFIG_COMMANDS(src, [
 378 test -d src || mkdir src
 379 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 380 ], [TARGETDIR="$TARGETDIR"])
 381
 382 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 383
 384 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
 385
 386 AC_OUTPUT