libstdc++-v3/acinclude.m4

   1 dnl
   2 dnl Initialize basic configure bits, set toplevel_srcdir for Makefiles.
   3 dnl
   4 dnl GLIBCPP_TOPREL_CONFIGURE
   5 AC_DEFUN(GLIBCPP_TOPREL_CONFIGURE, [
   6   dnl Default to --enable-multilib (this is also passed by default
   7   dnl from the ubercommon-top-level configure)
   8   AC_ARG_ENABLE(multilib,
   9   [  --enable-multilib       build hella library versions (default)],
  10   [case "${enableval}" in
  11     yes) multilib=yes ;;
  12     no)  multilib=no ;;
  13     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  14    esac], [multilib=yes])dnl
  15
  16   # When building with srcdir == objdir, links to the source files will
  17   # be created in directories within the target_subdir.  We have to
  18   # adjust toplevel_srcdir accordingly, so that configure finds
  19   # install-sh and other auxiliary files that live in the top-level
  20   # source directory.
  21   if test "${srcdir}" = "."; then
  22     if test -z "${with_target_subdir}"; then
  23       toprel=".."
  24     else
  25       if test "${with_target_subdir}" != "."; then
  26         toprel="${with_multisrctop}../.."
  27       else
  28         toprel="${with_multisrctop}.."
  29       fi
  30     fi
  31   else
  32     toprel=".."
  33   fi
  34   AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  35   toplevel_srcdir=\${top_srcdir}/$toprel
  36   AC_SUBST(toplevel_srcdir)
  37 ])
  38
  39 dnl
  40 dnl Initialize the rest of the library configury.
  41 dnl
  42 dnl GLIBCPP_CONFIGURE
  43 AC_DEFUN(GLIBCPP_CONFIGURE, [
  44   # Export build and source directories.
  45   # These need to be absolute paths, yet at the same time need to
  46   # canonicalize only relative paths, because then amd will not unmount
  47   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  48   glibcpp_builddir=`${PWDCMD-pwd}`
  49   case $srcdir in
  50   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  51   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  52   esac
  53   AC_SUBST(glibcpp_builddir)
  54   AC_SUBST(glibcpp_srcdir)
  55
  56   dnl This is here just to satisfy automake.
  57   ifelse(not,equal,[AC_CONFIG_AUX_DIR(..)])
  58
  59   AC_PROG_AWK
  60   # Will set LN_S to either 'ln -s' or 'ln'.  With autoconf 2.5x, can also
  61   # be 'cp -p' if linking isn't available.  Uncomment the next line to
  62   # force a particular method.
  63   #ac_cv_prog_LN_S='cp -p'
  64   AC_PROG_LN_S
  65
  66   # We use these options to decide which functions to include.
  67   AC_ARG_WITH(target-subdir,
  68   [  --with-target-subdir=SUBDIR
  69                           configuring in a subdirectory])
  70   AC_ARG_WITH(cross-host,
  71   [  --with-cross-host=HOST  configuring with a cross compiler])
  72
  73   glibcpp_basedir=$srcdir/$toprel/$1/libstdc++-v3
  74   AC_SUBST(glibcpp_basedir)
  75
  76   # Never versions of autoconf add an underscore to these functions.
  77   # Prevent future problems ...
  78   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  79   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  80   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  81   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  82
  83   # AC_PROG_CC
  84   # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  85   # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  86   # are probably using a cross compiler, which will not be able to fully
  87   # link an executable.  This is addressed in later versions of autoconf.
  88
  89   AC_DEFUN(LIB_AC_PROG_CC,
  90   [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  91   dnl Fool anybody using AC_PROG_CC.
  92   AC_PROVIDE([AC_PROG_CC])
  93   AC_CHECK_PROG(CC, gcc, gcc)
  94   if test -z "$CC"; then
  95     AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  96     test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  97   fi
  98
  99   AC_PROG_CC_GNU
 100
 101   if test $ac_cv_prog_gcc = yes; then
 102     GCC=yes
 103   dnl Check whether -g works, even if CFLAGS is set, in case the package
 104   dnl plays around with CFLAGS (such as to build both debugging and
 105   dnl normal versions of a library), tasteless as that idea is.
 106     ac_test_CFLAGS="${CFLAGS+set}"
 107     ac_save_CFLAGS="$CFLAGS"
 108     CFLAGS=
 109     AC_PROG_CC_G
 110     if test "$ac_test_CFLAGS" = set; then
 111       CFLAGS="$ac_save_CFLAGS"
 112     elif test $ac_cv_prog_cc_g = yes; then
 113       CFLAGS="-g -O2"
 114     else
 115       CFLAGS="-O2"
 116     fi
 117   else
 118     GCC=
 119     test "${CFLAGS+set}" = set || CFLAGS="-g"
 120   fi
 121   ])
 122
 123   LIB_AC_PROG_CC
 124
 125   # Likewise for AC_PROG_CXX.  We can't just call it directly because g++
 126   # will try to link in libstdc++.
 127   AC_DEFUN(LIB_AC_PROG_CXX,
 128   [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 129   dnl Fool anybody using AC_PROG_CXX.
 130   AC_PROVIDE([AC_PROG_CXX])
 131   # Use glibcpp_CXX so that we do not cause CXX to be cached with the
 132   # flags that come in CXX while configuring libstdc++.  They're different
 133   # from those used for all other target libraries.  If CXX is set in
 134   # the environment, respect that here.
 135   glibcpp_CXX=$CXX
 136   AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
 137   AC_SUBST(glibcpp_CXX)
 138   CXX=$glibcpp_CXX
 139   test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 140
 141   AC_PROG_CXX_GNU
 142
 143   if test $ac_cv_prog_gxx = yes; then
 144     GXX=yes
 145     dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 146     dnl plays around with CXXFLAGS (such as to build both debugging and
 147     dnl normal versions of a library), tasteless as that idea is.
 148     ac_test_CXXFLAGS="${CXXFLAGS+set}"
 149     ac_save_CXXFLAGS="$CXXFLAGS"
 150     CXXFLAGS=
 151     AC_PROG_CXX_G
 152     if test "$ac_test_CXXFLAGS" = set; then
 153       CXXFLAGS="$ac_save_CXXFLAGS"
 154     elif test $ac_cv_prog_cxx_g = yes; then
 155       CXXFLAGS="-g -O2"
 156     else
 157       CXXFLAGS="-O2"
 158     fi
 159   else
 160     GXX=
 161     test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 162   fi
 163   ])
 164
 165   LIB_AC_PROG_CXX
 166
 167   # For directory versioning (e.g., headers) and other variables.
 168   AC_MSG_CHECKING([for GCC version number])
 169   gcc_version=`$glibcpp_CXX -dumpversion`
 170   AC_MSG_RESULT($gcc_version)
 171
 172   # For some reason, gettext needs this.
 173   AC_ISC_POSIX
 174
 175   AC_CHECK_TOOL(AS, as)
 176   AC_CHECK_TOOL(AR, ar)
 177   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 178   AC_PROG_INSTALL
 179
 180   AM_MAINTAINER_MODE
 181
 182   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 183   # at least currently, we never actually build a program, so we never
 184   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 185   # fails, because we are probably configuring with a cross compiler
 186   # which can't create executables.  So we include AC_EXEEXT to keep
 187   # automake happy, but we don't execute it, since we don't care about
 188   # the result.
 189   if false; then
 190     # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
 191     # to nothing, so nothing would remain between `then' and `fi' if it
 192     # were not for the `:' below.
 193     :
 194     AC_EXEEXT
 195   fi
 196
 197   case [$]{glibcpp_basedir} in
 198     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 199     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 200   esac
 201
 202   # Find platform-specific directories containing configuration info.  In
 203   # addition to possibly modifying the same flags, it also sets up symlinks.
 204   GLIBCPP_CHECK_TARGET
 205 ])
 206
 207
 208 dnl
 209 dnl Check to see if g++ can compile this library, and if so, if any version-
 210 dnl specific precautions need to be taken.
 211 dnl
 212 dnl GLIBCPP_CHECK_COMPILER_VERSION
 213 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 214 if test ! -f stamp-sanity-compiler; then
 215   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 216   AC_LANG_SAVE
 217   AC_LANG_CPLUSPLUS
 218   AC_TRY_COMPILE(, [
 219   #if __GNUC__ < 3
 220     not_ok
 221   #endif
 222   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 223   AC_LANG_RESTORE
 224   AC_MSG_RESULT($gpp_satisfactory)
 225   touch stamp-sanity-compiler
 226 fi
 227 ])
 228
 229
 230 dnl
 231 dnl Tests for newer compiler features, or features that are present in newer
 232 dnl compiler versions but not older compiler versions still in use, should
 233 dnl be placed here.
 234 dnl
 235 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 236 dnl new inlining code or the new system_header pragma will die on -Werror.
 237 dnl Leave it out by default and use maint-mode to use it.
 238 dnl
 239 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 240 dnl compiler supports it and the user has not requested debug mode.
 241 dnl
 242 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 243 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 244   # All these tests are for C++; save the language and the compiler flags.
 245   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 246   # found in GLIBCPP_CONFIGURE.
 247   AC_LANG_SAVE
 248   AC_LANG_CPLUSPLUS
 249   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 250   ac_save_CXXFLAGS="$CXXFLAGS"
 251
 252   # Check for maintainer-mode bits.
 253   if test x"$USE_MAINTAINER_MODE" = xno; then
 254     WERROR=''
 255   else
 256     WERROR='-Werror'
 257   fi
 258
 259   # Check for -ffunction-sections -fdata-sections
 260   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 261   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 262   AC_TRY_COMPILE(, [int foo;
 263   ], [ac_fdsections=yes], [ac_fdsections=no])
 264   if test "$ac_test_CXXFLAGS" = set; then
 265     CXXFLAGS="$ac_save_CXXFLAGS"
 266   else
 267     # this is the suspicious part
 268     CXXFLAGS=''
 269   fi
 270   if test x"$ac_fdsections" = x"yes" &&
 271      test x"$enable_debug" = x"no"; then
 272     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 273   fi
 274   AC_MSG_RESULT($ac_fdsections)
 275
 276   AC_LANG_RESTORE
 277   AC_SUBST(WERROR)
 278   AC_SUBST(SECTION_FLAGS)
 279 ])
 280
 281
 282 dnl
 283 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 284 dnl the native linker is in use, all variables will be defined to something
 285 dnl safe (like an empty string).
 286 dnl
 287 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 288 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 289 dnl Define LD, with_gnu_ld, and (possibly) glibcpp_gnu_ld_version as
 290 dnl side-effects of testing.
 291 dnl
 292 dnl GLIBCPP_CHECK_LINKER_FEATURES
 293 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 294   # If we're not using GNU ld, then there's no point in even trying these
 295   # tests.  Check for that first.  We should have already tested for gld
 296   # by now (in libtool), but require it now just to be safe...
 297   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 298   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 299   AC_REQUIRE([AC_PROG_LD])
 300
 301   # The name set by libtool depends on the version of libtool.  Shame on us
 302   # for depending on an impl detail, but c'est la vie.  Older versions used
 303   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 304   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 305   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 306   # set (hence we're using an older libtool), then set it.
 307   if test x${with_gnu_ld+set} != xset; then
 308     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 309       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 310       with_gnu_ld=no
 311     else
 312       with_gnu_ld=$ac_cv_prog_gnu_ld
 313     fi
 314   fi
 315
 316   # Start by getting the version number.  I think the libtool test already
 317   # does some of this, but throws away the result.
 318   changequote(,)
 319   ldver=`$LD --version 2>/dev/null | head -1 | \
 320          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 321   changequote([,])
 322   glibcpp_gnu_ld_version=`echo $ldver | \
 323          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 324
 325   # Set --gc-sections.
 326   if test "$with_gnu_ld" = "notbroken"; then
 327     # GNU ld it is!  Joy and bunny rabbits!
 328
 329     # All these tests are for C++; save the language and the compiler flags.
 330     # Need to do this so that g++ won't try to link in libstdc++
 331     ac_test_CFLAGS="${CFLAGS+set}"
 332     ac_save_CFLAGS="$CFLAGS"
 333     CFLAGS='-x c++  -Wl,--gc-sections'
 334
 335     # Check for -Wl,--gc-sections
 336     # XXX This test is broken at the moment, as symbols required for
 337     # linking are now in libsupc++ (not built yet.....). In addition,
 338     # this test has cored on solaris in the past. In addition,
 339     # --gc-sections doesn't really work at the moment (keeps on discarding
 340     # used sections, first .eh_frame and now some of the glibc sections for
 341     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 342     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 343     AC_TRY_RUN([
 344      int main(void)
 345      {
 346        try { throw 1; }
 347        catch (...) { };
 348        return 0;
 349      }
 350     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 351     if test "$ac_test_CFLAGS" = set; then
 352       CFLAGS="$ac_save_CFLAGS"
 353     else
 354       # this is the suspicious part
 355       CFLAGS=''
 356     fi
 357     if test "$ac_sectionLDflags" = "yes"; then
 358       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 359     fi
 360     AC_MSG_RESULT($ac_sectionLDflags)
 361   fi
 362
 363   # Set linker optimization flags.
 364   if test x"$with_gnu_ld" = x"yes" && test x"$enable_debug" = x"no"; then
 365     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 366   fi
 367
 368   AC_SUBST(SECTION_LDFLAGS)
 369   AC_SUBST(OPT_LDFLAGS)
 370 ])
 371
 372
 373 dnl
 374 dnl Check to see if the (math function) argument passed is
 375 dnl declared when using the c++ compiler
 376 dnl ASSUMES argument is a math function with ONE parameter
 377 dnl
 378 dnl GLIBCPP_CHECK_MATH_DECL_1
 379 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 380   AC_MSG_CHECKING([for $1 declaration])
 381   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 382     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 383       AC_LANG_SAVE
 384       AC_LANG_CPLUSPLUS
 385       AC_TRY_COMPILE([#include <math.h>
 386                       #ifdef HAVE_IEEEFP_H
 387                       #include <ieeefp.h>
 388                       #endif
 389                      ],
 390                      [ $1(0);],
 391                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 392       AC_LANG_RESTORE
 393     ])
 394   fi
 395   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 396 ])
 397
 398 dnl
 399 dnl Check to see if the (math function) argument passed is
 400 dnl 1) declared when using the c++ compiler
 401 dnl 2) has "C" linkage
 402 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 403 dnl
 404 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 405 dnl
 406 dnl argument 1 is name of function to check
 407 dnl
 408 dnl ASSUMES argument is a math function with ONE parameter
 409 dnl
 410 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 411 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 412   GLIBCPP_CHECK_MATH_DECL_1($1)
 413   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 414     AC_CHECK_FUNCS($1)
 415   else
 416     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 417     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 418       AC_CHECK_FUNCS(_$1)
 419     fi
 420   fi
 421 ])
 422
 423
 424 dnl
 425 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 426 dnl of functions at once.  It's an all-or-nothing check -- either
 427 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 428 dnl Doing it this way saves significant configure time.
 429 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 430   AC_MSG_CHECKING([for $1 functions])
 431   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 432     AC_LANG_SAVE
 433     AC_LANG_CPLUSPLUS
 434     AC_TRY_COMPILE([#include <math.h>],
 435                    [ `for x in $3; do echo "$x (0);"; done` ],
 436                    [glibcpp_cv_func_$2_use=yes],
 437                    [glibcpp_cv_func_$2_use=no])
 438     AC_LANG_RESTORE])
 439   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 440   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 441     AC_CHECK_FUNCS($3)
 442   fi
 443 ])
 444
 445 dnl
 446 dnl Check to see if the (math function) argument passed is
 447 dnl declared when using the c++ compiler
 448 dnl ASSUMES argument is a math function with TWO parameters
 449 dnl
 450 dnl GLIBCPP_CHECK_MATH_DECL_2
 451 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 452   AC_MSG_CHECKING([for $1 declaration])
 453   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 454     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 455       AC_LANG_SAVE
 456       AC_LANG_CPLUSPLUS
 457       AC_TRY_COMPILE([#include <math.h>],
 458                      [ $1(0, 0);],
 459                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 460       AC_LANG_RESTORE
 461     ])
 462   fi
 463   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 464 ])
 465
 466 dnl
 467 dnl Check to see if the (math function) argument passed is
 468 dnl 1) declared when using the c++ compiler
 469 dnl 2) has "C" linkage
 470 dnl
 471 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 472 dnl
 473 dnl argument 1 is name of function to check
 474 dnl
 475 dnl ASSUMES argument is a math function with TWO parameters
 476 dnl
 477 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 478 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 479   GLIBCPP_CHECK_MATH_DECL_2($1)
 480   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 481     AC_CHECK_FUNCS($1)
 482   else
 483     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 484     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 485       AC_CHECK_FUNCS(_$1)
 486     fi
 487   fi
 488 ])
 489
 490
 491 dnl
 492 dnl Check to see if the (math function) argument passed is
 493 dnl declared when using the c++ compiler
 494 dnl ASSUMES argument is a math function with THREE parameters
 495 dnl
 496 dnl GLIBCPP_CHECK_MATH_DECL_3
 497 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 498   AC_MSG_CHECKING([for $1 declaration])
 499   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 500     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 501       AC_LANG_SAVE
 502       AC_LANG_CPLUSPLUS
 503       AC_TRY_COMPILE([#include <math.h>],
 504                      [ $1(0, 0, 0);],
 505                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 506       AC_LANG_RESTORE
 507     ])
 508   fi
 509   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 510 ])
 511
 512 dnl
 513 dnl Check to see if the (math function) argument passed is
 514 dnl 1) declared when using the c++ compiler
 515 dnl 2) has "C" linkage
 516 dnl
 517 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 518 dnl
 519 dnl argument 1 is name of function to check
 520 dnl
 521 dnl ASSUMES argument is a math function with THREE parameters
 522 dnl
 523 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 524 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 525   GLIBCPP_CHECK_MATH_DECL_3($1)
 526   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 527     AC_CHECK_FUNCS($1)
 528   else
 529     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 530     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 531       AC_CHECK_FUNCS(_$1)
 532     fi
 533   fi
 534 ])
 535
 536
 537 dnl
 538 dnl Check to see if the (stdlib function) argument passed is
 539 dnl 1) declared when using the c++ compiler
 540 dnl 2) has "C" linkage
 541 dnl
 542 dnl argument 1 is name of function to check
 543 dnl
 544 dnl ASSUMES argument is a math function with TWO parameters
 545 dnl
 546 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 547 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 548   AC_MSG_CHECKING([for $1 declaration])
 549   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 550     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 551       AC_LANG_SAVE
 552       AC_LANG_CPLUSPLUS
 553       AC_TRY_COMPILE([#include <stdlib.h>],
 554                      [ $1(0, 0);],
 555                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 556       AC_LANG_RESTORE
 557     ])
 558   fi
 559   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 560   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 561     AC_CHECK_FUNCS($1)
 562   fi
 563 ])
 564
 565
 566 dnl
 567 dnl Check to see if the (stdlib function) argument passed is
 568 dnl 1) declared when using the c++ compiler
 569 dnl 2) has "C" linkage
 570 dnl
 571 dnl argument 1 is name of function to check
 572 dnl
 573 dnl ASSUMES argument is a function with THREE parameters
 574 dnl
 575 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3
 576 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3, [
 577   AC_MSG_CHECKING([for $1 declaration])
 578   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 579     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 580       AC_LANG_SAVE
 581       AC_LANG_CPLUSPLUS
 582       AC_TRY_COMPILE([#include <stdlib.h>],
 583                      [ $1(0, 0, 0);],
 584                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 585       AC_LANG_RESTORE
 586     ])
 587   fi
 588   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 589   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 590     AC_CHECK_FUNCS($1)
 591   fi
 592 ])
 593
 594
 595 dnl
 596 dnl Because the builtins are picky picky picky about the arguments they take,
 597 dnl do an explict linkage tests here.
 598 dnl Check to see if the (math function) argument passed is
 599 dnl 1) declared when using the c++ compiler
 600 dnl 2) has "C" linkage
 601 dnl
 602 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 603 dnl
 604 dnl argument 1 is name of function to check
 605 dnl
 606 dnl ASSUMES argument is a math function with ONE parameter
 607 dnl
 608 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 609 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 610   AC_MSG_CHECKING([for $1 declaration])
 611   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 612     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 613       AC_LANG_SAVE
 614       AC_LANG_CPLUSPLUS
 615       AC_TRY_COMPILE([#include <math.h>],
 616                      [ $1(0);],
 617                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 618       AC_LANG_RESTORE
 619     ])
 620   fi
 621   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 622   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 623     AC_MSG_CHECKING([for $1 linkage])
 624     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 625       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 626         AC_TRY_LINK([#include <math.h>],
 627                     [ $1(0);],
 628                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 629       ])
 630     fi
 631     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 632     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 633       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 634       AC_DEFINE_UNQUOTED(${ac_tr_func})
 635     fi
 636   fi
 637 ])
 638
 639
 640 dnl
 641 dnl Check to see what builtin math functions are supported
 642 dnl
 643 dnl check for __builtin_abs
 644 dnl check for __builtin_fabsf
 645 dnl check for __builtin_fabs
 646 dnl check for __builtin_fabl
 647 dnl check for __builtin_labs
 648 dnl check for __builtin_sqrtf
 649 dnl check for __builtin_sqrtl
 650 dnl check for __builtin_sqrt
 651 dnl check for __builtin_sinf
 652 dnl check for __builtin_sin
 653 dnl check for __builtin_sinl
 654 dnl check for __builtin_cosf
 655 dnl check for __builtin_cos
 656 dnl check for __builtin_cosl
 657 dnl
 658 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 659 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 660   dnl Test for builtin math functions.
 661   dnl These are made in gcc/c-common.c
 662   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 663   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 664   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 665   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 666   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 667
 668   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 669   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrt)
 670   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 671
 672   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 673   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 674   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 675
 676   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 677   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 678   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 679
 680   dnl There is, without a doubt, a more elegant way to have these
 681   dnl names exported so that they won't be stripped out of acconfig.h by
 682   dnl autoheader. I leave this as an exercise to somebody less frustrated
 683   dnl than I.... please email the libstdc++ list if you can figure out a
 684   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 685   dnl AC_CHECK_FUNC for things to steal.)
 686   dummyvar=no
 687   if test x$dummyvar = x"yes"; then
 688     AC_DEFINE(HAVE___BUILTIN_ABS)
 689     AC_DEFINE(HAVE___BUILTIN_LABS)
 690     AC_DEFINE(HAVE___BUILTIN_COS)
 691     AC_DEFINE(HAVE___BUILTIN_COSF)
 692     AC_DEFINE(HAVE___BUILTIN_COSL)
 693     AC_DEFINE(HAVE___BUILTIN_FABS)
 694     AC_DEFINE(HAVE___BUILTIN_FABSF)
 695     AC_DEFINE(HAVE___BUILTIN_FABSL)
 696     AC_DEFINE(HAVE___BUILTIN_SIN)
 697     AC_DEFINE(HAVE___BUILTIN_SINF)
 698     AC_DEFINE(HAVE___BUILTIN_SINL)
 699     AC_DEFINE(HAVE___BUILTIN_SQRT)
 700     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 701     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 702   fi
 703 ])
 704
 705
 706 dnl
 707 dnl Check to see what the underlying c library
 708 dnl These checks need to do two things:
 709 dnl 1) make sure the name is declared when using the c++ compiler
 710 dnl 2) make sure the name has "C" linkage
 711 dnl This might seem like overkill but experience has shown that it's not...
 712 dnl
 713 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 714 dnl Define HAVE_STRTOF if "strtof" is declared and links
 715 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 716 dnl
 717 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 718 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 719   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 720   ac_save_CXXFLAGS="$CXXFLAGS"
 721   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 722
 723   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 724   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtof)
 725   AC_CHECK_FUNCS(drand48)
 726
 727   CXXFLAGS="$ac_save_CXXFLAGS"
 728 ])
 729
 730
 731 dnl
 732 dnl Check to see what the underlying c library or math library is like.
 733 dnl These checks need to do two things:
 734 dnl 1) make sure the name is declared when using the c++ compiler
 735 dnl 2) make sure the name has "C" linkage
 736 dnl This might seem like overkill but experience has shown that it's not...
 737 dnl
 738 dnl Define HAVE_CARGF etc if "cargf" is found.
 739 dnl
 740 dnl GLIBCPP_CHECK_MATH_SUPPORT
 741 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 742   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 743   ac_save_CXXFLAGS="$CXXFLAGS"
 744   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 745
 746   dnl Check libm
 747   AC_CHECK_LIB(m, sin, libm="-lm")
 748   ac_save_LIBS="$LIBS"
 749   LIBS="$LIBS $libm"
 750
 751   dnl Check to see if certain C math functions exist.
 752   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 753   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 754   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 755   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 756   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 757   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 758   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 759   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypot)
 760
 761   dnl Check to see if basic C math functions have float versions.
 762   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 763                                           float_trig,
 764                                           acosf asinf atanf \
 765                                           cosf sinf tanf \
 766                                           coshf sinhf tanhf)
 767   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 768                                           float_round,
 769                                           ceilf floorf)
 770   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expf)
 771   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 772   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 773   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 774   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 775   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 776   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 777   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotf)
 778   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 779   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 780   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 781   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 782   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 783   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 784   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 785   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 786
 787   dnl Check to see if basic C math functions have long double versions.
 788   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 789                                           long_double_trig,
 790                                           acosl asinl atanl \
 791                                           cosl sinl tanl \
 792                                           coshl sinhl tanhl)
 793   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 794                                           long_double_round,
 795                                           ceill floorl)
 796   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 797   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 798   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 799   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 800   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 801   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 802   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 803   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 804   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotl)
 805   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 806   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 807   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 808   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 809   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 810   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 811   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 812   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 813
 814   dnl Some runtimes have these functions with a preceding underscore. Please
 815   dnl keep this sync'd with the one above. And if you add any new symbol,
 816   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 817   dnl Check to see if certain C math functions exist.
 818
 819   dnl Check to see if basic C math functions have float versions.
 820   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 821                                           _float_trig,
 822                                           _acosf _asinf _atanf \
 823                                           _cosf _sinf _tanf \
 824                                           _coshf _sinhf _tanhf)
 825   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 826                                           _float_round,
 827                                           _ceilf _floorf)
 828
 829   dnl Check to see if basic C math functions have long double versions.
 830   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 831                                           _long_double_trig,
 832                                           _acosl _asinl _atanl \
 833                                           _cosl _sinl _tanl \
 834                                           _coshl _sinhl _tanhl)
 835   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 836                                           _long_double_round,
 837                                           _ceill _floorl)
 838
 839   LIBS="$ac_save_LIBS"
 840   CXXFLAGS="$ac_save_CXXFLAGS"
 841 ])
 842
 843
 844 dnl
 845 dnl Check to see if there is native support for complex
 846 dnl
 847 dnl Don't compile bits in math/* if native support exits.
 848 dnl
 849 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "copysignl" is found.
 850 dnl
 851 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 852 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 853   dnl Check for complex versions of math functions of platform.
 854   AC_CHECK_LIB(m, main)
 855   AC_REPLACE_MATHFUNCS(nan copysignf)
 856
 857   dnl For __signbit to signbit conversions.
 858   AC_CHECK_FUNCS([__signbit], , [LIBMATHOBJS="$LIBMATHOBJS signbit.lo"])
 859   AC_CHECK_FUNCS([__signbitf], , [LIBMATHOBJS="$LIBMATHOBJS signbitf.lo"])
 860
 861   dnl Compile the long double complex functions only if the function
 862   dnl provides the non-complex long double functions that are needed.
 863   dnl Currently this includes copysignl, which should be
 864   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 865   if test x$ac_cv_func_copysignl = x"yes"; then
 866     AC_CHECK_FUNCS([__signbitl], , [LIBMATHOBJS="$LIBMATHOBJS signbitl.lo"])
 867   fi
 868
 869   AC_SUBST(LIBMATHOBJS)
 870 ])
 871
 872
 873 dnl Check to see what architecture and operating system we are compiling
 874 dnl for.  Also, if architecture- or OS-specific flags are required for
 875 dnl compilation, pick them up here.
 876 dnl
 877 dnl GLIBCPP_CHECK_TARGET
 878 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 879     . [$]{glibcpp_basedir}/configure.target
 880     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 881     AC_MSG_RESULT(OS config directory is $os_include_dir)
 882 ])
 883
 884
 885 dnl
 886 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 887 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 888 dnl must have been previously checked.)
 889 dnl
 890 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 891 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 892 dnl
 893 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 894 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 895
 896   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 897   dnl others even if wchar_t support is not on.
 898   AC_MSG_CHECKING([for mbstate_t])
 899   AC_TRY_COMPILE([#include <wchar.h>],
 900   [mbstate_t teststate;],
 901   have_mbstate_t=yes, have_mbstate_t=no)
 902   AC_MSG_RESULT($have_mbstate_t)
 903   if test x"$have_mbstate_t" = xyes; then
 904     AC_DEFINE(HAVE_MBSTATE_T)
 905   fi
 906
 907   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 908   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 909   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 910
 911   dnl Only continue checking if the ISO C99 headers exist and support is on.
 912   if test x"$ac_has_wchar_h" = xyes &&
 913      test x"$ac_has_wctype_h" = xyes &&
 914      test x"$enable_c_mbchar" != xno; then
 915
 916     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 917     dnl numeric_limits can instantiate type_traits<wchar_t>
 918     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 919     AC_TRY_COMPILE([#include <wchar.h>],
 920     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 921     has_wchar_minmax=yes, has_wchar_minmax=no)
 922     AC_MSG_RESULT($has_wchar_minmax)
 923
 924     dnl Test wchar.h for WEOF, which is what we use to determine whether
 925     dnl to specialize for char_traits<wchar_t> or not.
 926     AC_MSG_CHECKING([for WEOF])
 927     AC_TRY_COMPILE([
 928       #include <wchar.h>
 929       #include <stddef.h>],
 930     [wint_t i = WEOF;],
 931     has_weof=yes, has_weof=no)
 932     AC_MSG_RESULT($has_weof)
 933
 934     dnl Tests for wide character functions used in char_traits<wchar_t>.
 935     ac_wfuncs=yes
 936     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset,, \
 937     ac_wfuncs=no)
 938
 939     dnl Checks for names injected into std:: by the c_std headers.
 940     AC_CHECK_FUNCS(btowc wctob fgetwc fgetwc fgetws fputwc fputws fwide \
 941     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 942     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 943     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 944     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 945     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr,, \
 946     ac_wfuncs=no)
 947
 948     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 949     if test x"$has_weof" = xyes &&
 950        test x"$has_wchar_minmax" = xyes &&
 951        test x"$ac_wfuncs" = xyes; then
 952       ac_isoC99_wchar_t=yes
 953     else
 954       ac_isoC99_wchar_t=no
 955     fi
 956     AC_MSG_RESULT($ac_isoC99_wchar_t)
 957
 958     dnl Use iconv for wchar_t to char conversions. As such, check for
 959     dnl X/Open Portability Guide, version 2 features (XPG2).
 960     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 961     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 962
 963     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 964     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 965     ac_save_LIBS="$LIBS"
 966     LIBS="$LIBS $libiconv"
 967
 968     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 969     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 970
 971     LIBS="$ac_save_LIBS"
 972
 973     AC_MSG_CHECKING([for XPG2 wchar_t support])
 974     if test x"$ac_has_iconv_h" = xyes &&
 975        test x"$ac_has_langinfo_h" = xyes &&
 976        test x"$ac_XPG2funcs" = xyes; then
 977       ac_XPG2_wchar_t=yes
 978     else
 979       ac_XPG2_wchar_t=no
 980     fi
 981     AC_MSG_RESULT($ac_XPG2_wchar_t)
 982
 983     dnl At the moment, only enable wchar_t specializations if all the
 984     dnl above support is present.
 985     AC_MSG_CHECKING([for enabled wchar_t specializations])
 986     if test x"$ac_isoC99_wchar_t" = xyes &&
 987        test x"$ac_XPG2_wchar_t" = xyes; then
 988       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
 989       AC_MSG_RESULT("yes")
 990     else
 991       AC_MSG_RESULT("no")
 992     fi
 993   else
 994     dnl Wide characters disabled by the user.
 995     AC_MSG_WARN([wchar_t support disabled.])
 996   fi
 997 ])
 998
 999
