libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_ENABLE(java-maintainer-mode,
  81         AS_HELP_STRING([--enable-java-maintainer-mode],
  82         [allow rebuilding of .class and .h files]))
  83 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
  99 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 100 save_CXXFLAGS="$CXXFLAGS"
 101 CXXFLAGS="$CXXFLAGS -fno-builtin"
 102 AC_PROG_CC
 103 AC_PROG_CXX
 104 CXXFLAGS="$save_CXXFLAGS"
 105 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 106 AC_SUBST(CFLAGS)
 107 AC_SUBST(CXXFLAGS)
 108 AC_SUBST(LDFLAGS)
 109
 110 AM_INIT_AUTOMAKE([1.9.0])
 111
 112 AC_CHECK_TOOL(AS, as)
 113 AC_CHECK_TOOL(LD, ld)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116 AC_PROG_AWK
 117 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 118 AC_PATH_PROG([ZIP], [zip], no)
 119 AC_PATH_PROG([UNZIP], [unzip], unzip)
 120
 121 # We need a jar that supports -@.  This is a GNU extension.
 122 if test "$JAR" != no; then
 123    rm -f config-test.jar
 124    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 125    if test -f config-test.jar; then
 126      rm -f config-test.jar
 127    else
 128      JAR=no
 129    fi
 130 fi
 131
 132 # Prefer the jar we found, but fall back to our jar script.
 133 if test "$JAR" = no; then
 134   if test "$ZIP" = no; then
 135     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 136   else
 137     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 138     JAR=`pwd`/scripts/jar
 139   fi
 140 fi
 141
 142 AC_PROG_INSTALL
 143
 144 AM_MAINTAINER_MODE
 145
 146 AC_EXEEXT
 147
 148 # configure.host sets the following important variables
 149 #       libgcj_cflags    - host specific C compiler flags
 150 #       libgcj_cxxflags  - host specific C++ compiler flags
 151 #       libgcj_javaflags - host specific Java compiler flags
 152
 153 libgcj_cflags=
 154 libgcj_cxxflags=
 155 libgcj_javaflags=
 156
 157 . ${srcdir}/configure.host
 158
 159 ACX_PROG_LD_GNU_SYMBOLIC
 160 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 161 if test -z "$libgcj_ld_symbolic"; then
 162   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 163 fi
 164
 165 LIBGCJ_CFLAGS="${libgcj_cflags}"
 166 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 167 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 168 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 169 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 170 AC_SUBST(LIBGCJ_CFLAGS)
 171 AC_SUBST(LIBGCJ_CXXFLAGS)
 172 AC_SUBST(LIBGCJ_JAVAFLAGS)
 173 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 174 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 175
 176 # Only use libltdl for non-newlib builds.
 177 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 178    AC_LTDL_SHLIBPATH
 179 fi
 180
 181 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 182
 183 # See if the user has requested runtime debugging.
 184 LIBGCJDEBUG="disable"
 185 AC_SUBST(LIBGCJDEBUG)
 186 AC_ARG_ENABLE(libgcj-debug,
 187   AS_HELP_STRING([--enable-libgcj-debug],
 188                  [enable runtime debugging code]),
 189   [if test "$enable_libgcj_debug" = yes; then
 190     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 191     LIBGCJDEBUG="enable"
 192   fi])
 193
 194 AC_ARG_WITH([escher],
 195          AS_HELP_STRING([--with-escher=ABS.PATH],
 196                         [specify path to escher dir or JAR for X peers]))
 197 case "$with_escher" in
 198 "")
 199         use_escher=false
 200         ;;
 201 "no")
 202         use_escher=false
 203         ;;
 204 "yes")
 205         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 206         ;;
 207 *)
 208         use_escher=true
 209         ;;
 210 esac
 211
 212 # Determine which AWT peer libraries to build
 213 AC_ARG_ENABLE(java-awt,
 214   AS_HELP_STRING([--enable-java-awt],
 215                  [list of AWT peer implementations to be built]))
 216
 217 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 218 use_xlib_awt=""
 219 use_gtk_awt=""
 220 use_qt_awt=""
 221 use_x_awt=""
 222 # The default toolkit to use is the first one specified.
 223 TOOLKIT=
 224 AC_SUBST(TOOLKIT)
 225
 226 for peer in $peerlibs ; do
 227   case $peer in
 228     xlib)
 229       if test "$no_x" = yes; then
 230         echo "*** xlib peers requested but no X library available" 1>&2
 231         exit 1
 232       else
 233         use_xlib_awt="yes"
 234         if test -z "$TOOLKIT"; then
 235            TOOLKIT=gnu.awt.xlib.XToolkit
 236         fi
 237       fi
 238       ;;
 239     gtk)
 240       if test "$no_x" = yes; then
 241          echo "*** gtk peers requested but no X library available" 1>&2
 242          exit 1
 243       else
 244          use_gtk_awt=yes
 245          if test -z "$TOOLKIT"; then
 246             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 247          fi
 248       fi
 249       ;;
 250     qt)
 251       if test "$no_x" = yes; then
 252          # Perhaps we should admit the possibility of embedded Qt.
 253          echo "*** Qt peers requested but no X library available" 1>&2
 254          exit 1
 255       else
 256          use_qt_awt=yes
 257          if test -z "$TOOLKIT"; then
 258             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 259          fi
 260       fi
 261       ;;
 262     x)
 263       use_x_awt=yes
 264       if test -z "$TOOLKIT"; then
 265          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 266       fi
 267       ;;
 268     no)
 269       use_xlib_awt=
 270       use_gtk_awt=
 271       use_qt_awt=
 272       use_x_awt=
 273       break
 274       ;;
 275     *)
 276       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 277       exit 1
 278   esac
 279 done
 280
 281 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 282 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 283
 284 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 285
 286 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 287
 288 # Create standard.omit based on decisions we just made.
 289 cp $srcdir/standard.omit.in standard.omit
 290 if test "$use_xlib_awt" != yes; then
 291    echo gnu/awt/xlib >> standard.omit
 292    echo gnu/gcj/xlib >> standard.omit
 293 fi
 294 if test "$use_x_awt" != yes; then
 295    echo gnu/java/awt/peer/x >> standard.omit
 296 fi
 297
 298 # Tools that need to be compiled against classpath's tools classes
 299 : > vm-tools-packages
 300 for package in gnu/gcj/tools/gc_analyze ; do
 301     echo $package >> standard.omit
 302     echo $package >> vm-tools-packages
 303 done
 304
 305 if test -z "${with_multisubdir}"; then
 306    builddotdot=.
 307 else
 308    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 309 fi
 310
 311 NATIVE=yes
 312
 313 # Which gcj and host gcj (for ecjx) do we use?
 314 which_gcj=default
 315 host_exeext=${ac_exeext}
 316 GCJ_FOR_ECJX=
 317 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 318 if test -n "${with_cross_host}"; then
 319   # We are being configured with a cross compiler. We can't
 320   # use ac_exeext, because that is for the target platform.
 321   NATIVE=no
 322   cross_host_exeext=
 323   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 324   case "${with_cross_host}" in
 325      *mingw* | *cygwin*)
 326          cross_host_exeext=.exe
 327      ;;
 328   esac
 329   host_exeext=${cross_host_exeext}
 330   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 331      if test x"$build_noncanonical" = x"$with_cross_host"; then
 332         # Ordinary cross (host!=target and host=build)
 333         which_gcj=built
 334      else
 335         # Canadian cross (host!=target and host!=build)
 336         which_gcj=cross
 337      fi
 338   else
 339      which_gcj=cross
 340   fi
 341 else
 342   # We are being configured with a native or crossed-native compiler
 343   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 344      if test x"$build" = x"$host"; then
 345         # True native build (host=target and host=build)
 346         which_gcj=built
 347      else
 348         # Crossed-native build (host=target and host!=build)
 349         which_gcj=cross
 350      fi
 351   else
 352      which_gcj=path
 353   fi
 354 fi
 355 case "${which_gcj}" in
 356    built)
 357       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 358       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 359    ;;
 360    cross)
 361       if test "x${with_newlib}" = "xyes"; then
 362          # FIXME (comment): Why is this needed?
 363          GCC_UNWIND_INCLUDE=
 364          GCJ="${target_noncanonical}-gcj"
 365       else
 366          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 367       fi
 368       GCJH='$(target_noncanonical)-gcjh'
 369    ;;
 370    path)
 371       GCJ="gcj -B`${PWDCMD-pwd}`/"
 372       GCJH=gcjh
 373    ;;
 374 esac
 375
 376 AC_SUBST(GCJ_FOR_ECJX)
 377 AC_SUBST(GCJH)
 378 AC_SUBST(host_exeext)
 379
 380 # Create it, so that compile/link tests don't fail
 381 test -f libgcj.spec || touch libgcj.spec
 382
 383
 384
 385 # Set up to configure Classpath.
 386 # FIXME: no supported way to pass args in autoconf.
 387 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 388 # Disable tool wrappers to avoid ltdl.h configure check.
 389 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 390 ac_configure_args="$ac_configure_args --disable-load-library"
 391 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 392 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 393 dir1=`cd $srcdir && pwd`
 394 dir2=`pwd`
 395 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 396 ac_configure_args="$ac_configure_args --disable-core-jni"
 397 dnl FIXME?
 398 ac_configure_args="$ac_configure_args --disable-examples"
 399 ac_configure_args="$ac_configure_args --with-glibj=build"
 400 if test "$plugin_enabled" != yes; then
 401   ac_configure_args="$ac_configure_args --disable-plugin"
 402 fi
 403 if test "$gconf_enabled" != yes; then
 404   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 405   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 406 fi
 407 if test "$use_gtk_awt" != yes; then
 408   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 409 fi
 410 if test "$use_qt_awt" != yes; then
 411   ac_configure_args="$ac_configure_args --disable-qt-peer"
 412 else
 413   # We need this as qt is disabled by default in classpath.
 414   ac_configure_args="$ac_configure_args --enable-qt-peer"
 415 fi
 416 if test "$use_x_awt" != yes; then
 417   ac_configure_args="$ac_configure_args --without-escher"
 418 else
 419   # We need this as escher is disabled by default in classpath.
 420   if test "$use_escher" != true; then
 421     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 422   else
 423     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 424   fi
 425 fi
 426 # -Werror causes unavoidable problems in code using alsa.
 427 ac_configure_args="$ac_configure_args --disable-Werror"
 428 dnl --with-gcj=$GCJ
 429 dnl --with-javah=$GCJH
 430 dnl gjdoc?
 431 dnl gtk-cairo -- just export here...
 432 dnl --enable-regen-headers?
 433
 434 # Only use libltdl for non-newlib builds.
 435 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 436    AC_LIBLTDL_CONVENIENCE
 437    AC_LIBTOOL_DLOPEN
 438    DIRLTDL=libltdl
 439    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 440    # Sigh.  Libtool's macro doesn't do the right thing.
 441    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 442    # FIXME: this is a hack.
 443    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 444    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 445 fi
 446 AC_SUBST(INCLTDL)
 447 AC_SUBST(LIBLTDL)
 448 AC_SUBST(DIRLTDL)
 449 AC_PROG_LIBTOOL
 450 AM_PROG_GCJ
 451 AM_PROG_CC_C_O
 452
 453 AC_CONFIG_SUBDIRS(classpath libltdl)
 454
 455 # The -no-testsuite modules omit the test subdir.
 456 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 457
 458 # Should the runtime set system properties by examining the
 459 # environment variable GCJ_PROPERTIES?
 460 AC_ARG_ENABLE(getenv-properties,
 461   AS_HELP_STRING([--disable-getenv-properties],
 462                  [don't set system properties from GCJ_PROPERTIES]))
 463
 464 # Whether GCJ_PROPERTIES is used depends on the target.
 465 if test -z "$enable_getenv_properties"; then
 466    enable_getenv_properties=${enable_getenv_properties_default-yes}
 467 fi
 468 if test "$enable_getenv_properties" = no; then
 469    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 470      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 471 fi
 472
 473 # Whether we should use arguments to main()
 474 if test -z "$enable_main_args"; then
 475    enable_main_args=${enable_main_args_default-yes}
 476 fi
 477 if test "$enable_main_args" = no; then
 478    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 479 fi
 480
 481
 482 # Should we use hashtable-based synchronization?
 483 # Currently works only for Linux X86/ia64
 484 # Typically faster and more space-efficient
 485 AC_ARG_ENABLE(hash-synchronization,
 486   AS_HELP_STRING([--enable-hash-synchronization],
 487                  [use global hash table for monitor locks]))
 488
 489 if test -z "$enable_hash_synchronization"; then
 490    enable_hash_synchronization=$enable_hash_synchronization_default
 491 fi
 492
 493
 494 install_ecj_jar=no
 495 ECJ_BUILD_JAR=
 496 ECJ_JAR=
 497 AC_ARG_WITH(ecj-jar,
 498         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 499         [ECJ_JAR=$withval],
 500         [if test -f $multi_basedir/ecj.jar; then
 501            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 502            ECJ_JAR='$(jardir)/ecj.jar'
 503            install_ecj_jar=yes
 504          fi])
 505 AC_SUBST(ECJ_BUILD_JAR)
 506 AC_SUBST(ECJ_JAR)
 507 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 508 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 509
 510 AC_ARG_WITH(java-home,
 511   AS_HELP_STRING([--with-java-home=DIRECTORY],
 512                  [value of java.home system property]),
 513                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 514 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 515 AC_SUBST(JAVA_HOME)
 516
 517 suppress_libgcj_bc=no
 518 AC_ARG_ENABLE(libgcj-bc,
 519   AS_HELP_STRING([--enable-libgcj-bc],
 520                  [enable(default) or disable BC ABI for portions of libgcj]),
 521   [if test "$enable_libgcj_bc" = "no"; then
 522      suppress_libgcj_bc=yes
 523    fi])
 524 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 525
 526 # What is the native OS API for MinGW?
 527 AC_ARG_WITH(win32-nlsapi,
 528   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 529                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 530 [case "${withval}" in
 531   ansi) with_win32_nlsapi=ansi ;;
 532   unicows) with_win32_nlsapi=unicows ;;
 533   unicode) with_win32_nlsapi=unicode ;;
 534   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 535 esac],[with_win32_nlsapi=ansi])
 536
 537 case "${with_win32_nlsapi}" in
 538   unicows | unicode)
 539     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 540       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 541     ;;
 542 esac
 543
 544 # configure.host sets slow_pthread_self if the synchronization code should
 545 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 546 if test "${slow_pthread_self}" = "yes"; then
 547   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 548     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 549 fi
 550
 551 # Check for gc debugging.  This option is handled both here and in the GC.
 552 AC_ARG_ENABLE(gc-debug,
 553    AS_HELP_STRING([--enable-gc-debug],
 554                   [include full support for pointer backtracing etc.]),
 555 [ if test "$enable_gc_debug" = "yes"; then
 556     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 557               [Define if we want to use debug calls into the garbage collector.])
 558   fi])
 559
 560 # See if the user has the interpreter included.
 561 AC_ARG_ENABLE(interpreter,
 562   AS_HELP_STRING([--enable-interpreter],
 563                  [enable interpreter]),
 564   [if test "$enable_interpreter" = yes; then
 565     # This can also be set in configure.host.
 566     libgcj_interpreter=yes
 567   elif test "$enable_interpreter" = no; then
 568     libgcj_interpreter=no
 569   fi])
 570
 571 if test "$libgcj_interpreter" = yes; then
 572    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 573 fi
 574 INTERPRETER="$libgcj_interpreter"
 575 AC_SUBST(INTERPRETER)
 576 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 577
 578 AC_MSG_CHECKING([for exception model to use])
 579 AC_LANG_PUSH(C++)
 580 AC_ARG_ENABLE(sjlj-exceptions,
 581   AS_HELP_STRING([--enable-sjlj-exceptions],
 582                  [force use of builtin_setjmp for exceptions]),
 583 [:],
 584 [dnl Botheration.  Now we've got to detect the exception model.
 585 dnl Link tests against libgcc.a are problematic since -- at least
 586 dnl as of this writing -- we've not been given proper -L bits for
 587 dnl single-tree newlib and libgloss.
 588 dnl
 589 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 590 dnl conftest files before we got a change to grep them first.
 591 cat > conftest.$ac_ext << EOF
 592 [#]line __oline__ "configure"
 593 struct S { ~S(); };
 594 void bar();
 595 void foo()
 596 {
 597   S s;
 598   bar();
 599 }
 600 EOF
 601 old_CXXFLAGS="$CXXFLAGS"
 602 CXXFLAGS=-S
 603 if AC_TRY_EVAL(ac_compile); then
 604   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 605     enable_sjlj_exceptions=yes
 606   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 607     enable_sjlj_exceptions=no
 608   fi
 609 fi
 610 CXXFLAGS="$old_CXXFLAGS"
 611 rm -f conftest*])
 612 if test x$enable_sjlj_exceptions = xyes; then
 613   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 614         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 615   ac_exception_model_name=sjlj
 616 elif test x$enable_sjlj_exceptions = xno; then
 617   ac_exception_model_name="call frame"
 618 else
 619   AC_MSG_ERROR([unable to detect exception model])
 620 fi
 621 AC_LANG_POP(C++)
 622 AC_MSG_RESULT($ac_exception_model_name)
 623
 624 # If we are non using SJLJ exceptions, and this host does not have support
 625 # for unwinding from a signal handler, enable checked dereferences and divides.
 626 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 627   CHECKREFSPEC=-fcheck-references
 628   DIVIDESPEC=-fuse-divide-subroutine
 629   EXCEPTIONSPEC=
 630 fi
 631
 632 # See if the user wants to disable java.net.  This is the mildly
 633 # ugly way that we admit that target-side configuration sucks.
 634 AC_ARG_ENABLE(java-net,
 635   AS_HELP_STRING([--disable-java-net],
 636                  [disable java.net]))
 637
 638 # Whether java.net is built by default can depend on the target.
 639 if test -z "$enable_java_net"; then
 640    enable_java_net=${enable_java_net_default-yes}
 641 fi
 642 if test "$enable_java_net" = no; then
 643    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 644 fi
 645
 646 # See if the user wants to configure without libffi.  Some
 647 # architectures don't support it, and default values are set in
 648 # configure.host.
 649 AC_ARG_WITH(libffi,
 650   AS_HELP_STRING([--without-libffi],
 651                  [don't use libffi]),
 652   [:],
 653   [with_libffi=${with_libffi_default-yes}])
 654
 655 LIBFFI=
 656 LIBFFIINCS=
 657 if test "$with_libffi" != no; then
 658    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 659    LIBFFI=../libffi/libffi_convenience.la
 660    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 661 fi
 662 AC_SUBST(LIBFFI)
 663 AC_SUBST(LIBFFIINCS)
 664
 665 # See if the user wants to disable JVMPI support.
 666 AC_ARG_ENABLE(jvmpi,
 667   AS_HELP_STRING([--disable-jvmpi],
 668                  [disable JVMPI support]))
 669
 670 if test "$enable_jvmpi" != no; then
 671     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 672 fi
 673
 674 # If the target is an eCos system, use the appropriate eCos
 675 # I/O routines.
 676 # FIXME: this should not be a local option but a global target
 677 # system; at present there is no eCos target.
 678 TARGET_ECOS=${PROCESS-"no"}
 679 AC_ARG_WITH(ecos,
 680 [  --with-ecos             enable runtime eCos target support],
 681 TARGET_ECOS="$with_ecos"
 682 )
 683
 684 case "$TARGET_ECOS" in
 685    no) case "$host" in
 686       *mingw*)
 687             PLATFORM=Win32
 688             PLATFORMNET=Win32
 689             PLATFORMH=win32.h
 690         CHECK_FOR_BROKEN_MINGW_LD
 691       ;;
 692       *)
 693             PLATFORM=Posix
 694             PLATFORMNET=Posix
 695             PLATFORMH=posix.h
 696       ;;
 697       esac
 698       ;;
 699    *)
 700       PLATFORM=Ecos
 701       PLATFORMNET=NoNet
 702       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 703       PLATFORMH=posix.h
 704       ;;
 705 esac
 706 AC_SUBST(PLATFORM)
 707 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 708
 709 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 710                                       [Define if you have int32_t and uint32_t.]))
 711 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 712                                         [Define if you have int32_t and uint32_t.]))
 713 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 714                                           [Define if you have u_int32_t]))
 715 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 716                                            [Define if you have u_int32_t]))
 717
 718 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 719 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 720
 721 case "$host" in
 722   *-darwin*) DARWIN_CRT=true ;;
 723   *) DARWIN_CRT=false ;;
 724 esac
 725 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 726
 727 # This may not be defined in a non-ANS conformant embedded system.
 728 # FIXME: Should these case a runtime exception in that case?
 729 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 730                                   [Define is you have 'localtime' in <time.h>]))
 731
 732 # Create the subdirectory for natFile.cc, or the attempt
 733 # to create the link will fail.
 734 test -d java || mkdir java
 735 test -d java/io || mkdir java/io
 736 test -d gnu || mkdir gnu
 737 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 738
 739 # Likewise for natConcreteProcess.cc.
 740 test -d java/lang || mkdir java/lang
 741 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 742
 743 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 744 test -d java/net || mkdir java/net
 745 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 746 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 747
 748 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 749 test -d gnu/java || mkdir gnu/java
 750 test -d gnu/java/net || mkdir gnu/java/net
 751 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 752 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 753
 754 # Likewise for natVMPipe.cc and natVMSelector.cc.
 755 test -d gnu/java/nio || mkdir gnu/java/nio
 756 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 757 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 758
 759 # Likewise for natFileChannelImpl.cc
 760 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 761 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 762
 763 case "${host}" in
 764     *mingw*)
 765       SYSTEMSPEC="-lgdi32 -lws2_32"
 766       if test "${with_win32_nlsapi}" = "unicows"; then
 767         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 768       fi
 769     ;;
 770     *)
 771       SYSTEMSPEC=
 772     ;;
 773 esac
 774 AC_SUBST(SYSTEMSPEC)
 775
 776 AC_ARG_WITH(system-zlib,
 777   AS_HELP_STRING([--with-system-zlib],
 778                  [use installed libz]))
 779 ZLIBSPEC=
 780 AC_SUBST(ZLIBSPEC)
 781 ZLIBTESTSPEC=
 782 AC_SUBST(ZLIBTESTSPEC)
 783
 784 AC_PATH_XTRA
 785
 786 # FIXME: this should be _libs on some hosts.
 787 libsubdir=.libs
 788
 789 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 790
 791 LIBSTDCXXSPEC=
 792 # extra LD Flags which are required for targets
 793 case "${host}" in
 794 *-*-darwin[[0-7]].*)
 795     # For now we have to disable it on darwin[8-9] because it slows down
 796     # the linking phase. A possible bug in ld?
 797     # on Darwin -single_module speeds up loading of the dynamic libraries.
 798     extra_ldflags_libjava=-Wl,-single_module
 799     ;;
 800 *-*-darwin[[9]]*)
 801     extra_gij_ldflags=-Wl,-allow_stack_execute
 802     ;;
 803 arm*linux*eabi)
 804     # Some of the ARM unwinder code is actually in libstdc++.  We
 805     # could in principle replicate it in libgcj, but it's better to
 806     # have a dependency on libstdc++.
 807     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 808     LIBSTDCXXSPEC=-lstdc++
 809     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 810     ;;
 811 esac
 812 AC_SUBST(extra_ldflags_libjava)
 813 AC_SUBST(extra_gij_ldflags)
 814 AC_SUBST(extra_ldflags)
 815 AC_SUBST(LIBSTDCXXSPEC)
 816
 817 AC_SUBST(LIBGCJTESTSPEC)
 818
 819 # Allow the GC to be disabled.  Can be useful when debugging.
 820 AC_MSG_CHECKING([for garbage collector to use])
 821 AC_ARG_ENABLE(java-gc,
 822   AS_HELP_STRING([--enable-java-gc=TYPE],
 823                  [choose garbage collector (default is boehm)]),
 824   [GC=$enableval],
 825   [GC=boehm])
 826 GCLIBS=
 827 GCINCS=
 828 GCDEPS=
 829 GCSPEC=
 830 JC1GCSPEC=
 831 GCTESTSPEC=
 832 case "$GC" in
 833  boehm)
 834     AC_MSG_RESULT(boehm)
 835     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 836     JC1GCSPEC='-fuse-boehm-gc'
 837     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 838     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 839     GCOBJS=boehm.lo
 840     GCHDR=boehm-gc.h
 841     # The POSIX thread support needs to know this.
 842     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 843     ;;
 844  no)
 845     AC_MSG_RESULT(none)
 846     GCHDR=no-gc.h
 847     ;;
 848  *)
 849     AC_MSG_ERROR([unrecognized collector "$GC"])
 850     ;;
 851 esac
 852 AC_SUBST(GCLIBS)
 853 AC_SUBST(GCINCS)
 854 AC_SUBST(GCDEPS)
 855 AC_SUBST(GCSPEC)
 856 AC_SUBST(JC1GCSPEC)
 857 AC_SUBST(GCTESTSPEC)
 858 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 859 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 860 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 861
 862
 863 AC_MSG_CHECKING([for thread model used by GCC])
 864 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 865 AC_MSG_RESULT([$THREADS])
 866
 867 case "$THREADS" in
 868  no | none | single)
 869     THREADS=none
 870     ;;
 871  posix | posix95 | pthreads)
 872     THREADS=posix
 873     case "$host" in
 874      *-*-linux*)
 875         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 876         ;;
 877     esac
 878     ;;
 879  win32)
 880     ;;
 881  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 882     AC_MSG_ERROR(thread package $THREADS not yet supported)
 883     ;;
 884  *)
 885     AC_MSG_ERROR($THREADS is an unknown thread package)
 886     ;;
 887 esac
 888
 889 THREADCXXFLAGS=
 890 THREADLDFLAGS=
 891 THREADLIBS=
 892 THREADINCS=
 893 THREADDEPS=
 894 THREADH=
 895 THREADSPEC=
 896 THREADSTARTFILESPEC=
 897 case "$THREADS" in
 898  posix)
 899     case "$host" in
 900      *-*-cygwin*)
 901         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 902         ;;
 903      *-*-freebsd[[1234]]*)
 904         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 905         # merely adds pthread_* functions) but it does have a -pthread switch
 906         # which is required at link-time to select -lc_r *instead* of -lc.
 907         THREADLDFLAGS=-pthread
 908         # Don't set THREADSPEC here as might be expected since -pthread is
 909         # not processed when found within a spec file, it must come from
 910         # the command line.  For now, the user must provide the -pthread
 911         # switch to link code compiled with gcj.  In future, consider adding
 912         # support for weak references to pthread_* functions ala gthr.h API.
 913         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 914         ;;
 915      *-*-freebsd*)
 916         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 917         # systems which support threads and -lpthread.
 918         THREADLDFLAGS=-pthread
 919         THREADSPEC=-lpthread
 920         ;;
 921      alpha*-dec-osf* | hppa*-hp-hpux*)
 922         THREADCXXFLAGS=-pthread
 923         # boehm-gc needs some functions from librt, so link that too.
 924         THREADLIBS='-lpthread -lrt'
 925         THREADSPEC='-lpthread -lrt'
 926         ;;
 927      *)
 928         THREADLIBS=-lpthread
 929         THREADSPEC=-lpthread
 930         ;;
 931     esac
 932     THREADH=posix-threads.h
 933     # MIT pthreads doesn't seem to have the mutexattr functions.
 934     # But for now we don't check for it.  We just assume you aren't
 935     # using MIT pthreads.
 936     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 937
 938     # If we're using the Boehm GC, then we happen to know that it
 939     # defines _REENTRANT, so we don't bother.  Eww.
 940     if test "$GC" != boehm; then
 941        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 942     fi
 943     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 944     ;;
 945
 946  win32)
 947     THREADH=win32-threads.h
 948     THREADCXXFLAGS=-mthreads
 949     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 950     # But we do not want the executables created to be dependent on
 951     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 952     # exception handling contexts.  The following kludge achieves this effect
 953     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 954     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 955     # A workaround is to explicitly use -mthreads while linking Java programs.
 956     # See PR libgcj/28263.
 957     #
 958     # FIXME: In Java we are able to detect thread death at the end of
 959     # Thread.run() so we should be able to clean up the exception handling
 960     # contexts ourselves.
 961     THREADSTARTFILESPEC='crtmt%O%s'
 962     ;;
 963
 964  none)
 965     THREADH=no-threads.h
 966     ;;
 967 esac
 968 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 969 AC_SUBST(THREADLIBS)
 970 AC_SUBST(THREADINCS)
 971 AC_SUBST(THREADDEPS)
 972 AC_SUBST(THREADSPEC)
 973 AC_SUBST(THREADSTARTFILESPEC)
 974 AC_SUBST(THREADLDFLAGS)
 975 AC_SUBST(THREADCXXFLAGS)
 976 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 977 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 978 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 979 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 980
 981 if test -d sysdep; then true; else mkdir sysdep; fi
 982 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 983 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 984 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 985
 986 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 987 if test "$use_libgcj_bc" = yes; then
 988   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
 989 fi
 990 AC_SUBST(LIBGCJ_SPEC)
 991
 992 HASH_SYNC_SPEC=
 993 # Hash synchronization is only useful with posix threads right now.
 994 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 995    HASH_SYNC_SPEC=-fhash-synchronization
 996    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 997 fi
 998 AC_SUBST(HASH_SYNC_SPEC)
 999
