gcc/ada/5atpopsp.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --    S Y S T E M . T A S K _ P R I M I T I V E S . O P E R A T I O N S .   --
   6 --                              S P E C I F I C                             --
   7 --                                                                          --
   8 --                                  B o d y                                 --
   9 --                                                                          --
  10 --         Copyright (C) 1992-2001, Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNARL was developed by the GNARL team at Florida State University.       --
  31 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is a POSIX version of this package where foreign threads are
  36 --  recognized.
  37 --  Currently, DEC Unix, SCO UnixWare, Solaris pthread, HPUX pthread,
  38 --  GNU/Linux threads and RTEMS use this version.
  39
  40 with System.Task_Info;
  41 --  Use for Unspecified_Task_Info
  42
  43 with System.Soft_Links;
  44 --  used to initialize TSD for a C thread, in function Self
  45
  46 separate (System.Task_Primitives.Operations)
  47 package body Specific is
  48
  49    ------------------
  50    --  Local Data  --
  51    ------------------
  52
  53    --  The followings are logically constants, but need to be initialized
  54    --  at run time.
  55
  56    ATCB_Key : aliased pthread_key_t;
  57    --  Key used to find the Ada Task_ID associated with a thread
  58
  59    --  The following are used to allow the Self function to
  60    --  automatically generate ATCB's for C threads that happen to call
  61    --  Ada procedure, which in turn happen to call the Ada runtime system.
  62
  63    type Fake_ATCB;
  64    type Fake_ATCB_Ptr is access Fake_ATCB;
  65    type Fake_ATCB is record
  66       Stack_Base : Interfaces.C.unsigned := 0;
  67       --  A value of zero indicates the node is not in use.
  68       Next : Fake_ATCB_Ptr;
  69       Real_ATCB : aliased Ada_Task_Control_Block (0);
  70    end record;
  71
  72    Fake_ATCB_List : Fake_ATCB_Ptr;
  73    --  A linear linked list.
  74    --  The list is protected by Single_RTS_Lock;
  75    --  Nodes are added to this list from the front.
  76    --  Once a node is added to this list, it is never removed.
  77
  78    Fake_Task_Elaborated : aliased Boolean := True;
  79    --  Used to identified fake tasks (i.e., non-Ada Threads).
  80
  81    Next_Fake_ATCB : Fake_ATCB_Ptr;
  82    --  Used to allocate one Fake_ATCB in advance. See comment in New_Fake_ATCB
  83
  84    -----------------------
  85    -- Local Subprograms --
  86    -----------------------
  87
  88    ---------------------------------
  89    --  Support for New_Fake_ATCB  --
  90    ---------------------------------
  91
  92    function New_Fake_ATCB return Task_ID;
  93    --  Allocate and Initialize a new ATCB. This code can safely be called from
  94    --  a foreign thread, as it doesn't access implicitly or explicitly
  95    --  "self" before having initialized the new ATCB.
  96
  97    -------------------
  98    -- New_Fake_ATCB --
  99    -------------------
 100
 101    function New_Fake_ATCB return Task_ID is
 102       Self_ID   : Task_ID;
 103       P, Q      : Fake_ATCB_Ptr;
 104       Succeeded : Boolean;
 105       Result    : Interfaces.C.int;
 106
 107    begin
 108       --  This section is ticklish.
 109       --  We dare not call anything that might require an ATCB, until
 110       --  we have the new ATCB in place.
 111
 112       Lock_RTS;
 113       Q := null;
 114       P := Fake_ATCB_List;
 115
 116       while P /= null loop
 117          if P.Stack_Base = 0 then
 118             Q := P;
 119          end if;
 120
 121          P := P.Next;
 122       end loop;
 123
 124       if Q = null then
 125
 126          --  Create a new ATCB with zero entries.
 127
 128          Self_ID := Next_Fake_ATCB.Real_ATCB'Access;
 129          Next_Fake_ATCB.Stack_Base := 1;
 130          Next_Fake_ATCB.Next := Fake_ATCB_List;
 131          Fake_ATCB_List := Next_Fake_ATCB;
 132          Next_Fake_ATCB := null;
 133
 134       else
 135          --  Reuse an existing fake ATCB.
 136
 137          Self_ID := Q.Real_ATCB'Access;
 138          Q.Stack_Base := 1;
 139       end if;
 140
 141       --  Record this as the Task_ID for the current thread.
 142
 143       Self_ID.Common.LL.Thread := pthread_self;
 144       Result := pthread_setspecific (ATCB_Key, To_Address (Self_ID));
 145       pragma Assert (Result = 0);
 146
 147       --  Do the standard initializations
 148
 149       System.Tasking.Initialize_ATCB
 150         (Self_ID, null, Null_Address, Null_Task, Fake_Task_Elaborated'Access,
 151          System.Priority'First, Task_Info.Unspecified_Task_Info, 0, Self_ID,
 152          Succeeded);
 153       pragma Assert (Succeeded);
 154
 155       --  Finally, it is safe to use an allocator in this thread.
 156
 157       if Next_Fake_ATCB = null then
 158          Next_Fake_ATCB := new Fake_ATCB;
 159       end if;
 160
 161       Self_ID.Master_of_Task := 0;
 162       Self_ID.Master_Within := Self_ID.Master_of_Task + 1;
 163
 164       for L in Self_ID.Entry_Calls'Range loop
 165          Self_ID.Entry_Calls (L).Self := Self_ID;
 166          Self_ID.Entry_Calls (L).Level := L;
 167       end loop;
 168
 169       Self_ID.Common.State := Runnable;
 170       Self_ID.Awake_Count := 1;
 171
 172       --  Since this is not an ordinary Ada task, we will start out undeferred
 173
 174       Self_ID.Deferral_Level := 0;
 175
 176       System.Soft_Links.Create_TSD (Self_ID.Common.Compiler_Data);
 177
 178       --  ????
 179       --  The following call is commented out to avoid dependence on
 180       --  the System.Tasking.Initialization package.
 181       --  It seems that if we want Ada.Task_Attributes to work correctly
 182       --  for C threads we will need to raise the visibility of this soft
 183       --  link to System.Soft_Links.
 184       --  We are putting that off until this new functionality is otherwise
 185       --  stable.
 186       --  System.Tasking.Initialization.Initialize_Attributes_Link.all (T);
 187
 188       for J in Known_Tasks'Range loop
 189          if Known_Tasks (J) = null then
 190             Known_Tasks (J) := Self_ID;
 191             Self_ID.Known_Tasks_Index := J;
 192             exit;
 193          end if;
 194       end loop;
 195
 196       --  Must not unlock until Next_ATCB is again allocated.
 197
 198       Unlock_RTS;
 199       return Self_ID;
 200    end New_Fake_ATCB;
 201
 202    ----------------
 203    -- Initialize --
 204    ----------------
 205
 206    procedure Initialize (Environment_Task : Task_ID) is
 207       Result : Interfaces.C.int;
 208    begin
 209       Result := pthread_key_create (ATCB_Key'Access, null);
 210       pragma Assert (Result = 0);
 211       Result := pthread_setspecific (ATCB_Key, To_Address (Environment_Task));
 212       pragma Assert (Result = 0);
 213
 214       --  Create a free ATCB for use on the Fake_ATCB_List.
 215
 216       Next_Fake_ATCB := new Fake_ATCB;
 217    end Initialize;
 218
 219    ---------
 220    -- Set --
 221    ---------
 222
 223    procedure Set (Self_Id : Task_ID) is
 224       Result  : Interfaces.C.int;
 225    begin
 226       Result := pthread_setspecific (ATCB_Key, To_Address (Self_Id));
 227       pragma Assert (Result = 0);
 228    end Set;
 229
 230    ----------
 231    -- Self --
 232    ----------
 233
 234    --  To make Ada tasks and C threads interoperate better, we have added some
 235    --  functionality to Self. Suppose a C main program (with threads) calls an
 236    --  Ada procedure and the Ada procedure calls the tasking runtime system.
 237    --  Eventually, a call will be made to self. Since the call is not coming
 238    --  from an Ada task, there will be no corresponding ATCB.
 239
 240    --  What we do in Self is to catch references that do not come from
 241    --  recognized Ada tasks, and create an ATCB for the calling thread.
 242
 243    --  The new ATCB will be "detached" from the normal Ada task master
 244    --  hierarchy, much like the existing implicitly created signal-server
 245    --  tasks.
 246
 247    function Self return Task_ID is
 248       Result : System.Address;
 249    begin
 250       Result := pthread_getspecific (ATCB_Key);
 251
 252       --  If the key value is Null, then it is a non-Ada task.
 253
 254       if Result = System.Null_Address then
 255          return New_Fake_ATCB;
 256       end if;
 257
 258       return To_Task_ID (Result);
 259    end Self;
 260
 261 end Specific;