libffi/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(fficonfig.h.in)
   3 AM_CONFIG_HEADER(fficonfig.h)
   4
   5 # This works around the fact that libtool configuration may change LD
   6 # for this particular configuration, but some shells, instead of
   7 # keeping the changes in LD private, export them just because LD is
   8 # exported.
   9 ORIGINAL_LD_FOR_MULTILIBS=$LD
  10
  11 dnl Default to --enable-multilib
  12 AC_ARG_ENABLE(multilib,
  13 [  --enable-multilib       build many library versions (default)],
  14 [case "${enableval}" in
  15   yes) multilib=yes ;;
  16   no)  multilib=no ;;
  17   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  18  esac], [multilib=yes])dnl
  19
  20 dnl We may get other options which we don't document:
  21 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  22
  23 if test "${srcdir}" = "."; then
  24   if test "${with_target_subdir}" != "."; then
  25     libffi_basedir="${with_multisrctop}../"
  26   else
  27     libffi_basedir="${with_multisrctop}"
  28   fi
  29 else
  30   libffi_basedir=
  31 fi
  32 AC_SUBST(libffi_basedir)
  33 AC_CONFIG_AUX_DIR(${libffi_basedir}..)
  34
  35 AC_CANONICAL_HOST
  36
  37 AM_PROG_LIBTOOL
  38
  39 AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define)
  40
  41 AC_EXEEXT
  42 AM_MAINTAINER_MODE
  43
  44 AC_PROG_CC
  45 AC_PROG_LIBTOOL
  46
  47 TARGETDIR="unknown"
  48 case "$host" in
  49 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; TARGETDIR=mips;;
  50 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  51 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  52 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  53 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
  54 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
  55 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  56 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  57 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  58 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  59 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  60 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
  61 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
  62 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
  63 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  64 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  65 mips64*-*);;
  66 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  67 powerpc-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  68 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  69 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  70 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  71 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  72 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  73 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  74 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  75 x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
  76 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  77 esac
  78
  79 if test $TARGETDIR = unknown; then
  80   AC_ERROR("libffi has not been ported to $host.")
  81 fi
  82
  83 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
  84 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
  85 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  86 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  87 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  88 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
  89 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
  90 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
  91 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
  92 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
  93 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
  94 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
  95 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
  96 AM_CONDITIONAL(S390, test x$TARGET = xS390)
  97 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
  98 AM_CONDITIONAL(SH, test x$TARGET = xSH)
  99
 100 if test x$TARGET = xMIPS_LINUX; then
 101   TARGET=MIPS
 102 fi
 103
 104 AC_HEADER_STDC
 105 AC_CHECK_FUNCS(memcpy)
 106 AC_FUNC_ALLOCA
 107
 108 dnl AC_CHECK_SIZEOF(char)
 109 AC_COMPILE_CHECK_SIZEOF(short)
 110 AC_COMPILE_CHECK_SIZEOF(int)
 111 AC_COMPILE_CHECK_SIZEOF(long)
 112 AC_COMPILE_CHECK_SIZEOF(long long)
 113 AC_COMPILE_CHECK_SIZEOF(float)
 114 AC_COMPILE_CHECK_SIZEOF(double)
 115 AC_COMPILE_CHECK_SIZEOF(long double)
 116
 117 AC_COMPILE_CHECK_SIZEOF(void *)
 118 AC_C_BIGENDIAN_CROSS
 119
 120 if test x$TARGET = xSPARC; then
 121     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 122         libffi_cv_as_sparc_ua_pcrel, [
 123         save_CFLAGS="$CFLAGS"
 124         save_LDFLAGS="$LDFLAGS"
 125         CFLAGS="$CFLAGS -fpic"
 126         LDFLAGS="$LDFLAGS -shared"
 127         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 128                     [libffi_cv_as_sparc_ua_pcrel=yes],
 129                     [libffi_cv_as_sparc_ua_pcrel=no])
 130         CFLAGS="$save_CFLAGS"
 131         LDFLAGS="$save_LDFLAGS"])
 132     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 133         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 134                   [Define if your assembler and linker support unaligned PC relative relocs.])
 135     fi
 136 fi
 137
 138 AC_SUBST(TARGET)
 139 AC_SUBST(TARGETDIR)
 140
 141 AC_SUBST(SHELL)
 142
 143 AC_ARG_ENABLE(debug,
 144 [  --enable-debug          debugging mode],
 145   if test "$enable_debug" = "yes"; then
 146     AC_DEFINE(FFI_DEBUG)
 147   fi)
 148
 149 AC_ARG_ENABLE(structs,
 150 [  --disable-structs       omit code for struct support],
 151   if test "$enable_structs" = "no"; then
 152     AC_DEFINE(FFI_NO_STRUCTS)
 153   fi)
 154
 155 AC_ARG_ENABLE(raw-api,
 156 [  --disable-raw-api       make the raw api unavailable],
 157   if test "$enable_raw_api" = "no"; then
 158     AC_DEFINE(FFI_NO_RAW_API)
 159   fi)
 160
 161 AC_ARG_ENABLE(purify-safety,
 162 [  --enable-purify-safety  purify-safe mode],
 163   if test "$enable_purify_safety" = "yes"; then
 164     AC_DEFINE(USING_PURIFY)
 165   fi)
 166
 167 if test -n "$with_cross_host" &&
 168    test x"$with_cross_host" != x"no"; then
 169   toolexecdir='$(exec_prefix)/$(target_alias)'
 170   toolexeclibdir='$(toolexecdir)/lib'
 171 else
 172   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 173   toolexeclibdir='$(libdir)'
 174 fi
 175 toolexeclibdir=$toolexeclibdir/`$CC -print-multi-os-directory`
 176 AC_SUBST(toolexecdir)
 177 AC_SUBST(toolexeclibdir)
 178
 179 if test "${multilib}" = "yes"; then
 180   multilib_arg="--enable-multilib"
 181 else
 182   multilib_arg=
 183 fi
 184
 185 AC_OUTPUT(include/Makefile include/ffi.h Makefile,
 186 [
 187 if test -n "$CONFIG_FILES"; then
 188    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 189    ac_file=Makefile . ${srcdir}/${libffi_basedir}../config-ml.in
 190 fi
 191 ],
 192 srcdir=${srcdir}
 193 host=${host}
 194 target=${target}
 195 with_multisubdir=${with_multisubdir}
 196 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 197 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 198 libffi_basedir=${libffi_basedir}
 199 CC="${CC}"
 200 DEFS="$DEFS"
 201 test ! -d include && mkdir include
 202 test ! -f include/fficonfig.h && cp fficonfig.h include/fficonfig.h
 203 if cmp -s fficonfig.h include/fficonfig.h 2>/dev/null; then
 204         echo fficonfig.h unchanged
 205 else
 206         echo Moving fficonfig.h to include/fficonfig.h
 207         cp fficonfig.h include/fficonfig.h
 208 fi
 209 )
 210
 211 # Make target subdirectories if required.
 212 test -d src || mkdir src
 213 test -d src/${TARGETDIR} || mkdir src/${TARGETDIR}