gcc/ada/restrict.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             R E S T R I C T                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This package deals with the implementation of the Restrictions pragma
  28
  29 with Rident; use Rident;
  30 with Table;
  31 with Types;  use Types;
  32 with Uintp;  use Uintp;
  33
  34 package Restrict is
  35
  36    Restrictions : Restrictions_Info;
  37    --  This variable records restrictions found in any units in the main
  38    --  extended unit, and in the case of restrictions checked for partition
  39    --  consistency, restrictions found in any with'ed units, parent specs
  40    --  etc, since we may as well check as much as we can at compile time.
  41    --  These variables should not be referenced directly by clients. Instead
  42    --  use Check_Restrictions to record a violation of a restriction, and
  43    --  Restriction_Active to test if a given restriction is active.
  44
  45    Restrictions_Loc : array (All_Restrictions) of Source_Ptr :=
  46                        (others => No_Location);
  47    --  Locations of Restrictions pragmas for error message purposes.
  48    --  Valid only if corresponding entry in Restrictions is set. A value
  49    --  of No_Location is used for implicit restrictions set by another
  50    --  pragma, and a value of System_Location is used for restrictions
  51    --  set from package Standard by the processing in Targparm.
  52
  53    Main_Restrictions : Restrictions_Info;
  54    --  This variable records only restrictions found in any units of the
  55    --  main extended unit. These are the variables used for ali file output,
  56    --  since we want the binder to be able to accurately diagnose inter-unit
  57    --  restriction violations.
  58
  59    Restriction_Warnings : Rident.Restriction_Flags;
  60    --  If one of these flags is set, then it means that violation of the
  61    --  corresponding restriction results only in a warning message, not
  62    --  in an error message, and the restriction is not otherwise enforced.
  63    --  Note that the flags in Restrictions are set to indicate that the
  64    --  restriction is set in this case, but Main_Restrictions is never
  65    --  set if Restriction_Warnings is set, so this does not look like a
  66    --  restriction to the binder.
  67
  68    type Save_Cunit_Boolean_Restrictions is private;
  69    --  Type used for saving and restoring compilation unit restrictions.
  70    --  See Cunit_Boolean_Restrictions_[Save|Restore] subprograms.
  71
  72    --  The following declarations establish a mapping between restriction
  73    --  identifiers, and the names of corresponding restriction library units.
  74
  75    type Unit_Entry is record
  76       Res_Id : Restriction_Id;
  77       Filenm : String (1 .. 8);
  78    end record;
  79
  80    Unit_Array : constant array (Positive range <>) of Unit_Entry := (
  81      (No_Asynchronous_Control,     "a-astaco"),
  82      (No_Calendar,                 "a-calend"),
  83      (No_Calendar,                 "calendar"),
  84      (No_Delay,                    "a-calend"),
  85      (No_Delay,                    "calendar"),
  86      (No_Dynamic_Priorities,       "a-dynpri"),
  87      (No_Finalization,             "a-finali"),
  88      (No_IO,                       "a-direio"),
  89      (No_IO,                       "directio"),
  90      (No_IO,                       "a-sequio"),
  91      (No_IO,                       "sequenio"),
  92      (No_IO,                       "a-ststio"),
  93      (No_IO,                       "a-textio"),
  94      (No_IO,                       "text_io "),
  95      (No_IO,                       "a-witeio"),
  96      (No_Task_Attributes_Package,  "a-tasatt"),
  97      (No_Unchecked_Conversion,     "a-unccon"),
  98      (No_Unchecked_Conversion,     "unchconv"),
  99      (No_Unchecked_Deallocation,   "a-uncdea"),
 100      (No_Unchecked_Deallocation,   "unchdeal"));
 101
 102    --  The following map has True for all GNAT pragmas. It is used to
 103    --  implement pragma Restrictions (No_Implementation_Restrictions)
 104    --  (which is why this restriction itself is excluded from the list).
 105
 106    Implementation_Restriction : array (All_Restrictions) of Boolean :=
 107      (Simple_Barriers                    => True,
 108       No_Calendar                        => True,
 109       No_Dynamic_Attachment              => True,
 110       No_Enumeration_Maps                => True,
 111       No_Entry_Calls_In_Elaboration_Code => True,
 112       No_Entry_Queue                     => True,
 113       No_Exception_Handlers              => True,
 114       No_Exception_Registration          => True,
 115       No_Implicit_Conditionals           => True,
 116       No_Implicit_Dynamic_Code           => True,
 117       No_Implicit_Loops                  => True,
 118       No_Local_Protected_Objects         => True,
 119       No_Protected_Type_Allocators       => True,
 120       No_Relative_Delay                  => True,
 121       No_Requeue_Statements              => True,
 122       No_Secondary_Stack                 => True,
 123       No_Select_Statements               => True,
 124       No_Standard_Storage_Pools          => True,
 125       No_Streams                         => True,
 126       No_Task_Attributes_Package         => True,
 127       No_Task_Termination                => True,
 128       No_Wide_Characters                 => True,
 129       Static_Priorities                  => True,
 130       Static_Storage_Size                => True,
 131       No_Implementation_Attributes       => True,
 132       No_Implementation_Pragmas          => True,
 133       No_Elaboration_Code                => True,
 134       others                             => False);
 135
 136    --  The following table records entries made by Restrictions pragmas
 137    --  that specify a parameter for No_Dependence. Each such pragma makes
 138    --  an entry in this table.
 139
 140    --  Note: we have chosen to implement this restriction in the "syntactic"
 141    --  form, where we do not check that the named package is a language defined
 142    --  package, but instead we allow arbitrary package names. The discussion of
 143    --  this issue is not complete in the ARG, but the sense seems to be leaning
 144    --  in this direction, which makes more sense to us, since it is much more
 145    --  useful, and much easier to implement.
 146
 147    type ND_Entry is record
 148       Unit : Node_Id;
 149       --  The unit parameter from the No_Dependence pragma
 150
 151       Warn : Boolean;
 152       --  True if from Restriction_Warnings, False if from Restrictions
 153    end record;
 154
 155    package No_Dependence is new Table.Table (
 156      Table_Component_Type => ND_Entry,
 157      Table_Index_Type     => Int,
 158      Table_Low_Bound      => 0,
 159      Table_Initial        => 200,
 160      Table_Increment      => 200,
 161      Table_Name           => "Name_No_Dependence");
 162
 163    -----------------
 164    -- Subprograms --
 165    -----------------
 166
 167    function Abort_Allowed return Boolean;
 168    pragma Inline (Abort_Allowed);
 169    --  Tests to see if abort is allowed by the current restrictions settings.
 170    --  For abort to be allowed, either No_Abort_Statements must be False,
 171    --  or Max_Asynchronous_Select_Nesting must be non-zero.
 172
 173    procedure Check_Restricted_Unit (U : Unit_Name_Type; N : Node_Id);
 174    --  Checks if loading of unit U is prohibited by the setting of some
 175    --  restriction (e.g. No_IO restricts the loading of unit Ada.Text_IO).
 176    --  If a restriction exists post error message at the given node.
 177
 178    procedure Check_Restriction
 179      (R : Restriction_Id;
 180       N : Node_Id;
 181       V : Uint := Uint_Minus_1);
 182    --  Checks that the given restriction is not set, and if it is set, an
 183    --  appropriate message is posted on the given node. Also records the
 184    --  violation in the appropriate internal arrays. Note that it is
 185    --  mandatory to always use this routine to check if a restriction
 186    --  is violated. Such checks must never be done directly by the caller,
 187    --  since otherwise violations in the absence of restrictions are not
 188    --  properly recorded. The value of V is relevant only for parameter
 189    --  restrictions, and in this case indicates the exact count for the
 190    --  violation. If the exact count is not known, V is left at its
 191    --  default value of -1 which indicates an unknown count.
 192
 193    procedure Check_Restriction_No_Dependence (U : Node_Id; Err : Node_Id);
 194    --  Called when a dependence on a unit is created (either implicitly, or by
 195    --  an explicit WITH clause). U is a node for the unit involved, and Err
 196    --  is the node to which an error will be attached if necessary.
 197
 198    procedure Check_Elaboration_Code_Allowed (N : Node_Id);
 199    --  Tests to see if elaboration code is allowed by the current restrictions
 200    --  settings. This function is called by Gigi when it needs to define
 201    --  an elaboration routine. If elaboration code is not allowed, an error
 202    --  message is posted on the node given as argument.
 203
 204    procedure Check_No_Implicit_Heap_Alloc (N : Node_Id);
 205    --  Equivalent to Check_Restriction (No_Implicit_Heap_Allocations, N).
 206    --  Provided for easy use by back end, which has to check this restriction.
 207
 208    function Cunit_Boolean_Restrictions_Save
 209      return Save_Cunit_Boolean_Restrictions;
 210    --  This function saves the compilation unit restriction settings, and
 211    --  resets them to False. This is used e.g. when compiling a with'ed
 212    --  unit to avoid incorrectly propagating restrictions. Note that it
 213    --  would not be wrong to also save and reset the partition restrictions,
 214    --  since the binder would catch inconsistencies, but actually it is a
 215    --  good thing to acquire restrictions from with'ed units if they are
 216    --  required to be partition wide, because it allows the restriction
 217    --  violation message to be given at compile time instead of link time.
 218
 219    procedure Cunit_Boolean_Restrictions_Restore
 220      (R : Save_Cunit_Boolean_Restrictions);
 221    --  This is the corresponding restore procedure to restore restrictions
 222    --  previously saved by Cunit_Boolean_Restrictions_Save.
 223
 224    function Get_Restriction_Id
 225      (N : Name_Id) return Restriction_Id;
 226    --  Given an identifier name, determines if it is a valid restriction
 227    --  identifier, and if so returns the corresponding Restriction_Id
 228    --  value, otherwise returns Not_A_Restriction_Id.
 229
 230    function No_Exception_Handlers_Set return Boolean;
 231    --  Test to see if current restrictions settings specify that no exception
 232    --  handlers are present. This function is called by Gigi when it needs to
 233    --  expand an AT END clean up identifier with no exception handler.
 234
 235    function Process_Restriction_Synonyms (N : Node_Id) return Name_Id;
 236    --  Id is a node whose Chars field contains the name of a restriction.
 237    --  If it is one of synonyms that we allow for historical purposes (for
 238    --  list see System.Rident), then the proper official name is returned.
 239    --  Otherwise the Chars field of the argument is returned unchanged.
 240
 241    function Restriction_Active (R : All_Restrictions) return Boolean;
 242    pragma Inline (Restriction_Active);
 243    --  Determines if a given restriction is active. This call should only be
 244    --  used where the compiled code depends on whether the restriction is
 245    --  active. Always use Check_Restriction to record a violation.
 246
 247    function Restricted_Profile return Boolean;
 248    --  Tests if set of restrictions corresponding to Profile (Restricted) is
 249    --  currently in effect (set by pragma Profile, or by an appropriate set
 250    --  of individual Restrictions pragms). Returns True only if all the
 251    --  required restrictions are set.
 252
 253    procedure Set_Profile_Restrictions
 254      (P    : Profile_Name;
 255       N    : Node_Id;
 256       Warn : Boolean);
 257    --  Sets the set of restrictions associated with the given profile
 258    --  name. N is the node of the construct to which error messages
 259    --  are to be attached as required. Warn is set True for the case
 260    --  of Profile_Warnings where the restrictions are set as warnings
 261    --  rather than legality requirements.
 262
 263    procedure Set_Restriction
 264      (R : All_Boolean_Restrictions;
 265       N : Node_Id);
 266    --  N is a node (typically a pragma node) that has the effect of setting
 267    --  Boolean restriction R. The restriction is set in Restrictions, and
 268    --  also in Main_Restrictions if this is the main unit.
 269
 270    procedure Set_Restriction
 271      (R : All_Parameter_Restrictions;
 272       N : Node_Id;
 273       V : Integer);
 274    --  Similar to the above, except that this is used for the case of a
 275    --  parameter restriction, and the corresponding value V is given.
 276
 277    procedure Set_Restriction_No_Dependence
 278      (Unit : Node_Id;
 279       Warn : Boolean);
 280    --  Sets given No_Dependence restriction in table if not there already.
 281    --  Warn is True if from Restriction_Warnings, False if from Restrictions.
 282
 283    function Tasking_Allowed return Boolean;
 284    pragma Inline (Tasking_Allowed);
 285    --  Tests to see if tasking operations are allowed by the current
 286    --  restrictions settings. For tasking to be allowed Max_Tasks must
 287    --  be non-zero.
 288
 289 private
 290    type Save_Cunit_Boolean_Restrictions is
 291      array (Cunit_Boolean_Restrictions) of Boolean;
 292    --  Type used for saving and restoring compilation unit restrictions.
 293    --  See Compilation_Unit_Restrictions_[Save|Restore] subprograms.
 294
 295 end Restrict;