libchill/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU CC.
   6 #
   7 #GNU CHILL is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU CHILL is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU CHILL; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_INIT(chillrt0.c)
  23
  24 if test "${srcdir}" = "." ; then
  25   if test "${with_target_subdir}" != "." ; then
  26     topsrcdir=${with_multisrctop}../..
  27   else
  28     topsrcdir=${with_multisrctop}..
  29   fi
  30 else
  31   topsrcdir=${srcdir}/..
  32 fi
  33 dnl This is needed for a multilibbed build in the source tree so
  34 dnl that install-sh and config.sub get found.
  35 AC_CONFIG_AUX_DIR($topsrcdir)
  36
  37 dnl Checks for programs.
  38 # For chill we'll set CC to point at the built gcc, but this will get it into
  39 # the makefiles
  40 AC_PROG_CC
  41
  42 test "$AR" || AR=ar
  43 AC_SUBST(AR)
  44 AC_PROG_MAKE_SET
  45
  46 dnl Checks for libraries.
  47
  48 dnl Checks for header files.
  49 # Sanity check for the cross-compilation case:
  50 AC_CHECK_HEADER(stdio.h,:,
  51   [AC_MSG_ERROR([Can't find stdio.h.
  52 You must have a usable C system for the target already installed, at least
  53 including headers and, preferably, the library, before you can configure
  54 the Chill runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  55 then the target library, then build with \`LANGUAGES=chill'.])])
  56
  57 AC_HEADER_STDC
  58
  59 AC_MSG_CHECKING(for posix)
  60 AC_CACHE_VAL(chill_cv_header_posix,
  61   AC_EGREP_CPP(yes,
  62   [#include <sys/types.h>
  63 #include <unistd.h>
  64 #ifdef _POSIX_VERSION
  65   yes
  66 #endif
  67 ],
  68   chill_cv_header_posix=yes,
  69   chill_cv_header_posix=no))
  70 AC_MSG_RESULT($chill_cv_header_posix)
  71
  72 # We can rely on the GNU library being posix-ish.  I guess checking the
  73 # header isn't actually like checking the functions, though...
  74 AC_MSG_CHECKING(for GNU library)
  75 AC_CACHE_VAL(chill_cv_lib_gnu,
  76   AC_EGREP_CPP(yes,
  77     [#include <stdio.h>
  78 #ifdef __GNU_LIBRARY__
  79   yes
  80 #endif
  81 ],
  82   chill_cv_lib_gnu=yes, chill_cv_lib_gnu=no))
  83 AC_MSG_RESULT($chill_cv_lib_gnu)
  84
  85 dnl Checks for library functions.
  86 AC_TYPE_SIGNAL
  87 # we'll get atexit by default
  88 if test $ac_cv_header_stdc != yes; then
  89 AC_CHECK_FUNC(atexit,
  90   AC_DEFINE(onexit,atexit),dnl just in case
  91   [AC_DEFINE(NO_ONEXIT)
  92   AC_CHECK_FUNC(onexit,,
  93     [AC_CHECK_FUNC(on_exit,
  94      AC_DEFINE(onexit,on_exit),)])])
  95 else true
  96 fi
  97
  98 # We need multilib support, but only if configuring for the target.
  99 AC_OUTPUT(Makefile,
 100 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 101 if test -n "$CONFIG_FILES"; then
 102   if test -n "${with_target_subdir}"; then
 103     # FIXME: We shouldn't need to set ac_file
 104     ac_file=Makefile
 105     . ${topsrcdir}/config-ml.in
 106   fi
 107 fi],
 108 srcdir=${srcdir}
 109 host=${host}
 110 target=${target}
 111 with_target_subdir=${with_target_subdir}
 112 with_multisubdir=${with_multisubdir}
 113 ac_configure_args="--enable-multilib ${ac_configure_args}"
 114 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 115 topsrcdir=${topsrcdir}
 116 )
 117
 118
 119
 120 dnl Local Variables:
 121 dnl comment-start: "dnl "
 122 dnl comment-end: ""
 123 dnl comment-start-skip: "\\bdnl\\b\\s *"
 124 dnl End: