gcc/ada/sem_dist.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ D I S T                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Casing;   use Casing;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Exp_Dist; use Exp_Dist;
  31 with Exp_Tss;  use Exp_Tss;
  32 with Nlists;   use Nlists;
  33 with Nmake;    use Nmake;
  34 with Namet;    use Namet;
  35 with Opt;      use Opt;
  36 with Rtsfind;  use Rtsfind;
  37 with Sem;      use Sem;
  38 with Sem_Aux;  use Sem_Aux;
  39 with Sem_Disp; use Sem_Disp;
  40 with Sem_Eval; use Sem_Eval;
  41 with Sem_Res;  use Sem_Res;
  42 with Sem_Util; use Sem_Util;
  43 with Sinfo;    use Sinfo;
  44 with Stand;    use Stand;
  45 with Stringt;  use Stringt;
  46 with Tbuild;   use Tbuild;
  47 with Uintp;    use Uintp;
  48
  49 package body Sem_Dist is
  50
  51    -----------------------
  52    -- Local Subprograms --
  53    -----------------------
  54
  55    procedure RAS_E_Dereference (Pref : Node_Id);
  56    --  Handles explicit dereference of Remote Access to Subprograms
  57
  58    function Full_Qualified_Name (E : Entity_Id) return String_Id;
  59    --  returns the full qualified name of the entity in lower case
  60
  61    -------------------------
  62    -- Add_Stub_Constructs --
  63    -------------------------
  64
  65    procedure Add_Stub_Constructs (N : Node_Id) is
  66       U    : constant Node_Id := Unit (N);
  67       Spec : Entity_Id        := Empty;
  68
  69       Exp : Node_Id := U;
  70       --  Unit that will be expanded
  71
  72    begin
  73       pragma Assert (Distribution_Stub_Mode /= No_Stubs);
  74
  75       if Nkind (U) = N_Package_Declaration then
  76          Spec := Defining_Entity (Specification (U));
  77
  78       elsif Nkind (U) = N_Package_Body then
  79          Spec := Corresponding_Spec (U);
  80
  81       else pragma Assert (Nkind (U) = N_Package_Instantiation);
  82          Exp  := Instance_Spec (U);
  83          Spec := Defining_Entity (Specification (Exp));
  84       end if;
  85
  86       pragma Assert (Is_Shared_Passive (Spec)
  87         or else Is_Remote_Call_Interface (Spec));
  88
  89       if Distribution_Stub_Mode = Generate_Caller_Stub_Body then
  90          if Is_Shared_Passive (Spec) then
  91             null;
  92          elsif Nkind (U) = N_Package_Body then
  93             Error_Msg_N
  94               ("Specification file expected from command line", U);
  95          else
  96             Expand_Calling_Stubs_Bodies (Exp);
  97          end if;
  98
  99       else
 100          if Is_Shared_Passive (Spec) then
 101             Build_Passive_Partition_Stub (Exp);
 102          else
 103             Expand_Receiving_Stubs_Bodies (Exp);
 104          end if;
 105
 106       end if;
 107    end Add_Stub_Constructs;
 108
 109    ---------------------------------------
 110    -- Build_RAS_Primitive_Specification --
 111    ---------------------------------------
 112
 113    function Build_RAS_Primitive_Specification
 114      (Subp_Spec          : Node_Id;
 115       Remote_Object_Type : Node_Id) return Node_Id
 116    is
 117       Loc : constant Source_Ptr := Sloc (Subp_Spec);
 118
 119       Primitive_Spec : constant Node_Id :=
 120                          Copy_Specification (Loc,
 121                            Spec     => Subp_Spec,
 122                            New_Name => Name_uCall);
 123
 124       Subtype_Mark_For_Self : Node_Id;
 125
 126    begin
 127       if No (Parameter_Specifications (Primitive_Spec)) then
 128          Set_Parameter_Specifications (Primitive_Spec, New_List);
 129       end if;
 130
 131       if Nkind (Remote_Object_Type) in N_Entity then
 132          Subtype_Mark_For_Self :=
 133            New_Occurrence_Of (Remote_Object_Type, Loc);
 134       else
 135          Subtype_Mark_For_Self := Remote_Object_Type;
 136       end if;
 137
 138       Prepend_To (
 139         Parameter_Specifications (Primitive_Spec),
 140         Make_Parameter_Specification (Loc,
 141           Defining_Identifier =>
 142             Make_Defining_Identifier (Loc, Name_uS),
 143           Parameter_Type      =>
 144             Make_Access_Definition (Loc,
 145               Subtype_Mark =>
 146                 Subtype_Mark_For_Self)));
 147
 148       --  Trick later semantic analysis into considering this operation as a
 149       --  primitive (dispatching) operation of tagged type Obj_Type.
 150
 151       Set_Comes_From_Source (
 152         Defining_Unit_Name (Primitive_Spec), True);
 153
 154       return Primitive_Spec;
 155    end Build_RAS_Primitive_Specification;
 156
 157    -------------------------
 158    -- Full_Qualified_Name --
 159    -------------------------
 160
 161    function Full_Qualified_Name (E : Entity_Id) return String_Id is
 162       Ent         : Entity_Id := E;
 163       Parent_Name : String_Id := No_String;
 164
 165    begin
 166       --  Deals properly with child units
 167
 168       if Nkind (Ent) = N_Defining_Program_Unit_Name then
 169          Ent := Defining_Identifier (Ent);
 170       end if;
 171
 172       --  Compute recursively the qualification (only "Standard" has no scope)
 173
 174       if Present (Scope (Scope (Ent))) then
 175          Parent_Name := Full_Qualified_Name (Scope (Ent));
 176       end if;
 177
 178       --  Every entity should have a name except some expanded blocks. Do not
 179       --  bother about those.
 180
 181       if Chars (Ent) = No_Name then
 182          return Parent_Name;
 183       end if;
 184
 185       --  Add a period between Name and qualification
 186
 187       if Parent_Name /= No_String then
 188          Start_String (Parent_Name);
 189          Store_String_Char (Get_Char_Code ('.'));
 190       else
 191          Start_String;
 192       end if;
 193
 194       --  Generates the entity name in upper case
 195
 196       Get_Name_String (Chars (Ent));
 197       Set_Casing (All_Lower_Case);
 198       Store_String_Chars (Name_Buffer (1 .. Name_Len));
 199       return End_String;
 200    end Full_Qualified_Name;
 201
 202    ------------------
 203    -- Get_PCS_Name --
 204    ------------------
 205
 206    function Get_PCS_Name return PCS_Names is
 207    begin
 208       return
 209         Chars (Entity (Expression (Parent (RTE (RE_DSA_Implementation)))));
 210    end Get_PCS_Name;
 211
 212    ---------------------
 213    -- Get_PCS_Version --
 214    ---------------------
 215
 216    function Get_PCS_Version return Int is
 217       PCS_Version_Entity : Entity_Id;
 218       PCS_Version        : Int;
 219
 220    begin
 221       if RTE_Available (RE_PCS_Version) then
 222          PCS_Version_Entity := RTE (RE_PCS_Version);
 223          pragma Assert (Ekind (PCS_Version_Entity) = E_Named_Integer);
 224          PCS_Version :=
 225            UI_To_Int (Expr_Value (Constant_Value (PCS_Version_Entity)));
 226
 227       else
 228          --  Case of System.Partition_Interface.PCS_Version not found:
 229          --  return a null version.
 230
 231          PCS_Version := 0;
 232       end if;
 233
 234       return PCS_Version;
 235    end Get_PCS_Version;
 236
 237    ------------------------
 238    -- Is_All_Remote_Call --
 239    ------------------------
 240
 241    function Is_All_Remote_Call (N : Node_Id) return Boolean is
 242       Par : Node_Id;
 243
 244    begin
 245       if Nkind_In (N, N_Function_Call, N_Procedure_Call_Statement)
 246         and then Nkind (Name (N)) in N_Has_Entity
 247         and then Is_Remote_Call_Interface (Entity (Name (N)))
 248         and then Has_All_Calls_Remote (Scope (Entity (Name (N))))
 249         and then Comes_From_Source (N)
 250       then
 251          Par := Parent (Entity (Name (N)));
 252          while Present (Par)
 253            and then (Nkind (Par) /= N_Package_Specification
 254                        or else Is_Wrapper_Package (Defining_Entity (Par)))
 255          loop
 256             Par := Parent (Par);
 257          end loop;
 258
 259          if Present (Par) then
 260             return
 261               not Scope_Within_Or_Same (Current_Scope, Defining_Entity (Par));
 262          else
 263             return False;
 264          end if;
 265       else
 266          return False;
 267       end if;
 268    end Is_All_Remote_Call;
 269
 270    ---------------------------------
 271    -- Is_RACW_Stub_Type_Operation --
 272    ---------------------------------
 273
 274    function Is_RACW_Stub_Type_Operation (Op : Entity_Id) return Boolean is
 275       Dispatching_Type : Entity_Id;
 276
 277    begin
 278       case Ekind (Op) is
 279          when E_Function | E_Procedure =>
 280             Dispatching_Type := Find_Dispatching_Type (Op);
 281             return Present (Dispatching_Type)
 282                      and then Is_RACW_Stub_Type (Dispatching_Type)
 283                      and then not Is_Internal (Op);
 284
 285          when others =>
 286             return False;
 287       end case;
 288    end Is_RACW_Stub_Type_Operation;
 289
 290    ------------------------------------
 291    -- Package_Specification_Of_Scope --
 292    ------------------------------------
 293
 294    function Package_Specification_Of_Scope (E : Entity_Id) return Node_Id is
 295       N : Node_Id;
 296
 297    begin
 298       N := Parent (E);
 299       while Nkind (N) /= N_Package_Specification loop
 300          N := Parent (N);
 301       end loop;
 302
 303       return N;
 304    end Package_Specification_Of_Scope;
 305
 306    --------------------------
 307    -- Process_Partition_ID --
 308    --------------------------
 309
 310    procedure Process_Partition_Id (N : Node_Id) is
 311       Loc            : constant Source_Ptr := Sloc (N);
 312       Ety            : Entity_Id;
 313       Get_Pt_Id      : Node_Id;
 314       Get_Pt_Id_Call : Node_Id;
 315       Prefix_String  : String_Id;
 316       Typ            : constant Entity_Id := Etype (N);
 317
 318    begin
 319       --  In case prefix is not a library unit entity, get the entity
 320       --  of library unit.
 321
 322       Ety := Entity (Prefix (N));
 323       while (Present (Scope (Ety))
 324         and then Scope (Ety) /= Standard_Standard)
 325         and not Is_Child_Unit (Ety)
 326       loop
 327          Ety := Scope (Ety);
 328       end loop;
 329
 330       --  Retrieve the proper function to call
 331
 332       if Is_Remote_Call_Interface (Ety) then
 333          Get_Pt_Id := New_Occurrence_Of
 334            (RTE (RE_Get_Active_Partition_Id), Loc);
 335
 336       elsif Is_Shared_Passive (Ety) then
 337          Get_Pt_Id := New_Occurrence_Of
 338            (RTE (RE_Get_Passive_Partition_Id), Loc);
 339
 340       else
 341          Get_Pt_Id := New_Occurrence_Of
 342            (RTE (RE_Get_Local_Partition_Id), Loc);
 343       end if;
 344
 345       --  Get and store the String_Id corresponding to the name of the
 346       --  library unit whose Partition_Id is needed.
 347
 348       Get_Library_Unit_Name_String (Unit_Declaration_Node (Ety));
 349       Prefix_String := String_From_Name_Buffer;
 350
 351       --  Build the function call which will replace the attribute
 352
 353       if Is_Remote_Call_Interface (Ety) or else Is_Shared_Passive (Ety) then
 354          Get_Pt_Id_Call :=
 355            Make_Function_Call (Loc,
 356              Name => Get_Pt_Id,
 357              Parameter_Associations =>
 358                New_List (Make_String_Literal (Loc, Prefix_String)));
 359
 360       else
 361          Get_Pt_Id_Call := Make_Function_Call (Loc, Get_Pt_Id);
 362       end if;
 363
 364       --  Replace the attribute node by a conversion of the function call
 365       --  to the target type.
 366
 367       Rewrite (N, Convert_To (Typ, Get_Pt_Id_Call));
 368       Analyze_And_Resolve (N, Typ);
 369    end Process_Partition_Id;
 370
 371    ----------------------------------
 372    -- Process_Remote_AST_Attribute --
 373    ----------------------------------
 374
 375    procedure Process_Remote_AST_Attribute
 376      (N        : Node_Id;
 377       New_Type : Entity_Id)
 378    is
 379       Loc                   : constant Source_Ptr := Sloc (N);
 380       Remote_Subp           : Entity_Id;
 381       Tick_Access_Conv_Call : Node_Id;
 382       Remote_Subp_Decl      : Node_Id;
 383       RS_Pkg_Specif         : Node_Id;
 384       RS_Pkg_E              : Entity_Id;
 385       RAS_Type              : Entity_Id := New_Type;
 386       Async_E               : Entity_Id;
 387       All_Calls_Remote_E    : Entity_Id;
 388       Attribute_Subp        : Entity_Id;
 389
 390    begin
 391       --  Check if we have to expand the access attribute
 392
 393       Remote_Subp := Entity (Prefix (N));
 394
 395       if not Expander_Active or else Get_PCS_Name = Name_No_DSA then
 396          return;
 397       end if;
 398
 399       if Ekind (RAS_Type) /= E_Record_Type then
 400          RAS_Type := Equivalent_Type (RAS_Type);
 401       end if;
 402
 403       Attribute_Subp := TSS (RAS_Type, TSS_RAS_Access);
 404       pragma Assert (Present (Attribute_Subp));
 405       Remote_Subp_Decl := Unit_Declaration_Node (Remote_Subp);
 406
 407       if Nkind (Remote_Subp_Decl) = N_Subprogram_Body then
 408          Remote_Subp := Corresponding_Spec (Remote_Subp_Decl);
 409          Remote_Subp_Decl := Unit_Declaration_Node (Remote_Subp);
 410       end if;
 411
 412       RS_Pkg_Specif := Parent (Remote_Subp_Decl);
 413       RS_Pkg_E := Defining_Entity (RS_Pkg_Specif);
 414
 415       Async_E :=
 416         Boolean_Literals (Ekind (Remote_Subp) = E_Procedure
 417                             and then Is_Asynchronous (Remote_Subp));
 418
 419       All_Calls_Remote_E :=
 420         Boolean_Literals (Has_All_Calls_Remote (RS_Pkg_E));
 421
 422       Tick_Access_Conv_Call :=
 423         Make_Function_Call (Loc,
 424           Name                   => New_Occurrence_Of (Attribute_Subp, Loc),
 425           Parameter_Associations =>
 426             New_List (
 427               Make_String_Literal (Loc,
 428                 Strval => Full_Qualified_Name (RS_Pkg_E)),
 429               Build_Subprogram_Id (Loc, Remote_Subp),
 430               New_Occurrence_Of (Async_E, Loc),
 431               New_Occurrence_Of (All_Calls_Remote_E, Loc)));
 432
 433       Rewrite (N, Tick_Access_Conv_Call);
 434       Analyze_And_Resolve (N, RAS_Type);
 435    end Process_Remote_AST_Attribute;
 436
 437    ------------------------------------
 438    -- Process_Remote_AST_Declaration --
 439    ------------------------------------
 440
 441    procedure Process_Remote_AST_Declaration (N : Node_Id) is
 442       Loc       : constant Source_Ptr := Sloc (N);
 443       User_Type : constant Node_Id    := Defining_Identifier (N);
 444       Scop      : constant Entity_Id  := Scope (User_Type);
 445       Is_RCI    : constant Boolean    := Is_Remote_Call_Interface (Scop);
 446       Is_RT     : constant Boolean    := Is_Remote_Types (Scop);
 447       Type_Def  : constant Node_Id    := Type_Definition (N);
 448       Parameter : Node_Id;
 449
 450       Is_Degenerate : Boolean;
 451       --  True iff this RAS has an access formal parameter (see
 452       --  Exp_Dist.Add_RAS_Dereference_TSS for details).
 453
 454       Subpkg      : constant Entity_Id :=
 455                       Make_Defining_Identifier (Loc,
 456                         New_Internal_Name ('S'));
 457       Subpkg_Decl : Node_Id;
 458       Subpkg_Body : Node_Id;
 459       Vis_Decls   : constant List_Id := New_List;
 460       Priv_Decls  : constant List_Id := New_List;
 461
 462       Obj_Type : constant Entity_Id :=
 463                     Make_Defining_Identifier (Loc,
 464                       New_External_Name (Chars (User_Type), 'R'));
 465
 466       Full_Obj_Type : constant Entity_Id :=
 467                         Make_Defining_Identifier (Loc,
 468                           Chars (Obj_Type));
 469
 470       RACW_Type : constant Entity_Id :=
 471                     Make_Defining_Identifier (Loc,
 472                       New_External_Name (Chars (User_Type), 'P'));
 473
 474       Fat_Type : constant Entity_Id :=
 475                    Make_Defining_Identifier (Loc,
 476                      Chars (User_Type));
 477
 478       Fat_Type_Decl : Node_Id;
 479
 480    begin
 481       Is_Degenerate := False;
 482       Parameter := First (Parameter_Specifications (Type_Def));
 483       while Present (Parameter) loop
 484          if Nkind (Parameter_Type (Parameter)) = N_Access_Definition then
 485             Error_Msg_N ("formal parameter& has anonymous access type?",
 486               Defining_Identifier (Parameter));
 487             Is_Degenerate := True;
 488             exit;
 489          end if;
 490
 491          Next (Parameter);
 492       end loop;
 493
 494       if Is_Degenerate then
 495          Error_Msg_NE
 496            ("remote access-to-subprogram type& can only be null?",
 497             Defining_Identifier (Parameter), User_Type);
 498
 499          --  The only legal value for a RAS with a formal parameter of an
 500          --  anonymous access type is null, because it cannot be subtype-
 501          --  conformant with any legal remote subprogram declaration. In this
 502          --  case, we cannot generate a corresponding primitive operation.
 503
 504       end if;
 505
 506       if Get_PCS_Name = Name_No_DSA then
 507          return;
 508       end if;
 509
 510       --  The tagged private type, primitive operation and RACW type associated
 511       --  with a RAS need to all be declared in a subpackage of the one that
 512       --  contains the RAS declaration, because the primitive of the object
 513       --  type, and the associated primitive of the stub type, need to be
 514       --  dispatching operations of these types, and the profile of the RAS
 515       --  might contain tagged types declared in the same scope.
 516
 517       Append_To (Vis_Decls,
 518         Make_Private_Type_Declaration (Loc,
 519           Defining_Identifier => Obj_Type,
 520           Abstract_Present => True,
 521           Tagged_Present   => True,
 522           Limited_Present  => True));
 523
 524       Append_To (Priv_Decls,
 525         Make_Full_Type_Declaration (Loc,
 526           Defining_Identifier => Full_Obj_Type,
 527           Type_Definition     =>
 528             Make_Record_Definition (Loc,
 529               Abstract_Present => True,
 530               Tagged_Present   => True,
 531               Limited_Present  => True,
 532               Null_Present     => True,
 533               Component_List   => Empty)));
 534
 535       --  Trick semantic analysis into swapping the public and full view when
 536       --  freezing the public view.
 537
 538       Set_Comes_From_Source (Full_Obj_Type, True);
 539
 540       if not Is_Degenerate then
 541          Append_To (Vis_Decls,
 542            Make_Abstract_Subprogram_Declaration (Loc,
 543              Specification => Build_RAS_Primitive_Specification (
 544                Subp_Spec          => Type_Def,
 545                Remote_Object_Type => Obj_Type)));
 546       end if;
 547
 548       Append_To (Vis_Decls,
 549         Make_Full_Type_Declaration (Loc,
 550           Defining_Identifier => RACW_Type,
 551           Type_Definition     =>
 552             Make_Access_To_Object_Definition (Loc,
 553               All_Present => True,
 554               Subtype_Indication =>
 555                 Make_Attribute_Reference (Loc,
 556                   Prefix         => New_Occurrence_Of (Obj_Type, Loc),
 557                   Attribute_Name => Name_Class))));
 558
 559       Set_Is_Remote_Call_Interface (RACW_Type, Is_RCI);
 560       Set_Is_Remote_Types (RACW_Type, Is_RT);
 561
 562       Subpkg_Decl :=
 563         Make_Package_Declaration (Loc,
 564           Make_Package_Specification (Loc,
 565             Defining_Unit_Name   => Subpkg,
 566             Visible_Declarations => Vis_Decls,
 567             Private_Declarations => Priv_Decls,
 568             End_Label            => New_Occurrence_Of (Subpkg, Loc)));
 569
 570       Set_Is_Remote_Call_Interface (Subpkg, Is_RCI);
 571       Set_Is_Remote_Types (Subpkg, Is_RT);
 572       Insert_After_And_Analyze (N, Subpkg_Decl);
 573
 574       --  Generate package body to receive RACW calling stubs
 575
 576       --  Note: Analyze_Declarations has an absolute requirement that the
 577       --  declaration list be non-empty, so provide dummy null statement here.
 578
 579       Subpkg_Body :=
 580         Make_Package_Body (Loc,
 581           Defining_Unit_Name => Make_Defining_Identifier (Loc, Chars (Subpkg)),
 582           Declarations       => New_List (Make_Null_Statement (Loc)));
 583       Insert_After_And_Analyze (Subpkg_Decl, Subpkg_Body);
 584
 585       --  Many parts of the analyzer and expander expect
 586       --  that the fat pointer type used to implement remote
 587       --  access to subprogram types be a record.
 588       --  Note: The structure of this type must be kept consistent
 589       --  with the code generated by Remote_AST_Null_Value for the
 590       --  corresponding 'null' expression.
 591
 592       Fat_Type_Decl := Make_Full_Type_Declaration (Loc,
 593         Defining_Identifier => Fat_Type,
 594         Type_Definition     =>
 595           Make_Record_Definition (Loc,
 596             Component_List =>
 597               Make_Component_List (Loc,
 598                 Component_Items => New_List (
 599                   Make_Component_Declaration (Loc,
 600                     Defining_Identifier =>
 601                       Make_Defining_Identifier (Loc, Name_Ras),
 602                     Component_Definition =>
 603                       Make_Component_Definition (Loc,
 604                         Aliased_Present     => False,
 605                         Subtype_Indication  =>
 606                           New_Occurrence_Of (RACW_Type, Loc)))))));
 607
 608       Set_Equivalent_Type (User_Type, Fat_Type);
 609       Set_Corresponding_Remote_Type (Fat_Type, User_Type);
 610       Insert_After_And_Analyze (Subpkg_Body, Fat_Type_Decl);
 611
 612       --  The reason we suppress the initialization procedure is that we know
 613       --  that no initialization is required (even if Initialize_Scalars mode
 614       --  is active), and there are order of elaboration problems if we do try
 615       --  to generate an init proc for this created record type.
 616
 617       Set_Suppress_Init_Proc (Fat_Type);
 618
 619       if Expander_Active then
 620          Add_RAST_Features (Parent (User_Type));
 621       end if;
 622    end Process_Remote_AST_Declaration;
 623
 624    -----------------------
 625    -- RAS_E_Dereference --
 626    -----------------------
 627
 628    procedure RAS_E_Dereference (Pref : Node_Id) is
 629       Loc             : constant Source_Ptr := Sloc (Pref);
 630       Call_Node       : Node_Id;
 631       New_Type        : constant Entity_Id := Etype (Pref);
 632       Explicit_Deref  : constant Node_Id   := Parent (Pref);
 633       Deref_Subp_Call : constant Node_Id   := Parent (Explicit_Deref);
 634       Deref_Proc      : Entity_Id;
 635       Params          : List_Id;
 636
 637    begin
 638       if Nkind (Deref_Subp_Call) = N_Procedure_Call_Statement then
 639          Params := Parameter_Associations (Deref_Subp_Call);
 640
 641          if Present (Params) then
 642             Prepend (Pref, Params);
 643          else
 644             Params := New_List (Pref);
 645          end if;
 646
 647       elsif Nkind (Deref_Subp_Call) = N_Indexed_Component then
 648          Params := Expressions (Deref_Subp_Call);
 649
 650          if Present (Params) then
 651             Prepend (Pref, Params);
 652          else
 653             Params := New_List (Pref);
 654          end if;
 655
 656       else
 657          --  Context is not a call
 658
 659          return;
 660       end if;
 661
 662       if not Expander_Active or else Get_PCS_Name = Name_No_DSA then
 663          return;
 664       end if;
 665
 666       Deref_Proc := TSS (New_Type, TSS_RAS_Dereference);
 667       pragma Assert (Present (Deref_Proc));
 668
 669       if Ekind (Deref_Proc) = E_Function then
 670          Call_Node :=
 671            Make_Function_Call (Loc,
 672               Name                   => New_Occurrence_Of (Deref_Proc, Loc),
 673               Parameter_Associations => Params);
 674       else
 675          Call_Node :=
 676            Make_Procedure_Call_Statement (Loc,
 677               Name                   => New_Occurrence_Of (Deref_Proc, Loc),
 678               Parameter_Associations => Params);
 679       end if;
 680
 681       Rewrite (Deref_Subp_Call, Call_Node);
 682       Analyze (Deref_Subp_Call);
 683    end RAS_E_Dereference;
 684
 685    ------------------------------
 686    -- Remote_AST_E_Dereference --
 687    ------------------------------
 688
 689    function Remote_AST_E_Dereference (P : Node_Id) return Boolean is
 690       ET : constant Entity_Id  := Etype (P);
 691
 692    begin
 693       --  Perform the changes only on original dereferences, and only if
 694       --  we are generating code.
 695
 696       if Comes_From_Source (P)
 697         and then Is_Record_Type (ET)
 698         and then (Is_Remote_Call_Interface (ET)
 699                    or else Is_Remote_Types (ET))
 700         and then Present (Corresponding_Remote_Type (ET))
 701         and then Nkind_In (Parent (Parent (P)), N_Procedure_Call_Statement,
 702                                                 N_Indexed_Component)
 703         and then Expander_Active
 704       then
 705          RAS_E_Dereference (P);
 706          return True;
 707       else
 708          return False;
 709       end if;
 710    end Remote_AST_E_Dereference;
 711
 712    ------------------------------
 713    -- Remote_AST_I_Dereference --
 714    ------------------------------
 715
 716    function Remote_AST_I_Dereference (P : Node_Id) return Boolean is
 717       ET     : constant Entity_Id  := Etype (P);
 718       Deref  : Node_Id;
 719
 720    begin
 721       if Comes_From_Source (P)
 722         and then (Is_Remote_Call_Interface (ET)
 723                    or else Is_Remote_Types (ET))
 724         and then Present (Corresponding_Remote_Type (ET))
 725         and then Ekind (Entity (P)) /= E_Function
 726       then
 727          Deref :=
 728            Make_Explicit_Dereference (Sloc (P),
 729              Prefix => Relocate_Node (P));
 730          Rewrite (P, Deref);
 731          Set_Etype (P, ET);
 732          RAS_E_Dereference (Prefix (P));
 733          return True;
 734       end if;
 735
 736       return False;
 737    end Remote_AST_I_Dereference;
 738
 739    ---------------------------
 740    -- Remote_AST_Null_Value --
 741    ---------------------------
 742
 743    function Remote_AST_Null_Value
 744      (N   : Node_Id;
 745       Typ : Entity_Id) return Boolean
 746    is
 747       Loc         : constant Source_Ptr := Sloc (N);
 748       Target_Type : Entity_Id;
 749
 750    begin
 751       if not Expander_Active or else Get_PCS_Name = Name_No_DSA then
 752          return False;
 753
 754       elsif Ekind (Typ) = E_Access_Subprogram_Type
 755         and then (Is_Remote_Call_Interface (Typ)
 756                     or else Is_Remote_Types (Typ))
 757         and then Comes_From_Source (N)
 758         and then Expander_Active
 759       then
 760          --  Any null that comes from source and is of the RAS type must
 761          --  be expanded, except if expansion is not active (nothing
 762          --  gets expanded into the equivalent record type).
 763
 764          Target_Type := Equivalent_Type (Typ);
 765
 766       elsif Ekind (Typ) = E_Record_Type
 767         and then Present (Corresponding_Remote_Type (Typ))
 768       then
 769          --  This is a record type representing a RAS type, this must be
 770          --  expanded.
 771
 772          Target_Type := Typ;
 773
 774       else
 775          --  We do not have to handle this case
 776
 777          return False;
 778       end if;
 779
 780       Rewrite (N,
 781         Make_Aggregate (Loc,
 782           Component_Associations => New_List (
 783             Make_Component_Association (Loc,
 784               Choices => New_List (Make_Identifier (Loc, Name_Ras)),
 785               Expression => Make_Null (Loc)))));
 786       Analyze_And_Resolve (N, Target_Type);
 787       return True;
 788    end Remote_AST_Null_Value;
 789
 790 end Sem_Dist;