gcc/ada/errout.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               E R R O U T                                --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package contains the routines to output error messages. They are
  27 --  basically system independent, however in some environments, e.g. when the
  28 --  parser is embedded into an editor, it may be appropriate to replace the
  29 --  implementation of this package.
  30
  31 with Err_Vars;
  32 with Erroutc;
  33 with Namet;    use Namet;
  34 with Table;
  35 with Types;    use Types;
  36 with Uintp;    use Uintp;
  37
  38 with System;
  39
  40 package Errout is
  41
  42    Serious_Errors_Detected : Nat renames Err_Vars.Serious_Errors_Detected;
  43    --  This is a count of errors that are serious enough to stop expansion,
  44    --  and hence to prevent generation of an object file even if the switch
  45    --  -gnatQ is set.
  46
  47    Total_Errors_Detected : Nat renames Err_Vars.Total_Errors_Detected;
  48    --  Number of errors detected so far. Includes count of serious errors and
  49    --  non-serious errors, so this value is always greater than or equal to
  50    --  the Serious_Errors_Detected value.
  51
  52    Warnings_Detected : Nat renames Err_Vars.Warnings_Detected;
  53    --  Number of warnings detected
  54
  55    Configurable_Run_Time_Violations : Nat := 0;
  56    --  Count of configurable run time violations so far. This is used to
  57    --  suppress certain cascaded error messages when we know that we may not
  58    --  have fully expanded some items, due to high integrity violations (i.e.
  59    --  the use of constructs not permitted by the library in use, or improper
  60    --  constructs in No_Run_Time mode).
  61
  62    Current_Error_Source_File : Source_File_Index
  63      renames Err_Vars.Current_Error_Source_File;
  64    --  Id of current messages. Used to post file name when unit changes. This
  65    --  is initialized to Main_Source_File at the start of a compilation, which
  66    --  means that no file names will be output unless there are errors in
  67    --  units other than the main unit. However, if the main unit has a pragma
  68    --  Source_Reference line, then this is initialized to No_Source_File, to
  69    --  force an initial reference to the real source file name.
  70
  71    Raise_Exception_On_Error : Nat renames Err_Vars.Raise_Exception_On_Error;
  72    --  If this value is non-zero, then any attempt to generate an error
  73    --  message raises the exception Error_Msg_Exception, and the error message
  74    --  is not output. This is used for defending against junk resulting from
  75    --  illegalities, and also for substitution of more appropriate error
  76    --  messages from higher semantic levels. It is a counter so that the
  77    --  increment/decrement protocol nests neatly.
  78
  79    Error_Msg_Exception : exception renames Err_Vars.Error_Msg_Exception;
  80    --  Exception raised if Raise_Exception_On_Error is true
  81
  82    -----------------------------------
  83    -- Suppression of Error Messages --
  84    -----------------------------------
  85
  86    --  In an effort to reduce the impact of redundant error messages, the
  87    --  error output routines in this package normally suppress certain
  88    --  classes of messages as follows:
  89
  90    --    1.  Identical messages placed at the same point in the text. Such
  91    --        duplicate error message result for example from rescanning
  92    --        sections of the text that contain lexical errors. Only one of
  93    --        such a set of duplicate messages is output, and the rest are
  94    --        suppressed.
  95
  96    --    2.  If more than one parser message is generated for a single source
  97    --        line, then only the first message is output, the remaining
  98    --        messages on the same line are suppressed.
  99
 100    --    3.  If a message is posted on a node for which a message has been
 101    --        previously posted, then only the first message is retained. The
 102    --        Error_Posted flag is used to detect such multiple postings. Note
 103    --        that this only applies to semantic messages, since otherwise
 104    --        for parser messages, this would be a special case of case 2.
 105
 106    --    4.  If a message is posted on a node whose Etype or Entity
 107    --        fields reference entities on which an error message has
 108    --        already been placed, as indicated by the Error_Posted flag
 109    --        being set on these entities, then the message is suppressed.
 110
 111    --    5.  If a message attempts to insert an Error node, or a direct
 112    --        reference to the Any_Type node, then the message is suppressed.
 113
 114    --    6.  Note that cases 2-5 only apply to error messages, not warning
 115    --        messages. Warning messages are only suppressed for case 1, and
 116    --        when they come from other than the main extended unit.
 117
 118    --  This normal suppression action may be overridden in cases 2-5 (but not
 119    --  in case 1) by setting All_Errors mode, or by setting the special
 120    --  unconditional message insertion character (!) at the end of the message
 121    --  text as described below.
 122
 123    ---------------------------------------------------------
 124    -- Error Message Text and Message Insertion Characters --
 125    ---------------------------------------------------------
 126
 127    --  Error message text strings are composed of lower case letters, digits
 128    --  and the special characters space, comma, period, colon and semicolon,
 129    --  apostrophe and parentheses. Special insertion characters can also
 130    --  appear which cause the error message circuit to modify the given
 131    --  string as follows:
 132
 133    --    Insertion character % (Percent: insert name from Names table)
 134    --      The character % is replaced by the text for the name specified by
 135    --      the Name_Id value stored in Error_Msg_Name_1. A blank precedes the
 136    --      name if it is preceded by a non-blank character other than left
 137    --      parenthesis. The name is enclosed in quotes unless manual quotation
 138    --      mode is set. If the Name_Id is set to No_Name, then no insertion
 139    --      occurs; if the Name_Id is set to Error_Name, then the string
 140    --      <error> is inserted. A second and third % may appear in a single
 141    --      message, similarly replaced by the names which are specified by the
 142    --      Name_Id values stored in Error_Msg_Name_2 and Error_Msg_Name_3. The
 143    --      names are decoded and cased according to the current identifier
 144    --      casing mode. Note: if a unit name ending with %b or %s is passed
 145    --      for this kind of insertion, this suffix is simply stripped. Use a
 146    --      unit name insertion ($) to process the suffix.
 147
 148    --    Insertion character %% (Double percent: insert literal name)
 149    --      The character sequence %% acts as described above for %, except
 150    --      that the name is simply obtained with Get_Name_String and is not
 151    --      decoded or cased, it is inserted literally from the names table.
 152    --      A trailing %b or %s is not treated specially.
 153
 154    --    Insertion character $ (Dollar: insert unit name from Names table)
 155    --      The character $ is treated similarly to %, except that the name is
 156    --      obtained from the Unit_Name_Type value in Error_Msg_Unit_1 and
 157    --      Error_Msg_Unit_2, as provided by Get_Unit_Name_String in package
 158    --      Uname. Note that this name includes the postfix (spec) or (body)
 159    --      strings. If this postfix is not required, use the normal %
 160    --      insertion for the unit name.
 161
 162    --    Insertion character { (Left brace: insert file name from names table)
 163    --      The character { is treated similarly to %, except that the input
 164    --      value is a File_Name_Type value stored in Error_Msg_File_1 or
 165    --      Error_Msg_File_2 or Error_Msg_File_3. The value is output literally,
 166    --      enclosed in quotes as for %, but the case is not modified, the
 167    --      insertion is the exact string stored in the names table without
 168    --      adjusting the casing.
 169
 170    --    Insertion character * (Asterisk, insert reserved word name)
 171    --      The insertion character * is treated exactly like % except that the
 172    --      resulting name is cased according to the default conventions for
 173    --      reserved words (see package Scans).
 174
 175    --    Insertion character & (Ampersand: insert name from node)
 176    --      The insertion character & is treated similarly to %, except that
 177    --      the name is taken from the Chars field of the given node, and may
 178    --      refer to a child unit name, or a selected component. The casing is,
 179    --      if possible, taken from the original source reference, which is
 180    --      obtained from the Sloc field of the given node or nodes. If no Sloc
 181    --      is available (happens e.g. for nodes in package Standard), then the
 182    --      default case (see Scans spec) is used. The nodes to be used are
 183    --      stored in Error_Msg_Node_1, Error_Msg_Node_2. No insertion occurs
 184    --      for the Empty node, and the Error node results in the insertion of
 185    --      the characters <error>. In addition, if the special global variable
 186    --      Error_Msg_Qual_Level is non-zero, then the reference will include
 187    --      up to the given number of levels of qualification, using the scope
 188    --      chain.
 189
 190    --    Insertion character # (Pound: insert line number reference)
 191    --      The character # is replaced by the string indicating the source
 192    --      position stored in Error_Msg_Sloc. There are three cases:
 193    --
 194    --        for package Standard:           in package Standard
 195    --        for locations in current file:  at line nnn:ccc
 196    --        for locations in other files:   at filename:nnn:ccc
 197    --
 198    --      By convention, the # insertion character is only used at the end of
 199    --      an error message, so the above strings only appear as the last
 200    --      characters of an error message. The only exceptions to this rule
 201    --      are that an RM reference may follow in the form (RM .....) and a
 202    --      right parenthesis may immediately follow the #. In the case of
 203    --      continued messages, # can only appear at the end of a group of
 204    --      continuation messages, except that \\ messages which always start
 205    --      a new line end the sequence from the point of view of this rule.
 206    --      The idea is that for any use of -gnatj, it will still be the case
 207    --      that a location reference appears only at the end of a line.
 208
 209    --      Note: the output of the string "at " is suppressed if the string
 210    --      " from" or " from " immediately precedes the insertion character #.
 211    --      Certain messages read better with from than at.
 212
 213    --    Insertion character } (Right brace: insert type reference)
 214    --      The character } is replaced by a string describing the type
 215    --      referenced by the entity whose Id is stored in Error_Msg_Node_1.
 216    --      the string gives the name or description of the type, and also
 217    --      where appropriate the location of its declaration. Special cases
 218    --      like "some integer type" are handled appropriately. Only one } is
 219    --      allowed in a message, since there is not enough room for two (the
 220    --      insertion can be quite long, including a file name) In addition, if
 221    --      the special global variable Error_Msg_Qual_Level is non-zero, then
 222    --      the reference will include up to the given number of levels of
 223    --      qualification, using the scope chain.
 224
 225    --    Insertion character @ (At: insert column number reference)
 226    --      The character @ is replaced by null if the RM_Column_Check mode is
 227    --      off (False). If the switch is on (True), then @ is replaced by the
 228    --      text string " in column nnn" where nnn is the decimal
 229    --      representation of the column number stored in Error_Msg_Col plus
 230    --      one (the plus one is because the number is stored 0-origin and
 231    --      displayed 1-origin).
 232
 233    --    Insertion character ^ (Caret: insert integer value)
 234    --      The character ^ is replaced by the decimal conversion of the Uint
 235    --      value stored in Error_Msg_Uint_1, with a possible leading minus.
 236    --      A second ^ may occur in the message, in which case it is replaced
 237    --      by the decimal conversion of the Uint value in Error_Msg_Uint_2.
 238
 239    --    Insertion character > (Right bracket, run time name)
 240    --      The character > is replaced by a string of the form (name) if
 241    --      Targparm scanned out a Run_Time_Name (see package Targparm for
 242    --      details). The name is enclosed in parentheses and output in mixed
 243    --      case mode (upper case after any space in the name). If no run time
 244    --      name is defined, this insertion character has no effect.
 245
 246    --    Insertion character ! (Exclamation: unconditional message)
 247    --      The character ! appearing as the last character of a message makes
 248    --      the message unconditional which means that it is output even if it
 249    --      would normally be suppressed. See section above for a description
 250    --      of the cases in which messages are normally suppressed. Note that
 251    --      in the case of warnings, the meaning is that the warning should not
 252    --      be removed in dead code (that's the only time that the use of !
 253    --      has any effect for a warning).
 254    --
 255    --      Note: the presence of ! is ignored in continuation messages (i.e.
 256    --      messages starting with the \ insertion character). The effect of the
 257    --      use of ! in a parent message automatically applies to all of its
 258    --      continuation messages (since we clearly don't want any case in which
 259    --      continuations are separated from the parent message. It is allowable
 260    --      to put ! in continuation messages, and the usual style is to include
 261    --      it, since it makes it clear that the continuation is part of an
 262    --      unconditional message.
 263
 264    --    Insertion character !! (Double exclamation: unconditional warning)
 265    --      Normally warning messages issued in other than the main unit are
 266    --      suppressed. If the message ends with !! then this suppression is
 267    --      avoided. This is currently used by the Compile_Time_Warning pragma
 268    --      to ensure the message for a with'ed unit is output, and for warnings
 269    --      on ineffective back-end inlining, which is detected in units that
 270    --      contain subprograms to be inlined in the main program.
 271
 272    --    Insertion character ? (Question: warning message)
 273    --      The character ? appearing anywhere in a message makes the message
 274    --      warning instead of a normal error message, and the text of the
 275    --      message will be preceded by "warning:" in the normal case. The
 276    --      handling of warnings if further controlled by the Warning_Mode
 277    --      option (-w switch), see package Opt for further details, and also by
 278    --      the current setting from pragma Warnings. This pragma applies only
 279    --      to warnings issued from the semantic phase (not the parser), but
 280    --      currently all relevant warnings are posted by the semantic phase
 281    --      anyway. Messages starting with (style) are also treated as warning
 282    --      messages.
 283    --
 284    --      Note: when a warning message is output, the text of the message is
 285    --      preceded by "warning: " in the normal case. An exception to this
 286    --      rule occurs when the text of the message starts with "info: " in
 287    --      which case this string is not prepended. This allows callers to
 288    --      label certain warnings as informational messages, rather than as
 289    --      warning messages requiring some action.
 290    --
 291    --      Note: the presence of ? is ignored in continuation messages (i.e.
 292    --      messages starting with the \ insertion character). The warning
 293    --      status of continuations is determined only by the parent message
 294    --      which is being continued. It is allowable to put ? in continuation
 295    --      messages, and the usual style is to include it, since it makes it
 296    --      clear that the continuation is part of a warning message.
 297
 298    --    Insertion character < (Less Than: conditional warning message)
 299    --      The character < appearing anywhere in a message is used for a
 300    --      conditional error message. If Error_Msg_Warn is True, then the
 301    --      effect is the same as ? described above. If Error_Msg_Warn is
 302    --      False, then there is no effect.
 303
 304    --    Insertion character A-Z (Upper case letter: Ada reserved word)
 305    --      If two or more upper case letters appear in the message, they are
 306    --      taken as an Ada reserved word, and are converted to the default
 307    --      case for reserved words (see Scans package spec). Surrounding
 308    --      quotes are added unless manual quotation mode is currently set.
 309
 310    --    Insertion character ` (Backquote: set manual quotation mode)
 311    --      The backquote character always appears in pairs. Each backquote of
 312    --      the pair is replaced by a double quote character. In addition, any
 313    --      reserved keywords, or name insertions between these backquotes are
 314    --      not surrounded by the usual automatic double quotes. See the
 315    --      section below on manual quotation mode for further details.
 316
 317    --    Insertion character ' (Quote: literal character)
 318    --      Precedes a character which is placed literally into the message.
 319    --      Used to insert characters into messages that are one of the
 320    --      insertion characters defined here. Also useful in inserting
 321    --      sequences of upper case letters which are not to be treated as
 322    --      keywords.
 323
 324    --    Insertion character \ (Backslash: continuation message)
 325    --      Indicates that the message is a continuation of a message
 326    --      previously posted. This is used to ensure that such groups of
 327    --      messages are treated as a unit. The \ character must be the first
 328    --      character of the message text.
 329
 330    --    Insertion character \\ (Two backslashes, continuation with new line)
 331    --      This differs from \ only in -gnatjnn mode (Error_Message_Line_Length
 332    --      set non-zero). This sequence forces a new line to start even when
 333    --      continuations are being gathered into a single message.
 334
 335    --    Insertion character | (Vertical bar: non-serious error)
 336    --      By default, error messages (other than warning messages) are
 337    --      considered to be fatal error messages which prevent expansion or
 338    --      generation of code in the presence of the -gnatQ switch. If the
 339    --      insertion character | appears, the message is considered to be
 340    --      non-serious, and does not cause Serious_Errors_Detected to be
 341    --      incremented (so expansion is not prevented by such a msg).
 342
 343    --    Insertion character ~ (Tilde: insert string)
 344    --      Indicates that Error_Msg_String (1 .. Error_Msg_Strlen) is to be
 345    --      inserted to replace the ~ character. The string is inserted in the
 346    --      literal form it appears, without any action on special characters.
 347
 348    ----------------------------------------
 349    -- Specialization of Messages for VMS --
 350    ----------------------------------------
 351
 352    --  Some messages mention gcc-style switch names. When using an OpenVMS
 353    --  host, such switch names must be converted to their corresponding VMS
 354    --  qualifer. The following table controls this translation. In each case
 355    --  the original message must contain the string "-xxx switch", where xxx
 356    --  is the Gname? entry from below, and this string will be replaced by
 357    --  "/yyy qualifier", where yyy is the corresponding Vname? entry.
 358
 359    Gname1 : aliased constant String := "fno-strict-aliasing";
 360    Vname1 : aliased constant String := "OPTIMIZE=NO_STRICT_ALIASING";
 361
 362    Gname2 : aliased constant String := "gnatX";
 363    Vname2 : aliased constant String := "EXTENSIONS_ALLOWED";
 364
 365    Gname3 : aliased constant String := "gnatW";
 366    Vname3 : aliased constant String := "WIDE_CHARACTER_ENCODING";
 367
 368    Gname4 : aliased constant String := "gnatf";
 369    Vname4 : aliased constant String := "REPORT_ERRORS=FULL";
 370
 371    Gname5 : aliased constant String := "gnat05";
 372    Vname5 : aliased constant String := "05";
 373
 374    Gname6 : aliased constant String := "gnat2005";
 375    Vname6 : aliased constant String := "2005";
 376
 377    Gname7 : aliased constant String := "gnat12";
 378    Vname7 : aliased constant String := "12";
 379
 380    Gname8 : aliased constant String := "gnat2012";
 381    Vname8 : aliased constant String := "2012";
 382
 383    Gname9 : aliased constant String := "gnateinn";
 384    Vname9 : aliased constant String := "MAX_INSTANTIATIONS=nn";
 385
 386    type Cstring_Ptr is access constant String;
 387
 388    Gnames : array (Nat range <>) of Cstring_Ptr :=
 389               (Gname1'Access,
 390                Gname2'Access,
 391                Gname3'Access,
 392                Gname4'Access,
 393                Gname5'Access,
 394                Gname6'Access,
 395                Gname7'Access,
 396                Gname8'Access,
 397                Gname9'Access);
 398
 399    Vnames : array (Nat range <>) of Cstring_Ptr :=
 400               (Vname1'Access,
 401                Vname2'Access,
 402                Vname3'Access,
 403                Vname4'Access,
 404                Vname5'Access,
 405                Vname6'Access,
 406                Vname7'Access,
 407                Vname8'Access,
 408                Vname9'Access);
 409
 410    -----------------------------------------------------
 411    -- Global Values Used for Error Message Insertions --
 412    -----------------------------------------------------
 413
 414    --  The following global variables are essentially additional parameters
 415    --  passed to the error message routine for insertion sequences described
 416    --  above. The reason these are passed globally is that the insertion
 417    --  mechanism is essentially an untyped one in which the appropriate
 418    --  variables are set depending on the specific insertion characters used.
 419
 420    --  Note that is mandatory that the caller ensure that global variables
 421    --  are set before the Error_Msg call, otherwise the result is undefined.
 422
 423    Error_Msg_Col : Column_Number renames Err_Vars.Error_Msg_Col;
 424    --  Column for @ insertion character in message
 425
 426    Error_Msg_Uint_1 : Uint renames Err_Vars.Error_Msg_Uint_1;
 427    Error_Msg_Uint_2 : Uint renames Err_Vars.Error_Msg_Uint_2;
 428    --  Uint values for ^ insertion characters in message
 429
 430    Error_Msg_Sloc : Source_Ptr renames Err_Vars.Error_Msg_Sloc;
 431    --  Source location for # insertion character in message
 432
 433    Error_Msg_Name_1 : Name_Id renames Err_Vars.Error_Msg_Name_1;
 434    Error_Msg_Name_2 : Name_Id renames Err_Vars.Error_Msg_Name_2;
 435    Error_Msg_Name_3 : Name_Id renames Err_Vars.Error_Msg_Name_3;
 436    --  Name_Id values for % insertion characters in message
 437
 438    Error_Msg_File_1 : File_Name_Type renames Err_Vars.Error_Msg_File_1;
 439    Error_Msg_File_2 : File_Name_Type renames Err_Vars.Error_Msg_File_2;
 440    Error_Msg_File_3 : File_Name_Type renames Err_Vars.Error_Msg_File_3;
 441    --  File_Name_Type values for { insertion characters in message
 442
 443    Error_Msg_Unit_1 : Unit_Name_Type renames Err_Vars.Error_Msg_Unit_1;
 444    Error_Msg_Unit_2 : Unit_Name_Type renames Err_Vars.Error_Msg_Unit_2;
 445    --  Unit_Name_Type values for $ insertion characters in message
 446
 447    Error_Msg_Node_1 : Node_Id renames Err_Vars.Error_Msg_Node_1;
 448    Error_Msg_Node_2 : Node_Id renames Err_Vars.Error_Msg_Node_2;
 449    --  Node_Id values for & insertion characters in message
 450
 451    Error_Msg_Qual_Level : Int renames Err_Vars.Error_Msg_Qual_Level;
 452    --  Number of levels of qualification required for type name (see the
 453    --  description of the } insertion character). Note that this value does
 454    --  note get reset by any Error_Msg call, so the caller is responsible
 455    --  for resetting it.
 456
 457    Error_Msg_Warn : Boolean renames Err_Vars.Error_Msg_Warn;
 458    --  Used if current message contains a < insertion character to indicate
 459    --  if the current message is a warning message. Must be set appropriately
 460    --  before any call to Error_Msg_xxx with a < insertion character present.
 461    --  Setting is irrelevant if no < insertion character is present.
 462
 463    Error_Msg_String : String  renames Err_Vars.Error_Msg_String;
 464    Error_Msg_Strlen : Natural renames Err_Vars.Error_Msg_Strlen;
 465    --  Used if current message contains a ~ insertion character to indicate
 466    --  insertion of the string Error_Msg_String (1 .. Error_Msg_Strlen).
 467
 468    -----------------------------------------------------
 469    -- Format of Messages and Manual Quotation Control --
 470    -----------------------------------------------------
 471
 472    --  Messages are generally all in lower case, except for inserted names
 473    --  and appear in one of the following three forms:
 474
 475    --    error: text
 476    --    warning: text
 477
 478    --  The prefixes error and warning are supplied automatically (depending
 479    --  on the use of the ? insertion character), and the call to the error
 480    --  message routine supplies the text. The "error: " prefix is omitted
 481    --  in brief error message formats.
 482
 483    --  Reserved Ada keywords in the message are in the default keyword case
 484    --  (determined from the given source program), surrounded by quotation
 485    --  marks. This is achieved by spelling the reserved word in upper case
 486    --  letters, which is recognized as a request for insertion of quotation
 487    --  marks by the error text processor. Thus for example:
 488
 489    --    Error_Msg_AP ("IS expected");
 490
 491    --  would result in the output of one of the following:
 492
 493    --    error: "is" expected
 494    --    error: "IS" expected
 495    --    error: "Is" expected
 496
 497    --  the choice between these being made by looking at the casing convention
 498    --  used for keywords (actually the first compilation unit keyword) in the
 499    --  source file.
 500
 501    --  Note: a special exception is that RM is never treated as a keyword
 502    --  but instead is copied literally into the message, this avoids the
 503    --  need for writing 'R'M for all reference manual quotes. A similar
 504    --  exception is applied to the occurrence of the string Alfa used in
 505    --  error messages about the Alfa subset of Ada.
 506
 507    --  In the case of names, the default mode for the error text processor
 508    --  is to surround the name by quotation marks automatically. The case
 509    --  used for the identifier names is taken from the source program where
 510    --  possible, and otherwise is the default casing convention taken from
 511    --  the source file usage.
 512
 513    --  In some cases, better control over the placement of quote marks is
 514    --  required. This is achieved using manual quotation mode. In this mode,
 515    --  one or more insertion sequences is surrounded by backquote characters.
 516    --  The backquote characters are output as double quote marks, and normal
 517    --  automatic insertion of quotes is suppressed between the double quotes.
 518    --  For example:
 519
 520    --    Error_Msg_AP ("`END &;` expected");
 521
 522    --  generates a message like
 523
 524    --    error: "end Open_Scope;" expected
 525
 526    --  where the node specifying the name Open_Scope has been stored in
 527    --  Error_Msg_Node_1 prior to the call. The great majority of error
 528    --  messages operates in normal quotation mode.
 529
 530    --  Note: the normal automatic insertion of spaces before insertion
 531    --  sequences (such as those that come from & and %) is suppressed in
 532    --  manual quotation mode, so blanks, if needed as in the above example,
 533    --  must be explicitly present.
 534
 535    ----------------------------
 536    -- Message ID Definitions --
 537    ----------------------------
 538
 539    subtype Error_Msg_Id is Erroutc.Error_Msg_Id;
 540    function "=" (Left, Right : Error_Msg_Id) return Boolean
 541      renames Erroutc."=";
 542    --  A type used to represent specific error messages. Used by the clients
 543    --  of this package only in the context of the Get_Error_Id and
 544    --  Change_Error_Text subprograms.
 545
 546    No_Error_Msg : constant Error_Msg_Id := Erroutc.No_Error_Msg;
 547    --  A constant which is different from any value returned by Get_Error_Id.
 548    --  Typically used by a client to indicate absense of a saved Id value.
 549
 550    function Get_Msg_Id return Error_Msg_Id renames Erroutc.Get_Msg_Id;
 551    --  Returns the Id of the message most recently posted using one of the
 552    --  Error_Msg routines.
 553
 554    function Get_Location (E : Error_Msg_Id) return Source_Ptr
 555      renames Erroutc.Get_Location;
 556    --  Returns the flag location of the error message with the given id E
 557
 558    ------------------------
 559    -- List Pragmas Table --
 560    ------------------------
 561
 562    --  When a pragma Page or pragma List is encountered by the parser, an
 563    --  entry is made in the following table. This table is then used to
 564    --  control the full listing if one is being generated. Note that the
 565    --  reason we do the processing in the parser is so that we get proper
 566    --  listing control even in syntax check only mode.
 567
 568    type List_Pragma_Type is (List_On, List_Off, Page);
 569
 570    type List_Pragma_Record is record
 571       Ptyp : List_Pragma_Type;
 572       Ploc : Source_Ptr;
 573    end record;
 574
 575    --  Note: Ploc points to the terminating semicolon in the List_Off and Page
 576    --  cases, and to the pragma keyword for List_On. In the case of a pragma
 577    --  List_Off, a List_On entry is also made in the table, pointing to the
 578    --  pragma keyword. This ensures that, as required, a List (Off) pragma is
 579    --  listed even in list off mode.
 580
 581    package List_Pragmas is new Table.Table (
 582      Table_Component_Type => List_Pragma_Record,
 583      Table_Index_Type     => Int,
 584      Table_Low_Bound      => 1,
 585      Table_Initial        => 50,
 586      Table_Increment      => 200,
 587      Table_Name           => "List_Pragmas");
 588
 589    ---------------------------
 590    -- Ignore_Errors Feature --
 591    ---------------------------
 592
 593    --  In certain cases, notably for optional subunits, the compiler operates
 594    --  in a mode where errors are to be ignored, and the whole unit is to be
 595    --  considered as not present. To implement this we provide the following
 596    --  flag to enable special handling, where error messages are suppressed,
 597    --  but the Fatal_Error flag will still be set in the normal manner.
 598
 599    Ignore_Errors_Enable : Nat := 0;
 600    --  Triggering switch. If non-zero, then ignore errors mode is activated.
 601    --  This is a counter to allow convenient nesting of enable/disable.
 602
 603    -----------------------
 604    --  CODEFIX Facility --
 605    -----------------------
 606
 607    --  The GPS and GNATBench IDE's have a codefix facility that allows for
 608    --  automatic correction of a subset of the errors and warnings issued
 609    --  by the compiler. This is done by recognizing the text of specific
 610    --  messages using appropriate matching patterns.
 611
 612    --  The text of such messages should not be altered without coordinating
 613    --  with the codefix code. All such messages are marked by a specific
 614    --  style of comments, as shown by the following example:
 615
 616    --     Error_Msg_N -- CODEFIX
 617    --       (parameters ....)
 618
 619    --  Any message marked with this -- CODEFIX comment should not be modified
 620    --  without appropriate coordination.
 621
 622    ------------------------------
 623    -- Error Output Subprograms --
 624    ------------------------------
 625
 626    procedure Initialize;
 627    --  Initializes for output of error messages. Must be called for each
 628    --  source file before using any of the other routines in the package.
 629
 630    procedure Finalize (Last_Call : Boolean);
 631    --  Finalize processing of error message list. Includes processing for
 632    --  duplicated error messages, and other similar final adjustment of the
 633    --  list of error messages. Note that this procedure must be called before
 634    --  calling Compilation_Errors to determine if there were any errors. It
 635    --  is perfectly fine to call Finalize more than once, providing that the
 636    --  parameter Last_Call is set False for every call except the last call.
 637
 638    --  This multiple call capability is used to do some processing that may
 639    --  generate messages. Call Finalize to eliminate duplicates and remove
 640    --  deleted warnings. Test for compilation errors using Compilation_Errors,
 641    --  then generate some more errors/warnings, call Finalize again to make
 642    --  sure that all duplicates in these new messages are dealt with, then
 643    --  finally call Output_Messages to output the final list of messages. The
 644    --  argument Last_Call must be set False on all calls except the last call,
 645    --  and must be set True on the last call (a value of True activates some
 646    --  processing that must only be done after all messages are posted).
 647
 648    procedure Output_Messages;
 649    --  Output list of messages, including messages giving number of detected
 650    --  errors and warnings.
 651
 652    procedure Error_Msg (Msg : String; Flag_Location : Source_Ptr);
 653    --  Output a message at specified location. Can be called from the parser
 654    --  or the semantic analyzer.
 655
 656    procedure Error_Msg_S (Msg : String);
 657    --  Output a message at current scan pointer location. This routine can be
 658    --  called only from the parser, since it references Scan_Ptr.
 659
 660    procedure Error_Msg_AP (Msg : String);
 661    --  Output a message just after the previous token. This routine can be
 662    --  called only from the parser, since it references Prev_Token_Ptr.
 663
 664    procedure Error_Msg_BC (Msg : String);
 665    --  Output a message just before the current token. Note that the important
 666    --  difference between this and the previous routine is that the BC case
 667    --  posts a flag on the current line, whereas AP can post a flag at the
 668    --  end of the preceding line. This routine can be called only from the
 669    --  parser, since it references Token_Ptr.
 670
 671    procedure Error_Msg_SC (Msg : String);
 672    --  Output a message at the start of the current token, unless we are at
 673    --  the end of file, in which case we always output the message after the
 674    --  last real token in the file. This routine can be called only from the
 675    --  parser, since it references Token_Ptr.
 676
 677    procedure Error_Msg_SP (Msg : String);
 678    --  Output a message at the start of the previous token. This routine can
 679    --  be called only from the parser, since it references Prev_Token_Ptr.
 680
 681    procedure Error_Msg_N (Msg : String; N : Node_Or_Entity_Id);
 682    --  Output a message at the Sloc of the given node. This routine can be
 683    --  called from the parser or the semantic analyzer, although the call from
 684    --  the latter is much more common (and is the most usual way of generating
 685    --  error messages from the analyzer). The message text may contain a
 686    --  single & insertion, which will reference the given node. The message is
 687    --  suppressed if the node N already has a message posted, or if it is a
 688    --  warning and N is an entity node for which warnings are suppressed.
 689
 690    procedure Error_Msg_F (Msg : String; N : Node_Id);
 691    --  Similar to Error_Msg_N except that the message is placed on the first
 692    --  node of the construct N (First_Node (N)).
 693
 694    procedure Error_Msg_NE
 695      (Msg : String;
 696       N   : Node_Or_Entity_Id;
 697       E   : Node_Or_Entity_Id);
 698    --  Output a message at the Sloc of the given node N, with an insertion of
 699    --  the name from the given entity node E. This is used by the semantic
 700    --  routines, where this is a common error message situation. The Msg text
 701    --  will contain a & or } as usual to mark the insertion point. This
 702    --  routine can be called from the parser or the analyzer.
 703
 704    procedure Error_Msg_FE
 705      (Msg : String;
 706       N   : Node_Id;
 707       E   : Node_Or_Entity_Id);
 708    --  Same as Error_Msg_NE, except that the message is placed on the first
 709    --  node of the construct N (First_Node (N)).
 710
 711    procedure Error_Msg_NEL
 712      (Msg           : String;
 713       N             : Node_Or_Entity_Id;
 714       E             : Node_Or_Entity_Id;
 715       Flag_Location : Source_Ptr);
 716    --  Exactly the same as Error_Msg_NE, except that the flag is placed at
 717    --  the specified Flag_Location instead of at Sloc (N).
 718
 719    procedure Error_Msg_NW
 720      (Eflag : Boolean;
 721       Msg   : String;
 722       N     : Node_Or_Entity_Id);
 723    --  This routine is used for posting a message conditionally. The message
 724    --  is posted (with the same effect as Error_Msg_N (Msg, N) if and only
 725    --  if Eflag is True and if the node N is within the main extended source
 726    --  unit and comes from source. Typically this is a warning mode flag.
 727    --  This routine can only be called during semantic analysis. It may not
 728    --  be called during parsing.
 729
 730    procedure Change_Error_Text (Error_Id : Error_Msg_Id; New_Msg : String);
 731    --  The error message text of the message identified by Id is replaced by
 732    --  the given text. This text may contain insertion characters in the
 733    --  usual manner, and need not be the same length as the original text.
 734
 735    function First_Node (C : Node_Id) return Node_Id;
 736    --  Given a construct C, finds the first node in the construct, i.e. the
 737    --  one with the lowest Sloc value. This is useful in placing error msgs.
 738
 739    function First_Sloc (N : Node_Id) return Source_Ptr;
 740    --  Given the node for an expression, return a source pointer value that
 741    --  points to the start of the first token in the expression. In the case
 742    --  where the expression is parenthesized, an attempt is made to include
 743    --  the parentheses (i.e. to return the location of the initial paren).
 744
 745    procedure Purge_Messages (From : Source_Ptr; To : Source_Ptr)
 746      renames Erroutc.Purge_Messages;
 747    --  All error messages whose location is in the range From .. To (not
 748    --  including the end points) will be deleted from the error listing.
 749
 750    procedure Remove_Warning_Messages (N : Node_Id);
 751    --  Remove any warning messages corresponding to the Sloc of N or any
 752    --  of its descendent nodes. No effect if no such warnings. Note that
 753    --  style messages (identified by the fact that they start with "(style)"
 754    --  are not removed by this call. Basically the idea behind this procedure
 755    --  is to remove warnings about execution conditions from known dead code.
 756
 757    procedure Remove_Warning_Messages (L : List_Id);
 758    --  Remove warnings on all elements of a list (Calls Remove_Warning_Messages
 759    --  on each element of the list, see above).
 760
 761    procedure Set_Ignore_Errors (To : Boolean);
 762    --  Following a call to this procedure with To=True, all error calls are
 763    --  ignored. A call with To=False restores the default treatment in which
 764    --  error calls are treated as usual (and as described in this spec).
 765
 766    procedure Set_Warnings_Mode_Off (Loc : Source_Ptr)
 767      renames Erroutc.Set_Warnings_Mode_Off;
 768    --  Called in response to a pragma Warnings (Off) to record the source
 769    --  location from which warnings are to be turned off.
 770
 771    procedure Set_Warnings_Mode_On (Loc : Source_Ptr)
 772      renames Erroutc.Set_Warnings_Mode_On;
 773    --  Called in response to a pragma Warnings (On) to record the source
 774    --  location from which warnings are to be turned back on.
 775
 776    procedure Set_Specific_Warning_Off
 777      (Loc    : Source_Ptr;
 778       Msg    : String;
 779       Config : Boolean;
 780       Used   : Boolean := False)
 781      renames Erroutc.Set_Specific_Warning_Off;
 782    --  This is called in response to the two argument form of pragma Warnings
 783    --  where the first argument is OFF, and the second argument is the prefix
 784    --  of a specific warning to be suppressed. The first argument is the start
 785    --  of the suppression range, and the second argument is the string from
 786    --  the pragma.
 787
 788    procedure Set_Specific_Warning_On
 789      (Loc : Source_Ptr;
 790       Msg : String;
 791       Err : out Boolean)
 792      renames Erroutc.Set_Specific_Warning_On;
 793    --  This is called in response to the two argument form of pragma Warnings
 794    --  where the first argument is ON, and the second argument is the prefix
 795    --  of a specific warning to be suppressed. The first argument is the end
 796    --  of the suppression range, and the second argument is the string from
 797    --  the pragma. Err is set to True on return to report the error of no
 798    --  matching Warnings Off pragma preceding this one.
 799
 800    function Compilation_Errors return Boolean;
 801    --  Returns true if errors have been detected, or warnings in -gnatwe
 802    --  (treat warnings as errors) mode. Note that it is mandatory to call
 803    --  Finalize before calling this routine.
 804
 805    procedure Error_Msg_CRT (Feature : String; N : Node_Id);
 806    --  Posts a non-fatal message on node N saying that the feature identified
 807    --  by the Feature argument is not supported in either configurable
 808    --  run-time mode or no run-time mode (as appropriate). In the former case,
 809    --  the name of the library is output if available.
 810
 811    procedure Error_Msg_PT (Typ : Node_Id; Subp : Node_Id);
 812    --  Posts an error on the protected type declaration Typ indicating wrong
 813    --  mode of the first formal of protected type primitive Subp.
 814
 815    procedure dmsg (Id : Error_Msg_Id) renames Erroutc.dmsg;
 816    --  Debugging routine to dump an error message
 817
 818    ------------------------------------
 819    -- Utility Interface for Back End --
 820    ------------------------------------
 821
 822    --  The following subprograms can be used by the back end for the purposes
 823    --  of concocting error messages that are not output via Errout, e.g. the
 824    --  messages generated by the gcc back end.
 825
 826    procedure Set_Identifier_Casing
 827      (Identifier_Name : System.Address;
 828       File_Name       : System.Address);
 829    --  The identifier is a null terminated string that represents the name of
 830    --  an identifier appearing in the source program. File_Name is a null
 831    --  terminated string giving the corresponding file name for the identifier
 832    --  as obtained from the front end by the use of Full_Debug_Name to the
 833    --  source file referenced by the corresponding source location value. On
 834    --  return, the name is in Name_Buffer, null terminated with Name_Len set.
 835    --  This name is the identifier name as passed, cased according to the
 836    --  default identifier casing for the given file.
 837
 838 end Errout;