libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(AR, ar)
 117 AC_CHECK_TOOL(RANLIB, ranlib, :)
 118
 119 AC_PROG_INSTALL
 120
 121 AM_MAINTAINER_MODE
 122
 123 AC_EXEEXT
 124
 125 # configure.host sets the following important variables
 126 #       libgcj_cflags    - host specific C compiler flags
 127 #       libgcj_cxxflags  - host specific C++ compiler flags
 128 #       libgcj_javaflags - host specific Java compiler flags
 129
 130 libgcj_cflags=
 131 libgcj_cxxflags=
 132 libgcj_javaflags=
 133
 134 . ${srcdir}/configure.host
 135
 136 LIBGCJ_CFLAGS="${libgcj_cflags}"
 137 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 138 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 139 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 140 AC_SUBST(LIBGCJ_CFLAGS)
 141 AC_SUBST(LIBGCJ_CXXFLAGS)
 142 AC_SUBST(LIBGCJ_JAVAFLAGS)
 143 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 144
 145 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 146
 147
 148 # See if the user has requested runtime debugging.
 149 LIBGCJDEBUG="disable"
 150 AC_SUBST(LIBGCJDEBUG)
 151 AC_ARG_ENABLE(libgcj-debug,
 152   AS_HELP_STRING([--enable-libgcj-debug],
 153                  [enable runtime debugging code]),
 154   [if test "$enable_libgcj_debug" = yes; then
 155     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 156     LIBGCJDEBUG="enable"
 157   fi])
 158
 159 # Determine which AWT peer libraries to build
 160 AC_ARG_ENABLE(java-awt,
 161   AS_HELP_STRING([--enable-java-awt],
 162                  [list of AWT peer implementations to be built]))
 163
 164 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 165 use_xlib_awt=""
 166 use_gtk_awt=""
 167 # The default toolkit to use is the first one specified.
 168 TOOLKIT=
 169 AC_SUBST(TOOLKIT)
 170
 171 for peer in $peerlibs ; do
 172   case $peer in
 173     xlib)
 174       if test "$no_x" = yes; then
 175         echo "*** xlib peers requested but no X library available" 1>&2
 176         exit 1
 177       else
 178         use_xlib_awt="yes"
 179         if test -z "$TOOLKIT"; then
 180            TOOLKIT=gnu.awt.xlib.XToolkit
 181         fi
 182       fi
 183       ;;
 184     gtk)
 185       if test "$no_x" = yes; then
 186          echo "*** xlib peers requested but no X library available" 1>&2
 187          exit 1
 188       else
 189          use_gtk_awt=yes
 190          if test -z "$TOOLKIT"; then
 191             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 192          fi
 193       fi
 194       ;;
 195     no)
 196       use_xlib_awt=
 197       use_gtk_awt=
 198       break
 199       ;;
 200     *)
 201       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 202       exit 1
 203   esac
 204 done
 205
 206 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 207 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 208
 209 # Create standard.omit based on decisions we just made.
 210 cp $srcdir/standard.omit.in standard.omit
 211 if test "$use_xlib_awt" != yes; then
 212    echo gnu/awt/xlib >> standard.omit
 213    echo gnu/gcj/xlib >> standard.omit
 214 fi
 215 if test "$use_gtk_awt" != yes; then
 216    echo gnu/java/awt/peer/gtk >> standard.omit
 217 fi
 218
 219 if test -z "${with_multisubdir}"; then
 220    builddotdot=.
 221 else
 222    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 223 fi
 224
 225 NATIVE=yes
 226
 227 # Which gcj do we use?
 228 which_gcj=default
 229 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 230 if test -n "${with_cross_host}"; then
 231   # We are being configured with a cross compiler. We can't
 232   # use ac_exeext, because that is for the target platform.
 233   NATIVE=no
 234   cross_host_exeext=
 235   case "${with_cross_host}" in
 236      *mingw* | *cygwin*)
 237          cross_host_exeext=.exe
 238      ;;
 239   esac
 240   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 241      if test x"$build_noncanonical" = x"$with_cross_host"; then
 242         # Ordinary cross (host!=target and host=build)
 243         which_gcj=built
 244      else
 245         # Canadian cross (host!=target and host!=build)
 246         which_gcj=cross
 247      fi
 248   else
 249      which_gcj=cross
 250   fi
 251 else
 252   # We are being configured with a native or crossed-native compiler
 253   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 254      if test x"$build" = x"$host"; then
 255         # True native build (host=target and host=build)
 256         which_gcj=built
 257      else
 258         # Crossed-native build (host=target and host!=build)
 259         which_gcj=cross
 260      fi
 261   else
 262      which_gcj=path
 263   fi
 264 fi
 265 case "${which_gcj}" in
 266    built)
 267       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 268       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 269       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
 270    ;;
 271    cross)
 272       if test "x${with_newlib}" = "xyes"; then
 273          # FIXME (comment): Why is this needed?
 274          GCC_UNWIND_INCLUDE=
 275          GCJ="${target_noncanonical}-gcj"
 276       else
 277          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 278       fi
 279       ZIP='$(target_noncanonical)-fastjar'
 280       GCJH='$(target_noncanonical)-gcjh'
 281    ;;
 282    path)
 283       GCJ="gcj -B`${PWDCMD-pwd}`/"
 284       ## In this case, gcj is found outside the build tree.  However, zip is
 285       ## found in the build tree.
 286       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
 287       GCJH=gcjh
 288    ;;
 289 esac
 290
 291 AC_SUBST(GCJH)
 292 AC_SUBST(ZIP)
 293
 294 # Create it, so that compile/link tests don't fail
 295 test -f libgcj.spec || touch libgcj.spec
 296
 297
 298
 299 # Set up to configure Classpath.
 300 # FIXME: no supported way to pass args in autoconf.
 301 ac_configure_args="$ac_configure_args --disable-load-library"
 302 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 303 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 304 dir1=`cd $srcdir && pwd`
 305 dir2=`pwd`
 306 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 307 ac_configure_args="$ac_configure_args --disable-core-jni"
 308 dnl FIXME?
 309 ac_configure_args="$ac_configure_args --disable-examples"
 310 ac_configure_args="$ac_configure_args --with-glibj=build"
 311 if test "$use_gtk_awt" != yes; then
 312   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 313 fi
 314 dnl --with-gcj=$GCJ
 315 dnl --with-javah=$GCJH
 316 dnl gjdoc?
 317 dnl gtk-cairo -- just export here...
 318 dnl --enable-regen-headers?
 319
 320 # Only use libltdl for non-newlib builds.
 321 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 322    AC_LIBLTDL_CONVENIENCE
 323    AC_LIBTOOL_DLOPEN
 324    DIRLTDL=libltdl
 325    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 326    # Sigh.  Libtool's macro doesn't do the right thing.
 327    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 328    # FIXME: this is a hack.
 329    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 330    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 331 fi
 332 AC_SUBST(INCLTDL)
 333 AC_SUBST(LIBLTDL)
 334 AC_SUBST(DIRLTDL)
 335 AC_PROG_LIBTOOL
 336 AM_PROG_GCJ
 337 AM_PROG_CC_C_O
 338
 339 AC_CONFIG_SUBDIRS(classpath libltdl)
 340
 341 # The -no-testsuite modules omit the test subdir.
 342 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 343
 344 # Should the runtime set system properties by examining the
 345 # environment variable GCJ_PROPERTIES?
 346 AC_ARG_ENABLE(getenv-properties,
 347   AS_HELP_STRING([--disable-getenv-properties],
 348                  [don't set system properties from GCJ_PROPERTIES]))
 349
 350 # Whether GCJ_PROPERTIES is used depends on the target.
 351 if test -z "$enable_getenv_properties"; then
 352    enable_getenv_properties=${enable_getenv_properties_default-yes}
 353 fi
 354 if test "$enable_getenv_properties" = no; then
 355    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 356      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 357 fi
 358
 359 # Whether we should use arguments to main()
 360 if test -z "$enable_main_args"; then
 361    enable_main_args=${enable_main_args_default-yes}
 362 fi
 363 if test "$enable_main_args" = no; then
 364    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 365 fi
 366
 367
 368 # Should we use hashtable-based synchronization?
 369 # Currently works only for Linux X86/ia64
 370 # Typically faster and more space-efficient
 371 AC_ARG_ENABLE(hash-synchronization,
 372   AS_HELP_STRING([--enable-hash-synchronization],
 373                  [use global hash table for monitor locks]))
 374
 375 if test -z "$enable_hash_synchronization"; then
 376    enable_hash_synchronization=$enable_hash_synchronization_default
 377 fi
 378
 379 AC_ARG_WITH(java-home,
 380   AS_HELP_STRING([--with-java-home=DIRECTORY],
 381                  [value of java.home system property]),
 382                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 383 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 384 AC_SUBST(JAVA_HOME)
 385
 386 # What is the native OS API for MinGW?
 387 AC_ARG_WITH(win32-nlsapi,
 388   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 389                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 390 [case "${withval}" in
 391   ansi) with_win32_nlsapi=ansi ;;
 392   unicows) with_win32_nlsapi=unicows ;;
 393   unicode) with_win32_nlsapi=unicode ;;
 394   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 395 esac],[with_win32_nlsapi=ansi])
 396
 397 case "${with_win32_nlsapi}" in
 398   unicows | unicode)
 399     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 400       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 401     ;;
 402 esac
 403
 404 # configure.host sets slow_pthread_self if the synchronization code should
 405 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 406 if test "${slow_pthread_self}" = "yes"; then
 407   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 408     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 409 fi
 410
 411 # Check for gc debugging.  This option is handled both here and in the GC.
 412 AC_ARG_ENABLE(gc-debug,
 413    AS_HELP_STRING([--enable-gc-debug],
 414                   [include full support for pointer backtracing etc.]),
 415 [ if test "$enable_gc_debug" = "yes"; then
 416     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 417               [Define if we want to use debug calls into the garbage collector.])
 418   fi])
 419
 420 # See if the user has the interpreter included.
 421 AC_ARG_ENABLE(interpreter,
 422   AS_HELP_STRING([--enable-interpreter],
 423                  [enable interpreter]),
 424   [if test "$enable_interpreter" = yes; then
 425     # This can also be set in configure.host.
 426     libgcj_interpreter=yes
 427   elif test "$enable_interpreter" = no; then
 428     libgcj_interpreter=no
 429   fi])
 430
 431 if test "$libgcj_interpreter" = yes; then
 432    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 433 fi
 434 INTERPRETER="$libgcj_interpreter"
 435 AC_SUBST(INTERPRETER)
 436
 437 AC_MSG_CHECKING([for exception model to use])
 438 AC_LANG_PUSH(C++)
 439 AC_ARG_ENABLE(sjlj-exceptions,
 440   AS_HELP_STRING([--enable-sjlj-exceptions],
 441                  [force use of builtin_setjmp for exceptions]),
 442 [:],
 443 [dnl Botheration.  Now we've got to detect the exception model.
 444 dnl Link tests against libgcc.a are problematic since -- at least
 445 dnl as of this writing -- we've not been given proper -L bits for
 446 dnl single-tree newlib and libgloss.
 447 dnl
 448 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 449 dnl conftest files before we got a change to grep them first.
 450 cat > conftest.$ac_ext << EOF
 451 [#]line __oline__ "configure"
 452 struct S { ~S(); };
 453 void bar();
 454 void foo()
 455 {
 456   S s;
 457   bar();
 458 }
 459 EOF
 460 old_CXXFLAGS="$CXXFLAGS"
 461 CXXFLAGS=-S
 462 if AC_TRY_EVAL(ac_compile); then
 463   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 464     enable_sjlj_exceptions=yes
 465   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 466     enable_sjlj_exceptions=no
 467   fi
 468 fi
 469 CXXFLAGS="$old_CXXFLAGS"
 470 rm -f conftest*])
 471 if test x$enable_sjlj_exceptions = xyes; then
 472   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 473         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 474   ac_exception_model_name=sjlj
 475 elif test x$enable_sjlj_exceptions = xno; then
 476   ac_exception_model_name="call frame"
 477 else
 478   AC_MSG_ERROR([unable to detect exception model])
 479 fi
 480 AC_LANG_POP(C++)
 481 AC_MSG_RESULT($ac_exception_model_name)
 482
 483 # If we are non using SJLJ exceptions, and this host does not have support
 484 # for unwinding from a signal handler, enable checked dereferences and divides.
 485 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 486   CHECKREFSPEC=-fcheck-references
 487   DIVIDESPEC=-fuse-divide-subroutine
 488   EXCEPTIONSPEC=
 489 fi
 490
 491 # See if the user wants to disable java.net.  This is the mildly
 492 # ugly way that we admit that target-side configuration sucks.
 493 AC_ARG_ENABLE(java-net,
 494   AS_HELP_STRING([--disable-java-net],
 495                  [disable java.net]))
 496
 497 # Whether java.net is built by default can depend on the target.
 498 if test -z "$enable_java_net"; then
 499    enable_java_net=${enable_java_net_default-yes}
 500 fi
 501 if test "$enable_java_net" = no; then
 502    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 503 fi
 504
 505 # See if the user wants to configure without libffi.  Some
 506 # architectures don't support it, and default values are set in
 507 # configure.host.
 508 AC_ARG_WITH(libffi,
 509   AS_HELP_STRING([--without-libffi],
 510                  [don't use libffi]),
 511   [:],
 512   [with_libffi=${with_libffi_default-yes}])
 513
 514 LIBFFI=
 515 LIBFFIINCS=
 516 if test "$with_libffi" != no; then
 517    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 518    LIBFFI=../libffi/libffi_convenience.la
 519    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 520 fi
 521 AC_SUBST(LIBFFI)
 522 AC_SUBST(LIBFFIINCS)
 523
 524 # See if the user wants to disable JVMPI support.
 525 AC_ARG_ENABLE(jvmpi,
 526   AS_HELP_STRING([--disable-jvmpi],
 527                  [disable JVMPI support]))
 528
 529 if test "$enable_jvmpi" != no; then
 530     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 531 fi
 532
 533 # If the target is an eCos system, use the appropriate eCos
 534 # I/O routines.
 535 # FIXME: this should not be a local option but a global target
 536 # system; at present there is no eCos target.
 537 TARGET_ECOS=${PROCESS-"no"}
 538 AC_ARG_WITH(ecos,
 539 [  --with-ecos             enable runtime eCos target support],
 540 TARGET_ECOS="$with_ecos"
 541 )
 542
 543 supply_backtrace=no
 544
 545 PLATFORM_INNER_NAT_HDRS=
 546 case "$TARGET_ECOS" in
 547    no) case "$host" in
 548       *mingw*)
 549             PLATFORM=Win32
 550             PLATFORMNET=Win32
 551             PLATFORMH=win32.h
 552         CHECK_FOR_BROKEN_MINGW_LD
 553       ;;
 554       *)
 555             PLATFORM=Posix
 556             PLATFORMNET=Posix
 557             PLATFORMH=posix.h
 558             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 559       ;;
 560       esac
 561       ;;
 562    *)
 563       PLATFORM=Ecos
 564       PLATFORMNET=NoNet
 565       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 566       PLATFORMH=posix.h
 567       ;;
 568 esac
 569 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 570 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 571
 572 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 573                                       [Define if you have int32_t and uint32_t.]))
 574 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 575                                         [Define if you have int32_t and uint32_t.]))
 576 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 577                                           [Define if you have u_int32_t]))
 578 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 579                                            [Define if you have u_int32_t]))
 580
 581 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 582 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 583
 584 case "$host" in
 585   *-darwin*) DARWIN_CRT=true ;;
 586   *) DARWIN_CRT=false ;;
 587 esac
 588 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 589
 590 # These may not be defined in a non-ANS conformant embedded system.
 591 # FIXME: Should these case a runtime exception in that case?
 592 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 593                                   [Define is you have 'mktime' in <time.h>]))
 594 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 595                                   [Define is you have 'localtime' in <time.h>]))
 596
 597 # Create the subdirectory for natFile.cc, or the attempt
 598 # to create the link will fail.
 599 test -d java || mkdir java
 600 test -d java/io || mkdir java/io
 601 test -d gnu || mkdir gnu
 602 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 603
 604 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 605 test -d java/lang || mkdir java/lang
 606 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 607 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 608
 609 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 610 test -d java/net || mkdir java/net
 611 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 612 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 613
 614 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 615 test -d gnu/java || mkdir gnu/java
 616 test -d gnu/java/net || mkdir gnu/java/net
 617 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 618 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 619
 620 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 621 test -d gnu/java/nio || mkdir gnu/java/nio
 622 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 623 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 624 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 625 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 626
 627 case "${host}" in
 628     *mingw*)
 629       SYSTEMSPEC="-lgdi32 -lws2_32"
 630       if test "${with_win32_nlsapi}" = "unicows"; then
 631         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 632       fi
 633     ;;
 634     *)
 635       SYSTEMSPEC=
 636     ;;
 637 esac
 638 AC_SUBST(SYSTEMSPEC)
 639
 640 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 641 AC_SUBST(LIBGCJTESTSPEC)
 642
 643 AC_ARG_WITH(system-zlib,
 644   AS_HELP_STRING([--with-system-zlib],
 645                  [use installed libz]))
 646 ZLIBSPEC=
 647 AC_SUBST(ZLIBSPEC)
 648 ZLIBTESTSPEC=
 649 AC_SUBST(ZLIBTESTSPEC)
 650
 651 AC_PATH_XTRA
 652
 653 # determine whether to enable the cairo GTK Graphics2D backend
 654 AC_ARG_ENABLE(gtk-cairo,
 655   AS_HELP_STRING([--enable-gtk-cairo],
 656                  [build the cairo Graphics2D implementation on GTK]))
 657 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 658 if test "x${enable_gtk_cairo}" = xyes
 659 then
 660         PKG_CHECK_MODULES(CAIRO, cairo)
 661         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 662 fi
 663 AC_SUBST(CAIRO_LIBS)
 664 AC_SUBST(CAIRO_CFLAGS)
 665 AC_SUBST(PANGOFT2_LIBS)
 666 AC_SUBST(PANGOFT2_CFLAGS)
 667
 668 # FIXME: this should be _libs on some hosts.
 669 libsubdir=.libs
 670
 671 # Allow the GC to be disabled.  Can be useful when debugging.
 672 AC_MSG_CHECKING([for garbage collector to use])
 673 AC_ARG_ENABLE(java-gc,
 674   AS_HELP_STRING([--enable-java-gc=TYPE],
 675                  [choose garbage collector (default is boehm)]),
 676   [GC=$enableval],
 677   [GC=boehm])
 678 GCLIBS=
 679 GCINCS=
 680 GCDEPS=
 681 GCSPEC=
 682 JC1GCSPEC=
 683 GCTESTSPEC=
 684 case "$GC" in
 685  boehm)
 686     AC_MSG_RESULT(boehm)
 687     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 688     JC1GCSPEC='-fuse-boehm-gc'
 689     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 690     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 691     GCOBJS=boehm.lo
 692     GCHDR=boehm-gc.h
 693     # The POSIX thread support needs to know this.
 694     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 695     ;;
 696  no)
 697     AC_MSG_RESULT(none)
 698     GCHDR=no-gc.h
 699     ;;
 700  *)
 701     AC_MSG_ERROR([unrecognized collector "$GC"])
 702     ;;
 703 esac
 704 AC_SUBST(GCLIBS)
 705 AC_SUBST(GCINCS)
 706 AC_SUBST(GCDEPS)
 707 AC_SUBST(GCSPEC)
 708 AC_SUBST(JC1GCSPEC)
 709 AC_SUBST(GCTESTSPEC)
 710 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 711 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 712 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 713
 714
 715 AC_MSG_CHECKING([for thread model used by GCC])
 716 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 717 AC_MSG_RESULT([$THREADS])
 718
 719 case "$THREADS" in
 720  no | none | single)
 721     THREADS=none
 722     ;;
 723  posix | posix95 | pthreads)
 724     THREADS=posix
 725     case "$host" in
 726      *-*-linux*)
 727         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 728         ;;
 729     esac
 730     ;;
 731  win32)
 732     ;;
 733  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 734     AC_MSG_ERROR(thread package $THREADS not yet supported)
 735     ;;
 736  *)
 737     AC_MSG_ERROR($THREADS is an unknown thread package)
 738     ;;
 739 esac
 740
 741 THREADCXXFLAGS=
 742 THREADLDFLAGS=
 743 THREADLIBS=
 744 THREADINCS=
 745 THREADDEPS=
 746 THREADH=
 747 THREADSPEC=
 748 case "$THREADS" in
 749  posix)
 750     case "$host" in
 751      *-*-cygwin*)
 752         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 753         ;;
 754      *-*-freebsd[[1234]]*)
 755         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 756         # merely adds pthread_* functions) but it does have a -pthread switch
 757         # which is required at link-time to select -lc_r *instead* of -lc.
 758         THREADLDFLAGS=-pthread
 759         # Don't set THREADSPEC here as might be expected since -pthread is
 760         # not processed when found within a spec file, it must come from
 761         # the command line.  For now, the user must provide the -pthread
 762         # switch to link code compiled with gcj.  In future, consider adding
 763         # support for weak references to pthread_* functions ala gthr.h API.
 764         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 765         ;;
 766      *-*-freebsd*)
 767         # FreeBSD 5 implements a model much closer to other modern UNIX
 768         # which support threads.  However, it still does not support
 769         # -lpthread.
 770         THREADLDFLAGS=-pthread
 771         THREADSPEC=-lc_r
 772         ;;
 773      alpha*-dec-osf*)
 774         THREADCXXFLAGS=-pthread
 775         # boehm-gc needs some functions from librt, so link that too.
 776         THREADLIBS='-lpthread -lrt'
 777         THREADSPEC='-lpthread -lrt'
 778         ;;
 779      *)
 780         THREADLIBS=-lpthread
 781         THREADSPEC=-lpthread
 782         ;;
 783     esac
 784     THREADH=posix-threads.h
 785     # MIT pthreads doesn't seem to have the mutexattr functions.
 786     # But for now we don't check for it.  We just assume you aren't
 787     # using MIT pthreads.
 788     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 789
 790     # If we're using the Boehm GC, then we happen to know that it
 791     # defines _REENTRANT, so we don't bother.  Eww.
 792     if test "$GC" != boehm; then
 793        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 794     fi
 795     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 796     ;;
 797
 798  win32)
 799     THREADH=win32-threads.h
 800     ;;
 801
 802  none)
 803     THREADH=no-threads.h
 804     ;;
 805 esac
 806 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 807 AC_SUBST(THREADLIBS)
 808 AC_SUBST(THREADINCS)
 809 AC_SUBST(THREADDEPS)
 810 AC_SUBST(THREADSPEC)
 811 AC_SUBST(THREADLDFLAGS)
 812 AC_SUBST(THREADCXXFLAGS)
 813 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 814 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 815 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 816
 817 if test -d sysdep; then true; else mkdir sysdep; fi
 818 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 819 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 820 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 821
 822 HASH_SYNC_SPEC=
 823 # Hash synchronization is only useful with posix threads right now.
 824 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 825    HASH_SYNC_SPEC=-fhash-synchronization
 826    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 827 fi
 828 AC_SUBST(HASH_SYNC_SPEC)
 829
 830 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 831
 832 # We're in the tree with gcc, and need to include some of its headers.
 833 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 834
 835 if test "x${with_newlib}" = "xyes"; then
 836    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 837    # may not work correctly, because the compiler may not be able to
 838    # link executables.
 839
 840    # We assume newlib.  This lets us hard-code the functions we know
 841    # we'll have.
 842    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 843    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 844    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 845    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 846    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 847    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 848    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 849    # This is only for POSIX threads.
 850    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 851    # We also assume we are using gcc, which provides alloca.
 852    AC_DEFINE(HAVE_ALLOCA)
 853
 854    # Assume we do not have getuid and friends.
 855    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 856    PLATFORMNET=NoNet
 857 else
 858    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 859                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 860                    access stat mkdir rename rmdir unlink realpath utime chmod \
 861                    nl_langinfo setlocale \
 862                    inet_pton uname inet_ntoa \
 863                    fork execvp pipe sigaction ftruncate])
 864    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 865    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 866    AC_CHECK_FUNC(backtrace, [
 867      case "$host" in
 868        ia64-*-linux*)
 869          # Has broken backtrace()
 870          ;;
 871        mips*-*-linux*)
 872          # Has broken backtrace(), but we supply our own.
 873          if test -d sysdep; then true; else mkdir -p sysdep; fi
 874          supply_backtrace=yes
 875          AC_DEFINE(HAVE_BACKTRACE, 1,
 876            [Define if your platform has a working backtrace() function.])
 877          ;;
 878        *)
 879          AC_DEFINE(HAVE_BACKTRACE, 1,
 880            [Define if your platform has a working backtrace() function.])
 881          ;;
 882      esac
 883    ], [
 884      case "$host" in
 885        *mingw*)
 886          # Has backtrace() defined in libgcj itself
 887          AC_DEFINE(HAVE_BACKTRACE, 1,
 888            [Define if your platform has a working backtrace() function.])
 889          ;;
 890      esac
 891    ])
 892
 893    AC_CHECK_LIB(dl, dladdr, [
 894      if test "x${disable_dladdr}" = "xyes"; then
 895        #Broken dladdr().
 896        true
 897      else
 898        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 899      fi
 900    ])
 901    if test x"$build" = x"$host"; then
 902      AC_CHECK_FILES(/proc/self/exe, [
 903        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 904    else
 905      case $host in
 906      *-linux*)
 907        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 908        ;;
 909      esac
 910    fi
 911
 912    AM_ICONV
 913    AM_LC_MESSAGES
 914    AC_STRUCT_TIMEZONE
 915
 916    AC_CHECK_FUNCS(gethostbyname_r, [
 917      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 918        [Define if you have the 'gethostbyname_r' function.])
 919      # There are two different kinds of gethostbyname_r.
 920      # We look for the one that returns `int'.
 921      # Hopefully this check is robust enough.
 922      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 923        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 924
 925      case " $GCINCS " in
 926      *" -D_REENTRANT "*) ;;
 927      *)
 928         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 929         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 930         [libjava_cv_gethostbyname_r_needs_reentrant],
 931         [ AC_LANG_PUSH(C++)
 932           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 933             [[gethostbyname_r("", 0, 0);]])],
 934             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 935                 CPPFLAGS_SAVE="$CPPFLAGS"
 936                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 937                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 938                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 939                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 940                 CPPFLAGS="$CPPFLAGS_SAVE"
 941           ])
 942           AC_LANG_POP(C++)
 943         ])
 944         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 945           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 946         fi
 947      ;;
 948      esac
 949
 950      AC_CACHE_CHECK([for struct hostent_data],
 951         [libjava_cv_struct_hostent_data], [dnl
 952         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 953 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 954 # define _REENTRANT 1
 955 #endif
 956 #include <netdb.h>]], [[struct hostent_data data;]])],
 957           [libjava_cv_struct_hostent_data=yes],
 958           [libjava_cv_struct_hostent_data=no])])
 959      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 960        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 961          [Define if struct hostent_data is defined in netdb.h])
 962      fi
 963    ])
 964
 965    # FIXME: libjava source code expects to find a prototype for
 966    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 967    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 968    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 969    # linkage check is enough, yet C++ code requires proper prototypes.)
 970    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 971    AC_CHECK_FUNCS(gethostbyaddr_r, [
 972      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 973        [Define if you have the 'gethostbyaddr_r' function.])
 974      # There are two different kinds of gethostbyaddr_r.
 975      # We look for the one that returns `int'.
 976      # Hopefully this check is robust enough.
 977      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 978        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 979          [Define if gethostbyaddr_r returns 'int'.])])])])
 980
 981    AC_CHECK_FUNCS(gethostname, [
 982      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 983        [Define if you have the 'gethostname' function.])
 984      AC_EGREP_HEADER(gethostname, unistd.h, [
 985        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 986          [Define if gethostname is declared in <unistd.h>.])])])
 987
 988    AC_CHECK_FUNCS(usleep, [
 989      AC_EGREP_HEADER(usleep, unistd.h, [
 990        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 991           [Define if usleep is declared in <unistd.h>.])])])
 992
 993    # Look for these functions in the thread library, but only bother
 994    # if using POSIX threads.
 995    if test "$THREADS" = posix; then
 996       save_LIBS="$LIBS"
 997       LIBS="$LIBS $THREADLIBS"
 998       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 999       # E.g., Solaris.
