gcc/ada/s-taasde.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --           S Y S T E M . T A S K I N G . A S Y N C _ D E L A Y S          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --         Copyright (C) 1998-2006, Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Polling (Off);
  35 --  Turn off polling, we do not want ATC polling to take place during
  36 --  tasking operations. It causes infinite loops and other problems.
  37
  38 with Ada.Exceptions;
  39 --  Used for Raise_Exception
  40
  41 with System.Task_Primitives.Operations;
  42 --  Used for Write_Lock,
  43 --           Unlock,
  44 --           Self,
  45 --           Monotonic_Clock,
  46 --           Self,
  47 --           Timed_Sleep,
  48 --           Wakeup,
  49 --           Yield
  50
  51 with System.Tasking.Utilities;
  52 --  Used for Make_Independent
  53
  54 with System.Tasking.Initialization;
  55 --  Used for Defer_Abort
  56 --           Undefer_Abort
  57
  58 with System.Tasking.Debug;
  59 --  Used for Trace
  60
  61 with System.OS_Primitives;
  62 --  used for Max_Sensible_Delay
  63
  64 with Ada.Task_Identification;
  65 --  used for Task_Id type
  66
  67 with System.Interrupt_Management.Operations;
  68 --  used for Setup_Interrupt_Mask
  69
  70 with System.Parameters;
  71 --  used for Single_Lock
  72 --           Runtime_Traces
  73
  74 with System.Traces.Tasking;
  75 --  used for Send_Trace_Info
  76
  77 with Unchecked_Conversion;
  78
  79 package body System.Tasking.Async_Delays is
  80
  81    package STPO renames System.Task_Primitives.Operations;
  82    package ST renames System.Tasking;
  83    package STU renames System.Tasking.Utilities;
  84    package STI renames System.Tasking.Initialization;
  85    package OSP renames System.OS_Primitives;
  86
  87    use Parameters;
  88    use System.Traces;
  89    use System.Traces.Tasking;
  90
  91    function To_System is new Unchecked_Conversion
  92      (Ada.Task_Identification.Task_Id, Task_Id);
  93
  94    Timer_Server_ID : ST.Task_Id;
  95
  96    Timer_Attention : Boolean := False;
  97    pragma Atomic (Timer_Attention);
  98
  99    task Timer_Server is
 100       pragma Interrupt_Priority (System.Any_Priority'Last);
 101    end Timer_Server;
 102
 103    --  The timer queue is a circular doubly linked list, ordered by absolute
 104    --  wakeup time. The first item in the queue is Timer_Queue.Succ.
 105    --  It is given a Resume_Time that is larger than any legitimate wakeup
 106    --  time, so that the ordered insertion will always stop searching when it
 107    --  gets back to the queue header block.
 108
 109    Timer_Queue : aliased Delay_Block;
 110
 111    ------------------------
 112    -- Cancel_Async_Delay --
 113    ------------------------
 114
 115    --  This should (only) be called from the compiler-generated cleanup routine
 116    --  for an async. select statement with delay statement as trigger. The
 117    --  effect should be to remove the delay from the timer queue, and exit one
 118    --  ATC nesting level.
 119    --  The usage and logic are similar to Cancel_Protected_Entry_Call, but
 120    --  simplified because this is not a true entry call.
 121
 122    procedure Cancel_Async_Delay (D : Delay_Block_Access) is
 123       Dpred : Delay_Block_Access;
 124       Dsucc : Delay_Block_Access;
 125
 126    begin
 127       --  Note that we mark the delay as being cancelled
 128       --  using a level value that is reserved.
 129
 130       --  make this operation idempotent
 131
 132       if D.Level = ATC_Level_Infinity then
 133          return;
 134       end if;
 135
 136       D.Level := ATC_Level_Infinity;
 137
 138       --  remove self from timer queue
 139
 140       STI.Defer_Abort_Nestable (D.Self_Id);
 141
 142       if Single_Lock then
 143          STPO.Lock_RTS;
 144       end if;
 145
 146       STPO.Write_Lock (Timer_Server_ID);
 147       Dpred := D.Pred;
 148       Dsucc := D.Succ;
 149       Dpred.Succ := Dsucc;
 150       Dsucc.Pred := Dpred;
 151       D.Succ := D;
 152       D.Pred := D;
 153       STPO.Unlock (Timer_Server_ID);
 154
 155       --  Note that the above deletion code is required to be
 156       --  idempotent, since the block may have been dequeued
 157       --  previously by the Timer_Server.
 158
 159       --  leave the asynchronous select
 160
 161       STPO.Write_Lock (D.Self_Id);
 162       STU.Exit_One_ATC_Level (D.Self_Id);
 163       STPO.Unlock (D.Self_Id);
 164
 165       if Single_Lock then
 166          STPO.Unlock_RTS;
 167       end if;
 168
 169       STI.Undefer_Abort_Nestable (D.Self_Id);
 170    end Cancel_Async_Delay;
 171
 172    ---------------------------
 173    -- Enqueue_Time_Duration --
 174    ---------------------------
 175
 176    function Enqueue_Duration
 177      (T : Duration;
 178       D : Delay_Block_Access) return Boolean
 179    is
 180    begin
 181       if T <= 0.0 then
 182          D.Timed_Out := True;
 183          STPO.Yield;
 184          return False;
 185
 186       else
 187          --  The corresponding call to Undefer_Abort is performed by the
 188          --  expanded code (see exp_ch9).
 189
 190          STI.Defer_Abort (STPO.Self);
 191          Time_Enqueue
 192            (STPO.Monotonic_Clock
 193             + Duration'Min (T, OSP.Max_Sensible_Delay), D);
 194          return True;
 195       end if;
 196    end Enqueue_Duration;
 197
 198    ------------------
 199    -- Time_Enqueue --
 200    ------------------
 201
 202    --  Allocate a queue element for the wakeup time T and put it in the
 203    --  queue in wakeup time order.  Assume we are on an asynchronous
 204    --  select statement with delay trigger.  Put the calling task to
 205    --  sleep until either the delay expires or is cancelled.
 206
 207    --  We use one entry call record for this delay, since we have
 208    --  to increment the ATC nesting level, but since it is not a
 209    --  real entry call we do not need to use any of the fields of
 210    --  the call record.  The following code implements a subset of
 211    --  the actions for the asynchronous case of Protected_Entry_Call,
 212    --  much simplified since we know this never blocks, and does not
 213    --  have the full semantics of a protected entry call.
 214
 215    procedure Time_Enqueue
 216      (T : Duration;
 217       D : Delay_Block_Access)
 218    is
 219       Self_Id : constant Task_Id  := STPO.Self;
 220       Q       : Delay_Block_Access;
 221
 222       use type ST.Task_Id;
 223       --  for visibility of operator "="
 224
 225    begin
 226       pragma Debug (Debug.Trace (Self_Id, "Async_Delay", 'P'));
 227       pragma Assert (Self_Id.Deferral_Level = 1,
 228         "async delay from within abort-deferred region");
 229
 230       if Self_Id.ATC_Nesting_Level = ATC_Level'Last then
 231          Ada.Exceptions.Raise_Exception (Storage_Error'Identity,
 232            "not enough ATC nesting levels");
 233       end if;
 234
 235       Self_Id.ATC_Nesting_Level := Self_Id.ATC_Nesting_Level + 1;
 236
 237       pragma Debug
 238         (Debug.Trace (Self_Id, "ASD: entered ATC level: " &
 239          ATC_Level'Image (Self_Id.ATC_Nesting_Level), 'A'));
 240
 241       D.Level := Self_Id.ATC_Nesting_Level;
 242       D.Self_Id := Self_Id;
 243       D.Resume_Time := T;
 244
 245       if Single_Lock then
 246          STPO.Lock_RTS;
 247       end if;
 248
 249       STPO.Write_Lock (Timer_Server_ID);
 250
 251       --  Previously, there was code here to dynamically create
 252       --  the Timer_Server task, if one did not already exist.
 253       --  That code had a timing window that could allow multiple
 254       --  timer servers to be created. Luckily, the need for
 255       --  postponing creation of the timer server should now be
 256       --  gone, since this package will only be linked in if
 257       --  there are calls to enqueue calls on the timer server.
 258
 259       --  Insert D in the timer queue, at the position determined
 260       --  by the wakeup time T.
 261
 262       Q := Timer_Queue.Succ;
 263
 264       while Q.Resume_Time < T loop
 265          Q := Q.Succ;
 266       end loop;
 267
 268       --  Q is the block that has Resume_Time equal to or greater than
 269       --  T. After the insertion we want Q to be the successor of D.
 270
 271       D.Succ := Q;
 272       D.Pred := Q.Pred;
 273       D.Pred.Succ := D;
 274       Q.Pred := D;
 275
 276       --  If the new element became the head of the queue,
 277       --  signal the Timer_Server to wake up.
 278
 279       if Timer_Queue.Succ = D then
 280          Timer_Attention := True;
 281          STPO.Wakeup (Timer_Server_ID, ST.Timer_Server_Sleep);
 282       end if;
 283
 284       STPO.Unlock (Timer_Server_ID);
 285
 286       if Single_Lock then
 287          STPO.Unlock_RTS;
 288       end if;
 289    end Time_Enqueue;
 290
 291    ---------------
 292    -- Timed_Out --
 293    ---------------
 294
 295    function Timed_Out (D : Delay_Block_Access) return Boolean is
 296    begin
 297       return D.Timed_Out;
 298    end Timed_Out;
 299
 300    ------------------
 301    -- Timer_Server --
 302    ------------------
 303
 304    task body Timer_Server is
 305       function Get_Next_Wakeup_Time return Duration;
 306       --  Used to initialize Next_Wakeup_Time, but also to ensure that
 307       --  Make_Independent is called during the elaboration of this task
 308
 309       --------------------------
 310       -- Get_Next_Wakeup_Time --
 311       --------------------------
 312
 313       function Get_Next_Wakeup_Time return Duration is
 314       begin
 315          STU.Make_Independent;
 316          return Duration'Last;
 317       end Get_Next_Wakeup_Time;
 318
 319       Next_Wakeup_Time : Duration := Get_Next_Wakeup_Time;
 320       Timedout         : Boolean;
 321       Yielded          : Boolean;
 322       Now              : Duration;
 323       Dequeued         : Delay_Block_Access;
 324       Dequeued_Task    : Task_Id;
 325
 326    begin
 327       Timer_Server_ID := STPO.Self;
 328
 329       --  Since this package may be elaborated before System.Interrupt,
 330       --  we need to call Setup_Interrupt_Mask explicitly to ensure that
 331       --  this task has the proper signal mask.
 332
 333       Interrupt_Management.Operations.Setup_Interrupt_Mask;
 334
 335       --  Initialize the timer queue to empty, and make the wakeup time of the
 336       --  header node be larger than any real wakeup time we will ever use.
 337
 338       loop
 339          STI.Defer_Abort (Timer_Server_ID);
 340
 341          if Single_Lock then
 342             STPO.Lock_RTS;
 343          end if;
 344
 345          STPO.Write_Lock (Timer_Server_ID);
 346
 347          --  The timer server needs to catch pending aborts after finalization
 348          --  of library packages. If it doesn't poll for it, the server will
 349          --  sometimes hang.
 350
 351          if not Timer_Attention then
 352             Timer_Server_ID.Common.State := ST.Timer_Server_Sleep;
 353
 354             if Next_Wakeup_Time = Duration'Last then
 355                Timer_Server_ID.User_State := 1;
 356                Next_Wakeup_Time :=
 357                  STPO.Monotonic_Clock + OSP.Max_Sensible_Delay;
 358
 359             else
 360                Timer_Server_ID.User_State := 2;
 361             end if;
 362
 363             STPO.Timed_Sleep
 364               (Timer_Server_ID, Next_Wakeup_Time,
 365                OSP.Absolute_RT, ST.Timer_Server_Sleep,
 366                Timedout, Yielded);
 367             Timer_Server_ID.Common.State := ST.Runnable;
 368          end if;
 369
 370          --  Service all of the wakeup requests on the queue whose times have
 371          --  been reached, and update Next_Wakeup_Time to next wakeup time
 372          --  after that (the wakeup time of the head of the queue if any, else
 373          --  a time far in the future).
 374
 375          Timer_Server_ID.User_State := 3;
 376          Timer_Attention := False;
 377
 378          Now := STPO.Monotonic_Clock;
 379
 380          while Timer_Queue.Succ.Resume_Time <= Now loop
 381
 382             --  Dequeue the waiting task from the front of the queue
 383
 384             pragma Debug (System.Tasking.Debug.Trace
 385               (Timer_Server_ID, "Timer service: waking up waiting task", 'E'));
 386
 387             Dequeued := Timer_Queue.Succ;
 388             Timer_Queue.Succ := Dequeued.Succ;
 389             Dequeued.Succ.Pred := Dequeued.Pred;
 390             Dequeued.Succ := Dequeued;
 391             Dequeued.Pred := Dequeued;
 392
 393             --  We want to abort the queued task to the level of the async.
 394             --  select statement with the delay. To do that, we need to lock
 395             --  the ATCB of that task, but to avoid deadlock we need to release
 396             --  the lock of the Timer_Server. This leaves a window in which
 397             --  another task might perform an enqueue or dequeue operation on
 398             --  the timer queue, but that is OK because we always restart the
 399             --  next iteration at the head of the queue.
 400
 401             if Parameters.Runtime_Traces then
 402                Send_Trace_Info (E_Kill, Dequeued.Self_Id);
 403             end if;
 404
 405             STPO.Unlock (Timer_Server_ID);
 406             STPO.Write_Lock (Dequeued.Self_Id);
 407             Dequeued_Task := Dequeued.Self_Id;
 408             Dequeued.Timed_Out := True;
 409             STI.Locked_Abort_To_Level
 410               (Timer_Server_ID, Dequeued_Task, Dequeued.Level - 1);
 411             STPO.Unlock (Dequeued_Task);
 412             STPO.Write_Lock (Timer_Server_ID);
 413          end loop;
 414
 415          Next_Wakeup_Time := Timer_Queue.Succ.Resume_Time;
 416
 417          --  Service returns the Next_Wakeup_Time.
 418          --  The Next_Wakeup_Time is either an infinity (no delay request)
 419          --  or the wakeup time of the queue head. This value is used for
 420          --  an actual delay in this server.
 421
 422          STPO.Unlock (Timer_Server_ID);
 423
 424          if Single_Lock then
 425             STPO.Unlock_RTS;
 426          end if;
 427
 428          STI.Undefer_Abort (Timer_Server_ID);
 429       end loop;
 430    end Timer_Server;
 431
 432    ------------------------------
 433    -- Package Body Elaboration --
 434    ------------------------------
 435
 436 begin
 437    Timer_Queue.Succ := Timer_Queue'Unchecked_Access;
 438    Timer_Queue.Pred := Timer_Queue'Unchecked_Access;
 439    Timer_Queue.Resume_Time := Duration'Last;
 440    Timer_Server_ID := To_System (Timer_Server'Identity);
 441 end System.Tasking.Async_Delays;