gcc/ada/ali.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  A L I                                   --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2015, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package defines the internal data structures used for representation
  27 --  of Ada Library Information (ALI) acquired from the ALI files generated by
  28 --  the front end.
  29
  30 with Casing;  use Casing;
  31 with Gnatvsn; use Gnatvsn;
  32 with Namet;   use Namet;
  33 with Rident;  use Rident;
  34 with Table;
  35 with Types;   use Types;
  36
  37 with GNAT.HTable; use GNAT.HTable;
  38
  39 package ALI is
  40
  41    --------------
  42    -- Id Types --
  43    --------------
  44
  45    --  The various entries are stored in tables with distinct subscript ranges.
  46    --  The following type definitions show the ranges used for the subscripts
  47    --  (Id values) for the various tables.
  48
  49    type ALI_Id is range 0 .. 999_999;
  50    --  Id values used for ALIs table entries
  51
  52    type Unit_Id is range 1_000_000 .. 1_999_999;
  53    --  Id values used for Unit table entries
  54
  55    type With_Id is range 2_000_000 .. 2_999_999;
  56    --  Id values used for Withs table entries
  57
  58    type Arg_Id is range 3_000_000 .. 3_999_999;
  59    --  Id values used for argument table entries
  60
  61    type Sdep_Id is range 4_000_000 .. 4_999_999;
  62    --  Id values used for Sdep table entries
  63
  64    type Source_Id is range 5_000_000 .. 5_999_999;
  65    --  Id values used for Source table entries
  66
  67    type Interrupt_State_Id is range 6_000_000 .. 6_999_999;
  68    --  Id values used for Interrupt_State table entries
  69
  70    type Priority_Specific_Dispatching_Id is range 7_000_000 .. 7_999_999;
  71    --  Id values used for Priority_Specific_Dispatching table entries
  72
  73    --------------------
  74    -- ALI File Table --
  75    --------------------
  76
  77    --  Each ALI file read generates an entry in the ALIs table
  78
  79    No_ALI_Id : constant ALI_Id := ALI_Id'First;
  80    --  Special value indicating no ALI entry
  81
  82    First_ALI_Entry : constant ALI_Id := No_ALI_Id + 1;
  83    --  Id of first actual entry in table
  84
  85    type Main_Program_Type is (None, Proc, Func);
  86    --  Indicator of whether unit can be used as main program
  87
  88    type ALIs_Record is record
  89
  90       Afile : File_Name_Type;
  91       --  Name of ALI file
  92
  93       Ofile_Full_Name : File_Name_Type;
  94       --  Full name of object file corresponding to the ALI file
  95
  96       Sfile : File_Name_Type;
  97       --  Name of source file that generates this ALI file (which is equal
  98       --  to the name of the source file in the first unit table entry for
  99       --  this ALI file, since the body if present is always first).
 100
 101       Ver : String (1 .. Ver_Len_Max);
 102       --  Value of library version (V line in ALI file). Not set if
 103       --  V lines are ignored as a result of the Ignore_Lines parameter.
 104
 105       Ver_Len : Natural;
 106       --  Length of characters stored in Ver. Not set if V lines are ignored as
 107       --  a result of the Ignore_Lines parameter.
 108
 109       SAL_Interface : Boolean;
 110       --  Set True when this is an interface to a standalone library
 111
 112       First_Unit : Unit_Id;
 113       --  Id of first Unit table entry for this file
 114
 115       Last_Unit : Unit_Id;
 116       --  Id of last Unit table entry for this file
 117
 118       First_Sdep : Sdep_Id;
 119       --  Id of first Sdep table entry for this file
 120
 121       Last_Sdep : Sdep_Id;
 122       --  Id of last Sdep table entry for this file
 123
 124       Main_Program : Main_Program_Type;
 125       --  Indicator of whether first unit can be used as main program. Not set
 126       --  if 'M' appears in Ignore_Lines.
 127
 128       Main_Priority : Int;
 129       --  Indicates priority value if Main_Program field indicates that this
 130       --  can be a main program. A value of -1 (No_Main_Priority) indicates
 131       --  that no parameter was found, or no M line was present. Not set if
 132       --  'M' appears in Ignore_Lines.
 133
 134       Main_CPU : Int;
 135       --  Indicates processor if Main_Program field indicates that this can
 136       --  be a main program. A value of -1 (No_Main_CPU) indicates that no C
 137       --  parameter was found, or no M line was present. Not set if 'M' appears
 138       --  in Ignore_Lines.
 139
 140       Time_Slice_Value : Int;
 141       --  Indicates value of time slice parameter from T=xxx on main program
 142       --  line. A value of -1 indicates that no T=xxx parameter was found, or
 143       --  no M line was present. Not set if 'M' appears in Ignore_Lines.
 144
 145       WC_Encoding : Character;
 146       --  Wide character encoding if main procedure. Otherwise not relevant.
 147       --  Not set if 'M' appears in Ignore_Lines.
 148
 149       Locking_Policy : Character;
 150       --  Indicates locking policy for units in this file. Space means tasking
 151       --  was not used, or that no Locking_Policy pragma was present or that
 152       --  this is a language defined unit. Otherwise set to first character
 153       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 154
 155       Partition_Elaboration_Policy : Character;
 156       --  Indicates partition elaboration policy for units in this file. Space
 157       --  means that no Partition_Elaboration_Policy pragma was present or that
 158       --  this is a language defined unit. Otherwise set to first character
 159       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 160
 161       Queuing_Policy : Character;
 162       --  Indicates queuing policy for units in this file. Space means tasking
 163       --  was not used, or that no Queuing_Policy pragma was present or that
 164       --  this is a language defined unit. Otherwise set to first character
 165       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 166
 167       Task_Dispatching_Policy : Character;
 168       --  Indicates task dispatching policy for units in this file. Space means
 169       --  tasking was not used, or that no Task_Dispatching_Policy pragma was
 170       --  present or that this is a language defined unit. Otherwise set to
 171       --  first character (upper case) of policy name. Not set if 'P' appears
 172       --  in Ignore_Lines.
 173
 174       Compile_Errors : Boolean;
 175       --  Set to True if compile errors for unit. Note that No_Object will
 176       --  always be set as well in this case. Not set if 'P' appears in
 177       --  Ignore_Lines.
 178
 179       GNATprove_Mode : Boolean;
 180       --  Set to True if ALI and object file produced in GNATprove_Mode as
 181       --  signalled by GP appearing on the P line. Not set if 'P' appears in
 182       --  Ignore_Lines.
 183
 184       No_Object : Boolean;
 185       --  Set to True if no object file generated. Not set if 'P' appears in
 186       --  Ignore_Lines.
 187
 188       Normalize_Scalars : Boolean;
 189       --  Set to True if file was compiled with Normalize_Scalars. Not set if
 190       --  'P' appears in Ignore_Lines.
 191
 192       SSO_Default : Character;
 193       --  Set to 'H' or 'L' if file was compiled with a configuration pragma
 194       --  file containing Default_Scalar_Storage_Order (High/Low_Order_First).
 195       --  Set to ' ' if neither pragma was present. Not set if 'P' appears in
 196       --  Ignore_Lines.
 197
 198       Unit_Exception_Table : Boolean;
 199       --  Set to True if unit exception table pointer generated. Not set if 'P'
 200       --  appears in Ignore_Lines.
 201
 202       Zero_Cost_Exceptions : Boolean;
 203       --  Set to True if file was compiled with zero cost exceptions. Not set
 204       --  if 'P' appears in Ignore_Lines.
 205
 206       Restrictions : Restrictions_Info;
 207       --  Restrictions information reconstructed from R lines
 208
 209       First_Interrupt_State : Interrupt_State_Id;
 210       Last_Interrupt_State  : Interrupt_State_Id'Base;
 211       --  These point to the first and last entries in the interrupt state
 212       --  table for this unit. If no entries, then Last_Interrupt_State =
 213       --  First_Interrupt_State - 1 (that's why the 'Base reference is there,
 214       --  it can be one less than the lower bound of the subtype). Not set if
 215       --  'I' appears in Ignore_Lines
 216
 217       First_Specific_Dispatching : Priority_Specific_Dispatching_Id;
 218       Last_Specific_Dispatching  : Priority_Specific_Dispatching_Id'Base;
 219       --  These point to the first and last entries in the priority specific
 220       --  dispatching table for this unit. If there are no entries, then
 221       --  Last_Specific_Dispatching = First_Specific_Dispatching - 1. That
 222       --  is why the 'Base reference is there, it can be one less than the
 223       --  lower bound of the subtype. Not set if 'S' appears in Ignore_Lines.
 224
 225    end record;
 226
 227    No_Main_Priority : constant Int := -1;
 228    --  Code for no main priority set
 229
 230    No_Main_CPU : constant Int := -1;
 231    --  Code for no main cpu set
 232
 233    package ALIs is new Table.Table (
 234      Table_Component_Type => ALIs_Record,
 235      Table_Index_Type     => ALI_Id,
 236      Table_Low_Bound      => First_ALI_Entry,
 237      Table_Initial        => 500,
 238      Table_Increment      => 200,
 239      Table_Name           => "ALIs");
 240
 241    ----------------
 242    -- Unit Table --
 243    ----------------
 244
 245    --  Each unit within an ALI file generates an entry in the unit table
 246
 247    No_Unit_Id : constant Unit_Id := Unit_Id'First;
 248    --  Special value indicating no unit table entry
 249
 250    First_Unit_Entry : constant Unit_Id := No_Unit_Id + 1;
 251    --  Id of first actual entry in table
 252
 253    type Unit_Type is (Is_Spec, Is_Body, Is_Spec_Only, Is_Body_Only);
 254    --  Indicates type of entry, if both body and spec appear in the ALI file,
 255    --  then the first unit is marked Is_Body, and the second is marked Is_Spec.
 256    --  If only a spec appears, then it is marked as Is_Spec_Only, and if only
 257    --  a body appears, then it is marked Is_Body_Only).
 258
 259    subtype Version_String is String (1 .. 8);
 260    --  Version string, taken from unit record
 261
 262    type Unit_Record is record
 263
 264       My_ALI : ALI_Id;
 265       --  Corresponding ALI entry
 266
 267       Uname : Unit_Name_Type;
 268       --  Name of Unit
 269
 270       Sfile : File_Name_Type;
 271       --  Name of source file
 272
 273       Preelab : Boolean;
 274       --  Indicates presence of PR parameter for a preelaborated package
 275
 276       No_Elab : Boolean;
 277       --  Indicates presence of NE parameter for a unit that has does not
 278       --  have an elaboration routine (since it has no elaboration code).
 279
 280       Pure : Boolean;
 281       --  Indicates presence of PU parameter for a package having pragma Pure
 282
 283       Dynamic_Elab : Boolean;
 284       --  Set to True if the unit was compiled with dynamic elaboration checks
 285       --  (i.e. either -gnatE or pragma Elaboration_Checks (RM) was used to
 286       --  compile the unit).
 287
 288       Elaborate_Body : Boolean;
 289       --  Indicates presence of EB parameter for a package which has a pragma
 290       --  Elaborate_Body, and also for generic package instantiations.
 291
 292       Set_Elab_Entity : Boolean;
 293       --  Indicates presence of EE parameter for a unit which has an
 294       --  elaboration entity which must be set true as part of the
 295       --  elaboration of the unit.
 296
 297       Has_RACW : Boolean;
 298       --  Indicates presence of RA parameter for a package that declares at
 299       --  least one Remote Access to Class_Wide (RACW) object.
 300
 301       Remote_Types : Boolean;
 302       --  Indicates presence of RT parameter for a package which has a
 303       --  pragma Remote_Types.
 304
 305       Serious_Errors : Boolean;
 306       --  Indicates presence of SE parameter indicating that compilation of
 307       --  the unit encountered as serious error.
 308
 309       Shared_Passive : Boolean;
 310       --  Indicates presence of SP parameter for a package which has a pragma
 311       --  Shared_Passive.
 312
 313       RCI : Boolean;
 314       --  Indicates presence of RC parameter for a package which has a pragma
 315       --  Remote_Call_Interface.
 316
 317       Predefined : Boolean;
 318       --  Indicates if unit is language predefined (or a child of such a unit)
 319
 320       Internal : Boolean;
 321       --  Indicates if unit is an internal unit (or a child of such a unit)
 322
 323       First_With : With_Id;
 324       --  Id of first withs table entry for this file
 325
 326       Last_With : With_Id;
 327       --  Id of last withs table entry for this file
 328
 329       First_Arg : Arg_Id;
 330       --  Id of first args table entry for this file
 331
 332       Last_Arg : Arg_Id;
 333       --  Id of last args table entry for this file
 334
 335       Utype : Unit_Type;
 336       --  Type of entry
 337
 338       Is_Generic : Boolean;
 339       --  True for generic unit (i.e. a generic declaration, or a generic
 340       --  body). False for a non-generic unit.
 341
 342       Unit_Kind : Character;
 343       --  Indicates the nature of the unit. 'p' for Packages and 's' for
 344       --  subprograms.
 345
 346       Version : Version_String;
 347       --  Version of unit
 348
 349       Icasing : Casing_Type;
 350       --  Indicates casing of identifiers in source file for this unit. This
 351       --  is used for informational output, and also for constructing the main
 352       --  unit if it is being built in Ada.
 353
 354       Kcasing : Casing_Type;
 355       --  Indicates casing of keywords in source file for this unit. This is
 356       --  used for informational output, and also for constructing the main
 357       --  unit if it is being built in Ada.
 358
 359       Elab_Position : aliased Natural;
 360       --  Initialized to zero. Set non-zero when a unit is chosen and
 361       --  placed in the elaboration order. The value represents the
 362       --  ordinal position in the elaboration order.
 363
 364       Init_Scalars : Boolean;
 365       --  Set True if IS qualifier appears in ALI file, indicating that
 366       --  an Initialize_Scalars pragma applies to the unit.
 367
 368       SAL_Interface : Boolean;
 369       --  Set True when this is an interface to a standalone library
 370
 371       Directly_Scanned : Boolean;
 372       --  True iff it is a unit from an ALI file specified to gnatbind
 373
 374       Body_Needed_For_SAL : Boolean;
 375       --  Indicates that the source for the body of the unit (subprogram,
 376       --  package, or generic unit) must be included in a standalone library.
 377
 378       Elaborate_Body_Desirable : Boolean;
 379       --  Indicates that the front end elaboration circuitry decided that it
 380       --  would be a good idea if this package had Elaborate_Body. The binder
 381       --  will attempt, but does not promise, to place the elaboration call
 382       --  for the body right after the call for the spec, or at least as close
 383       --  together as possible.
 384
 385       Optimize_Alignment : Character;
 386       --  Optimize_Alignment setting. Set to L/S/T/O for OL/OS/OT/OO present
 387
 388       Has_Finalizer : Boolean;
 389       --  Indicates whether a package body or a spec has a library-level
 390       --  finalization routine.
 391    end record;
 392
 393    package Units is new Table.Table (
 394      Table_Component_Type => Unit_Record,
 395      Table_Index_Type     => Unit_Id,
 396      Table_Low_Bound      => First_Unit_Entry,
 397      Table_Initial        => 100,
 398      Table_Increment      => 200,
 399      Table_Name           => "Unit");
 400
 401    ---------------------------
 402    -- Interrupt State Table --
 403    ---------------------------
 404
 405    --  An entry is made in this table for each I (interrupt state) line
 406    --  encountered in the input ALI file. The First/Last_Interrupt_Id
 407    --  fields of the ALI file entry show the range of entries defined
 408    --  within a particular ALI file.
 409
 410    type Interrupt_State_Record is record
 411       Interrupt_Id : Nat;
 412       --  Id from interrupt state entry
 413
 414       Interrupt_State : Character;
 415       --  State from interrupt state entry ('u'/'r'/'s')
 416
 417       IS_Pragma_Line : Nat;
 418       --  Line number of Interrupt_State pragma
 419    end record;
 420
 421    package Interrupt_States is new Table.Table (
 422      Table_Component_Type => Interrupt_State_Record,
 423      Table_Index_Type     => Interrupt_State_Id'Base,
 424      Table_Low_Bound      => Interrupt_State_Id'First,
 425      Table_Initial        => 100,
 426      Table_Increment      => 200,
 427      Table_Name           => "Interrupt_States");
 428
 429    -----------------------------------------
 430    -- Priority Specific Dispatching Table --
 431    -----------------------------------------
 432
 433    --  An entry is made in this table for each S (priority specific
 434    --  dispatching) line encountered in the input ALI file. The
 435    --  First/Last_Specific_Dispatching_Id fields of the ALI file
 436    --  entry show the range of entries defined within a particular
 437    --  ALI file.
 438
 439    type Specific_Dispatching_Record is record
 440       Dispatching_Policy : Character;
 441       --  First character (upper case) of the corresponding policy name
 442
 443       First_Priority     : Nat;
 444       --  Lower bound of the priority range to which the specified dispatching
 445       --  policy applies.
 446
 447       Last_Priority      : Nat;
 448       --  Upper bound of the priority range to which the specified dispatching
 449       --  policy applies.
 450
 451       PSD_Pragma_Line : Nat;
 452       --  Line number of Priority_Specific_Dispatching pragma
 453    end record;
 454
 455    package Specific_Dispatching is new Table.Table (
 456      Table_Component_Type => Specific_Dispatching_Record,
 457      Table_Index_Type     => Priority_Specific_Dispatching_Id'Base,
 458      Table_Low_Bound      => Priority_Specific_Dispatching_Id'First,
 459      Table_Initial        => 100,
 460      Table_Increment      => 200,
 461      Table_Name           => "Priority_Specific_Dispatching");
 462
 463    --------------
 464    -- Switches --
 465    --------------
 466
 467    --  These switches record status information about ali files that
 468    --  have been read, for quick reference without searching tables.
 469
 470    --  Note: a switch will be left set at its default value if the line
 471    --  which might otherwise set it is ignored (from Ignore_Lines).
 472
 473    Dynamic_Elaboration_Checks_Specified : Boolean := False;
 474    --  Set to False by Initialize_ALI. Set to True if Scan_ALI reads
 475    --  a unit for which dynamic elaboration checking is enabled.
 476
 477    GNATprove_Mode_Specified : Boolean := False;
 478    --  Set to True if an ali file was produced in GNATprove mode.
 479
 480    Initialize_Scalars_Used : Boolean := False;
 481    --  Set True if an ali file contains the Initialize_Scalars flag
 482
 483    Locking_Policy_Specified : Character := ' ';
 484    --  Set to blank by Initialize_ALI. Set to the appropriate locking policy
 485    --  character if an ali file contains a P line setting the locking policy.
 486
 487    No_Normalize_Scalars_Specified : Boolean := False;
 488    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 489    --  that the file was compiled without normalize scalars.
 490
 491    No_Object_Specified : Boolean := False;
 492    --  Set to False by Initialize_ALI. Set to True if an ali file contains
 493    --  the No_Object flag.
 494
 495    Normalize_Scalars_Specified : Boolean := False;
 496    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 497    --  that the file was compiled in Normalize_Scalars mode.
 498
 499    Partition_Elaboration_Policy_Specified : Character := ' ';
 500    --  Set to blank by Initialize_ALI. Set to the appropriate partition
 501    --  elaboration policy character if an ali file contains a P line setting
 502    --  the policy.
 503
 504    Queuing_Policy_Specified : Character := ' ';
 505    --  Set to blank by Initialize_ALI. Set to the appropriate queuing policy
 506    --  character if an ali file contains a P line setting the queuing policy.
 507
 508    Cumulative_Restrictions : Restrictions_Info := No_Restrictions;
 509    --  This variable records the cumulative contributions of R lines in all
 510    --  ali files, showing whether a restriction pragma exists anywhere, and
 511    --  accumulating the aggregate knowledge of violations.
 512
 513    SSO_Default_Specified : Boolean := False;
 514    --  Set to True if at least one ALI file contains an OH/OL flag indicating
 515    --  that it was compiled with a configuration pragmas file containing the
 516    --  pragma Default_Scalar_Storage_Order (OH/OL present in ALI file P line).
 517
 518    Stack_Check_Switch_Set : Boolean := False;
 519    --  Set to True if at least one ALI file contains '-fstack-check' in its
 520    --  argument list.
 521
 522    Static_Elaboration_Model_Used : Boolean := False;
 523    --  Set to False by Initialize_ALI. Set to True if any ALI file for a
 524    --  non-internal unit compiled with the static elaboration model is
 525    --  encountered.
 526
 527    Task_Dispatching_Policy_Specified : Character := ' ';
 528    --  Set to blank by Initialize_ALI. Set to the appropriate task dispatching
 529    --  policy character if an ali file contains a P line setting the
 530    --  task dispatching policy.
 531
 532    Unreserve_All_Interrupts_Specified : Boolean := False;
 533    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 534    --  has  P line specifying unreserve all interrupts mode.
 535
 536    Zero_Cost_Exceptions_Specified : Boolean := False;
 537    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 538    --  has a P line specifying the generation of zero cost exceptions.
 539
 540    -----------------
 541    -- Withs Table --
 542    -----------------
 543
 544    --  Each With line (W line) in an ALI file generates a Withs table entry
 545
 546    --  Note: there will be no entries in this table if 'W' lines are ignored
 547
 548    No_With_Id : constant With_Id := With_Id'First;
 549    --  Special value indicating no withs table entry
 550
 551    First_With_Entry : constant With_Id := No_With_Id + 1;
 552    --  Id of first actual entry in table
 553
 554    type With_Record is record
 555
 556       Uname : Unit_Name_Type;
 557       --  Name of Unit
 558
 559       Sfile : File_Name_Type;
 560       --  Name of source file, set to No_File in generic case
 561
 562       Afile : File_Name_Type;
 563       --  Name of ALI file, set to No_File in generic case
 564
 565       Elaborate : Boolean;
 566       --  Indicates presence of E parameter
 567
 568       Elaborate_All : Boolean;
 569       --  Indicates presence of EA parameter
 570
 571       Elab_All_Desirable : Boolean;
 572       --  Indicates presence of AD parameter
 573
 574       Elab_Desirable     : Boolean;
 575       --  Indicates presence of ED parameter
 576
 577       SAL_Interface : Boolean := False;
 578       --  True if the Unit is an Interface of a Stand-Alone Library
 579
 580       Limited_With : Boolean := False;
 581       --  True if unit is named in a limited_with_clause
 582
 583       Implicit_With_From_Instantiation : Boolean := False;
 584       --  True if this is an implicit with from a generic instantiation
 585    end record;
 586
 587    package Withs is new Table.Table (
 588      Table_Component_Type => With_Record,
 589      Table_Index_Type     => With_Id,
 590      Table_Low_Bound      => First_With_Entry,
 591      Table_Initial        => 5000,
 592      Table_Increment      => 200,
 593      Table_Name           => "Withs");
 594
 595    ---------------------
 596    -- Arguments Table --
 597    ---------------------
 598
 599    --  Each Arg line (A line) in an ALI file generates an Args table entry
 600
 601    --  Note: there will be no entries in this table if 'A' lines are ignored
 602
 603    No_Arg_Id : constant Arg_Id := Arg_Id'First;
 604    --  Special value indicating no args table entry
 605
 606    First_Arg_Entry : constant Arg_Id := No_Arg_Id + 1;
 607    --  Id of first actual entry in table
 608
 609    package Args is new Table.Table (
 610      Table_Component_Type => String_Ptr,
 611      Table_Index_Type     => Arg_Id,
 612      Table_Low_Bound      => First_Arg_Entry,
 613      Table_Initial        => 1000,
 614      Table_Increment      => 100,
 615      Table_Name           => "Args");
 616
 617    --------------------------
 618    -- Linker_Options Table --
 619    --------------------------
 620
 621    --  If an ALI file has one of more Linker_Options lines, then a single
 622    --  entry is made in this table. If more than one Linker_Options lines
 623    --  appears in a given ALI file, then the arguments are concatenated
 624    --  to form the entry in this table, using a NUL character as the
 625    --  separator, and a final NUL character is appended to the end.
 626
 627    --  Note: there will be no entries in this table if 'L' lines are ignored
 628
 629    type Linker_Option_Record is record
 630       Name : Name_Id;
 631       --  Name entry containing concatenated list of Linker_Options
 632       --  arguments separated by NUL and ended by NUL as described above.
 633
 634       Unit : Unit_Id;
 635       --  Unit_Id for the entry
 636
 637       Internal_File : Boolean;
 638       --  Set True if the linker options are from an internal file. This is
 639       --  used to insert certain standard entries after all the user entries
 640       --  but before the entries from the run-time.
 641
 642       Original_Pos : Positive;
 643       --  Keep track of original position in the linker options table. This
 644       --  is used to implement a stable sort when we sort the linker options
 645       --  table.
 646    end record;
 647
 648    --  The indexes of active entries in this table range from 1 to the
 649    --  value of Linker_Options.Last. The zero'th element is for sort call.
 650
 651    package Linker_Options is new Table.Table (
 652      Table_Component_Type => Linker_Option_Record,
 653      Table_Index_Type     => Integer,
 654      Table_Low_Bound      => 0,
 655      Table_Initial        => 200,
 656      Table_Increment      => 400,
 657      Table_Name           => "Linker_Options");
 658
 659    -----------------
 660    -- Notes Table --
 661    -----------------
 662
 663    --  The notes table records entries from N lines
 664
 665    type Notes_Record is record
 666       Pragma_Type : Character;
 667       --  'A', 'C', 'I', 'S', 'T' for Annotate/Comment/Ident/Subtitle/Title
 668
 669       Pragma_Line : Nat;
 670       --  Line number of pragma
 671
 672       Pragma_Col : Nat;
 673       --  Column number of pragma
 674
 675       Pragma_Source_File : File_Name_Type;
 676       --  Source file of pragma
 677
 678       Pragma_Args : Name_Id;
 679       --  Pragma arguments. No_Name if no arguments, otherwise a single
 680       --  name table entry consisting of all the characters on the notes
 681       --  line from the first non-blank character following the source
 682       --  location to the last character on the line.
 683    end record;
 684
 685    --  The indexes of active entries in this table range from 1 to the
 686    --  value of Linker_Options.Last. The zero'th element is for convenience
 687    --  if the table needs to be sorted.
 688
 689    package Notes is new Table.Table (
 690      Table_Component_Type => Notes_Record,
 691      Table_Index_Type     => Integer,
 692      Table_Low_Bound      => 0,
 693      Table_Initial        => 200,
 694      Table_Increment      => 400,
 695      Table_Name           => "Notes");
 696
 697    -------------------------------------------
 698    -- External Version Reference Hash Table --
 699    -------------------------------------------
 700
 701    --  This hash table keeps track of external version reference strings
 702    --  as read from E lines in the ali file. The stored values do not
 703    --  include the terminating quote characters.
 704
 705    --  Note: there will be no entries in this table if 'E' lines are ignored
 706
 707    type Vindex is range 0 .. 98;
 708    --  Type to define range of headers
 709
 710    function SHash (S : String_Ptr) return Vindex;
 711    --  Hash function for this table
 712
 713    function SEq (F1, F2 : String_Ptr) return Boolean;
 714    --  Equality function for this table
 715
 716    package Version_Ref is new Simple_HTable (
 717      Header_Num => Vindex,
 718      Element    => Boolean,
 719      No_Element => False,
 720      Key        => String_Ptr,
 721      Hash       => SHash,
 722      Equal      => SEq);
 723
 724    -------------------------
 725    -- No_Dependency Table --
 726    -------------------------
 727
 728    --  Each R line for a No_Dependency Restriction generates an entry in
 729    --  this No_Dependency table.
 730
 731    type No_Dep_Record is record
 732       ALI_File : ALI_Id;
 733       --  ALI File containing the entry
 734
 735       No_Dep_Unit : Name_Id;
 736       --  Id for names table entry including entire name, including periods
 737    end record;
 738
 739    package No_Deps is new Table.Table (
 740      Table_Component_Type => No_Dep_Record,
 741      Table_Index_Type     => Integer,
 742      Table_Low_Bound      => 0,
 743      Table_Initial        => 200,
 744      Table_Increment      => 400,
 745      Table_Name           => "No_Deps");
 746
 747    ------------------------------------
 748    -- Sdep (Source Dependency) Table --
 749    ------------------------------------
 750
 751    --  Each source dependency (D line) in an ALI file generates an entry in the
 752    --  Sdep table.
 753
 754    --  Note: there will be no entries in this table if 'D' lines are ignored
 755
 756    No_Sdep_Id : constant Sdep_Id := Sdep_Id'First;
 757    --  Special value indicating no Sdep table entry
 758
 759    First_Sdep_Entry : Sdep_Id := No_Sdep_Id + 1;
 760    --  Id of first Sdep entry for current ali file. This is initialized to the
 761    --  first Sdep entry in the table, and then incremented appropriately as
 762    --  successive ALI files are scanned.
 763
 764    type Sdep_Record is record
 765
 766       Sfile : File_Name_Type;
 767       --  Name of source file
 768
 769       Stamp : Time_Stamp_Type;
 770       --  Time stamp value. Note that this will be all zero characters for the
 771       --  dummy entries for missing or non-dependent files.
 772
 773       Checksum : Word;
 774       --  Checksum value. Note that this will be all zero characters for the
 775       --  dummy entries for missing or non-dependent files
 776
 777       Dummy_Entry : Boolean;
 778       --  Set True for dummy entries that correspond to missing files or files
 779       --  where no dependency relationship exists.
 780
 781       Subunit_Name : Name_Id;
 782       --  Name_Id for subunit name if present, else No_Name
 783
 784       Unit_Name : Name_Id;
 785       --  Name_Id for the unit name if not a subunit (No_Name for a subunit)
 786       Rfile : File_Name_Type;
 787       --  Reference file name. Same as Sfile unless a Source_Reference pragma
 788       --  was used, in which case it reflects the name used in the pragma.
 789
 790       Start_Line : Nat;
 791       --  Starting line number in file. Always 1, unless a Source_Reference
 792       --  pragma was used, in which case it reflects the line number value
 793       --  given in the pragma.
 794
 795    end record;
 796
 797    package Sdep is new Table.Table (
 798      Table_Component_Type => Sdep_Record,
 799      Table_Index_Type     => Sdep_Id,
 800      Table_Low_Bound      => First_Sdep_Entry,
 801      Table_Initial        => 5000,
 802      Table_Increment      => 200,
 803      Table_Name           => "Sdep");
 804
 805    ----------------------------
 806    -- Use of Name Table Info --
 807    ----------------------------
 808
 809    --  All unit names and file names are entered into the Names table. The Info
 810    --  fields of these entries are used as follows:
 811
 812    --    Unit name           Info field has Unit_Id of unit table entry
 813    --    ALI file name       Info field has ALI_Id of ALI table entry
 814    --    Source file name    Info field has Source_Id of source table entry
 815
 816    --------------------------
 817    -- Cross-Reference Data --
 818    --------------------------
 819
 820    --  The following table records cross-reference sections, there is one entry
 821    --  for each X header line in the ALI file for an xref section.
 822
 823    --  Note: there will be no entries in this table if 'X' lines are ignored
 824
 825    type Xref_Section_Record is record
 826       File_Num : Sdep_Id;
 827       --  Dependency number for file (entry in Sdep.Table)
 828
 829       File_Name : File_Name_Type;
 830       --  Name of file
 831
 832       First_Entity : Nat;
 833       --  First entry in Xref_Entity table
 834
 835       Last_Entity : Nat;
 836       --  Last entry in Xref_Entity table
 837    end record;
 838
 839    package Xref_Section is new Table.Table (
 840      Table_Component_Type => Xref_Section_Record,
 841      Table_Index_Type     => Nat,
 842      Table_Low_Bound      => 1,
 843      Table_Initial        => 50,
 844      Table_Increment      => 300,
 845      Table_Name           => "Xref_Section");
 846
 847    --  The following is used to indicate whether a typeref field is present
 848    --  for the entity, and if so what kind of typeref field.
 849
 850    type Tref_Kind is (
 851      Tref_None,    --  No typeref present
 852      Tref_Access,  --  Access type typeref (points to designated type)
 853      Tref_Derived, --  Derived type typeref (points to parent type)
 854      Tref_Type);   --  All other cases
 855
 856    type Visibility_Kind is
 857      (Global, --  Library level entity
 858       Static, --  Static C/C++ entity
 859       Other); --  Local and other entity
 860
 861    --  The following table records entities for which xrefs are recorded
 862
 863    type Xref_Entity_Record is record
 864       Line : Pos;
 865       --  Line number of definition
 866
 867       Etype : Character;
 868       --  Set to the identification character for the entity. See section
 869       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 870
 871       Col : Pos;
 872       --  Column number of definition
 873
 874       Visibility : Visibility_Kind;
 875       --  Visibility of entity
 876
 877       Entity : Name_Id;
 878       --  Name of entity
 879
 880       Iref_File_Num : Sdep_Id;
 881       --  This field is set to the dependency reference for the file containing
 882       --  the generic entity that this one instantiates, or to No_Sdep_Id if
 883       --  the current entity is not an instantiation
 884
 885       Iref_Line : Nat;
 886       --  This field is set to the line number in Iref_File_Num of the generic
 887       --  entity that this one instantiates, or to zero if the current entity
 888       --  is not an instantiation.
 889
 890       Rref_Line : Nat;
 891       --  This field is set to the line number of a renaming reference if
 892       --  one is present, or to zero if no renaming reference is present
 893
 894       Rref_Col : Nat;
 895       --  This field is set to the column number of a renaming reference
 896       --  if one is present, or to zero if no renaming reference is present.
 897
 898       Tref : Tref_Kind;
 899       --  Indicates if a typeref is present, and if so what kind. Set to
 900       --  Tref_None if no typeref field is present.
 901
 902       Tref_File_Num : Sdep_Id;
 903       --  This field is set to No_Sdep_Id if no typeref is present, or
 904       --  if the typeref refers to an entity in standard. Otherwise it
 905       --  it is the dependency reference for the file containing the
 906       --  declaration of the typeref entity.
 907
 908       Tref_Line : Nat;
 909       --  This field is set to zero if no typeref is present, or if the
 910       --  typeref refers to an entity in standard. Otherwise it contains
 911       --  the line number of the declaration of the typeref entity.
 912
 913       Tref_Type : Character;
 914       --  This field is set to blank if no typeref is present, or if the
 915       --  typeref refers to an entity in standard. Otherwise it contains
 916       --  the identification character for the typeref entity. See section
 917       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 918
 919       Tref_Col : Nat;
 920       --  This field is set to zero if no typeref is present, or if the
 921       --  typeref refers to an entity in standard. Otherwise it contains
 922       --  the column number of the declaration of the parent type.
 923
 924       Tref_Standard_Entity : Name_Id;
 925       --  This field is set to No_Name if no typeref is present or if the
 926       --  typeref refers to a declared entity rather than an entity in
 927       --  package Standard. If there is a typeref that references an
 928       --  entity in package Standard, then this field is a Name_Id
 929       --  reference for the entity name.
 930
 931       Oref_File_Num : Sdep_Id;
 932       --  This field is set to No_Sdep_Id if the entity doesn't override any
 933       --  other entity, or to the dependency reference for the overridden
 934       --  entity.
 935
 936       Oref_Line : Nat;
 937       Oref_Col  : Nat;
 938       --  These two fields are set to the line and column of the overridden
 939       --  entity.
 940
 941       First_Xref : Nat;
 942       --  Index into Xref table of first cross-reference
 943
 944       Last_Xref : Nat;
 945       --  Index into Xref table of last cross-reference. The value in
 946       --  Last_Xref can be less than the First_Xref value to indicate
 947       --  that no entries are present in the Xref Table.
 948    end record;
 949
 950    package Xref_Entity is new Table.Table (
 951      Table_Component_Type => Xref_Entity_Record,
 952      Table_Index_Type     => Nat,
 953      Table_Low_Bound      => 1,
 954      Table_Initial        => 500,
 955      Table_Increment      => 300,
 956      Table_Name           => "Xref_Entity");
 957
 958    Array_Index_Reference : constant Character := '*';
 959    Interface_Reference   : constant Character := 'I';
 960    --  Some special types of references. In the ALI file itself, these
 961    --  are output as attributes of the entity, not as references, but
 962    --  there is no provision in Xref_Entity_Record for storing multiple
 963    --  such references.
 964
 965    --  The following table records actual cross-references
 966
 967    type Xref_Record is record
 968       File_Num : Sdep_Id;
 969       --  Set to the file dependency number for the cross-reference. Note
 970       --  that if no file entry is present explicitly, this is just a copy
 971       --  of the reference for the current cross-reference section.
 972
 973       Line : Nat;
 974       --  Line number for the reference. This is zero when referencing a
 975       --  predefined entity, but in this case Name is set.
 976
 977       Rtype : Character;
 978       --  Indicates type of reference, using code used in ALI file:
 979       --    r = reference
 980       --    m = modification
 981       --    b = body entity
 982       --    c = completion of private or incomplete type
 983       --    x = type extension
 984       --    i = implicit reference
 985       --    Array_Index_Reference = reference to the index of an array
 986       --    Interface_Reference   = reference to an interface implemented
 987       --                            by the type
 988       --  See description in lib-xref.ads for further details
 989
 990       Col : Nat;
 991       --  Column number for the reference
 992
 993       Name : Name_Id := No_Name;
 994       --  This is only used when referencing a predefined entity. Currently,
 995       --  this only occurs for array indexes.
 996
 997       --  Note: for instantiation references, Rtype is set to ' ', and Col is
 998       --  set to zero. One or more such entries can follow any other reference.
 999       --  When there is more than one such entry, this is to be read as:
1000       --     e.g. ref1  ref2  ref3
1001       --     ref1 is a reference to an entity that was instantied at ref2.
1002       --     ref2 itself is also the result of an instantiation, that took
1003       --     place at ref3
1004
1005       Imported_Lang : Name_Id := No_Name;
1006       Imported_Name : Name_Id := No_Name;
1007       --  Language and name of imported entity reference
1008    end record;
1009
1010    package Xref is new Table.Table (
1011      Table_Component_Type => Xref_Record,
1012      Table_Index_Type     => Nat,
1013      Table_Low_Bound      => 1,
1014      Table_Initial        => 2000,
1015      Table_Increment      => 300,
1016      Table_Name           => "Xref");
1017
1018    --------------------------------------
1019    -- Subprograms for Reading ALI File --
1020    --------------------------------------
1021
1022    procedure Initialize_ALI;
1023    --  Initialize the ALI tables. Also resets all switch values to defaults
1024
1025    function Scan_ALI
1026      (F                : File_Name_Type;
1027       T                : Text_Buffer_Ptr;
1028       Ignore_ED        : Boolean;
1029       Err              : Boolean;
1030       Read_Xref        : Boolean := False;
1031       Read_Lines       : String  := "";
1032       Ignore_Lines     : String  := "X";
1033       Ignore_Errors    : Boolean := False;
1034       Directly_Scanned : Boolean := False) return ALI_Id;
1035    --  Given the text, T, of an ALI file, F, scan and store the information
1036    --  from the file, and return the Id of the resulting entry in the ALI
1037    --  table. Switch settings may be modified as described above in the
1038    --  switch description settings.
1039    --
1040    --    Ignore_ED is normally False. If set to True, it indicates that
1041    --    all AD/ED (elaboration desirable) indications in the ALI file are
1042    --    to be ignored. This parameter is obsolete now that the -f switch
1043    --    is removed from gnatbind, and should be removed ???
1044    --
1045    --    Err determines the action taken on an incorrectly formatted file.
1046    --    If Err is False, then an error message is output, and the program
1047    --    is terminated. If Err is True, then no error message is output,
1048    --    and No_ALI_Id is returned.
1049    --
1050    --    Ignore_Lines requests that Scan_ALI ignore any lines that start
1051    --    with any given key character. The default value of X causes all
1052    --    Xref lines to be ignored. The corresponding data in the ALI
1053    --    tables will not be filled in this case. It is not possible
1054    --    to ignore U (unit) lines, they are always read.
1055    --
1056    --    Read_Lines requests that Scan_ALI process only lines that start
1057    --    with one of the given characters. The corresponding data in the
1058    --    ALI file for any characters not given in the list will not be
1059    --    set. The default value of the null string indicates that all
1060    --    lines should be read (unless Ignore_Lines is specified). U
1061    --    (unit) lines are always read regardless of the value of this
1062    --    parameter.
1063    --
1064    --    Note: either Ignore_Lines or Read_Lines should be non-null, but not
1065    --    both. If both are provided then only the Read_Lines value is used,
1066    --    and the Ignore_Lines parameter is ignored.
1067    --
1068    --    Read_XREF is set True to read and acquire the cross-reference
1069    --    information. If Read_XREF is set to True, then the effect is to ignore
1070    --    all lines other than U, W, D and X lines and the Ignore_Lines and
1071    --    Read_Lines parameters are ignored (i.e. the use of True for Read_XREF
1072    --    is equivalent to specifying an argument of "UWDX" for Read_Lines.
1073    --
1074    --    Ignore_Errors is normally False. If it is set True, then Scan_ALI
1075    --    will do its best to scan through a file and extract all information
1076    --    it can, even if there are errors. In this case Err is only set if
1077    --    Scan_ALI was completely unable to process the file (e.g. it did not
1078    --    look like an ALI file at all). Ignore_Errors is intended to improve
1079    --    the downward compatibility of new compilers with old tools.
1080    --
1081    --    Directly_Scanned is normally False. If it is set to True, then the
1082    --    units (spec and/or body) corresponding to the ALI file are marked as
1083    --    such. It is used to decide for what units gnatbind should generate
1084    --    the symbols corresponding to 'Version or 'Body_Version in
1085    --    Stand-Alone Libraries.
1086
1087 end ALI;