1000 dnl
1001 dnl Check for special debugging mode; not for production use.
1002 dnl
1003 dnl GLIBCPP_ENABLE_DEBUG
1004 dnl --enable-debug sets '-ggdb3 -O0'.
1005 dnl --disable-debug sets '-g' and whatever optimization options the
1006 dnl     compiler can handle.
1007 dnl  +  --enable-maintainer-mode automatically defaults this to on.
1008 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
1009 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
1010 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1011 dnl       defaults to `no'.
1012 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
1013 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
1014 AC_ARG_ENABLE(debug,
1015 changequote(<<, >>)dnl
1016 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
1017 changequote([, ])dnl
1018 [case "${enableval}" in
1019  yes) enable_debug=yes ;;
1020  no)  enable_debug=no ;;
1021  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
1022  esac],
1023 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
1024
1025 dnl Option parsed, now set things appropriately
1026 case "${enable_debug}" in
1027     yes)
1028         DEBUG_FLAGS='-O0 -ggdb3'
1029         ;;
1030     no)
1031         DEBUG_FLAGS='-g'
1032         ;;
1033 esac
1034 AC_SUBST(DEBUG_FLAGS)
1035 ])
1036
1037
1038 dnl
1039 dnl Check for "unusual" flags to pass to the compiler while building.
1040 dnl
1041 dnl GLIBCPP_ENABLE_CXX_FLAGS
1042 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1043 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
1044 dnl     Somehow this same set of flags must be passed when [re]building
1045 dnl     libgcc.
1046 dnl --disable-cxx-flags passes nothing.
1047 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1048 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1049 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1050 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
1051 dnl       If "default flags" is an empty string (or "none"), the effect is
1052 dnl       the same as --disable or --enable=no.
1053 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
1054 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1055 AC_ARG_ENABLE(cxx-flags,
1056 changequote(<<, >>)dnl
1057 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
1058                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
1059 changequote([, ])dnl
1060 [case "x$enableval" in
1061  xyes)
1062         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
1063  xno|x)
1064         enable_cxx_flags='' ;;
1065  *)
1066         enable_cxx_flags="$enableval" ;;
1067  esac],
1068 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
1069
1070 dnl Thinko on my part during design.  This kludge is the workaround.
1071 if test "$enable_cxx_flags" = "none"; then
1072   enable_cxx_flags='';
1073 fi
1074
1075 dnl Run through flags (either default or command-line) and set anything
1076 dnl extra (e.g., #defines) that must accompany particular g++ options.
1077 if test -n "$enable_cxx_flags"; then
1078     for f in $enable_cxx_flags; do
1079         case "$f" in
1080             -fhonor-std)  ;;
1081             -*)  ;;
1082             *)   # and we're trying to pass /what/ exactly?
1083                  AC_MSG_ERROR([compiler flags start with a -]) ;;
1084         esac
1085     done
1086 fi
1087 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1088 AC_SUBST(EXTRA_CXX_FLAGS)
1089 ])
1090
1091
1092 dnl
1093 dnl Check for which locale library to use:  gnu or generic.
1094 dnl
1095 dnl GLIBCPP_ENABLE_CLOCALE
1096 dnl --enable-clocale=gnu sets config/locale/c_locale_gnu.cc and friends
1097 dnl --enable-clocale=generic sets config/locale/c_locale_generic.cc and friends
1098 dnl
1099 dnl default is generic
1100 dnl
1101 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
1102   AC_MSG_CHECKING([for clocale to use])
1103   AC_ARG_ENABLE(clocale,
1104   [  --enable-clocale        enable model for target locale package.
1105   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
1106   ],
1107   if test x$enable_clocale = xno; then
1108      enable_clocale=no
1109   fi,
1110      enable_clocale=no)
1111
1112   enable_clocale_flag=$enable_clocale
1113
1114   dnl Probe for locale support if no specific model is specified.
1115   dnl Default to "generic"
1116   if test x$enable_clocale_flag = xno; then
1117     case x${target_os} in
1118       xlinux* | xgnu*)
1119         AC_EGREP_CPP([_GLIBCPP_ok], [
1120         #include <features.h>
1121         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1122           _GLIBCPP_ok
1123         #endif
1124         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1125
1126         # Test for bugs early in glibc-2.2.x series
1127         if test x$enable_clocale_flag = xgnu; then
1128           AC_TRY_RUN([
1129           #define _GNU_SOURCE 1
1130           #include <locale.h>
1131           #include <string.h>
1132           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1133           extern __typeof(newlocale) __newlocale;
1134           extern __typeof(duplocale) __duplocale;
1135           extern __typeof(strcoll_l) __strcoll_l;
1136           #endif
1137           int main()
1138           {
1139             const char __one[] = "Äuglein Augmen";
1140             const char __two[] = "Äuglein";
1141             int i;
1142             int j;
1143             __locale_t  loc;
1144             __locale_t  loc_dup;
1145             loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1146             loc_dup = __duplocale(loc);
1147             i = __strcoll_l(__one, __two, loc);
1148             j = __strcoll_l(__one, __two, loc_dup);
1149             return 0;
1150           }
1151           ],
1152           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1153           [enable_clocale_flag=generic])
1154         fi
1155
1156         # ... at some point put __strxfrm_l tests in as well.
1157         ;;
1158       *)
1159         enable_clocale_flag=generic
1160         ;;
1161     esac
1162   fi
1163
1164   dnl Deal with gettext issues.
1165   AC_ARG_ENABLE(nls,
1166   [  --enable-nls            use Native Language Support (default)],
1167   , enable_nls=yes)
1168   USE_NLS=no
1169
1170   dnl Set configure bits for specified locale package
1171   case x${enable_clocale_flag} in
1172     xgeneric)
1173       AC_MSG_RESULT(generic)
1174
1175       CLOCALE_H=config/locale/generic/c_locale.h
1176       CLOCALE_CC=config/locale/generic/c_locale.cc
1177       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1178       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1179       CCOLLATE_CC=config/locale/generic/collate_members.cc
1180       CCTYPE_CC=config/locale/generic/ctype_members.cc
1181       CMESSAGES_H=config/locale/generic/messages_members.h
1182       CMESSAGES_CC=config/locale/generic/messages_members.cc
1183       CMONEY_CC=config/locale/generic/monetary_members.cc
1184       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1185       CTIME_CC=config/locale/generic/time_members.cc
1186       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1187       ;;
1188     xgnu)
1189       AC_MSG_RESULT(gnu)
1190
1191       # Declare intention to use gettext, and add support for specific
1192       # languages.
1193       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1194       ALL_LINGUAS="de fr"
1195
1196       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1197       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1198       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1199         USE_NLS=yes
1200       fi
1201       # Export the build objects.
1202       for ling in $ALL_LINGUAS; do \
1203         glibcpp_MOFILES="$glibcpp_MOFILES $ling.mo"; \
1204         glibcpp_POFILES="$glibcpp_POFILES $ling.po"; \
1205       done
1206       AC_SUBST(glibcpp_MOFILES)
1207       AC_SUBST(glibcpp_POFILES)
1208
1209       CLOCALE_H=config/locale/gnu/c_locale.h
1210       CLOCALE_CC=config/locale/gnu/c_locale.cc
1211       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1212       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1213       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1214       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1215       CMESSAGES_H=config/locale/gnu/messages_members.h
1216       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1217       CMONEY_CC=config/locale/gnu/monetary_members.cc
1218       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1219       CTIME_CC=config/locale/gnu/time_members.cc
1220       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1221       ;;
1222     xieee_1003.1-2001)
1223       AC_MSG_RESULT(generic)
1224
1225       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1226       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1227       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1228       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1229       CCOLLATE_CC=config/locale/generic/collate_members.cc
1230       CCTYPE_CC=config/locale/generic/ctype_members.cc
1231       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1232       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1233       CMONEY_CC=config/locale/generic/monetary_members.cc
1234       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1235       CTIME_CC=config/locale/generic/time_members.cc
1236       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1237       ;;
1238     *)
1239       echo "$enable_clocale is an unknown locale package" 1>&2
1240       exit 1
1241       ;;
1242   esac
1243
1244   # This is where the testsuite looks for locale catalogs, using the
1245   # -DLOCALEDIR define during testsuite compilation.
1246   glibcpp_localedir=${glibcpp_builddir}/po/share/locale
1247   AC_SUBST(glibcpp_localedir)
1248
1249   # For the time being, transform ctype_noninline.h to ctype_members_char.cc
1250 #  CCTYPE_CHAR_CC=config/${os_include_dir}/ctype_noninline.h
1251
1252   AC_SUBST(USE_NLS)
1253   AC_SUBST(CLOCALE_H)
1254   AC_SUBST(CCODECVT_H)
1255   AC_SUBST(CMESSAGES_H)
1256   AC_LINK_FILES($CLOCALE_CC, src/c++locale.cc)
1257   AC_LINK_FILES($CCODECVT_CC, src/codecvt_members.cc)
1258   AC_LINK_FILES($CCOLLATE_CC, src/collate_members.cc)
1259 #  AC_LINK_FILES($CCTYPE_CHAR_CC, src/ctype_members_char.cc)
1260   AC_LINK_FILES($CCTYPE_CC, src/ctype_members.cc)
1261   AC_LINK_FILES($CMESSAGES_CC, src/messages_members.cc)
1262   AC_LINK_FILES($CMONEY_CC, src/monetary_members.cc)
1263   AC_LINK_FILES($CNUMERIC_CC, src/numeric_members.cc)
1264   AC_LINK_FILES($CTIME_CC, src/time_members.cc)
1265   AC_LINK_FILES($CLOCALE_INTERNAL_H, src/c++locale_internal.h)
1266 ])
1267
1268
1269 dnl
1270 dnl Check for which I/O library to use:  libio, or something specific.
1271 dnl
1272 dnl GLIBCPP_ENABLE_CSTDIO
1273 dnl --enable-cstdio=libio sets config/io/c_io_libio.h and friends
1274 dnl
1275 dnl default is stdio
1276 dnl
1277 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1278   AC_MSG_CHECKING([for cstdio to use])
1279   AC_ARG_ENABLE(cstdio,
1280   [  --enable-cstdio         enable stdio for target io package.
1281   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1282   ],
1283   if test x$enable_cstdio = xno; then
1284      enable_cstdio=stdio
1285   fi,
1286      enable_cstdio=stdio)
1287
1288   enable_cstdio_flag=$enable_cstdio
1289
1290   dnl Check if a valid I/O package
1291   case x${enable_cstdio_flag} in
1292     xlibio)
1293       CSTDIO_H=config/io/c_io_libio.h
1294       BASIC_FILE_H=config/io/basic_file_libio.h
1295       BASIC_FILE_CC=config/io/basic_file_libio.cc
1296       AC_MSG_RESULT(libio)
1297
1298       # see if we are on a system with libio native (ie, linux)
1299       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1300
1301       # Need to check and see what version of glibc is being used. If
1302       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1303       # compile most of libio for linux systems.
1304       if test x$has_libio = x"yes"; then
1305         case "$target" in
1306           *-*-linux*)
1307               AC_MSG_CHECKING([for glibc version >= 2.2])
1308               AC_EGREP_CPP([ok], [
1309             #include <features.h>
1310               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1311                     ok
1312               #endif
1313               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1314               AC_MSG_RESULT($glibc_satisfactory)
1315             ;;
1316         esac
1317
1318         # XXX at the moment, admit defeat and force the recompilation
1319         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1320         glibc_satisfactory=no
1321
1322         if test x$glibc_satisfactory = x"yes"; then
1323            need_libio=no
1324            need_wlibio=no
1325         else
1326            need_libio=yes
1327            # bkoz XXX need to add checks to enable this
1328            # pme XXX here's a first pass at such a check
1329            if test x$enable_c_mbchar != xno; then
1330               need_wlibio=yes
1331            else
1332               need_wlibio=no
1333            fi
1334         fi
1335
1336       else
1337          # Using libio, but <libio.h> doesn't exist on the target system. . .
1338          need_libio=yes
1339          # bkoz XXX need to add checks to enable this
1340          # pme XXX here's a first pass at such a check
1341          if test x$enable_c_mbchar != xno; then
1342              need_wlibio=yes
1343          else
1344              need_wlibio=no
1345          fi
1346       fi
1347       ;;
1348     xstdio | x | xno | xnone | xyes)
1349       # default
1350       CSTDIO_H=config/io/c_io_stdio.h
1351       BASIC_FILE_H=config/io/basic_file_stdio.h
1352       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1353       AC_MSG_RESULT(stdio)
1354
1355       # We're not using stdio.
1356       need_libio=no
1357       need_wlibio=no
1358       ;;
1359     *)
1360       echo "$enable_cstdio is an unknown io package" 1>&2
1361       exit 1
1362       ;;
1363   esac
1364   AC_SUBST(CSTDIO_H)
1365   AC_SUBST(BASIC_FILE_H)
1366   AC_LINK_FILES($BASIC_FILE_CC, src/basic_file.cc)
1367
1368   # 2000-08-04 bkoz hack
1369   CCODECVT_C=config/io/c_io_libio_codecvt.c
1370   AC_SUBST(CCODECVT_C)
1371   # 2000-08-04 bkoz hack
1372
1373   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1374                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1375   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1376   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1377   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1378     libio_la=../libio/libio.la
1379   else
1380     libio_la=
1381   fi
1382   AC_SUBST(libio_la)
1383 ])
1384
1385
1386 dnl
1387 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1388 dnl We must stage the required headers so that they will be installed
1389 dnl with the library (unlike libgcc, the STL implementation is provided
1390 dnl solely within headers).  Since we must not inject random user-space
1391 dnl macro names into user-provided C++ code, we first stage into <file>-in
1392 dnl and process to <file> with an output command.  The reason for a two-
1393 dnl stage process here is to correctly handle $srcdir!=$objdir without
1394 dnl having to write complex code (the sed commands to clean the macro
1395 dnl namespace are complex and fragile enough as it is).  We must also
1396 dnl add a relative path so that -I- is supported properly.
1397 dnl
1398 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1399   AC_MSG_CHECKING([for thread model used by GCC])
1400   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1401   AC_MSG_RESULT([$target_thread_file])
1402
1403   if test $target_thread_file != single; then
1404     AC_DEFINE(HAVE_GTHR_DEFAULT)
1405     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1406   fi
1407
1408   glibcpp_thread_h=gthr-$target_thread_file.h
1409   AC_SUBST(glibcpp_thread_h)
1410 ])
1411
1412
1413 dnl
1414 dnl Check for exception handling support.  If an explicit enable/disable
1415 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1416 dnl target may or may not support call frame exceptions.
1417 dnl
1418 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1419 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1420 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1421 dnl
1422 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1423 dnl
1424 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1425   AC_MSG_CHECKING([for exception model to use])
1426   AC_LANG_SAVE
1427   AC_LANG_CPLUSPLUS
1428   AC_ARG_ENABLE(sjlj-exceptions,
1429   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1430   [:],
1431   [dnl Botheration.  Now we've got to detect the exception model.
1432    dnl Link tests against libgcc.a are problematic since -- at least
1433    dnl as of this writing -- we've not been given proper -L bits for
1434    dnl single-tree newlib and libgloss.
1435    dnl
1436    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1437    dnl conftest files before we got a change to grep them first.
1438    cat > conftest.$ac_ext << EOF
1439 [#]line __oline__ "configure"
1440 struct S { ~S(); };
1441 void bar();
1442 void foo()
1443 {
1444   S s;
1445   bar();
1446 }
1447 EOF
1448    old_CXXFLAGS="$CXXFLAGS"
1449    CXXFLAGS=-S
1450    if AC_TRY_EVAL(ac_compile); then
1451      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1452        enable_sjlj_exceptions=yes
1453      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1454        enable_sjlj_exceptions=no
1455      fi
1456    fi
1457    CXXFLAGS="$old_CXXFLAGS"
1458    rm -f conftest*])
1459    if test x$enable_sjlj_exceptions = xyes; then
1460      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1461         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1462      ac_exception_model_name=sjlj
1463    elif test x$enable_sjlj_exceptions = xno; then
1464      ac_exception_model_name="call frame"
1465    else
1466      AC_MSG_ERROR([unable to detect exception model])
1467    fi
1468    AC_LANG_RESTORE
1469    AC_MSG_RESULT($ac_exception_model_name)
1470 ])
1471
1472
1473 dnl
1474 dnl Check for libunwind exception handling support. If enabled then
1475 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1476 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1477 dnl libunwind instead of libgcc and that libstdc++ has a dependency
1478 dnl on libunwind as well as libgcc.
1479 dnl
1480 dnl GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS
1481 dnl --enable-libunwind-exceptions forces the use of libunwind.
1482 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1483 dnl
1484 dnl Define _GLIBCPP_LIBUNWIND_EXCEPTIONS if requested.
1485 dnl
1486 AC_DEFUN(GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS, [
1487   AC_MSG_CHECKING([for use of libunwind])
1488   AC_ARG_ENABLE(libunwind-exceptions,
1489   [  --enable-libunwind-exceptions  force use of libunwind for exceptions],
1490   use_libunwind_exceptions=$enableval,
1491   use_libunwind_exceptions=no)
1492   AC_MSG_RESULT($use_libunwind_exceptions)
1493   dnl Option parsed, now set things appropriately
1494   if test x"$use_libunwind_exceptions" = xyes; then
1495     LIBUNWIND_FLAG="-lunwind"
1496   else
1497     LIBUNWIND_FLAG=""
1498   fi
1499   AC_SUBST(LIBUNWIND_FLAG)
1500 ])
1501
1502 dnl
1503 dnl Check for ISO/IEC 9899:1999 "C99" support.
1504 dnl
1505 dnl GLIBCPP_ENABLE_C99
1506 dnl --enable-c99 defines _GLIBCPP_USE_C99
1507 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1508 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1509 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1510 dnl       defaults to `no'.
1511 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1512 dnl
1513 dnl GLIBCPP_ENABLE_C99
1514 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1515   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1516
1517   AC_ARG_ENABLE(c99,
1518   changequote(<<, >>)dnl
1519   <<--enable-c99            turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1520   changequote([, ])dnl
1521   [case "$enableval" in
1522    yes) enable_c99=yes ;;
1523    no)  enable_c99=no ;;
1524    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1525    esac],
1526   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1527
1528   AC_LANG_SAVE
1529   AC_LANG_CPLUSPLUS
1530
1531   # Check for the existence of <math.h> functions used if C99 is enabled.
1532   ac_c99_math=yes;
1533   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1534   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1535   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1536   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1537   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1538   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1539   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1540   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1541   AC_TRY_COMPILE([#include <math.h>],
1542                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1543   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1544   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1545   AC_TRY_COMPILE([#include <math.h>],
1546                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1547   AC_TRY_COMPILE([#include <math.h>],
1548                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1549   AC_MSG_RESULT($ac_c99_math)
1550
1551   # Check for the existence in <stdio.h> of vscanf, et. al.
1552   ac_c99_stdio=yes;
1553   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1554   AC_TRY_COMPILE([#include <stdio.h>],
1555                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
1556   AC_TRY_COMPILE([#include <stdio.h>
1557                   #include <stdarg.h>
1558                   void foo(char* fmt, ...)
1559                   {va_list args; va_start(args, fmt);
1560                   vfscanf(stderr, "%i", args);}],
1561                   [],, [ac_c99_stdio=no])
1562   AC_TRY_COMPILE([#include <stdio.h>
1563                   #include <stdarg.h>
1564                   void foo(char* fmt, ...)
1565                   {va_list args; va_start(args, fmt);
1566                   vscanf("%i", args);}],
1567                   [],, [ac_c99_stdio=no])
1568   AC_TRY_COMPILE([#include <stdio.h>
1569                   #include <stdarg.h>
1570                   void foo(char* fmt, ...)
1571                   {va_list args; va_start(args, fmt);
1572                   vsnprintf(fmt, 0, "%i", args);}],
1573                   [],, [ac_c99_stdio=no])
1574   AC_TRY_COMPILE([#include <stdio.h>
1575                   #include <stdarg.h>
1576                   void foo(char* fmt, ...)
1577                   {va_list args; va_start(args, fmt);
1578                   vsscanf(fmt, "%i", args);}],
1579                   [],, [ac_c99_stdio=no])
1580   AC_MSG_RESULT($ac_c99_stdio)
1581
1582   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1583   ac_c99_stdlib=yes;
1584   AC_MSG_CHECKING([for lldiv_t declaration])
1585   AC_CACHE_VAL(ac_c99_lldiv_t, [
1586   AC_TRY_COMPILE([#include <stdlib.h>],
1587                    [ lldiv_t mydivt;],
1588                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1589   ])
1590   AC_MSG_RESULT($ac_c99_lldiv_t)
1591
1592   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1593   AC_TRY_COMPILE([#include <stdlib.h>],
1594                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1595   AC_TRY_COMPILE([#include <stdlib.h>],
1596                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1597   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1598   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1599   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1600   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1601   if test x"$ac_c99_lldiv_t" = x"no"; then
1602     ac_c99_stdlib=no;
1603   fi;
1604   AC_MSG_RESULT($ac_c99_stdlib)
1605
1606   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1607   # XXX the wchar.h checks should be rolled into the general C99 bits.
1608   ac_c99_wchar=yes;
1609   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1610   AC_TRY_COMPILE([#include <wchar.h>],
1611                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1612   AC_TRY_COMPILE([#include <wchar.h>],
1613                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1614   AC_TRY_COMPILE([#include <wchar.h>],
1615                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1616   AC_MSG_RESULT($ac_c99_wchar)
1617
1618   AC_MSG_CHECKING([for enabled ISO C99 support])
1619   if test x"$ac_c99_math" = x"no" ||
1620      test x"$ac_c99_stdio" = x"no" ||
1621      test x"$ac_c99_stdlib" = x"no" ||
1622      test x"$ac_c99_wchar" = x"no"; then
1623     enable_c99=no;
1624   fi;
1625   AC_MSG_RESULT($enable_c99)
1626
1627   # Option parsed, now set things appropriately
1628   if test x"$enable_c99" = x"yes"; then
1629     AC_DEFINE(_GLIBCPP_USE_C99)
1630   fi
1631
1632   AC_LANG_RESTORE
1633 ])
1634
1635
1636 dnl
1637 dnl Check for template specializations for the 'long long' type extension.
1638 dnl The result determines only whether 'long long' I/O is enabled; things
1639 dnl like numeric_limits<> specializations are always available.
1640 dnl
1641 dnl GLIBCPP_ENABLE_LONG_LONG
1642 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1643 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1644 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1645 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1646 dnl       defaults to `no'.
1647 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1648 dnl
1649 dnl GLIBCPP_ENABLE_LONG_LONG
1650 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1651   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1652
1653   AC_ARG_ENABLE(long-long,
1654   changequote(<<, >>)dnl
1655   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1656   changequote([, ])dnl
1657   [case "$enableval" in
1658    yes) enable_long_long=yes ;;
1659    no)  enable_long_long=no ;;
1660    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1661    esac],
1662   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1663
1664   AC_LANG_SAVE
1665   AC_LANG_CPLUSPLUS
1666
1667   AC_MSG_CHECKING([for enabled long long I/O support])
1668   # iostreams require strtoll, strtoull to compile
1669   AC_TRY_COMPILE([#include <stdlib.h>],
1670                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1671   AC_TRY_COMPILE([#include <stdlib.h>],
1672                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1673
1674   # Option parsed, now set things appropriately
1675   if test x"$enable_long_long" = xyes; then
1676     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1677   fi
1678   AC_MSG_RESULT($enable_long_long)
1679
1680   AC_LANG_RESTORE
1681 ])
1682
1683
1684 dnl
1685 dnl Check for what kind of C headers to use.
1686 dnl
1687 dnl GLIBCPP_ENABLE_CHEADERS
1688 dnl --enable-cheaders= [does stuff].
1689 dnl --disable-cheaders [does not do anything, really].
1690 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1691 dnl       Where DEFAULT is either `c' or `c_std'.
1692 dnl       If ommitted, it defaults to `c_std'.
1693 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1694 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1695 AC_MSG_CHECKING([for c header strategy to use])
1696 AC_ARG_ENABLE(cheaders,
1697 changequote(<<, >>)dnl
1698 <<  --enable-cheaders       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1699 changequote([, ])
1700   [case "$enableval" in
1701    c)
1702         enable_cheaders=c
1703         ;;
1704    c_std)
1705         enable_cheaders=c_std
1706         ;;
1707    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1708         ;;
1709   esac],
1710   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1711   AC_MSG_RESULT($enable_cheaders)
1712
1713   dnl Option parsed, now set things appropriately
1714   case "$enable_cheaders" in
1715     c_std)
1716         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_std'
1717         ;;
1718     c)
1719         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c'
1720         ;;
1721   esac
1722
1723   AC_SUBST(C_INCLUDE_DIR)
1724   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C, test "$enable_cheaders" = c)
1725   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C_STD, test "$enable_cheaders" = c_std)
1726   AM_CONDITIONAL(GLIBCPP_C_HEADERS_COMPATIBILITY, test "$c_compatibility" = yes)
1727 ])
1728
1729
1730 dnl
1731 dnl Check for wide character support.  Has the same effect as the option
1732 dnl in gcc's configure, but in a form that autoconf can mess with.
1733 dnl
1734 dnl GLIBCPP_ENABLE_C_MBCHAR
1735 dnl --enable-c-mbchar requests all the wchar_t stuff.
1736 dnl --disable-c-mbchar doesn't.
1737 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1738 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1739 dnl       defaults to `no'.
1740 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1741 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1742 AC_ARG_ENABLE(c-mbchar,
1743 changequote(<<, >>)dnl
1744 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1745 changequote([, ])dnl
1746 [case "$enableval" in
1747  yes) enable_c_mbchar=yes ;;
1748  no)  enable_c_mbchar=no ;;
1749  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1750  esac],
1751 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1752 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1753 ])
1754
1755
1756 dnl
1757 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1758 dnl
1759 dnl TOPLEVEL_INCLUDES
1760 dnl LIBMATH_INCLUDES
1761 dnl LIBSUPCXX_INCLUDES
1762 dnl LIBIO_INCLUDES
1763 dnl
1764 dnl GLIBCPP_EXPORT_INCLUDES
1765 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1766   # Root level of the build directory include sources.
1767   GLIBCPP_INCLUDES="-I${glibcpp_builddir}/include/${target_alias} -I${glibcpp_builddir}/include"
1768
1769   # Passed down for canadian crosses.
1770   if test x"$CANADIAN" = xyes; then
1771     TOPLEVEL_INCLUDES='-I$(includedir)'
1772   fi
1773
1774   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1775
1776   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1777
1778   if test x"$need_libio" = xyes; then
1779     LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1780     AC_SUBST(LIBIO_INCLUDES)
1781   fi
1782
1783   # Now, export this to all the little Makefiles....
1784   AC_SUBST(GLIBCPP_INCLUDES)
1785   AC_SUBST(TOPLEVEL_INCLUDES)
1786   AC_SUBST(LIBMATH_INCLUDES)
1787   AC_SUBST(LIBSUPCXX_INCLUDES)
1788 ])
1789
1790
1791 dnl
1792 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1793 dnl
1794 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1795   # Optimization flags that are probably a good idea for thrill-seekers. Just
1796   # uncomment the lines below and make, everything else is ready to go...
1797   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1798   OPTIMIZE_CXXFLAGS=
1799   AC_SUBST(OPTIMIZE_CXXFLAGS)
1800
1801   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1802   AC_SUBST(WARN_FLAGS)
1803 ])
1804
1805 dnl
1806 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1807 dnl  calculates gxx_install_dir
1808 dnl  exports glibcpp_toolexecdir
1809 dnl  exports glibcpp_toolexeclibdir
1810 dnl  exports glibcpp_prefixdir
1811 dnl
1812 dnl Assumes cross_compiling bits already done, and with_cross_host in
1813 dnl particular
1814 dnl
1815 dnl GLIBCPP_EXPORT_INSTALL_INFO
1816 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1817 # Assumes glibcpp_builddir, glibcpp_srcdir are alreay set up and
1818 # exported correctly in GLIBCPP_CONFIGURE.
1819 glibcpp_toolexecdir=no
1820 glibcpp_toolexeclibdir=no
1821 glibcpp_prefixdir=${prefix}
1822
1823 # Process the option --with-gxx-include-dir=<path to include-files directory>
1824 AC_MSG_CHECKING([for --with-gxx-include-dir])
1825 AC_ARG_WITH(gxx-include-dir,
1826 [  --with-gxx-include-dir  the installation directory for include files],
1827 [case "${withval}" in
1828   yes)
1829     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1830     gxx_include_dir=no
1831     ;;
1832   no)
1833     gxx_include_dir=no
1834     ;;
1835   *)
1836     gxx_include_dir=${withval}
1837     ;;
1838 esac], [gxx_include_dir=no])
1839 AC_MSG_RESULT($gxx_include_dir)
1840
1841 # Process the option "--enable-version-specific-runtime-libs"
1842 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1843 AC_ARG_ENABLE(version-specific-runtime-libs,
1844 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1845 [case "$enableval" in
1846  yes) version_specific_libs=yes ;;
1847  no)  version_specific_libs=no ;;
1848  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
1849  esac],
1850 version_specific_libs=no)dnl
1851 # Option set, now we can test it.
1852 AC_MSG_RESULT($version_specific_libs)
1853
1854 # Default case for install directory for include files.
1855 if test $version_specific_libs = no && test $gxx_include_dir = no; then
1856   gxx_include_dir='$(prefix)'/include/c++/${gcc_version}
1857 fi
1858
1859 # Version-specific runtime libs processing.
1860 if test $version_specific_libs = yes; then
1861   # Need the gcc compiler version to know where to install libraries
1862   # and header files if --enable-version-specific-runtime-libs option
1863   # is selected.
1864   if test x"$gxx_include_dir" = x"no"; then
1865     gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/c++
1866   fi
1867   glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1868   glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1869 fi
1870
1871 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1872 # Install a library built with a cross compiler in tooldir, not libdir.
1873 if test x"$glibcpp_toolexecdir" = x"no"; then
1874   if test -n "$with_cross_host" &&
1875      test x"$with_cross_host" != x"no"; then
1876     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1877     glibcpp_toolexeclibdir='$(toolexecdir)/lib$(MULTISUBDIR)'
1878   else
1879     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1880     glibcpp_toolexeclibdir='$(libdir)$(MULTISUBDIR)'
1881   fi
1882 fi
1883
1884 AC_MSG_CHECKING([for install location])
1885 AC_MSG_RESULT($gxx_include_dir)
1886
1887 AC_SUBST(glibcpp_prefixdir)
1888 AC_SUBST(gxx_include_dir)
1889 AC_SUBST(glibcpp_toolexecdir)
1890 AC_SUBST(glibcpp_toolexeclibdir)
1891 ])
1892
1893
1894 # Check for functions in math library.
1895 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1896 #
1897 # This file can be copied and used freely without restrictions.  It can
1898 # be used in projects which are not available under the GNU Public License
1899 # but which still want to provide support for the GNU gettext functionality.
1900 # Please note that the actual code is *not* freely available.
1901
1902 # serial 1
1903
1904 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1905 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1906 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])])
1907
1908
1909 dnl This macro searches for a GNU version of make.  If a match is found, the
1910 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1911 dnl set to "#". This is useful for  including a special features in a Makefile,
1912 dnl which cannot be handled by other versions of make.  The variable
1913 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1914 dnl the empty string otherwise.
1915 dnl
1916 dnl Here is an example of its use:
1917 dnl
1918 dnl Makefile.in might contain:
1919 dnl
1920 dnl     # A failsafe way of putting a dependency rule into a makefile
1921 dnl     $(DEPEND):
1922 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1923 dnl
1924 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1925 dnl     @ifGNUmake@ include $(DEPEND)
1926 dnl     @ifGNUmake@ endif
1927 dnl
1928 dnl Then configure.in would normally contain:
1929 dnl
1930 dnl     CHECK_GNU_MAKE()
1931 dnl     AC_OUTPUT(Makefile)
1932 dnl
1933 dnl Then perhaps to cause gnu make to override any other make, we could do
1934 dnl something like this (note that GNU make always looks for GNUmakefile first):
1935 dnl
1936 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1937 dnl             mv Makefile GNUmakefile
1938 dnl             echo .DEFAULT: > Makefile ;
1939 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1940 dnl     fi
1941 dnl
1942 dnl Then, if any (well almost any) other make is called, and GNU make also
1943 dnl exists, then the other make wraps the GNU make.
1944 dnl
1945 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1946 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1947 dnl
1948 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1949 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1950 dnl #### conditional's subshell (" --version" is not a command), using a
1951 dnl #### different option to grep(1).
1952 dnl #### -pme
1953 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1954 dnl #### ${MAKE:-make}).
1955 dnl #### -msokolov
1956 AC_DEFUN(
1957   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1958           _cv_gnu_make_command='' ;
1959 dnl Search all the common names for GNU make
1960           for a in "${MAKE-make}" make gmake gnumake ; do
1961                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1962                   then
1963                           _cv_gnu_make_command=$a ;
1964                           break;
1965                   fi
1966           done ;
1967   ) ;
1968 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1969 dnl string, '#' otherwise
1970   if test  "x$_cv_gnu_make_command" != "x"  ; then
1971           ifGNUmake='' ;
1972   else
1973           ifGNUmake='#' ;
1974   fi
1975   AC_SUBST(ifGNUmake)
1976 ])
1977
1978
1979 dnl Check for headers for, and arguments to, the setrlimit() function.
1980 dnl Used only in testsuite_hooks.h.
1981 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT_ancilliary, [
1982   AC_TRY_COMPILE([#include <unistd.h>
1983                   #include <sys/time.h>
1984                   #include <sys/resource.h>
1985                  ], [ int f = RLIMIT_$1 ; ],
1986                  [glibcpp_mresult=1], [glibcpp_mresult=0])
1987   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcpp_mresult,
1988                      [Only used in build directory testsuite_hooks.h.])
1989 ])
1990 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT, [
1991   setrlimit_have_headers=yes
1992   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
1993                    [],
1994                    setrlimit_have_headers=no)
1995   # If don't have the headers, then we can't run the tests now, and we
1996   # won't be seeing any of these during testsuite compilation.
1997   if test $setrlimit_have_headers = yes; then
1998     # Can't do these in a loop, else the resulting syntax is wrong.
1999     GLIBCPP_CHECK_SETRLIMIT_ancilliary(DATA)
2000     GLIBCPP_CHECK_SETRLIMIT_ancilliary(RSS)
2001     GLIBCPP_CHECK_SETRLIMIT_ancilliary(VMEM)
2002     GLIBCPP_CHECK_SETRLIMIT_ancilliary(AS)
2003
2004     # Check for rlimit, setrlimit.
2005     AC_CACHE_VAL(ac_setrlimit, [
2006       AC_TRY_COMPILE([#include <unistd.h>
2007                   #include <sys/time.h>
2008                   #include <sys/resource.h>
2009                      ],
2010                      [ struct rlimit r; setrlimit(0, &r);],
2011                      [ac_setrlimit=yes], [ac_setrlimit=no])
2012     ])
2013   fi
2014
2015   AC_MSG_CHECKING([for testsuite memory limit support])
2016   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
2017     ac_mem_limits=yes
2018     AC_DEFINE(_GLIBCPP_MEM_LIMITS)
2019   else
2020     ac_mem_limits=no
2021   fi
2022   AC_MSG_RESULT($ac_mem_limits)
2023 ])
2024
2025
2026 dnl
2027 dnl Does any necessary configuration of the testsuite directory.  Generates
2028 dnl the testsuite_hooks.h header.
2029 dnl
2030 dnl GLIBCPP_CONFIGURE_TESTSUITE  [no args]
2031 AC_DEFUN(GLIBCPP_CONFIGURE_TESTSUITE, [
2032   GLIBCPP_CHECK_SETRLIMIT
2033
2034   # Look for setenv, so that extended locale tests can be performed.
2035   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
2036
2037   # Export file names for ABI checking.
2038   baseline_file="${glibcpp_srcdir}/config/abi/${abi_baseline_triplet}/baseline_symbols.txt"
2039   AC_SUBST(baseline_file)
2040
2041   # Don't do ABI checking unless native.
2042   AM_CONDITIONAL(GLIBCPP_BUILD_ABI_CHECK,
2043                  test x"$build" = x"$host" && test -z "$with_cross_host")
2044 ])
2045
2046
2047 sinclude(../libtool.m4)
2048 dnl The lines below arrange for aclocal not to bring an installed
2049 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
2050 dnl add a definition of LIBTOOL to Makefile.in.
2051 ifelse(,,,[AC_SUBST(LIBTOOL)
2052 AC_DEFUN([AM_PROG_LIBTOOL])
2053 AC_DEFUN([AC_LIBTOOL_DLOPEN])
2054 AC_DEFUN([AC_PROG_LD])
2055 ])
2056
2057
2058 # Check whether LC_MESSAGES is available in <locale.h>.
2059 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2060 #
2061 # This file file be copied and used freely without restrictions.  It can
2062 # be used in projects which are not available under the GNU Public License
2063 # but which still want to provide support for the GNU gettext functionality.
2064 # Please note that the actual code is *not* freely available.
2065
2066 # serial 1
2067
2068 AC_DEFUN(AC_LC_MESSAGES, [
2069   AC_CHECK_HEADER(locale.h, [
2070     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2071       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2072        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2073     if test $ac_cv_val_LC_MESSAGES = yes; then
2074       AC_DEFINE(HAVE_LC_MESSAGES)
2075     fi
2076   ])
2077 ])
2078
2079
2080 dnl
2081 dnl Check for whether the Boost-derived checks should be turned on.
2082 dnl
2083 dnl GLIBCPP_ENABLE_CONCEPT_CHECKS
2084 dnl --enable-concept-checks turns them on.
2085 dnl --disable-concept-checks leaves them off.
2086 dnl  +  Usage:  GLIBCPP_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2087 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2088 dnl       defaults to `no'.
2089 AC_DEFUN(GLIBCPP_ENABLE_CONCEPT_CHECKS, [dnl
2090 define([GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT], ifelse($1, yes, yes, no))dnl
2091 AC_ARG_ENABLE(concept-checks,
2092 changequote(<<, >>)dnl
2093 <<  --enable-concept-checks use Boost-derived template checks [default=>>GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT],
2094 changequote([, ])dnl
2095 [case "$enableval" in
2096  yes) enable_concept_checks=yes ;;
2097  no)  enable_concept_checks=no ;;
2098  *)   AC_MSG_ERROR([Unknown argument to enable/disable concept checks]) ;;
2099  esac],
2100 enable_concept_checks=GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT)dnl
2101 dnl Option parsed, now set things appropriately
2102 if test x"$enable_concept_checks" = xyes; then
2103   AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS)
2104 fi
2105 ])
2106
2107
2108 dnl
2109 dnl Add version tags to symbols in shared library (or not), additionally
2110 dnl marking other symbols as private/local (or not).
2111 dnl
2112 dnl GLIBCPP_ENABLE_SYMVERS
2113 dnl --enable-symvers=style adds a version script to the linker call when
2114 dnl       creating the shared library.  The choice of version script is
2115 dnl       controlled by 'style'.
2116 dnl --disable-symvers does not.
2117 dnl  +  Usage:  GLIBCPP_ENABLE_SYMVERS[(DEFAULT)]
2118 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2119 dnl       defaults to `no'.  Passing `yes' tries to choose a default style
2120 dnl       based on linker characteristics.  Passing 'no' disables versioning.
2121 AC_DEFUN(GLIBCPP_ENABLE_SYMVERS, [dnl
2122 define([GLIBCPP_ENABLE_SYMVERS_DEFAULT], ifelse($1, yes, yes, no))dnl
2123 AC_ARG_ENABLE(symvers,
2124 changequote(<<, >>)dnl
2125 <<  --enable-symvers=style  enables symbol versioning of the shared library [default=>>GLIBCPP_ENABLE_SYMVERS_DEFAULT],
2126 changequote([, ])dnl
2127 [case "$enableval" in
2128  yes) enable_symvers=yes ;;
2129  no)  enable_symvers=no ;;
2130  # other names here, just as sanity checks
2131  #gnu|sun|etcetera) enable_symvers=$enableval ;;
2132  gnu) enable_symvers=$enableval ;;
2133  *)   AC_MSG_ERROR([Unknown argument to enable/disable symvers]) ;;
2134  esac],
2135 enable_symvers=GLIBCPP_ENABLE_SYMVERS_DEFAULT)dnl
2136
2137 # If we never went through the GLIBCPP_CHECK_LINKER_FEATURES macro, then we
2138 # don't know enough about $LD to do tricks...
2139 if test x$enable_shared = xno ||
2140         test "x$LD" = x ||
2141         test x$glibcpp_gnu_ld_version = x; then
2142   enable_symvers=no
2143 fi
2144
2145 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2146 if test $enable_symvers != no; then
2147   AC_MSG_CHECKING([for shared libgcc])
2148   ac_save_CFLAGS="$CFLAGS"
2149   CFLAGS=' -lgcc_s'
2150   AC_TRY_LINK(, [return 0], glibcpp_shared_libgcc=yes, glibcpp_shared_libgcc=no)
2151   CFLAGS="$ac_save_CFLAGS"
2152   AC_MSG_RESULT($glibcpp_shared_libgcc)
2153 fi
2154
2155 # For GNU ld, we need at least this version.  It's 2.12 in the same format
2156 # as the tested-for version.  See GLIBCPP_CHECK_LINKER_FEATURES for more.
2157 glibcpp_min_gnu_ld_version=21200
2158
2159 # Check to see if unspecified "yes" value can win, given results
2160 # above.
2161 if test $enable_symvers = yes ; then
2162   if test $with_gnu_ld = yes &&
2163     test $glibcpp_shared_libgcc = yes ;
2164   then
2165     if test $glibcpp_gnu_ld_version -ge $glibcpp_min_gnu_ld_version ; then
2166         enable_symvers=gnu
2167     else
2168       ac_test_CFLAGS="${CFLAGS+set}"
2169       ac_save_CFLAGS="$CFLAGS"
2170       CFLAGS='-shared -Wl,--version-script,conftest.map'
2171       enable_symvers=no
2172       changequote(,)
2173       echo 'FOO { global: f[a-z]o; local: *; };' > conftest.map
2174       changequote([,])
2175       AC_TRY_LINK([int foo;],, enable_symvers=gnu)
2176       if test "$ac_test_CFLAGS" = set; then
2177         CFLAGS="$ac_save_CFLAGS"
2178       else
2179         # this is the suspicious part
2180         CFLAGS=''
2181       fi
2182       rm -f conftest.map
2183     fi
2184   else
2185     # just fail for now
2186     enable_symvers=no
2187   fi
2188 fi
2189
2190 dnl Everything parsed; figure out what file to use.
2191 case $enable_symvers in
2192   no)
2193       LINKER_MAP=config/linker-map.dummy
2194       ;;
2195   gnu)
2196       LINKER_MAP=config/linker-map.gnu
2197       ;;
2198 esac
2199
2200 AC_LINK_FILES($LINKER_MAP, src/linker.map)
2201 AM_CONDITIONAL(GLIBCPP_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
2202 AC_MSG_CHECKING([versioning on shared library symbols])
2203 AC_MSG_RESULT($enable_symvers)
2204 ])
2205