libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 # Libtool setup.
  92 if test "x${with_newlib}" != "xyes"; then
  93   AC_LIBTOOL_DLOPEN
  94 fi
  95 AM_PROG_LIBTOOL
  96 ACX_LT_HOST_FLAGS
  97 AC_SUBST(enable_shared)
  98 AC_SUBST(enable_static)
  99
 100 if test "$enable_vtable_verify" = yes; then
 101   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 102   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 103 fi
 104
 105
 106 # libtool variables for C++ shared and position-independent compiles.
 107 #
 108 # Use glibcxx_lt_pic_flag to designate the automake variable
 109 # used to encapsulate the default libtool approach to creating objects
 110 # with position-independent code. Default: -prefer-pic.
 111 #
 112 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 113 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 114 #
 115 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 116 # creating position-independent objects. This varies with the target
 117 # hardware and operating system, but is often: -DPIC -fPIC.
 118 if test "$enable_shared" = yes; then
 119   glibcxx_lt_pic_flag="-prefer-pic"
 120   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 121   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 122
 123 else
 124   glibcxx_lt_pic_flag=
 125   glibcxx_compiler_pic_flag=
 126   glibcxx_compiler_shared_flag=
 127 fi
 128 AC_SUBST(glibcxx_lt_pic_flag)
 129 AC_SUBST(glibcxx_compiler_pic_flag)
 130 AC_SUBST(glibcxx_compiler_shared_flag)
 131
 132 # Override the libtool's pic_flag and pic_mode.
 133 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 134 # NB: this impacts --with-pic and --without-pic.
 135 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 136 pic_mode='default'
 137
 138 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 139 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 140
 141 # Possibly disable most of the library.
 142 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 143 ## than just ignoring the results.  Faster /and/ more correct, win win.
 144 GLIBCXX_ENABLE_HOSTED
 145
 146 # Enable descriptive messages to standard output on termination.
 147 GLIBCXX_ENABLE_VERBOSE
 148
 149 # Enable compiler support that doesn't require linking.
 150 GLIBCXX_ENABLE_PCH($is_hosted)
 151 GLIBCXX_ENABLE_THREADS
 152 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 153 GLIBCXX_ENABLE_DECIMAL_FLOAT
 154 GLIBCXX_ENABLE_INT128_FLOAT128
 155 if test "$enable_float128" = yes; then
 156   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 157 fi
 158
 159 # Checks for compiler support that doesn't require linking.
 160 GLIBCXX_CHECK_COMPILER_FEATURES
 161
 162 # Enable all the variable C++ runtime options that don't require linking.
 163 GLIBCXX_ENABLE_CSTDIO
 164 GLIBCXX_ENABLE_CLOCALE
 165 GLIBCXX_ENABLE_ALLOCATOR
 166 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 167 GLIBCXX_ENABLE_LONG_LONG([yes])
 168 GLIBCXX_ENABLE_WCHAR_T([yes])
 169 GLIBCXX_ENABLE_C99([yes])
 170 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 171 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
 172 GLIBCXX_ENABLE_DEBUG([no])
 173 GLIBCXX_ENABLE_PARALLEL([yes])
 174 GLIBCXX_ENABLE_CXX_FLAGS
 175 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 176 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 177 GLIBCXX_ENABLE_PYTHON
 178 GLIBCXX_ENABLE_WERROR([yes])
 179 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 180
 181 # Checks for operating systems support that doesn't require linking.
 182 GLIBCXX_CHECK_STDIO_PROTO
 183 GLIBCXX_CHECK_MATH11_PROTO
 184 GLIBCXX_CHECK_SYSTEM_ERROR
 185 GLIBCXX_CHECK_UCHAR_H
 186
 187 # For the streamoff typedef.
 188 GLIBCXX_CHECK_INT64_T
 189
 190 # For LFS support.
 191 GLIBCXX_CHECK_LFS
 192
 193 # For showmanyc_helper().
 194 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 195 GLIBCXX_CHECK_POLL
 196 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 197
 198 # For xsputn_2().
 199 AC_CHECK_HEADERS(sys/uio.h)
 200 GLIBCXX_CHECK_WRITEV
 201
 202 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 203 # so that the check is done with the C compiler (not C++).
 204 # Checking with C++ can break a canadian cross build if either
 205 # file does not exist in C but does in C++.
 206 AC_CHECK_HEADERS(fenv.h complex.h)
 207
 208 # For C99 support to TR1.
 209 GLIBCXX_CHECK_C99_TR1
 210
 211 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 212 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 213
 214 # For gettimeofday support.
 215 GLIBCXX_CHECK_GETTIMEOFDAY
 216
 217 # For clock_gettime, nanosleep and sched_yield support.
 218 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 219
 220 # Check for tmpnam which is obsolescent in POSIX.1-2008
 221 GLIBCXX_CHECK_TMPNAM
 222
 223 AC_LC_MESSAGES
 224
 225 # For hardware_concurrency
 226 AC_CHECK_HEADERS(sys/sysinfo.h)
 227 GLIBCXX_CHECK_GET_NPROCS
 228 AC_CHECK_HEADERS(unistd.h)
 229 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 230 GLIBCXX_CHECK_SC_NPROC_ONLN
 231 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 232 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 233 GLIBCXX_CHECK_SDT_H
 234
 235 # Check for available headers.
 236 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 237 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 238 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 239 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 240 wchar.h wctype.h])
 241
 242 # Only do link tests if native. Else, hardcode.
 243 if $GLIBCXX_IS_NATIVE; then
 244
 245   # We can do more elaborate tests that assume a working linker.
 246   CANADIAN=no
 247
 248   GLIBCXX_CHECK_LINKER_FEATURES
 249   GLIBCXX_CHECK_MATH_SUPPORT
 250   GLIBCXX_CHECK_STDLIB_SUPPORT
 251
 252   # For /dev/random and /dev/urandom for TR1.
 253   GLIBCXX_CHECK_RANDOM_TR1
 254
 255   # For TLS support.
 256   GCC_CHECK_TLS
 257
 258   AC_CHECK_FUNCS(__cxa_thread_atexit_impl)
 259
 260   # For iconv support.
 261   AM_ICONV
 262
 263 else
 264
 265   # This lets us hard-code the functionality we know we'll have in the cross
 266   # target environment.  "Let" is a sugar-coated word placed on an especially
 267   # dull and tedious hack, actually.
 268   #
 269   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 270   # that involve linking, can't be used:
 271   #    "cannot open sim-crt0.o"
 272   #    "cannot open crt0.o"
 273   # etc.  All this is because there currently exists no unified, consistent
 274   # way for top level CC information to be passed down to target directories:
 275   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 276   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 277   # crosses can be removed.
 278
 279   # If Canadian cross, then don't pick up tools from the build directory.
 280   # Used only in GLIBCXX_EXPORT_INCLUDES.
 281   if test -n "$with_cross_host" &&
 282      test x"$build_alias" != x"$with_cross_host" &&
 283      test x"$build" != x"$target";
 284   then
 285     CANADIAN=yes
 286   else
 287     CANADIAN=no
 288   fi
 289
 290   # Construct crosses by hand, eliminating bits that need ld...
 291   # GLIBCXX_CHECK_MATH_SUPPORT
 292
 293   # First, test for "known" system libraries.  We may be using newlib even
 294   # on a hosted environment.
 295   if test "x${with_newlib}" = "xyes"; then
 296     os_include_dir="os/newlib"
 297     AC_DEFINE(HAVE_HYPOT)
 298
 299     # GLIBCXX_CHECK_STDLIB_SUPPORT
 300     AC_DEFINE(HAVE_STRTOF)
 301
 302     AC_DEFINE(HAVE_ACOSF)
 303     AC_DEFINE(HAVE_ASINF)
 304     AC_DEFINE(HAVE_ATAN2F)
 305     AC_DEFINE(HAVE_ATANF)
 306     AC_DEFINE(HAVE_CEILF)
 307     AC_DEFINE(HAVE_COSF)
 308     AC_DEFINE(HAVE_COSHF)
 309     AC_DEFINE(HAVE_EXPF)
 310     AC_DEFINE(HAVE_FABSF)
 311     AC_DEFINE(HAVE_FLOORF)
 312     AC_DEFINE(HAVE_FMODF)
 313     AC_DEFINE(HAVE_FREXPF)
 314     AC_DEFINE(HAVE_LDEXPF)
 315     AC_DEFINE(HAVE_LOG10F)
 316     AC_DEFINE(HAVE_LOGF)
 317     AC_DEFINE(HAVE_MODFF)
 318     AC_DEFINE(HAVE_POWF)
 319     AC_DEFINE(HAVE_SINF)
 320     AC_DEFINE(HAVE_SINHF)
 321     AC_DEFINE(HAVE_SQRTF)
 322     AC_DEFINE(HAVE_TANF)
 323     AC_DEFINE(HAVE_TANHF)
 324
 325     AC_DEFINE(HAVE_ICONV)
 326   else
 327     GLIBCXX_CROSSCONFIG
 328   fi
 329
 330   # At some point, we should differentiate between architectures
 331   # like x86, which have long double versions, and alpha/powerpc/etc.,
 332   # which don't. For the time being, punt.
 333   if test x"long_double_math_on_this_cpu" = x"yes"; then
 334     AC_DEFINE(HAVE_ACOSL)
 335     AC_DEFINE(HAVE_ASINL)
 336     AC_DEFINE(HAVE_ATAN2L)
 337     AC_DEFINE(HAVE_ATANL)
 338     AC_DEFINE(HAVE_CEILL)
 339     AC_DEFINE(HAVE_COSL)
 340     AC_DEFINE(HAVE_COSHL)
 341     AC_DEFINE(HAVE_EXPL)
 342     AC_DEFINE(HAVE_FABSL)
 343     AC_DEFINE(HAVE_FLOORL)
 344     AC_DEFINE(HAVE_FMODL)
 345     AC_DEFINE(HAVE_FREXPL)
 346     AC_DEFINE(HAVE_LDEXPL)
 347     AC_DEFINE(HAVE_LOG10L)
 348     AC_DEFINE(HAVE_LOGL)
 349     AC_DEFINE(HAVE_MODFL)
 350     AC_DEFINE(HAVE_POWL)
 351     AC_DEFINE(HAVE_SINCOSL)
 352     AC_DEFINE(HAVE_SINL)
 353     AC_DEFINE(HAVE_SINHL)
 354     AC_DEFINE(HAVE_SQRTL)
 355     AC_DEFINE(HAVE_TANL)
 356     AC_DEFINE(HAVE_TANHL)
 357   fi
 358 fi
 359
 360 # Check for _Unwind_GetIPInfo.
 361 GCC_CHECK_UNWIND_GETIPINFO
 362
 363 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 364
 365 GCC_HEADER_STDINT(include/gstdint.h)
 366
 367 GLIBCXX_ENABLE_SYMVERS([yes])
 368 AC_SUBST(libtool_VERSION)
 369
 370 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 371
 372 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 373 GLIBCXX_DEFAULT_ABI
 374
 375 ac_ldbl_compat=no
 376 case "$target" in
 377   powerpc*-*-linux* | \
 378   sparc*-*-linux* | \
 379   s390*-*-linux* | \
 380   alpha*-*-linux*)
 381   AC_TRY_COMPILE(, [
 382 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 383 #error no need for long double compatibility
 384 #endif
 385   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 386   if test "$ac_ldbl_compat" = yes; then
 387     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 388               [Define if compatibility should be provided for -mlong-double-64.])
 389     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 390   fi
 391 esac
 392 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 393
 394 # Check if assembler supports disabling hardware capability support.
 395 GLIBCXX_CHECK_ASSEMBLER_HWCAP
 396
 397 # Check if assembler supports rdrand opcode.
 398 GLIBCXX_CHECK_X86_RDRAND
 399
 400 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 401 GLIBCXX_CONFIGURE_TESTSUITE
 402
 403 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 404 GLIBCXX_CHECK_GTHREADS
 405
 406 # For Filesystem TS.
 407 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 408 GLIBCXX_ENABLE_FILESYSTEM_TS
 409 GLIBCXX_CHECK_FILESYSTEM_DEPS
 410
 411 # For Transactional Memory TS
 412 GLIBCXX_CHECK_SIZE_T_MANGLING
 413
 414 # Define documentation rules conditionally.
 415
 416 # See if makeinfo has been installed and is modern enough
 417 # that we can use it.
 418 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 419                    [GNU texinfo.* \([0-9][0-9.]*\)],
 420                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 421 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 422
 423 # Check for doxygen
 424 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 425 AC_CHECK_PROG([DOT], dot, yes, no)
 426
 427 # Check for docbook
 428 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 429 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 430 GLIBCXX_CONFIGURE_DOCBOOK
 431
 432 # Check for xml/html dependencies.
 433 AM_CONDITIONAL(BUILD_XML,
 434                test $ac_cv_prog_DOXYGEN = "yes" &&
 435                test $ac_cv_prog_DOT = "yes" &&
 436                test $ac_cv_prog_XSLTPROC = "yes" &&
 437                test $ac_cv_prog_XMLLINT = "yes" &&
 438                test $glibcxx_stylesheets = "yes")
 439
 440 AM_CONDITIONAL(BUILD_HTML,
 441                test $ac_cv_prog_DOXYGEN = "yes" &&
 442                test $ac_cv_prog_DOT = "yes" &&
 443                test $ac_cv_prog_XSLTPROC = "yes" &&
 444                test $ac_cv_prog_XMLLINT = "yes" &&
 445                test $glibcxx_stylesheets = "yes")
 446
 447 # Check for man dependencies.
 448 AM_CONDITIONAL(BUILD_MAN,
 449                test $ac_cv_prog_DOXYGEN = "yes" &&
 450                test $ac_cv_prog_DOT = "yes")
 451
 452 # Check for pdf dependencies.
 453 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 454 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 455 AM_CONDITIONAL(BUILD_PDF,
 456                test $ac_cv_prog_DBLATEX = "yes" &&
 457                test $ac_cv_prog_PDFLATEX = "yes")
 458
 459
 460 # Propagate the target-specific source directories through the build chain.
 461 ATOMICITY_SRCDIR=config/${atomicity_dir}
 462 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 463 ATOMIC_FLAGS=${atomic_flags}
 464 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 465 OS_INC_SRCDIR=config/${os_include_dir}
 466 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 467 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 468 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 469 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 470 AC_SUBST(ATOMICITY_SRCDIR)
 471 AC_SUBST(ATOMIC_WORD_SRCDIR)
 472 AC_SUBST(ATOMIC_FLAGS)
 473 AC_SUBST(CPU_DEFINES_SRCDIR)
 474 AC_SUBST(ABI_TWEAKS_SRCDIR)
 475 AC_SUBST(OS_INC_SRCDIR)
 476 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 477 AC_SUBST(CPU_OPT_EXT_RANDOM)
 478 AC_SUBST(CPU_OPT_BITS_RANDOM)
 479
 480
 481 # Determine cross-compile flags and AM_CONDITIONALs.
 482 #AC_SUBST(GLIBCXX_IS_NATIVE)
 483 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 484 GLIBCXX_EVALUATE_CONDITIONALS
 485
 486 AC_CACHE_SAVE
 487
 488 if test ${multilib} = yes; then
 489   multilib_arg="--enable-multilib"
 490 else
 491   multilib_arg=
 492 fi
 493
 494 # Export all the install information.
 495 GLIBCXX_EXPORT_INSTALL_INFO
 496
 497 # Export all the include and flag information to Makefiles.
 498 GLIBCXX_EXPORT_INCLUDES
 499 GLIBCXX_EXPORT_FLAGS
 500
 501 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 502 dnl which can all be called multiple times as needed, plus one (different)
 503 dnl AC_OUTPUT macro.  This one lists the files to be created:
 504 AC_CONFIG_FILES(Makefile)
 505 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 506 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 507 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 508
 509 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 510 # that multilib installs will end up installed in the correct place.
 511 # The testsuite needs it for multilib-aware ABI baseline files.
 512 # To work around this not being passed down from config-ml.in ->
 513 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 514 # append it here.  Only modify Makefiles that have just been created.
 515 #
 516 # Also, get rid of this simulated-VPATH thing that automake does.
 517 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 518   [cat > vpsed$$ << \_EOF
 519 s!`test -f '$<' || echo '$(srcdir)/'`!!
 520 _EOF
 521    sed -f vpsed$$ $ac_file > tmp$$
 522    mv tmp$$ $ac_file
 523    rm vpsed$$
 524    echo 'MULTISUBDIR =' >> $ac_file
 525    ml_norecursion=yes
 526    . ${multi_basedir}/config-ml.in
 527    AS_UNSET([ml_norecursion])
 528 ])
 529
 530 AC_CONFIG_COMMANDS([generate-headers],
 531   [(cd include && ${MAKE-make} pch_build= )])
 532
 533 dnl And this actually makes things happen:
 534 AC_OUTPUT