gcc/ada/exp_ch13.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ C H 1 3                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Exp_Ch3;  use Exp_Ch3;
  30 with Exp_Ch6;  use Exp_Ch6;
  31 with Exp_Imgv; use Exp_Imgv;
  32 with Exp_Tss;  use Exp_Tss;
  33 with Exp_Util; use Exp_Util;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Opt;      use Opt;
  38 with Restrict; use Restrict;
  39 with Rident;   use Rident;
  40 with Rtsfind;  use Rtsfind;
  41 with Sem;      use Sem;
  42 with Sem_Aux;  use Sem_Aux;
  43 with Sem_Ch7;  use Sem_Ch7;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Eval; use Sem_Eval;
  46 with Sem_Util; use Sem_Util;
  47 with Sinfo;    use Sinfo;
  48 with Snames;   use Snames;
  49 with Targparm; use Targparm;
  50 with Tbuild;   use Tbuild;
  51 with Uintp;    use Uintp;
  52 with Validsw;  use Validsw;
  53
  54 package body Exp_Ch13 is
  55
  56    ------------------------------------------
  57    -- Expand_N_Attribute_Definition_Clause --
  58    ------------------------------------------
  59
  60    --  Expansion action depends on attribute involved
  61
  62    procedure Expand_N_Attribute_Definition_Clause (N : Node_Id) is
  63       Loc : constant Source_Ptr := Sloc (N);
  64       Exp : constant Node_Id    := Expression (N);
  65       Ent : Entity_Id;
  66       V   : Node_Id;
  67
  68    begin
  69       Ent := Entity (Name (N));
  70
  71       if Is_Type (Ent) then
  72          Ent := Underlying_Type (Ent);
  73       end if;
  74
  75       case Get_Attribute_Id (Chars (N)) is
  76
  77          -------------
  78          -- Address --
  79          -------------
  80
  81          when Attribute_Address =>
  82
  83             --  If there is an initialization which did not come from the
  84             --  source program, then it is an artifact of our expansion, and we
  85             --  suppress it. The case we are most concerned about here is the
  86             --  initialization of a packed array to all false, which seems
  87             --  inappropriate for variable to which an address clause is
  88             --  applied. The expression may itself have been rewritten if the
  89             --  type is packed array, so we need to examine whether the
  90             --  original node is in the source. An exception though is the case
  91             --  of an access variable which is default initialized to null, and
  92             --  such initialization is retained.
  93
  94             --  Furthermore, if the initialization is the equivalent aggregate
  95             --  of the type initialization procedure, it replaces an implicit
  96             --  call to the init proc, and must be respected. Note that for
  97             --  packed types we do not build equivalent aggregates.
  98
  99             --  Also, if Init_Or_Norm_Scalars applies, then we need to retain
 100             --  any default initialization for objects of scalar types and
 101             --  types with scalar components. Normally a composite type will
 102             --  have an init_proc in the presence of Init_Or_Norm_Scalars,
 103             --  so when that flag is set we have just have to do a test for
 104             --  scalar and string types (the predefined string types such as
 105             --  String and Wide_String don't have an init_proc).
 106
 107             declare
 108                Decl : constant Node_Id := Declaration_Node (Ent);
 109                Typ  : constant Entity_Id := Etype (Ent);
 110
 111             begin
 112                if Nkind (Decl) = N_Object_Declaration
 113                   and then Present (Expression (Decl))
 114                   and then Nkind (Expression (Decl)) /= N_Null
 115                   and then
 116                    not Comes_From_Source (Original_Node (Expression (Decl)))
 117                then
 118                   if Present (Base_Init_Proc (Typ))
 119                     and then
 120                       Present (Static_Initialization (Base_Init_Proc (Typ)))
 121                   then
 122                      null;
 123
 124                   elsif Init_Or_Norm_Scalars
 125                     and then
 126                       (Is_Scalar_Type (Typ) or else Is_String_Type (Typ))
 127                   then
 128                      null;
 129
 130                   else
 131                      Set_Expression (Decl, Empty);
 132                   end if;
 133
 134                --  An object declaration to which an address clause applies
 135                --  has a delayed freeze, but the address expression itself
 136                --  must be elaborated at the point it appears. If the object
 137                --  is controlled, additional checks apply elsewhere.
 138
 139                elsif Nkind (Decl) = N_Object_Declaration
 140                  and then not Needs_Constant_Address (Decl, Typ)
 141                then
 142                   Remove_Side_Effects (Exp);
 143                end if;
 144             end;
 145
 146          ---------------
 147          -- Alignment --
 148          ---------------
 149
 150          when Attribute_Alignment =>
 151
 152             --  As required by Gigi, we guarantee that the operand is an
 153             --  integer literal (this simplifies things in Gigi).
 154
 155             if Nkind (Exp) /= N_Integer_Literal then
 156                Rewrite
 157                  (Exp, Make_Integer_Literal (Loc, Expr_Value (Exp)));
 158             end if;
 159
 160          ------------------
 161          -- Storage_Size --
 162          ------------------
 163
 164          when Attribute_Storage_Size =>
 165
 166             --  If the type is a task type, then assign the value of the
 167             --  storage size to the Size variable associated with the task.
 168             --  Insert the assignment right after the declaration of the Size
 169             --  variable.
 170
 171             --  Generate:
 172
 173             --  task_typeZ := expression
 174
 175             if Ekind (Ent) = E_Task_Type then
 176                declare
 177                   Assign : Node_Id;
 178
 179                begin
 180                   Assign :=
 181                     Make_Assignment_Statement (Loc,
 182                       Name =>
 183                         New_Reference_To (Storage_Size_Variable (Ent), Loc),
 184                       Expression =>
 185                         Convert_To (RTE (RE_Size_Type), Expression (N)));
 186
 187                   Insert_After
 188                     (Parent (Storage_Size_Variable (Entity (N))), Assign);
 189
 190                   Analyze (Assign);
 191                end;
 192
 193             --  For Storage_Size for an access type, create a variable to hold
 194             --  the value of the specified size with name typeV and expand an
 195             --  assignment statement to initialize this value.
 196
 197             elsif Is_Access_Type (Ent) then
 198
 199                --  We don't need the variable for a storage size of zero
 200
 201                if not No_Pool_Assigned (Ent) then
 202                   V :=
 203                     Make_Defining_Identifier (Loc,
 204                       Chars => New_External_Name (Chars (Ent), 'V'));
 205
 206                   --  Insert the declaration of the object
 207
 208                   Insert_Action (N,
 209                     Make_Object_Declaration (Loc,
 210                       Defining_Identifier => V,
 211                       Object_Definition  =>
 212                         New_Reference_To (RTE (RE_Storage_Offset), Loc),
 213                       Expression =>
 214                         Convert_To (RTE (RE_Storage_Offset), Expression (N))));
 215
 216                   Set_Storage_Size_Variable (Ent, Entity_Id (V));
 217                end if;
 218             end if;
 219
 220          --  Other attributes require no expansion
 221
 222          when others =>
 223             null;
 224
 225       end case;
 226    end Expand_N_Attribute_Definition_Clause;
 227
 228    -----------------------------
 229    -- Expand_N_Free_Statement --
 230    -----------------------------
 231
 232    procedure Expand_N_Free_Statement (N : Node_Id) is
 233       Expr : constant Node_Id := Expression (N);
 234       Typ  : Entity_Id;
 235
 236    begin
 237       --  Certain run-time configurations and targets do not provide support
 238       --  for controlled types.
 239
 240       if Restriction_Active (No_Finalization) then
 241          return;
 242
 243       --  Do not create a specialized Deallocate since .NET/JVM compilers do
 244       --  not support pools and address arithmetic.
 245
 246       elsif VM_Target /= No_VM then
 247          return;
 248       end if;
 249
 250       --  Use the base type to perform the check for finalization master
 251
 252       Typ := Etype (Expr);
 253
 254       if Ekind (Typ) = E_Access_Subtype then
 255          Typ := Etype (Typ);
 256       end if;
 257
 258       --  Handle private access types
 259
 260       if Is_Private_Type (Typ)
 261         and then Present (Full_View (Typ))
 262       then
 263          Typ := Full_View (Typ);
 264       end if;
 265
 266       --  Do not create a custom Deallocate when freeing an object with
 267       --  suppressed finalization. In such cases the object is never attached
 268       --  to a master, so it does not need to be detached. Use a regular free
 269       --  statement instead.
 270
 271       if No (Finalization_Master (Typ)) then
 272          return;
 273       end if;
 274
 275       --  Use a temporary to store the result of a complex expression. Perform
 276       --  the following transformation:
 277       --
 278       --     Free (Complex_Expression);
 279       --
 280       --     Temp : constant Type_Of_Expression := Complex_Expression;
 281       --     Free (Temp);
 282
 283       if Nkind (Expr) /= N_Identifier then
 284          declare
 285             Expr_Typ : constant Entity_Id  := Etype (Expr);
 286             Loc      : constant Source_Ptr := Sloc (N);
 287             New_Expr : Node_Id;
 288             Temp_Id  : Entity_Id;
 289
 290          begin
 291             Temp_Id := Make_Temporary (Loc, 'T');
 292             Insert_Action (N,
 293               Make_Object_Declaration (Loc,
 294                 Defining_Identifier => Temp_Id,
 295                 Object_Definition =>
 296                   New_Reference_To (Expr_Typ, Loc),
 297                 Expression =>
 298                   Relocate_Node (Expr)));
 299
 300             New_Expr := New_Reference_To (Temp_Id, Loc);
 301             Set_Etype (New_Expr, Expr_Typ);
 302
 303             Set_Expression (N, New_Expr);
 304          end;
 305       end if;
 306
 307       --  Create a custom Deallocate for a controlled object. This routine
 308       --  ensures that the hidden list header will be deallocated along with
 309       --  the actual object.
 310
 311       Build_Allocate_Deallocate_Proc (N, Is_Allocate => False);
 312    end Expand_N_Free_Statement;
 313
 314    ----------------------------
 315    -- Expand_N_Freeze_Entity --
 316    ----------------------------
 317
 318    procedure Expand_N_Freeze_Entity (N : Node_Id) is
 319       E              : constant Entity_Id := Entity (N);
 320       E_Scope        : Entity_Id;
 321       In_Other_Scope : Boolean;
 322       In_Outer_Scope : Boolean;
 323       Decl           : Node_Id;
 324       Delete         : Boolean := False;
 325
 326    begin
 327       --  If there are delayed aspect specifications, we insert them just
 328       --  before the freeze node. They are already analyzed so we don't need
 329       --  to reanalyze them (they were analyzed before the type was frozen),
 330       --  but we want them in the tree for the back end, and so that the
 331       --  listing from sprint is clearer on where these occur logically.
 332
 333       if Has_Delayed_Aspects (E) then
 334          declare
 335             Aitem : Node_Id;
 336             Ritem : Node_Id;
 337
 338          begin
 339             --  Look for aspect specs for this entity
 340
 341             Ritem := First_Rep_Item (E);
 342             while Present (Ritem) loop
 343                if Nkind (Ritem) = N_Aspect_Specification
 344                  and then Entity (Ritem) = E
 345                then
 346                   Aitem := Aspect_Rep_Item (Ritem);
 347
 348                   --  Skip this for aspects (e.g. Current_Value) for which
 349                   --  there is no corresponding pragma or attribute.
 350
 351                   if Present (Aitem) then
 352                      pragma Assert (Is_Delayed_Aspect (Aitem));
 353                      Insert_Before (N, Aitem);
 354                   end if;
 355                end if;
 356
 357                Next_Rep_Item (Ritem);
 358             end loop;
 359          end;
 360       end if;
 361
 362       --  Processing for objects with address clauses
 363
 364       if Is_Object (E) and then Present (Address_Clause (E)) then
 365          Apply_Address_Clause_Check (E, N);
 366          return;
 367
 368       --  Only other items requiring any front end action are types and
 369       --  subprograms.
 370
 371       elsif not Is_Type (E) and then not Is_Subprogram (E) then
 372          return;
 373       end if;
 374
 375       --  Here E is a type or a subprogram
 376
 377       E_Scope := Scope (E);
 378
 379       --  This is an error protection against previous errors
 380
 381       if No (E_Scope) then
 382          return;
 383       end if;
 384
 385       --  Remember that we are processing a freezing entity and its freezing
 386       --  nodes. This flag (non-zero = set) is used to avoid the need of
 387       --  climbing through the tree while processing the freezing actions (ie.
 388       --  to avoid generating spurious warnings or to avoid killing constant
 389       --  indications while processing the code associated with freezing
 390       --  actions). We use a counter to deal with nesting.
 391
 392       Inside_Freezing_Actions := Inside_Freezing_Actions + 1;
 393
 394       --  If we are freezing entities defined in protected types, they belong
 395       --  in the enclosing scope, given that the original type has been
 396       --  expanded away. The same is true for entities in task types, in
 397       --  particular the parameter records of entries (Entities in bodies are
 398       --  all frozen within the body). If we are in the task body, this is a
 399       --  proper scope. If we are within a subprogram body, the proper scope
 400       --  is the corresponding spec. This may happen for itypes generated in
 401       --  the bodies of protected operations.
 402
 403       if Ekind (E_Scope) = E_Protected_Type
 404         or else (Ekind (E_Scope) = E_Task_Type
 405                   and then not Has_Completion (E_Scope))
 406       then
 407          E_Scope := Scope (E_Scope);
 408
 409       elsif Ekind (E_Scope) = E_Subprogram_Body then
 410          E_Scope := Corresponding_Spec (Unit_Declaration_Node (E_Scope));
 411       end if;
 412
 413       --  If the scope of the entity is in open scopes, it is the current one
 414       --  or an enclosing one, including a loop, a block, or a subprogram.
 415
 416       if In_Open_Scopes (E_Scope) then
 417          In_Other_Scope := False;
 418          In_Outer_Scope := E_Scope /= Current_Scope;
 419
 420       --  Otherwise it is a local package or a different compilation unit
 421
 422       else
 423          In_Other_Scope := True;
 424          In_Outer_Scope := False;
 425       end if;
 426
 427       --  If the entity being frozen is defined in a scope that is not
 428       --  currently on the scope stack, we must establish the proper
 429       --  visibility before freezing the entity and related subprograms.
 430
 431       if In_Other_Scope then
 432          Push_Scope (E_Scope);
 433
 434          --  Finalizers are little odd in terms of freezing. The spec of the
 435          --  procedure appears in the declarations while the body appears in
 436          --  the statement part of a single construct. Since the finalizer must
 437          --  be called by the At_End handler of the construct, the spec is
 438          --  manually frozen right after its declaration. The only side effect
 439          --  of this action appears in contexts where the construct is not in
 440          --  its final resting place. These contexts are:
 441
 442          --    * Entry bodies - The declarations and statements are moved to
 443          --      the procedure equivalen of the entry.
 444          --    * Protected subprograms - The declarations and statements are
 445          --      moved to the non-protected version of the subprogram.
 446          --    * Task bodies - The declarations and statements are moved to the
 447          --      task body procedure.
 448
 449          --  Visible declarations do not need to be installed in these three
 450          --  cases since it does not make semantic sense to do so. All entities
 451          --  referenced by a finalizer are visible and already resolved, plus
 452          --  the enclosing scope may not have visible declarations at all.
 453
 454          if Ekind (E) = E_Procedure
 455            and then Is_Finalizer (E)
 456            and then
 457              (Is_Entry (E_Scope)
 458                 or else (Is_Subprogram (E_Scope)
 459                            and then Is_Protected_Type (Scope (E_Scope)))
 460                 or else Is_Task_Type (E_Scope))
 461          then
 462             null;
 463          else
 464             Install_Visible_Declarations (E_Scope);
 465          end if;
 466
 467          if Is_Package_Or_Generic_Package (E_Scope) or else
 468             Is_Protected_Type (E_Scope)             or else
 469             Is_Task_Type (E_Scope)
 470          then
 471             Install_Private_Declarations (E_Scope);
 472          end if;
 473
 474       --  If the entity is in an outer scope, then that scope needs to
 475       --  temporarily become the current scope so that operations created
 476       --  during type freezing will be declared in the right scope and
 477       --  can properly override any corresponding inherited operations.
 478
 479       elsif In_Outer_Scope then
 480          Push_Scope (E_Scope);
 481       end if;
 482
 483       --  If type, freeze the type
 484
 485       if Is_Type (E) then
 486          Delete := Freeze_Type (N);
 487
 488          --  And for enumeration type, build the enumeration tables
 489
 490          if Is_Enumeration_Type (E) then
 491             Build_Enumeration_Image_Tables (E, N);
 492          end if;
 493
 494       --  If subprogram, freeze the subprogram
 495
 496       elsif Is_Subprogram (E) then
 497          Freeze_Subprogram (N);
 498
 499          --  Ada 2005 (AI-251): Remove the freezing node associated with the
 500          --  entities internally used by the frontend to register primitives
 501          --  covering abstract interfaces. The call to Freeze_Subprogram has
 502          --  already expanded the code that fills the corresponding entry in
 503          --  its secondary dispatch table and therefore the code generator
 504          --  has nothing else to do with this freezing node.
 505
 506          Delete := Present (Interface_Alias (E));
 507       end if;
 508
 509       --  Analyze actions generated by freezing. The init_proc contains source
 510       --  expressions that may raise Constraint_Error, and the assignment
 511       --  procedure for complex types needs checks on individual component
 512       --  assignments, but all other freezing actions should be compiled with
 513       --  all checks off.
 514
 515       if Present (Actions (N)) then
 516          Decl := First (Actions (N));
 517          while Present (Decl) loop
 518             if Nkind (Decl) = N_Subprogram_Body
 519               and then (Is_Init_Proc (Defining_Entity (Decl))
 520                           or else
 521                             Chars (Defining_Entity (Decl)) = Name_uAssign)
 522             then
 523                Analyze (Decl);
 524
 525             --  A subprogram body created for a renaming_as_body completes
 526             --  a previous declaration, which may be in a different scope.
 527             --  Establish the proper scope before analysis.
 528
 529             elsif Nkind (Decl) = N_Subprogram_Body
 530               and then Present (Corresponding_Spec (Decl))
 531               and then Scope (Corresponding_Spec (Decl)) /= Current_Scope
 532             then
 533                Push_Scope (Scope (Corresponding_Spec (Decl)));
 534                Analyze (Decl, Suppress => All_Checks);
 535                Pop_Scope;
 536
 537             --  We treat generated equality specially, if validity checks are
 538             --  enabled, in order to detect components default-initialized
 539             --  with invalid values.
 540
 541             elsif Nkind (Decl) = N_Subprogram_Body
 542               and then Chars (Defining_Entity (Decl)) = Name_Op_Eq
 543               and then Validity_Checks_On
 544               and then Initialize_Scalars
 545             then
 546                declare
 547                   Save_Force : constant Boolean := Force_Validity_Checks;
 548                begin
 549                   Force_Validity_Checks := True;
 550                   Analyze (Decl);
 551                   Force_Validity_Checks := Save_Force;
 552                end;
 553
 554             else
 555                Analyze (Decl, Suppress => All_Checks);
 556             end if;
 557
 558             Next (Decl);
 559          end loop;
 560       end if;
 561
 562       --  If we are to delete this N_Freeze_Entity, do so by rewriting so that
 563       --  a loop on all nodes being inserted will work propertly.
 564
 565       if Delete then
 566          Rewrite (N, Make_Null_Statement (Sloc (N)));
 567       end if;
 568
 569       --  Pop scope if we installed one for the analysis
 570
 571       if In_Other_Scope then
 572          if Ekind (Current_Scope) = E_Package then
 573             End_Package_Scope (E_Scope);
 574          else
 575             End_Scope;
 576          end if;
 577
 578       elsif In_Outer_Scope then
 579          Pop_Scope;
 580       end if;
 581
 582       --  Restore previous value of the nesting-level counter that records
 583       --  whether we are inside a (possibly nested) call to this procedure.
 584
 585       Inside_Freezing_Actions := Inside_Freezing_Actions - 1;
 586    end Expand_N_Freeze_Entity;
 587
 588    -------------------------------------------
 589    -- Expand_N_Record_Representation_Clause --
 590    -------------------------------------------
 591
 592    --  The only expansion required is for the case of a mod clause present,
 593    --  which is removed, and translated into an alignment representation
 594    --  clause inserted immediately after the record rep clause with any
 595    --  initial pragmas inserted at the start of the component clause list.
 596
 597    procedure Expand_N_Record_Representation_Clause (N : Node_Id) is
 598       Loc     : constant Source_Ptr := Sloc (N);
 599       Rectype : constant Entity_Id  := Entity (Identifier (N));
 600       Mod_Val : Uint;
 601       Citems  : List_Id;
 602       Repitem : Node_Id;
 603       AtM_Nod : Node_Id;
 604
 605    begin
 606       if Present (Mod_Clause (N)) and then not Ignore_Rep_Clauses then
 607          Mod_Val := Expr_Value (Expression (Mod_Clause (N)));
 608          Citems  := Pragmas_Before (Mod_Clause (N));
 609
 610          if Present (Citems) then
 611             Append_List_To (Citems, Component_Clauses (N));
 612             Set_Component_Clauses (N, Citems);
 613          end if;
 614
 615          AtM_Nod :=
 616            Make_Attribute_Definition_Clause (Loc,
 617              Name       => New_Reference_To (Base_Type (Rectype), Loc),
 618              Chars      => Name_Alignment,
 619              Expression => Make_Integer_Literal (Loc, Mod_Val));
 620
 621          Set_From_At_Mod (AtM_Nod);
 622          Insert_After (N, AtM_Nod);
 623          Set_Mod_Clause (N, Empty);
 624       end if;
 625
 626       --  If the record representation clause has no components, then
 627       --  completely remove it.  Note that we also have to remove
 628       --  ourself from the Rep Item list.
 629
 630       if Is_Empty_List (Component_Clauses (N)) then
 631          if First_Rep_Item (Rectype) = N then
 632             Set_First_Rep_Item (Rectype, Next_Rep_Item (N));
 633          else
 634             Repitem := First_Rep_Item (Rectype);
 635             while Present (Next_Rep_Item (Repitem)) loop
 636                if Next_Rep_Item (Repitem) = N then
 637                   Set_Next_Rep_Item (Repitem, Next_Rep_Item (N));
 638                   exit;
 639                end if;
 640
 641                Next_Rep_Item (Repitem);
 642             end loop;
 643          end if;
 644
 645          Rewrite (N,
 646            Make_Null_Statement (Loc));
 647       end if;
 648    end Expand_N_Record_Representation_Clause;
 649
 650 end Exp_Ch13;