gcc/ada/par-ch11.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             P A R . C H 1 1                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 pragma Style_Checks (All_Checks);
  27 --  Turn off subprogram body ordering check. Subprograms are in order
  28 --  by RM section rather than alphabetical
  29
  30 with Sinfo.CN; use Sinfo.CN;
  31
  32 separate (Par)
  33 package body Ch11 is
  34
  35    --  Local functions, used only in this chapter
  36
  37    function P_Exception_Handler  return Node_Id;
  38    function P_Exception_Choice   return Node_Id;
  39
  40    ---------------------------------
  41    -- 11.1  Exception Declaration --
  42    ---------------------------------
  43
  44    --  Parsed by P_Identifier_Declaration (3.3.1)
  45
  46    ------------------------------------------
  47    -- 11.2  Handled Sequence Of Statements --
  48    ------------------------------------------
  49
  50    --  HANDLED_SEQUENCE_OF_STATEMENTS ::=
  51    --      SEQUENCE_OF_STATEMENTS
  52    --    [exception
  53    --      EXCEPTION_HANDLER
  54    --      {EXCEPTION_HANDLER}]
  55
  56    --  Error_Recovery : Cannot raise Error_Resync
  57
  58    function P_Handled_Sequence_Of_Statements return Node_Id is
  59       Handled_Stmt_Seq_Node : Node_Id;
  60
  61    begin
  62       Handled_Stmt_Seq_Node :=
  63         New_Node (N_Handled_Sequence_Of_Statements, Token_Ptr);
  64       Set_Statements
  65         (Handled_Stmt_Seq_Node, P_Sequence_Of_Statements (SS_Extm_Sreq));
  66
  67       if Token = Tok_Exception then
  68          Scan; -- past EXCEPTION
  69          Set_Exception_Handlers
  70            (Handled_Stmt_Seq_Node, Parse_Exception_Handlers);
  71       end if;
  72
  73       return Handled_Stmt_Seq_Node;
  74    end P_Handled_Sequence_Of_Statements;
  75
  76    -----------------------------
  77    -- 11.2  Exception Handler --
  78    -----------------------------
  79
  80    --  EXCEPTION_HANDLER ::=
  81    --    when [CHOICE_PARAMETER_SPECIFICATION :]
  82    --      EXCEPTION_CHOICE {| EXCEPTION_CHOICE} =>
  83    --        SEQUENCE_OF_STATEMENTS
  84
  85    --  CHOICE_PARAMETER_SPECIFICATION ::= DEFINING_IDENTIFIER
  86
  87    --  Error recovery: cannot raise Error_Resync
  88
  89    function P_Exception_Handler return Node_Id is
  90       Scan_State        : Saved_Scan_State;
  91       Handler_Node      : Node_Id;
  92       Choice_Param_Node : Node_Id;
  93
  94    begin
  95       Exception_Handler_Encountered := True;
  96       Handler_Node := New_Node (N_Exception_Handler, Token_Ptr);
  97       Set_Local_Raise_Statements (Handler_Node, No_Elist);
  98
  99       if Style_Check then
 100          Style.Check_Indentation;
 101       end if;
 102
 103       T_When;
 104
 105       --  Test for possible choice parameter present
 106
 107       if Token = Tok_Identifier then
 108          Choice_Param_Node := Token_Node;
 109          Save_Scan_State (Scan_State); -- at identifier
 110          Scan; -- past identifier
 111
 112          if Token = Tok_Colon then
 113             if Ada_Version = Ada_83 then
 114                Error_Msg_SP ("(Ada 83) choice parameter not allowed!");
 115             end if;
 116
 117             Scan; -- past :
 118             Change_Identifier_To_Defining_Identifier (Choice_Param_Node);
 119             Set_Choice_Parameter (Handler_Node, Choice_Param_Node);
 120
 121          elsif Token = Tok_Others then
 122             Error_Msg_AP ("missing "":""");
 123             Change_Identifier_To_Defining_Identifier (Choice_Param_Node);
 124             Set_Choice_Parameter (Handler_Node, Choice_Param_Node);
 125
 126          else
 127             Restore_Scan_State (Scan_State); -- to identifier
 128          end if;
 129       end if;
 130
 131       --  Loop through exception choices
 132
 133       Set_Exception_Choices (Handler_Node, New_List);
 134
 135       loop
 136          Append (P_Exception_Choice, Exception_Choices (Handler_Node));
 137          exit when Token /= Tok_Vertical_Bar;
 138          Scan; -- past vertical bar
 139       end loop;
 140
 141       TF_Arrow;
 142       Set_Statements (Handler_Node, P_Sequence_Of_Statements (SS_Sreq_Whtm));
 143       return Handler_Node;
 144    end P_Exception_Handler;
 145
 146    ------------------------------------------
 147    -- 11.2  Choice Parameter Specification --
 148    ------------------------------------------
 149
 150    --  Parsed by P_Exception_Handler (11.2)
 151
 152    ----------------------------
 153    -- 11.2  Exception Choice --
 154    ----------------------------
 155
 156    --  EXCEPTION_CHOICE ::= exception_NAME | others
 157
 158    --  Error recovery: cannot raise Error_Resync. If an error occurs, then the
 159    --  scan pointer is advanced to the next arrow or vertical bar or semicolon.
 160
 161    function P_Exception_Choice return Node_Id is
 162    begin
 163
 164       if Token = Tok_Others then
 165          Scan; -- past OTHERS
 166          return New_Node (N_Others_Choice, Prev_Token_Ptr);
 167
 168       else
 169          return P_Name; -- exception name
 170       end if;
 171
 172    exception
 173       when Error_Resync =>
 174          Resync_Choice;
 175          return Error;
 176    end P_Exception_Choice;
 177
 178    ---------------------------
 179    -- 11.3  Raise Statement --
 180    ---------------------------
 181
 182    --  RAISE_STATEMENT ::= raise [exception_NAME];
 183
 184    --  The caller has verified that the initial token is RAISE
 185
 186    --  Error recovery: can raise Error_Resync
 187
 188    function P_Raise_Statement return Node_Id is
 189       Raise_Node : Node_Id;
 190
 191    begin
 192       Raise_Node := New_Node (N_Raise_Statement, Token_Ptr);
 193       Scan; -- past RAISE
 194
 195       if Token /= Tok_Semicolon then
 196          Set_Name (Raise_Node, P_Name);
 197       end if;
 198
 199       if Token = Tok_With then
 200          if Ada_Version < Ada_05 then
 201             Error_Msg_SC ("string expression in raise is Ada 2005 extension");
 202             Error_Msg_SC ("\unit must be compiled with -gnat05 switch");
 203          end if;
 204
 205          Scan; -- past WITH
 206          Set_Expression (Raise_Node, P_Expression);
 207       end if;
 208
 209       TF_Semicolon;
 210       return Raise_Node;
 211    end P_Raise_Statement;
 212
 213    ------------------------------
 214    -- Parse_Exception_Handlers --
 215    ------------------------------
 216
 217    --  This routine scans out a list of exception handlers appearing in a
 218    --  construct as:
 219
 220    --    exception
 221    --      EXCEPTION_HANDLER {EXCEPTION_HANDLER}
 222
 223    --  The caller has scanned out the EXCEPTION keyword
 224
 225    --  Control returns after scanning the last exception handler, presumably
 226    --  at the keyword END, but this is not checked in this routine.
 227
 228    --  Error recovery: cannot raise Error_Resync
 229
 230    function Parse_Exception_Handlers return List_Id is
 231       Handler       : Node_Id;
 232       Handlers_List : List_Id;
 233
 234    begin
 235       Handlers_List := New_List;
 236       P_Pragmas_Opt (Handlers_List);
 237
 238       if Token = Tok_End then
 239          Error_Msg_SC ("must have at least one exception handler!");
 240
 241       else
 242          loop
 243             Handler := P_Exception_Handler;
 244             Append (Handler, Handlers_List);
 245
 246             --  Note: no need to check for pragmas here. Although the
 247             --  syntax officially allows them in this position, they
 248             --  will have been swallowed up as part of the statement
 249             --  sequence of the handler we just scanned out.
 250
 251             exit when Token /= Tok_When;
 252          end loop;
 253       end if;
 254
 255       return Handlers_List;
 256    end Parse_Exception_Handlers;
 257
 258 end Ch11;