libstdc++-v3/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT(package-unused, version-unused,, libstdc++)
   6 AC_CONFIG_SRCDIR(src/ios.cc)
   7 AC_CONFIG_HEADER(config.h)
   8
   9 # This works around the fact that libtool configuration may change LD
  10 # for this particular configuration, but some shells, instead of
  11 # keeping the changes in LD private, export them just because LD is
  12 # exported.  Only used at the end of this file.
  13 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  14
  15 # For libtool versioning info, format is CURRENT:REVISION:AGE
  16 libtool_VERSION=6:0:0
  17 AC_SUBST(libtool_VERSION)
  18
  19 # Find the rest of the source tree framework.
  20 GLIBCXX_TOPREL_CONFIGURE
  21
  22 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  23 #
  24 # You will slowly go insane if you do not grok the following fact:  when
  25 # building v3 as part of the compiler, the top-level /target/ becomes the
  26 # library's /host/.  configure then causes --target to default to --host,
  27 # exactly like any other package using autoconf.  Therefore, 'target' and
  28 # 'host' will always be the same.  This makes sense both for native and
  29 # cross compilers, just think about it for a little while.  :-)
  30 #
  31 # Also, if v3 is being configured as part of a cross compiler, the top-level
  32 # configure script will pass the "real" host as $with_cross_host.
  33 #
  34 # Do not delete or change the following two lines.  For why, see
  35 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  36 AC_CANONICAL_SYSTEM
  37 target_alias=${target_alias-$host_alias}
  38
  39 # Handy for debugging:
  40 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  41
  42 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  43 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  44 #  1.x:  minimum required version
  45 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  46 #              of other PACKAGE_* variables will, however, and there's nothing
  47 #              we can do about that; they come from AC_INIT).
  48 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  49 #            file in the top srcdir, etc, etc), so stop complaining.
  50 #  no-dependencies:  turns off auto dependency generation (just for now)
  51 #  -Wall:  turns on all automake warnings
  52 AM_INIT_AUTOMAKE([1.7.6 no-define foreign no-dependencies -Wall])
  53
  54 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  55 # up critical shell variables.
  56 GLIBCXX_CONFIGURE
  57
  58 #AC_MSG_NOTICE([====== Starting libtool configuration])
  59 AC_LIBTOOL_DLOPEN
  60 AM_PROG_LIBTOOL
  61 AC_SUBST(enable_shared)
  62 AC_SUBST(enable_static)
  63 #AC_MSG_NOTICE([====== Finished libtool configuration]) ; sleep 10
  64
  65 # Check for support bits and g++ features that don't require linking.
  66 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  67 GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS
  68 GLIBCXX_ENABLE_PCH([yes])
  69
  70 # Enable all the variable C++ runtime options.
  71 # NB: C_MBCHAR must come early.
  72 GLIBCXX_ENABLE_CSTDIO
  73 GLIBCXX_ENABLE_CLOCALE
  74 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
  75 GLIBCXX_ENABLE_C_MBCHAR([yes])
  76 GLIBCXX_ENABLE_C99([yes])
  77 GLIBCXX_ENABLE_LONG_LONG([yes])
  78 GLIBCXX_ENABLE_THREADS
  79 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
  80 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
  81 GLIBCXX_ENABLE_DEBUG([no])
  82 GLIBCXX_ENABLE_CXX_FLAGS
  83
  84 # No surprises, no surprises...
  85 if test $atomicity_include_dir = cpu/generic ; then
  86   AC_MSG_WARN([No native atomic operations are provided for this platform.])
  87   if test $target_thread_file = single; then
  88     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
  89     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
  90   else
  91     AC_MSG_WARN([They will be faked using a mutex.])
  92     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
  93   fi
  94 fi
  95
  96
  97 if test "$build" != "$host"; then
  98
  99   # We are being configured with some form of cross compiler.
 100   GLIBCXX_IS_NATIVE=false
 101
 102   # This lets us hard-code the functionality we know we'll have in the cross
 103   # target environment.  "Let" is a sugar-coated word placed on an especially
 104   # dull and tedious hack, actually.
 105   #
 106   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 107   # that involve linking, can't be used:
 108   #    "cannot open sim-crt0.o"
 109   #    "cannot open crt0.o"
 110   # etc.  All this is because there currently exists no unified, consistent
 111   # way for top level CC information to be passed down to target directories:
 112   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 113   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 114   # crosses can be removed.
 115
 116   # If Canadian cross, then don't pick up tools from the build directory.
 117   # Used in GLIBCXX_EXPORT_INCLUDES (and nowhere else?).
 118   if test -n "$with_cross_host" &&
 119      test x"$build" != x"$with_cross_host" &&
 120      test x"$build" != x"$target";
 121   then
 122     CANADIAN=yes
 123   else
 124     CANADIAN=no
 125   fi
 126
 127   # Construct crosses by hand, eliminating bits that need ld...
 128   # GLIBCXX_CHECK_COMPILER_FEATURES
 129   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 130   # GLIBCXX_CHECK_MATH_SUPPORT
 131
 132   # First, test for "known" system libraries.  We may be using newlib even
 133   # on a hosted environment.
 134   if test "x${with_newlib}" = "xyes"; then
 135     os_include_dir="os/newlib"
 136     AC_DEFINE(HAVE_HYPOT)
 137
 138     # GLIBCXX_CHECK_STDLIB_SUPPORT
 139     AC_DEFINE(HAVE_STRTOF)
 140     AC_DEFINE(HAVE_STRTOLD)
 141     # AC_FUNC_MMAP
 142     AC_DEFINE(HAVE_MMAP)
 143
 144     AC_DEFINE(HAVE_ACOSF)
 145     AC_DEFINE(HAVE_ASINF)
 146     AC_DEFINE(HAVE_ATAN2F)
 147     AC_DEFINE(HAVE_ATANF)
 148     AC_DEFINE(HAVE_CEILF)
 149     AC_DEFINE(HAVE_COPYSIGN)
 150     AC_DEFINE(HAVE_COPYSIGNF)
 151     AC_DEFINE(HAVE_COSF)
 152     AC_DEFINE(HAVE_COSHF)
 153     AC_DEFINE(HAVE_EXPF)
 154     AC_DEFINE(HAVE_FABSF)
 155     AC_DEFINE(HAVE_FLOORF)
 156     AC_DEFINE(HAVE_FMODF)
 157     AC_DEFINE(HAVE_FREXPF)
 158     AC_DEFINE(HAVE_LDEXPF)
 159     AC_DEFINE(HAVE_LOG10F)
 160     AC_DEFINE(HAVE_LOGF)
 161     AC_DEFINE(HAVE_MODFF)
 162     AC_DEFINE(HAVE_POWF)
 163     AC_DEFINE(HAVE_SINF)
 164     AC_DEFINE(HAVE_SINHF)
 165     AC_DEFINE(HAVE_SQRTF)
 166     AC_DEFINE(HAVE_TANF)
 167     AC_DEFINE(HAVE_TANHF)
 168   else
 169     m4_include([crossconfig.m4])
 170   fi
 171
 172   # At some point, we should differentiate between architectures
 173   # like x86, which have long double versions, and alpha/powerpc/etc.,
 174   # which don't. For the time being, punt.
 175   if test x"long_double_math_on_this_cpu" = x"yes"; then
 176     AC_DEFINE(HAVE_ACOSL)
 177     AC_DEFINE(HAVE_ASINL)
 178     AC_DEFINE(HAVE_ATAN2L)
 179     AC_DEFINE(HAVE_ATANL)
 180     AC_DEFINE(HAVE_CEILL)
 181     AC_DEFINE(HAVE_COPYSIGNL)
 182     AC_DEFINE(HAVE_COSL)
 183     AC_DEFINE(HAVE_COSHL)
 184     AC_DEFINE(HAVE_EXPL)
 185     AC_DEFINE(HAVE_FABSL)
 186     AC_DEFINE(HAVE_FLOORL)
 187     AC_DEFINE(HAVE_FMODL)
 188     AC_DEFINE(HAVE_FREXPL)
 189     AC_DEFINE(HAVE_LDEXPL)
 190     AC_DEFINE(HAVE_LOG10L)
 191     AC_DEFINE(HAVE_LOGL)
 192     AC_DEFINE(HAVE_MODFL)
 193     AC_DEFINE(HAVE_POWL)
 194     AC_DEFINE(HAVE_SINCOSL)
 195     AC_DEFINE(HAVE_SINL)
 196     AC_DEFINE(HAVE_SINHL)
 197     AC_DEFINE(HAVE_SQRTL)
 198     AC_DEFINE(HAVE_TANL)
 199     AC_DEFINE(HAVE_TANHL)
 200   fi
 201
 202 else
 203
 204   # We are being configured natively.  We can do more elaborate tests that
 205   # include AC_TRY_COMPILE now, as the linker is assumed to be working.
 206   GLIBCXX_IS_NATIVE=true
 207   CANADIAN=no
 208
 209   # Check for available headers.
 210   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 211   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 212   sys/types.h])
 213
 214   GLIBCXX_CHECK_COMPILER_FEATURES
 215   GLIBCXX_CHECK_LINKER_FEATURES
 216   GLIBCXX_CHECK_MATH_SUPPORT
 217   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 218   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 219   GLIBCXX_CHECK_WCHAR_T_SUPPORT
 220   GLIBCXX_CHECK_STDLIB_SUPPORT
 221
 222   # For showmanyc_helper().
 223   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 224   GLIBCXX_CHECK_POLL
 225   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 226
 227   # For xsputn_2().
 228   AC_CHECK_HEADERS(sys/uio.h)
 229   GLIBCXX_CHECK_WRITEV
 230
 231   AC_LC_MESSAGES
 232
 233   AC_TRY_COMPILE(
 234     [#include <setjmp.h>],
 235     [sigjmp_buf env;
 236      while (! sigsetjmp (env, 1))
 237        siglongjmp (env, 1);
 238     ],
 239     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 240
 241   AC_FUNC_MMAP
 242 fi
 243
 244 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 245 GLIBCXX_ENABLE_SYMVERS([yes])
 246
 247 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 248 GLIBCXX_CONFIGURE_TESTSUITE
 249
 250 # Propagate the target-specific source directories through the build chain.
 251 # (Nothing currently uses cpu_include_dir directly; only atomicity_include_dir
 252 # uses it, and it only gets used in this file.)
 253 ATOMICITY_INC_SRCDIR=config/${atomicity_include_dir}
 254 OS_INC_SRCDIR=config/${os_include_dir}
 255 FPOS_INC_SRCDIR=config/${fpos_include_dir}
 256 AC_SUBST(ATOMICITY_INC_SRCDIR)
 257 AC_SUBST(FPOS_INC_SRCDIR)
 258 AC_SUBST(OS_INC_SRCDIR)
 259
 260 # Determine cross-compile flags and AM_CONDITIONALs.
 261 #AC_SUBST(GLIBCXX_IS_NATIVE)
 262 AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 263 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 264 AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 265
 266 AC_CACHE_SAVE
 267
 268 if test ${multilib} = yes; then
 269   multilib_arg="--enable-multilib"
 270 else
 271   multilib_arg=
 272 fi
 273
 274 # Export all the install information
 275 GLIBCXX_EXPORT_INSTALL_INFO
 276
 277 # Export all the include and flag information to Makefiles.
 278 GLIBCXX_EXPORT_INCLUDES
 279 GLIBCXX_EXPORT_FLAGS
 280
 281 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 282    grep "enable shared" > /dev/null;
 283 then
 284   LIBSUPCXX_PICFLAGS=-prefer-pic
 285 else
 286   LIBSUPCXX_PICFLAGS=
 287 fi
 288 AC_SUBST(LIBSUPCXX_PICFLAGS)
 289
 290 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 291 dnl which can all be called multiple times as needed, plus one (different)
 292 dnl AC_OUPUT macro.  This one lists the files to be created:
 293 AC_CONFIG_FILES([ \
 294   Makefile \
 295   include/Makefile \
 296   libmath/Makefile \
 297   libsupc++/Makefile \
 298   po/Makefile \
 299   src/Makefile \
 300   testsuite/Makefile \
 301   ])
 302 AC_CONFIG_FILES([scripts/check_survey],[chmod +x scripts/check_survey])
 303 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 304
 305 dnl These commands are run at the end of config.status:
 306 AC_CONFIG_COMMANDS([default],
 307 [if test -n "$CONFIG_FILES"; then
 308    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 309    # that multilib installs will end up installed in the correct place.
 310    # The testsuite needs it for multilib-aware ABI baseline files.
 311    # To work around this not being passed down from config-ml.in ->
 312    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 313    # append it here.  Only modify Makefiles that have just been created.
 314    for i in src libsupc++ testsuite; do
 315     case $CONFIG_FILES in
 316      *${i}/Makefile*)
 317        #echo "Adding MULTISUBDIR to $i/Makefile"
 318        grep '^MULTISUBDIR =' Makefile >> $i/Makefile
 319        ;;
 320     esac
 321    done
 322  fi
 323  (cd include && ${MAKE-make})
 324 ],
 325 [
 326 # No init-vars needed so far which aren't already passed by autoconf.
 327 ])
 328
 329 dnl And this actually makes things happen:
 330 AC_OUTPUT