gcc/ada/g-table.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                            G N A T . T A B L E                           --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 1998-2007, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System;        use System;
  35 with System.Memory; use System.Memory;
  36
  37 with Ada.Unchecked_Conversion;
  38
  39 package body GNAT.Table is
  40
  41    Min : constant Integer := Integer (Table_Low_Bound);
  42    --  Subscript of the minimum entry in the currently allocated table
  43
  44    Max : Integer;
  45    --  Subscript of the maximum entry in the currently allocated table
  46
  47    Length : Integer := 0;
  48    --  Number of entries in currently allocated table. The value of zero
  49    --  ensures that we initially allocate the table.
  50
  51    Last_Val : Integer;
  52    --  Current value of Last
  53
  54    -----------------------
  55    -- Local Subprograms --
  56    -----------------------
  57
  58    procedure Reallocate;
  59    --  Reallocate the existing table according to the current value stored
  60    --  in Max. Works correctly to do an initial allocation if the table
  61    --  is currently null.
  62
  63    pragma Warnings (Off);
  64    --  Turn off warnings. The following unchecked conversions are only used
  65    --  internally in this package, and cannot never result in any instances
  66    --  of improperly aliased pointers for the client of the package.
  67
  68    function To_Address is new Ada.Unchecked_Conversion (Table_Ptr, Address);
  69    function To_Pointer is new Ada.Unchecked_Conversion (Address, Table_Ptr);
  70
  71    pragma Warnings (On);
  72
  73    --------------
  74    -- Allocate --
  75    --------------
  76
  77    function Allocate (Num : Integer := 1) return Table_Index_Type is
  78       Old_Last : constant Integer := Last_Val;
  79
  80    begin
  81       Last_Val := Last_Val + Num;
  82
  83       if Last_Val > Max then
  84          Reallocate;
  85       end if;
  86
  87       return Table_Index_Type (Old_Last + 1);
  88    end Allocate;
  89
  90    ------------
  91    -- Append --
  92    ------------
  93
  94    procedure Append (New_Val : Table_Component_Type) is
  95    begin
  96       Set_Item (Table_Index_Type (Last_Val + 1), New_Val);
  97    end Append;
  98
  99    --------------------
 100    -- Decrement_Last --
 101    --------------------
 102
 103    procedure Decrement_Last is
 104    begin
 105       Last_Val := Last_Val - 1;
 106    end Decrement_Last;
 107
 108    ----------
 109    -- Free --
 110    ----------
 111
 112    procedure Free is
 113    begin
 114       Free (To_Address (Table));
 115       Table := null;
 116       Length := 0;
 117    end Free;
 118
 119    --------------------
 120    -- Increment_Last --
 121    --------------------
 122
 123    procedure Increment_Last is
 124    begin
 125       Last_Val := Last_Val + 1;
 126
 127       if Last_Val > Max then
 128          Reallocate;
 129       end if;
 130    end Increment_Last;
 131
 132    ----------
 133    -- Init --
 134    ----------
 135
 136    procedure Init is
 137       Old_Length : constant Integer := Length;
 138
 139    begin
 140       Last_Val := Min - 1;
 141       Max      := Min + Table_Initial - 1;
 142       Length   := Max - Min + 1;
 143
 144       --  If table is same size as before (happens when table is never
 145       --  expanded which is a common case), then simply reuse it. Note
 146       --  that this also means that an explicit Init call right after
 147       --  the implicit one in the package body is harmless.
 148
 149       if Old_Length = Length then
 150          return;
 151
 152       --  Otherwise we can use Reallocate to get a table of the right size.
 153       --  Note that Reallocate works fine to allocate a table of the right
 154       --  initial size when it is first allocated.
 155
 156       else
 157          Reallocate;
 158       end if;
 159    end Init;
 160
 161    ----------
 162    -- Last --
 163    ----------
 164
 165    function Last return Table_Index_Type is
 166    begin
 167       return Table_Index_Type (Last_Val);
 168    end Last;
 169
 170    ----------------
 171    -- Reallocate --
 172    ----------------
 173
 174    procedure Reallocate is
 175       New_Size : size_t;
 176
 177    begin
 178       if Max < Last_Val then
 179          pragma Assert (not Locked);
 180
 181          while Max < Last_Val loop
 182
 183             --  Increase length using the table increment factor, but make
 184             --  sure that we add at least ten elements (this avoids a loop
 185             --  for silly small increment values)
 186
 187             Length := Integer'Max
 188                         (Length * (100 + Table_Increment) / 100,
 189                          Length + 10);
 190             Max := Min + Length - 1;
 191          end loop;
 192       end if;
 193
 194       New_Size :=
 195         size_t ((Max - Min + 1) *
 196                 (Table_Type'Component_Size / Storage_Unit));
 197
 198       if Table = null then
 199          Table := To_Pointer (Alloc (New_Size));
 200
 201       elsif New_Size > 0 then
 202          Table :=
 203            To_Pointer (Realloc (Ptr  => To_Address (Table),
 204                                 Size => New_Size));
 205       end if;
 206
 207       if Length /= 0 and then Table = null then
 208          raise Storage_Error;
 209       end if;
 210
 211    end Reallocate;
 212
 213    -------------
 214    -- Release --
 215    -------------
 216
 217    procedure Release is
 218    begin
 219       Length := Last_Val - Integer (Table_Low_Bound) + 1;
 220       Max    := Last_Val;
 221       Reallocate;
 222    end Release;
 223
 224    --------------
 225    -- Set_Item --
 226    --------------
 227
 228    procedure Set_Item
 229       (Index : Table_Index_Type;
 230        Item  : Table_Component_Type)
 231    is
 232       --  If Item is a value within the current allocation, and we are going to
 233       --  reallocate, then we must preserve an intermediate copy here before
 234       --  calling Increment_Last. Otherwise, if Table_Component_Type is passed
 235       --  by reference, we are going to end up copying from storage that might
 236       --  have been deallocated from Increment_Last calling Reallocate.
 237
 238       subtype Allocated_Table_T is
 239         Table_Type (Table'First .. Table_Index_Type (Max + 1));
 240       --  A constrained table subtype one element larger than the currently
 241       --  allocated table.
 242
 243       Allocated_Table_Address : constant System.Address :=
 244                                   Table.all'Address;
 245       --  Used for address clause below (we can't use non-static expression
 246       --  Table.all'Address directly in the clause because some older versions
 247       --  of the compiler do not allow it).
 248
 249       Allocated_Table : Allocated_Table_T;
 250       pragma Import (Ada, Allocated_Table);
 251       pragma Suppress (Range_Check, On => Allocated_Table);
 252       for Allocated_Table'Address use Allocated_Table_Address;
 253       --  Allocated_Table represents the currently allocated array, plus
 254       --  one element (the supplementary element is used to have a
 255       --  convenient way of computing the address just past the end of the
 256       --  current allocation). Range checks are suppressed because this unit
 257       --  uses direct calls to System.Memory for allocation, and this can
 258       --  yield misaligned storage (and we cannot rely on the bootstrap
 259       --  compiler supporting specifically disabling alignment checks, so we
 260       --  need to suppress all range checks). It is safe to suppress this check
 261       --  here because we know that a (possibly misaligned) object of that type
 262       --  does actually exist at that address.
 263       --  ??? We should really improve the allocation circuitry here to
 264       --  guarantee proper alignment.
 265
 266       Need_Realloc : constant Boolean := Integer (Index) > Max;
 267       --  True if this operation requires storage reallocation (which may
 268       --  involve moving table contents around).
 269
 270    begin
 271       --  If we're going to reallocate, check whether Item references an
 272       --  element of the currently allocated table.
 273
 274       if Need_Realloc
 275         and then Allocated_Table'Address <= Item'Address
 276         and then Item'Address <
 277                    Allocated_Table (Table_Index_Type (Max + 1))'Address
 278       then
 279          --  If so, save a copy on the stack because Increment_Last will
 280          --  reallocate storage and might deallocate the current table.
 281
 282          declare
 283             Item_Copy : constant Table_Component_Type := Item;
 284          begin
 285             Set_Last (Index);
 286             Table (Index) := Item_Copy;
 287          end;
 288
 289       else
 290          --  Here we know that either we won't reallocate (case of Index < Max)
 291          --  or that Item is not in the currently allocated table.
 292
 293          if Integer (Index) > Last_Val then
 294             Set_Last (Index);
 295          end if;
 296
 297          Table (Index) := Item;
 298       end if;
 299    end Set_Item;
 300
 301    --------------
 302    -- Set_Last --
 303    --------------
 304
 305    procedure Set_Last (New_Val : Table_Index_Type) is
 306    begin
 307       if Integer (New_Val) < Last_Val then
 308          Last_Val := Integer (New_Val);
 309       else
 310          Last_Val := Integer (New_Val);
 311
 312          if Last_Val > Max then
 313             Reallocate;
 314          end if;
 315       end if;
 316    end Set_Last;
 317
 318 begin
 319    Init;
 320 end GNAT.Table;