1000 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1001
1002 # We're in the tree with gcc, and need to include some of its headers.
1003 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1004
1005 if test "x${with_newlib}" = "xyes"; then
1006    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1007    # may not work correctly, because the compiler may not be able to
1008    # link executables.
1009
1010    # We assume newlib.  This lets us hard-code the functions we know
1011    # we'll have.
1012    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1013    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1014    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1015    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1016    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1017    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1018    # This is only for POSIX threads.
1019    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1020
1021    # Assume we do not have getuid and friends.
1022    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1023    PLATFORMNET=NoNet
1024 else
1025    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1026                    localtime_r readdir_r getpwuid_r getcwd \
1027                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1028                    nl_langinfo setlocale \
1029                    inet_pton uname inet_ntoa \
1030                    getrlimit sigaction ftruncate mmap \
1031                    getifaddrs])
1032    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1033    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1034    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1035    AC_CHECK_LIB(dl, dladdr, [
1036        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1037        AC_CHECK_LIB(dld, dladdr, [
1038        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1039
1040    if test x"$cross_compiling" = x"no"; then
1041      AC_CHECK_FILES(/proc/self/exe, [
1042        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1043      AC_CHECK_FILES(/proc/self/maps, [
1044        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1045          [Define if you have /proc/self/maps])])
1046    else
1047      case $host in
1048      *-linux*)
1049        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1050        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1051        ;;
1052      esac
1053    fi
1054
1055    AM_ICONV
1056    AM_LC_MESSAGES
1057    AC_STRUCT_TIMEZONE
1058
1059    AC_CHECK_FUNCS(gethostbyname_r, [
1060      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1061        [Define if you have the 'gethostbyname_r' function.])
1062      # There are two different kinds of gethostbyname_r.
1063      # We look for the one that returns `int'.
1064      # Hopefully this check is robust enough.
1065      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1066        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1067
1068      case " $GCINCS " in
1069      *" -D_REENTRANT "*) ;;
1070      *)
1071         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1072         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1073         [libjava_cv_gethostbyname_r_needs_reentrant],
1074         [ AC_LANG_PUSH(C++)
1075           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1076             [[gethostbyname_r("", 0, 0);]])],
1077             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1078                 CPPFLAGS_SAVE="$CPPFLAGS"
1079                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1080                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1081                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1082                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1083                 CPPFLAGS="$CPPFLAGS_SAVE"
1084           ])
1085           AC_LANG_POP(C++)
1086         ])
1087         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1088           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1089         fi
1090      ;;
1091      esac
1092
1093      AC_CACHE_CHECK([for struct hostent_data],
1094         [libjava_cv_struct_hostent_data], [dnl
1095         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1096 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1097 # define _REENTRANT 1
1098 #endif
1099 #include <netdb.h>]], [[struct hostent_data data;]])],
1100           [libjava_cv_struct_hostent_data=yes],
1101           [libjava_cv_struct_hostent_data=no])])
1102      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1103        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1104          [Define if struct hostent_data is defined in netdb.h])
1105      fi
1106    ])
1107
1108    # FIXME: libjava source code expects to find a prototype for
1109    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1110    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1111    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1112    # linkage check is enough, yet C++ code requires proper prototypes.)
1113    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1114    AC_CHECK_FUNCS(gethostbyaddr_r, [
1115      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1116        [Define if you have the 'gethostbyaddr_r' function.])
1117      # There are two different kinds of gethostbyaddr_r.
1118      # We look for the one that returns `int'.
1119      # Hopefully this check is robust enough.
1120      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1121        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1122          [Define if gethostbyaddr_r returns 'int'.])])])])
1123
1124    AC_CHECK_FUNCS(gethostname, [
1125      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1126        [Define if you have the 'gethostname' function.])
1127      AC_EGREP_HEADER(gethostname, unistd.h, [
1128        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1129          [Define if gethostname is declared in <unistd.h>.])])])
1130
1131    AC_CHECK_FUNCS(usleep, [
1132      AC_EGREP_HEADER(usleep, unistd.h, [
1133        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1134           [Define if usleep is declared in <unistd.h>.])])])
1135
1136    # Look for these functions in the thread library, but only bother
1137    # if using POSIX threads.
1138    if test "$THREADS" = posix; then
1139       save_LIBS="$LIBS"
1140       LIBS="$LIBS $THREADLIBS"
1141
1142       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1143       # Solaris 7 the name librt is preferred.
1144       AC_CHECK_FUNCS(sched_yield, , [
1145         AC_CHECK_LIB(rt, sched_yield, [
1146           AC_DEFINE(HAVE_SCHED_YIELD)
1147           THREADLIBS="$THREADLIBS -lrt"
1148           THREADSPEC="$THREADSPEC -lrt"], [
1149           AC_CHECK_LIB(posix4, sched_yield, [
1150             AC_DEFINE(HAVE_SCHED_YIELD)
1151             THREADLIBS="$THREADLIBS -lposix4"
1152             THREADSPEC="$THREADSPEC -lposix4"])])])
1153
1154       AC_CHECK_LIB(rt, clock_gettime, [
1155          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1156          case "$THREADSPEC" in
1157            *-lrt*) ;;
1158            *)
1159              THREADSPEC="$THREADSPEC -lrt"
1160              THREADLIBS="$THREADLIBS -lrt"
1161              ;;
1162          esac])
1163
1164       LIBS="$save_LIBS"
1165
1166       # We can save a little space at runtime if the mutex has m_count
1167       # or __m_count.  This is a nice hack for Linux.
1168       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1169           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1170         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1171              [Define if pthread_mutex_t has m_count member.]), [
1172         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1173             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1174           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1175             [Define if pthread_mutex_t has __m_count member.]))])
1176    fi
1177
1178    # We require a way to get the time.
1179    time_found=no
1180    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1181    if test "$time_found" = no; then
1182       AC_MSG_ERROR([no function found to get the time])
1183    fi
1184
1185    AC_CHECK_FUNCS(memmove)
1186
1187    # We require memcpy.
1188    memcpy_found=no
1189    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1190    if test "$memcpy_found" = no; then
1191       AC_MSG_ERROR([memcpy is required])
1192    fi
1193    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1194    AC_CHECK_LIB(dl, dlopen, [
1195        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1196        AC_CHECK_LIB(dld, dlopen, [
1197        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1198
1199    # Some library-finding code we stole from Tcl.
1200    #--------------------------------------------------------------------
1201    #    Check for the existence of the -lsocket and -lnsl libraries.
1202    #    The order here is important, so that they end up in the right
1203    #    order in the command line generated by make.  Here are some
1204    #    special considerations:
1205    #    1. Use "connect" and "accept" to check for -lsocket, and
1206    #       "gethostbyname" to check for -lnsl.
1207    #    2. Use each function name only once:  can't redo a check because
1208    #       autoconf caches the results of the last check and won't redo it.
1209    #    3. Use -lnsl and -lsocket only if they supply procedures that
1210    #       aren't already present in the normal libraries.  This is because
1211    #       IRIX 5.2 has libraries, but they aren't needed and they're
1212    #       bogus:  they goof up name resolution if used.
1213    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1214    #       To get around this problem, check for both libraries together
1215    #       if -lsocket doesn't work by itself.
1216    #--------------------------------------------------------------------
1217
1218    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1219     [gcj_cv_lib_sockets=
1220      gcj_checkBoth=0
1221      unset ac_cv_func_connect
1222      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1223      if test "$gcj_checkSocket" = 1; then
1224          unset ac_cv_func_connect
1225          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1226                       gcj_checkBoth=1)
1227      fi
1228      if test "$gcj_checkBoth" = 1; then
1229          gcj_oldLibs=$LIBS
1230          LIBS="$LIBS -lsocket -lnsl"
1231          unset ac_cv_func_accept
1232          AC_CHECK_FUNC(accept,
1233                        [gcj_checkNsl=0
1234                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1235          unset ac_cv_func_accept
1236          LIBS=$gcj_oldLibs
1237      fi
1238      unset ac_cv_func_gethostbyname
1239      gcj_oldLibs=$LIBS
1240      LIBS="$LIBS $gcj_cv_lib_sockets"
1241      AC_CHECK_FUNC(gethostbyname, ,
1242                    [AC_CHECK_LIB(nsl, main,
1243                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1244      unset ac_cv_func_gethostbyname
1245      LIBS=$gcj_oldLIBS
1246    ])
1247    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1248
1249    if test "$with_system_zlib" = yes; then
1250       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1251    fi
1252
1253    # Test for Gtk stuff, if asked for.
1254    if test "$use_gtk_awt" = yes; then
1255       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1256       AC_SUBST(GTK_CFLAGS)
1257       AC_SUBST(GTK_LIBS)
1258
1259       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1260       AC_SUBST(GLIB_CFLAGS)
1261       AC_SUBST(GLIB_LIBS)
1262
1263       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1264       AC_SUBST(LIBART_CFLAGS)
1265       AC_SUBST(LIBART_LIBS)
1266
1267       # We require the XTest Extension to support java.awt.Robot.
1268       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1269                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1270                    [${X_LIBS}])
1271    fi
1272
1273    # On Solaris, and maybe other architectures, the Boehm collector
1274    # requires -ldl.
1275    if test "$GC" = boehm; then
1276       case "${host}" in
1277           mips-sgi-irix6*)
1278             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1279             # libgcj.spec is used, so override here
1280             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1281           ;;
1282           *)
1283             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1284           ;;
1285       esac
1286    fi
1287 fi
1288
1289 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1290 case $build in
1291     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1292     *)         CLASSPATH_SEPARATOR=':' ;;
1293 esac
1294 AC_SUBST(CLASSPATH_SEPARATOR)
1295
1296 # We must search the source tree for java.lang, since we still don't
1297 # have libgcj.jar nor java/lang/*.class
1298 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1299 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1300
1301 # Since some classes depend on this one, we need its source available
1302 # before we can do any GCJ compilation test :-(
1303 if test ! -f gnu/classpath/Configuration.java; then
1304   test -d gnu || mkdir gnu
1305   test -d gnu/classpath || mkdir gnu/classpath
1306   # Note that it is not crucial that all the values here be correct.
1307   sed -e "s,@prefix@,$prefix," \
1308       -e "s,@VERSION@,$VERSION," \
1309       -e "s,@LIBDEBUG@,false," \
1310       -e "s,@INIT_LOAD_LIBRARY@,false," \
1311       -e "s,@@,$LIBGCJDEBUG," \
1312       -e "s,@default_toolkit@,$TOOLKIT," \
1313       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1314       -e "s,@GTK_CAIRO_ENABLED@,false," \
1315       -e "s,@ECJ_JAR@,," \
1316         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1317         > gnu/classpath/Configuration.java
1318   # We do not want to redirect the output of the grep below to /dev/null,
1319   # but we add /dev/null to the input list so that grep will print the
1320   # filename of Configuration.java in case it finds any matches.
1321   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1322     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1323   fi
1324 fi
1325
1326 LT_AC_PROG_GCJ
1327
1328 # Now remove it.
1329 rm -f gnu/classpath/Configuration.java
1330
1331 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1332
1333 AC_CHECK_SIZEOF(void *)
1334
1335 AC_C_BIGENDIAN
1336
1337 ZLIBS=
1338 SYS_ZLIBS=
1339 ZINCS=
1340
1341 if test -z "$ZLIBSPEC"; then
1342    # Use zlib from the GCC tree.
1343    ZINCS='-I$(top_srcdir)/../zlib'
1344    ZLIBS=../zlib/libzgcj_convenience.la
1345 else
1346    # System's zlib.
1347    SYS_ZLIBS="$ZLIBSPEC"
1348 fi
1349 AC_SUBST(ZLIBS)
1350 AC_SUBST(SYS_ZLIBS)
1351 AC_SUBST(ZINCS)
1352 AC_SUBST(DIVIDESPEC)
1353 AC_SUBST(CHECKREFSPEC)
1354 AC_SUBST(EXCEPTIONSPEC)
1355 AC_SUBST(BACKTRACESPEC)
1356 AC_SUBST(IEEESPEC)
1357
1358 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1359 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1360 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1361 AC_SUBST(GCC_UNWIND_INCLUDE)
1362
1363 # Process the option "--enable-version-specific-runtime-libs"
1364 # Calculate toolexeclibdir
1365 case ${version_specific_libs} in
1366   yes)
1367     # Need the gcc compiler version to know where to install libraries
1368     # and header files if --enable-version-specific-runtime-libs option
1369     # is selected.
1370     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1371     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1372     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1373     toolexeclibdir=$toolexecmainlibdir
1374     ;;
1375   no)
1376     if test -n "$with_cross_host" &&
1377        test x"$with_cross_host" != x"no"; then
1378       # Install a library built with a cross compiler in tooldir, not libdir.
1379       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1380       toolexecmainlibdir='$(toolexecdir)/lib'
1381     else
1382       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1383       toolexecmainlibdir='$(libdir)'
1384     fi
1385     multi_os_directory=`$CC -print-multi-os-directory`
1386     case $multi_os_directory in
1387       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1388       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1389     esac
1390     ;;
1391 esac
1392 AC_SUBST(toolexecdir)
1393 AC_SUBST(toolexecmainlibdir)
1394 AC_SUBST(toolexeclibdir)
1395
1396 # Determine gcj and libgcj version number.
1397 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1398 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1399 GCJVERSION=$gcjversion
1400 AC_SUBST(GCJVERSION)
1401 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1402
1403 # Determine where the standard .db file and GNU Classpath JNI
1404 # libraries are found.
1405 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1406 multi_os_directory=`$CC -print-multi-os-directory`
1407 case $multi_os_directory in
1408   .)
1409    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1410    ;;
1411   *)
1412    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1413    ;;
1414 esac
1415 AC_SUBST(dbexecdir)
1416
1417 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1418 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1419
1420 TL_AC_GXX_INCLUDE_DIR
1421
1422 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1423 # On that system, sys/ioctl.h will not include sys/filio.h unless
1424 # BSD_COMP is defined; just including sys/filio.h is simpler.
1425 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1426 # for now.  If you change this, you also must update natFile.cc.
1427 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1428                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1429                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1430                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1431                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1432 AC_CHECK_HEADERS(inttypes.h, [
1433     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1434     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1435 ])
1436
1437 AC_CHECK_TYPE([ssize_t], [int])
1438 AC_CHECK_TYPE([magic_t], [
1439     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1440 #ifdef HAVE_MAGIC_H
1441 #include <magic.h>
1442 #endif])
1443
1444 AC_MSG_CHECKING([for in_addr_t])
1445 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1446 #if STDC_HEADERS
1447 #include <stdlib.h>
1448 #include <stddef.h>
1449 #endif
1450 #if HAVE_NETINET_IN_H
1451 #include <netinet/in.h>
1452 #endif]], [[in_addr_t foo;]])],
1453   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1454      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1455    AC_MSG_RESULT(yes)],
1456   [AC_MSG_RESULT(no)])
1457
1458 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1459 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1460   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1461      [Define if struct ip_mreq is defined in netinet/in.h.])
1462    AC_MSG_RESULT(yes)],
1463   [AC_MSG_RESULT(no)])
1464
1465 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1466 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1467   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1468      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1469    AC_MSG_RESULT(yes)],
1470   [AC_MSG_RESULT(no)])
1471
1472 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1473 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1474   [AC_DEFINE(HAVE_INET6, 1,
1475      [Define if inet6 structures are defined in netinet/in.h.])
1476    AC_MSG_RESULT(yes)],
1477   [AC_MSG_RESULT(no)])
1478
1479 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1480 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1481 #include <sys/types.h>
1482 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1483   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1484    AC_MSG_RESULT(yes)],
1485   [AC_MSG_RESULT(no)])
1486
1487 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1488 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1489   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1490    AC_MSG_RESULT(yes)],
1491   [AC_MSG_RESULT(no)
1492    AC_MSG_CHECKING([for global timezone variable])
1493    dnl FIXME: we don't want a link check here because that won't work
1494    dnl when cross-compiling.  So instead we make an assumption that
1495    dnl the header file will mention timezone if it exists.
1496    dnl Don't find the win32 function timezone
1497    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1498      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1499       AC_MSG_RESULT(yes)],
1500      [AC_MSG_RESULT(no)
1501        AC_MSG_CHECKING([for global _timezone variable])
1502        dnl FIXME: As above, don't want link check
1503        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1504          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1505             [Define if your platform has the global _timezone variable.])
1506           AC_MSG_RESULT(yes)],
1507           [AC_MSG_RESULT(no)])])])
1508
1509 AC_CHECK_PROGS(PERL, perl, false)
1510
1511 SYSDEP_SOURCES=
1512 SIGNAL_HANDLER_AUX=
1513
1514 case "${host}" in
1515  i?86-*-linux*)
1516     SIGNAL_HANDLER=include/i386-signal.h
1517     ;;
1518  sparc*-sun-solaris*)
1519     SIGNAL_HANDLER=include/sparc-signal.h
1520     ;;
1521 # ia64-*)
1522 #    SYSDEP_SOURCES=sysdep/ia64.c
1523 #    test -d sysdep || mkdir sysdep
1524 #    ;;
1525  hppa*-*-linux*)
1526     SIGNAL_HANDLER=include/pa-signal.h
1527     ;;
1528  hppa*-hp-hpux*)
1529     SIGNAL_HANDLER=include/hppa-signal.h
1530     ;;
1531  ia64-*-linux*)
1532     SIGNAL_HANDLER=include/dwarf2-signal.h
1533     ;;
1534  powerpc*-*-linux*)
1535     SIGNAL_HANDLER=include/powerpc-signal.h
1536     ;;
1537  alpha*-*-linux*)
1538     SIGNAL_HANDLER=include/dwarf2-signal.h
1539     ;;
1540  s390*-*-linux*)
1541     SIGNAL_HANDLER=include/s390-signal.h
1542     ;;
1543  x86_64*-*-linux*)
1544     SIGNAL_HANDLER=include/x86_64-signal.h
1545     SIGNAL_HANDLER_AUX=include/i386-signal.h
1546     ;;
1547  sparc*-*-linux*)
1548     SIGNAL_HANDLER=include/dwarf2-signal.h
1549     ;;
1550  sh*-*-linux*)
1551     SIGNAL_HANDLER=include/sh-signal.h
1552     ;;
1553  *mingw*)
1554     SIGNAL_HANDLER=include/win32-signal.h
1555     ;;
1556  mips*-*-linux*)
1557     SIGNAL_HANDLER=include/mips-signal.h
1558     ;;
1559  m68*-*-linux*)
1560     SIGNAL_HANDLER=include/dwarf2-signal.h
1561     ;;
1562  powerpc*-*-darwin* | i?86-*-darwin9* | x86_64-*-darwin9*)
1563     SIGNAL_HANDLER=include/darwin-signal.h
1564     ;;
1565  *)
1566     SIGNAL_HANDLER=include/default-signal.h
1567     ;;
1568 esac
1569
1570 # If we're using sjlj exceptions, forget what we just learned.
1571 if test "$enable_sjlj_exceptions" = yes; then
1572    SIGNAL_HANDLER=include/default-signal.h
1573    SIGNAL_HANDLER_AUX=
1574 fi
1575
1576 AC_SUBST(SYSDEP_SOURCES)
1577
1578 if test -z "$SIGNAL_HANDLER_AUX"; then
1579   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1580 fi
1581
1582 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1583                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1584
1585 if test "${multilib}" = "yes"; then
1586   multilib_arg="--enable-multilib"
1587 else
1588   multilib_arg=
1589 fi
1590
1591 # See if we support thread-local storage.
1592 GCC_CHECK_TLS
1593
1594 # For _Unwind_GetIPInfo.
1595 GCC_CHECK_UNWIND_GETIPINFO
1596
1597 # See if linker supports anonymous version scripts.
1598 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1599   [libjava_cv_anon_version_script],
1600   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1601    libjava_cv_anon_version_script=no
1602    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1603    echo '{ global: globalsymb*; local: *; };' > conftest.map
1604    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1605                [libjava_cv_anon_version_script=yes], [])
1606    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1607   ])
1608 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1609
1610 # Check if linker supports static linking on a per library basis
1611 LD_START_STATIC_SPEC=
1612 LD_FINISH_STATIC_SPEC=
1613 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1614   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1615     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1616     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1617   fi
1618 fi
1619 AC_SUBST(LD_START_STATIC_SPEC)
1620 AC_SUBST(LD_FINISH_STATIC_SPEC)
1621
1622 here=`${PWDCMD-pwd}`
1623 AC_SUBST(here)
1624
1625 # We get this from the environment.
1626 AC_SUBST(GCJFLAGS)
1627
1628 AC_CONFIG_FILES([
1629 Makefile
1630 libgcj.pc
1631 libgcj.spec
1632 libgcj-test.spec
1633 gcj/Makefile
1634 include/Makefile
1635 testsuite/Makefile
1636 ])
1637
1638 if test ${multilib} = yes; then
1639   multilib_arg="--enable-multilib"
1640 else
1641   multilib_arg=
1642 fi
1643
1644 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1645 AC_OUTPUT