1000       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1001
1002       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1003       # Solaris 7 the name librt is preferred.
1004       AC_CHECK_FUNCS(sched_yield, , [
1005         AC_CHECK_LIB(rt, sched_yield, [
1006           AC_DEFINE(HAVE_SCHED_YIELD)
1007           THREADLIBS="$THREADLIBS -lrt"
1008           THREADSPEC="$THREADSPEC -lrt"], [
1009           AC_CHECK_LIB(posix4, sched_yield, [
1010             AC_DEFINE(HAVE_SCHED_YIELD)
1011             THREADLIBS="$THREADLIBS -lposix4"
1012             THREADSPEC="$THREADSPEC -lposix4"])])])
1013       LIBS="$save_LIBS"
1014
1015       # We can save a little space at runtime if the mutex has m_count
1016       # or __m_count.  This is a nice hack for Linux.
1017       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1018           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1019         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1020              [Define if pthread_mutex_t has m_count member.]), [
1021         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1022             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1023           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1024             [Define if pthread_mutex_t has __m_count member.]))])
1025    fi
1026
1027    # We require a way to get the time.
1028    time_found=no
1029    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1030    if test "$time_found" = no; then
1031       AC_MSG_ERROR([no function found to get the time])
1032    fi
1033
1034    AC_CHECK_FUNCS(memmove)
1035
1036    # We require memcpy.
1037    memcpy_found=no
1038    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1039    if test "$memcpy_found" = no; then
1040       AC_MSG_ERROR([memcpy is required])
1041    fi
1042
1043    AC_CHECK_LIB(dl, dlopen, [
1044        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
1045
1046    # Some library-finding code we stole from Tcl.
1047    #--------------------------------------------------------------------
1048    #    Check for the existence of the -lsocket and -lnsl libraries.
1049    #    The order here is important, so that they end up in the right
1050    #    order in the command line generated by make.  Here are some
1051    #    special considerations:
1052    #    1. Use "connect" and "accept" to check for -lsocket, and
1053    #       "gethostbyname" to check for -lnsl.
1054    #    2. Use each function name only once:  can't redo a check because
1055    #       autoconf caches the results of the last check and won't redo it.
1056    #    3. Use -lnsl and -lsocket only if they supply procedures that
1057    #       aren't already present in the normal libraries.  This is because
1058    #       IRIX 5.2 has libraries, but they aren't needed and they're
1059    #       bogus:  they goof up name resolution if used.
1060    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1061    #       To get around this problem, check for both libraries together
1062    #       if -lsocket doesn't work by itself.
1063    #--------------------------------------------------------------------
1064
1065    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1066     [gcj_cv_lib_sockets=
1067      gcj_checkBoth=0
1068      unset ac_cv_func_connect
1069      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1070      if test "$gcj_checkSocket" = 1; then
1071          unset ac_cv_func_connect
1072          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1073                       gcj_checkBoth=1)
1074      fi
1075      if test "$gcj_checkBoth" = 1; then
1076          gcj_oldLibs=$LIBS
1077          LIBS="$LIBS -lsocket -lnsl"
1078          unset ac_cv_func_accept
1079          AC_CHECK_FUNC(accept,
1080                        [gcj_checkNsl=0
1081                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1082          unset ac_cv_func_accept
1083          LIBS=$gcj_oldLibs
1084      fi
1085      unset ac_cv_func_gethostbyname
1086      gcj_oldLibs=$LIBS
1087      LIBS="$LIBS $gcj_cv_lib_sockets"
1088      AC_CHECK_FUNC(gethostbyname, ,
1089                    [AC_CHECK_LIB(nsl, main,
1090                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1091      unset ac_cv_func_gethostbyname
1092      LIBS=$gcj_oldLIBS
1093    ])
1094    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1095
1096    if test "$with_system_zlib" = yes; then
1097       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1098    fi
1099
1100    # Test for Gtk stuff, if asked for.
1101    if test "$use_gtk_awt" = yes; then
1102       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1103       AC_SUBST(GTK_CFLAGS)
1104       AC_SUBST(GTK_LIBS)
1105
1106       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1107       AC_SUBST(GLIB_CFLAGS)
1108       AC_SUBST(GLIB_LIBS)
1109
1110       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1111       AC_SUBST(LIBART_CFLAGS)
1112       AC_SUBST(LIBART_LIBS)
1113
1114       # We require the XTest Extension to support java.awt.Robot.
1115       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1116                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1117                    [${X_LIBS}])
1118    fi
1119
1120    # On Solaris, and maybe other architectures, the Boehm collector
1121    # requires -ldl.
1122    if test "$GC" = boehm; then
1123       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1124    fi
1125 fi
1126 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1127
1128 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1129 case $build in
1130     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1131     *)         CLASSPATH_SEPARATOR=':' ;;
1132 esac
1133 AC_SUBST(CLASSPATH_SEPARATOR)
1134
1135 # We must search the source tree for java.lang, since we still don't
1136 # have libgcj.jar nor java/lang/*.class
1137 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1138 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1139
1140 # Since some classes depend on this one, we need its source available
1141 # before we can do any GCJ compilation test :-(
1142 if test ! -f gnu/classpath/Configuration.java; then
1143   test -d gnu || mkdir gnu
1144   test -d gnu/classpath || mkdir gnu/classpath
1145   sed -e "s,@LIBGCJDEBUG@,$LIBGCJDEBUG," \
1146       -e "s,@TOOLKIT@,$TOOLKIT," \
1147         < $srcdir/gnu/classpath/Configuration.java.in \
1148         > gnu/classpath/Configuration.java
1149   # We do not want to redirect the output of the grep below to /dev/null,
1150   # but we add /dev/null to the input list so that grep will print the
1151   # filename of Configuration.java in case it finds any matches.
1152   if grep @ gnu/classpath/Configuration.java /dev/null; then
1153     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1154   fi
1155 fi
1156
1157 LT_AC_PROG_GCJ
1158
1159 # Now remove it.
1160 rm -f gnu/classpath/Configuration.java
1161
1162 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1163
1164 AC_CHECK_SIZEOF(void *)
1165
1166 AC_C_BIGENDIAN
1167
1168 ZLIBS=
1169 SYS_ZLIBS=
1170 ZINCS=
1171
1172 if test -z "$ZLIBSPEC"; then
1173    # Use zlib from the GCC tree.
1174    ZINCS='-I$(top_srcdir)/../zlib'
1175    ZLIBS=../zlib/libzgcj_convenience.la
1176 else
1177    # System's zlib.
1178    SYS_ZLIBS="$ZLIBSPEC"
1179 fi
1180 AC_SUBST(ZLIBS)
1181 AC_SUBST(SYS_ZLIBS)
1182 AC_SUBST(ZINCS)
1183 AC_SUBST(DIVIDESPEC)
1184 AC_SUBST(CHECKREFSPEC)
1185 AC_SUBST(EXCEPTIONSPEC)
1186 AC_SUBST(BACKTRACESPEC)
1187 AC_SUBST(IEEESPEC)
1188
1189 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1190 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1191 AC_SUBST(GCC_UNWIND_INCLUDE)
1192
1193 # Process the option "--enable-version-specific-runtime-libs"
1194 # Calculate toolexeclibdir
1195 case ${version_specific_libs} in
1196   yes)
1197     # Need the gcc compiler version to know where to install libraries
1198     # and header files if --enable-version-specific-runtime-libs option
1199     # is selected.
1200     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1201     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1202     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1203     toolexeclibdir=$toolexecmainlibdir
1204     ;;
1205   no)
1206     if test -n "$with_cross_host" &&
1207        test x"$with_cross_host" != x"no"; then
1208       # Install a library built with a cross compiler in tooldir, not libdir.
1209       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1210       toolexecmainlibdir='$(toolexecdir)/lib'
1211     else
1212       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1213       toolexecmainlibdir='$(libdir)'
1214     fi
1215     multi_os_directory=`$CC -print-multi-os-directory`
1216     case $multi_os_directory in
1217       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1218       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1219     esac
1220     ;;
1221 esac
1222 AC_SUBST(toolexecdir)
1223 AC_SUBST(toolexecmainlibdir)
1224 AC_SUBST(toolexeclibdir)
1225
1226 # Determine gcj version number.
1227 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1228 GCJVERSION=$gcjversion
1229 AC_SUBST(GCJVERSION)
1230 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1231
1232 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1233 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1234
1235 TL_AC_GXX_INCLUDE_DIR
1236
1237 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1238 # On that system, sys/ioctl.h will not include sys/filio.h unless
1239 # BSD_COMP is defined; just including sys/filio.h is simpler.
1240 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1241 # for now.  If you change this, you also must update natFile.cc.
1242 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1243                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1244                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1245                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1246                   dirent.h])
1247 AC_CHECK_HEADERS(inttypes.h, [
1248     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1249     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1250 ])
1251 AC_HEADER_SYS_WAIT
1252
1253 AC_CHECK_TYPE([ssize_t], [int])
1254
1255 AC_MSG_CHECKING([for in_addr_t])
1256 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1257 #if STDC_HEADERS
1258 #include <stdlib.h>
1259 #include <stddef.h>
1260 #endif
1261 #if HAVE_NETINET_IN_H
1262 #include <netinet/in.h>
1263 #endif]], [[in_addr_t foo;]])],
1264   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1265      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1266    AC_MSG_RESULT(yes)],
1267   [AC_MSG_RESULT(no)])
1268
1269 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1270 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1271   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1272      [Define if struct ip_mreq is defined in netinet/in.h.])
1273    AC_MSG_RESULT(yes)],
1274   [AC_MSG_RESULT(no)])
1275
1276 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1277 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1278   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1279      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1280    AC_MSG_RESULT(yes)],
1281   [AC_MSG_RESULT(no)])
1282
1283 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1284 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1285   [AC_DEFINE(HAVE_INET6, 1,
1286      [Define if inet6 structures are defined in netinet/in.h.])
1287    AC_MSG_RESULT(yes)],
1288   [AC_MSG_RESULT(no)])
1289
1290 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1291 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1292 #include <sys/types.h>
1293 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1294   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1295    AC_MSG_RESULT(yes)],
1296   [AC_MSG_RESULT(no)])
1297
1298 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1299 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1300   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1301    AC_MSG_RESULT(yes)],
1302   [AC_MSG_RESULT(no)
1303    AC_MSG_CHECKING([for global timezone variable])
1304    dnl FIXME: we don't want a link check here because that won't work
1305    dnl when cross-compiling.  So instead we make an assumption that
1306    dnl the header file will mention timezone if it exists.
1307    dnl Don't find the win32 function timezone
1308    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1309      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1310       AC_MSG_RESULT(yes)],
1311      [AC_MSG_RESULT(no)
1312        AC_MSG_CHECKING([for global _timezone variable])
1313        dnl FIXME: As above, don't want link check
1314        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1315          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1316             [Define if your platform has the global _timezone variable.])
1317           AC_MSG_RESULT(yes)],
1318           [AC_MSG_RESULT(no)])])])
1319
1320 AC_FUNC_ALLOCA
1321 AC_FUNC_MMAP
1322
1323 AC_CHECK_PROGS(PERL, perl, false)
1324
1325 SYSDEP_SOURCES=
1326 SIGNAL_HANDLER_AUX=
1327
1328 case "${host}" in
1329  i?86-*-linux*)
1330     SIGNAL_HANDLER=include/i386-signal.h
1331     ;;
1332  sparc*-sun-solaris*)
1333     SIGNAL_HANDLER=include/sparc-signal.h
1334     ;;
1335 # ia64-*)
1336 #    SYSDEP_SOURCES=sysdep/ia64.c
1337 #    test -d sysdep || mkdir sysdep
1338 #    ;;
1339  hppa*-*-linux*)
1340     SIGNAL_HANDLER=include/pa-signal.h
1341     ;;
1342  ia64-*-linux*)
1343     SIGNAL_HANDLER=include/dwarf2-signal.h
1344     ;;
1345  powerpc*-*-linux*)
1346     SIGNAL_HANDLER=include/powerpc-signal.h
1347     ;;
1348  alpha*-*-linux*)
1349     SIGNAL_HANDLER=include/dwarf2-signal.h
1350     ;;
1351  s390*-*-linux*)
1352     SIGNAL_HANDLER=include/s390-signal.h
1353     ;;
1354  x86_64*-*-linux*)
1355     SIGNAL_HANDLER=include/x86_64-signal.h
1356     SIGNAL_HANDLER_AUX=include/i386-signal.h
1357     ;;
1358  sparc*-*-linux*)
1359     SIGNAL_HANDLER=include/dwarf2-signal.h
1360     ;;
1361  sh*-*-linux*)
1362     SIGNAL_HANDLER=include/sh-signal.h
1363     ;;
1364  *mingw*)
1365     SIGNAL_HANDLER=include/win32-signal.h
1366     ;;
1367  mips*-*-linux*)
1368     SIGNAL_HANDLER=include/mips-signal.h
1369     ;;
1370  *-*-darwin*)
1371     SIGNAL_HANDLER=include/darwin-signal.h
1372     ;;
1373  *)
1374     SIGNAL_HANDLER=include/default-signal.h
1375     ;;
1376 esac
1377
1378 # If we're using sjlj exceptions, forget what we just learned.
1379 if test "$enable_sjlj_exceptions" = yes; then
1380    SIGNAL_HANDLER=include/default-signal.h
1381    SIGNAL_HANDLER_AUX=
1382 fi
1383
1384 AC_SUBST(SYSDEP_SOURCES)
1385
1386 if test -z "$SIGNAL_HANDLER_AUX"; then
1387   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1388 fi
1389
1390 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1391                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1392
1393 if test "${multilib}" = "yes"; then
1394   multilib_arg="--enable-multilib"
1395 else
1396   multilib_arg=
1397 fi
1398
1399
1400
1401 here=`${PWDCMD-pwd}`
1402 AC_SUBST(here)
1403
1404 # We get this from the environment.
1405 AC_SUBST(GCJFLAGS)
1406
1407 AC_CONFIG_FILES([
1408 Makefile
1409 libgcj.pc
1410 libgcj.spec
1411 libgcj-test.spec
1412 gcj/Makefile
1413 include/Makefile
1414 testsuite/Makefile
1415 ])
1416
1417 AC_CONFIG_COMMANDS([default],
1418 [# Only add multilib support code if we just rebuilt top-level Makefile.
1419 case " $CONFIG_FILES " in
1420  *" Makefile "*)
1421    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1422    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1423    ;;
1424 esac
1425 for ac_multi_file in $CONFIG_FILES; do
1426   case $ac_multi_file in
1427   */Makefile)
1428     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1429   esac
1430 done
1431 ],
1432 srcdir=${srcdir}
1433 host=${host}
1434 target=${target}
1435 with_multisubdir=${with_multisubdir}
1436 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1437 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1438 libgcj_basedir=${libgcj_basedir}
1439 CC="${CC}"
1440 CXX="${CXX}"
1441 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1442 )
1443
1444 AC_OUTPUT