zlib/configure.in

   1 dnl Process this with autoconf to create configure
   2
   3 AC_INIT(zlib.h)
   4 AC_CANONICAL_SYSTEM
   5 AM_INIT_AUTOMAKE(zlib, 1.1.3)
   6
   7 AM_MAINTAINER_MODE
   8
   9 AC_CONFIG_AUX_DIR(..)
  10
  11 dnl We use these options to decide which functions to include.
  12 AC_ARG_WITH(target-subdir,
  13 [  --with-target-subdir=SUBDIR
  14                           configuring in a subdirectory])
  15 AC_ARG_WITH(cross-host,
  16 [  --with-cross-host=HOST  configuring with a cross compiler])
  17
  18 dnl Default to --enable-multilib
  19 AC_ARG_ENABLE(multilib,
  20 [  --enable-multilib       build many library versions (default)],
  21 [case "${enableval}" in
  22   yes) multilib=yes ;;
  23   no)  multilib=no ;;
  24   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  25  esac], [test -z "$with_target_subdir" && multilib=no || multilib=yes])dnl
  26
  27 dnl We may get other options which we dont document:
  28 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  29
  30 if test "x[$]{with_target_subdir}" != x && \
  31    test "[$]{srcdir}" = "."; then
  32   if test "[$]{with_target_subdir}" != "."; then
  33     zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}../"
  34   else
  35     zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}"
  36   fi
  37 else
  38   zlib_basedir="[$]{srcdir}/"
  39 fi
  40 AC_SUBST(zlib_basedir)
  41
  42 AC_ARG_WITH(system-zlib,
  43 [  --with-system-zlib      use installed libz])
  44
  45 LIB_AC_PROG_CC
  46 # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
  47 # at least currently, we never actually build a program, so we never
  48 # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
  49 # fails, because we are probably configuring with a cross compiler
  50 # which cant create executables.  So we include AC_EXEEXT to keep
  51 # automake happy, but we dont execute it, since we dont care about
  52 # the result.
  53 if false; then
  54   AC_EXEEXT
  55 fi
  56 AM_PROG_LIBTOOL
  57
  58 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  59    COMPPATH=.
  60 else
  61    COMPPATH=..
  62 fi
  63 AC_SUBST(COMPPATH)
  64
  65 # Find CPP now so that any conditional tests below won't do it and
  66 # thereby make the resulting definitions conditional.
  67 AC_PROG_CPP
  68
  69 if test -n "$with_cross_host"; then
  70    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
  71    # may not work correctly, because the compiler may not be able to
  72    # link executables.
  73
  74    # We assume newlib.  This lets us hard-code the functions we know
  75    # we'll have.
  76    AC_DEFINE(HAVE_MEMCPY)
  77    AC_DEFINE(HAVE_STRERROR)
  78
  79    # We ignore --with-system-zlib in this case.
  80    target_all=libzgcj.la
  81 else
  82    AC_FUNC_MMAP
  83    AC_CHECK_FUNCS(memcpy strerror)
  84
  85    if test "$with_system_zlib" = yes; then
  86       AC_CHECK_LIB(z, deflate, target_all=, target_all=libzgcj.la)
  87    else
  88       target_all=libzgcj.la
  89    fi
  90 fi
  91
  92 AC_SUBST(target_all)
  93
  94 AC_CHECK_HEADERS(unistd.h)
  95
  96 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
  97 AM_CONDITIONAL(TARGET_LIBRARY, test -n "$with_target_subdir")
  98
  99 if test "${multilib}" = "yes"; then
 100   multilib_arg="--enable-multilib"
 101 else
 102   multilib_arg=
 103 fi
 104
 105 AC_OUTPUT(Makefile,
 106 [if test -n "$CONFIG_FILES"; then
 107   ac_file=Makefile . ${zlib_basedir}/../config-ml.in
 108 fi],
 109 srcdir=${srcdir}
 110 host=${host}
 111 target=${target}
 112 with_multisubdir=${with_multisubdir}
 113 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 114 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 115 zlib_basedir=${zlib_basedir}
 116 CC="${CC}"
 117 CXX="${CXX}"
 118 )