gcc/ada/a-calend.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         A D A . C A L E N D A R                          --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 package Ada.Calendar is
  39
  40    type Time is private;
  41
  42    --  Declarations representing limits of allowed local time values. Note that
  43    --  these do NOT constrain the possible stored values of time which may well
  44    --  permit a larger range of times (this is explicitly allowed in Ada 95).
  45
  46    subtype Year_Number  is Integer range 1901 .. 2399;
  47    subtype Month_Number is Integer range 1 .. 12;
  48    subtype Day_Number   is Integer range 1 .. 31;
  49
  50    --  A Day_Duration value of 86_400.0 designates a new day
  51
  52    subtype Day_Duration is Duration range 0.0 .. 86_400.0;
  53
  54    function Clock return Time;
  55    --  The returned time value is the number of nanoseconds since the start
  56    --  of Ada time (1901-01-01 00:00:00.0 UTC). If leap seconds are enabled,
  57    --  the result will contain all elapsed leap seconds since the start of
  58    --  Ada time until now.
  59
  60    function Year    (Date : Time) return Year_Number;
  61    function Month   (Date : Time) return Month_Number;
  62    function Day     (Date : Time) return Day_Number;
  63    function Seconds (Date : Time) return Day_Duration;
  64
  65    procedure Split
  66      (Date    : Time;
  67       Year    : out Year_Number;
  68       Month   : out Month_Number;
  69       Day     : out Day_Number;
  70       Seconds : out Day_Duration);
  71    --  Break down a time value into its date components set in the current
  72    --  time zone. If Split is called on a time value created using Ada 2005
  73    --  Time_Of in some arbitrary time zone, the input value will always be
  74    --  interpreted as relative to the local time zone.
  75
  76    function Time_Of
  77      (Year    : Year_Number;
  78       Month   : Month_Number;
  79       Day     : Day_Number;
  80       Seconds : Day_Duration := 0.0) return Time;
  81    --  GNAT Note: Normally when procedure Split is called on a Time value
  82    --  result of a call to function Time_Of, the out parameters of procedure
  83    --  Split are identical to the in parameters of function Time_Of. However,
  84    --  when a non-existent time of day is specified, the values for Seconds
  85    --  may or may not be different. This may happen when Daylight Saving Time
  86    --  (DST) is in effect, on the day when switching to DST, if Seconds
  87    --  specifies a time of day in the hour that does not exist. For example,
  88    --  in New York:
  89    --
  90    --    Time_Of (Year => 1998, Month => 4, Day => 5, Seconds => 10740.0)
  91    --
  92    --  will return a Time value T. If Split is called on T, the resulting
  93    --  Seconds may be 14340.0 (3:59:00) instead of 10740.0 (2:59:00 being
  94    --  a time that not exist).
  95
  96    function "+" (Left : Time;     Right : Duration) return Time;
  97    function "+" (Left : Duration; Right : Time)     return Time;
  98    function "-" (Left : Time;     Right : Duration) return Time;
  99    function "-" (Left : Time;     Right : Time)     return Duration;
 100    --  The first three functions will raise Time_Error if the resulting time
 101    --  value is less than the start of Ada time in UTC or greater than the
 102    --  end of Ada time in UTC. The last function will raise Time_Error if the
 103    --  resulting difference cannot fit into a duration value.
 104
 105    function "<"  (Left, Right : Time) return Boolean;
 106    function "<=" (Left, Right : Time) return Boolean;
 107    function ">"  (Left, Right : Time) return Boolean;
 108    function ">=" (Left, Right : Time) return Boolean;
 109
 110    Time_Error : exception;
 111
 112 private
 113    pragma Inline (Clock);
 114
 115    pragma Inline (Year);
 116    pragma Inline (Month);
 117    pragma Inline (Day);
 118
 119    pragma Inline ("+");
 120    pragma Inline ("-");
 121
 122    pragma Inline ("<");
 123    pragma Inline ("<=");
 124    pragma Inline (">");
 125    pragma Inline (">=");
 126
 127    --  The units used in this version of Ada.Calendar are nanoseconds. The
 128    --  following constants provide values used in conversions of seconds or
 129    --  days to the underlying units.
 130
 131    Nano         : constant := 1_000_000_000;
 132    Nano_F       : constant := 1_000_000_000.0;
 133    Nanos_In_Day : constant := 86_400_000_000_000;
 134    Secs_In_Day  : constant := 86_400;
 135
 136    ----------------------------
 137    -- Implementation of Time --
 138    ----------------------------
 139
 140    --  Time is represented as a signed 64 bit integer count of nanoseconds
 141    --  since the start of Ada time (1901-01-01 00:00:00.0 UTC). Time values
 142    --  produced by Time_Of are internaly normalized to UTC regardless of their
 143    --  local time zone. This representation ensures correct handling of leap
 144    --  seconds as well as performing arithmetic. In Ada 95, Split and Time_Of
 145    --  will treat a time value as being in the local time zone, in Ada 2005,
 146    --  Split and Time_Of will treat a time value as being in the designated
 147    --  time zone by the formal parameter or in UTC by default. The size of the
 148    --  type is large enough to cover the Ada 2005 range of time (1901-01-01
 149    --  00:00:00.0 UTC - 2399-12-31-23:59:59.999999999 UTC).
 150
 151    ------------------
 152    -- Leap seconds --
 153    ------------------
 154
 155    --  Due to Earth's slowdown, the astronomical time is not as precise as the
 156    --  International Atomic Time. To compensate for this inaccuracy, a single
 157    --  leap second is added after the last day of June or December. The count
 158    --  of seconds during those occurences becomes:
 159
 160    --    ... 58, 59, leap second 60, 0, 1, 2 ...
 161
 162    --  Unlike leap days, leap seconds occur simultaneously around the world.
 163    --  In other words, if a leap second occurs at 23:59:60 UTC, it also occurs
 164    --  on 18:59:60 -5 the same day or 2:59:60 +2 on the next day.
 165
 166    --  Leap seconds do not follow a formula. The International Earth Rotation
 167    --  and Reference System Service decides when to add one. Leap seconds are
 168    --  included in the representation of time in Ada 95 mode. As a result,
 169    --  the following two time values will differ by two seconds:
 170
 171    --    1972-06-30 23:59:59.0
 172    --    1972-07-01 00:00:00.0
 173
 174    --  When a new leap second is introduced, the following steps must be
 175    --  carried out:
 176
 177    --     1) Increment Leap_Seconds_Count in a-calend.adb by one
 178    --     2) Increment LS_Count in xleaps.adb by one
 179    --     3) Add the new date to the aggregate of array LS_Dates in
 180    --        xleaps.adb
 181    --     4) Compile and execute xleaps
 182    --     5) Replace the values of Leap_Second_Times in a-calend.adb with the
 183    --        aggregate generated by xleaps
 184
 185    --  The algorithms that build the actual leap second values and discover
 186    --  how many leap seconds have occured between two dates do not need any
 187    --  modification.
 188
 189    ------------------------------
 190    -- Non-leap centenial years --
 191    ------------------------------
 192
 193    --  Over the range of Ada time, centenial years 2100, 2200 and 2300 are
 194    --  non-leap. As a consequence, seven non-leap years occur over the period
 195    --  of year - 4 to year + 4. Internaly, routines Split and Time_Of add or
 196    --  subtract a "fake" February 29 to facilitate the arithmetic involved.
 197
 198    --  The underlying type of Time has been chosen to be a 64 bit signed
 199    --  integer number since it allows for easier processing of sub seconds
 200    --  and arithmetic.
 201
 202    type Time_Rep is range -2 ** 63 .. +2 ** 63 - 1;
 203    type Time is new Time_Rep;
 204
 205    Days_In_Month : constant array (Month_Number) of Day_Number :=
 206                      (31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31);
 207
 208    Invalid_Time_Zone_Offset : Long_Integer;
 209    pragma Import (C, Invalid_Time_Zone_Offset, "__gnat_invalid_tzoff");
 210
 211    function Is_Leap (Year : Year_Number) return Boolean;
 212    --  Determine whether a given year is leap
 213
 214    --  The following packages provide a target independent interface to the
 215    --  children of Calendar - Arithmetic, Delays, Formatting and Time_Zones.
 216
 217    package Arithmetic_Operations is
 218       function Add (Date : Time; Days : Long_Integer) return Time;
 219       --  Add a certain number of days to a time value
 220
 221       procedure Difference
 222         (Left         : Time;
 223          Right        : Time;
 224          Days         : out Long_Integer;
 225          Seconds      : out Duration;
 226          Leap_Seconds : out Integer);
 227       --  Calculate the difference between two time values in terms of days,
 228       --  seconds and leap seconds elapsed. The leap seconds are not included
 229       --  in the seconds returned. If Left is greater than Right, the returned
 230       --  values are positive, negative otherwise.
 231
 232       function Subtract (Date : Time; Days : Long_Integer) return Time;
 233       --  Subtract a certain number of days from a time value
 234    end Arithmetic_Operations;
 235
 236    package Delays_Operations is
 237       function To_Duration (Date : Time) return Duration;
 238       --  Given a time value in nanoseconds since 1901, convert it into a
 239       --  duration value giving the number of nanoseconds since the Unix Epoch.
 240    end Delays_Operations;
 241
 242    package Formatting_Operations is
 243       function Day_Of_Week (Date : Time) return Integer;
 244       --  Determine which day of week Date falls on. The returned values are
 245       --  within the range of 0 .. 6 (Monday .. Sunday).
 246
 247       procedure Split
 248         (Date      : Time;
 249          Year      : out Year_Number;
 250          Month     : out Month_Number;
 251          Day       : out Day_Number;
 252          Day_Secs  : out Day_Duration;
 253          Hour      : out Integer;
 254          Minute    : out Integer;
 255          Second    : out Integer;
 256          Sub_Sec   : out Duration;
 257          Leap_Sec  : out Boolean;
 258          Is_Ada_05 : Boolean;
 259          Time_Zone : Long_Integer);
 260       --  Split a time value into its components. Set Is_Ada_05 to use the
 261       --  local time zone (the value in Time_Zone is ignored) when splitting
 262       --  a time value.
 263
 264       function Time_Of
 265         (Year         : Year_Number;
 266          Month        : Month_Number;
 267          Day          : Day_Number;
 268          Day_Secs     : Day_Duration;
 269          Hour         : Integer;
 270          Minute       : Integer;
 271          Second       : Integer;
 272          Sub_Sec      : Duration;
 273          Leap_Sec     : Boolean;
 274          Use_Day_Secs : Boolean;
 275          Is_Ada_05    : Boolean;
 276          Time_Zone    : Long_Integer) return Time;
 277       --  Given all the components of a date, return the corresponding time
 278       --  value. Set Use_Day_Secs to use the value in Day_Secs, otherwise the
 279       --  day duration will be calculated from Hour, Minute, Second and Sub_
 280       --  Sec. Set Is_Ada_05 to use the local time zone (the value in formal
 281       --  Time_Zone is ignored) when building a time value and to verify the
 282       --  validity of a requested leap second.
 283    end Formatting_Operations;
 284
 285    package Time_Zones_Operations is
 286       function UTC_Time_Offset (Date : Time) return Long_Integer;
 287       --  Return the offset in seconds from UTC
 288    end Time_Zones_Operations;
 289
 290 end Ada.Calendar;