gcc/ada/5aml-tgt.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             M L I B . T G T                              --
   6 --                             (True64 Version)                             --
   7 --                                                                          --
   8 --                                 B o d y                                  --
   9 --                                                                          --
  10 --              Copyright (C) 2002-2003 Free Software Foundation, Inc.      --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- GNAT was originally developed  by the GNAT team at  New York University. --
  24 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  25 --                                                                          --
  26 ------------------------------------------------------------------------------
  27
  28 --  This package provides a set of target dependent routines to build
  29 --  static, dynamic and shared libraries.
  30
  31 --  This is the True64 version of the body.
  32
  33 with MLib.Fil;
  34 with MLib.Utl;
  35 with Namet;  use Namet;
  36 with Opt;
  37 with Output; use Output;
  38 with Prj.Com;
  39 with System;
  40
  41 package body MLib.Tgt is
  42
  43    use GNAT;
  44    use MLib;
  45
  46    Expect_Unresolved : aliased String := "-Wl,-expect_unresolved,*";
  47
  48    No_Arguments        : aliased Argument_List         := (1 .. 0 => null);
  49    Empty_Argument_List : constant Argument_List_Access := No_Arguments'Access;
  50
  51    Wl_Init_String : aliased String         := "-Wl,-init";
  52    Wl_Init        : constant String_Access := Wl_Init_String'Access;
  53    Wl_Fini_String : aliased String         := "-Wl,-fini";
  54    Wl_Fini        : constant String_Access := Wl_Fini_String'Access;
  55
  56    Init_Fini_List :  constant Argument_List_Access :=
  57                        new Argument_List'(1 => Wl_Init,
  58                                           2 => null,
  59                                           3 => Wl_Fini,
  60                                           4 => null);
  61    --  Used to put switches for automatic elaboration/finalization
  62
  63    ---------------------
  64    -- Archive_Builder --
  65    ---------------------
  66
  67    function Archive_Builder return String is
  68    begin
  69       return "ar";
  70    end Archive_Builder;
  71
  72    -----------------------------
  73    -- Archive_Builder_Options --
  74    -----------------------------
  75
  76    function Archive_Builder_Options return String_List_Access is
  77    begin
  78       return new String_List'(1 => new String'("cr"));
  79    end Archive_Builder_Options;
  80
  81    -----------------
  82    -- Archive_Ext --
  83    -----------------
  84
  85    function Archive_Ext return  String is
  86    begin
  87       return "a";
  88    end Archive_Ext;
  89
  90    ---------------------
  91    -- Archive_Indexer --
  92    ---------------------
  93
  94    function Archive_Indexer return String is
  95    begin
  96       return "ranlib";
  97    end Archive_Indexer;
  98
  99    ---------------------------
 100    -- Build_Dynamic_Library --
 101    ---------------------------
 102
 103    procedure Build_Dynamic_Library
 104      (Ofiles       : Argument_List;
 105       Foreign      : Argument_List;
 106       Afiles       : Argument_List;
 107       Options      : Argument_List;
 108       Interfaces   : Argument_List;
 109       Lib_Filename : String;
 110       Lib_Dir      : String;
 111       Symbol_Data  : Symbol_Record;
 112       Driver_Name  : Name_Id := No_Name;
 113       Lib_Address  : String  := "";
 114       Lib_Version  : String  := "";
 115       Relocatable  : Boolean := False;
 116       Auto_Init    : Boolean := False)
 117    is
 118       pragma Unreferenced (Foreign);
 119       pragma Unreferenced (Afiles);
 120       pragma Unreferenced (Interfaces);
 121       pragma Unreferenced (Symbol_Data);
 122       pragma Unreferenced (Lib_Address);
 123       pragma Unreferenced (Relocatable);
 124
 125       Lib_File : constant String :=
 126         Lib_Dir & Directory_Separator & "lib" &
 127         Fil.Ext_To (Lib_Filename, DLL_Ext);
 128
 129       Version_Arg          : String_Access;
 130       Symbolic_Link_Needed : Boolean := False;
 131
 132       Init_Fini : Argument_List_Access := Empty_Argument_List;
 133
 134    begin
 135       if Opt.Verbose_Mode then
 136          Write_Str ("building relocatable shared library ");
 137          Write_Line (Lib_File);
 138       end if;
 139
 140       --  If specified, add automatic elaboration/finalization
 141
 142       if Auto_Init then
 143          Init_Fini := Init_Fini_List;
 144          Init_Fini (2) := new String'("-Wl," & Lib_Filename & "init");
 145          Init_Fini (4) := new String'("-Wl," & Lib_Filename & "final");
 146       end if;
 147
 148       if Lib_Version = "" then
 149          Utl.Gcc
 150            (Output_File => Lib_File,
 151             Objects     => Ofiles,
 152             Options     =>
 153               Options &
 154               Expect_Unresolved'Access &
 155               Init_Fini.all,
 156             Driver_Name => Driver_Name);
 157
 158       else
 159          Version_Arg := new String'("-Wl,-soname," & Lib_Version);
 160
 161          if Is_Absolute_Path (Lib_Version) then
 162             Utl.Gcc
 163               (Output_File => Lib_Version,
 164                Objects     => Ofiles,
 165                Options     =>
 166                  Options &
 167                  Version_Arg &
 168                  Expect_Unresolved'Access &
 169                  Init_Fini.all,
 170                Driver_Name => Driver_Name);
 171             Symbolic_Link_Needed := Lib_Version /= Lib_File;
 172
 173          else
 174             Utl.Gcc
 175               (Output_File => Lib_Dir & Directory_Separator & Lib_Version,
 176                Objects     => Ofiles,
 177                Options     =>
 178                  Options &
 179                  Version_Arg &
 180                  Expect_Unresolved'Access &
 181                  Init_Fini.all,
 182                Driver_Name => Driver_Name);
 183             Symbolic_Link_Needed :=
 184               Lib_Dir & Directory_Separator & Lib_Version /= Lib_File;
 185          end if;
 186
 187          if Symbolic_Link_Needed then
 188             declare
 189                Success : Boolean;
 190                Oldpath : String (1 .. Lib_Version'Length + 1);
 191                Newpath : String (1 .. Lib_File'Length + 1);
 192                Result  : Integer;
 193
 194                function Symlink
 195                  (Oldpath : System.Address;
 196                   Newpath : System.Address)
 197                   return    Integer;
 198                pragma Import (C, Symlink, "__gnat_symlink");
 199
 200             begin
 201                Oldpath (1 .. Lib_Version'Length) := Lib_Version;
 202                Oldpath (Oldpath'Last)            := ASCII.NUL;
 203                Newpath (1 .. Lib_File'Length)    := Lib_File;
 204                Newpath (Newpath'Last)            := ASCII.NUL;
 205
 206                Delete_File (Lib_File, Success);
 207
 208                Result := Symlink (Oldpath'Address, Newpath'Address);
 209             end;
 210          end if;
 211       end if;
 212    end Build_Dynamic_Library;
 213
 214    -------------------------
 215    -- Default_DLL_Address --
 216    -------------------------
 217
 218    function Default_DLL_Address return String is
 219    begin
 220       return "";
 221    end Default_DLL_Address;
 222
 223    -------------
 224    -- DLL_Ext --
 225    -------------
 226
 227    function DLL_Ext return String is
 228    begin
 229       return "so";
 230    end DLL_Ext;
 231
 232    --------------------
 233    -- Dynamic_Option --
 234    --------------------
 235
 236    function Dynamic_Option return String is
 237    begin
 238       return "-shared";
 239    end Dynamic_Option;
 240
 241    -------------------
 242    -- Is_Object_Ext --
 243    -------------------
 244
 245    function Is_Object_Ext (Ext : String) return Boolean is
 246    begin
 247       return Ext = ".o";
 248    end Is_Object_Ext;
 249
 250    --------------
 251    -- Is_C_Ext --
 252    --------------
 253
 254    function Is_C_Ext (Ext : String) return Boolean is
 255    begin
 256       return Ext = ".c";
 257    end Is_C_Ext;
 258
 259    --------------------
 260    -- Is_Archive_Ext --
 261    --------------------
 262
 263    function Is_Archive_Ext (Ext : String) return Boolean is
 264    begin
 265       return Ext = ".a" or else Ext = ".so";
 266    end Is_Archive_Ext;
 267
 268    -------------
 269    -- Libgnat --
 270    -------------
 271
 272    function Libgnat return String is
 273    begin
 274       return "libgnat.a";
 275    end Libgnat;
 276
 277    ------------------------
 278    -- Library_Exists_For --
 279    ------------------------
 280
 281    function Library_Exists_For (Project : Project_Id) return Boolean is
 282    begin
 283       if not Projects.Table (Project).Library then
 284          Prj.Com.Fail ("INTERNAL ERROR: Library_Exists_For called " &
 285                        "for non library project");
 286          return False;
 287
 288       else
 289          declare
 290             Lib_Dir : constant String :=
 291               Get_Name_String (Projects.Table (Project).Library_Dir);
 292             Lib_Name : constant String :=
 293               Get_Name_String (Projects.Table (Project).Library_Name);
 294
 295          begin
 296             if Projects.Table (Project).Library_Kind = Static then
 297                return Is_Regular_File
 298                  (Lib_Dir & Directory_Separator & "lib" &
 299                   Fil.Ext_To (Lib_Name, Archive_Ext));
 300
 301             else
 302                return Is_Regular_File
 303                  (Lib_Dir & Directory_Separator & "lib" &
 304                   Fil.Ext_To (Lib_Name, DLL_Ext));
 305             end if;
 306          end;
 307       end if;
 308    end Library_Exists_For;
 309
 310    ---------------------------
 311    -- Library_File_Name_For --
 312    ---------------------------
 313
 314    function Library_File_Name_For (Project : Project_Id) return Name_Id is
 315    begin
 316       if not Projects.Table (Project).Library then
 317          Prj.Com.Fail ("INTERNAL ERROR: Library_File_Name_For called " &
 318                        "for non library project");
 319          return No_Name;
 320
 321       else
 322          declare
 323             Lib_Name : constant String :=
 324               Get_Name_String (Projects.Table (Project).Library_Name);
 325
 326          begin
 327             Name_Len := 3;
 328             Name_Buffer (1 .. Name_Len) := "lib";
 329
 330             if Projects.Table (Project).Library_Kind = Static then
 331                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, Archive_Ext));
 332
 333             else
 334                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, DLL_Ext));
 335             end if;
 336
 337             return Name_Find;
 338          end;
 339       end if;
 340    end Library_File_Name_For;
 341
 342    --------------------------------
 343    -- Linker_Library_Path_Option --
 344    --------------------------------
 345
 346    function Linker_Library_Path_Option return String_Access is
 347    begin
 348       return new String'("-Wl,-rpath,");
 349    end Linker_Library_Path_Option;
 350
 351    ----------------
 352    -- Object_Ext --
 353    ----------------
 354
 355    function Object_Ext return String is
 356    begin
 357       return "o";
 358    end Object_Ext;
 359
 360    ----------------
 361    -- PIC_Option --
 362    ----------------
 363
 364    function PIC_Option return String is
 365    begin
 366       return "";
 367    end PIC_Option;
 368
 369    -----------------------------------------------
 370    -- Standalone_Library_Auto_Init_Is_Supported --
 371    -----------------------------------------------
 372
 373    function Standalone_Library_Auto_Init_Is_Supported return Boolean is
 374    begin
 375       return True;
 376    end Standalone_Library_Auto_Init_Is_Supported;
 377
 378    ---------------------------
 379    -- Support_For_Libraries --
 380    ---------------------------
 381
 382    function Support_For_Libraries return Library_Support is
 383    begin
 384       return Full;
 385    end Support_For_Libraries;
 386
 387 end MLib.Tgt;