re PR tree-optimization/58143 (wrong code at -O3)
[official-gcc.git] / gcc / ada / a-calend.ads
blob668efb9b32ae894e9820598dc7c944fe237d4d72
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT RUN-TIME COMPONENTS --
4 -- --
5 -- A D A . C A L E N D A R --
6 -- --
7 -- S p e c --
8 -- --
9 -- Copyright (C) 1992-2012, Free Software Foundation, Inc. --
10 -- --
11 -- This specification is derived from the Ada Reference Manual for use with --
12 -- GNAT. The copyright notice above, and the license provisions that follow --
13 -- apply solely to the contents of the part following the private keyword. --
14 -- --
15 -- GNAT is free software; you can redistribute it and/or modify it under --
16 -- terms of the GNU General Public License as published by the Free Soft- --
17 -- ware Foundation; either version 3, or (at your option) any later ver- --
18 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
19 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
20 -- or FITNESS FOR A PARTICULAR PURPOSE. --
21 -- --
22 -- As a special exception under Section 7 of GPL version 3, you are granted --
23 -- additional permissions described in the GCC Runtime Library Exception, --
24 -- version 3.1, as published by the Free Software Foundation. --
25 -- --
26 -- You should have received a copy of the GNU General Public License and --
27 -- a copy of the GCC Runtime Library Exception along with this program; --
28 -- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
29 -- <http://www.gnu.org/licenses/>. --
30 -- --
31 -- GNAT was originally developed by the GNAT team at New York University. --
32 -- Extensive contributions were provided by Ada Core Technologies Inc. --
33 -- --
34 ------------------------------------------------------------------------------
36 package Ada.Calendar is
38 type Time is private;
40 -- Declarations representing limits of allowed local time values. Note that
41 -- these do NOT constrain the possible stored values of time which may well
42 -- permit a larger range of times (this is explicitly allowed in Ada 95).
44 subtype Year_Number is Integer range 1901 .. 2399;
45 subtype Month_Number is Integer range 1 .. 12;
46 subtype Day_Number is Integer range 1 .. 31;
48 -- A Day_Duration value of 86_400.0 designates a new day
50 subtype Day_Duration is Duration range 0.0 .. 86_400.0;
52 function Clock return Time;
53 -- The returned time value is the number of nanoseconds since the start
54 -- of Ada time (1901-01-01 00:00:00.0 UTC). If leap seconds are enabled,
55 -- the result will contain all elapsed leap seconds since the start of
56 -- Ada time until now.
58 function Year (Date : Time) return Year_Number;
59 function Month (Date : Time) return Month_Number;
60 function Day (Date : Time) return Day_Number;
61 function Seconds (Date : Time) return Day_Duration;
63 procedure Split
64 (Date : Time;
65 Year : out Year_Number;
66 Month : out Month_Number;
67 Day : out Day_Number;
68 Seconds : out Day_Duration);
69 -- Break down a time value into its date components set in the current
70 -- time zone. If Split is called on a time value created using Ada 2005
71 -- Time_Of in some arbitrary time zone, the input value will always be
72 -- interpreted as relative to the local time zone.
74 function Time_Of
75 (Year : Year_Number;
76 Month : Month_Number;
77 Day : Day_Number;
78 Seconds : Day_Duration := 0.0) return Time;
79 -- GNAT Note: Normally when procedure Split is called on a Time value
80 -- result of a call to function Time_Of, the out parameters of procedure
81 -- Split are identical to the in parameters of function Time_Of. However,
82 -- when a non-existent time of day is specified, the values for Seconds
83 -- may or may not be different. This may happen when Daylight Saving Time
84 -- (DST) is in effect, on the day when switching to DST, if Seconds
85 -- specifies a time of day in the hour that does not exist. For example,
86 -- in New York:
88 -- Time_Of (Year => 1998, Month => 4, Day => 5, Seconds => 10740.0)
90 -- will return a Time value T. If Split is called on T, the resulting
91 -- Seconds may be 14340.0 (3:59:00) instead of 10740.0 (2:59:00 being
92 -- a time that not exist).
94 function "+" (Left : Time; Right : Duration) return Time;
95 function "+" (Left : Duration; Right : Time) return Time;
96 function "-" (Left : Time; Right : Duration) return Time;
97 function "-" (Left : Time; Right : Time) return Duration;
98 -- The first three functions will raise Time_Error if the resulting time
99 -- value is less than the start of Ada time in UTC or greater than the
100 -- end of Ada time in UTC. The last function will raise Time_Error if the
101 -- resulting difference cannot fit into a duration value.
103 function "<" (Left, Right : Time) return Boolean;
104 function "<=" (Left, Right : Time) return Boolean;
105 function ">" (Left, Right : Time) return Boolean;
106 function ">=" (Left, Right : Time) return Boolean;
108 Time_Error : exception;
110 private
111 pragma Inline (Clock);
113 pragma Inline (Year);
114 pragma Inline (Month);
115 pragma Inline (Day);
117 pragma Inline ("+");
118 pragma Inline ("-");
120 pragma Inline ("<");
121 pragma Inline ("<=");
122 pragma Inline (">");
123 pragma Inline (">=");
125 -- The units used in this version of Ada.Calendar are nanoseconds. The
126 -- following constants provide values used in conversions of seconds or
127 -- days to the underlying units.
129 Nano : constant := 1_000_000_000;
130 Nano_F : constant := 1_000_000_000.0;
131 Nanos_In_Day : constant := 86_400_000_000_000;
132 Secs_In_Day : constant := 86_400;
134 ----------------------------
135 -- Implementation of Time --
136 ----------------------------
138 -- Time is represented as a signed 64 bit integer count of nanoseconds
139 -- since the start of Ada time (1901-01-01 00:00:00.0 UTC). Time values
140 -- produced by Time_Of are internally normalized to UTC regardless of their
141 -- local time zone. This representation ensures correct handling of leap
142 -- seconds as well as performing arithmetic. In Ada 95, Split and Time_Of
143 -- will treat a time value as being in the local time zone, in Ada 2005,
144 -- Split and Time_Of will treat a time value as being in the designated
145 -- time zone by the formal parameter or in UTC by default. The size of the
146 -- type is large enough to cover the Ada 2005 range of time (1901-01-01
147 -- 00:00:00.0 UTC - 2399-12-31-23:59:59.999999999 UTC).
149 ------------------
150 -- Leap Seconds --
151 ------------------
153 -- Due to Earth's slowdown, the astronomical time is not as precise as the
154 -- International Atomic Time. To compensate for this inaccuracy, a single
155 -- leap second is added after the last day of June or December. The count
156 -- of seconds during those occurrences becomes:
158 -- ... 58, 59, leap second 60, 0, 1, 2 ...
160 -- Unlike leap days, leap seconds occur simultaneously around the world.
161 -- In other words, if a leap second occurs at 23:59:60 UTC, it also occurs
162 -- on 18:59:60 -5 the same day or 2:59:60 +2 on the next day.
164 -- Leap seconds do not follow a formula. The International Earth Rotation
165 -- and Reference System Service decides when to add one. Leap seconds are
166 -- included in the representation of time in Ada 95 mode. As a result,
167 -- the following two time values will differ by two seconds:
169 -- 1972-06-30 23:59:59.0
170 -- 1972-07-01 00:00:00.0
172 -- When a new leap second is introduced, the following steps must be
173 -- carried out:
175 -- 1) Increment Leap_Seconds_Count in a-calend.adb by one
176 -- 2) Increment LS_Count in xleaps.adb by one
177 -- 3) Add the new date to the aggregate of array LS_Dates in
178 -- xleaps.adb
179 -- 4) Compile and execute xleaps
180 -- 5) Replace the values of Leap_Second_Times in a-calend.adb with the
181 -- aggregate generated by xleaps
183 -- The algorithms that build the actual leap second values and discover
184 -- how many leap seconds have occurred between two dates do not need any
185 -- modification.
187 ------------------------------
188 -- Non-leap Centennial Years --
189 ------------------------------
191 -- Over the range of Ada time, centennial years 2100, 2200 and 2300 are
192 -- non-leap. As a consequence, seven non-leap years occur over the period
193 -- of year - 4 to year + 4. Internally, routines Split and Time_Of add or
194 -- subtract a "fake" February 29 to facilitate the arithmetic involved.
196 ------------------------
197 -- Local Declarations --
198 ------------------------
200 type Time_Rep is range -2 ** 63 .. +2 ** 63 - 1;
201 type Time is new Time_Rep;
202 -- The underlying type of Time has been chosen to be a 64 bit signed
203 -- integer number since it allows for easier processing of sub seconds
204 -- and arithmetic.
206 Days_In_Month : constant array (Month_Number) of Day_Number :=
207 (31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31);
208 -- Days in month for non-leap year, leap year case is adjusted in code
210 Invalid_Time_Zone_Offset : Long_Integer;
211 pragma Import (C, Invalid_Time_Zone_Offset, "__gnat_invalid_tzoff");
213 function Is_Leap (Year : Year_Number) return Boolean;
214 -- Determine whether a given year is leap
216 ----------------------------------------------------------
217 -- Target-Independent Interface to Children of Calendar --
218 ----------------------------------------------------------
220 -- The following packages provide a target-independent interface to the
221 -- children of Calendar - Arithmetic, Conversions, Delays, Formatting and
222 -- Time_Zones.
224 ---------------------------
225 -- Arithmetic_Operations --
226 ---------------------------
228 package Arithmetic_Operations is
230 function Add (Date : Time; Days : Long_Integer) return Time;
231 -- Add a certain number of days to a time value
233 procedure Difference
234 (Left : Time;
235 Right : Time;
236 Days : out Long_Integer;
237 Seconds : out Duration;
238 Leap_Seconds : out Integer);
239 -- Calculate the difference between two time values in terms of days,
240 -- seconds and leap seconds elapsed. The leap seconds are not included
241 -- in the seconds returned. If Left is greater than Right, the returned
242 -- values are positive, negative otherwise.
244 function Subtract (Date : Time; Days : Long_Integer) return Time;
245 -- Subtract a certain number of days from a time value
247 end Arithmetic_Operations;
249 ---------------------------
250 -- Conversion_Operations --
251 ---------------------------
253 package Conversion_Operations is
255 function To_Ada_Time (Unix_Time : Long_Integer) return Time;
256 -- Unix to Ada Epoch conversion
258 function To_Ada_Time
259 (tm_year : Integer;
260 tm_mon : Integer;
261 tm_day : Integer;
262 tm_hour : Integer;
263 tm_min : Integer;
264 tm_sec : Integer;
265 tm_isdst : Integer) return Time;
266 -- Struct tm to Ada Epoch conversion
268 function To_Duration
269 (tv_sec : Long_Integer;
270 tv_nsec : Long_Integer) return Duration;
271 -- Struct timespec to Duration conversion
273 procedure To_Struct_Timespec
274 (D : Duration;
275 tv_sec : out Long_Integer;
276 tv_nsec : out Long_Integer);
277 -- Duration to struct timespec conversion
279 procedure To_Struct_Tm
280 (T : Time;
281 tm_year : out Integer;
282 tm_mon : out Integer;
283 tm_day : out Integer;
284 tm_hour : out Integer;
285 tm_min : out Integer;
286 tm_sec : out Integer);
287 -- Time to struct tm conversion
289 function To_Unix_Time (Ada_Time : Time) return Long_Integer;
290 -- Ada to Unix Epoch conversion
292 end Conversion_Operations;
294 ----------------------
295 -- Delay_Operations --
296 ----------------------
298 package Delay_Operations is
300 function To_Duration (Date : Time) return Duration;
301 -- Given a time value in nanoseconds since 1901, convert it into a
302 -- duration value giving the number of nanoseconds since the Unix Epoch.
304 end Delay_Operations;
306 ---------------------------
307 -- Formatting_Operations --
308 ---------------------------
310 package Formatting_Operations is
312 function Day_Of_Week (Date : Time) return Integer;
313 -- Determine which day of week Date falls on. The returned values are
314 -- within the range of 0 .. 6 (Monday .. Sunday).
316 procedure Split
317 (Date : Time;
318 Year : out Year_Number;
319 Month : out Month_Number;
320 Day : out Day_Number;
321 Day_Secs : out Day_Duration;
322 Hour : out Integer;
323 Minute : out Integer;
324 Second : out Integer;
325 Sub_Sec : out Duration;
326 Leap_Sec : out Boolean;
327 Use_TZ : Boolean;
328 Is_Historic : Boolean;
329 Time_Zone : Long_Integer);
330 pragma Export (Ada, Split, "__gnat_split");
331 -- Split a time value into its components. If flag Is_Historic is set,
332 -- this routine would try to use to the best of the OS's abilities the
333 -- time zone offset that was or will be in effect on Date. Set Use_TZ
334 -- to use the local time zone (the value in Time_Zone is ignored) when
335 -- splitting a time value.
337 function Time_Of
338 (Year : Year_Number;
339 Month : Month_Number;
340 Day : Day_Number;
341 Day_Secs : Day_Duration;
342 Hour : Integer;
343 Minute : Integer;
344 Second : Integer;
345 Sub_Sec : Duration;
346 Leap_Sec : Boolean;
347 Use_Day_Secs : Boolean;
348 Use_TZ : Boolean;
349 Is_Historic : Boolean;
350 Time_Zone : Long_Integer) return Time;
351 pragma Export (Ada, Time_Of, "__gnat_time_of");
352 -- Given all the components of a date, return the corresponding time
353 -- value. Set Use_Day_Secs to use the value in Day_Secs, otherwise the
354 -- day duration will be calculated from Hour, Minute, Second and Sub_
355 -- Sec. If flag Is_Historic is set, this routine would try to use to the
356 -- best of the OS's abilities the time zone offset that was or will be
357 -- in effect on the input date. Set Use_TZ to use the local time zone
358 -- (the value in formal Time_Zone is ignored) when building a time value
359 -- and to verify the validity of a requested leap second.
361 end Formatting_Operations;
363 ---------------------------
364 -- Time_Zones_Operations --
365 ---------------------------
367 package Time_Zones_Operations is
369 function UTC_Time_Offset (Date : Time) return Long_Integer;
370 -- Return (in seconds) the difference between the local time zone and
371 -- UTC time at a specific historic date.
373 end Time_Zones_Operations;
375 end Ada.Calendar;