libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1994-2016 Free Software Foundation, Inc.
   3 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GCC.
   6 #
   7 #GCC is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 3, or (at your option)
  10 #any later version.
  11 #
  12 #GCC is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GCC; see the file COPYING3.  If not see
  19 #<http://www.gnu.org/licenses/>.
  20
  21 m4_include([../config/pkg.m4])
  22
  23 AC_PREREQ(2.64)
  24 AC_INIT(package-unused, version-unused,, libobjc)
  25 AC_CONFIG_SRCDIR([objc/objc.h])
  26 GCC_TOPLEV_SUBDIRS
  27
  28 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  29 PACKAGE=libobjc
  30 # Version is pulled out to make it a bit easier to change using sed.
  31 VERSION=4:0:0
  32 AC_SUBST(VERSION)
  33
  34 # This works around the fact that libtool configuration may change LD
  35 # for this particular configuration, but some shells, instead of
  36 # keeping the changes in LD private, export them just because LD is
  37 # exported.
  38 ORIGINAL_LD_FOR_MULTILIBS=$LD
  39
  40 # -------
  41 # Options
  42 # -------
  43
  44 # We use these options to decide which functions to include.
  45 AC_ARG_WITH(target-subdir,
  46 [  --with-target-subdir=SUBDIR
  47                            configuring in a subdirectory])
  48 AC_ARG_WITH(cross-host,
  49 [  --with-cross-host=HOST  configuring with a cross compiler])
  50
  51 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  52 AC_ARG_ENABLE(version-specific-runtime-libs,
  53 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  54 [case "$enableval" in
  55  yes) version_specific_libs=yes ;;
  56  no)  version_specific_libs=no ;;
  57  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  58  esac],
  59 [version_specific_libs=no])
  60 AC_MSG_RESULT($version_specific_libs)
  61
  62 # -----------
  63 # Directories
  64 # -----------
  65
  66 # Find the rest of the source tree framework.
  67 AM_ENABLE_MULTILIB(, ..)
  68
  69 AC_CANONICAL_SYSTEM
  70 ACX_NONCANONICAL_TARGET
  71
  72 # Export source directory.
  73 # These need to be absolute paths, yet at the same time need to
  74 # canonicalize only relative paths, because then amd will not unmount
  75 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  76 case $srcdir in
  77   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  78   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  79 esac
  80 AC_SUBST(glibcpp_srcdir)
  81
  82 # Calculate toolexeclibdir
  83 # Also toolexecdir, though it's only used in toolexeclibdir
  84 case ${version_specific_libs} in
  85   yes)
  86     # Need the gcc compiler version to know where to install libraries
  87     # and header files if --enable-version-specific-runtime-libs option
  88     # is selected.
  89     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
  90     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  91     ;;
  92   no)
  93     if test -n "$with_cross_host" &&
  94        test x"$with_cross_host" != x"no"; then
  95       # Install a library built with a cross compiler in tooldir, not libdir.
  96       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
  97       toolexeclibdir='$(toolexecdir)/lib'
  98     else
  99       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 100       toolexeclibdir='$(libdir)'
 101     fi
 102     multi_os_directory=`$CC -print-multi-os-directory`
 103     case $multi_os_directory in
 104       .) ;; # Avoid trailing /.
 105       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 106     esac
 107     ;;
 108 esac
 109 AC_SUBST(toolexecdir)
 110 AC_SUBST(toolexeclibdir)
 111
 112 # Figure out if we want to name the include directory and the
 113 #  library name changes differently.
 114 includedirname=include
 115 libsuffix=
 116 case "${host}" in
 117   *-darwin*)
 118     # Darwin is the only target so far that needs a different include directory.
 119     includedirname=include-gnu-runtime
 120     libsuffix=-gnu
 121     ;;
 122 esac
 123 AC_SUBST(includedirname)
 124 AC_SUBST(libsuffix)
 125
 126 AC_CONFIG_HEADERS(config.h)
 127
 128 # --------
 129 # Programs
 130 # --------
 131
 132 GCC_NO_EXECUTABLES
 133
 134 # We must force CC to /not/ be a precious variable; otherwise
 135 # the wrong, non-multilib-adjusted value will be used in multilibs.
 136 # As a side effect, we have to subst CFLAGS ourselves.
 137 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 138 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 139 AC_PROG_CC
 140 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 141
 142 # extra LD Flags which are required for targets
 143 ACX_LT_HOST_FLAGS
 144 case "${host}" in
 145   *-darwin*)
 146     # Darwin needs -single_module when linking libobjc
 147     extra_ldflags_libobjc='$(lt_host_flags) -Wl,-single_module'
 148     ;;
 149   *-cygwin*|*-mingw*)
 150     # Tell libtool to build DLLs on Windows
 151     extra_ldflags_libobjc='$(lt_host_flags)'
 152     ;;
 153 esac
 154 AC_SUBST(extra_ldflags_libobjc)
 155
 156 AC_SUBST(CFLAGS)
 157
 158 AC_CHECK_TOOL(AS, as)
 159 AC_CHECK_TOOL(AR, ar)
 160 AC_CHECK_TOOL(RANLIB, ranlib, :)
 161 AC_PROG_INSTALL
 162
 163 AM_MAINTAINER_MODE
 164
 165 # Enable Win32 DLL on MS Windows - FIXME
 166 AC_LIBTOOL_WIN32_DLL
 167
 168 AC_PROG_LIBTOOL
 169
 170 AM_PROG_CC_C_O
 171
 172 AC_PROG_MAKE_SET
 173
 174 # -------
 175 # Headers
 176 # -------
 177
 178 # Sanity check for the cross-compilation case:
 179 AC_CHECK_HEADER(stdio.h,:,
 180   [AC_MSG_ERROR([Can't find stdio.h.
 181 You must have a usable C system for the target already installed, at least
 182 including headers and, preferably, the library, before you can configure
 183 the Objective C runtime system.  If necessary, install gcc now with
 184 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 185
 186 AC_HEADER_STDC
 187
 188 AC_CHECK_HEADERS(sched.h)
 189
 190 # -----------
 191 # Miscellanea
 192 # -----------
 193
 194 # Check if we have thread-local storage
 195 GCC_CHECK_TLS
 196
 197 gt_BITFIELD_TYPE_MATTERS
 198
 199 # -----------
 200 # boehm-gc
 201 # -----------
 202
 203 AC_ARG_ENABLE(objc-gc,
 204 [AS_HELP_STRING([--enable-objc-gc],
 205                 [enable use of Boehm's garbage collector with the
 206                  GNU Objective-C runtime])],,enable_objc_gc=no)
 207 AC_ARG_WITH([target-bdw-gc],
 208 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
 209                 [specify prefix directory for installed bdw-gc package.
 210                  Equivalent to --with-target-bdw-gc-include=PATH/include
 211                  plus --with-target-bdw-gc-lib=PATH/lib])])
 212 AC_ARG_WITH([target-bdw-gc-include],
 213 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
 214                 [specify directories for installed bdw-gc include files])])
 215 AC_ARG_WITH([target-bdw-gc-lib],
 216 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
 217                 [specify directories for installed bdw-gc library])])
 218
 219 case "$enable_objc_gc" in
 220 no)
 221   use_bdw_gc=no
 222   ;;
 223 *)
 224   AC_MSG_CHECKING([for bdw garbage collector])
 225   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
 226     dnl no bdw-gw options, fall back to the bdw-gc pkg-config module
 227     PKG_CHECK_EXISTS(bdw-gc,
 228       [AC_MSG_RESULT([using bdw-gc pkg-config module])
 229        BDW_GC_CFLAGS=`$PKG_CONFIG --cflags bdw-gc`
 230        BDW_GC_LIBS=`$PKG_CONFIG --libs bdw-gc`],
 231       AC_MSG_ERROR([no --with-target-bdw-gc options and no bdw-gc pkg-config module found]))
 232   else
 233     dnl bdw-gw options passed by configure flags
 234     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
 235       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
 236     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
 237       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
 238     else
 239       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
 240     fi
 241     mldir=`${CC-gcc} --print-multi-directory 2>/dev/null`
 242     bdw_val=
 243     if test "x$with_target_bdw_gc" != x; then
 244       for i in `echo $with_target_bdw_gc | tr ',' ' '`; do
 245         case "$i" in
 246           *=*) sd=${i%%=*}; d=${i#*=} ;;
 247           *) sd=.; d=$i ;;
 248         esac
 249         if test "$mldir" = "$sd"; then
 250           bdw_val=$d
 251         fi
 252       done
 253       if test "x$bdw_val" = x; then
 254         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc])
 255       fi
 256       bdw_inc_dir="$bdw_val/include"
 257       bdw_lib_dir="$bdw_val/lib"
 258     fi
 259     bdw_val=
 260     if test "x$with_target_bdw_gc_include" != x; then
 261       for i in `echo $with_target_bdw_gc_include | tr ',' ' '`; do
 262         case "$i" in
 263           *=*) sd=${i%%=*}; d=${i#*=} ;;
 264           *) sd=.; d=$i ;;
 265         esac
 266         if test "$mldir" = "$sd"; then
 267           bdw_val=$d
 268         fi
 269       done
 270       if test "x$bdw_val" = x; then
 271         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 272       fi
 273       bdw_inc_dir="$bdw_val"
 274     fi
 275     bdw_val=
 276     if test "x$with_target_bdw_gc_lib" != x; then
 277       for i in `echo $with_target_bdw_gc_lib | tr ',' ' '`; do
 278         case "$i" in
 279           *=*) sd=${i%%=*}; d=${i#*=} ;;
 280           *) sd=.; d=$i ;;
 281         esac
 282         if test "$mldir" = "$sd"; then
 283           bdw_val=$d
 284         fi
 285       done
 286       if test "x$bdw_val" = x; then
 287         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 288       fi
 289       bdw_lib_dir="$bdw_val"
 290     fi
 291     if test "x$bdw_inc_dir" = x; then
 292       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 293     fi
 294     if test "x$bdw_lib_dir" = x; then
 295       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 296     fi
 297     BDW_GC_CFLAGS="-I$bdw_inc_dir"
 298     BDW_GC_LIBS="-L$bdw_lib_dir -lgc"
 299     AC_MSG_RESULT([found])
 300   fi
 301
 302   AC_MSG_CHECKING([for system boehm-gc])
 303   save_CFLAGS=$CFLAGS
 304   save_LIBS=$LIBS
 305   CFLAGS="$CFLAGS $BDW_GC_CFLAGS"
 306   LIBS="$LIBS $BDW_GC_LIBS"
 307   dnl the link test is not good enough for ARM32 multilib detection,
 308   dnl first check to link, then to run
 309   AC_LINK_IFELSE(
 310     [AC_LANG_PROGRAM([#include <gc/gc.h>],[GC_init()])],
 311     [
 312       AC_RUN_IFELSE([AC_LANG_SOURCE([[
 313         #include <gc/gc.h>
 314         int main() {
 315           GC_init();
 316           return 0;
 317         }
 318         ]])],
 319         [system_bdw_gc_found=yes],
 320         [system_bdw_gc_found=no],
 321         dnl assume no system boehm-gc for cross builds ...
 322         [system_bdw_gc_found=no]
 323       )
 324     ],
 325     [system_bdw_gc_found=no])
 326   CFLAGS=$save_CFLAGS
 327   LIBS=$save_LIBS
 328   if test x$enable_objc_gc = xauto && test x$system_bdw_gc_found = xno; then
 329     AC_MSG_WARN([system bdw-gc not found, not building libobjc_gc])
 330     use_bdw_gc=no
 331   elif test x$enable_objc_gc = xyes && test x$system_bdw_gc_found = xno; then
 332     AC_MSG_ERROR([system bdw-gc required but not found])
 333   else
 334     use_bdw_gc=yes
 335     AC_MSG_RESULT([found])
 336   fi
 337 esac
 338
 339 if test "$use_bdw_gc" = no; then
 340   OBJC_GCFLAGS=''
 341   OBJC_BOEHM_GC=''
 342   OBJC_BOEHM_GC_INCLUDES=''
 343   OBJC_BOEHM_GC_LIBS=''
 344 else
 345   OBJC_GCFLAGS='-DOBJC_WITH_GC=1'
 346   OBJC_BOEHM_GC='libobjc_gc$(libsuffix).la'
 347   OBJC_BOEHM_GC_INCLUDES=$BDW_GC_CFLAGS
 348   OBJC_BOEHM_GC_LIBS=$BDW_GC_LIBS
 349 fi
 350 AC_SUBST(OBJC_GCFLAGS)
 351 AC_SUBST(OBJC_BOEHM_GC)
 352 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
 353 AC_SUBST(OBJC_BOEHM_GC_LIBS)
 354
 355 # ------
 356 # Output
 357 # ------
 358
 359 if test ${multilib} = yes; then
 360   multilib_arg="--enable-multilib"
 361 else
 362   multilib_arg=
 363 fi
 364
 365 AC_CONFIG_FILES([Makefile])
 366 AC_OUTPUT