libf2c/libI77/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 2001 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Fortran.
   6 #
   7 #GNU Fortran is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Fortran; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(ftell_.c)
  24 AC_CONFIG_HEADER(config.h)
  25
  26 dnl Checks for programs.
  27
  28 dnl FIXME AC_PROG_CC wants CC to be able to link things, but it may
  29 dnl not be able to.
  30 define([AC_PROG_CC_WORKS],[])
  31
  32 # For g77 we'll set CC to point at the built gcc, but this will get it into
  33 # the makefiles
  34 AC_PROG_CC
  35
  36 test "$AR" || AR=ar
  37 AC_SUBST(AR)
  38 AC_PROG_MAKE_SET
  39
  40 dnl Checks for libraries.
  41
  42 dnl Checks for header files.
  43 # Sanity check for the cross-compilation case:
  44 AC_CHECK_HEADER(stdio.h,:,
  45   [AC_MSG_ERROR([Can't find stdio.h.
  46 You must have a usable C system for the target already installed, at least
  47 including headers and, preferably, the library, before you can configure
  48 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  49 then the target library, then build with \`LANGUAGES=f77'.])])
  50
  51 AC_HEADER_STDC
  52 dnl We could do this if we didn't know we were using gcc
  53 dnl AC_MSG_CHECKING(for prototype-savvy compiler)
  54 dnl AC_CACHE_VAL(g77_cv_sys_proto,
  55 dnl   [AC_TRY_LINK(,
  56 dnl dnl looks screwy because TRY_LINK expects a function body
  57 dnl    [return 0;} int foo (int * bar) {],
  58 dnl    g77_cv_sys_proto=yes,
  59 dnl    [g77_cv_sys_proto=no
  60 dnl     AC_DEFINE(KR_headers)])])
  61 dnl AC_MSG_RESULT($g77_cv_sys_proto)
  62
  63 AC_MSG_CHECKING(for posix)
  64 AC_CACHE_VAL(g77_cv_header_posix,
  65   AC_EGREP_CPP(yes,
  66   [#include <sys/types.h>
  67 #include <unistd.h>
  68 #ifdef _POSIX_VERSION
  69   yes
  70 #endif
  71 ],
  72   g77_cv_header_posix=yes,
  73   g77_cv_header_posix=no))
  74 AC_MSG_RESULT($g77_cv_header_posix)
  75
  76 # We can rely on the GNU library being posix-ish.  I guess checking the
  77 # header isn't actually like checking the functions, though...
  78 AC_MSG_CHECKING(for GNU library)
  79 AC_CACHE_VAL(g77_cv_lib_gnu,
  80   AC_EGREP_CPP(yes,
  81     [#include <stdio.h>
  82 #ifdef __GNU_LIBRARY__
  83   yes
  84 #endif
  85 ],
  86   g77_cv_lib_gnu=yes, g77_cv_lib_gnu=no))
  87 AC_MSG_RESULT($g77_cv_lib_gnu)
  88
  89 # Apparently cygwin needs to be special-cased.
  90 AC_MSG_CHECKING([for cyg\`win'32])
  91 AC_CACHE_VAL(g77_cv_sys_cygwin32,
  92   AC_EGREP_CPP(yes,
  93   [#ifdef __CYGWIN32__
  94   yes
  95 #endif
  96 ],
  97   g77_cv_sys_cygwin32=yes,
  98   g77_cv_sys_cygwin32=no))
  99 AC_MSG_RESULT($g77_cv_sys_cygwin32)
 100
 101 # ditto for mingw32.
 102 AC_MSG_CHECKING([for mingw32])
 103 AC_CACHE_VAL(g77_cv_sys_mingw32,
 104   AC_EGREP_CPP(yes,
 105   [#ifdef __MINGW32__
 106   yes
 107 #endif
 108 ],
 109   g77_cv_sys_mingw32=yes,
 110   g77_cv_sys_mingw32=no))
 111 AC_MSG_RESULT($g77_cv_sys_mingw32)
 112
 113
 114 AC_CHECK_HEADER(fcntl.h,
 115    test $g77_cv_header_posix = yes && AC_DEFINE(_POSIX_SOURCE),
 116    AC_DEFINE(NO_FCNTL, 1, [Define if fcntl.h is missing.])
 117    AC_DEFINE(OPEN_DECL, 1, [Define if fcntl.h is missing.]))
 118
 119 dnl Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_CONST
 121 AC_TYPE_SIZE_T
 122
 123 dnl Checks for library functions.
 124
 125 # This should always succeed on unix.
 126 # Apparently positive result on cygwin loses re. NON_UNIX_STDIO
 127 # (as of cygwin b18). Likewise on mingw.
 128 AC_CHECK_FUNC(fstat)
 129 AC_MSG_CHECKING([need for NON_UNIX_STDIO])
 130 if test $g77_cv_sys_cygwin32 = yes \
 131   || test $g77_cv_sys_mingw32 = yes \
 132   || test $ac_cv_func_fstat = no; then
 133   AC_MSG_RESULT(yes)
 134   AC_DEFINE(NON_UNIX_STDIO, 1, [Define if we do not have Unix Stdio.])
 135 else
 136   AC_MSG_RESULT(no)
 137 fi
 138
 139 AC_CHECK_FUNCS(ftruncate)
 140 AC_CHECK_FUNCS(mkstemp)
 141 AC_CHECK_FUNCS(tempnam)
 142
 143 # posix will guarantee the right behaviour for sprintf, else we can't be
 144 # sure; HEADER_STDC wouldn't be the right check in sunos4, for instance.
 145 # However, on my sunos4/gcc setup unistd.h leads us wrongly to believe
 146 # we're posix-conformant, so always do the test.
 147 AC_MSG_CHECKING(for ansi/posix sprintf result)
 148 dnl This loses if included as an argument to AC_CACHE_VAL because the
 149 dnl changequote doesn't take effect and the [] vanish.
 150 dnl fixme: use cached value
 151 AC_TRY_RUN(changequote(<<, >>)dnl
 152   <<#include <stdio.h>
 153     /* does sprintf return the number of chars transferred? */
 154     main () {char foo[2]; (sprintf(foo, "1") == 1) ? exit(0) : exit(1);}
 155 >>changequote([, ]),
 156     g77_cv_sys_sprintf_ansi=yes,
 157     g77_cv_sys_sprintf_ansi=no,
 158     g77_cv_sys_sprintf_ansi=no)
 159 AC_CACHE_VAL(g77_cv_sys_sprintf_ansi,
 160      g77_cv_sys_sprintf_ansi=$g77_cv_sys_sprintf_ansi)
 161 dnl We get a misleading `(cached)' message...
 162 AC_MSG_RESULT($g77_cv_sys_sprintf_ansi)
 163
 164 # The cygwin patch takes steps to avoid defining USE_STRLEN here -- I don't
 165 # understand why.
 166 if test $g77_cv_sys_sprintf_ansi != yes; then
 167   AC_DEFINE(USE_STRLEN, 1, [Define if we use strlen.])
 168 fi
 169
 170 # define NON_ANSI_RW_MODES on unix (can't hurt)
 171 AC_MSG_CHECKING(NON_ANSI_RW_MODES)
 172 AC_EGREP_CPP(yes,
 173 [#ifdef unix
 174   yes
 175 #endif
 176 #ifdef __unix
 177   yes
 178 #endif
 179 #ifdef __unix__
 180   yes
 181 #endif
 182 ], is_unix=yes, is_unix=no)
 183 # NON_ANSI_RW_MODES shouldn't be necessary on cygwin for binary mounts.
 184 if test $g77_cv_sys_cygwin32 = yes || test $g77_cv_sys_mingw32 = yes; then
 185   AC_MSG_RESULT(no)
 186 else
 187   if test $is_unix = yes; then
 188     AC_DEFINE(NON_ANSI_RW_MODES, 1, [Define if we have non ANSI RW modes.])
 189     AC_MSG_RESULT(yes)
 190   else
 191     AC_MSG_RESULT(no)
 192   fi
 193 fi
 194
 195 # This EOF_CHAR is a misfeature on unix.
 196 AC_DEFINE(NO_EOF_CHAR_CHECK, 1, [Always defined.])
 197
 198 AC_TYPE_OFF_T
 199
 200 AC_DEFINE(Skip_f2c_Undefs, 1, [Define to skip f2c undefs.])
 201
 202 AC_OUTPUT(Makefile)
 203
 204 dnl We might have configuration options to:
 205 dnl * change unit preconnexion in err.c (f_init.c)
 206 dnl * -DALWAYS_FLUSH
 207 dnl * -DOMIT_BLANK_CC
 208
 209 dnl Local Variables:
 210 dnl comment-start: "dnl "
 211 dnl comment-end: ""
 212 dnl comment-start-skip: "\\bdnl\\b\\s *"
 213 dnl End: