libstdc++-v3/acinclude.m4

   1 dnl
   2 dnl Initialize configure bits.
   3 dnl
   4 dnl GLIBCPP_CONFIGURE
   5 AC_DEFUN(GLIBCPP_CONFIGURE, [
   6   dnl Default to --enable-multilib
   7   AC_ARG_ENABLE(multilib,
   8   [  --enable-multilib       build hella library versions (default)],
   9   [case "${enableval}" in
  10     yes) multilib=yes ;;
  11     no)  multilib=no ;;
  12     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  13    esac], [multilib=yes])dnl
  14
  15 # When building with srcdir == objdir, links to the source files will
  16 # be created in directories within the target_subdir.  We have to
  17 # adjust toplevel_srcdir accordingly, so that configure finds
  18 # install-sh and other auxiliary files that live in the top-level
  19 # source directory.
  20 if test "${srcdir}" = "."; then
  21   if test -z "${with_target_subdir}"; then
  22     toprel=".."
  23   else
  24     if test "${with_target_subdir}" != "."; then
  25       toprel="${with_multisrctop}../.."
  26     else
  27       toprel="${with_multisrctop}.."
  28     fi
  29   fi
  30 else
  31   toprel=".."
  32 fi
  33 AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  34 toplevel_srcdir=\${top_srcdir}/$toprel
  35 AC_SUBST(toplevel_srcdir)
  36
  37 # Export build and source directories.
  38 # These need to be absolute paths, yet at the same time need to
  39 # canonicalize only relative paths, because then amd will not unmount
  40 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  41 glibcpp_builddir=`pwd`
  42 case $srcdir in
  43 [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  44 *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  45 esac
  46 AC_SUBST(glibcpp_builddir)
  47 AC_SUBST(glibcpp_srcdir)
  48
  49 dnl This is here just to satisfy automake.
  50 ifelse(not,equal,[AC_CONFIG_AUX_DIR(..)])
  51
  52 # Will set LN_S to either 'ln -s' or 'ln'.  With autoconf 2.50+, can also
  53 # be 'cp -p' if linking isn't available.
  54 #ac_cv_prog_LN_S='cp -p'
  55 AC_PROG_LN_S
  56
  57 # We use these options to decide which functions to include.
  58 AC_ARG_WITH(target-subdir,
  59 [  --with-target-subdir=SUBDIR
  60                            configuring in a subdirectory])
  61 AC_ARG_WITH(cross-host,
  62 [  --with-cross-host=HOST  configuring with a cross compiler])
  63
  64   glibcpp_basedir=$srcdir/$toprel/$1/libstdc++-v3
  65   AC_SUBST(glibcpp_basedir)
  66
  67   # Never versions of autoconf add an underscore to these functions.
  68   # Prevent future problems ...
  69   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  70   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  71   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  72   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  73
  74 #  AC_PROG_CC
  75
  76 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  77 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  78 # are probably using a cross compiler, which will not be able to fully
  79 # link an executable.  This should really be fixed in autoconf
  80 # itself.
  81
  82 AC_DEFUN(LIB_AC_PROG_CC,
  83 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  84 dnl Fool anybody using AC_PROG_CC.
  85 AC_PROVIDE([AC_PROG_CC])
  86 AC_CHECK_PROG(CC, gcc, gcc)
  87 if test -z "$CC"; then
  88   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  89   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  90 fi
  91
  92 AC_PROG_CC_GNU
  93
  94 if test $ac_cv_prog_gcc = yes; then
  95   GCC=yes
  96 dnl Check whether -g works, even if CFLAGS is set, in case the package
  97 dnl plays around with CFLAGS (such as to build both debugging and
  98 dnl normal versions of a library), tasteless as that idea is.
  99   ac_test_CFLAGS="${CFLAGS+set}"
 100   ac_save_CFLAGS="$CFLAGS"
 101   CFLAGS=
 102   AC_PROG_CC_G
 103   if test "$ac_test_CFLAGS" = set; then
 104     CFLAGS="$ac_save_CFLAGS"
 105   elif test $ac_cv_prog_cc_g = yes; then
 106     CFLAGS="-g -O2"
 107   else
 108     CFLAGS="-O2"
 109   fi
 110 else
 111   GCC=
 112   test "${CFLAGS+set}" = set || CFLAGS="-g"
 113 fi
 114 ])
 115
 116 LIB_AC_PROG_CC
 117
 118 # Can't just call these here as g++ requires libstc++ to be built....
 119 #  AC_PROG_CXX
 120
 121 # Likewise for AC_PROG_CXX.
 122 AC_DEFUN(LIB_AC_PROG_CXX,
 123 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 124 dnl Fool anybody using AC_PROG_CXX.
 125 AC_PROVIDE([AC_PROG_CXX])
 126 # Use glibcpp_CXX so that we do not cause CXX to be cached with the
 127 # flags that come in CXX while configuring libstdc++.  They're different
 128 # from those used for all other target libraries.  If CXX is set in
 129 # the environment, respect that here.
 130 glibcpp_CXX=$CXX
 131 AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
 132 AC_SUBST(glibcpp_CXX)
 133 CXX=$glibcpp_CXX
 134 test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 135
 136 AC_PROG_CXX_GNU
 137
 138 if test $ac_cv_prog_gxx = yes; then
 139   GXX=yes
 140 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 141 dnl plays around with CXXFLAGS (such as to build both debugging and
 142 dnl normal versions of a library), tasteless as that idea is.
 143   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 144   ac_save_CXXFLAGS="$CXXFLAGS"
 145   CXXFLAGS=
 146   AC_PROG_CXX_G
 147   if test "$ac_test_CXXFLAGS" = set; then
 148     CXXFLAGS="$ac_save_CXXFLAGS"
 149   elif test $ac_cv_prog_cxx_g = yes; then
 150     CXXFLAGS="-g -O2"
 151   else
 152     CXXFLAGS="-O2"
 153   fi
 154 else
 155   GXX=
 156   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 157 fi
 158 ])
 159
 160 LIB_AC_PROG_CXX
 161
 162    # For some reason, gettext needs this.
 163    AC_ISC_POSIX
 164
 165   AC_CHECK_TOOL(AS, as)
 166   AC_CHECK_TOOL(AR, ar)
 167   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 168   AC_PROG_INSTALL
 169
 170   AM_MAINTAINER_MODE
 171
 172   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 173   # at least currently, we never actually build a program, so we never
 174   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 175   # fails, because we are probably configuring with a cross compiler
 176   # which can't create executables.  So we include AC_EXEEXT to keep
 177   # automake happy, but we don't execute it, since we don't care about
 178   # the result.
 179   if false; then
 180     # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
 181     # to nothing, so nothing would remain between `then' and `fi' if it
 182     # were not for the `:' below.
 183     :
 184     AC_EXEEXT
 185   fi
 186
 187   . [$]{glibcpp_basedir}/configure.host
 188
 189   case [$]{glibcpp_basedir} in
 190     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 191     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 192   esac
 193
 194   # This does for the target what configure.host does for the host.  In
 195   # addition to possibly modifying the same flags, it also sets up symlinks.
 196   GLIBCPP_CHECK_TARGET
 197
 198   #
 199 ])
 200
 201
 202 dnl
 203 dnl Check to see if g++ can compile this library, and if so, if any version-
 204 dnl specific precautions need to be taken.
 205 dnl
 206 dnl GLIBCPP_CHECK_COMPILER_VERSION
 207 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 208 if test ! -f stamp-sanity-compiler; then
 209   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 210   AC_LANG_SAVE
 211   AC_LANG_CPLUSPLUS
 212   AC_TRY_COMPILE(, [
 213   #if __GNUC__ < 3
 214     not_ok
 215   #endif
 216   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 217   AC_LANG_RESTORE
 218   AC_MSG_RESULT($gpp_satisfactory)
 219   touch stamp-sanity-compiler
 220 fi
 221 ])
 222
 223
 224 dnl
 225 dnl Tests for newer compiler features, or features that are present in newer
 226 dnl compiler versions but not older compiler versions still in use, should
 227 dnl be placed here.
 228 dnl
 229 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 230 dnl new inlining code or the new system_header pragma will die on -Werror.
 231 dnl Leave it out by default and use maint-mode to use it.
 232 dnl
 233 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 234 dnl compiler supports it and the user has not requested debug mode.
 235 dnl
 236 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 237 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 238   # All these tests are for C++; save the language and the compiler flags.
 239   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 240   # found in GLIBCPP_CONFIGURE.
 241   AC_LANG_SAVE
 242   AC_LANG_CPLUSPLUS
 243   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 244   ac_save_CXXFLAGS="$CXXFLAGS"
 245
 246   # Check for maintainer-mode bits.
 247   if test x"$USE_MAINTAINER_MODE" = xno; then
 248     WERROR=''
 249   else
 250     WERROR='-Werror'
 251   fi
 252
 253   # Check for -ffunction-sections -fdata-sections
 254   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 255   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 256   AC_TRY_COMPILE(, [int foo;
 257   ], [ac_fdsections=yes], [ac_fdsections=no])
 258   if test "$ac_test_CXXFLAGS" = set; then
 259     CXXFLAGS="$ac_save_CXXFLAGS"
 260   else
 261     # this is the suspicious part
 262     CXXFLAGS=''
 263   fi
 264   if test x"$ac_fdsections" = x"yes" &&
 265      test x"$enable_debug" = x"no"; then
 266     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 267   fi
 268   AC_MSG_RESULT($ac_fdsections)
 269
 270   AC_LANG_RESTORE
 271   AC_SUBST(WERROR)
 272   AC_SUBST(SECTION_FLAGS)
 273 ])
 274
 275
 276 dnl
 277 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 278 dnl the native linker is in use, all variables will be defined to something
 279 dnl safe (like an empty string).
 280 dnl
 281 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 282 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 283 dnl
 284 dnl GLIBCPP_CHECK_LINKER_FEATURES
 285 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 286   # If we're not using GNU ld, then there's no point in even trying these
 287   # tests.  Check for that first.  We should have already tested for gld
 288   # by now (in libtool), but require it now just to be safe...
 289   SECTION_LDFLAGS=''
 290   OPT_LDFLAGS=''
 291   AC_REQUIRE([AC_PROG_LD])
 292
 293   # Set --gc-sections.
 294   if test "$ac_cv_prog_gnu_ld" = "notbroken"; then
 295     # GNU ld it is!  Joy and bunny rabbits!
 296
 297     # All these tests are for C++; save the language and the compiler flags.
 298     # Need to do this so that g++ won't try to link in libstdc++
 299     ac_test_CFLAGS="${CFLAGS+set}"
 300     ac_save_CFLAGS="$CFLAGS"
 301     CFLAGS='-x c++  -Wl,--gc-sections'
 302
 303     # Check for -Wl,--gc-sections
 304     # XXX This test is broken at the moment, as symbols required for
 305     # linking are now in libsupc++ (not built yet.....). In addition,
 306     # this test has cored on solaris in the past. In addition,
 307     # --gc-sections doesn't really work at the moment (keeps on discarding
 308     # used sections, first .eh_frame and now some of the glibc sections for
 309     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 310     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 311     AC_TRY_RUN([
 312      int main(void)
 313      {
 314        try { throw 1; }
 315        catch (...) { };
 316        return 0;
 317      }
 318     ], [ac_sectionLDflags=yes],[ac_sectionLFflags=no], [ac_sectionLDflags=yes])
 319     if test "$ac_test_CFLAGS" = set; then
 320       CFLAGS="$ac_save_CFLAGS"
 321     else
 322       # this is the suspicious part
 323       CFLAGS=''
 324     fi
 325     if test "$ac_sectionLDflags" = "yes"; then
 326       SECTION_LDFLAGS='-Wl,--gc-sections'
 327     fi
 328     AC_MSG_RESULT($ac_sectionLDflags)
 329   fi
 330
 331   # Set linker optimization flags.
 332   if test x"$ac_cv_prog_gnu_ld" = x"yes" &&
 333      test x"$enable_debug" = x"no"; then
 334     OPT_LDFLAGS='-Wl,-O1'
 335   fi
 336
 337   AC_SUBST(SECTION_LDFLAGS)
 338   AC_SUBST(OPT_LDFLAGS)
 339 ])
 340
 341
 342 dnl
 343 dnl Check to see if the (math function) argument passed is
 344 dnl declared when using the c++ compiler
 345 dnl ASSUMES argument is a math function with ONE parameter
 346 dnl
 347 dnl GLIBCPP_CHECK_MATH_DECL_1
 348 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 349   AC_MSG_CHECKING([for $1 declaration])
 350   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 351     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 352       AC_LANG_SAVE
 353       AC_LANG_CPLUSPLUS
 354       AC_TRY_COMPILE([#include <math.h>
 355                       #ifdef HAVE_IEEEFP_H
 356                       #include <ieeefp.h>
 357                       #endif
 358                      ],
 359                      [ $1(0);],
 360                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 361       AC_LANG_RESTORE
 362     ])
 363   fi
 364   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 365 ])
 366
 367 dnl
 368 dnl Check to see if the (math function) argument passed is
 369 dnl 1) declared when using the c++ compiler
 370 dnl 2) has "C" linkage
 371 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 372 dnl
 373 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 374 dnl
 375 dnl argument 1 is name of function to check
 376 dnl
 377 dnl ASSUMES argument is a math function with ONE parameter
 378 dnl
 379 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 380 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 381   GLIBCPP_CHECK_MATH_DECL_1($1)
 382   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 383     AC_CHECK_FUNCS($1)
 384   else
 385     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 386     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 387       AC_CHECK_FUNCS(_$1)
 388     fi
 389   fi
 390 ])
 391
 392
 393 dnl
 394 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 395 dnl of functions at once.  It's an all-or-nothing check -- either
 396 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 397 dnl Doing it this way saves significant configure time.
 398 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 399   AC_MSG_CHECKING([for $1 functions])
 400   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 401     AC_LANG_SAVE
 402     AC_LANG_CPLUSPLUS
 403     AC_TRY_COMPILE([#include <math.h>],
 404                    [ `for x in $3; do echo "$x (0);"; done` ],
 405                    [glibcpp_cv_func_$2_use=yes],
 406                    [glibcpp_cv_func_$2_use=no])
 407     AC_LANG_RESTORE])
 408   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 409   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 410     AC_CHECK_FUNCS($3)
 411   fi
 412 ])
 413
 414 dnl
 415 dnl Check to see if the (math function) argument passed is
 416 dnl declared when using the c++ compiler
 417 dnl ASSUMES argument is a math function with TWO parameters
 418 dnl
 419 dnl GLIBCPP_CHECK_MATH_DECL_2
 420 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 421   AC_MSG_CHECKING([for $1 declaration])
 422   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 423     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 424       AC_LANG_SAVE
 425       AC_LANG_CPLUSPLUS
 426       AC_TRY_COMPILE([#include <math.h>],
 427                      [ $1(0, 0);],
 428                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 429       AC_LANG_RESTORE
 430     ])
 431   fi
 432   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 433 ])
 434
 435 dnl
 436 dnl Check to see if the (math function) argument passed is
 437 dnl 1) declared when using the c++ compiler
 438 dnl 2) has "C" linkage
 439 dnl
 440 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 441 dnl
 442 dnl argument 1 is name of function to check
 443 dnl
 444 dnl ASSUMES argument is a math function with TWO parameters
 445 dnl
 446 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 447 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 448   GLIBCPP_CHECK_MATH_DECL_2($1)
 449   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 450     AC_CHECK_FUNCS($1)
 451   else
 452     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 453     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 454       AC_CHECK_FUNCS(_$1)
 455     fi
 456   fi
 457 ])
 458
 459
 460 dnl
 461 dnl Check to see if the (math function) argument passed is
 462 dnl declared when using the c++ compiler
 463 dnl ASSUMES argument is a math function with THREE parameters
 464 dnl
 465 dnl GLIBCPP_CHECK_MATH_DECL_3
 466 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 467   AC_MSG_CHECKING([for $1 declaration])
 468   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 469     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 470       AC_LANG_SAVE
 471       AC_LANG_CPLUSPLUS
 472       AC_TRY_COMPILE([#include <math.h>],
 473                      [ $1(0, 0, 0);],
 474                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 475       AC_LANG_RESTORE
 476     ])
 477   fi
 478   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 479 ])
 480
 481 dnl
 482 dnl Check to see if the (math function) argument passed is
 483 dnl 1) declared when using the c++ compiler
 484 dnl 2) has "C" linkage
 485 dnl
 486 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 487 dnl
 488 dnl argument 1 is name of function to check
 489 dnl
 490 dnl ASSUMES argument is a math function with THREE parameters
 491 dnl
 492 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 493 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 494   GLIBCPP_CHECK_MATH_DECL_3($1)
 495   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 496     AC_CHECK_FUNCS($1)
 497   else
 498     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 499     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 500       AC_CHECK_FUNCS(_$1)
 501     fi
 502   fi
 503 ])
 504
 505
 506 dnl
 507 dnl Check to see if the (stdlib function) argument passed is
 508 dnl 1) declared when using the c++ compiler
 509 dnl 2) has "C" linkage
 510 dnl
 511 dnl argument 1 is name of function to check
 512 dnl
 513 dnl ASSUMES argument is a math function with TWO parameters
 514 dnl
 515 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 516 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 517   AC_MSG_CHECKING([for $1 declaration])
 518   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 519     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 520       AC_LANG_SAVE
 521       AC_LANG_CPLUSPLUS
 522       AC_TRY_COMPILE([#include <stdlib.h>],
 523                      [ $1(0, 0);],
 524                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 525       AC_LANG_RESTORE
 526     ])
 527   fi
 528   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 529   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 530     AC_CHECK_FUNCS($1)
 531   fi
 532 ])
 533
 534
 535 dnl
 536 dnl Because the builtins are picky picky picky about the arguments they take,
 537 dnl do an explict linkage tests here.
 538 dnl Check to see if the (math function) argument passed is
 539 dnl 1) declared when using the c++ compiler
 540 dnl 2) has "C" linkage
 541 dnl
 542 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 543 dnl
 544 dnl argument 1 is name of function to check
 545 dnl
 546 dnl ASSUMES argument is a math function with ONE parameter
 547 dnl
 548 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 549 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 550   AC_MSG_CHECKING([for $1 declaration])
 551   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 552     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 553       AC_LANG_SAVE
 554       AC_LANG_CPLUSPLUS
 555       AC_TRY_COMPILE([#include <math.h>],
 556                      [ $1(0);],
 557                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 558       AC_LANG_RESTORE
 559     ])
 560   fi
 561   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 562   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 563     AC_MSG_CHECKING([for $1 linkage])
 564     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 565       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 566         AC_TRY_LINK([#include <math.h>],
 567                     [ $1(0);],
 568                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 569       ])
 570     fi
 571     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 572     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 573       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 574       AC_DEFINE_UNQUOTED(${ac_tr_func})
 575     fi
 576   fi
 577 ])
 578
 579
 580 dnl
 581 dnl Check to see what builtin math functions are supported
 582 dnl
 583 dnl check for __builtin_abs
 584 dnl check for __builtin_fabsf
 585 dnl check for __builtin_fabs
 586 dnl check for __builtin_fabl
 587 dnl check for __builtin_labs
 588 dnl check for __builtin_sqrtf
 589 dnl check for __builtin_sqrtl
 590 dnl check for __builtin_sqrt
 591 dnl check for __builtin_sinf
 592 dnl check for __builtin_sin
 593 dnl check for __builtin_sinl
 594 dnl check for __builtin_cosf
 595 dnl check for __builtin_cos
 596 dnl check for __builtin_cosl
 597 dnl
 598 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 599 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 600   dnl Test for builtin math functions.
 601   dnl These are made in gcc/c-common.c
 602   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 603   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 604   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 605   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 606   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 607
 608   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 609   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrt)
 610   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 611
 612   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 613   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 614   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 615
 616   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 617   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 618   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 619
 620   dnl There is, without a doubt, a more elegant way to have these
 621   dnl names exported so that they won't be stripped out of acconfig.h by
 622   dnl autoheader. I leave this as an exercise to somebody less frustrated
 623   dnl than I.... please email the libstdc++ list if you can figure out a
 624   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 625   dnl AC_CHECK_FUNC for things to steal.)
 626   dummyvar=no
 627   if test x$dummyvar = x"yes"; then
 628     AC_DEFINE(HAVE___BUILTIN_ABS)
 629     AC_DEFINE(HAVE___BUILTIN_LABS)
 630     AC_DEFINE(HAVE___BUILTIN_COS)
 631     AC_DEFINE(HAVE___BUILTIN_COSF)
 632     AC_DEFINE(HAVE___BUILTIN_COSL)
 633     AC_DEFINE(HAVE___BUILTIN_FABS)
 634     AC_DEFINE(HAVE___BUILTIN_FABSF)
 635     AC_DEFINE(HAVE___BUILTIN_FABSL)
 636     AC_DEFINE(HAVE___BUILTIN_SIN)
 637     AC_DEFINE(HAVE___BUILTIN_SINF)
 638     AC_DEFINE(HAVE___BUILTIN_SINL)
 639     AC_DEFINE(HAVE___BUILTIN_SQRT)
 640     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 641     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 642   fi
 643 ])
 644
 645
 646 dnl
 647 dnl Check to see what the underlying c library
 648 dnl These checks need to do two things:
 649 dnl 1) make sure the name is declared when using the c++ compiler
 650 dnl 2) make sure the name has "C" linkage
 651 dnl This might seem like overkill but experience has shown that it's not...
 652 dnl
 653 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 654 dnl Define HAVE_STRTOF if "strtof" is declared and links
 655 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 656 dnl
 657 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 658 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 659   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 660   ac_save_CXXFLAGS="$CXXFLAGS"
 661   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 662
 663   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 664   AC_CHECK_FUNCS(drand48)
 665
 666   CXXFLAGS="$ac_save_CXXFLAGS"
 667 ])
 668
 669
 670 dnl
 671 dnl Check to see what the underlying c library or math library is like.
 672 dnl These checks need to do two things:
 673 dnl 1) make sure the name is declared when using the c++ compiler
 674 dnl 2) make sure the name has "C" linkage
 675 dnl This might seem like overkill but experience has shown that it's not...
 676 dnl
 677 dnl Define HAVE_CARGF etc if "cargf" is found.
 678 dnl
 679 dnl GLIBCPP_CHECK_MATH_SUPPORT
 680 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 681   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 682   ac_save_CXXFLAGS="$CXXFLAGS"
 683   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 684
 685   dnl Check libm
 686   AC_CHECK_LIB(m, sin, libm="-lm")
 687   ac_save_LIBS="$LIBS"
 688   LIBS="$LIBS $libm"
 689
 690   dnl Check to see if certain C math functions exist.
 691   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 692   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 693   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 694   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 695   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 696   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 697   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 698   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypot)
 699
 700   dnl Check to see if basic C math functions have float versions.
 701   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 702                                           float_trig,
 703                                           acosf asinf atanf \
 704                                           cosf sinf tanf \
 705                                           coshf sinhf tanhf)
 706   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 707                                           float_round,
 708                                           ceilf floorf)
 709   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 710   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 711   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 712   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 713   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 714   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 715   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotf)
 716   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 717   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 718   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 719   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 720   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 721   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 722   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 723   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 724
 725   dnl Check to see if basic C math functions have long double versions.
 726   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 727                                           long_double_trig,
 728                                           acosl asinl atanl \
 729                                           cosl sinl tanl \
 730                                           coshl sinhl tanhl)
 731   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 732                                           long_double_round,
 733                                           ceill floorl)
 734   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 735   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 736   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 737   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 738   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 739   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 740   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 741   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 742   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotl)
 743   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 744   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 745   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 746   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 747   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 748   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 749   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 750   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 751
 752   dnl Some runtimes have these functions with a preceding underscore. Please
 753   dnl keep this sync'd with the one above. And if you add any new symbol,
 754   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 755   dnl Check to see if certain C math functions exist.
 756
 757   dnl Check to see if basic C math functions have float versions.
 758   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 759                                           _float_trig,
 760                                           _acosf _asinf _atanf \
 761                                           _cosf _sinf _tanf \
 762                                           _coshf _sinhf _tanhf)
 763   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 764                                           _float_round,
 765                                           _ceilf _floorf)
 766
 767   dnl Check to see if basic C math functions have long double versions.
 768   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 769                                           _long_double_trig,
 770                                           _acosl _asinl _atanl \
 771                                           _cosl _sinl _tanl \
 772                                           _coshl _sinhl _tanhl)
 773   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 774                                           _long_double_round,
 775                                           _ceill _floorl)
 776
 777   LIBS="$ac_save_LIBS"
 778   CXXFLAGS="$ac_save_CXXFLAGS"
 779 ])
 780
 781
 782 dnl
 783 dnl Check to see if there is native support for complex
 784 dnl
 785 dnl Don't compile bits in math/* if native support exits.
 786 dnl
 787 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "copysignl" is found.
 788 dnl
 789 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 790 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 791   dnl Check for complex versions of math functions of platform.
 792   AC_CHECK_LIB(m, main)
 793   AC_REPLACE_MATHFUNCS(nan copysignf)
 794
 795   dnl Compile the long double complex functions only if the function
 796   dnl provides the non-complex long double functions that are needed.
 797   dnl Currently this includes copysignl, which should be
 798   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 799   USE_COMPLEX_LONG_DOUBLE=no
 800   if test x$ac_cv_func_copysignl = x"yes"; then
 801     USE_COMPLEX_LONG_DOUBLE=yes
 802     AC_REPLACE_MATHFUNCS(signbitl)
 803   fi
 804
 805   AC_SUBST(USE_COMPLEX_LONG_DOUBLE)
 806 ])
 807
 808
 809 dnl Check to see what architecture and operating system we are compiling
 810 dnl for.  Also, if architecture- or OS-specific flags are required for
 811 dnl compilation, pick them up here.
 812 dnl
 813 dnl GLIBCPP_CHECK_TARGET
 814 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 815     . [$]{glibcpp_basedir}/configure.target
 816     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 817     AC_MSG_RESULT(OS config directory is $os_include_dir)
 818 ])
 819
 820
 821 dnl
 822 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 823 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 824 dnl must have been previously checked.)
 825 dnl
 826 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 827 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 828 dnl
 829 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 830 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 831
 832   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 833   dnl others even if wchar_t support is not on.
 834   AC_MSG_CHECKING([for mbstate_t])
 835   AC_TRY_COMPILE([#include <wchar.h>],
 836   [mbstate_t teststate;],
 837   have_mbstate_t=yes, have_mbstate_t=no)
 838   AC_MSG_RESULT($have_mbstate_t)
 839   if test x"$have_mbstate_t" = xyes; then
 840     AC_DEFINE(HAVE_MBSTATE_T)
 841   fi
 842
 843   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 844   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 845   AC_CHECK_HEADER(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 846
 847   dnl Only continue checking if the ISO C99 headers exist and support is on.
 848   if test x"$ac_has_wchar_h" = xyes &&
 849      test x"$ac_has_wctype_h" = xyes &&
 850      test x"$enable_c_mbchar" != xno; then
 851
 852     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 853     dnl numeric_limits can instantiate type_traits<wchar_t>
 854     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 855     AC_TRY_COMPILE([#include <wchar.h>],
 856     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 857     has_wchar_minmax=yes, has_wchar_minmax=no)
 858     AC_MSG_RESULT($has_wchar_minmax)
 859
 860     dnl Test wchar.h for WEOF, which is what we use to determine whether
 861     dnl to specialize for char_traits<wchar_t> or not.
 862     AC_MSG_CHECKING([for WEOF])
 863     AC_TRY_COMPILE([
 864       #include <wchar.h>
 865       #include <stddef.h>],
 866     [wint_t i = WEOF;],
 867     has_weof=yes, has_weof=no)
 868     AC_MSG_RESULT($has_weof)
 869
 870     dnl Tests for wide character functions used in char_traits<wchar_t>.
 871     ac_wfuncs=yes
 872     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset,, \
 873     ac_wfuncs=no)
 874
 875     dnl Checks for names injected into std:: by the c_std headers.
 876     AC_CHECK_FUNCS(btowc wctob fgetwc fgetwc fgetws fputwc fputws fwide \
 877     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 878     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 879     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 880     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 881     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr,, \
 882     ac_wfuncs=no)
 883
 884     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 885     if test x"$has_weof" = xyes &&
 886        test x"$has_wchar_minmax" = xyes &&
 887        test x"$ac_wfuncs" = xyes; then
 888       ac_isoC99_wchar_t=yes
 889     else
 890       ac_isoC99_wchar_t=no
 891     fi
 892     AC_MSG_RESULT($ac_isoC99_wchar_t)
 893
 894     dnl Use iconv for wchar_t to char conversions. As such, check for
 895     dnl X/Open Portability Guide, version 2 features (XPG2).
 896     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 897     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 898
 899     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 900     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 901     ac_save_LIBS="$LIBS"
 902     LIBS="$LIBS $libiconv"
 903
 904     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 905     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 906
 907     LIBS="$ac_save_LIBS"
 908
 909     AC_MSG_CHECKING([for XPG2 wchar_t support])
 910     if test x"$ac_has_iconv_h" = xyes &&
 911        test x"$ac_has_langinfo_h" = xyes &&
 912        test x"$ac_XPG2funcs" = xyes; then
 913       ac_XPG2_wchar_t=yes
 914     else
 915       ac_XPG2_wchar_t=no
 916     fi
 917     AC_MSG_RESULT($ac_XPG2_wchar_t)
 918
 919     dnl At the moment, only enable wchar_t specializations if all the
 920     dnl above support is present.
 921     AC_MSG_CHECKING([for enabled wchar_t specializations])
 922     if test x"$ac_isoC99_wchar_t" = xyes &&
 923        test x"$ac_XPG2_wchar_t" = xyes; then
 924       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
 925       AC_MSG_RESULT("yes")
 926     else
 927       AC_MSG_RESULT("no")
 928     fi
 929   else
 930     dnl Wide characters disabled by the user.
 931     AC_MSG_WARN([wchar_t support disabled.])
 932   fi
 933 ])
 934
 935
 936 dnl
 937 dnl Check for special debugging mode; not for production use.
 938 dnl
 939 dnl GLIBCPP_ENABLE_DEBUG
 940 dnl --enable-debug sets '-ggdb3 -O0'.
 941 dnl --disable-debug sets '-g' and whatever optimization options the
 942 dnl     compiler can handle.
 943 dnl  +  --enable-maintainer-mode automatically defaults this to on.
 944 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
 945 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
 946 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
 947 dnl       defaults to `no'.
 948 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
 949 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
 950 AC_ARG_ENABLE(debug,
 951 changequote(<<, >>)dnl
 952 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
 953 changequote([, ])dnl
 954 [case "${enableval}" in
 955  yes) enable_debug=yes ;;
 956  no)  enable_debug=no ;;
 957  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
 958  esac],
 959 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
 960
 961 dnl Option parsed, now set things appropriately
 962 case "${enable_debug}" in
 963     yes)
 964         DEBUG_FLAGS='-O0 -ggdb3'
 965         ;;
 966     no)
 967         DEBUG_FLAGS='-g'
 968         ;;
 969 esac
 970 AC_SUBST(DEBUG_FLAGS)
 971 ])
 972
 973
 974 dnl
 975 dnl Check for "unusual" flags to pass to the compiler while building.
 976 dnl
 977 dnl GLIBCPP_ENABLE_CXX_FLAGS
 978 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
 979 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
 980 dnl     Somehow this same set of flags must be passed when [re]building
 981 dnl     libgcc.
 982 dnl --disable-cxx-flags passes nothing.
 983 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
 984 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
 985 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
 986 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
 987 dnl       If "default flags" is an empty string (or "none"), the effect is
 988 dnl       the same as --disable or --enable=no.
 989 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
 990 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
 991 AC_ARG_ENABLE(cxx-flags,
 992 changequote(<<, >>)dnl
 993 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
 994                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
 995 changequote([, ])dnl
 996 [case "x$enableval" in
 997  xyes)
 998         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
 999  xno|x)
1000         enable_cxx_flags='' ;;
1001  *)
1002         enable_cxx_flags="$enableval" ;;
1003  esac],
1004 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
1005
1006 dnl Thinko on my part during design.  This kludge is the workaround.
1007 if test "$enable_cxx_flags" = "none"; then
1008   enable_cxx_flags='';
1009 fi
1010
1011 dnl Run through flags (either default or command-line) and set anything
1012 dnl extra (e.g., #defines) that must accompany particular g++ options.
1013 if test -n "$enable_cxx_flags"; then
1014     for f in $enable_cxx_flags; do
1015         case "$f" in
1016             -fhonor-std)  ;;
1017             -*)  ;;
1018             *)   # and we're trying to pass /what/ exactly?
1019                  AC_MSG_ERROR([compiler flags start with a -]) ;;
1020         esac
1021     done
1022 fi
1023 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1024 AC_SUBST(EXTRA_CXX_FLAGS)
1025 ])
1026
1027
1028 dnl
1029 dnl Check for which locale library to use:  gnu or generic.
1030 dnl
1031 dnl GLIBCPP_ENABLE_CLOCALE
1032 dnl --enable-clocale=gnu sets config/locale/c_locale_gnu.cc and friends
1033 dnl --enable-clocale=generic sets config/locale/c_locale_generic.cc and friends
1034 dnl
1035 dnl default is generic
1036 dnl
1037 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
1038   AC_MSG_CHECKING([for clocale to use])
1039   AC_ARG_ENABLE(clocale,
1040   [  --enable-clocale        enable model for target locale package.
1041   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
1042   ],
1043   if test x$enable_clocale = xno; then
1044      enable_clocale=no
1045   fi,
1046      enable_clocale=no)
1047
1048   enable_clocale_flag=$enable_clocale
1049
1050   dnl Probe for locale support if no specific model is specified.
1051   dnl Default to "generic"
1052   if test x$enable_clocale_flag = xno; then
1053     case x${target_os} in
1054       xlinux* | xgnu*)
1055         AC_EGREP_CPP([ok], [
1056         #include <features.h>
1057         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1058           ok
1059         #endif
1060         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1061         ;;
1062       *)
1063         enable_clocale_flag=generic
1064         ;;
1065     esac
1066   fi
1067
1068   dnl Set configure bits for specified locale package
1069   case x${enable_clocale_flag} in
1070     xgeneric)
1071       AC_MSG_RESULT(generic)
1072
1073       # Don't use gettext.
1074       USE_NLS=no
1075
1076       CLOCALE_H=config/locale/c_locale_generic.h
1077       CLOCALE_CC=config/locale/c_locale_generic.cc
1078       CCODECVT_H=config/locale/codecvt_specializations_generic.h
1079       CCOLLATE_CC=config/locale/collate_members_generic.cc
1080       CCTYPE_CC=config/locale/ctype_members_generic.cc
1081       CMESSAGES_H=config/locale/messages_members_generic.h
1082       CMESSAGES_CC=config/locale/messages_members_generic.cc
1083       CMONEY_CC=config/locale/moneypunct_members_generic.cc
1084       CNUMERIC_CC=config/locale/numpunct_members_generic.cc
1085       CTIME_CC=config/locale/time_members_generic.cc
1086       ;;
1087     xgnu)
1088       AC_MSG_RESULT(gnu)
1089
1090       # Declare intention to use gettext, and add support for specific
1091       # languages.
1092       # For some reason, ALL_LINGUAS has to be before AM_GNU_GETTEXT
1093       ALL_LINGUAS="de fr"
1094       # Don't call AM_GNU_GETTEXT here. Instead, assume glibc.
1095       # Need to deal with MSGFMT, USE_NLS, and glibcpp_[P,M]OFILES
1096       USE_NLS=yes
1097
1098       # Export the build objects.
1099       for ling in $ALL_LINGUAS; do \
1100         glibcpp_MOFILES="$glibcpp_MOFILES $ling.mo"; \
1101         glibcpp_POFILES="$glibcpp_POFILES $ling.po"; \
1102       done
1103       AC_SUBST(glibcpp_MOFILES)
1104       AC_SUBST(glibcpp_POFILES)
1105
1106       CLOCALE_H=config/locale/c_locale_gnu.h
1107       CLOCALE_CC=config/locale/c_locale_gnu.cc
1108       CCODECVT_H=config/locale/codecvt_specializations_ieee_1003.1-200x.h
1109       CCOLLATE_CC=config/locale/collate_members_gnu.cc
1110       CCTYPE_CC=config/locale/ctype_members_gnu.cc
1111       CMESSAGES_H=config/locale/messages_members_gnu.h
1112       CMESSAGES_CC=config/locale/messages_members_gnu.cc
1113       CMONEY_CC=config/locale/moneypunct_members_gnu.cc
1114       CNUMERIC_CC=config/locale/numpunct_members_gnu.cc
1115       CTIME_CC=config/locale/time_members_gnu.cc
1116       ;;
1117     xieee_1003.1)
1118       AC_MSG_RESULT(generic)
1119
1120       # Don't use gettext.
1121       USE_NLS=no
1122
1123       CLOCALE_H=config/locale/c_locale_ieee_1003.1-200x.h
1124       CLOCALE_CC=config/locale/c_locale_ieee_1003.1-200x.cc
1125       CCODECVT_H=config/locale/codecvt_specializations_ieee_1003.1-200x.h
1126       CCOLLATE_CC=config/locale/collate_members_generic.cc
1127       CCTYPE_CC=config/locale/ctype_members_generic.cc
1128       CMESSAGES_H=config/locale/messages_members_ieee_1003.1-200x.h
1129       CMESSAGES_CC=config/locale/messages_members_ieee_1003.1-200x.cc
1130       CMONEY_CC=config/locale/moneypunct_members_generic.cc
1131       CNUMERIC_CC=config/locale/numpunct_members_generic.cc
1132       CTIME_CC=config/locale/time_members_generic.cc
1133       ;;
1134     *)
1135       echo "$enable_clocale is an unknown locale package" 1>&2
1136       exit 1
1137       ;;
1138   esac
1139
1140   # This is where the testsuite looks for locale catalogs, using the
1141   # -DLOCALEDIR define during testsuite compilation.
1142   glibcpp_localedir=${glibcpp_builddir}/po/share/locale
1143   AC_SUBST(glibcpp_localedir)
1144
1145   AC_SUBST(USE_NLS)
1146   AC_SUBST(CLOCALE_H)
1147   AC_SUBST(CCODECVT_H)
1148   AC_SUBST(CMESSAGES_H)
1149   AC_LINK_FILES($CLOCALE_CC, src/c++locale.cc)
1150   AC_LINK_FILES($CCOLLATE_CC, src/collate.cc)
1151   AC_LINK_FILES($CCTYPE_CC, src/ctype.cc)
1152   AC_LINK_FILES($CMESSAGES_CC, src/messages.cc)
1153   AC_LINK_FILES($CMONEY_CC, src/moneypunct.cc)
1154   AC_LINK_FILES($CNUMERIC_CC, src/numpunct.cc)
1155   AC_LINK_FILES($CTIME_CC, src/time.cc)
1156 ])
1157
1158
1159 dnl
1160 dnl Check for which I/O library to use:  libio, or something specific.
1161 dnl
1162 dnl GLIBCPP_ENABLE_CSTDIO
1163 dnl --enable-cstdio=libio sets config/io/c_io_libio.h and friends
1164 dnl
1165 dnl default is stdio
1166 dnl
1167 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1168   AC_MSG_CHECKING([for cstdio to use])
1169   AC_ARG_ENABLE(cstdio,
1170   [  --enable-cstdio         enable stdio for target io package.
1171   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1172   ],
1173   if test x$enable_cstdio = xno; then
1174      enable_cstdio=stdio
1175   fi,
1176      enable_cstdio=stdio)
1177
1178   enable_cstdio_flag=$enable_cstdio
1179
1180   dnl Check if a valid I/O package
1181   case x${enable_cstdio_flag} in
1182     xlibio)
1183       CSTDIO_H=config/io/c_io_libio.h
1184       BASIC_FILE_H=config/io/basic_file_libio.h
1185       BASIC_FILE_CC=config/io/basic_file_libio.cc
1186       AC_MSG_RESULT(libio)
1187
1188       # see if we are on a system with libio native (ie, linux)
1189       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1190
1191       # Need to check and see what version of glibc is being used. If
1192       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1193       # compile most of libio for linux systems.
1194       if test x$has_libio = x"yes"; then
1195         case "$target" in
1196           *-*-linux*)
1197               AC_MSG_CHECKING([for glibc version >= 2.2])
1198               AC_EGREP_CPP([ok], [
1199             #include <features.h>
1200               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1201                     ok
1202               #endif
1203               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1204               AC_MSG_RESULT($glibc_satisfactory)
1205             ;;
1206         esac
1207
1208         # XXX at the moment, admit defeat and force the recompilation
1209         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1210         glibc_satisfactory=no
1211
1212         if test x$glibc_satisfactory = x"yes"; then
1213            need_libio=no
1214            need_wlibio=no
1215         else
1216            need_libio=yes
1217            # bkoz XXX need to add checks to enable this
1218            # pme XXX here's a first pass at such a check
1219            if test x$enable_c_mbchar != xno; then
1220               need_wlibio=yes
1221            else
1222               need_wlibio=no
1223            fi
1224         fi
1225
1226       else
1227          # Using libio, but <libio.h> doesn't exist on the target system. . .
1228          need_libio=yes
1229          # bkoz XXX need to add checks to enable this
1230          # pme XXX here's a first pass at such a check
1231          if test x$enable_c_mbchar != xno; then
1232              need_wlibio=yes
1233          else
1234              need_wlibio=no
1235          fi
1236       fi
1237       ;;
1238     xstdio | x | xno | xnone | xyes)
1239       # default
1240       CSTDIO_H=config/io/c_io_stdio.h
1241       BASIC_FILE_H=config/io/basic_file_stdio.h
1242       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1243       AC_MSG_RESULT(stdio)
1244
1245       # We're not using stdio.
1246       need_libio=no
1247       need_wlibio=no
1248       ;;
1249     *)
1250       echo "$enable_cstdio is an unknown io package" 1>&2
1251       exit 1
1252       ;;
1253   esac
1254   AC_SUBST(CSTDIO_H)
1255   AC_SUBST(BASIC_FILE_H)
1256   AC_LINK_FILES($BASIC_FILE_CC, src/basic_file.cc)
1257
1258   # 2000-08-04 bkoz hack
1259   CCODECVT_C=config/io/c_io_libio_codecvt.c
1260   AC_SUBST(CCODECVT_C)
1261   # 2000-08-04 bkoz hack
1262
1263   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1264                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1265   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1266   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1267   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1268     libio_la=../libio/libio.la
1269   else
1270     libio_la=
1271   fi
1272   AC_SUBST(libio_la)
1273 ])
1274
1275
1276 dnl
1277 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1278 dnl We must stage the required headers so that they will be installed
1279 dnl with the library (unlike libgcc, the STL implementation is provided
1280 dnl solely within headers).  Since we must not inject random user-space
1281 dnl macro names into user-provided C++ code, we first stage into <file>-in
1282 dnl and process to <file> with an output command.  The reason for a two-
1283 dnl stage process here is to correctly handle $srcdir!=$objdir without
1284 dnl having to write complex code (the sed commands to clean the macro
1285 dnl namespace are complex and fragile enough as it is).  We must also
1286 dnl add a relative path so that -I- is supported properly.
1287 dnl
1288 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1289   AC_MSG_CHECKING([for thread model used by GCC])
1290   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1291   AC_MSG_RESULT([$target_thread_file])
1292
1293   if test $target_thread_file != single; then
1294     AC_DEFINE(HAVE_GTHR_DEFAULT)
1295     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1296   fi
1297
1298   glibcpp_thread_h=gthr-$target_thread_file.h
1299   AC_SUBST(glibcpp_thread_h)
1300 ])
1301
1302
1303 dnl
1304 dnl Check for exception handling support.  If an explicit enable/disable
1305 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1306 dnl target may or may not support call frame exceptions.
1307 dnl
1308 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1309 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1310 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1311 dnl
1312 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1313 dnl
1314 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1315   AC_MSG_CHECKING([for exception model to use])
1316   AC_LANG_SAVE
1317   AC_LANG_CPLUSPLUS
1318   AC_ARG_ENABLE(sjlj-exceptions,
1319   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1320   [:],
1321   [dnl Botheration.  Now we've got to detect the exception model.
1322    dnl Link tests against libgcc.a are problematic since -- at least
1323    dnl as of this writing -- we've not been given proper -L bits for
1324    dnl single-tree newlib and libgloss.
1325    dnl
1326    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1327    dnl conftest files before we got a change to grep them first.
1328    cat > conftest.$ac_ext << EOF
1329 [#]line __oline__ "configure"
1330 struct S { ~S(); };
1331 void bar();
1332 void foo()
1333 {
1334   S s;
1335   bar();
1336 }
1337 EOF
1338    old_CXXFLAGS="$CXXFLAGS"
1339    CXXFLAGS=-S
1340    if AC_TRY_EVAL(ac_compile); then
1341      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1342        enable_sjlj_exceptions=yes
1343      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1344        enable_sjlj_exceptions=no
1345      fi
1346    fi
1347    CXXFLAGS="$old_CXXFLAGS"
1348    rm -f conftest*])
1349    if test x$enable_sjlj_exceptions = xyes; then
1350      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1351         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1352      ac_exception_model_name=sjlj
1353    elif test x$enable_sjlj_exceptions = xno; then
1354      ac_exception_model_name="call frame"
1355    else
1356      AC_MSG_ERROR([unable to detect exception model])
1357    fi
1358    AC_LANG_RESTORE
1359    AC_MSG_RESULT($ac_exception_model_name)
1360 ])
1361
1362
1363 dnl
1364 dnl Check for ISO/IEC 9899:1999 "C99" support.
1365 dnl
1366 dnl GLIBCPP_ENABLE_C99
1367 dnl --enable-c99 defines _GLIBCPP_USE_C99
1368 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1369 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1370 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1371 dnl       defaults to `no'.
1372 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1373 dnl
1374 dnl GLIBCPP_ENABLE_C99
1375 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1376   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1377
1378   AC_ARG_ENABLE(c99,
1379   changequote(<<, >>)dnl
1380   <<--enable-c99            turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1381   changequote([, ])dnl
1382   [case "$enableval" in
1383    yes) enable_c99=yes ;;
1384    no)  enable_c99=no ;;
1385    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1386    esac],
1387   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1388
1389   AC_LANG_SAVE
1390   AC_LANG_CPLUSPLUS
1391
1392   # Check for the existence of <math.h> functions used if C99 is enabled.
1393   ac_c99_math=yes;
1394   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1395   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1396   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1397   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1398   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1399   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1400   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1401   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1402   AC_TRY_COMPILE([#include <math.h>],
1403                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1404   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1405   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1406   AC_TRY_COMPILE([#include <math.h>],
1407                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1408   AC_TRY_COMPILE([#include <math.h>],
1409                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1410   AC_MSG_RESULT($ac_c99_math)
1411
1412   # Check for the existence in <stdio.h> of vscanf, et. al.
1413   ac_c99_stdio=yes;
1414   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1415   AC_TRY_COMPILE([#include <stdio.h>],
1416                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
1417   AC_TRY_COMPILE([#include <stdio.h>
1418                   #include <stdarg.h>
1419                   void foo(char* fmt, ...)
1420                   {va_list args; va_start(args, fmt);
1421                   vfscanf(stderr, "%i", args);}],
1422                   [],, [ac_c99_stdio=no])
1423   AC_TRY_COMPILE([#include <stdio.h>
1424                   #include <stdarg.h>
1425                   void foo(char* fmt, ...)
1426                   {va_list args; va_start(args, fmt);
1427                   vscanf("%i", args);}],
1428                   [],, [ac_c99_stdio=no])
1429   AC_TRY_COMPILE([#include <stdio.h>
1430                   #include <stdarg.h>
1431                   void foo(char* fmt, ...)
1432                   {va_list args; va_start(args, fmt);
1433                   vsnprintf(fmt, 0, "%i", args);}],
1434                   [],, [ac_c99_stdio=no])
1435   AC_TRY_COMPILE([#include <stdio.h>
1436                   #include <stdarg.h>
1437                   void foo(char* fmt, ...)
1438                   {va_list args; va_start(args, fmt);
1439                   vsscanf(fmt, "%i", args);}],
1440                   [],, [ac_c99_stdio=no])
1441   AC_MSG_RESULT($ac_c99_stdio)
1442
1443   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1444   ac_c99_stdlib=yes;
1445   AC_MSG_CHECKING([for lldiv_t declaration])
1446   AC_CACHE_VAL(ac_c99_lldiv_t, [
1447   AC_TRY_COMPILE([#include <stdlib.h>],
1448                    [ lldiv_t mydivt;],
1449                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1450   ])
1451   AC_MSG_RESULT($ac_c99_lldiv_t)
1452
1453   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1454   AC_TRY_COMPILE([#include <stdlib.h>],
1455                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1456   AC_TRY_COMPILE([#include <stdlib.h>],
1457                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1458   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1459   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1460   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1461   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1462   if test x"$ac_c99_lldiv_t" = x"no"; then
1463     ac_c99_stdlib=no;
1464   fi;
1465   AC_MSG_RESULT($ac_c99_stdlib)
1466
1467   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1468   # XXX the wchar.h checks should be rolled into the general C99 bits.
1469   ac_c99_wchar=yes;
1470   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1471   AC_TRY_COMPILE([#include <wchar.h>],
1472                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1473   AC_TRY_COMPILE([#include <wchar.h>],
1474                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1475   AC_TRY_COMPILE([#include <wchar.h>],
1476                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1477   AC_MSG_RESULT($ac_c99_wchar)
1478
1479   AC_MSG_CHECKING([for enabled ISO C99 support])
1480   if test x"$ac_c99_math" = x"no" ||
1481      test x"$ac_c99_stdio" = x"no" ||
1482      test x"$ac_c99_stdlib" = x"no" ||
1483      test x"$ac_c99_wchar" = x"no"; then
1484     enable_c99=no;
1485   fi;
1486   AC_MSG_RESULT($enable_c99)
1487
1488   # Option parsed, now set things appropriately
1489   if test x"$enable_c99" = x"yes"; then
1490     AC_DEFINE(_GLIBCPP_USE_C99)
1491   fi
1492
1493   AC_LANG_RESTORE
1494 ])
1495
1496
1497 dnl
1498 dnl Check for template specializations for the 'long long' type extension.
1499 dnl The result determines only whether 'long long' I/O is enabled; things
1500 dnl like numeric_limits<> specializations are always available.
1501 dnl
1502 dnl GLIBCPP_ENABLE_LONG_LONG
1503 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1504 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1505 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1506 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1507 dnl       defaults to `no'.
1508 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1509 dnl
1510 dnl GLIBCPP_ENABLE_LONG_LONG
1511 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1512   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1513
1514   AC_ARG_ENABLE(long-long,
1515   changequote(<<, >>)dnl
1516   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1517   changequote([, ])dnl
1518   [case "$enableval" in
1519    yes) enable_long_long=yes ;;
1520    no)  enable_long_long=no ;;
1521    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1522    esac],
1523   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1524
1525   AC_LANG_SAVE
1526   AC_LANG_CPLUSPLUS
1527
1528   AC_MSG_CHECKING([for enabled long long I/O support])
1529   # iostreams require strtoll, strtoull to compile
1530   AC_TRY_COMPILE([#include <stdlib.h>],
1531                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1532   AC_TRY_COMPILE([#include <stdlib.h>],
1533                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1534
1535   # Option parsed, now set things appropriately
1536   if test x"$enable_long_long" = xyes; then
1537     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1538   fi
1539   AC_MSG_RESULT($enable_long_long)
1540
1541   AC_LANG_RESTORE
1542 ])
1543
1544
1545 dnl
1546 dnl Check for what kind of C headers to use.
1547 dnl
1548 dnl GLIBCPP_ENABLE_CHEADERS
1549 dnl --enable-cheaders= [does stuff].
1550 dnl --disable-cheaders [does not do anything, really].
1551 dnl  +  This will eventually need to be 'c_shadow' by default.
1552 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1553 dnl       Where DEFAULT is either `c' or `c_std' or 'c_shadow'.
1554 dnl       If ommitted, it defaults to `c_std'.
1555 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1556 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1557 AC_MSG_CHECKING([for c header strategy to use])
1558 AC_ARG_ENABLE(cheaders,
1559 changequote(<<, >>)dnl
1560 <<  --enable-cheaders       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1561 changequote([, ])
1562   [case "$enableval" in
1563    c)
1564         enable_cheaders=c
1565         ;;
1566    c_std)
1567         enable_cheaders=c_std
1568         ;;
1569    c_shadow)
1570         enable_cheaders=c_shadow
1571         ;;
1572    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1573         ;;
1574   esac],
1575   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1576   AC_MSG_RESULT($enable_cheaders)
1577
1578   dnl Option parsed, now set things appropriately
1579   case "$enable_cheaders" in
1580     c_shadow)
1581         CSHADOW_FLAGS="-fno-builtin"
1582         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_shadow'
1583         AC_DEFINE(_GLIBCPP_USE_SHADOW_HEADERS)
1584         ;;
1585     c_std)
1586         CSHADOW_FLAGS=""
1587         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_std'
1588         ;;
1589     c)
1590         CSHADOW_FLAGS=""
1591         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c'
1592         ;;
1593   esac
1594
1595   AC_SUBST(CSHADOW_FLAGS)
1596   AC_SUBST(C_INCLUDE_DIR)
1597   AM_CONDITIONAL(GLIBCPP_USE_CSHADOW, test "$enable_cheaders" = c_shadow)
1598 ])
1599
1600
1601 dnl
1602 dnl Check for wide character support.  Has the same effect as the option
1603 dnl in gcc's configure, but in a form that autoconf can mess with.
1604 dnl
1605 dnl GLIBCPP_ENABLE_C_MBCHAR
1606 dnl --enable-c-mbchar requests all the wchar_t stuff.
1607 dnl --disable-c-mbchar doesn't.
1608 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1609 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1610 dnl       defaults to `no'.
1611 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1612 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1613 AC_ARG_ENABLE(c-mbchar,
1614 changequote(<<, >>)dnl
1615 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1616 changequote([, ])dnl
1617 [case "$enableval" in
1618  yes) enable_c_mbchar=yes ;;
1619  no)  enable_c_mbchar=no ;;
1620  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1621  esac],
1622 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1623 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1624 ])
1625
1626
1627 dnl
1628 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1629 dnl
1630 dnl TOPLEVEL_INCLUDES
1631 dnl LIBMATH_INCLUDES
1632 dnl LIBSUPCXX_INCLUDES
1633 dnl LIBIO_INCLUDES
1634 dnl CSHADOW_INCLUDES
1635 dnl
1636 dnl GLIBCPP_EXPORT_INCLUDES
1637 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1638   # Root level of the build directory include sources.
1639   GLIBCPP_INCLUDES="-I${glibcpp_builddir}/include/${target_alias} -I${glibcpp_builddir}/include"
1640
1641   # Passed down for canadian crosses.
1642   if test x"$CANADIAN" = xyes; then
1643     TOPLEVEL_INCLUDES='-I$(includedir)'
1644   fi
1645
1646   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1647
1648   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1649
1650   if test x"$need_libio" = xyes; then
1651     LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1652     AC_SUBST(LIBIO_INCLUDES)
1653   fi
1654
1655   # Now, export this to all the little Makefiles....
1656   AC_SUBST(GLIBCPP_INCLUDES)
1657   AC_SUBST(TOPLEVEL_INCLUDES)
1658   AC_SUBST(LIBMATH_INCLUDES)
1659   AC_SUBST(LIBSUPCXX_INCLUDES)
1660 ])
1661
1662
1663 dnl
1664 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1665 dnl
1666 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1667   # Optimization flags that are probably a good idea for thrill-seekers. Just
1668   # uncomment the lines below and make, everything else is ready to go...
1669   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1670   OPTIMIZE_CXXFLAGS=
1671   AC_SUBST(OPTIMIZE_CXXFLAGS)
1672
1673   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1674   AC_SUBST(WARN_FLAGS)
1675 ])
1676
1677 dnl
1678 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1679 dnl  calculates gxx_install_dir
1680 dnl  exports glibcpp_toolexecdir
1681 dnl  exports glibcpp_toolexeclibdir
1682 dnl  exports glibcpp_prefixdir
1683 dnl
1684 dnl Assumes cross_compiling bits already done, and with_cross_host in
1685 dnl particular
1686 dnl
1687 dnl GLIBCPP_EXPORT_INSTALL_INFO
1688 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1689 # Assumes glibcpp_builddir, glibcpp_srcdir are alreay set up and
1690 # exported correctly in GLIBCPP_CONFIGURE.
1691 glibcpp_toolexecdir=no
1692 glibcpp_toolexeclibdir=no
1693 glibcpp_prefixdir=${prefix}
1694
1695 AC_MSG_CHECKING([for interface version number])
1696 libstdcxx_interface=$INTERFACE
1697 AC_MSG_RESULT($libstdcxx_interface)
1698
1699 # Process the option --with-gxx-include-dir=<path to include-files directory>
1700 AC_MSG_CHECKING([for --with-gxx-include-dir])
1701 AC_ARG_WITH(gxx-include-dir,
1702 [  --with-gxx-include-dir  the installation directory for include files],
1703 [case "${withval}" in
1704   yes)
1705     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1706     gxx_include_dir=no
1707     ;;
1708   no)
1709     gxx_include_dir=no
1710     ;;
1711   *)
1712     gxx_include_dir=${withval}
1713     ;;
1714 esac], [gxx_include_dir=no])
1715 AC_MSG_RESULT($gxx_include_dir)
1716
1717 # Process the option "--enable-version-specific-runtime-libs"
1718 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1719 AC_ARG_ENABLE(version-specific-runtime-libs,
1720 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1721 [case "$enableval" in
1722  yes) version_specific_libs=yes ;;
1723  no)  version_specific_libs=no ;;
1724  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
1725  esac],
1726 version_specific_libs=no)dnl
1727 # Option set, now we can test it.
1728 AC_MSG_RESULT($version_specific_libs)
1729
1730 if test $version_specific_libs = yes; then
1731   # Need the gcc compiler version to know where to install libraries
1732   # and header files if --enable-version-specific-runtime-libs option
1733   # is selected.
1734   changequote(,)dnl
1735   gcc_version_trigger=${srcdir}/../gcc/version.c
1736   gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
1737   gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1738   gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/g++
1739   glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1740   glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1741   changequote([,])dnl
1742 fi
1743
1744 # Default case for install directory for include files.
1745 if test $version_specific_libs = no &&
1746    test $gxx_include_dir = no; then
1747   gxx_include_dir='$(prefix)'/include/g++-${libstdcxx_interface}
1748 fi
1749
1750 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1751 # Install a library built with a cross compiler in tooldir, not libdir.
1752 if test x"$glibcpp_toolexecdir" = x"no"; then
1753   if test -n "$with_cross_host" &&
1754      test x"$with_cross_host" != x"no"; then
1755     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1756     glibcpp_toolexeclibdir='$(toolexecdir)/lib$(MULTISUBDIR)'
1757   else
1758     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1759     glibcpp_toolexeclibdir='$(libdir)$(MULTISUBDIR)'
1760   fi
1761 fi
1762
1763 AC_MSG_CHECKING([for install location])
1764 AC_MSG_RESULT($gxx_include_dir)
1765
1766 AC_SUBST(glibcpp_prefixdir)
1767 AC_SUBST(gxx_include_dir)
1768 AC_SUBST(glibcpp_toolexecdir)
1769 AC_SUBST(glibcpp_toolexeclibdir)
1770 ])
1771
1772
1773 # Check for functions in math library.
1774 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1775 #
1776 # This file can be copied and used freely without restrictions.  It can
1777 # be used in projects which are not available under the GNU Public License
1778 # but which still want to provide support for the GNU gettext functionality.
1779 # Please note that the actual code is *not* freely available.
1780
1781 # serial 1
1782
1783 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1784 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1785 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])
1786 AC_SUBST(LIBMATHOBJS)dnl
1787 ])
1788
1789
1790
1791 dnl This macro searches for a GNU version of make.  If a match is found, the
1792 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1793 dnl set to "#". This is useful for  including a special features in a Makefile,
1794 dnl which cannot be handled by other versions of make.  The variable
1795 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1796 dnl the empty string otherwise.
1797 dnl
1798 dnl Here is an example of its use:
1799 dnl
1800 dnl Makefile.in might contain:
1801 dnl
1802 dnl     # A failsafe way of putting a dependency rule into a makefile
1803 dnl     $(DEPEND):
1804 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1805 dnl
1806 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1807 dnl     @ifGNUmake@ include $(DEPEND)
1808 dnl     @ifGNUmake@ endif
1809 dnl
1810 dnl Then configure.in would normally contain:
1811 dnl
1812 dnl     CHECK_GNU_MAKE()
1813 dnl     AC_OUTPUT(Makefile)
1814 dnl
1815 dnl Then perhaps to cause gnu make to override any other make, we could do
1816 dnl something like this (note that GNU make always looks for GNUmakefile first):
1817 dnl
1818 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1819 dnl             mv Makefile GNUmakefile
1820 dnl             echo .DEFAULT: > Makefile ;
1821 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1822 dnl     fi
1823 dnl
1824 dnl Then, if any (well almost any) other make is called, and GNU make also
1825 dnl exists, then the other make wraps the GNU make.
1826 dnl
1827 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1828 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1829 dnl
1830 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1831 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1832 dnl #### conditional's subshell (" --version" is not a command), using a
1833 dnl #### different option to grep(1).
1834 dnl #### -pme
1835 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1836 dnl #### ${MAKE:-make}).
1837 dnl #### -msokolov
1838 AC_DEFUN(
1839   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1840           _cv_gnu_make_command='' ;
1841 dnl Search all the common names for GNU make
1842           for a in "${MAKE-make}" make gmake gnumake ; do
1843                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1844                   then
1845                           _cv_gnu_make_command=$a ;
1846                           break;
1847                   fi
1848           done ;
1849   ) ;
1850 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1851 dnl string, '#' otherwise
1852   if test  "x$_cv_gnu_make_command" != "x"  ; then
1853           ifGNUmake='' ;
1854   else
1855           ifGNUmake='#' ;
1856   fi
1857   AC_SUBST(ifGNUmake)
1858 ])
1859
1860
1861 dnl Check for headers for, and arguments to, the setrlimit() function.
1862 dnl Used only in testsuite_hooks.h.
1863 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT_ancilliary, [
1864   AC_TRY_COMPILE([#include <sys/resource.h>
1865                   #include <unistd.h>
1866                  ], [ int f = RLIMIT_$1 ; ],
1867                  [glibcpp_mresult=1], [glibcpp_mresult=0])
1868   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcpp_mresult,
1869                      [Only used in build directory testsuite_hooks.h.])
1870 ])
1871 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT, [
1872   setrlimit_have_headers=yes
1873   AC_CHECK_HEADERS(sys/resource.h unistd.h,
1874                    [],
1875                    setrlimit_have_headers=no)
1876   # If don't have the headers, then we can't run the tests now, and we
1877   # won't be seeing any of these during testsuite compilation.
1878   if test $setrlimit_have_headers = yes; then
1879     # Can't do these in a loop, else the resulting syntax is wrong.
1880     GLIBCPP_CHECK_SETRLIMIT_ancilliary(DATA)
1881     GLIBCPP_CHECK_SETRLIMIT_ancilliary(RSS)
1882     GLIBCPP_CHECK_SETRLIMIT_ancilliary(VMEM)
1883     GLIBCPP_CHECK_SETRLIMIT_ancilliary(AS)
1884
1885     # Check for rlimit, setrlimit.
1886     AC_CACHE_VAL(ac_setrlimit, [
1887       AC_TRY_COMPILE([#include <sys/resource.h>
1888                       #include <unistd.h>
1889                      ],
1890                      [ struct rlimit r; setrlimit(0, &r);],
1891                      [ac_setrlimit=yes], [ac_setrlimit=no])
1892     ])
1893   fi
1894
1895   AC_MSG_CHECKING([for testsuite memory limit support])
1896   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
1897     ac_mem_limits=yes
1898     AC_DEFINE(_GLIBCPP_MEM_LIMITS)
1899   else
1900     ac_mem_limits=no
1901   fi
1902   AC_MSG_RESULT($ac_mem_limits)
1903 ])
1904
1905
1906 dnl
1907 dnl Does any necessary configuration of the testsuite directory.  Generates
1908 dnl the testsuite_hooks.h header.
1909 dnl
1910 dnl GLIBCPP_CONFIGURE_TESTSUITE  [no args]
1911 AC_DEFUN(GLIBCPP_CONFIGURE_TESTSUITE, [
1912   GLIBCPP_CHECK_SETRLIMIT
1913 ])
1914
1915
1916 sinclude(../libtool.m4)
1917 dnl The lines below arrange for aclocal not to bring an installed
1918 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1919 dnl add a definition of LIBTOOL to Makefile.in.
1920 ifelse(,,,[AC_SUBST(LIBTOOL)
1921 AC_DEFUN([AM_PROG_LIBTOOL])
1922 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1923 AC_DEFUN([AC_PROG_LD])
1924 ])
1925
1926
1927 # Check whether LC_MESSAGES is available in <locale.h>.
1928 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1929 #
1930 # This file file be copied and used freely without restrictions.  It can
1931 # be used in projects which are not available under the GNU Public License
1932 # but which still want to provide support for the GNU gettext functionality.
1933 # Please note that the actual code is *not* freely available.
1934
1935 # serial 1
1936
1937 AC_DEFUN(AC_LC_MESSAGES, [
1938   AC_CHECK_HEADER(locale.h, [
1939     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1940       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1941        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1942     if test $ac_cv_val_LC_MESSAGES = yes; then
1943       AC_DEFINE(HAVE_LC_MESSAGES)
1944     fi
1945   ])
1946 ])
1947
1948
1949 dnl
1950 dnl Check for whether the Boost-derived checks should be turned on.
1951 dnl
1952 dnl GLIBCPP_ENABLE_CONCEPT_CHECKS
1953 dnl --enable-concept-checks turns them on.
1954 dnl --disable-concept-checks leaves them off.
1955 dnl  +  Usage:  GLIBCPP_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1956 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1957 dnl       defaults to `no'.
1958 AC_DEFUN(GLIBCPP_ENABLE_CONCEPT_CHECKS, [dnl
1959 define([GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT], ifelse($1, yes, yes, no))dnl
1960 AC_ARG_ENABLE(concept-checks,
1961 changequote(<<, >>)dnl
1962 <<  --enable-concept-checks use Boost-derived template checks [default=>>GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT],
1963 changequote([, ])dnl
1964 [case "$enableval" in
1965  yes) enable_concept_checks=yes ;;
1966  no)  enable_concept_checks=no ;;
1967  *)   AC_MSG_ERROR([Unknown argument to enable/disable concept checks]) ;;
1968  esac],
1969 enable_concept_checks=GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT)dnl
1970 dnl Option parsed, now set things appropriately
1971 if test x"$enable_concept_checks" = xyes; then
1972   AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS)
1973 fi
1974 ])
1975
1976