boehm-gc/configure.in

   1 dnl Process this file with autoconf to produce configure.
   2
   3 AC_INIT(gc_mark.h)
   4
   5 BOEHM_CONFIGURE(.)
   6
   7 AM_PROG_LIBTOOL
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                           configuring with a cross compiler])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 AM_MAINTAINER_MODE
  17 # automake wants to see AC_EXEEXT.  But we don't need it.  And having
  18 # it is actually a problem, because the compiler we're passed can't
  19 # necessarily do a full link.  So we fool automake here.
  20 if test "x" = "y"; then
  21    AC_EXEEXT
  22 fi
  23
  24 AC_MSG_CHECKING([for thread model used by GCC])
  25 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
  26 AC_MSG_RESULT([$THREADS])
  27
  28 INCLUDES=
  29 THREADLIBS=
  30 case "$THREADS" in
  31  no | none | single)
  32     THREADS=none
  33     ;;
  34  posix | pthreads)
  35     THREADS=posix
  36     case "$host" in
  37      *-*-linux*)
  38         AC_DEFINE(LINUX_THREADS)
  39         AC_DEFINE(_REENTRANT)
  40         ;;
  41      *-*-solaris*)
  42         AC_DEFINE(SOLARIS_THREADS)
  43         AC_DEFINE(_SOLARIS_PTHREADS)
  44         ;;
  45      *-*-irix*)
  46         AC_DEFINE(IRIX_THREADS)
  47         ;;
  48     esac
  49     THREADLIBS=-lpthread
  50     ;;
  51  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
  52     AC_MSG_ERROR(thread package $THREADS not yet supported)
  53     ;;
  54  *)
  55     AC_MSG_ERROR($THREADS is an unknown thread package)
  56     ;;
  57 esac
  58 AC_SUBST(THREADLIBS)
  59
  60 AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
  61 AC_SUBST(EXTRA_TEST_LIBS)
  62
  63 AC_ARG_ENABLE(java-gc,
  64 changequote(<<,>>)dnl
  65 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
  66 changequote([,])
  67   GC=$enableval,
  68   GC=boehm)
  69 target_all=
  70 if test "$GC" = "boehm"; then
  71    target_all=libgcjgc.la
  72 fi
  73 AC_SUBST(target_all)
  74
  75 dnl If the target is an eCos system, use the appropriate eCos
  76 dnl I/O routines.
  77 dnl FIXME: this should not be a local option but a global target
  78 dnl system; at present there is no eCos target.
  79 TARGET_ECOS="no"
  80 AC_ARG_WITH(ecos,
  81 [  --with-ecos             enable runtime eCos target support],
  82 TARGET_ECOS="$with_ecos"
  83 )
  84
  85 addobjs=
  86 CXXINCLUDES=
  87 case "$TARGET_ECOS" in
  88    no)
  89       ;;
  90    *)
  91       AC_DEFINE(ECOS)
  92       CXXINCLUDES="-I${TARGET_ECOS}/include"
  93       addobjs="$addobjs ecos.lo"
  94       ;;
  95 esac
  96 AC_SUBST(CXX)
  97
  98 AC_SUBST(INCLUDES)
  99 AC_SUBST(CXXINCLUDES)
 100
 101 machdep=
 102 case "$host" in
 103 # alpha_mach_dep.s assumes that pointers are not saved in fp registers.
 104 # Gcc on a 21264 can spill pointers to fp registers.  Oops.
 105 # alpha*-*-*)
 106 #    machdep="alpha_mach_dep.lo"
 107 #    ;;
 108  mipstx39-*-elf*)
 109     machdep="mips_ultrix_mach_dep.lo"
 110     AC_DEFINE(STACKBASE, __stackbase)
 111     AC_DEFINE(DATASTART_IS_ETEXT)
 112     ;;
 113  mips-dec-ultrix*)
 114     machdep="mips_ultrix_mach-dep.lo"
 115     ;;
 116  mips-*-*)
 117     machdep="mips_sgi_mach_dep.lo"
 118     AC_DEFINE(NO_EXECUTE_PERMISSION)
 119     ;;
 120  sparc-sun-solaris2.3*)
 121     AC_DEFINE(SUNOS53_SHARED_LIB)
 122     ;;
 123 esac
 124 if test x"$machdep" = x; then
 125    machdep="mach_dep.lo"
 126 fi
 127 addobjs="$addobjs $machdep"
 128 AC_SUBST(addobjs)
 129
 130 dnl As of 4.13a2, the collector will not properly work on Solaris when
 131 dnl built with gcc and -O.  So we remove -O in the appropriate case.
 132 case "$host" in
 133  sparc-sun-solaris2*)
 134     if test "$GCC" = yes; then
 135        new_CFLAGS=
 136        for i in $CFLAGS; do
 137           case "$i" in
 138            -O*)
 139               ;;
 140            *)
 141               new_CFLAGS="$new_CFLAGS $i"
 142               ;;
 143           esac
 144        done
 145        CFLAGS="$new_CFLAGS"
 146     fi
 147     ;;
 148 esac
 149
 150 dnl We need to override the top-level CFLAGS.  This is how we do it.
 151 MY_CFLAGS="$CFLAGS"
 152 AC_SUBST(MY_CFLAGS)
 153
 154 dnl Define a few things to retarget the library towards
 155 dnl embedded Java.
 156 AC_DEFINE(SILENT)
 157 AC_DEFINE(NO_SIGNALS)
 158 AC_DEFINE(JAVA_FINALIZATION)
 159 AC_DEFINE(GC_GCJ_SUPPORT)
 160
 161 dnl This is something of a hack.  When cross-compiling we turn off
 162 dnl some functionality.  We also enable the "small" configuration.
 163 dnl These is only correct when targetting an embedded system.  FIXME.
 164 if test -n "${with_cross_host}"; then
 165    AC_DEFINE(NO_SIGSET)
 166    AC_DEFINE(NO_CLOCK)
 167    AC_DEFINE(SMALL_CONFIG)
 168    AC_DEFINE(NO_DEBUGGING)
 169 fi
 170
 171 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 172
 173 if test "${multilib}" = "yes"; then
 174   multilib_arg="--enable-multilib"
 175 else
 176   multilib_arg=
 177 fi
 178
 179 AC_OUTPUT(Makefile,
 180 [
 181 dnl Put all the -D options in a file.  These are required before
 182 dnl boehm-config.h can be included.  This is a huge hack brought
 183 dnl about by overall poor structuring of this entire library.
 184 echo "$DEFS" > boehm-cflags
 185
 186 if test -n "$CONFIG_FILES"; then
 187   ac_file=Makefile . ${boehm_gc_basedir}/../config-ml.in
 188 fi],
 189 srcdir=${srcdir}
 190 host=${host}
 191 target=${target}
 192 with_multisubdir=${with_multisubdir}
 193 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 194 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 195 boehm_gc_basedir=${boehm_gc_basedir}
 196 CC="${CC}"
 197 DEFS="$DEFS"
 198 )