gcc/gdbinit.in

   1 # Copyright (C) 2001, 2002, 2003, 2004, 2006,
   2 # 2008, 2010, 2012 Free Software Foundation, Inc.
   3 #
   4 # This file is part of GCC.
   5 #
   6 # GCC is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3, or (at your option)
   9 # any later version.
  10 #
  11 # GCC is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with GCC; see the file COPYING3.  If not see
  18 # <http://www.gnu.org/licenses/>.
  19
  20 define pr
  21 set debug_rtx ($)
  22 end
  23
  24 document pr
  25 Print the full structure of the rtx that is $.
  26 Works only when an inferior is executing.
  27 end
  28
  29 define prl
  30 set debug_rtx_list ($, debug_rtx_count)
  31 end
  32
  33 document prl
  34 Print the full structure of all rtx insns beginning at $.
  35 Works only when an inferior is executing.
  36 Uses variable debug_rtx_count to control number of insns printed:
  37   debug_rtx_count > 0: print from $ on.
  38   debug_rtx_count < 0: print a window around $.
  39
  40 There is also debug_rtx_find (rtx, uid) that will scan a list for UID and print
  41 it using debug_rtx_list. Usage example: set $foo=debug_rtx_find(first, 42)
  42 end
  43
  44 define pt
  45 set debug_tree ($)
  46 end
  47
  48 document pt
  49 Print the full structure of the tree that is $.
  50 Works only when an inferior is executing.
  51 end
  52
  53 define pct
  54 set debug_c_tree ($)
  55 end
  56
  57 document pct
  58 Print the tree that is $ in C syntax.
  59 Works only when an inferior is executing.
  60 end
  61
  62 define pgg
  63 set debug_gimple_stmt ($)
  64 end
  65
  66 document pgg
  67 Print the Gimple statement that is $ in C syntax.
  68 Works only when an inferior is executing.
  69 end
  70
  71 define pgq
  72 set debug_gimple_seq ($)
  73 end
  74
  75 document pgq
  76 Print the Gimple sequence that is $ in C syntax.
  77 Works only when an inferior is executing.
  78 end
  79
  80 define pgs
  81 set debug_generic_stmt ($)
  82 end
  83
  84 document pgs
  85 Print the statement that is $ in C syntax.
  86 Works only when an inferior is executing.
  87 end
  88
  89 define pge
  90 set debug_generic_expr ($)
  91 end
  92
  93 document pge
  94 Print the expression that is $ in C syntax.
  95 Works only when an inferior is executing.
  96 end
  97
  98 define ptc
  99 output (enum tree_code) $.common.code
 100 echo \n
 101 end
 102
 103 document ptc
 104 Print the tree-code of the tree node that is $.
 105 end
 106
 107 define pdn
 108 output $.decl_minimal.name->identifier.id.str
 109 echo \n
 110 end
 111
 112 document pdn
 113 Print the name of the decl-node that is $.
 114 end
 115
 116 define ptn
 117 output $.type.name->decl_minimal.name->identifier.id.str
 118 echo \n
 119 end
 120
 121 document ptn
 122 Print the name of the type-node that is $.
 123 end
 124
 125 define pvt
 126 set debug_vec_tree ($)
 127 end
 128
 129 document pvt
 130 Print the VEC(tree) that is in $.
 131 end
 132
 133 define pdd
 134 set debug_dwarf_die ($)
 135 end
 136
 137 document pdd
 138 Print the dw_die_ref that is in $.
 139 end
 140
 141 define prc
 142 output (enum rtx_code) $.code
 143 echo \ (
 144 output $.mode
 145 echo )\n
 146 end
 147
 148 document prc
 149 Print the rtx-code and machine mode of the rtx that is $.
 150 end
 151
 152 define pi
 153 print $.u.fld[0].rt_rtx@7
 154 end
 155
 156 document pi
 157 Print the fields of an instruction that is $.
 158 end
 159
 160 define pbs
 161 set print_binding_stack ()
 162 end
 163
 164 document pbs
 165 In cc1plus, print the current binding stack, frame by frame, up to and
 166 including the global binding level.
 167 end
 168
 169 define pbb
 170 set dump_bb ($, stderr, 0)
 171 end
 172
 173 document pbb
 174 Dump the basic block that is in $, including rtx.
 175 end
 176
 177 define pbm
 178 set bitmap_print (stderr, $, "", "\n")
 179 end
 180
 181 document pbm
 182 Dump the bitmap that is in $ as a comma-separated list of numbers.
 183 end
 184
 185 # Define some macros helpful to gdb when it is expanding macros.
 186 macro define __FILE__ "gdb"
 187 macro define __LINE__ 1
 188
 189 # Gracefully handle aborts in functions used from gdb.
 190 set unwindonsignal on
 191
 192 # Put breakpoints at exit and fancy_abort in case abort is mapped
 193 # to either fprintf/exit or fancy_abort.
 194 b fancy_abort
 195
 196 # Put a breakpoint on internal_error to help with debugging ICEs.
 197 b internal_error
 198
 199 set complaints 0
 200 # Don't let abort actually run, as it will make
 201 # stdio stop working and therefore the `pr' command above as well.
 202 # Put this last because gcc does not reference it any more unless
 203 # USE_SYSTEM_ABORT is defined, so gdb may complain and bail out.
 204 b exit
 205 b abort
 206
 207 # Skip all inline functions in tree.h.
 208 # These are used in accessor macros.
 209 # Note that this is added at the end because older gdb versions
 210 # do not understand the 'skip' command.
 211 skip file tree.h