libf2c/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 1999 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Fortran.
   6 #
   7 #GNU Fortran is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Fortran; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.13)
  23 AC_INIT(libF77/Version.c)
  24
  25 if test "${srcdir}" = "."  ; then
  26   if test "${with_target_subdir}" != "." ; then
  27     topsrcdir=${with_multisrctop}../..
  28   else
  29     topsrcdir=${with_multisrctop}..
  30   fi
  31 else
  32   topsrcdir=${srcdir}/..
  33 fi
  34 dnl This is needed for a multilibbed build in the source tree so
  35 dnl that install-sh and config.sub get found.
  36 AC_CONFIG_AUX_DIR($topsrcdir)
  37
  38 # We have to handle 3 cases -- native, cross and canadian cross -- and
  39 # the extension returned from this macro needs to be treated as a possible
  40 # scenario and not the only one.
  41 AC_EXEEXT
  42
  43 # If the language specific compiler does not exist, but the "gcc" directory
  44 # does, we do not build anything. Note, $r is set by the top-level Makefile.
  45 # Note that when we look for the compiler, we search both with and without
  46 # extension to handle cross and canadian cross builds.
  47 compiler_name=f771
  48 rm -f skip-this-dir
  49 AC_MSG_CHECKING(if compiler $compiler_name has been built)
  50 AC_CACHE_VAL(g77_cv_compiler_exists,
  51 [g77_cv_compiler_exists=yes
  52 if test -n "$r"; then
  53   if test -d "$r"/gcc; then
  54     if test -f "$r"/gcc/$compiler_name \
  55        || test -f "$r"/gcc/$compiler_name$EXEEXT; then
  56       true
  57     else
  58       g77_cv_compiler_exists=no
  59       echo "rm -f config.cache config.log multilib.out" > skip-this-dir
  60     fi
  61   fi
  62 fi
  63 ])
  64 AC_MSG_RESULT($g77_cv_compiler_exists)
  65 if test x$g77_cv_compiler_exists = xno
  66 then
  67   rm -f Makefile conftest* confdefs* core
  68   exit 0
  69 fi
  70
  71 dnl Checks for programs.
  72 # For g77 we'll set CC to point at the built gcc, but this will get it into
  73 # the makefiles
  74 AC_PROG_CC
  75
  76 dnl These should be inherited in the recursive make, but ensure they are
  77 dnl defined:
  78 test "$AR" || AR=ar
  79 AC_SUBST(AR)
  80 if test "$RANLIB"; then :
  81   AC_SUBST(RANLIB)
  82 else
  83   AC_PROG_RANLIB
  84 fi
  85 AC_PROG_INSTALL
  86 AC_PROG_MAKE_SET
  87
  88 dnl Checks for header files.
  89 # Sanity check for the cross-compilation case:
  90 AC_CHECK_HEADER(stdio.h,:,
  91   [AC_MSG_ERROR([Can't find stdio.h.
  92 You must have a usable C system for the target already installed, at least
  93 including headers and, preferably, the library, before you can configure
  94 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  95 then the target library, then build with \`LANGUAGES=f77'.])])
  96
  97 # We have to firkle with the info in hconfig.h to figure out suitable types
  98 # (via com.h).  proj.h and com.h are in gcc/f/, config.h which they need
  99 # is in gcc/ and the config files are in gcc/config/.
 100 AC_MSG_CHECKING(f2c integer type)
 101 # Set this back later below!
 102 late_ac_cpp=$ac_cpp
 103 late_cflags=$CFLAGS
 104 extra_includes="-I$topsrcdir/gcc/f -I$topsrcdir/gcc -I$topsrcdir/include -I$topsrcdir/gcc/config -I$r/gcc"
 105 ac_cpp="$late_ac_cpp -DIN_GCC -DHAVE_CONFIG_H $extra_includes"
 106
 107 # The AC_EGREP_CPPs below have been known to fail when the header
 108 # path is wrong after things have been moved about; the cpp error status
 109 # counts for nothing.  First check that there aren't any errors from
 110 # the headers.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H -DIN_GCC $extra_includes"
 112 AC_TRY_COMPILE([#include "proj.h"
 113 #define FFECOM_DETERMINE_TYPES 1
 114 #include "com.h"],,,
 115 AC_MSG_ERROR([Can't run check for integer sizes -- see config.log]))
 116 CFLAGS=$late_cflags
 117
 118 AC_CACHE_VAL(g77_cv_sys_f2cinteger,
 119 echo "configure:__oline__: using $ac_cpp" >&AC_FD_CC
 120 AC_EGREP_CPP(F2C_INTEGER=long int,
 121 [#include "proj.h"
 122 #define FFECOM_DETERMINE_TYPES 1
 123 #include "com.h"
 124 #if FFECOM_f2cINTEGER == FFECOM_f2ccodeLONG
 125 F2C_INTEGER=long int
 126 #elif FFECOM_f2cINTEGER == FFECOM_f2ccodeINT
 127 F2C_INTEGER=int
 128 #else
 129 #  error "Cannot find a suitable type for F2C_INTEGER"
 130 #endif
 131 ],
 132  g77_cv_sys_f2cinteger="long int",)
 133 if test "$g77_cv_sys_f2cinteger" = ""; then
 134 echo "configure:__oline__: using $ac_cpp" >&AC_FD_CC
 135   AC_EGREP_CPP(F2C_INTEGER=int,
 136 [#include "proj.h"
 137 #define FFECOM_DETERMINE_TYPES 1
 138 #include "com.h"
 139 #if FFECOM_f2cINTEGER == FFECOM_f2ccodeLONG
 140 F2C_INTEGER=long int
 141 #elif FFECOM_f2cINTEGER == FFECOM_f2ccodeINT
 142 F2C_INTEGER=int
 143 #else
 144 #  error "Cannot find a suitable type for F2C_INTEGER"
 145 #endif
 146 ],
 147    g77_cv_sys_f2cinteger=int,)
 148 fi
 149 if test "$g77_cv_sys_f2cinteger" = ""; then
 150   AC_MSG_RESULT("")
 151   AC_MSG_ERROR([Can't determine type for f2c integer; config.log may help.])
 152 fi
 153 )
 154 AC_MSG_RESULT($g77_cv_sys_f2cinteger)
 155 F2C_INTEGER=$g77_cv_sys_f2cinteger
 156 AC_SUBST(F2C_INTEGER)
 157
 158 AC_MSG_CHECKING(f2c long int type)
 159 AC_CACHE_VAL(g77_cv_sys_f2clongint,
 160 echo "configure:__oline__: using $ac_cpp" >&AC_FD_CC
 161 AC_EGREP_CPP(F2C_LONGINT=long int,
 162 [#include "proj.h"
 163 #define FFECOM_DETERMINE_TYPES 1
 164 #include "com.h"
 165 #if FFECOM_f2cLONGINT == FFECOM_f2ccodeLONG
 166 F2C_LONGINT=long int
 167 #elif FFECOM_f2cLONGINT == FFECOM_f2ccodeLONGLONG
 168 F2C_LONGINT=long long int
 169 #else
 170 #  error "Cannot find a suitable type for F2C_LONGINT"
 171 #endif
 172 ],
 173  g77_cv_sys_f2clongint="long int",)
 174
 175 if test "$g77_cv_sys_f2clongint" = ""; then
 176 echo "configure:__oline__: using $ac_cpp" >&AC_FD_CC
 177   AC_EGREP_CPP(F2C_LONGINT=long long int,
 178 [#include "proj.h"
 179 #define FFECOM_DETERMINE_TYPES 1
 180 #include "com.h"
 181 #if FFECOM_f2cLONGINT == FFECOM_f2ccodeLONG
 182 F2C_LONGINT=long int
 183 #elif FFECOM_f2cLONGINT == FFECOM_f2ccodeLONGLONG
 184 F2C_LONGINT=long long int
 185 #else
 186 #  error "Cannot find a suitable type for F2C_LONGINT"
 187 #endif
 188 ],
 189    g77_cv_sys_f2clongint="long long int",)
 190 fi
 191 if test "$g77_cv_sys_f2clongint" = ""; then
 192   AC_MSG_RESULT("")
 193   AC_MSG_ERROR([Can't determine type for f2c long int; config.log may help.])
 194 fi
 195 )
 196 AC_MSG_RESULT($g77_cv_sys_f2clongint)
 197 F2C_LONGINT=$g77_cv_sys_f2clongint
 198 AC_SUBST(F2C_LONGINT)
 199 ac_cpp=$late_ac_cpp
 200
 201 # avoid confusion in case the `makefile's from the f2c distribution have
 202 # got put here
 203 test -f libF77/makefile && mv libF77/makefile  libF77/makefile.ori
 204 test -f libI77/makefile && mv libI77/makefile  libI77/makefile.ori
 205 test -f libU77/makefile && mv libU77/makefile  libU77/makefile.ori
 206
 207 # Get the version trigger filename from the toplevel
 208 if [[ "${with_gcc_version_trigger+set}" = set ]]; then
 209         gcc_version_trigger=$with_gcc_version_trigger
 210         gcc_version=`sed -e 's/.*\"\([[^ \"]]*\)[[ \"]].*/\1/' < ${gcc_version_trigger}`
 211 else
 212         gcc_version_trigger=
 213         gcc_version=UNKNOWN
 214 fi
 215
 216 AC_SUBST(gcc_version)
 217 AC_SUBST(gcc_version_trigger)
 218 AC_CANONICAL_SYSTEM
 219 AC_SUBST(target_alias)
 220 AC_CONFIG_SUBDIRS(libU77 libI77 libF77)
 221 # Do Makefile first since g2c.h depends on it and shouldn't get an
 222 # earlier timestamp.  Of course, it does when the multilib gunk below
 223 # edits Makefile, sigh; see additional touch below.
 224 AC_OUTPUT(Makefile g2c.h:g2c.hin,
 225  [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 226 if test -n "$CONFIG_FILES"; then
 227   if test -n "${with_target_subdir}"; then
 228     # FIXME: We shouldn't need to set ac_file
 229     ac_file=Makefile
 230     . ${topsrcdir}/config-ml.in
 231     touch g2c.h   # to keep it more recent than Makefile
 232   fi
 233 fi],
 234 srcdir=${srcdir}
 235 host=${host}
 236 target=${target}
 237 with_target_subdir=${with_target_subdir}
 238 with_multisubdir=${with_multisubdir}
 239 ac_configure_args="--enable-multilib ${ac_configure_args}"
 240 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 241 topsrcdir=${topsrcdir}
 242 )
 243
 244
 245 dnl Local Variables:
 246 dnl comment-start: "dnl "
 247 dnl comment-end: ""
 248 dnl comment-start-skip: "\\bdnl\\b\\s *"
 249 dnl End: